configure.ac

   1 AC_INIT([libusb], [1.0.1])
   2 AM_INIT_AUTOMAKE
   3 AC_CONFIG_SRCDIR([libusb/core.c])
   4 AM_CONFIG_HEADER([config.h])
   5
   6 AC_PREREQ([2.50])
   7 AC_PROG_CC
   8 AC_PROG_LIBTOOL
   9 AC_C_INLINE
  10 AM_PROG_CC_C_O
  11 AC_DEFINE([_GNU_SOURCE], [], [Use GNU extensions])
  12
  13 AC_MSG_CHECKING([operating system])
  14 case $host in
  15 *-linux*)
  16         AC_DEFINE(OS_LINUX, [], [Linux backend])
  17         AC_SUBST(OS_LINUX)
  18         AC_MSG_RESULT([Linux])
  19         backend="linux"
  20         AC_CHECK_LIB(rt, clock_gettime)
  21         AM_LDFLAGS=""
  22         ;;
  23 *-darwin*)
  24         AC_DEFINE(OS_DARWIN, [], [Darwin backend])
  25         AC_SUBST(OS_DARWIN)
  26         AC_MSG_RESULT([Darwin/MacOS X])
  27         backend="darwin"
  28         AM_LDFLAGS="-Wl,-framework -Wl,IOKit -Wl,-framework -Wl,CoreFoundation -Wl,-prebind -no-undefined"
  29         ;;
  30 *)
  31         AC_MSG_ERROR([unsupported operating system])
  32 esac
  33
  34 AM_CONDITIONAL([OS_LINUX], [test "x$backend" == "xlinux"])
  35 AM_CONDITIONAL([OS_DARWIN], [test "x$backend" == "xdarwin"])
  36
  37 # Library versioning
  38 lt_major="0"
  39 lt_revision="0"
  40 lt_age="0"
  41 AC_SUBST(lt_major)
  42 AC_SUBST(lt_revision)
  43 AC_SUBST(lt_age)
  44
  45 # Message logging
  46 AC_ARG_ENABLE([log], [AS_HELP_STRING([--disable-log], [disable all logging])],
  47         [log_enabled=$enableval],
  48         [log_enabled='yes'])
  49 if test "x$log_enabled" != "xno"; then
  50         AC_DEFINE([ENABLE_LOGGING], 1, [Message logging])
  51 fi
  52
  53 AC_ARG_ENABLE([debug-log], [AS_HELP_STRING([--enable-debug-log],
  54         [enable debug logging (default n)])],
  55         [debug_log_enabled=$enableval],
  56         [debug_log_enabled='no'])
  57 if test "x$debug_log_enabled" != "xno"; then
  58         AC_DEFINE([ENABLE_DEBUG_LOGGING], 1, [Debug message logging])
  59 fi
  60
  61 # Examples build
  62 AC_ARG_ENABLE([examples-build], [AS_HELP_STRING([--enable-examples-build],
  63         [build example applications (default n)])],
  64         [build_examples=$enableval],
  65         [build_examples='no'])
  66 AM_CONDITIONAL([BUILD_EXAMPLES], [test "x$build_examples" != "xno"])
  67
  68 # Restore gnu89 inline semantics on gcc 4.3 and newer
  69 saved_cflags="$CFLAGS"
  70 CFLAGS="$CFLAGS -fgnu89-inline"
  71 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]), inline_cflags="-fgnu89-inline", inline_cflags="")
  72 CFLAGS="$saved_cflags"
  73
  74 # check for -fvisibility=hidden compiler support (GCC >= 3.4)
  75 saved_cflags="$CFLAGS"
  76 CFLAGS="$CFLAGS -fvisibility=hidden"
  77 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
  78         [VISIBILITY_CFLAGS="-fvisibility=hidden"
  79          AC_DEFINE([API_EXPORTED], [__attribute__((visibility("default")))], [Default visibility]) ],
  80         [ VISIBILITY_CFLAGS=""
  81          AC_DEFINE([API_EXPORTED], [], [Default visibility]) ],
  82         ])
  83 CFLAGS="$saved_cflags"
  84
  85 # check for -Wno-pointer-sign compiler support (GCC >= 4)
  86 saved_cflags="$CFLAGS"
  87 CFLAGS="$CFLAGS -Wno-pointer-sign"
  88 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
  89         nopointersign_cflags="-Wno-pointer-sign", nopointersign_cflags="")
  90 CFLAGS="$saved_cflags"
  91
  92 AM_CFLAGS="-std=gnu99 $inline_cflags -Wall -Wundef -Wunused -Wstrict-prototypes -Werror-implicit-function-declaration $nopointersign_cflags -Wshadow"
  93
  94 AC_SUBST(VISIBILITY_CFLAGS)
  95 AC_SUBST(AM_CFLAGS)
  96 AC_SUBST(AM_LDFLAGS)
  97
  98 AC_CONFIG_FILES([libusb-1.0.pc] [Makefile] [libusb/Makefile] [examples/Makefile] [doc/Makefile] [doc/doxygen.cfg])
  99 AC_OUTPUT
 100