configure.ac

   1 AC_PREREQ(2.69)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer libav, 1.9.2.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gst-libav)
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([ext/libav/gstav.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output by default
  34 AM_SILENT_RULES([yes])
  35
  36 dnl our libraries and install dirs use major.minor as a version
  37 GST_API_VERSION=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  38 dnl we override it here if we need to for the release candidate of new series
  39 GST_API_VERSION=1.0
  40 AC_SUBST(GST_API_VERSION)
  41
  42 AG_GST_LIBTOOL_PREPARE
  43 AS_LIBTOOL(GST, 902, 0, 902)
  44
  45 dnl *** required versions of GStreamer stuff ***
  46 GST_REQ=1.9.2
  47 GST_PBREQ=1.9.2
  48
  49 ORC_REQ=0.4.16
  50 ORC_CHECK([$ORC_REQ])
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl *** check for arguments to configure ***
  61
  62 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  63 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  64
  65 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  66 AG_GST_ARG_WITH_PACKAGE_NAME
  67 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  68 AG_GST_ARG_VALGRIND
  69 AG_GST_ARG_GCOV
  70
  71 dnl *** checks for platform ***
  72
  73 dnl * hardware/architecture *
  74
  75 dnl common/m4/gst-arch.m4
  76 dnl check CPU type
  77 AG_GST_ARCH
  78
  79 dnl *** checks for programs ***
  80
  81 dnl find a compiler
  82 AC_PROG_CC
  83 AC_PROG_CC_STDC
  84
  85 dnl check if the compiler supports '-c' and '-o' options
  86 AM_PROG_CC_C_O
  87
  88 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
  89 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
  90
  91 dnl check for documentation tools
  92 GTK_DOC_CHECK([1.12])
  93 AG_GST_PLUGIN_DOCS([1.12])
  94
  95 dnl *** checks for libraries ***
  96
  97 dnl check for libm, for sin()
  98 LT_LIB_M
  99 AC_SUBST(LIBM)
 100
 101 dnl check for pthreads
 102 AX_PTHREAD
 103
 104 dnl *** checks for header files ***
 105
 106 dnl check if we have ANSI C header files
 107 AC_HEADER_STDC
 108
 109 dnl *** checks for types/defines ***
 110
 111 dnl *** checks for structures ***
 112
 113 dnl *** checks for compiler characteristics ***
 114
 115 dnl *** checks for library functions ***
 116
 117 dnl *** checks for dependancy libraries ***
 118
 119 dnl GLib is required
 120 GLIB_REQ=2.40.0
 121 AC_SUBST([GLIB_REQ])
 122 AG_GST_GLIB_CHECK([$GLIB_REQ])
 123
 124 dnl checks for gstreamer
 125 dnl uninstalled is selected preferentially -- see pkg-config(1)
 126 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ])
 127 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ])
 128 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GST_PBREQ])
 129 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 130 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 131
 132 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 133 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 134
 135 dnl Check for -Bsymbolic-functions linker flag used to avoid
 136 dnl intra-library PLT jumps, if available.
 137 AC_ARG_ENABLE(Bsymbolic,
 138               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 139               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 140                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 141                LDFLAGS=-Wl,-Bsymbolic-functions
 142                LIBS=
 143                AC_TRY_LINK([], [return 0],
 144                            AC_MSG_RESULT(yes)
 145                            enable_Bsymbolic=yes,
 146                            AC_MSG_RESULT(no)
 147                            enable_Bsymbolic=no)
 148                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 149
 150 dnl *** set variables based on configure arguments ***
 151
 152 dnl set location of plugin directory
 153 AG_GST_SET_PLUGINDIR
 154
 155 dnl build static plugins or not
 156 AC_MSG_CHECKING([whether to build static plugins or not])
 157 AC_ARG_ENABLE(
 158   static-plugins,
 159   AC_HELP_STRING(
 160     [--enable-static-plugins],
 161     [build static plugins @<:@default=no@:>@]),
 162   [AS_CASE(
 163     [$enableval], [no], [], [yes], [],
 164     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 165   [enable_static_plugins=no])
 166 AC_MSG_RESULT([$enable_static_plugins])
 167 if test "x$enable_static_plugins" = xyes; then
 168   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 169     [Define if static plugins should be built])
 170   GST_PLUGIN_LIBTOOLFLAGS=""
 171 else
 172   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 173 fi
 174 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 175 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 176
 177 dnl define an ERROR_CFLAGS Makefile variable
 178 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 179     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 180     -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition
 181     -Winit-self -Wmissing-include-dirs -Waddress
 182     -Waggregate-return -Wno-multichar -Wnested-externs ])
 183
 184 dnl define correct level for debugging messages
 185 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 186
 187 dnl *** finalize CFLAGS, LDFLAGS, LIBS ***
 188
 189 dnl Overview:
 190 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 191 dnl GST_*:              flags shared by built objects to link against GStreamer
 192 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 193 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 194 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 195 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 196
 197 dnl GST_OPTION_CFLAGS
 198 if test "x$USE_DEBUG" = xyes; then
 199    PROFILE_CFLAGS="-g"
 200 fi
 201 AC_SUBST(PROFILE_CFLAGS)
 202
 203 if test "x$GST_GIT" = "xyes"; then
 204   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 205 else
 206   DEPRECATED_CFLAGS=""
 207 fi
 208 AC_SUBST(DEPRECATED_CFLAGS)
 209
 210 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 211 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 212
 213 AC_SUBST(GST_OPTION_CFLAGS)
 214
 215 dnl FIXME: do we want to rename to GST_ALL_* ?
 216 dnl prefer internal headers to already installed ones
 217 dnl also add builddir include for enumtypes and marshal
 218 dnl add GST_OPTION_CFLAGS, but overridable
 219 GST_CFLAGS="$GST_CFLAGS"
 220 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 221 AC_SUBST(GST_CFLAGS)
 222 AC_SUBST(GST_LIBS)
 223
 224 GST_ALL_LDFLAGS="-no-undefined"
 225 if test "x${enable_Bsymbolic}" = "xyes"; then
 226   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 227 fi
 228 AC_SUBST(GST_ALL_LDFLAGS)
 229
 230 dnl this really should only contain flags, not libs - they get added before
 231 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 232 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 233 AC_SUBST(GST_PLUGIN_LDFLAGS)
 234
 235 dnl Add MacOSX specific flags
 236 AC_CANONICAL_HOST
 237 case $host_os in
 238      darwin*)
 239         DARWIN_LDFLAGS="-Wl,-read_only_relocs,suppress"
 240         ;;
 241      *)
 242         DARWIN_LDFLAGS=""
 243         ;;
 244 esac
 245 AC_SUBST(DARWIN_LDFLAGS)
 246
 247 dnl *** Check for bz2
 248 save_LIBS=$LIBS
 249 LIBS="$LIBS -lbz2"
 250 AC_MSG_CHECKING([for BZ2_bzlibVersion in -lbz2])
 251 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <bzlib.h>]], [[const char *version = BZ2_bzlibVersion ();]])],[HAVE_BZ2=yes],[HAVE_BZ2=no])
 252 AC_MSG_RESULT($HAVE_BZ2)
 253 LIBS=$save_LIBS
 254 AM_CONDITIONAL(HAVE_BZ2, test "x$HAVE_BZ2" = "xyes")
 255 if test "x$HAVE_BZ2" = "xno"; then
 256   AC_WARN([libbz2 not found, matroska demuxer will not be able to read bz2 tracks])
 257 fi
 258
 259 dnl *** Check for lzma
 260 save_LIBS=$LIBS
 261 LIBS="$LIBS -llzma"
 262 AC_MSG_CHECKING([for lzma_version_string in -llzma])
 263 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <lzma.h>]], [[const char *version = lzma_version_string ();]])],[HAVE_LZMA=yes],[HAVE_LZMA=no])
 264 AC_MSG_RESULT($HAVE_LZMA)
 265 LIBS=$save_LIBS
 266 AM_CONDITIONAL(HAVE_LZMA, test "x$HAVE_LZMA" = "xyes")
 267 if test "x$HAVE_LZMA" = "xno"; then
 268     AC_WARN([lzma not found, tiff reader will not be able to read lzma files])
 269 fi
 270
 271 AC_ARG_ENABLE(gpl,
 272               [AC_HELP_STRING([--enable-gpl], [build a GPL licensed gst-libav])])
 273 AM_CONDITIONAL(GST_LIBAV_ENABLE_GPL, test "x$enable_gpl" = "xyes")
 274 if test "x$enable_gpl" = "xyes"; then
 275   AC_DEFINE([GST_LIBAV_ENABLE_GPL], [], [Defined if building a GPL-licensed version of gst-libav])
 276 fi
 277
 278 dnl *** configure external libs ***
 279
 280 HAVE_LIBAV_UNINSTALLED=1
 281
 282 AC_ARG_WITH(system-libav,
 283             [AC_HELP_STRING([--with-system-libav], [use system Libav libraries])])
 284
 285 if test "x$with_system_libav" = "xyes"; then
 286   PKG_CHECK_MODULES(LIBAV, libavfilter libavformat libavcodec libavutil)
 287   PKG_CHECK_MODULES(SWSCALE, libswscale libavutil)
 288   saved_CPPFLAGS="$CPPFLAGS"
 289   CPPFLAGS="$CPPFLAGS $LIBAV_CFLAGS"
 290   AC_CHECK_HEADERS([avi.h])
 291   AC_DEFINE([LIBAV_SOURCE], ["system install"], [Describes where the Libav libraries come from.])
 292   HAVE_LIBAV_UNINSTALLED=0
 293   AC_MSG_NOTICE([Using system-installed libav code])
 294   AC_MSG_CHECKING([whether libav is provided by FFmpeg])
 295   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 296     #include <libavcodec/avcodec.h>
 297     ]],[[
 298         #if LIBAVCODEC_VERSION_MICRO >= 100
 299         /* FFmpeg uses 100+ as its micro version */
 300         #else
 301         #error libav provider should be FFmpeg
 302         #endif
 303     ]])], [is_ffmpeg=yes], [is_ffmpeg=no])
 304   AC_MSG_RESULT([$is_ffmpeg])
 305   CPPFLAGS="$saved_CPPFLAGS"
 306   if test "$is_ffmpeg" = no; then
 307     AC_MSG_ERROR([Uncompatible libavcodec found])
 308   fi
 309 else
 310   AC_MSG_NOTICE([Using local Libav snapshot])
 311
 312   dnl libgstlibav.la: include dirs
 313   LIBAV_CFLAGS="-I \$(top_srcdir)/gst-libs/ext/libav \
 314                 -I \$(top_builddir)/gst-libs/ext/libav \
 315                  -Wno-deprecated-declarations"
 316
 317   LIBAV_DEPS="\$(top_builddir)/gst-libs/ext/libav/libavformat/libavformat.a \
 318               \$(top_builddir)/gst-libs/ext/libav/libavcodec/libavcodec.a \
 319               \$(top_builddir)/gst-libs/ext/libav/libavfilter/libavfilter.a \
 320               \$(top_builddir)/gst-libs/ext/libav/libswresample/libswresample.a \
 321               \$(top_builddir)/gst-libs/ext/libav/libavutil/libavutil.a"
 322   if test "x$enable_static_plugins" = xyes; then
 323       dnl with static linking we can't use the .a archive directly as they would
 324       dnl be included in the final libgstlibav.a as a file and won't be usable.
 325       dnl libav*.a must be copied to the final destination too
 326       LIBAV_LIBS="-lavformat -lavcodec -lswresample -lavutil -lavfilter"
 327   else
 328       dnl libgstlibav.la: libs to statically link to
 329       LIBAV_LIBS="$LIBAV_DEPS"
 330   fi
 331
 332   dnl
 333   SWSCALE_CFLAGS="-I \$(top_srcdir)/gst-libs/ext/libav \
 334                   -I \$(top_builddir)/gst-libs/ext/libav \
 335                   -Wno-deprecated-declarations"
 336
 337   SWSCALE_DEPS="\$(top_builddir)/gst-libs/ext/libav/libswscale/libswscale.a \
 338                 \$(top_builddir)/gst-libs/ext/libav/libavutil/libavutil.a"
 339   if test "x$enable_static_plugins" = xyes; then
 340       dnl with static linking we can't use the .a archive directly as they would
 341       dnl be included in the final libgstswscale.a as a file and won't be usable.
 342       dnl libav*.a must be copied to the final destination too
 343       SWSCALE_LIBS="-lswscale -lavutil"
 344   else
 345       dnl libgstswscale.la: libs to statically link to
 346       SWSCALE_LIBS="$SWSCALE_DEPS"
 347   fi
 348
 349   LIBAV_SUBDIRS=gst-libs
 350   AC_DEFINE(HAVE_AVI_H)
 351   AC_DEFINE([LIBAV_SOURCE], ["local snapshot"], [Describes where the Libav libraries come from.])
 352
 353   AC_ARG_WITH(libav-extra-configure,
 354       AC_HELP_STRING([--with-libav-extra-configure="xxx"],
 355       [extra configure options for internal libav ./configure script]),,
 356       with_libav=no)
 357
 358   # basic arguments
 359   emblibav_configure_args="--prefix=$prefix"
 360
 361   # Enable pic and static so that we get .a files, but with PIC code.
 362   emblibav_configure_args="$emblibav_configure_args \
 363         --enable-static --enable-pic \
 364         --disable-avdevice --disable-postproc \
 365         --disable-programs --disable-ffserver --disable-ffplay --disable-ffprobe --disable-ffmpeg \
 366         --disable-encoder=flac --disable-protocols --disable-devices \
 367         --disable-network --disable-hwaccels --disable-dxva2 --disable-vdpau \
 368         --disable-filters --enable-filter=yadif --disable-doc --disable-vda --disable-d3d11va --disable-dxva2 \
 369         --disable-audiotoolbox --disable-videotoolbox --disable-vaapi --disable-crystalhd \
 370         --disable-mediacodec --disable-nvenc --disable-mmal --disable-omx \
 371         --disable-omx-rpi --disable-cuda --disable-cuvid --disable-libmfx \
 372         --disable-libnpp --disable-iconv --disable-jni --enable-optimizations"
 373
 374   if test "x$enable_gpl" == "xyes"; then
 375     emblibav_configure_args="$emblibav_configure_args --enable-gpl"
 376   fi
 377
 378   # if we are cross-compiling, tell libav so
 379   case $host in
 380       *android*)
 381         target_os=linux
 382       ;;
 383       *darwin*)
 384         target_os=darwin
 385       ;;
 386       *)
 387         target_os=`echo $host_os | sed 's/-gnu//'`
 388       ;;
 389   esac
 390
 391   if test "x$cross_compiling" = xyes; then
 392     emblibav_configure_args="$emblibav_configure_args --enable-cross-compile \
 393         --target-os=$target_os --arch=$host_cpu --cross-prefix=$host_alias-"
 394   fi
 395
 396   case $host_os in
 397     mingw32*)
 398       emblibav_configure_args="$emblibav_configure_args --enable-memalign-hack"
 399       WIN32_LIBS="-lws2_32"
 400       ;;
 401     *)
 402       WIN32_LIBS=
 403       ;;
 404   esac
 405
 406   if test x"$AR" != x; then
 407     emblibav_configure_args="$emblibav_configure_args --ar=\\\"\\\$AR\\\""
 408   fi
 409
 410   if test x"$AS" != x; then
 411     emblibav_configure_args="$emblibav_configure_args --as=\\\"\\\$CC\\\""
 412   fi
 413
 414   if test x"$CC" != x; then
 415     emblibav_configure_args="$emblibav_configure_args --cc=\\\"\\\$CC\\\""
 416   fi
 417
 418   if test x"$LD" != x; then
 419     emblibav_configure_args="$emblibav_configure_args --ld=\\\"\\\$CC\\\""
 420   fi
 421
 422   if test x"$NM" != x; then
 423     emblibav_configure_args="$emblibav_configure_args --nm=\\\"\\\$NM\\\""
 424   fi
 425
 426   dnl checks for extra enable/disable flags
 427   LIBAV_OPTS=`cd $srcdir/gst-libs/ext/libav && ./configure --help`
 428   # Let's check if we can disable the building of the libav binary
 429   can_disable=`echo "$LIBAV_OPTS" | grep 'disable-ffmpeg'`
 430   if test "$can_disable" != ""; then
 431     emblibav_configure_args="$emblibav_configure_args --disable-ffmpeg"
 432   fi
 433   dnl check if libswscale needs enabling explicitly
 434   can_enable=`echo "$LIBAV_OPTS" | grep 'enable-swscale'`
 435   if test "$can_enable" != ""; then
 436     emblibav_configure_args="$emblibav_configure_args --enable-swscale"
 437   fi
 438
 439   # append extra configure options to emblibav_configure_args if needed
 440   if test "x$with_libav_extra_configure" != "xno"; then
 441     emblibav_configure_args="$emblibav_configure_args $with_libav_extra_configure"
 442   fi
 443
 444   AC_SUBST(LIBAV_CO_DIR)
 445   AC_SUBST(LIBAV_SVN)
 446   AC_SUBST(LIBAV_REVISION)
 447   AC_SUBST(LIBAV_EXTERNALS_REVISION)
 448   AC_CONFIG_COMMANDS([configure-embedded-libav],
 449     [echo "Configuring included Libav instance with args $emblibav_configure_args"
 450      origdir=`pwd`
 451      dnl Don't put path on the configure call when not needed, as FFmpeg's configure relies on it
 452      dnl to detect out-of-tree builds
 453      if test -z "$srcdir" -o "$srcdir" = .; then
 454        confcmd=./configure
 455      else
 456        confcmd="$ac_abs_top_srcdir"/gst-libs/ext/libav/configure
 457      fi
 458
 459      AS_MKDIR_P(["$ac_top_build_prefix"gst-libs/ext/libav])
 460      cd "$ac_top_build_prefix"gst-libs/ext/libav &&
 461          eval "$confcmd $emblibav_configure_args" ||
 462          AC_MSG_ERROR([Failed to configure embedded Libav tree])
 463      cd "$origdir"
 464     ],
 465     [emblibav_configure_args="$emblibav_configure_args"])
 466   AC_MSG_NOTICE([Using included Libav code])
 467 fi
 468
 469 AC_SUBST(LIBAV_CFLAGS)
 470 AC_SUBST(LIBAV_DEPS)
 471 AC_SUBST(LIBAV_LIBS)
 472 AC_SUBST(LIBAV_SUBDIRS)
 473 AC_SUBST(SWSCALE_CFLAGS)
 474 AC_SUBST(SWSCALE_DEPS)
 475 AC_SUBST(SWSCALE_LIBS)
 476 AC_SUBST(WIN32_LIBS)
 477
 478 if test x$HAVE_LIBAV_UNINSTALLED = x1; then
 479   AC_DEFINE(HAVE_LIBAV_UNINSTALLED, [], [Defined if building against uninstalled Libav source])
 480 fi
 481 AM_CONDITIONAL(HAVE_LIBAV_UNINSTALLED, test x$HAVE_LIBAV_UNINSTALLED = x1)
 482
 483 AC_CONFIG_FILES(
 484 Makefile
 485 common/Makefile
 486 common/m4/Makefile
 487 gst-libav.spec
 488 ext/Makefile
 489 ext/libav/Makefile
 490 ext/libswscale/Makefile
 491 gst-libs/Makefile
 492 gst-libs/ext/Makefile
 493 docs/Makefile
 494 docs/plugins/Makefile
 495 docs/version.entities
 496 tests/Makefile
 497 tests/check/Makefile
 498 tests/files/Makefile
 499 pkgconfig/Makefile
 500 pkgconfig/gstreamer-plugins-libav-uninstalled.pc
 501 )
 502 AC_OUTPUT
 503
 504 ORC_OUTPUT