configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # This file is part of libatasmart.
   5 #
   6 # Copyright 2008 Lennart Poettering
   7 #
   8 # libatasmart is free software; you can redistribute it and/or modify
   9 # it under the terms of the GNU Lesser General Public License as
  10 # published by the Free Software Foundation, either version 2.1 of the
  11 # License, or (at your option) any later version.
  12 #
  13 # libatasmart is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  16 # Lesser General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with libatasmart. If not, If not, see
  20 # <http://www.gnu.org/licenses/>.
  21
  22 AC_PREREQ(2.63)
  23
  24 AC_INIT([libatasmart], 0.17, [mzyvongnfzneg (at) 0pointer (dot) net])
  25 AC_CONFIG_SRCDIR([atasmart.c])
  26 AC_CONFIG_HEADERS([config.h])
  27 AC_CONFIG_MACRO_DIR(m4)
  28
  29 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax])
  30
  31 AC_SUBST(PACKAGE_URL, [http://git.0pointer.de/?p=libatasmart.git])
  32
  33 AC_SUBST(LIBATASMART_VERSION_INFO, [4:3:0])
  34
  35 AC_CANONICAL_HOST
  36
  37 AM_SILENT_RULES([yes])
  38
  39 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  40    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  41    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  42 fi
  43
  44 #### Checks for programs. ####
  45
  46 # CC
  47
  48 AC_PROG_CC
  49 AM_PROG_CC_C_O
  50 AC_PROG_GCC_TRADITIONAL
  51 AC_USE_SYSTEM_EXTENSIONS
  52
  53 # C++
  54
  55 AC_PROG_CXX
  56
  57 # GCC flags
  58
  59 test_gcc_flag() {
  60     AC_LANG_CONFTEST([int main(int argc, char*argv[]) {}])
  61     $CC -c conftest.c $CFLAGS "$1" -o conftest.o > /dev/null 2> /dev/null
  62     ret=$?
  63     rm -f conftest.o
  64     return $ret
  65 }
  66
  67 # If using GCC specify some additional parameters
  68 if test "x$GCC" = "xyes" ; then
  69
  70     # We use gnu99 instead of c99 because many have interpreted the standard
  71     # in a way that int64_t isn't defined on non-64 bit platforms.
  72     DESIRED_FLAGS="-std=gnu99 -Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter -ffast-math"
  73
  74     for flag in $DESIRED_FLAGS ; do
  75         AC_MSG_CHECKING([whether $CC accepts $flag])
  76         if test_gcc_flag $flag ; then
  77            CFLAGS="$CFLAGS $flag"
  78            CXXFLAGS="$CXXFLAGS $flag"
  79            AC_MSG_RESULT([yes])
  80         else
  81            AC_MSG_RESULT([no])
  82         fi
  83     done
  84 fi
  85
  86 #### libtool stuff ####
  87
  88 AC_PROG_LIBTOOL
  89
  90 #### Checks for header files. ####
  91
  92 # ISO
  93 AC_HEADER_STDC
  94
  95 # XPG4-UNIX
  96 AC_CHECK_HEADERS([sys/poll.h])
  97
  98 # Other
  99 AC_CHECK_HEADERS([sys/ioctl.h])
 100 AC_CHECK_HEADERS([byteswap.h])
 101
 102 #### Typdefs, structures, etc. ####
 103
 104 AC_C_CONST
 105 AC_C_BIGENDIAN
 106 AC_TYPE_PID_T
 107 AC_TYPE_SIZE_T
 108 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 109     [Define ssize_t if it is not done by the standard libs.])])
 110 AC_TYPE_OFF_T
 111 AC_TYPE_SIGNAL
 112 AC_TYPE_UID_T
 113
 114 #### Large File-Support (LFS) ####
 115
 116 AC_SYS_LARGEFILE
 117
 118 PKG_CHECK_MODULES([LIBUDEV], [libudev])
 119 AC_DEFINE([LIBUDEV_I_KNOW_THE_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 120
 121 ###################################
 122 #            Output               #
 123 ###################################
 124
 125 AC_CONFIG_FILES([
 126 Makefile
 127 libatasmart.pc
 128 ])
 129 AC_OUTPUT
 130
 131 echo "
 132  ---{ $PACKAGE_NAME $VERSION }---
 133
 134     prefix:                 ${prefix}
 135     sysconfdir:             ${sysconfdir}
 136     localstatedir:          ${localstatedir}
 137     Compiler:               ${CC}
 138     CFLAGS:                 ${CFLAGS}
 139 "