configure.ac

   1 # get rid of that stupid cache mechanism
   2 rm -f config.cache
   3
   4 AC_INIT([ecore], [0.9.9.063], [enlightenment-devel@lists.sourceforge.net])
   5 release="ver-pre-svn-05"
   6 AC_PREREQ([2.52])
   7 AC_CONFIG_SRCDIR([configure.ac])
   8 AC_CONFIG_MACRO_DIR([m4])
   9 AC_CANONICAL_BUILD
  10 AC_CANONICAL_HOST
  11 AC_ISC_POSIX
  12
  13 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  14 AM_CONFIG_HEADER([config.h])
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_GNU_SOURCE
  18
  19 AC_LIBTOOL_WIN32_DLL
  20 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  21 AC_PROG_LIBTOOL
  22
  23 VMAJ=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $1);}'`
  24 VMIN=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $2);}'`
  25 VMIC=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $3);}'`
  26 SNAP=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $4);}'`
  27 version_info=`expr $VMAJ + $VMIN`":$VMIC:$VMIN"
  28 AC_SUBST(version_info)
  29
  30 AM_GNU_GETTEXT_VERSION([0.12.1])
  31 AM_GNU_GETTEXT([external])
  32
  33 EFL_CHECK_PATH_MAX
  34
  35 case "$host_os" in
  36    mingw32ce* | cegcc*)
  37       ;;
  38    *)
  39       ecore_config_release_info="-release $release"
  40       ecore_con_release_info="-release $release"
  41       ecore_data_release_info="-release $release"
  42       ecore_directfb_release_info="-release $release"
  43       ecore_evas_release_info="-release $release"
  44       ecore_fb_release_info="-release $release"
  45       ecore_file_release_info="-release $release"
  46       ecore_imf_evas_release_info="-release $release"
  47       ecore_imf_release_info="-release $release"
  48       ecore_input_release_info="-release $release"
  49       ecore_input_evas_release_info="-release $release"
  50       ecore_ipc_release_info="-release $release"
  51       ecore_quartz_release_info="-release $release"
  52       ecore_release_info="-release $release"
  53       ecore_sdl_release_info="-release $release"
  54       ecore_txt_release_info="-release $release"
  55       ecore_win32_release_info="-release $release"
  56       ecore_x_release_info="-release $release"
  57       ;;
  58 esac
  59 AC_SUBST(ecore_config_release_info)
  60 AC_SUBST(ecore_con_release_info)
  61 AC_SUBST(ecore_data_release_info)
  62 AC_SUBST(ecore_directfb_release_info)
  63 AC_SUBST(ecore_evas_release_info)
  64 AC_SUBST(ecore_fb_release_info)
  65 AC_SUBST(ecore_file_release_info)
  66 AC_SUBST(ecore_imf_evas_release_info)
  67 AC_SUBST(ecore_imf_release_info)
  68 AC_SUBST(ecore_input_release_info)
  69 AC_SUBST(ecore_input_evas_release_info)
  70 AC_SUBST(ecore_ipc_release_info)
  71 AC_SUBST(ecore_quartz_release_info)
  72 AC_SUBST(ecore_release_info)
  73 AC_SUBST(ecore_sdl_release_info)
  74 AC_SUBST(ecore_txt_release_info)
  75 AC_SUBST(ecore_win32_release_info)
  76 AC_SUBST(ecore_wince_release_info)
  77 AC_SUBST(ecore_x_release_info)
  78
  79 AC_DEFINE_UNQUOTED(SHARED_LIB_SUFFIX, "$shrext_cmds", [Suffix for shared objects])
  80
  81
  82 ### Default options with respect to host
  83
  84 # dependencies and options
  85 want_curl="no"
  86 want_abstract_sockets="no"
  87 want_gnutls="no"
  88 want_openssl="no"
  89 want_cares="no"
  90 want_cipher="no"
  91 want_signature="no"
  92 want_poll="yes"
  93 want_inotify="no"
  94 want_notify_win32="no"
  95 want_tslib="no"
  96 want_glib="no"
  97
  98 # core modules
  99 want_ecore_txt="yes"
 100 want_ecore_con="no"
 101 want_ecore_ipc="no"
 102 want_ecore_file="yes"
 103 want_ecore_config="no"
 104 want_ecore_imf="no"
 105 want_ecore_input="yes"
 106
 107 # graphic system modules
 108 want_evas_simple_x11="no"
 109 want_ecore_x_xcb="no"
 110 want_ecore_x="no"
 111 want_ecore_win32="no"
 112 want_ecore_quartz="no"
 113 want_ecore_sdl="no"
 114 want_ecore_fb="no"
 115 want_ecore_directfb="no"
 116 want_ecore_wince="no"
 117
 118 # ecore_evas modules
 119 want_ecore_evas="yes"
 120 want_ecore_evas_software_buffer="yes"
 121 want_ecore_evas_software_x11="no"
 122 want_ecore_evas_xrender_x11="no"
 123 want_ecore_evas_opengl_x11="no"
 124 want_ecore_evas_software_16_x11="no"
 125 want_ecore_evas_software_xcb="no"
 126 want_ecore_evas_xrender_xcb="no"
 127 want_ecore_evas_software_gdi="no"
 128 want_ecore_evas_software_ddraw="no"
 129 want_ecore_evas_direct3d="no"
 130 want_ecore_evas_opengl_glew="no"
 131 want_ecore_evas_software_16_ddraw="no"
 132 want_ecore_evas_quartz="no"
 133 want_ecore_evas_software_sdl="no"
 134 want_ecore_evas_gl_sdl="no"
 135 want_ecore_evas_directfb="no"
 136 want_ecore_evas_fb="no"
 137 want_ecore_evas_software_16_wince="no"
 138
 139 case "$host_os" in
 140    mingw32ce* | cegcc*)
 141       want_ecore_wince="yes"
 142       want_ecore_evas_software_16_wince="yes"
 143       ;;
 144    mingw*)
 145       want_notify_win32="yes"
 146       want_curl="yes"
 147       want_glib="auto"
 148       want_ecore_imf="yes"
 149       want_ecore_win32="yes"
 150       want_ecore_evas_software_gdi="yes"
 151       want_ecore_evas_software_ddraw="yes"
 152       want_ecore_evas_direct3d="yes"
 153       want_ecore_evas_opengl_glew="yes"
 154       want_ecore_evas_software_16_ddraw="auto"
 155       want_ecore_evas_software_sdl="yes"
 156       want_ecore_evas_gl_sdl="yes"
 157       ;;
 158    darwin*)
 159       want_curl="yes"
 160       want_glib="auto"
 161       want_gnutls="auto"
 162       want_openssl="auto"
 163       want_ecore_con="yes"
 164       want_ecore_ipc="yes"
 165       want_ecore_config="yes"
 166       want_ecore_imf="yes"
 167       want_ecore_quartz="yes"
 168       want_ecore_evas_quartz="yes"
 169       want_ecore_evas_software_sdl="yes"
 170       want_ecore_evas_gl_sdl="yes"
 171       ;;
 172    *)
 173       want_curl="yes"
 174       want_glib="auto"
 175       want_abstract_sockets="yes"
 176       want_gnutls="auto"
 177       want_openssl="auto"
 178       want_cipher="yes"
 179       want_signature="yes"
 180       want_inotify="yes"
 181       want_tslib="yes"
 182       want_ecore_con="yes"
 183       want_ecore_ipc="yes"
 184       want_ecore_config="yes"
 185       want_ecore_imf="yes"
 186       want_ecore_x="yes"
 187       want_ecore_evas_software_x11="yes"
 188       want_ecore_evas_xrender_x11="yes"
 189       want_ecore_evas_opengl_x11="yes"
 190       want_ecore_evas_software_16_x11="yes"
 191       want_ecore_evas_software_xcb="yes"
 192       want_ecore_evas_xrender_xcb="yes"
 193       want_ecore_evas_software_sdl="yes"
 194       want_ecore_evas_gl_sdl="yes"
 195       want_ecore_evas_directfb="yes"
 196       want_ecore_evas_fb="yes"
 197       ;;
 198 esac
 199
 200 requirements_ecore=""
 201 requirements_ecore_con=""
 202 requirements_ecore_config=""
 203 requirements_ecore_data=""
 204 requirements_ecore_directfb=""
 205 requirements_ecore_evas=""
 206 requirements_ecore_fb=""
 207 requirements_ecore_file=""
 208 requirements_ecore_imf=""
 209 requirements_ecore_imf_evas=""
 210 requirements_ecore_input=""
 211 requirements_ecore_input_evas=""
 212 requirements_ecore_ipc=""
 213 requirements_ecore_quartz=""
 214 requirements_ecore_sdl=""
 215 requirements_ecore_txt=""
 216 requirements_ecore_x=""
 217 requirements_ecore_win32=""
 218 requirements_ecore_wince=""
 219
 220 ### Additional options to configure
 221
 222 # abstract sockets (ecore_con.c)
 223 AC_ARG_ENABLE([abstract-sockets],
 224    [AC_HELP_STRING([--disable-abstract-sockets], [disable abstract sockets.])],
 225    [
 226     if test "x${enableval}" = "xyes" ; then
 227        want_abstract_sockets="yes"
 228     else
 229        want_abstract_sockets="no"
 230     fi
 231    ],
 232    [want_abstract_sockets="yes"])
 233
 234 if test "x${want_abstract_sockets}" = "xyes" ; then
 235    AC_DEFINE([HAVE_ABSTRACT_SOCKETS], [1], [Have abstract sockets namespace])
 236 fi
 237
 238 # Simple X11 build/link
 239
 240 AC_ARG_ENABLE(simple-x11,
 241   AC_HELP_STRING([--enable-simple-x11], [enable simple x11 linking]),
 242   [want_evas_simple_x11=$enableval])
 243
 244 # XIM
 245 AC_ARG_ENABLE([xim],
 246    [AC_HELP_STRING([--enable-xim], [enable X Input Method.])],
 247    [
 248     if test "x${enableval}" = "xyes" ; then
 249        want_xim="yes"
 250     else
 251        want_xim="no"
 252     fi
 253    ],
 254    [want_xim="no"])
 255
 256 if test "x${want_xim}" = "xyes" ; then
 257    AC_DEFINE([ENABLE_XIM], [1], [Enable X Input Method])
 258 fi
 259
 260
 261 ### Checks for programs
 262
 263 m4_ifdef([AC_PROG_OBJC],
 264    [
 265     AC_PROG_OBJC
 266     _AM_DEPENDENCIES(OBJC)
 267    ],
 268    [
 269     AC_CHECK_TOOL([OBJC], [gcc])
 270     AC_SUBST([OBJC])
 271     AC_SUBST([OBJCFLAGS])
 272    ])
 273 AC_PROG_CXX
 274 AC_PROG_CC
 275
 276 have_gnu_objc=${ac_cv_objc_compiler_gnu}
 277
 278 # doxygen program for documentation building
 279
 280 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 281
 282 # The first call to PKG_CHECK_MODULES is done conditionally,
 283 # so we should include this here:
 284 PKG_PROG_PKG_CONFIG
 285
 286 # Check whether pkg-config supports Requires.private
 287 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 288    pkgconfig_requires_private="Requires.private"
 289 else
 290    pkgconfig_requires_private="Requires"
 291 fi
 292 AC_SUBST(pkgconfig_requires_private)
 293
 294
 295 ### Checks for libraries
 296
 297 # Evil library for compilation on Windows
 298
 299 case "$host_os" in
 300    mingw* | cegcc*)
 301       PKG_CHECK_MODULES([EVIL], [evil])
 302       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if Evil library is installed])
 303       requirements_ecore="evil ${requirements_ecore}"
 304       requirements_ecore_evas="evil ${requirements_ecore_evas}"
 305       requirements_ecore_file="evil ${requirements_ecore_file}"
 306       requirements_ecore_imf="evil ${requirements_ecore_imf}"
 307       requirements_ecore_imf_evas="evil ${requirements_ecore_imf_evas}"
 308       requirements_ecore_txt="evil ${requirements_ecore_txt}"
 309       EFL_ECORE_BUILD="-DEFL_ECORE_BUILD"
 310       EFL_ECORE_TXT_BUILD="-DEFL_ECORE_TXT_BUILD"
 311       EFL_ECORE_FILE_BUILD="-DEFL_ECORE_FILE_BUILD"
 312       EFL_ECORE_EVAS_BUILD="-DEFL_ECORE_EVAS_BUILD"
 313       EFL_ECORE_IMF_BUILD="-DEFL_ECORE_IMF_BUILD"
 314       EFL_ECORE_INPUT_BUILD="-DEFL_ECORE_INPUT_BUILD"
 315       ;;
 316 esac
 317
 318 have_win32=""
 319 have_wince=""
 320 case "$host_os" in
 321    mingw32ce* | cegcc*)
 322       EFL_ECORE_WINCE_BUILD="-DEFL_ECORE_WINCE_BUILD"
 323       requirements_ecore_wince="evil ${requirements_ecore_wince}"
 324       have_wince="yes"
 325       ;;
 326    mingw*)
 327       EFL_ECORE_WIN32_BUILD="-DEFL_ECORE_WIN32_BUILD"
 328       EFL_ECORE_SDL_BUILD="-DEFL_ECORE_SDL_BUILD"
 329       requirements_ecore_win32="evil ${requirements_ecore_win32}"
 330       requirements_ecore_sdl="evil ${requirements_ecore_sdl}"
 331       have_win32="yes"
 332       ;;
 333 esac
 334
 335 AC_SUBST(EFL_ECORE_BUILD)
 336 AC_SUBST(EFL_ECORE_TXT_BUILD)
 337 AC_SUBST(EFL_ECORE_FILE_BUILD)
 338 AC_SUBST(EFL_ECORE_EVAS_BUILD)
 339 AC_SUBST(EFL_ECORE_IMF_BUILD)
 340 AC_SUBST(EFL_ECORE_INPUT_BUILD)
 341 AC_SUBST(EFL_ECORE_WINCE_BUILD)
 342 AC_SUBST(EFL_ECORE_WIN32_BUILD)
 343 AC_SUBST(EFL_ECORE_SDL_BUILD)
 344
 345 AM_CONDITIONAL(ECORE_HAVE_WINCE, test "x${have_wince}" = "xyes")
 346 AM_CONDITIONAL(ECORE_HAVE_WIN32, test "x${have_win32}" = "xyes")
 347
 348 WIN32_LIBS=""
 349 case "$host_os" in
 350    mingw32ce* | cegcc*)
 351       WIN32_LIBS="-lws2"
 352       dlopen_libs="-ldl"
 353       ;;
 354    mingw*)
 355       WIN32_LIBS="-lws2_32"
 356       dlopen_libs="-ldl"
 357       ;;
 358    *)
 359       AC_CHECK_LIB(dl, dlopen, dlopen_libs=-ldl)
 360       ;;
 361 esac
 362 AC_SUBST(WIN32_LIBS)
 363 AC_SUBST(dlopen_libs)
 364
 365 # Eina library
 366
 367 PKG_CHECK_MODULES(EINA, [eina-0])
 368 #FIXME check all the requirements when the eina move will be finished
 369 requirements_ecore="eina-0 ${requirements_ecore}"
 370 requirements_ecore_con="ecore eina-0 ${requirements_ecore_con}"
 371 requirements_ecore_config="ecore eina-0 ${requirements_ecore_config}"
 372 requirements_ecore_data="ecore eina-0 ${requirements_ecore_data}"
 373 requirements_ecore_directfb="ecore eina-0 ${requirements_ecore_directfb}"
 374 requirements_ecore_evas="ecore eina-0 ${requirements_ecore_evas}"
 375 requirements_ecore_fb="ecore eina-0 ${requirements_ecore_fb}"
 376 requirements_ecore_file="ecore eina-0 ${requirements_ecore_file}"
 377 requirements_ecore_imf="ecore eina-0 ${requirements_ecore_imf}"
 378 requirements_ecore_imf_evas="ecore eina-0 ${requirements_ecore_imf_evas}"
 379 requirements_ecore_input="ecore eina-0 ${requirements_ecore_input}"
 380 requirements_ecore_input_evas="ecore eina-0 ${requirements_ecore_input_evas}"
 381 requirements_ecore_ipc="ecore eina-0 ${requirements_ecore_ipc}"
 382 requirements_ecore_quartz="ecore eina-0 ${requirements_ecore_quartz}"
 383 requirements_ecore_sdl="ecore eina-0 ${requirements_ecore_sdl}"
 384 requirements_ecore_win32="ecore eina-0 ${requirements_ecore_win32}"
 385 requirements_ecore_wince="ecore eina-0 ${requirements_ecore_wince}"
 386 requirements_ecore_x="ecore eina-0 ${requirements_ecore_x}"
 387
 388
 389 # glib support (main loop integration)
 390 AC_ARG_ENABLE([glib],
 391    [AC_HELP_STRING([--disable-glib], [enable glib support. @<:@default=detect@:>@])],
 392    [want_glib=$enableval], [])
 393
 394 if test "x$want_glib" != "xno"; then
 395    PKG_CHECK_MODULES([GLIB], [glib-2.0], [have_glib="yes"], [have_glib="no"])
 396 else
 397    have_glib="no"
 398 fi
 399 if test "x$want_glib" = "xyes" -a "x$have_glib" = "xno"; then
 400    AC_MSG_ERROR([GLib support requested, but no GLib found by pkg-config.])
 401 elif test "x$have_glib" = "xyes"; then
 402    AC_DEFINE(HAVE_GLIB, [1], [Have GLib])
 403    requirements_ecore="glib-2.0 ${requirements_ecore}"
 404 fi
 405
 406
 407 # iconv library (ecore_txt)
 408
 409 iconv_cflags=""
 410 iconv_libs=""
 411 have_iconv="no"
 412 AC_ARG_WITH([iconv-link],
 413    AC_HELP_STRING([--with-iconv-link=ICONV_LINK], [explicitly specify an iconv link option]),
 414    [
 415     iconv_libs=$withval
 416     have_iconv="yes"
 417    ])
 418
 419 AC_MSG_CHECKING(for explicit iconv link options)
 420 if test "x${iconv_libs}" = "x" ; then
 421    AC_MSG_RESULT([no explicit iconv link option])
 422 else
 423    AC_MSG_RESULT([$iconv_libs])
 424 fi
 425
 426 AM_ICONV
 427
 428 if test "x${have_iconv}" = "xno" && test "x${am_cv_func_iconv}" = "xyes" ; then
 429    iconv_cflags=${LIBICONV}
 430    iconv_libs=${LTLIBICONV}
 431    have_iconv="yes"
 432 fi
 433
 434 AC_SUBST(iconv_cflags)
 435 AC_SUBST(iconv_libs)
 436
 437
 438 # SDL library (ecore_sdl)
 439
 440 have_sdl="no"
 441 SDL_CONFIG="sdl-config"
 442 AC_ARG_WITH([sdl-config],
 443    [AC_HELP_STRING([--with-sdl-config=PATH], [use sdl-config specified])],
 444    [
 445     SDL_CONFIG=$withval
 446     AC_MSG_NOTICE([using ${SDL_CONFIG} for sdl-config])
 447    ])
 448
 449 AC_PATH_PROG([SDL_CONFIG], ["sdl-config"], [""], [$PATH])
 450
 451 if test -z "$SDL_CONFIG" ; then
 452    SDL_CFLAGS=`$SDL_CONFIG --cflags`
 453    SDL_LIBS=`$SDL_CONFIG --libs`
 454    AC_SUBST(SDL_CFLAGS)
 455    AC_SUBST(SDL_LIBS)
 456    have_sdl="no"
 457 else
 458    PKG_CHECK_MODULES([SDL], [sdl >= 1.2.0], [have_sdl="yes"], [have_sdl="no"])
 459 fi
 460
 461 if test "x${have_sdl}" = "xyes" ; then
 462    PKG_CHECK_EXISTS([sdl >= 1.3.0],
 463       [AC_DEFINE(BUILD_ECORE_EVAS_SDL_130, 1, [Support for SVN SDL])])
 464 fi
 465
 466
 467 # DirectFB library (ecore_directfb)
 468
 469 PKG_CHECK_MODULES([DIRECTFB],
 470    [directfb >= 0.9.16],
 471    [have_directfb="yes"],
 472    [have_directfb="no"])
 473
 474
 475 # Eet library (ecore_config)
 476
 477 PKG_CHECK_MODULES([EET],
 478    [eet >= 1.0.0],
 479    [have_eet="yes"],
 480    [have_eet="no"])
 481
 482
 483 # Xlib and XCB (ecore_x)
 484
 485 have_x="no"
 486 have_ecore_x="no"
 487 have_ecore_x_xlib="no"
 488 have_ecore_x_xcb="no"
 489
 490 x_dir="";
 491 x_includes="";
 492 x_cflags="";
 493 x_libs="";
 494
 495 ecore_x_libs_private=""
 496
 497 AC_ARG_ENABLE(ecore-x-xcb,
 498    [AC_HELP_STRING([--enable-ecore-x-xcb],
 499        [enable the ecore_x module with XCB backend. [[default=disabled]]])],
 500    [want_ecore_x_xcb=$enableval],
 501    [want_ecore_x_xcb="no"])
 502
 503 AC_MSG_CHECKING(whether ecore_x with XCB backend is to be built)
 504 AC_MSG_RESULT($want_ecore_x_xcb)
 505
 506 if test "x$want_ecore_x_xcb" = "xyes" ; then
 507   PKG_CHECK_MODULES(XCB, xcb xcb-icccm xcb-image xcb-keysyms pixman-1,
 508     [ have_ecore_x_xcb="yes"
 509       requirements_ecore_x="xcb xcb-icccm xcb-image xcb-keysyms pixman-1 ${requirements_ecore_x}" ],
 510     [ have_ecore_x_xcb="no" ])
 511
 512   if test "x$have_ecore_x_xcb" = "xyes" ; then
 513     PKG_CHECK_MODULES(XCB_COMPOSITE, xcb-composite,
 514       [ have_ecore_x_xcb_composite="yes"
 515         requirements_ecore_x="xcb-composite ${requirements_ecore_x}"
 516         AC_DEFINE(ECORE_XCB_COMPOSITE, 1, [Build support for XCB composite]) ],
 517       [ have_ecore_x_xcb_composite="no" ])
 518
 519     PKG_CHECK_MODULES(XCB_DAMAGE, xcb-damage,
 520       [ have_ecore_x_xcb_damage="yes"
 521         requirements_ecore_x="xcb-damage ${requirements_ecore_x}"
 522         AC_DEFINE(ECORE_XCB_DAMAGE, 1, [Build support for XCB damage]) ],
 523       [ have_ecore_x_xcb_damage="no" ])
 524
 525     PKG_CHECK_MODULES(XCB_DPMS, xcb-dpms,
 526       [ have_ecore_x_xcb_dpms="yes"
 527         requirements_ecore_x="xcb-dpms ${requirements_ecore_x}"
 528         AC_DEFINE(ECORE_XCB_DPMS, 1, [Build support for XCB dpms]) ],
 529       [ have_ecore_x_xcb_dpms="no" ])
 530
 531     PKG_CHECK_MODULES(XCB_RANDR, xcb-randr,
 532       [ have_ecore_x_xcb_randr="yes"
 533         requirements_ecore_x="xcb-randr ${requirements_ecore_x}"
 534         AC_DEFINE(ECORE_XCB_RANDR, 1, [Build support for XCB randr]) ],
 535       [ have_ecore_x_xcb_randr="no" ])
 536
 537     PKG_CHECK_MODULES(XCB_RENDER, xcb-render,
 538       [ have_ecore_x_xcb_render="yes"
 539         requirements_ecore_x="xcb-render ${requirements_ecore_x}"
 540         AC_DEFINE(ECORE_XCB_RENDER, 1, [Build support for XCB render]) ],
 541       [ have_ecore_x_xcb_render="no" ])
 542
 543     PKG_CHECK_MODULES(XCB_SCREENSAVER, xcb-screensaver,
 544       [ have_ecore_x_xcb_screensaver="yes"
 545         requirements_ecore_x="xcb-screensaver ${requirements_ecore_x}"
 546         AC_DEFINE(ECORE_XCB_SCREENSAVER, 1, [Build support for XCB screensaver]) ],
 547       [ have_ecore_x_xcb_screensaver="no" ])
 548
 549     PKG_CHECK_MODULES(XCB_SHAPE, xcb-shape,
 550       [ have_ecore_x_xcb_shape="yes"
 551         requirements_ecore_x="xcb-shape ${requirements_ecore_x}"
 552         AC_DEFINE(ECORE_XCB_SHAPE, 1, [Build support for XCB shape]) ],
 553       [ have_ecore_x_xcb_shape="no" ])
 554
 555     PKG_CHECK_MODULES(XCB_SYNC, xcb-sync,
 556       [ have_ecore_x_xcb_sync="yes"
 557         requirements_ecore_x="xcb-sync ${requirements_ecore_x}"
 558         AC_DEFINE(ECORE_XCB_SYNC, 1, [Build support for XCB sync]) ],
 559       [ have_ecore_x_xcb_sync="no" ])
 560
 561     PKG_CHECK_MODULES(XCB_XFIXES, xcb-xfixes,
 562       [ have_ecore_x_xcb_xfixes="yes"
 563         requirements_ecore_x="xcb-xfixes ${requirements_ecore_x}"
 564         AC_DEFINE(ECORE_XCB_FIXES, 1, [Build support for XCB xfixes]) ],
 565       [ have_ecore_x_xcb_xfixes="no" ])
 566
 567     PKG_CHECK_MODULES(XCB_XINERAMA, xcb-xinerama,
 568       [ have_ecore_x_xcb_xinerama="yes"
 569         requirements_ecore_x="xcb-xinerama ${requirements_ecore_x}"
 570         AC_DEFINE(ECORE_XCB_XINERAMA, 1, [Build support for XCB xinerama]) ],
 571       [ have_ecore_x_xcb_xinerama="no" ])
 572
 573     PKG_CHECK_MODULES(XCB_XPRINT, xcb-xprint,
 574       [ have_ecore_x_xcb_xprint="yes"
 575         requirements_ecore_x="xcb-xprint ${requirements_ecore_x}"
 576         AC_DEFINE(ECORE_XCB_XPRINT, 1, [Build support for XCB xprint]) ],
 577       [ have_ecore_x_xcb_xprint="no" ])
 578
 579     PKG_CHECK_MODULES(XCB_XTEST, xcb-xtest,
 580       [ have_ecore_x_xcb_xtest="yes"
 581         requirements_ecore_x="xcb-xtest ${requirements_ecore_x}"
 582         AC_DEFINE(ECORE_XCB_XTEST, 1, [Build support for XCB xtest]) ],
 583       [ have_ecore_x_xcb_xtest="no" ])
 584
 585     AC_DEFINE(HAVE_ECORE_X_XCB, 1, [Defined to 1 if XCB is enabled.])
 586
 587     x_cflags=$XCB_CFLAGS
 588     x_libs=$XCB_LIBS
 589     have_x="yes"
 590
 591     have_ecore_x_xcb_define="-DHAVE_ECORE_X_XCB"
 592     AC_SUBST(have_ecore_x_xcb_define)
 593   fi
 594 fi
 595
 596 if ! test "x$have_ecore_x_xcb" = "xyes" ; then
 597   AC_PATH_XTRA
 598   AC_CHECK_HEADER(X11/X.h,
 599     [
 600      if test "x$want_evas_simple_x11" = "xyes"; then
 601        x_libs="${x_libs} -lX11 -lXext"
 602      else
 603        x_dir=${x_dir:-/usr/X11R6}
 604        x_cflags=${x_cflags:--I${x_includes:-$x_dir/include}}
 605        x_libs="${x_libs:--L${x_libraries:-$x_dir/lib}} -lX11 -lXext"
 606      fi
 607      have_ecore_x_xlib="yes"
 608     ]
 609   )
 610
 611   if test "x$have_ecore_x_xlib" = "xyes"; then
 612     Xcursor_libs=""
 613     Xcursor_cflags=""
 614     use_Xcursor="no"
 615     PCFLAGS=$CFLAGS
 616     CFLAGS="$x_cflags $x_includes"
 617     AC_CHECK_HEADER(X11/Xcursor/Xcursor.h,
 618       [
 619         AC_CHECK_LIB(Xcursor, XcursorImageLoadCursor,
 620           [
 621             AC_DEFINE(ECORE_XCURSOR, 1, [Build support for Xcursor])
 622             Xcursor_cflags=""
 623             Xcursor_libs="-lXcursor"
 624             use_Xcursor="yes"
 625           ], [
 626             Xcursor_cflags=""
 627             Xcursor_libs=""
 628             use_Xcursor="no"
 629           ], [
 630             $x_libs -lXrender
 631           ]
 632         )
 633       ], [
 634         Xcursor_cflags=""
 635         Xcursor_libs=""
 636         use_Xcursor="no"
 637       ], [
 638         #include <X11/Xlib.h>
 639       ]
 640     )
 641     CFLAGS=$PCFLAGS
 642
 643     AC_SUBST(Xcursor_cflags)
 644     AC_SUBST(Xcursor_libs)
 645
 646     ECORE_CHECK_X_EXTENSION([Xkb], [XKB.h], [X11], [XkbSetDetectableAutoRepeat])
 647     ECORE_CHECK_X_EXTENSION([Xcomposite], [Xcomposite.h], [Xcomposite], [XCompositeQueryExtension])
 648     ECORE_CHECK_X_EXTENSION([Xdamage], [Xdamage.h], [Xdamage], [XDamageSubtract])
 649     ECORE_CHECK_X_EXTENSION([Xdpms], [dpms.h], [Xdpms], [DPMSQueryExtension])
 650     if test "x$use_xdpms" = "xno" ; then
 651       ECORE_CHECK_X_EXTENSION([Xdpms], [dpms.h], [Xext], [DPMSQueryExtension])
 652     fi
 653     ECORE_CHECK_X_EXTENSION([Xfixes], [Xfixes.h], [Xfixes], [XFixesExpandRegion])
 654     ECORE_CHECK_X_EXTENSION([Xinerama], [Xinerama.h], [Xinerama], [XineramaQueryScreens])
 655     ECORE_CHECK_X_EXTENSION([Xprint], [Print.h], [Xp], [XpQueryScreens])
 656     ECORE_CHECK_X_EXTENSION([Xrandr], [Xrandr.h], [Xrandr], [XRRGetScreenResourcesCurrent])
 657     ECORE_CHECK_X_EXTENSION([Xrender], [Xrender.h], [Xrender], [XRenderFindVisualFormat])
 658     ECORE_CHECK_X_EXTENSION([Xtest], [XTest.h], [Xtst], [XTestFakeKeyEvent])
 659     ECORE_CHECK_X_EXTENSION([Xss], [scrnsaver.h], [Xss], [XScreenSaverSelectInput])
 660     ECORE_CHECK_X_EXTENSION([Xi2], [XInput2.h], [Xi], [XIQueryDevice])
 661
 662     ecore_x_libs_private="${Xcursor_libs} ${XKB_LIBS} ${XCOMPOSITE_LIBS} ${XDAMAGE_LIBS} ${XDPMS_LIBS} ${XFIXES_LIBS} ${XINERAMA_LIBS} ${XPRINT_LIBS} ${XRANDR_LIBS} ${XRENDER_LIBS} ${XTEST_LIBS} ${XSS_LIBS} ${XI2_LIBS}"
 663
 664     AC_DEFINE(HAVE_ECORE_X_XLIB, 1, [Defined to 1 if Xlib is enabled.])
 665     have_x="yes"
 666
 667     have_ecore_x_xlib="yes"
 668   fi
 669 fi
 670
 671 AC_SUBST(x_cflags)
 672 AC_SUBST(x_includes)
 673 AC_SUBST(x_libs)
 674 AC_SUBST(ecore_x_libs_private)
 675
 676 AM_CONDITIONAL(BUILD_ECORE_X_XLIB, test $have_ecore_x_xlib = yes)
 677 AM_CONDITIONAL(BUILD_ECORE_X_XCB, test $have_ecore_x_xcb = yes)
 678
 679
 680 # Evas library (ecore_config, ecore_input_evas, ecore_imf_evas and ecore_evas)
 681
 682 PKG_CHECK_MODULES([EVAS], [evas >= 0.9.9],
 683    [have_evas="yes"],
 684    [have_evas="no"])
 685
 686
 687 ### Checks for header files
 688
 689 AC_HEADER_SYS_WAIT
 690
 691 case "$host_os" in
 692    mingw* | cegcc*)
 693       AC_DEFINE(HAVE_DLFCN_H, 1, [Define to 1 if you have the <dlfcn.h> header file.])
 694       AC_DEFINE(HAVE_SYS_MMAN_H, 1, [Define to 1 if you have the <sys/mman.h> header file.])
 695       AC_DEFINE(HAVE_SYS_TIME_H, 1, [Define to 1 if you have the <sys/time.h> header file.])
 696       ;;
 697    *)
 698       AC_CHECK_HEADERS([dlfcn.h features.h langinfo.h locale.h netdb.h netinet/in.h sys/time.h sys/mman.h signal.h sys/resource.h])
 699       ;;
 700 esac
 701
 702 # Framebuffer (ecore_fb)
 703 have_fb="no"
 704 AC_CHECK_HEADER([linux/fb.h],
 705    [AC_CHECK_HEADER([linux/input.h], [have_fb="yes"])])
 706
 707 # Quartz header files (ecore_quartz)
 708
 709 quartz_ldflags="";
 710 have_quartz="no"
 711
 712 if test "x${have_gnu_objc}" = "xyes" ; then
 713    AC_LANG_PUSH([Objective C])
 714    AC_CHECK_HEADER([Cocoa/Cocoa.h],
 715       [
 716        have_quartz="yes"
 717        quartz_ldflags="-framework Cocoa"
 718       ],
 719       [have_quartz="no"])
 720    AC_LANG_POP([Objective C])
 721 fi
 722
 723 AC_SUBST(quartz_ldflags)
 724
 725 # basic pthread support
 726
 727 EFL_CHECK_PTHREAD([have_pthread="yes"], [have_pthread="no"])
 728
 729 ### Checks for types
 730 AC_CHECK_SIZEOF(int, 4)
 731 AC_CHECK_SIZEOF(long, 4)
 732
 733
 734 ### Checks for structures
 735
 736
 737 ### Checks for compiler characteristics
 738 AM_PROG_CC_STDC
 739 AC_C_CONST
 740 AC_C_BIGENDIAN
 741 AC_HEADER_STDC
 742 AC_C___ATTRIBUTE__
 743
 744 WIN32_CPPFLAGS=""
 745 WIN32_CFLAGS=""
 746 case "$host_os" in
 747    mingw32ce*)
 748       WIN32_CPPFLAGS="-D_WIN32_WCE=0x0420"
 749       ;;
 750    cegcc*)
 751       WIN32_CPPFLAGS="-D_WIN32_WCE=0x0420"
 752       WIN32_CFLAGS="-mwin32"
 753       ;;
 754    mingw*)
 755       WIN32_CPPFLAGS="-D_WIN32_WINNT=0x0500"
 756       ;;
 757 esac
 758 AC_SUBST(WIN32_CPPFLAGS)
 759 AC_SUBST(WIN32_CFLAGS)
 760
 761
 762 ### Checks for linker characteristics
 763
 764 # use --enable-auto-import on Windows
 765
 766 lt_enable_auto_import=""
 767 case "$host_os" in
 768    mingw* | cegcc*)
 769       lt_enable_auto_import="-Wl,--enable-auto-import"
 770       ;;
 771 esac
 772 AC_SUBST(lt_enable_auto_import)
 773
 774 ### Checks for library functions
 775 AC_FUNC_ALLOCA
 776 AC_CHECK_FUNCS(gettimeofday strlcpy)
 777
 778 have_atfile_source=auto
 779 AC_ARG_ENABLE(atfile-source,
 780         AC_HELP_STRING([--disable-atfile-source],
 781                        [disable use of atfile source functions as openat and mkdirat @<:@default=detect@:>@]),
 782         [have_atfile_source=$enableval], [have_atfile_source=auto])
 783
 784 if test "x$have_atfile_source" != "xno"; then
 785         AC_CHECK_FUNCS(mkdirat,
 786                 [
 787                 have_atfile_source=yes
 788                 AC_DEFINE(HAVE_ATFILE_SOURCE, 1, [mkdirat exists])
 789                 ],
 790                 [
 791                 if test "x$have_atfile_source" = "xyes"; then
 792                         AC_MSG_ERROR([required atfile-source but no mkdirat()])
 793                 fi
 794                 have_atfile_source=no
 795                 ])
 796 fi
 797
 798 ### Ecore modules
 799
 800 ## Core modules
 801
 802 # ecore_txt
 803 ECORE_CHECK_MODULE([txt], [${want_ecore_txt}], [Txt], [$have_iconv])
 804
 805 # ecore_con
 806 ECORE_CHECK_MODULE([con], [${want_ecore_con}], [Con])
 807
 808 have_curl="no"
 809 have_gnutls="no"
 810 have_openssl="no"
 811 have_cares="no"
 812 if test "x${have_ecore_con}" = "xyes" ; then
 813
 814    ECORE_CHECK_CURL([${want_curl}],
 815       [
 816        have_curl="yes"
 817        requirements_ecore_con="libcurl ${requirements_ecore_con}"
 818       ],
 819       [have_curl="no"])
 820
 821    ECORE_CHECK_GNUTLS([${want_gnutls}],
 822       [have_gnutls="yes"],
 823       [have_gnutls="no"])
 824
 825    ECORE_CHECK_OPENSSL([${want_openssl}],
 826       [have_openssl="yes"],
 827       [have_openssl="no"])
 828
 829    if test "x${have_gnutls}" = "xyes" ; then
 830       requirements_ecore_con="gnutls ${requirements_ecore_con}"
 831       # no need to add it to req_ecore_ipc, since they
 832       # depends on ecore_con anyway.
 833    else
 834       if test "x${have_openssl}" = "xyes" ; then
 835          requirements_ecore_con="openssl ${requirements_ecore_con}"
 836          # no need to add it to req_ecore_ipc, since they
 837          # depends on ecore_con anyway.
 838       fi
 839    fi
 840
 841    ECORE_CHECK_CARES([${want_cares}],
 842       [
 843        have_cares="yes"
 844        requirements_ecore_con="libcares ${requirements_ecore_con}"
 845       ],
 846       [have_cares="no"])
 847
 848 fi
 849
 850 AM_CONDITIONAL([HAVE_CARES], [test "x${have_cares}" = "xyes"])
 851
 852 # ecore_ipc
 853 ECORE_CHECK_MODULE([ipc], [${want_ecore_ipc}], [Ipc], [${have_ecore_con}],
 854    [requirements_ecore_ipc="ecore-con ${requirements_ecore_ipc}"])
 855
 856 # ecore_file
 857 ECORE_CHECK_MODULE([file], [${want_ecore_file}], [File])
 858
 859 have_poll="no"
 860 have_inotify="no"
 861 have_notify_win32="no"
 862 if test "x${have_ecore_file}" = "xyes" ; then
 863    ECORE_CHECK_POLL([${want_poll}], [have_poll="yes"], [have_poll="no"])
 864    ECORE_CHECK_INOTIFY([${want_inotify}], [have_inotify="yes"], [have_inotify="no"])
 865    ECORE_CHECK_NOTIFY_WIN32([${want_notify_win32}], [have_notify_win32="yes"], [have_notify_win32="no"])
 866
 867    if test "x${have_ecore_con}" = "xyes" ; then
 868       requirements_ecore_file="ecore-con ${requirements_ecore_file}"
 869    fi
 870 fi
 871
 872 # ecore_config
 873 ecore_config_deps="no"
 874 if test "x${have_eet}" = "xyes" -a "x${have_evas}"  -a "x${have_ecore_ipc}" ; then
 875    ecore_config_deps="yes"
 876 fi
 877
 878 ECORE_CHECK_MODULE([config], [${want_ecore_config}], [Config], [${ecore_config_deps}],
 879    [requirements_ecore_config="ecore-ipc evas eet ${requirements_ecore_config}"])
 880
 881 # ecore_imf
 882
 883 ECORE_CHECK_MODULE([imf], [${want_ecore_imf}], [Imf])
 884
 885 # ecore_imf_evas
 886
 887 ecore_imf_evas_deps="no"
 888 if test "x${have_ecore_imf}" = "xyes" -a "x${have_evas}" = "xyes" ; then
 889    ecore_imf_evas_deps="yes"
 890 fi
 891
 892 ECORE_CHECK_MODULE([imf-evas], [${want_ecore_imf}], [Imf_Evas], [${ecore_imf_evas_deps}],
 893    [requirements_ecore_imf_evas="ecore-imf evas ${requirements_ecore_imf_evas}"])
 894
 895 # ecore_input{_evas}
 896 ECORE_CHECK_MODULE([input], [${want_ecore_input}], [Input])
 897 ECORE_CHECK_MODULE([input-evas], [${want_ecore_input}], [Input_Evas], [${have_evas}],
 898    [requirements_ecore_input_evas="ecore-input evas ${requirements_ecore_input}"])
 899
 900 ## Graphic systems
 901
 902 # ecore_x{cb}
 903
 904 ecore_x_deps="no"
 905 if test "x${have_x}" = "xyes" -a \
 906         "x${have_ecore_input}" = "xyes" -a \
 907         "x${have_ecore_txt}" = "xyes" ; then
 908    ecore_x_deps="yes"
 909 fi
 910
 911 ECORE_CHECK_MODULE([x], [${want_ecore_x}], [X], [${ecore_x_deps}],
 912   [
 913    ecore_x_libs="$ecore_x_libs $x_libs"
 914    requirements_ecore_x="ecore-input ecore-txt ${requirements_ecore_x}"
 915   ])
 916
 917 # ecore_win32
 918
 919 ECORE_CHECK_MODULE([win32], [${want_ecore_win32}], [Win32], [${have_ecore_input}],
 920    [
 921     ecore_win32_libs="-lole32 -lgdi32"
 922     requirements_ecore_win32="ecore-input ${requirements_ecore_win32}"
 923    ])
 924 AC_SUBST(ecore_win32_libs)
 925
 926 # ecore_quartz
 927
 928 ecore_quartz_deps="no"
 929 if test "x${have_ecore_input}" = "xyes" -a "x${have_quartz}" = "xyes" ; then
 930    ecore_quartz_deps="yes"
 931 fi
 932
 933 ECORE_CHECK_MODULE([quartz], [${want_ecore_quartz}], [Quartz], [${ecore_quartz_deps}],
 934    [requirements_ecore_quartz="ecore-input ${requirements_ecore_quartz}"])
 935
 936 # ecore_sdl
 937
 938 ecore_sdl_deps="no"
 939 if test "x${have_sdl}" = "xyes" -a "x${have_ecore_input}" = "xyes" ; then
 940    ecore_sdl_deps="yes"
 941 fi
 942
 943 ECORE_CHECK_MODULE([sdl], [${want_ecore_sdl}], [Sdl], [${ecore_sdl_deps}],
 944    [requirements_ecore_sdl="ecore-input ${requirements_ecore_sdl}"])
 945
 946 # ecore_fb
 947 ECORE_CHECK_MODULE([fb], [${want_ecore_fb}], [FB], [$have_fb])
 948
 949 if test "x${have_ecore_fb}" = "xyes" ; then
 950    ECORE_CHECK_TSLIB([${want_tslib}],
 951       [
 952        have_tslib="yes"
 953        requirements_ecore_fb="${_tslib_requirement} ${requirements_ecore_fb}"
 954       ],
 955       [have_tslib="no"])
 956 fi
 957
 958 # ecore_directfb
 959
 960 ECORE_CHECK_MODULE([directfb], [${want_ecore_directfb}], [DirectFB], [${have_directfb}],
 961    [requirements_ecore_directfb="directfb ${requirements_ecore_directfb}"])
 962
 963 # ecore_wince
 964
 965 ECORE_CHECK_MODULE([wince], [${want_ecore_wince}], [WinCE], [${have_ecore_input}],
 966    [requirements_ecore_win32="ecore-input ${requirements_ecore_win32}"])
 967
 968 ## Ecore Evas
 969
 970 # ecore_evas
 971
 972 ecore_evas_deps="no"
 973 if test "x${have_evas}" = "xyes" -a "x${have_ecore_input}" = "xyes" -a "x${have_ecore_input_evas}" = "xyes" ; then
 974    ecore_evas_deps="yes"
 975 fi
 976
 977 ECORE_CHECK_MODULE([evas], [${want_ecore_evas}], [Evas], [${ecore_evas_deps}],
 978   [requirements_ecore_evas="ecore-input ecore-input-evas evas ${requirements_ecore_evas}"])
 979
 980 # ecore_evas_buffer
 981
 982 ECORE_EVAS_CHECK_MODULE([software-buffer],
 983    [${want_ecore_evas_software_buffer}],
 984    [Software Buffer],
 985    [yes])
 986
 987 # ecore_evas_x11
 988
 989 # ecore_evas_software_x11
 990
 991 ECORE_EVAS_CHECK_MODULE([software-x11],
 992    [${want_ecore_evas_software_x11}],
 993    [Software X11],
 994    [${have_ecore_x}])
 995
 996 have_ecore_evas_software_xlib=no"
 997 have_ecore_evas_software_xcb=no"
 998 if test "x$have_ecore_evas_software_x11" = "xyes" ; then
 999    have_ecore_evas_software_xlib=`${PKG_CONFIG} --variable=Xlib evas-software-x11`
1000    if test "x${have_ecore_evas_software_xlib}" = "xyes" -a "x${have_ecore_x_xlib}" = "xyes" ; then
1001       AC_DEFINE(BUILD_ECORE_EVAS_SOFTWARE_XLIB, 1, [Evas Software Xlib Engine Support])
1002    fi
1003    have_ecore_evas_software_xcb=`${PKG_CONFIG} --variable=XCB evas-software-x11`
1004    if test "x$have_ecore_evas_software_xcb" = "xyes" -a "x${have_ecore_x_xcb}" = "xyes" ; then
1005       AC_DEFINE(BUILD_ECORE_EVAS_SOFTWARE_XCB, 1, [Evas Software XCB Engine Support])
1006    fi
1007 fi
1008
1009 # ecore_evas_xrender_x11
1010
1011 ECORE_EVAS_CHECK_MODULE([xrender-x11],
1012    [${want_ecore_evas_xrender_x11}],
1013    [XRender Xlib],
1014    [${have_ecore_x_xlib}])
1015
1016 # ecore_evas_opengl_x11
1017
1018 ECORE_EVAS_CHECK_MODULE([opengl-x11],
1019    [${want_ecore_evas_opengl_x11}],
1020    [OpenGL Xlib],
1021    [${have_ecore_x_xlib}])
1022
1023 # ecore_evas_software_x11 16 bits
1024
1025 ECORE_EVAS_CHECK_MODULE([software-16-x11],
1026    [${want_ecore_evas_software_16_x11}],
1027    [Software Xlib 16 bits],
1028    [${have_ecore_x_xlib}])
1029
1030 # ecore_evas_xrender_xcb
1031
1032 ECORE_EVAS_CHECK_MODULE([xrender-xcb],
1033    [${want_ecore_evas_xrender_xcb}],
1034    [XRender XCB],
1035    [${ecore_evas_xcb_deps}])
1036
1037 if test "x$have_ecore_evas_software_x11" = "xyes" -o \
1038         "x$have_ecore_evas_xrender_x11" = "xyes" -o \
1039         "x$have_ecore_evas_opengl_x11" = "xyes" -o \
1040         "x$have_ecore_evas_software_16_x11" = "xyes" -o \
1041         "x$have_ecore_evas_software_xcb" = "xyes" -o \
1042         "x$have_ecore_evas_xrender_xcb" = "xyes"; then
1043    AC_DEFINE(BUILD_ECORE_EVAS_X11, 1, [Support for X Window Engines in Ecore_Evas])
1044    requirements_ecore_evas="ecore-x ${requirements_ecore_evas}"
1045 fi
1046
1047 # ecore_evas_win32
1048
1049 ECORE_EVAS_CHECK_MODULE([software-gdi],
1050    [${want_ecore_evas_software_gdi}],
1051    [Software GDI],
1052    [${have_ecore_win32}])
1053
1054 ECORE_EVAS_CHECK_MODULE([software-ddraw],
1055    [${want_ecore_evas_software_ddraw}],
1056    [Software DirectDraw],
1057    [${have_ecore_win32}])
1058
1059 ECORE_EVAS_CHECK_MODULE([direct3d],
1060    [${want_ecore_evas_direct3d}],
1061    [Direct3d],
1062    [${have_ecore_win32}])
1063
1064 ECORE_EVAS_CHECK_MODULE([opengl-glew],
1065    [${want_ecore_evas_opengl_glew}],
1066    [Glew OpenGL],
1067    [${have_ecore_win32}])
1068
1069 ECORE_EVAS_CHECK_MODULE([software-16-ddraw],
1070    [${want_ecore_evas_software_16_ddraw}],
1071    [16 bpp Software DirectDraw],
1072    [${have_ecore_win32}])
1073
1074 if test "x${have_ecore_evas_software_gdi}" = "xyes" -o \
1075         "x${have_ecore_evas_software_ddraw}" = "xyes" -o \
1076         "x${have_ecore_evas_direct3d}" = "xyes" -o \
1077         "x${have_ecore_evas_opengl_glew}" = "xyes" -o \
1078         "x${have_ecore_evas_software_16_ddraw}" = "xyes" ; then
1079    AC_DEFINE(BUILD_ECORE_EVAS_WIN32, 1, [Support for Win32 Engine in Ecore_Evas])
1080    requirements_ecore_evas="ecore-win32 ${requirements_ecore_evas}"
1081 fi
1082
1083 # ecore_evas_quartz
1084
1085 ECORE_EVAS_CHECK_MODULE([quartz],
1086    [${want_ecore_evas_quartz}],
1087    [Quartz],
1088    [${have_ecore_quartz}],
1089    [requirements_ecore_evas="ecore-quartz ${requirements_ecore_evas}"])
1090
1091 # ecore_evas_software_sdl
1092
1093 ECORE_EVAS_CHECK_MODULE([software-sdl],
1094    [${want_ecore_evas_software_sdl}],
1095    [Software SDL],
1096    [${have_ecore_sdl}],
1097    [requirements_ecore_evas="ecore-sdl ${requirements_ecore_evas}"])
1098
1099 # ecore_evas_gl_sdl
1100
1101 ECORE_EVAS_CHECK_MODULE([opengl-sdl],
1102    [${want_ecore_evas_gl_sdl}],
1103    [OpenGL SDL],
1104    [${have_ecore_sdl}],
1105    [requirements_ecore_evas="ecore-sdl ${requirements_ecore_evas}"])
1106
1107 # ecore_evas_directfb
1108
1109 ECORE_EVAS_CHECK_MODULE([directfb],
1110    [${want_ecore_evas_directfb}],
1111    [DirectFB],
1112    [${have_ecore_directfb}],
1113    [requirements_ecore_evas="ecore-directfb ${requirements_ecore_evas}"])
1114
1115 # ecore_evas_fb
1116
1117 ECORE_EVAS_CHECK_MODULE([fb],
1118    [${want_ecore_evas_fb}],
1119    [Linux Framebuffer],
1120    [${have_ecore_fb}],
1121    [requirements_ecore_evas="ecore-fb ${requirements_ecore_evas}"])
1122
1123 # ecore_evas_wince
1124
1125 ECORE_EVAS_CHECK_MODULE([software-16-wince],
1126    [${want_ecore_evas_software_16_wince}],
1127    [16 bpp Software Windows CE],
1128    [${have_ecore_wince}],
1129    [requirements_ecore_evas="ecore-wince ${requirements_ecore_evas}"])
1130
1131
1132
1133 ### requirements
1134
1135 AC_SUBST(requirements_ecore)
1136 AC_SUBST(requirements_ecore_con)
1137 AC_SUBST(requirements_ecore_config)
1138 AC_SUBST(requirements_ecore_data)
1139 AC_SUBST(requirements_ecore_directfb)
1140 AC_SUBST(requirements_ecore_evas)
1141 AC_SUBST(requirements_ecore_fb)
1142 AC_SUBST(requirements_ecore_file)
1143 AC_SUBST(requirements_ecore_imf)
1144 AC_SUBST(requirements_ecore_imf_evas)
1145 AC_SUBST(requirements_ecore_input)
1146 AC_SUBST(requirements_ecore_input_evas)
1147 AC_SUBST(requirements_ecore_ipc)
1148 AC_SUBST(requirements_ecore_quartz)
1149 AC_SUBST(requirements_ecore_sdl)
1150 AC_SUBST(requirements_ecore_txt)
1151 AC_SUBST(requirements_ecore_x)
1152 AC_SUBST(requirements_ecore_win32)
1153 AC_SUBST(requirements_ecore_wince)
1154
1155 AC_OUTPUT([
1156 Makefile
1157 ecore-con.pc
1158 ecore-config.pc
1159 ecore-data.pc
1160 ecore-directfb.pc
1161 ecore-evas.pc
1162 ecore-fb.pc
1163 ecore-file.pc
1164 ecore-quartz.pc
1165 ecore-imf.pc
1166 ecore-imf-evas.pc
1167 ecore-ipc.pc
1168 ecore-x.pc
1169 ecore-input.pc
1170 ecore-input-evas.pc
1171 ecore-win32.pc
1172 ecore-sdl.pc
1173 ecore-txt.pc
1174 ecore-wince.pc
1175 ecore.pc
1176 doc/ecore.dox
1177 doc/Makefile
1178 src/Makefile
1179 src/bin/Makefile
1180 src/lib/Makefile
1181 src/lib/ecore/Makefile
1182 src/lib/ecore_con/Makefile
1183 src/lib/ecore_config/Makefile
1184 src/lib/ecore_data/Makefile
1185 src/lib/ecore_directfb/Makefile
1186 src/lib/ecore_evas/Makefile
1187 src/lib/ecore_fb/Makefile
1188 src/lib/ecore_file/Makefile
1189 src/lib/ecore_quartz/Makefile
1190 src/lib/ecore_sdl/Makefile
1191 src/lib/ecore_imf/Makefile
1192 src/lib/ecore_imf_evas/Makefile
1193 src/lib/ecore_input/Makefile
1194 src/lib/ecore_input_evas/Makefile
1195 src/lib/ecore_ipc/Makefile
1196 src/lib/ecore_txt/Makefile
1197 src/lib/ecore_win32/Makefile
1198 src/lib/ecore_wince/Makefile
1199 src/lib/ecore_x/Makefile
1200 src/lib/ecore_x/xlib/Makefile
1201 src/lib/ecore_x/xcb/Makefile
1202 README
1203 ecore.spec
1204 po/Makefile.in
1205 ])
1206
1207 echo
1208 echo "$PACKAGE $VERSION"
1209 echo
1210 echo "Optional Modules:"
1211 echo
1212 echo " Core:"
1213 echo
1214 echo "  Ecore........................: always"
1215 echo "    Thread support.............: $have_pthread"
1216 echo "    GLib support...............: $have_glib"
1217 echo "  Ecore_Txt....................: $have_ecore_txt"
1218 echo "  Ecore_Con....................: $have_ecore_con"
1219 if test "x$have_ecore_con" = "xyes" ; then
1220   echo $ECHO_N "    OpenSSL....................: $have_openssl $ECHO_C"
1221 if test "x$have_gnutls" = "xyes" ; then
1222   echo " (disabled)"
1223 else
1224   echo
1225 fi
1226   echo "    GnuTLS.....................: $have_gnutls"
1227   echo "    CURL.......................: $have_curl"
1228   echo "    Abstract Sockets...........: $want_abstract_sockets"
1229   echo "    c-ares.....................: $have_cares"
1230 fi
1231 echo "  Ecore_Ipc....................: $have_ecore_ipc"
1232 if test "x$have_ecore_ipc" = "xyes" ; then
1233   echo $ECHO_N "    OpenSSL....................: $have_openssl $ECHO_C"
1234 if test "x$have_gnutls" = "xyes" ; then
1235   echo " (disabled)"
1236 else
1237   echo
1238 fi
1239   echo "    GnuTLS.....................: $have_gnutls"
1240 fi
1241 echo "  Ecore_File...................: $have_ecore_file"
1242 if test "x$have_ecore_file" = "xyes" ; then
1243   echo "    Inotify....................: $have_inotify"
1244   echo "    Windows notification.......: $have_notify_win32"
1245   echo "    Poll.......................: $have_poll"
1246   echo "    CURL.......................: $have_curl"
1247 fi
1248 echo "  Ecore_Config.................: $have_ecore_config"
1249 echo "  Ecore_IMF....................: $have_ecore_imf"
1250 echo "  Ecore_IMF_Evas...............: $have_ecore_imf_evas"
1251 echo "  Ecore_Input..................: $have_ecore_input"
1252 echo "  Ecore_Input_Evas.............: $have_ecore_input_evas"
1253
1254 echo
1255 echo " Graphic systems:"
1256 echo
1257
1258 if test "x$have_ecore_x" = "xyes" ; then
1259   if test "x$have_ecore_x_xcb" = "xyes" ; then
1260     echo "  Ecore_X (XCB backend)........: $have_ecore_x_xcb"
1261     echo "    Xprint.....................: $have_ecore_x_xcb_xprint"
1262     echo "    Xinerama...................: $have_ecore_x_xcb_xinerama"
1263     echo "    Xrandr.....................: $have_ecore_x_xcb_randr"
1264     echo "    Xscreensaver...............: $have_ecore_x_xcb_screensaver"
1265     echo "    Xshape.....................: $have_ecore_x_xcb_shape"
1266     echo "    Xsync......................: $have_ecore_x_xcb_sync"
1267     echo "    Xrender....................: $have_ecore_x_xcb_render"
1268     echo "    Xcomposite.................: $have_ecore_x_xcb_composite"
1269     echo "    Xfixes.....................: $have_ecore_x_xcb_xfixes"
1270     echo "    Xdamage....................: $have_ecore_x_xcb_damage"
1271     echo "    Xdpms......................: $have_ecore_x_xcb_dpms"
1272     echo "    Xtest......................: $have_ecore_x_xcb_xtest"
1273   else
1274     echo "  Ecore_X (Xlib backend).......: $have_ecore_x"
1275     echo "    Xcursor....................: $use_Xcursor"
1276     echo "    Xkb........................: $use_xkb"
1277     echo "    Xprint.....................: $use_xprint"
1278     echo "    Xinerama...................: $use_xinerama"
1279     echo "    Xrandr.....................: $use_xrandr"
1280     echo "    Xscreensaver...............: $use_xss"
1281     echo "    Xrender....................: $use_xrender"
1282     echo "    Xcomposite.................: $use_xcomposite"
1283     echo "    Xfixes.....................: $use_xfixes"
1284     echo "    Xdamage....................: $use_xdamage"
1285     echo "    Xdpms......................: $use_xdpms"
1286     echo "    Xtest......................: $use_xtest"
1287     echo "    XIM........................: $want_xim"
1288     echo "    Xi2........................: $use_xi2"
1289   fi
1290 else
1291   echo "  Ecore_X......................: $have_ecore_x"
1292 fi
1293 echo "  Ecore_Win32..................: $have_ecore_win32"
1294 echo "  Ecore_Quartz.................: $have_ecore_quartz"
1295 echo "  Ecore_SDL....................: $have_ecore_sdl"
1296 echo "  Ecore_FB.....................: $have_ecore_fb"
1297 if test "x${have_ecore_fb}" = "xyes" ; then
1298   echo "    Touchscreen................: $have_tslib"
1299 fi
1300 echo "  Ecore_DirectFB...............: $have_ecore_directfb"
1301 echo "  Ecore_WinCE..................: $have_ecore_wince"
1302
1303 echo
1304 echo " Ecore Evas:"
1305 echo
1306
1307 echo "  Ecore_Evas...................: $have_ecore_evas"
1308 if test "x${have_ecore_evas}" = "xyes" ; then
1309   echo "    Software Memory Buffer.....: $have_ecore_evas_software_buffer"
1310   if test "x${have_ecore_evas_software_x11}" = "xyes" ; then
1311     echo "    Software X11...............: $have_ecore_evas_software_x11 (Xlib=${have_ecore_evas_software_xlib}) (XCB=${have_ecore_evas_software_xcb})"
1312   else
1313     echo "    Software X11...............: $have_ecore_evas_software_x11"
1314   fi
1315   echo "    XRender X11................: $have_ecore_evas_xrender_x11"
1316   echo "    OpenGL X11.................: $have_ecore_evas_opengl_x11"
1317   echo "    XRender XCB................: $have_ecore_evas_xrender_xcb"
1318   echo "    Software GDI...............: $have_ecore_evas_software_gdi"
1319   echo "    Software DirectDraw........: $have_ecore_evas_software_ddraw"
1320   echo "    Direct3D...................: $have_ecore_evas_direct3d"
1321   echo "    OpenGL Glew................: $have_ecore_evas_opengl_glew"
1322   echo "    Quartz.....................: $have_ecore_evas_quartz"
1323   echo "    Software SDL...............: $have_ecore_evas_software_sdl"
1324   echo "    OpenGL SDL.................: $have_ecore_evas_opengl_sdl"
1325   echo "    DirectFB...................: $have_ecore_evas_directfb"
1326   echo "    Software Framebuffer.......: $have_ecore_evas_fb"
1327   echo "    Software 16bit X11.........: $have_ecore_evas_software_16_x11"
1328   echo "    Software 16bit DirectDraw..: $have_ecore_evas_software_16_ddraw"
1329   echo "    Software 16bit WinCE.......: $have_ecore_evas_software_16_wince"
1330 fi
1331 echo
1332 echo " Documentation.................: ${build_doc}"
1333 echo
1334 echo " Compilation...................: make (or gmake)"
1335 if test "x${build_doc}" = "xyes" ; then
1336    echo " Build of the documentation....: make doc"
1337 fi
1338 echo
1339 echo " Installation..................: make install"
1340 echo
1341 echo "    prefix.....................: $prefix"
1342 echo
1343
1344 echo
1345 echo "Compilation............: make (or gmake)"
1346 echo "  CPPFLAGS.............: $CPPFLAGS"
1347 echo "  CFLAGS...............: $CFLAGS"
1348 echo "  CXXFLAGS.............: $CXXFLAGS"
1349 echo "  LDFLAGS..............: $LDFLAGS"
1350 echo
1351 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
1352 echo "  prefix...............: $prefix"
1353 echo