configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.21.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl CURRENT, REVISION, AGE
  42 dnl - library source changed -> increment REVISION
  43 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  44 dnl - interfaces added -> increment AGE
  45 dnl - interfaces removed -> AGE = 0
  46 dnl sets GST_LT_LDFLAGS
  47 AS_LIBTOOL(GST, 15, 0, 15)
  48
  49 dnl FIXME: this macro doesn't actually work;
  50 dnl the generated libtool script has no support for the listed tags.
  51 dnl So this needs to be fixed first if we want to use this
  52 dnl AS_LIBTOOL_TAGS
  53
  54 AC_LIBTOOL_WIN32_DLL
  55 AM_PROG_LIBTOOL
  56
  57 dnl *** required versions of GStreamer stuff ***
  58 GST_REQ=0.10.21.1
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67
  68 dnl set up gettext
  69 dnl the version check needs to stay here because autopoint greps for it
  70 AM_GNU_GETTEXT_VERSION([0.17])
  71 AM_GNU_GETTEXT([external])
  72 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  73
  74 dnl *** check for arguments to configure ***
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 dnl let distro override plugin install helper path
  88 AC_ARG_WITH(install-plugins-helper,
  89   AC_HELP_STRING([--with-install-plugins-helper],
  90     [specify path of helper script to call to install plugins]),
  91   [
  92     case "${withval}" in
  93       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  94       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  95       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  96     esac
  97   ],
  98   [
  99     dnl Default value
 100     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 101   ]
 102 )
 103 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 104 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 105     [plugin install helper script])
 106 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 107
 108 AG_GST_ARG_WITH_PLUGINS
 109
 110 AG_GST_ARG_ENABLE_EXTERNAL
 111
 112 AG_GST_ARG_ENABLE_EXPERIMENTAL
 113
 114 dnl *** checks for platform ***
 115
 116 dnl * hardware/architecture *
 117
 118 dnl common/m4/gst-arch.m4
 119 dnl check CPU type
 120 AG_GST_ARCH
 121
 122 dnl check for large file support
 123 dnl affected plugins must include config.h
 124 AC_SYS_LARGEFILE
 125
 126 dnl *** checks for programs ***
 127
 128 dnl find a compiler
 129 AC_PROG_CC
 130
 131 dnl check if the compiler supports '-c' and '-o' options
 132 AM_PROG_CC_C_O
 133
 134 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 135 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 136
 137 dnl check for documentation tools
 138 GTK_DOC_CHECK([1.3])
 139 AS_PATH_PYTHON([2.1])
 140 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 141
 142 dnl *** checks for libraries ***
 143
 144 dnl libm, for sin() etc.
 145 AC_CHECK_LIBM
 146 AC_SUBST(LIBM)
 147
 148 dnl *** checks for header files ***
 149
 150 dnl check if we have ANSI C header files
 151 AC_HEADER_STDC
 152
 153 dnl used in gst/ffmpegcolorspace/mem.c
 154 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 155 AC_CHECK_HEADERS([malloc.h])
 156
 157 dnl used in gst/subparse/gstsubparse.c
 158 AC_CHECK_HEADERS([regex.h], HAVE_REGEX_H="yes", HAVE_REGEX_H="no")
 159 AM_CONDITIONAL(HAVE_REGEX_H, test "x$HAVE_REGEX_H" = "xyes")
 160
 161 if test "x$HAVE_REGEX_H" = "xyes"; then
 162   ac_cppflags_save="$CPPFLAGS"
 163   CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 164   AC_COMPILE_IFELSE(
 165     AC_LANG_PROGRAM([
 166 #include <libxml/HTMLparser.h>
 167                      ],[
 168 #ifndef LIBXML_HTML_ENABLED
 169 #error libxml2 has no HTML support
 170 #endif /* LIBXML_HTML_ENABLED */
 171                      ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 172   CPPFLAGS="$ac_cppflags_save"
 173 else
 174   HAVE_LIBXML_HTML="no"
 175 fi
 176 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 177
 178 dnl used in gst/tcp
 179 AC_CHECK_HEADERS([sys/socket.h],
 180   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 181 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 182
 183 dnl used in gst-libs/gst/rtsp
 184 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 185 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 186   WIN32_LIBS="-lws2_32"
 187   AC_SUBST(WIN32_LIBS)
 188 fi
 189
 190 dnl check for hstrerror, for gst-libs/gst/rtsp
 191 save_libs="$LIBS"
 192 AC_CHECK_FUNC(hstrerror, ,
 193     AC_CHECK_LIB(resolv, hstrerror, ,
 194         [AC_DEFINE(NO_HSTRERROR, 1,
 195              [Define if you have no native hstrerror() function.])]))
 196 HSTRERROR_LIBS=$LIBS
 197 AC_SUBST(HSTRERROR_LIBS)
 198 LIBS="$save_libs"
 199
 200 dnl used in gst-libs/gst/pbutils and associated unit test
 201 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 202
 203 dnl ffmpegcolorspace includes _stdint.h
 204 dnl also, Windows does not have long long
 205 AX_CREATE_STDINT_H
 206
 207 dnl *** checks for functions ***
 208 AC_CHECK_FUNCS([localtime_r gmtime_r])
 209
 210 dnl *** checks for types/defines ***
 211
 212 dnl Check for FIONREAD ioctl declaration
 213 dnl used in gst/tcp
 214 GST_CHECK_FIONREAD
 215
 216 dnl *** checks for structures ***
 217
 218 dnl *** checks for compiler characteristics ***
 219
 220 dnl make sure we can use "inline" from C code
 221 AC_C_INLINE
 222
 223 dnl *** checks for library functions ***
 224
 225 dnl check for fseeko()
 226 AC_FUNC_FSEEKO
 227
 228 dnl Check for fast float to int casting as defined in C99
 229 dnl used in gst-libs/gst/floatcast/floatcast.h
 230 save_libs=$LIBS
 231 LIBS="$LIBS $LIBM"
 232 AC_C99_FUNC_LRINT
 233 AC_C99_FUNC_LRINTF
 234 LIBS=$save_libs
 235
 236 dnl Check for a way to display the function name in debug output
 237 AG_GST_CHECK_FUNCTION
 238
 239 dnl *** checks for dependency libraries ***
 240
 241 dnl GLib is required
 242 AG_GST_GLIB_CHECK([2.12])
 243
 244 dnl liboil is required
 245 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.14, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 246 if test "x$HAVE_LIBOIL" != "xyes"; then
 247   AC_ERROR([liboil-0.3.14 or later is required])
 248 fi
 249
 250 dnl checks for gstreamer
 251 dnl uninstalled is selected preferentially -- see pkg-config(1)
 252 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 253 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 254 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 255 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 256 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 257 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 258
 259 dnl Check for documentation xrefs
 260 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 261 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 262 AC_SUBST(GLIB_PREFIX)
 263 AC_SUBST(GST_PREFIX)
 264
 265 dnl GTK is optional and only used in examples
 266 PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.12.0, HAVE_GTK=yes, HAVE_GTK=no)
 267 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 268
 269 dnl some examples need gtk+-x11
 270 PKG_CHECK_MODULES(GTK_X11, gtk+-x11-2.0 >= 2.12.0,
 271     HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 272 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 273
 274 dnl *** set variables based on configure arguments ***
 275
 276 dnl set license and copyright notice
 277 GST_LICENSE="LGPL"
 278 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 279 AC_SUBST(GST_LICENSE)
 280
 281 dnl set location of plugin directory
 282 AG_GST_SET_PLUGINDIR
 283
 284 dnl define an ERROR_CFLAGS Makefile variable
 285 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 286
 287 dnl define correct level for debugging messages
 288 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 289
 290 dnl used in examples
 291 AG_GST_DEFAULT_ELEMENTS
 292
 293 dnl *** plug-ins to include ***
 294
 295 dnl these are all the gst plug-ins, compilable without additional libs
 296 AG_GST_CHECK_PLUGIN(adder)
 297 AG_GST_CHECK_PLUGIN(app)
 298 AG_GST_CHECK_PLUGIN(audioconvert)
 299 AG_GST_CHECK_PLUGIN(audiorate)
 300 AG_GST_CHECK_PLUGIN(audiotestsrc)
 301 AG_GST_CHECK_PLUGIN(ffmpegcolorspace)
 302 AG_GST_CHECK_PLUGIN(gdp)
 303 AG_GST_CHECK_PLUGIN(playback)
 304 AG_GST_CHECK_PLUGIN(speexresample)
 305 AG_GST_CHECK_PLUGIN(subparse)
 306 AG_GST_CHECK_PLUGIN(tcp)
 307 AG_GST_CHECK_PLUGIN(typefind)
 308 AG_GST_CHECK_PLUGIN(videotestsrc)
 309 AG_GST_CHECK_PLUGIN(videorate)
 310 AG_GST_CHECK_PLUGIN(videoscale)
 311 AG_GST_CHECK_PLUGIN(volume)
 312
 313 dnl check for gstreamer core features (subsystems)
 314 GST_CONFIGPATH=`$PKG_CONFIG --variable=includedir gstreamer-0.10`"/gst/gstconfig.h"
 315 AG_GST_PARSE_SUBSYSTEM_DISABLES($GST_CONFIGPATH)
 316 AM_CONDITIONAL(USE_XML, test $GST_DISABLE_XML != "1")
 317
 318 dnl disable plug-ins that require libxml2's HTML support if it is not available
 319 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 320   AG_GST_DISABLE_PLUGIN(subparse)
 321 fi
 322
 323 dnl disable plug-ins that require sys/socket.h if it is not available
 324 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 325   AG_GST_DISABLE_PLUGIN(tcp)
 326 fi
 327
 328 dnl *** sys plug-ins ***
 329
 330 echo
 331 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 332 echo
 333
 334 dnl *** X11 ***
 335 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 336 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 337                   [ximagesink], [
 338   AC_PATH_XTRA
 339   ac_cflags_save="$CFLAGS"
 340   ac_cppflags_save="$CPPFLAGS"
 341   CFLAGS="$CFLAGS $X_CFLAGS"
 342   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 343
 344   dnl now try to find the HEADER
 345   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 346
 347   if test "x$HAVE_X" = "xno"
 348   then
 349     AC_MSG_NOTICE([cannot find X11 development files])
 350   else
 351     dnl this is much more than we want
 352     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 353     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 354     dnl it does not add the libs; therefore we add them here
 355     X_LIBS="$X_LIBS -lX11"
 356     AC_SUBST(X_CFLAGS)
 357     AC_SUBST(X_LIBS)
 358   fi
 359   AC_SUBST(HAVE_X)
 360   CFLAGS="$ac_cflags_save"
 361   CPPFLAGS="$ac_cppflags_save"
 362 ])
 363
 364 dnl Check for Xv extension
 365 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 366 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 367                   [xvimagesink], [
 368   AG_GST_CHECK_XV
 369 ])
 370
 371 dnl check for X Shm
 372 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 373 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 374   if test x$HAVE_X = xyes; then
 375     AC_CHECK_LIB(Xext, XShmAttach,
 376                  HAVE_XSHM="yes", HAVE_XSHM="no",
 377                  $X_LIBS)
 378     if test "x$HAVE_XSHM" = "xyes"; then
 379       XSHM_LIBS="-lXext"
 380     else
 381       dnl On AIX, it is in XextSam instead, but we still need -lXext
 382       AC_CHECK_LIB(XextSam, XShmAttach,
 383                    HAVE_XSHM="yes", HAVE_XSHM="no",
 384                    $X_LIBS)
 385       if test "x$HAVE_XSHM" = "xyes"; then
 386         XSHM_LIBS="-lXext -lXextSam"
 387       fi
 388     fi
 389   fi
 390 ], , [
 391   AC_SUBST(HAVE_XSHM)
 392   AC_SUBST(XSHM_LIBS)
 393 ])
 394
 395 dnl v4l/v4l2 checks have been moved down because they require X
 396
 397 dnl *** Video 4 Linux ***
 398 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 399 dnl renamed to GST_V4L in accordance with V4L2 below
 400 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 401 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 402   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 403 #include <sys/types.h>
 404 #define _LINUX_TIME_H
 405 #define __user
 406 #include <linux/videodev.h>
 407   ])
 408
 409   dnl we can build v4l without Xv, but then we won't have XOverlay support
 410   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 411   then
 412     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 413     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 414   fi
 415 ])
 416
 417 dnl *** ext plug-ins ***
 418 dnl keep this list sorted alphabetically !
 419
 420 if test "x$BUILD_EXTERNAL" = "xyes"; then
 421
 422 echo
 423 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 424 echo
 425
 426 dnl *** alsa ***
 427 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 428 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 429   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 430     HAVE_ALSA="yes"
 431     AC_SUBST(ALSA_CFLAGS)
 432     AC_SUBST(ALSA_LIBS)
 433   ], [
 434     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 435   ])
 436 ])
 437
 438 dnl *** CDParanoia ***
 439 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 440 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 441   AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 442                       cdda_open, -lm,
 443                       cdda_interface.h,
 444                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 445                       HEADER_DIR="no"
 446                       FOUND_CDPARANOIA="yes")
 447   if test "x$FOUND_CDPARANOIA" != "xyes";
 448   then
 449     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 450                         cdda_open, -lm,
 451                         cdda/cdda_interface.h,
 452                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 453                         HEADER_DIR="yes"
 454                         FOUND_CDPARANOIA="yes")
 455   fi
 456   if test "x$HEADER_DIR" = "xyes";
 457   then
 458     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 459                        defined if cdda headers are in a cdda/ directory)
 460   fi
 461   AC_SUBST(CDPARANOIA_LIBS)
 462 ])
 463 dnl FIXME : add second check somehow if that is necessary
 464 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 465 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 466
 467 dnl *** GNOME VFS ***
 468 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 469 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 470   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, [
 471       HAVE_GNOME_VFS="yes"
 472       AC_SUBST(GNOME_VFS_CFLAGS)
 473       AC_SUBST(GNOME_VFS_LIBS)
 474       GNOME_VFS_MODULES_DIR="`$PKG_CONFIG --variable=modulesdir gnome-vfs-2.0`"
 475       AC_DEFINE_UNQUOTED(GNOME_VFS_MODULES_DIR, "$GNOME_VFS_MODULES_DIR",
 476              [The GnomeVFS modules directory.])
 477     ],[
 478       HAVE_GNOME_VFS="no"
 479     ]
 480     )
 481 ])
 482
 483 dnl *** libgio ***
 484 USE_GIO=$BUILD_EXPERIMENTAL
 485 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 486 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 487   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.15.2, [
 488     HAVE_GIO="yes"
 489     GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 490     AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 491            [The GIO modules directory.])
 492     GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 493     AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 494            [The GIO library directory.])
 495   ], [
 496     HAVE_GIO="no"
 497     AC_MSG_RESULT(no)
 498   ])
 499   AC_SUBST(GIO_CFLAGS)
 500   AC_SUBST(GIO_LIBS)
 501   AC_SUBST(GIO_LDFLAGS)
 502 ])
 503
 504 dnl *** libvisual ***
 505 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 506 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 507   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 508   if test $HAVE_LIBVISUAL = no
 509   then
 510     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 511     if test x$HAVE_LIBVISUAL == xyes; then
 512       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 513     fi
 514   else
 515     if test x$HAVE_LIBVISUAL == xyes; then
 516       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 517     fi
 518   fi
 519   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 520   if test x$LIBVIS_PLUGINSDIR != x; then
 521     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 522         "$LIBVIS_PLUGINSDIR",
 523         [directory in which the detected libvisual's plugins are located])
 524   fi
 525 ])
 526
 527 dnl *** ogg ***
 528 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 529 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 530   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 531   if test $HAVE_OGG = no
 532   then
 533     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 534     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 535   fi
 536 ])
 537
 538 dnl *** pango ***
 539 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 540 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 541   AG_GST_PKG_CHECK_MODULES(PANGO, pango pangoft2)
 542 ])
 543
 544 dnl *** theora ***
 545 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 546 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 547   dnl theora uses pkg-config version incorrectly, for pkg-config:
 548   dnl 1.0 < 1.0RCX < 1.0alphaX < 1.0betaX < 1.0.0
 549   dnl theoraenc and theoradec appeared in 1.0beta3
 550
 551   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec theoraenc)
 552   if test x$HAVE_THEORA = xno; then
 553     AG_GST_PKG_CHECK_MODULES(THEORA, theora >= 1.0alpha5)
 554   fi
 555 ])
 556
 557 dnl *** vorbis ***
 558 dnl AM_PATH_VORBIS only takes two options
 559 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 560 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 561   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 562   if test $HAVE_VORBIS = no
 563   then
 564     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 565     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 566   fi
 567 ])
 568
 569 if test "x$HAVE_VORBIS" = "xyes"; then
 570   ac_cflags_save="$CFLAGS"
 571   AC_COMPILE_IFELSE(
 572     AC_LANG_PROGRAM([
 573 #include <vorbis/codec.h>
 574                      ],[
 575 vorbis_dsp_state *v;
 576
 577 vorbis_synthesis_restart (v);
 578                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 579   if test "x$HAVE_VSR" = "xyes"; then
 580     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 581                        [defined if vorbis_synthesis_restart is present])
 582   fi
 583   CFLAGS="$ac_cflags_save"
 584 fi
 585
 586 else
 587
 588 dnl not building plugins with external dependencies,
 589 dnl but we still need to set the conditionals
 590 AM_CONDITIONAL(USE_ALSA, false)
 591 AM_CONDITIONAL(USE_CDPARANOIA, false)
 592 AM_CONDITIONAL(USE_GNOME_VFS, false)
 593 AM_CONDITIONAL(USE_GIO, false)
 594 AM_CONDITIONAL(USE_LIBVISUAL, false)
 595 AM_CONDITIONAL(USE_OGG, false)
 596 AM_CONDITIONAL(USE_PANGO, false)
 597 AM_CONDITIONAL(USE_THEORA, false)
 598 AM_CONDITIONAL(USE_VORBIS, false)
 599
 600 fi dnl of EXT plugins
 601
 602 dnl seeking needs freetype, so check for it here
 603 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 604   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 605 ])
 606 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 607 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 608 AC_SUBST(FT2_CFLAGS)
 609 AC_SUBST(FT2_LIBS)
 610
 611 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 612
 613 dnl Overview:
 614 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 615 dnl GST_*:              flags shared by built objects to link against GStreamer
 616 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 617 dnl                          (compare to other modules) or for i18n
 618 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 619 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 620 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 621 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 622
 623 dnl GST_OPTION_CFLAGS
 624 if test "x$USE_DEBUG" = xyes; then
 625    PROFILE_CFLAGS="-g"
 626 fi
 627 AC_SUBST(PROFILE_CFLAGS)
 628
 629 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 630   dnl Define _only_ during CVS (not pre-releases or releases)
 631   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 632 else
 633   DEPRECATED_CFLAGS=""
 634 fi
 635 AC_SUBST(DEPRECATED_CFLAGS)
 636
 637 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 638 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 639 AC_SUBST(GST_OPTION_CFLAGS)
 640
 641 dnl our libraries need to be versioned correctly
 642 AC_SUBST(GST_LT_LDFLAGS)
 643
 644 dnl GST_PLUGINS_BASE_CFLAGS
 645 dnl prefer internal headers to already installed ones
 646 dnl also add builddir include for enumtypes and marshal
 647 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 648 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 649
 650 dnl FIXME: do we want to rename to GST_ALL_* ?
 651 dnl add GST_OPTION_CFLAGS, but overridable
 652 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 653 AC_SUBST(GST_CFLAGS)
 654 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 655 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 656 AC_SUBST(GST_LIBS)
 657
 658 dnl LDFLAGS really should only contain flags, not libs - they get added before
 659 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 660 GST_ALL_LDFLAGS="-no-undefined"
 661 AC_SUBST(GST_ALL_LDFLAGS)
 662
 663 dnl GST_LIB_LDFLAGS
 664 dnl linker flags shared by all libraries
 665 dnl LDFLAGS modifier defining exported symbols from built libraries
 666 dnl (export _gst_foo but not __gst_foo)
 667 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 668 AC_SUBST(GST_LIB_LDFLAGS)
 669
 670 dnl this really should only contain flags, not libs - they get added before
 671 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 672 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 673 AC_SUBST(GST_PLUGIN_LDFLAGS)
 674
 675 dnl *** output files ***
 676
 677 AC_CONFIG_FILES(
 678 Makefile
 679 gst-plugins-base.spec
 680 gst/Makefile
 681 gst/adder/Makefile
 682 gst/app/Makefile
 683 gst/audioconvert/Makefile
 684 gst/audiorate/Makefile
 685 gst/audiotestsrc/Makefile
 686 gst/ffmpegcolorspace/Makefile
 687 gst/gdp/Makefile
 688 gst/playback/Makefile
 689 gst/speexresample/Makefile
 690 gst/subparse/Makefile
 691 gst/tcp/Makefile
 692 gst/typefind/Makefile
 693 gst/videotestsrc/Makefile
 694 gst/videorate/Makefile
 695 gst/videoscale/Makefile
 696 gst/volume/Makefile
 697 sys/Makefile
 698 sys/ximage/Makefile
 699 sys/xvimage/Makefile
 700 sys/v4l/Makefile
 701 ext/Makefile
 702 ext/alsa/Makefile
 703 ext/cdparanoia/Makefile
 704 ext/gnomevfs/Makefile
 705 ext/gio/Makefile
 706 ext/libvisual/Makefile
 707 ext/ogg/Makefile
 708 ext/pango/Makefile
 709 ext/theora/Makefile
 710 ext/vorbis/Makefile
 711 gst-libs/Makefile
 712 gst-libs/gst/Makefile
 713 gst-libs/gst/audio/Makefile
 714 gst-libs/gst/app/Makefile
 715 gst-libs/gst/cdda/Makefile
 716 gst-libs/gst/fft/Makefile
 717 gst-libs/gst/floatcast/Makefile
 718 gst-libs/gst/interfaces/Makefile
 719 gst-libs/gst/netbuffer/Makefile
 720 gst-libs/gst/riff/Makefile
 721 gst-libs/gst/rtp/Makefile
 722 gst-libs/gst/rtsp/Makefile
 723 gst-libs/gst/sdp/Makefile
 724 gst-libs/gst/tag/Makefile
 725 gst-libs/gst/pbutils/Makefile
 726 gst-libs/gst/video/Makefile
 727 tools/Makefile
 728 win32/common/config.h
 729 pkgconfig/Makefile
 730 pkgconfig/gstreamer-audio.pc
 731 pkgconfig/gstreamer-audio-uninstalled.pc
 732 pkgconfig/gstreamer-app.pc
 733 pkgconfig/gstreamer-app-uninstalled.pc
 734 pkgconfig/gstreamer-cdda.pc
 735 pkgconfig/gstreamer-cdda-uninstalled.pc
 736 pkgconfig/gstreamer-fft.pc
 737 pkgconfig/gstreamer-fft-uninstalled.pc
 738 pkgconfig/gstreamer-floatcast.pc
 739 pkgconfig/gstreamer-floatcast-uninstalled.pc
 740 pkgconfig/gstreamer-interfaces.pc
 741 pkgconfig/gstreamer-interfaces-uninstalled.pc
 742 pkgconfig/gstreamer-netbuffer.pc
 743 pkgconfig/gstreamer-netbuffer-uninstalled.pc
 744 pkgconfig/gstreamer-pbutils.pc
 745 pkgconfig/gstreamer-pbutils-uninstalled.pc
 746 pkgconfig/gstreamer-riff.pc
 747 pkgconfig/gstreamer-riff-uninstalled.pc
 748 pkgconfig/gstreamer-rtp.pc
 749 pkgconfig/gstreamer-rtp-uninstalled.pc
 750 pkgconfig/gstreamer-rtsp.pc
 751 pkgconfig/gstreamer-rtsp-uninstalled.pc
 752 pkgconfig/gstreamer-sdp.pc
 753 pkgconfig/gstreamer-sdp-uninstalled.pc
 754 pkgconfig/gstreamer-tag.pc
 755 pkgconfig/gstreamer-tag-uninstalled.pc
 756 pkgconfig/gstreamer-video.pc
 757 pkgconfig/gstreamer-video-uninstalled.pc
 758 pkgconfig/gstreamer-plugins-base.pc
 759 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 760 tests/Makefile
 761 tests/check/Makefile
 762 tests/examples/Makefile
 763 tests/examples/app/Makefile
 764 tests/examples/dynamic/Makefile
 765 tests/examples/seek/Makefile
 766 tests/examples/volume/Makefile
 767 tests/examples/snapshot/Makefile
 768 tests/icles/Makefile
 769 docs/Makefile
 770 docs/design/Makefile
 771 docs/libs/Makefile
 772 docs/plugins/Makefile
 773 docs/version.entities
 774 po/Makefile.in
 775 common/Makefile
 776 common/m4/Makefile
 777 m4/Makefile
 778 )
 779 AC_OUTPUT
 780
 781 AG_GST_OUTPUT_PLUGINS