configure.ac

   1 AC_PREREQ(2.60)
   2 AC_INIT([kmod],
   3         [4],
   4         [linux-modules@vger.kernel.org],
   5         [kmod],
   6         [http://git.profusion.mobi/cgit.cgi/kmod.git/])
   7
   8 AC_CONFIG_SRCDIR([libkmod/libkmod.c])
   9 AC_CONFIG_AUX_DIR([build-aux])
  10 AM_INIT_AUTOMAKE([check-news foreign 1.11 silent-rules
  11         tar-pax no-dist-gzip dist-xz subdir-objects])
  12 AC_PROG_CC_STDC
  13 AC_USE_SYSTEM_EXTENSIONS
  14 AC_SYS_LARGEFILE
  15 AC_CONFIG_MACRO_DIR([m4])
  16 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  17 AM_SILENT_RULES([yes])
  18 LT_INIT([disable-static pic-only])
  19 AC_PREFIX_DEFAULT([/usr])
  20
  21 AC_PROG_CC
  22 AC_PROG_CC_C99
  23 AC_C_TYPEOF
  24 AM_PROG_CC_C_O
  25 AC_PROG_GCC_TRADITIONAL
  26 AC_C_BIGENDIAN
  27
  28 AC_PROG_SED
  29 AC_PROG_MKDIR_P
  30 AC_PATH_PROG([XSLTPROC], [xsltproc])
  31 PKG_PROG_PKG_CONFIG
  32
  33 AC_ARG_WITH([rootprefix],
  34         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
  35         [], [with_rootprefix=""])
  36 AC_SUBST([rootprefix], [$with_rootprefix])
  37
  38 AC_ARG_WITH([rootlibdir],
  39         AS_HELP_STRING([--with-rootlibdir=DIR], [rootfs directory to install shared libraries]),
  40         [], [with_rootlibdir=$libdir])
  41 AC_SUBST([rootlibdir], [$with_rootlibdir])
  42
  43 AC_ARG_ENABLE([tools],
  44         AS_HELP_STRING([--disable-tools], [disable building tools that provide same functionality as module-init-tools @<:@default=enabled@:>@]),
  45         [], enable_tools=yes)
  46 AM_CONDITIONAL([BUILD_TOOLS], [test "x$enable_tools" = "xyes"])
  47
  48 AC_ARG_ENABLE([logging],
  49         AS_HELP_STRING([--disable-logging], [disable system logging @<:@default=enabled@:>@]),
  50         [], enable_logging=yes)
  51 AS_IF([test "x$enable_logging" = "xyes"], [
  52         AC_DEFINE(ENABLE_LOGGING, [1], [System logging.])
  53 ])
  54
  55 AC_ARG_WITH([xz],
  56         AS_HELP_STRING([--with-xz], [handle Xz-compressed modules @<:@default=disabled@:>@]),
  57         [], [with_xz=no])
  58 AS_IF([test "x$with_xz" != "xno"], [
  59         PKG_CHECK_MODULES([liblzma], [liblzma >= 4.99])
  60         AC_DEFINE([ENABLE_XZ], [1], [Enable Xz for modules.])
  61 ], [
  62         AC_MSG_NOTICE([Xz support not requested])
  63 ])
  64
  65 AC_ARG_WITH([zlib],
  66         AS_HELP_STRING([--with-zlib], [handle gzipped modules @<:@default=disabled@:>@]),
  67         [], [with_zlib=no])
  68 AS_IF([test "x$with_zlib" != "xno"], [
  69         PKG_CHECK_MODULES([zlib], [zlib])
  70         AC_DEFINE([ENABLE_ZLIB], [1], [Enable zlib for modules.])
  71 ], [
  72         AC_MSG_NOTICE([zlib support not requested])
  73 ])
  74
  75 AC_ARG_ENABLE([debug],
  76         AS_HELP_STRING([--enable-debug], [enable debug messages @<:@default=disabled@:>@]),
  77         [], [enable_debug=no])
  78 AS_IF([test "x$enable_debug" = "xyes"], [
  79         AC_DEFINE(ENABLE_DEBUG, [1], [Debug messages.])
  80 ])
  81
  82 CC_CHECK_CFLAGS_APPEND([ \
  83                         -pipe \
  84                         -DANOTHER_BRICK_IN_THE \
  85                         -Wall \
  86                         -W \
  87                         -Wextra \
  88                         -Wno-inline \
  89                         -Wvla \
  90                         -Wundef \
  91                         -Wformat=2 \
  92                         -Wlogical-op \
  93                         -Wsign-compare \
  94                         -Wformat-security \
  95                         -Wmissing-include-dirs \
  96                         -Wformat-nonliteral \
  97                         -Wold-style-definition \
  98                         -Wpointer-arith \
  99                         -Winit-self \
 100                         -Wdeclaration-after-statement \
 101                         -Wfloat-equal \
 102                         -Wmissing-prototypes \
 103                         -Wstrict-prototypes \
 104                         -Wredundant-decls \
 105                         -Wmissing-declarations \
 106                         -Wmissing-noreturn \
 107                         -Wshadow \
 108                         -Wendif-labels \
 109                         -Wstrict-aliasing=2 \
 110                         -Wwrite-strings \
 111                         -Wno-long-long \
 112                         -Wno-overlength-strings \
 113                         -Wno-unused-parameter \
 114                         -Wno-missing-field-initializers \
 115                         -Wno-unused-result \
 116                         -Wnested-externs \
 117                         -Wchar-subscripts \
 118                         -Wtype-limits \
 119                         -Wuninitialized \
 120                         -fno-common \
 121                         -fdiagnostics-show-option \
 122                         -fvisibility=hidden \
 123                         -ffunction-sections \
 124                         -fdata-sections \
 125                         -Wl,--as-needed \
 126                         -Wl,--gc-sections])
 127
 128
 129 AC_CONFIG_HEADERS(config.h)
 130 AC_CONFIG_FILES([
 131         Makefile
 132         man/Makefile
 133         libkmod/docs/Makefile
 134         libkmod/docs/version.xml
 135 ])
 136
 137 m4_ifdef([GTK_DOC_CHECK], [
 138 GTK_DOC_CHECK([1.14],[--flavour no-tmpl-flat])
 139 ], [
 140 AM_CONDITIONAL([ENABLE_GTK_DOC], false)])
 141
 142 AC_OUTPUT
 143 AC_MSG_RESULT([
 144         $PACKAGE $VERSION
 145         ======
 146
 147         prefix:                 ${prefix}
 148         rootprefix:             ${rootprefix}
 149         sysconfdir:             ${sysconfdir}
 150         libdir:                 ${libdir}
 151         rootlibdir:             ${rootlibdir}
 152         includedir:             ${includedir}
 153         bindir:                 ${bindir}
 154
 155         compiler:               ${CC}
 156         cflags:                 ${CFLAGS}
 157         ldflags:                ${LDFLAGS}
 158
 159         tools:                  ${enable_tools}
 160         logging:                ${enable_logging}
 161         compression:            xz=${with_xz}  zlib=${with_zlib}
 162         debug:                  ${enable_debug}
 163         doc:                    ${enable_gtk_doc}
 164 ])