configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT([GStreamer Good Plug-ins],[1.13.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-good])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 AG_GST_LIBTOOL_PREPARE
  46 AS_LIBTOOL(GST, 1300, 0, 1300)
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=1.13.0.1
  50 GSTPB_REQ=1.13.0.1
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.17])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  69 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  70
  71 AG_GST_ARG_DEBUG
  72 AG_GST_ARG_PROFILING
  73 AG_GST_ARG_VALGRIND
  74 AG_GST_ARG_GCOV
  75
  76 AG_GST_ARG_EXAMPLES
  77
  78 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  79 AG_GST_ARG_WITH_PACKAGE_NAME
  80 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  81
  82 AG_GST_ARG_WITH_PLUGINS
  83
  84 AG_GST_ARG_ENABLE_EXTERNAL
  85
  86 AG_GST_ARG_ENABLE_EXPERIMENTAL
  87
  88 AG_GST_PKG_CONFIG_PATH
  89
  90 dnl *** checks for platform ***
  91
  92 dnl * hardware/architecture *
  93
  94 dnl common/m4/gst-arch.m4
  95 dnl check CPU type
  96 AG_GST_ARCH
  97
  98 dnl Determine endianness
  99 AC_C_BIGENDIAN
 100
 101 dnl *** checks for programs ***
 102
 103 dnl find a compiler
 104 AC_PROG_CC
 105 AC_PROG_CC_STDC
 106
 107 dnl determine c++ compiler
 108 AC_PROG_CXX
 109 dnl determine if c++ is available on this system
 110 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 111
 112 dnl determine c++ preprocessor
 113 dnl FIXME: do we need this ?
 114 AC_PROG_CXXCPP
 115
 116 AC_PROG_OBJC
 117
 118 dnl check if the compiler supports '-c' and '-o' options
 119 AM_PROG_CC_C_O
 120
 121 dnl find an assembler
 122 AM_PROG_AS
 123
 124 dnl check if the compiler supports do while(0) macros
 125 AG_GST_CHECK_DOWHILE_MACROS
 126
 127 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 128 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 129
 130 dnl check for documentation tools
 131 GTK_DOC_CHECK([1.12])
 132 AG_GST_PLUGIN_DOCS([1.12])
 133
 134 dnl *** checks for libraries ***
 135
 136 dnl check for libm, for sin()
 137 LT_LIB_M
 138 AC_SUBST(LIBM)
 139
 140 AC_CHECK_FUNCS(clock_gettime, [], [
 141   AC_CHECK_LIB(rt, clock_gettime, [
 142     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 143     LIBRT="-lrt"
 144     AC_SUBST([LIBRT])
 145   ])
 146 ])
 147
 148 dnl check for pthreads
 149 AX_PTHREAD
 150
 151 dnl *** checks for header files ***
 152
 153 dnl check if we have ANSI C header files
 154 AC_HEADER_STDC
 155
 156 dnl used by ext/wavpack
 157 AX_CREATE_STDINT_H
 158
 159 dnl used in gst/udp
 160 AC_CHECK_HEADERS([sys/time.h])
 161
 162 dnl used in gst/udp
 163 AC_CHECK_HEADERS([sys/socket.h])
 164
 165 dnl *** checks for types/defines ***
 166
 167 dnl Check for FIONREAD ioctl declaration.  This check is needed
 168 dnl for the UDP plugin to build on Solaris
 169 GST_CHECK_FIONREAD
 170
 171 dnl *** checks for structures ***
 172
 173 dnl *** checks for compiler characteristics ***
 174
 175 dnl check if we have GCC inline-asm
 176 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 177 if test x$HAVE_GCC_ASM = xyes ; then
 178   AC_DEFINE(HAVE_GCC_ASM, 1,
 179     [Define if compiler supports gcc inline assembly])
 180 fi
 181 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 182
 183 dnl *** checks for library functions ***
 184
 185 LIBS_SAVE=$LIBS
 186 LIBS="$LIBS $LIBM"
 187 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 188 LIBS=$LIBS_SAVE
 189
 190 dnl Check whether isinf() is defined by math.h
 191 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 192     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 193 if test "$ac_cv_have_isinf" = "yes"
 194 then
 195     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 196 fi
 197
 198 dnl Check for mmap (needed by electricfence plugin)
 199 AC_FUNC_MMAP
 200 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 201
 202 dnl Check for mmap (needed by electricfence plugin)
 203
 204 AC_CHECK_TYPE([struct ip_mreqn], [
 205               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 206               [#include <netinet/in.h>])
 207
 208 dnl *** checks for dependency libraries ***
 209
 210
 211 dnl GLib
 212 GLIB_REQ=2.40.0
 213 AG_GST_GLIB_CHECK([$GLIB_REQ])
 214
 215 dnl Orc
 216 ORC_CHECK([0.4.17])
 217
 218 dnl checks for gstreamer
 219 dnl uninstalled is selected preferentially -- see pkg-config(1)
 220 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 221 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 222 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 223 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 224 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 225 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 226
 227 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 228 if test -z $GST_TOOLS_DIR; then
 229   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 230 fi
 231 AC_SUBST(GST_TOOLS_DIR)
 232
 233 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 234 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 235
 236 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 237
 238 dnl Check for documentation xrefs
 239 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 240 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 241 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 242 AC_SUBST(GLIB_PREFIX)
 243 AC_SUBST(GST_PREFIX)
 244 AC_SUBST(GSTPB_PREFIX)
 245
 246 dnl GTK is optional and used in examples
 247 HAVE_GTK=no
 248 GTK_REQ=3.0.0
 249 if test "x$BUILD_EXAMPLES" = "xyes"; then
 250   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 251   dnl some examples need gtk+-x11
 252   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 253   AC_SUBST(GTK_LIBS)
 254   AC_SUBST(GTK_CFLAGS)
 255 fi
 256 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 257 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 258
 259 dnl Check for -Bsymbolic-functions linker flag used to avoid
 260 dnl intra-library PLT jumps, if available.
 261 AC_ARG_ENABLE(Bsymbolic,
 262               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 263               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 264                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 265                LDFLAGS=-Wl,-Bsymbolic-functions
 266                LIBS=
 267                AC_TRY_LINK([], [return 0],
 268                            AC_MSG_RESULT(yes)
 269                            enable_Bsymbolic=yes,
 270                            AC_MSG_RESULT(no)
 271                            enable_Bsymbolic=no)
 272                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 273
 274 dnl *** set variables based on configure arguments ***
 275
 276 dnl set license and copyright notice
 277 GST_LICENSE="LGPL"
 278 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 279 AC_SUBST(GST_LICENSE)
 280
 281 dnl set location of plugin directory
 282 AG_GST_SET_PLUGINDIR
 283
 284 dnl set release date/time
 285 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 286   ["${srcdir}/gst-plugins-good.doap"],
 287   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 288
 289 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 290 dnl make sure it doesn't complain about unused variables if debugging is disabled
 291 NO_WARNINGS=""
 292 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 293
 294 dnl define an ERROR_CFLAGS Makefile variable
 295 dnl -Wundef: too many broken headers
 296 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 297       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 298       -Wwrite-strings -Wold-style-definition -Waggregate-return
 299       -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 300       -Wnested-externs $NO_WARNINGS])
 301
 302 dnl define an ERROR_CXXFLAGS Makefile variable
 303 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 304         -Wmissing-declarations -Wredundant-decls
 305         -Wwrite-strings
 306         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 307         $NO_WARNINGS])
 308
 309 dnl define an ERROR_OBJCFLAGS Makefile variable
 310 AG_GST_SET_ERROR_OBJCFLAGS($FATAL_WARNINGS, [
 311       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 312       -Wwrite-strings -Wold-style-definition
 313       -Winit-self -Wmissing-include-dirs -Wno-multichar
 314       -Wnested-externs $NO_WARNINGS])
 315
 316 dnl define correct level for debugging messages
 317 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 318
 319 dnl used in examples
 320 AG_GST_DEFAULT_ELEMENTS
 321
 322 dnl *** plug-ins to include ***
 323
 324 dnl these are all the gst plug-ins, compilable without additional libs
 325 dnl videofilter is at the top because others depend on it
 326 AG_GST_CHECK_PLUGIN(alpha)
 327 AG_GST_CHECK_PLUGIN(apetag)
 328 AG_GST_CHECK_PLUGIN(audiofx)
 329 AG_GST_CHECK_PLUGIN(audioparsers)
 330 AG_GST_CHECK_PLUGIN(auparse)
 331 AG_GST_CHECK_PLUGIN(autodetect)
 332 AG_GST_CHECK_PLUGIN(avi)
 333 AG_GST_CHECK_PLUGIN(cutter)
 334 AG_GST_CHECK_PLUGIN(debugutils)
 335 AG_GST_CHECK_PLUGIN(deinterlace)
 336 AG_GST_CHECK_PLUGIN(dtmf)
 337 AG_GST_CHECK_PLUGIN(effectv)
 338 AG_GST_CHECK_PLUGIN(equalizer)
 339 AG_GST_CHECK_PLUGIN(flv)
 340 AG_GST_CHECK_PLUGIN(flx)
 341 AG_GST_CHECK_PLUGIN(goom)
 342 AG_GST_CHECK_PLUGIN(goom2k1)
 343 AG_GST_CHECK_PLUGIN(icydemux)
 344 AG_GST_CHECK_PLUGIN(id3demux)
 345 AG_GST_CHECK_PLUGIN(imagefreeze)
 346 AG_GST_CHECK_PLUGIN(interleave)
 347 AG_GST_CHECK_PLUGIN(isomp4)
 348 AG_GST_CHECK_PLUGIN(law)
 349 AG_GST_CHECK_PLUGIN(level)
 350 AG_GST_CHECK_PLUGIN(matroska)
 351 AG_GST_CHECK_PLUGIN(monoscope)
 352 AG_GST_CHECK_PLUGIN(multifile)
 353 AG_GST_CHECK_PLUGIN(multipart)
 354 AG_GST_CHECK_PLUGIN(replaygain)
 355 AG_GST_CHECK_PLUGIN(rtp)
 356 AG_GST_CHECK_PLUGIN(rtpmanager)
 357 AG_GST_CHECK_PLUGIN(rtsp)
 358 AG_GST_CHECK_PLUGIN(shapewipe)
 359 AG_GST_CHECK_PLUGIN(smpte)
 360 AG_GST_CHECK_PLUGIN(spectrum)
 361 AG_GST_CHECK_PLUGIN(udp)
 362 AG_GST_CHECK_PLUGIN(videobox)
 363 AG_GST_CHECK_PLUGIN(videocrop)
 364 AG_GST_CHECK_PLUGIN(videofilter)
 365 AG_GST_CHECK_PLUGIN(videomixer)
 366 AG_GST_CHECK_PLUGIN(wavenc)
 367 AG_GST_CHECK_PLUGIN(wavparse)
 368 AG_GST_CHECK_PLUGIN(y4m)
 369
 370 dnl disable experimental plug-ins
 371 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 372   AG_GST_DISABLE_PLUGIN(monoscope)
 373 fi
 374
 375 dnl *** sys plug-ins ***
 376
 377 echo
 378 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 379 echo
 380
 381 dnl DirectSound
 382 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 383 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 384   HAVE_DIRECTSOUND="no"
 385   save_CFLAGS="$CFLAGS"
 386   save_LDFLAGS="$LDFLAGS"
 387   save_LIBS="$LIBS"
 388   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 389   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 390   LIBS="$LIBS -ldsound -ldxerr9 -luser32 -lole32"
 391   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 392   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 393 #include <windows.h>
 394 #include <dxerr9.h>
 395 #include <dsound.h>
 396 ]], [[
 397   DXGetErrorString9 (0);
 398   DirectSoundCreate(NULL, NULL, NULL);
 399   CLSIDFromString(NULL, NULL);
 400 ]])
 401 ],
 402     [HAVE_DIRECTSOUND="yes"],
 403     [HAVE_DIRECTSOUND="no"])
 404   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 405   CFLAGS=$save_CFLAGS
 406   LDFLAGS=$save_LDFLAGS
 407   LIBS=$save_LIBS
 408
 409   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 410     dnl this is much more than we want
 411     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32 -lole32"
 412     AC_SUBST(DIRECTSOUND_CFLAGS)
 413     AC_SUBST(DIRECTSOUND_LDFLAGS)
 414     AC_SUBST(DIRECTSOUND_LIBS)
 415   fi
 416   AC_SUBST(HAVE_DIRECTSOUND)
 417 ])
 418
 419 dnl *** Win32 WaveOut ***
 420 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 421 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 422   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 423 ])
 424
 425 dnl *** OSS audio *** (Linux, *BSD)
 426 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 427 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 428  HAVE_OSS="yes"
 429 dnl Linux and newer BSD versions :
 430  AC_CHECK_HEADER(sys/soundcard.h, [
 431    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 432    ] , [
 433 dnl Some old BSD versions and also newer OpenBSD versions :
 434    AC_CHECK_HEADER(soundcard.h, [
 435      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 436      ], [
 437   dnl Some old BSD versions :
 438      AC_CHECK_HEADER(machine/soundcard.h, [
 439        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 440          [Define if OSS includes are in /machine/])
 441        ], [
 442        HAVE_OSS="no"
 443      ])
 444    ])
 445  ])
 446 ])
 447
 448 dnl *** oss4 ***
 449 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 450 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 451   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 452   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 453       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 454       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 455 ])
 456
 457 dnl *** Sun Audio ***
 458 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 459 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 460   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 461 ])
 462
 463 dnl *** OSX Audio ***
 464 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 465 HAVE_IOS="no"
 466 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 467   AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 468     [HAVE_OSX_AUDIO="yes"],
 469     [AC_CHECK_HEADER(CoreAudio/CoreAudioTypes.h,
 470     [
 471       HAVE_OSX_AUDIO="yes"
 472       HAVE_IOS="yes"
 473     ], [
 474       HAVE_OSX_AUDIO="no"
 475       HAVE_IOS="no"
 476     ])]
 477   )
 478 ])
 479 if test "x$HAVE_IOS" = "xyes"; then
 480   AC_DEFINE(HAVE_IOS, 1, [building for iOS platofrm])
 481 fi
 482 AM_CONDITIONAL(HAVE_IOS, test "x$HAVE_IOS" = "xyes")
 483
 484 dnl *** OS X video ***
 485 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 486 HAVE_OSX_VIDEO="no"
 487 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 488   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 489
 490   dnl in case header OpenGL/gl.h is found on other platforms (or older, unsupported OS X)
 491   dnl also require Snow Leopard or newer
 492
 493   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 494         #include <AvailabilityMacros.h>
 495         #if MAC_OS_X_VERSION_MIN_REQUIRED < 1060
 496         #error Too old OSX version
 497         #endif
 498       ]], [[return 0;]])],[HAVE_OSX_VIDEO="yes"],[HAVE_OSX_VIDEO="no"])
 499 ])
 500
 501 dnl *** Video 4 Linux 2 ***
 502 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 503 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 504 HAVE_GST_V4L2=no
 505 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], video4linux2, [
 506   AC_MSG_CHECKING([Checking for video4linux2 header ...])
 507   AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_GST_V4L2=yes ],
 508   [
 509     AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_GST_V4L2=yes ],
 510     [
 511       AC_CHECK_HEADER(sys/videoio.h, [ HAVE_GST_V4L2=yes ])
 512     ])
 513   ])
 514   if test "x$HAVE_VIDEODEV" = "xno"; then
 515      AC_MSG_WARN([video4linux2 was not found])
 516   fi
 517 ])
 518
 519 # Optional gudev for device probing
 520 AC_ARG_WITH([gudev],
 521   AS_HELP_STRING([--with-gudev],[device detection with gudev]),
 522   [],
 523   [with_gudev=check])
 524 if test x$HAVE_GST_V4L2 = xyes; then
 525   if test x$with_gudev != xno; then
 526     PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 147 ],
 527       [ AC_DEFINE(HAVE_GUDEV, 1,
 528           [Whether gudev is available for device detection])
 529       ],
 530       [true])
 531   fi
 532 fi
 533
 534 AC_SUBST(GUDEV_CFLAGS)
 535 AC_SUBST(GUDEV_LIBS)
 536
 537 # Make libv4l2 non-automagic
 538 AC_ARG_WITH([libv4l2],
 539   AS_HELP_STRING([--with-libv4l2],[support video buffer conversion using libv4l2]),
 540   [],
 541   [with_libv4l2=check])
 542 if test x$HAVE_GST_V4L2 = xyes; then
 543   if test x$with_libv4l2 != xno; then
 544       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 545           [ have_libv4l2=yes
 546             AC_DEFINE(HAVE_LIBV4L2, 1,
 547                 [Whether libv4l2 is available for video buffer conversion])
 548           ], [
 549           have_libv4l2=no
 550           ])
 551   else
 552     have_libv4l2=no
 553   fi
 554 fi
 555
 556 dnl Allow enabling v4l2 device probing
 557 AS_CASE([$host],
 558     [*-*linux*],
 559       [AS_CASE([$host_cpu],
 560         [arm*], [
 561           enable_v4l2_probe="yes"],
 562         [aarch64*], [
 563           enable_v4l2_probe="yes"])])
 564 AC_ARG_ENABLE(
 565   v4l2-probe,
 566   AC_HELP_STRING(
 567     [--enable-v4l2-probe],
 568     [enable V4L2 plugin to probe devices @<:@default=no@:>@]))
 569 if test "x$enable_v4l2_probe" = "xyes"; then
 570   AC_DEFINE(GST_V4L2_ENABLE_PROBE, 1,
 571     [Define if Video4Linux probe shall be run at plugin load])
 572 fi
 573
 574 dnl Check for X11
 575 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 576 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 577                   [ximagesrc], [
 578   PKG_CHECK_MODULES([X], [x11], [
 579     HAVE_X="yes"
 580     dnl check for Xfixes
 581     PKG_CHECK_MODULES([XFIXES], [ xfixes ], [
 582       AC_DEFINE(HAVE_XFIXES, 1, [Defined if Xfixes is available])
 583     ], [ HAVE_XFIXES="no" ])
 584
 585     dnl check for Xdamage
 586     PKG_CHECK_MODULES([XDAMAGE], [ xdamage ], [
 587       AC_DEFINE(HAVE_XDAMAGE, 1, [Defined if Xdamage is available])
 588     ], [ HAVE_XDAMAGE="no" ])
 589
 590     dnl check for X Shm
 591     PKG_CHECK_MODULES([XEXT], [ xext ], [
 592       AC_CHECK_LIB([Xext], [ XShmAttach ], [
 593         AC_DEFINE(HAVE_XSHM, 1, [Defined if XShm is available])
 594         XSHM_LIBS="$XEXT_LIBS"
 595         XSHM_CFLAGS="$XEXT_CFLAGS"
 596       ], [ HAVE_XEXT="no" ] , [ $X_LIBS ])
 597     ])
 598     AC_SUBST(XSHM_LIBS)
 599     AC_SUBST(XSHM_CFLAGS)
 600   ], [ HAVE_X="no" ])
 601 ])
 602
 603 dnl *** ext plug-ins ***
 604 dnl keep this list sorted alphabetically !
 605
 606 if test "x$BUILD_EXTERNAL" = "xyes"; then
 607
 608 echo
 609 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 610 echo
 611
 612 dnl *** aalib ***
 613 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 614 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 615   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 616 ])
 617
 618 dnl *** cairo ***
 619 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 620 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering and gobject bindings], cairo, [
 621   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.10.0 cairo-gobject >= 1.10.0)
 622 ])
 623
 624 dnl *** FLAC ***
 625 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 626 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 627   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 628 ])
 629
 630 dnl *** GDK pixbuf ***
 631 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 632 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 633   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 634 ])
 635
 636 dnl *** Jack ***
 637 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 638 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 639   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 640   AC_SUBST(JACK_CFLAGS)
 641   AC_SUBST(JACK_LIBS)
 642
 643   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 644   if test x$HAVE_JACK_0_120_1 = xyes; then
 645     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 646   fi
 647   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 648   if test x$HAVE_JACK_1_9_7 = xyes; then
 649     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 650   fi
 651
 652 ])
 653
 654 dnl *** jpeg ***
 655 dnl FIXME: we could use header checks here as well IMO
 656 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 657 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 658   AC_ARG_WITH(jpeg-mmx,
 659     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 660   OLD_LIBS="$LIBS"
 661   if test x$with_jpeg_mmx != x; then
 662     LIBS="$LIBS -L$with_jpeg_mmx"
 663   fi
 664   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 665   JPEG_LIBS="$LIBS -ljpeg-mmx"
 666   LIBS="$OLD_LIBS"
 667   if test x$HAVE_JPEG != xyes; then
 668     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 669     JPEG_LIBS="-ljpeg"
 670   fi
 671   AC_SUBST(JPEG_LIBS)
 672 ])
 673
 674 dnl *** libcaca ***
 675 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 676 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 677   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 678 ])
 679
 680 dnl *** libdv ***
 681 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 682 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 683   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 684 ])
 685
 686 dnl *** libpng ***
 687 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 688 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 689   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 690 ])
 691
 692 dnl *** pulseaudio ***
 693 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 694 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 695
 696   dnl used in ext/pulse/pulseutil.c
 697   AC_CHECK_HEADERS([process.h])
 698
 699   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 2.0)
 700 ])
 701
 702 dnl *** dv1394 ***
 703 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 704 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 705   dnl first test for libraw1394 >= 2.0.0
 706   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 707   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 708   dnl now see how far we got
 709   if test x$HAVE_RAW1394 = xyes && \
 710      test x$HAVE_LIBIEC61883 = xyes; then
 711        AG_GST_CHECK_LIBHEADER(AVC1394,
 712         avc1394, avc1394_send_command, $RAW1394_LIBS,
 713         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 714        AG_GST_CHECK_LIBHEADER(ROM1394,
 715         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 716         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 717        if test x$HAVE_AVC1394 = xyes && \
 718           test x$HAVE_AVC1394 = xyes && \
 719           test x$HAVE_ROM1394 = xyes; then
 720           HAVE_DV1394=yes
 721           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 722           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 723           AC_SUBST(DV1394_CFLAGS)
 724           AC_SUBST(DV1394_LIBS)
 725         fi
 726   else
 727        if test x$HAVE_RAW1394 = xno; then
 728           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 729           AG_GST_CHECK_LIBHEADER(AVC1394,
 730            avc1394, avc1394_send_command, $RAW1394_LIBS,
 731            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 732           AG_GST_CHECK_LIBHEADER(ROM1394,
 733            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 734            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 735           if test x$HAVE_RAW1394 = xyes && \
 736              test x$HAVE_AVC1394 = xyes && \
 737              test x$HAVE_ROM1394 = xyes; then
 738              HAVE_DV1394=yes
 739              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 740              DV1394_CFLAGS="$RAW1394_CFLAGS"
 741              if test x$HAVE_LIBIEC61883 = xyes; then
 742                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 743                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 744              fi
 745              AC_SUBST(DV1394_CFLAGS)
 746              AC_SUBST(DV1394_LIBS)
 747            fi
 748          fi
 749   fi
 750 ])
 751 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 752
 753 dnl *** shout2 ***
 754 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 755 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 756   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 757 ])
 758
 759 dnl *** soup ***
 760 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 761 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 762   PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.48, [HAVE_SOUP="yes"], [HAVE_SOUP="no"])
 763   AC_SUBST(SOUP_CFLAGS)
 764   AC_SUBST(SOUP_LIBS)
 765 ])
 766
 767 dnl *** speex ***
 768 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 769 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 770   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 771 ])
 772
 773 dnl *** taglib ***
 774 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 775 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 776   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 777   if test "x$HAVE_CXX" != "xyes"; then
 778     USE_TAGLIB=false
 779     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 780   else
 781     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 782     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 783         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 784       ], [
 785         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 786     ])
 787     AC_SUBST(TAGLIB_CXXFLAGS)
 788   fi
 789 ])
 790
 791 dnl *** vpx ***
 792 translit(dnm, m, l) AM_CONDITIONAL(USE_VPX, vpx)
 793 AG_GST_CHECK_FEATURE(VPX, [VPX decoder], vpx, [
 794   PKG_CHECK_MODULES(VPX, vpx >= 1.1.0, [HAVE_VPX="yes"], [HAVE_VPX="no"])
 795   HAVE_VP8=no
 796   HAVE_VP9=no
 797
 798   if test $HAVE_VPX = "yes"; then
 799     OLD_LIBS="$LIBS"
 800     OLD_CFLAGS="$CFLAGS"
 801     CFLAGS="$CFLAGS $VPX_CFLAGS"
 802     LIBS="$LIBS $VPX_LIBS"
 803     AC_CHECK_LIB(vpx, vpx_codec_vp8_cx_algo, [
 804       HAVE_VP8=yes
 805       AC_DEFINE(HAVE_VP8_ENCODER, 1, [Defined if the VP8 encoder is available])
 806     ])
 807     AC_CHECK_LIB(vpx, vpx_codec_vp8_dx_algo, [
 808       HAVE_VP8=yes
 809       AC_DEFINE(HAVE_VP8_DECODER, 1, [Defined if the VP8 decoder is available])
 810     ])
 811
 812     PKG_CHECK_MODULES(VPX_130, vpx >= 1.3.0, [
 813       AC_CHECK_LIB(vpx, vpx_codec_vp9_cx_algo, [
 814         HAVE_VP9=yes
 815         AC_DEFINE(HAVE_VP9_ENCODER, 1, [Defined if the VP9 encoder is available])
 816       ])
 817       AC_CHECK_LIB(vpx, vpx_codec_vp9_dx_algo, [
 818         HAVE_VP9=yes
 819         AC_DEFINE(HAVE_VP9_DECODER, 1, [Defined if the VP9 decoder is available])
 820       ])
 821     ], [true])
 822
 823     PKG_CHECK_MODULES(VPX_140, vpx >= 1.4.0, [
 824       AC_DEFINE(HAVE_VPX_1_4, 1, [Defined if the VPX library version is 1.4 or bigger])
 825     ], [true])
 826
 827     LIBS="$OLD_LIBS"
 828     CFLAGS="$OLD_CFLAGS"
 829   fi
 830   AC_SUBST(VPX_LIBS)
 831   AC_SUBST(VPX_CFLAGS)
 832 ])
 833
 834 dnl *** wavpack ***
 835 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 836 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 837   AG_GST_PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.60.0)
 838 ])
 839
 840 dnl *** qtdemux & matroska prefer to have zlib ***
 841 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 842 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 843   AG_GST_CHECK_LIBHEADER(ZLIB,
 844     z, uncompress,, zlib.h, [
 845     HAVE_ZLIB="yes"
 846     ZLIB_LIBS="-lz"
 847     AC_SUBST(ZLIB_LIBS)
 848   ])
 849 ])
 850
 851 dnl *** matroska prefers to have bz2 ***
 852 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 853 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 854   save_LIBS=$LIBS
 855   LIBS="$LIBS -lbz2"
 856   AC_MSG_CHECKING([for BZ2_bzlibVersion in -lbz2])
 857   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <bzlib.h>]], [[const char *version = BZ2_bzlibVersion ();]])],[HAVE_BZ2=yes],[HAVE_BZ2=no])
 858   AC_MSG_RESULT($HAVE_BZ2)
 859   LIBS=$save_LIBS
 860   if test "x$HAVE_BZ2" = "xyes"; then
 861     BZ2_LIBS="-lbz2"
 862   fi
 863   AC_SUBST(BZ2_LIBS)
 864 ])
 865
 866 else
 867
 868 dnl not building plugins with external dependencies,
 869 dnl but we still need to set the conditionals
 870 AM_CONDITIONAL(USE_AALIB, false)
 871 AM_CONDITIONAL(USE_BZ2, false)
 872 AM_CONDITIONAL(USE_CAIRO, false)
 873 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 874 AM_CONDITIONAL(USE_DV1394, false)
 875 AM_CONDITIONAL(USE_FLAC, false)
 876 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 877 AM_CONDITIONAL(USE_JACK, false)
 878 AM_CONDITIONAL(USE_JPEG, false)
 879 AM_CONDITIONAL(USE_LIBCACA, false)
 880 AM_CONDITIONAL(USE_LIBDV, false)
 881 AM_CONDITIONAL(USE_LIBIEC61883, false)
 882 AM_CONDITIONAL(USE_LIBPNG, false)
 883 AM_CONDITIONAL(USE_OSS, false)
 884 AM_CONDITIONAL(USE_OSS4, false)
 885 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 886 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 887 AM_CONDITIONAL(USE_PULSE, false)
 888 AM_CONDITIONAL(USE_SHOUT2, false)
 889 AM_CONDITIONAL(USE_SOUP, false)
 890 AM_CONDITIONAL(USE_SPEEX, false)
 891 AM_CONDITIONAL(USE_SUNAUDIO, false)
 892 AM_CONDITIONAL(USE_TAGLIB, false)
 893 AM_CONDITIONAL(USE_VPX, false)
 894 AM_CONDITIONAL(USE_WAVEFORM, false)
 895 AM_CONDITIONAL(USE_WAVPACK, false)
 896 AM_CONDITIONAL(USE_X, false)
 897 AM_CONDITIONAL(USE_ZLIB, false)
 898
 899 fi dnl of EXT plugins
 900
 901 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 902
 903 dnl Overview:
 904 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 905 dnl GST_*:              flags shared by all built objects
 906 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 907 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 908 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 909 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 910
 911 dnl GST_OPTION_CFLAGS
 912 if test "x$USE_DEBUG" = xyes; then
 913    PROFILE_CFLAGS="-g"
 914 fi
 915 AC_SUBST(PROFILE_CFLAGS)
 916
 917 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 918   dnl Define _only_ for git (not pre-releases or releases)
 919   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 920 else
 921   DEPRECATED_CFLAGS=""
 922 fi
 923 AC_SUBST(DEPRECATED_CFLAGS)
 924
 925 dnl every flag in GST_OPTION_CFLAGS, GST_OPTION_CXXFLAGS and GST_OPTION_OBJCFLAGS can be overridden
 926 dnl at make time with e.g. make ERROR_CFLAGS=""
 927 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 928 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 929 GST_OPTION_OBJCFLAGS="\$(WARNING_OBJCFLAGS) \$(ERROR_OBJCFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 930 AC_SUBST(GST_OPTION_CFLAGS)
 931 AC_SUBST(GST_OPTION_CXXFLAGS)
 932 AC_SUBST(GST_OPTION_OBJCFLAGS)
 933
 934 dnl our libraries need to be versioned correctly
 935 AC_SUBST(GST_LT_LDFLAGS)
 936
 937 dnl FIXME: do we want to rename to GST_ALL_* ?
 938 dnl prefer internal headers to already installed ones
 939 dnl also add builddir include for enumtypes and marshal
 940 dnl add ERROR_CFLAGS, but overridable
 941 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
 942 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 943 GST_OBJCFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_OBJCFLAGS)"
 944 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 945 AC_SUBST(GST_CFLAGS)
 946 AC_SUBST(GST_CXXFLAGS)
 947 AC_SUBST(GST_OBJCFLAGS)
 948 AC_SUBST(GST_LIBS)
 949
 950 dnl LDFLAGS really should only contain flags, not libs - they get added before
 951 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 952 GST_ALL_LDFLAGS="-no-undefined"
 953 if test "x${enable_Bsymbolic}" = "xyes"; then
 954   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 955 fi
 956 AC_SUBST(GST_ALL_LDFLAGS)
 957
 958 dnl this really should only contain flags, not libs - they get added before
 959 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 960 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 961 AC_SUBST(GST_PLUGIN_LDFLAGS)
 962
 963 dnl *** output files ***
 964
 965 $MKDIR_P tests/check/orc
 966
 967 dnl keep this alphabetic per directory, please
 968 AC_CONFIG_FILES(
 969 Makefile
 970 gst/Makefile
 971 gst/alpha/Makefile
 972 gst/apetag/Makefile
 973 gst/audiofx/Makefile
 974 gst/audioparsers/Makefile
 975 gst/auparse/Makefile
 976 gst/autodetect/Makefile
 977 gst/avi/Makefile
 978 gst/cutter/Makefile
 979 gst/deinterlace/Makefile
 980 gst/dtmf/Makefile
 981 gst/debugutils/Makefile
 982 gst/effectv/Makefile
 983 gst/equalizer/Makefile
 984 gst/flv/Makefile
 985 gst/goom/Makefile
 986 gst/goom2k1/Makefile
 987 gst/id3demux/Makefile
 988 gst/icydemux/Makefile
 989 gst/imagefreeze/Makefile
 990 gst/interleave/Makefile
 991 gst/isomp4/Makefile
 992 gst/law/Makefile
 993 gst/level/Makefile
 994 gst/matroska/Makefile
 995 gst/monoscope/Makefile
 996 gst/multifile/Makefile
 997 gst/multipart/Makefile
 998 gst/replaygain/Makefile
 999 gst/rtp/Makefile
1000 gst/rtpmanager/Makefile
1001 gst/rtsp/Makefile
1002 gst/shapewipe/Makefile
1003 gst/smpte/Makefile
1004 gst/spectrum/Makefile
1005 gst/udp/Makefile
1006 gst/videobox/Makefile
1007 gst/videocrop/Makefile
1008 gst/videofilter/Makefile
1009 gst/videomixer/Makefile
1010 gst/wavenc/Makefile
1011 gst/wavparse/Makefile
1012 gst/flx/Makefile
1013 gst/y4m/Makefile
1014 ext/Makefile
1015 ext/aalib/Makefile
1016 ext/cairo/Makefile
1017 ext/dv/Makefile
1018 ext/flac/Makefile
1019 ext/gdk_pixbuf/Makefile
1020 ext/jack/Makefile
1021 ext/jpeg/Makefile
1022 ext/libcaca/Makefile
1023 ext/libpng/Makefile
1024 ext/pulse/Makefile
1025 ext/raw1394/Makefile
1026 ext/shout2/Makefile
1027 ext/soup/Makefile
1028 ext/speex/Makefile
1029 ext/taglib/Makefile
1030 ext/vpx/Makefile
1031 ext/wavpack/Makefile
1032 sys/Makefile
1033 sys/directsound/Makefile
1034 sys/oss/Makefile
1035 sys/oss4/Makefile
1036 sys/osxaudio/Makefile
1037 sys/osxvideo/Makefile
1038 sys/sunaudio/Makefile
1039 sys/v4l2/Makefile
1040 sys/waveform/Makefile
1041 sys/ximage/Makefile
1042 po/Makefile.in
1043 tests/Makefile
1044 tests/check/Makefile
1045 tests/examples/Makefile
1046 tests/examples/audiofx/Makefile
1047 tests/examples/cairo/Makefile
1048 tests/examples/equalizer/Makefile
1049 tests/examples/jack/Makefile
1050 tests/examples/level/Makefile
1051 tests/examples/rtp/Makefile
1052 tests/examples/shapewipe/Makefile
1053 tests/examples/spectrum/Makefile
1054 tests/examples/v4l2/Makefile
1055 tests/files/Makefile
1056 tests/icles/Makefile
1057 common/Makefile
1058 common/m4/Makefile
1059 m4/Makefile
1060 docs/Makefile
1061 docs/plugins/Makefile
1062 docs/version.entities
1063 pkgconfig/Makefile
1064 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1065 )
1066 AC_OUTPUT
1067
1068 AG_GST_OUTPUT_PLUGINS
1069 ORC_OUTPUT
1070