configure.ac

   1 # get rid of that stupid cache mechanism
   2 rm -f config.cache
   3
   4 AC_INIT([ecore], [0.9.9.062], [enlightenment-devel@lists.sourceforge.net])
   5 AC_PREREQ([2.52])
   6 AC_CONFIG_SRCDIR([configure.ac])
   7 AC_CONFIG_MACRO_DIR([m4])
   8 AC_CANONICAL_BUILD
   9 AC_CANONICAL_HOST
  10 AC_ISC_POSIX
  11
  12 AM_INIT_AUTOMAKE(1.6 dist-bzip2)
  13 AM_CONFIG_HEADER(config.h)
  14 AC_GNU_SOURCE
  15
  16 AC_LIBTOOL_WIN32_DLL
  17 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  18 AC_PROG_LIBTOOL
  19
  20 VMAJ=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $1);}'`
  21 VMIN=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $2);}'`
  22 VMIC=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $3);}'`
  23 SNAP=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $4);}'`
  24 version_info=`expr $VMAJ + $VMIN`":$VMIC:$VMIN"
  25 AC_SUBST(version_info)
  26
  27 release="ver-pre-svn-04"
  28 case "$host_os" in
  29    mingw32ce* | cegcc*)
  30       ;;
  31    *)
  32       ecore_config_release_info="-release $release"
  33       ecore_con_release_info="-release $release"
  34       ecore_directfb_release_info="-release $release"
  35       ecore_evas_release_info="-release $release"
  36       ecore_fb_release_info="-release $release"
  37       ecore_file_release_info="-release $release"
  38       ecore_imf_evas_release_info="-release $release"
  39       ecore_imf_release_info="-release $release"
  40       ecore_input_release_info="-release $release"
  41       ecore_ipc_release_info="-release $release"
  42       ecore_job_release_info="-release $release"
  43       ecore_quartz_release_info="-release $release"
  44       ecore_release_info="-release $release"
  45       ecore_sdl_release_info="-release $release"
  46       ecore_txt_release_info="-release $release"
  47       ecore_win32_release_info="-release $release"
  48       ecore_x_release_info="-release $release"
  49       ;;
  50 esac
  51 AC_SUBST(ecore_config_release_info)
  52 AC_SUBST(ecore_con_release_info)
  53 AC_SUBST(ecore_directfb_release_info)
  54 AC_SUBST(ecore_evas_release_info)
  55 AC_SUBST(ecore_fb_release_info)
  56 AC_SUBST(ecore_file_release_info)
  57 AC_SUBST(ecore_imf_evas_release_info)
  58 AC_SUBST(ecore_imf_release_info)
  59 AC_SUBST(ecore_input_release_info)
  60 AC_SUBST(ecore_ipc_release_info)
  61 AC_SUBST(ecore_job_release_info)
  62 AC_SUBST(ecore_quartz_release_info)
  63 AC_SUBST(ecore_release_info)
  64 AC_SUBST(ecore_sdl_release_info)
  65 AC_SUBST(ecore_txt_release_info)
  66 AC_SUBST(ecore_win32_release_info)
  67 AC_SUBST(ecore_wince_release_info)
  68 AC_SUBST(ecore_x_release_info)
  69
  70 AC_DEFINE_UNQUOTED(SHARED_LIB_SUFFIX, "$shrext_cmds", [Suffix for shared objects])
  71
  72
  73 ### Default options with respect to host
  74
  75 # dependencies and options
  76 want_curl="no"
  77 want_abstract_sockets="no"
  78 want_gnutls="no"
  79 want_openssl="no"
  80 want_cipher="no"
  81 want_signature="no"
  82 want_poll="yes"
  83 want_inotify="no"
  84 want_tslib="no"
  85
  86 # core modules
  87 want_ecore_job="yes"
  88 want_ecore_txt="yes"
  89 want_ecore_con="no"
  90 want_ecore_ipc="no"
  91 want_ecore_file="yes"
  92 want_ecore_config="no"
  93 want_ecore_imf="no"
  94 want_ecore_input="yes"
  95
  96 # graphic system modules
  97 want_evas_simple_x11="no"
  98 want_ecore_x_xcb="no"
  99 want_ecore_x="no"
 100 want_ecore_win32="no"
 101 want_ecore_quartz="no"
 102 want_ecore_sdl="no"
 103 want_ecore_fb="no"
 104 want_ecore_directfb="no"
 105 want_ecore_wince="no"
 106
 107 # ecore_evas modules
 108 want_ecore_evas="yes"
 109 want_ecore_evas_software_buffer="yes"
 110 want_ecore_evas_software_x11="no"
 111 want_ecore_evas_xrender_x11="no"
 112 want_ecore_evas_opengl_x11="no"
 113 want_ecore_evas_software_16_x11="no"
 114 want_ecore_evas_software_xcb="no"
 115 want_ecore_evas_xrender_xcb="no"
 116 want_ecore_evas_software_gdi="no"
 117 want_ecore_evas_software_ddraw="no"
 118 want_ecore_evas_direct3d="no"
 119 want_ecore_evas_opengl_glew="no"
 120 want_ecore_evas_software_16_ddraw="no"
 121 want_ecore_evas_quartz="no"
 122 want_ecore_evas_software_sdl="no"
 123 want_ecore_evas_directfb="no"
 124 want_ecore_evas_fb="no"
 125 want_ecore_evas_software_16_wince="no"
 126
 127 case "$host_os" in
 128    mingw32ce* | cegcc*)
 129       want_ecore_wince="yes"
 130       want_ecore_evas_software_16_wince="yes"
 131       ;;
 132    mingw*)
 133       want_curl="yes"
 134       want_ecore_imf="yes"
 135       want_ecore_win32="yes"
 136       want_ecore_evas_software_gdi="yes"
 137       want_ecore_evas_software_ddraw="yes"
 138       want_ecore_evas_direct3d="yes"
 139       want_ecore_evas_opengl_glew="yes"
 140       want_ecore_evas_software_16_ddraw="auto"
 141       want_ecore_evas_software_sdl="yes"
 142       ;;
 143    darwin*)
 144       want_curl="yes"
 145       want_gnutls="auto"
 146       want_openssl="auto"
 147       want_ecore_con="yes"
 148       want_ecore_ipc="yes"
 149       want_ecore_config="yes"
 150       want_ecore_imf="yes"
 151       want_ecore_quartz="yes"
 152       want_ecore_evas_quartz="yes"
 153       want_ecore_evas_software_sdl="yes"
 154       ;;
 155    *)
 156       want_curl="yes"
 157       want_abstract_sockets="yes"
 158       want_gnutls="auto"
 159       want_openssl="auto"
 160       want_cipher="yes"
 161       want_signature="yes"
 162       want_inotify="yes"
 163       want_tslib="yes"
 164       want_ecore_con="yes"
 165       want_ecore_ipc="yes"
 166       want_ecore_config="yes"
 167       want_ecore_imf="yes"
 168       want_ecore_x="yes"
 169       want_ecore_evas_software_x11="yes"
 170       want_ecore_evas_xrender_x11="yes"
 171       want_ecore_evas_opengl_x11="yes"
 172       want_ecore_evas_software_16_x11="yes"
 173       want_ecore_evas_software_xcb="yes"
 174       want_ecore_evas_xrender_xcb="yes"
 175       want_ecore_evas_software_sdl="yes"
 176       want_ecore_evas_directfb="yes"
 177       want_ecore_evas_fb="yes"
 178       ;;
 179 esac
 180
 181 requirements_ecore=""
 182 requirements_ecore_con=""
 183 requirements_ecore_config=""
 184 requirements_ecore_directfb=""
 185 requirements_ecore_evas=""
 186 requirements_ecore_fb=""
 187 requirements_ecore_file=""
 188 requirements_ecore_imf=""
 189 requirements_ecore_imf_evas=""
 190 requirements_ecore_input=""
 191 requirements_ecore_ipc=""
 192 requirements_ecore_job=""
 193 requirements_ecore_quartz=""
 194 requirements_ecore_sdl=""
 195 requirements_ecore_txt=""
 196 requirements_ecore_x=""
 197 requirements_ecore_win32=""
 198 requirements_ecore_wince=""
 199
 200 ### Additional options to configure
 201
 202 # abstract sockets (ecore_con.c)
 203 AC_ARG_ENABLE([abstract-sockets],
 204    [AC_HELP_STRING([--disable-abstract-sockets], [disable abstract sockets.])],
 205    [
 206     if test "x${enableval}" = "xyes" ; then
 207        want_abstract_sockets="yes"
 208     else
 209        want_abstract_sockets="no"
 210     fi
 211    ],
 212    [want_abstract_sockets="yes"])
 213
 214 if test "x${want_abstract_sockets}" = "xyes" ; then
 215    AC_DEFINE([HAVE_ABSTRACT_SOCKETS], [1], [Have abstract sockets namespace])
 216 fi
 217
 218 # Simple X11 build/link
 219
 220 AC_ARG_ENABLE(simple-x11,
 221   AC_HELP_STRING([--enable-simple-x11], [enable simple x11 linking]),
 222   [want_evas_simple_x11=$enableval])
 223
 224
 225 ### Checks for programs
 226
 227 m4_ifdef([AC_PROG_OBJC],
 228    [
 229     AC_PROG_OBJC
 230     _AM_DEPENDENCIES(OBJC)
 231    ],
 232    [
 233     AC_CHECK_TOOL([OBJC], [gcc])
 234     AC_SUBST([OBJC])
 235     AC_SUBST([OBJCFLAGS])
 236    ])
 237 AC_PROG_CXX
 238 AC_PROG_CC
 239
 240 have_gnu_objc=${ac_cv_objc_compiler_gnu}
 241
 242 # doxygen program for documentation building
 243
 244 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 245
 246 # The first call to PKG_CHECK_MODULES is done conditionally,
 247 # so we should include this here:
 248 PKG_PROG_PKG_CONFIG
 249
 250
 251 ### Checks for libraries
 252
 253 # Evil library for compilation on Windows
 254
 255 case "$host_os" in
 256    mingw* | cegcc*)
 257       PKG_CHECK_MODULES([EVIL], [evil])
 258       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if Evil library is installed])
 259       requirements_ecore="evil ${requirements_ecore}"
 260       requirements_ecore_evas="evil ${requirements_ecore_evas}"
 261       requirements_ecore_file="evil ${requirements_ecore_file}"
 262       requirements_ecore_imf="evil ${requirements_ecore_imf}"
 263       requirements_ecore_imf_evas="evil ${requirements_ecore_imf_evas}"
 264       requirements_ecore_job="evil ${requirements_ecore_job}"
 265       requirements_ecore_txt="evil ${requirements_ecore_txt}"
 266       EFL_ECORE_BUILD="-DEFL_ECORE_BUILD"
 267       EFL_ECORE_JOB_BUILD="-DEFL_ECORE_JOB_BUILD"
 268       EFL_ECORE_TXT_BUILD="-DEFL_ECORE_TXT_BUILD"
 269       EFL_ECORE_FILE_BUILD="-DEFL_ECORE_FILE_BUILD"
 270       EFL_ECORE_EVAS_BUILD="-DEFL_ECORE_EVAS_BUILD"
 271       EFL_ECORE_IMF_BUILD="-DEFL_ECORE_IMF_BUILD"
 272       EFL_ECORE_INPUT_BUILD="-DEFL_ECORE_INPUT_BUILD"
 273       ;;
 274 esac
 275
 276 have_win32=""
 277 have_wince=""
 278 case "$host_os" in
 279    mingw32ce* | cegcc*)
 280       EFL_ECORE_WINCE_BUILD="-DEFL_ECORE_WINCE_BUILD"
 281       requirements_ecore_wince="evil ${requirements_ecore_wince}"
 282       have_wince="yes"
 283       ;;
 284    mingw*)
 285       EFL_ECORE_WIN32_BUILD="-DEFL_ECORE_WIN32_BUILD"
 286       EFL_ECORE_SDL_BUILD="-DEFL_ECORE_SDL_BUILD"
 287       requirements_ecore_win32="evil ${requirements_ecore_win32}"
 288       requirements_ecore_sdl="evil ${requirements_ecore_sdl}"
 289       have_win32="yes"
 290       ;;
 291 esac
 292
 293 AC_SUBST(EFL_ECORE_BUILD)
 294 AC_SUBST(EFL_ECORE_JOB_BUILD)
 295 AC_SUBST(EFL_ECORE_TXT_BUILD)
 296 AC_SUBST(EFL_ECORE_FILE_BUILD)
 297 AC_SUBST(EFL_ECORE_EVAS_BUILD)
 298 AC_SUBST(EFL_ECORE_IMF_BUILD)
 299 AC_SUBST(EFL_ECORE_INPUT_BUILD)
 300 AC_SUBST(EFL_ECORE_WINCE_BUILD)
 301 AC_SUBST(EFL_ECORE_WIN32_BUILD)
 302 AC_SUBST(EFL_ECORE_SDL_BUILD)
 303
 304 AM_CONDITIONAL(ECORE_HAVE_WINCE, test "x${have_wince}" = "xyes")
 305 AM_CONDITIONAL(ECORE_HAVE_WIN32, test "x${have_win32}" = "xyes")
 306
 307 WIN32_LIBS=""
 308 case "$host_os" in
 309    mingw32ce* | cegcc*)
 310       WIN32_LIBS="-lws2"
 311       dlopen_libs="-ldl"
 312       ;;
 313    mingw*)
 314       WIN32_LIBS="-lws2_32"
 315       dlopen_libs="-ldl"
 316       ;;
 317    *)
 318       AC_CHECK_LIB(dl, dlopen, dlopen_libs=-ldl)
 319       ;;
 320 esac
 321 AC_SUBST(WIN32_LIBS)
 322 AC_SUBST(dlopen_libs)
 323
 324 # Eina library
 325
 326 PKG_CHECK_MODULES(EINA, [eina-0])
 327 #FIXME check all the requirements when the eina move will be finished
 328 requirements_ecore="eina-0 ${requirements_ecore}"
 329 requirements_ecore_con="ecore eina-0 ${requirements_ecore_con}"
 330 requirements_ecore_config="ecore eina-0 ${requirements_ecore_config}"
 331 requirements_ecore_directfb="ecore eina-0 ${requirements_ecore_directfb}"
 332 requirements_ecore_evas="ecore eina-0 ${requirements_ecore_evas}"
 333 requirements_ecore_fb="ecore eina-0 ${requirements_ecore_fb}"
 334 requirements_ecore_file="ecore eina-0 ${requirements_ecore_file}"
 335 requirements_ecore_imf="ecore eina-0 ${requirements_ecore_imf}"
 336 requirements_ecore_imf_evas="ecore eina-0 ${requirements_ecore_imf_evas}"
 337 requirements_ecore_input="ecore eina-0 ${requirements_ecore_input}"
 338 requirements_ecore_ipc="ecore eina-0 ${requirements_ecore_ipc}"
 339 requirements_ecore_job="ecore eina-0 ${requirements_ecore_job}"
 340 requirements_ecore_quartz="ecore eina-0 ${requirements_ecore_quartz}"
 341 requirements_ecore_sdl="ecore eina-0 ${requirements_ecore_sdl}"
 342 requirements_ecore_x="ecore eina-0 ${requirements_ecore_x}"
 343 requirements_ecore_win32="ecore eina-0 ${requirements_ecore_win32}"
 344 requirements_ecore_wince="ecore eina-0 ${requirements_ecore_wince}"
 345
 346
 347 # iconv library (ecore_txt)
 348
 349 iconv_cflags=""
 350 iconv_libs=""
 351 have_iconv="no"
 352 AC_ARG_WITH([iconv-link],
 353    AC_HELP_STRING([--with-iconv-link=ICONV_LINK], [explicitly specify an iconv link option]),
 354    [
 355     iconv_libs=$withval
 356     have_iconv="yes"
 357    ]
 358 )
 359
 360 if test "x${have_iconv}" = "xno" ; then
 361    AC_CHECK_LIB(c, iconv,
 362       [have_iconv="yes"]   )
 363
 364    if ! test "x${have_iconv}" = "xyes" ; then
 365       AC_CHECK_LIB(iconv, iconv,
 366          [
 367           iconv_libs="-liconv"
 368           have_iconv="yes"
 369          ])
 370    fi
 371
 372    if test "x$have_iconv" != "xyes"; then
 373       AC_CHECK_LIB(iconv_plug, iconv,
 374          [
 375           iconv_libs="-liconv -liconv_plug"
 376           have_iconv="yes"
 377          ])
 378    fi
 379
 380 # force the iconv library on mac os x
 381    case "$host_os" in
 382       darwin*)
 383          iconv_libs="/usr/lib/libiconv.la"
 384          have_iconv="yes"
 385       ;;
 386    esac
 387 fi
 388 AC_MSG_CHECKING(for explicit iconv link options)
 389 AC_MSG_RESULT($iconv_libs)
 390
 391 AC_SUBST(iconv_cflags)
 392 AC_SUBST(iconv_libs)
 393
 394
 395 # SDL library (ecore_sdl)
 396
 397 have_sdl="no"
 398 SDL_CONFIG="sdl-config"
 399 AC_ARG_WITH([sdl-config],
 400    [AC_HELP_STRING([--with-sdl-config=PATH], [use sdl-config specified])],
 401    [
 402     SDL_CONFIG=$withval
 403     AC_MSG_NOTICE([using ${SDL_CONFIG} for sdl-config])
 404    ])
 405
 406 AC_PATH_PROG([SDL_CONFIG], ["sdl-config"], [""], [$PATH])
 407
 408 if test -z "$SDL_CONFIG" ; then
 409    SDL_CFLAGS=`$SDL_CONFIG --cflags`
 410    SDL_LIBS=`$SDL_CONFIG --libs`
 411    AC_SUBST(SDL_CFLAGS)
 412    AC_SUBST(SDL_LIBS)
 413    have_sdl="no"
 414 else
 415    PKG_CHECK_MODULES([SDL], [sdl >= 1.2.0], [have_sdl="yes"], [have_sdl="no"])
 416 fi
 417
 418 if test "x${have_sdl}" = "xyes" ; then
 419    PKG_CHECK_EXISTS([sdl >= 1.3.0],
 420       [AC_DEFINE(BUILD_ECORE_EVAS_SDL_130, 1, [Support for SVN SDL])])
 421 fi
 422
 423
 424 # DirectFB library (ecore_directfb)
 425
 426 PKG_CHECK_MODULES([DIRECTFB], [directfb >= 0.9.16],
 427    [
 428     have_directfb="yes"
 429     requirements_ecore_directfb="evas ${requirements_ecore_directfb}"
 430    ],
 431    [have_directfb="no"])
 432
 433
 434 # Eet library (ecore_config)
 435
 436 PKG_CHECK_MODULES(EET, [eet >= 1.0.0],
 437   [ have_eet="yes" ],
 438   [ have_eet="no" ])
 439
 440
 441 # Xlib and XCB (ecore_x)
 442
 443 have_x="no"
 444 have_ecore_x="no"
 445 have_ecore_x_xlib="no"
 446 have_ecore_x_xcb="no"
 447
 448 x_dir="";
 449 x_includes="";
 450 x_cflags="";
 451 x_libs="";
 452
 453 AC_ARG_ENABLE(ecore-x-xcb,
 454    [AC_HELP_STRING([--enable-ecore-x-xcb],
 455        [enable the ecore_x module with XCB backend. [[default=disabled]]])],
 456    [want_ecore_x_xcb=$enableval],
 457    [want_ecore_x_xcb="no"])
 458
 459 AC_MSG_CHECKING(whether ecore_x with XCB backend is to be built)
 460 AC_MSG_RESULT($want_ecore_x_xcb)
 461
 462 if test "x$want_ecore_x_xcb" = "xyes" ; then
 463   PKG_CHECK_MODULES(XCB, xcb xcb-icccm xcb-image xcb-keysyms pixman-1,
 464     [ have_ecore_x_xcb="yes" ],
 465     [ have_ecore_x_xcb="no" ])
 466
 467   if test "x$have_ecore_x_xcb" = "xyes" ; then
 468     PKG_CHECK_MODULES(XCB_COMPOSITE, xcb-composite,
 469       [ have_ecore_x_xcb_composite="yes"
 470         AC_DEFINE(ECORE_XCB_COMPOSITE, 1, [Build support for XCB composite]) ],
 471       [ have_ecore_x_xcb_composite="no" ])
 472
 473     PKG_CHECK_MODULES(XCB_DAMAGE, xcb-damage,
 474       [ have_ecore_x_xcb_damage="yes"
 475         AC_DEFINE(ECORE_XCB_DAMAGE, 1, [Build support for XCB damage]) ],
 476       [ have_ecore_x_xcb_damage="no" ])
 477
 478     PKG_CHECK_MODULES(XCB_DPMS, xcb-dpms,
 479       [ have_ecore_x_xcb_dpms="yes"
 480         AC_DEFINE(ECORE_XCB_DPMS, 1, [Build support for XCB dpms]) ],
 481       [ have_ecore_x_xcb_dpms="no" ])
 482
 483     PKG_CHECK_MODULES(XCB_RANDR, xcb-randr,
 484       [ have_ecore_x_xcb_randr="yes"
 485         AC_DEFINE(ECORE_XCB_RANDR, 1, [Build support for XCB randr]) ],
 486       [ have_ecore_x_xcb_randr="no" ])
 487
 488     PKG_CHECK_MODULES(XCB_RENDER, xcb-render,
 489       [ have_ecore_x_xcb_render="yes"
 490         AC_DEFINE(ECORE_XCB_RENDER, 1, [Build support for XCB render]) ],
 491       [ have_ecore_x_xcb_render="no" ])
 492
 493     PKG_CHECK_MODULES(XCB_SCREENSAVER, xcb-screensaver,
 494       [ have_ecore_x_xcb_screensaver="yes"
 495         AC_DEFINE(ECORE_XCB_SCREENSAVER, 1, [Build support for XCB screensaver]) ],
 496       [ have_ecore_x_xcb_screensaver="no" ])
 497
 498     PKG_CHECK_MODULES(XCB_SHAPE, xcb-shape,
 499       [ have_ecore_x_xcb_shape="yes"
 500         AC_DEFINE(ECORE_XCB_SHAPE, 1, [Build support for XCB shape]) ],
 501       [ have_ecore_x_xcb_shape="no" ])
 502
 503     PKG_CHECK_MODULES(XCB_SYNC, xcb-sync,
 504       [ have_ecore_x_xcb_sync="yes"
 505         AC_DEFINE(ECORE_XCB_SYNC, 1, [Build support for XCB sync]) ],
 506       [ have_ecore_x_xcb_sync="no" ])
 507
 508     PKG_CHECK_MODULES(XCB_XFIXES, xcb-xfixes,
 509       [ have_ecore_x_xcb_xfixes="yes"
 510         AC_DEFINE(ECORE_XCB_FIXES, 1, [Build support for XCB xfixes]) ],
 511       [ have_ecore_x_xcb_xfixes="no" ])
 512
 513     PKG_CHECK_MODULES(XCB_XINERAMA, xcb-xinerama,
 514       [ have_ecore_x_xcb_xinerama="yes"
 515         AC_DEFINE(ECORE_XCB_XINERAMA, 1, [Build support for XCB xinerama]) ],
 516       [ have_ecore_x_xcb_xinerama="no" ])
 517
 518     PKG_CHECK_MODULES(XCB_XPRINT, xcb-xprint,
 519       [ have_ecore_x_xcb_xprint="yes"
 520         AC_DEFINE(ECORE_XCB_XPRINT, 1, [Build support for XCB xprint]) ],
 521       [ have_ecore_x_xcb_xprint="no" ])
 522
 523     PKG_CHECK_MODULES(XCB_XTEST, xcb-xtest,
 524       [ have_ecore_x_xcb_xtest="yes"
 525         AC_DEFINE(ECORE_XCB_XTEST, 1, [Build support for XCB xtest]) ],
 526       [ have_ecore_x_xcb_xtest="no" ])
 527
 528     AC_DEFINE(HAVE_ECORE_X_XCB, 1, [Defined to 1 if XCB is enabled.])
 529
 530     x_cflags=$XCB_CFLAGS
 531     x_libs=$XCB_LIBS
 532     have_x="yes"
 533
 534     have_ecore_x_xcb_define="-DHAVE_ECORE_X_XCB"
 535     AC_SUBST(have_ecore_x_xcb_define)
 536   fi
 537 fi
 538
 539 if ! test "x$have_ecore_x_xcb" = "xyes" ; then
 540   AC_PATH_XTRA
 541   AC_CHECK_HEADER(X11/X.h,
 542     [
 543      if test "x$want_evas_simple_x11" = "xyes"; then
 544        x_libs="${x_libs} -lX11 -lXext"
 545      else
 546        x_dir=${x_dir:-/usr/X11R6}
 547        x_cflags=${x_cflags:--I${x_includes:-$x_dir/include}}
 548        x_libs="${x_libs:--L${x_libraries:-$x_dir/lib}} -lX11 -lXext"
 549      fi
 550      have_ecore_x_xlib="yes"
 551     ]
 552   )
 553
 554   if test "x$have_ecore_x_xlib" = "xyes"; then
 555     Xcursor_libs=""
 556     Xcursor_cflags=""
 557     use_Xcursor="no"
 558     PCFLAGS=$CFLAGS
 559     CFLAGS="$x_cflags $x_includes"
 560     AC_CHECK_HEADER(X11/Xcursor/Xcursor.h,
 561       [
 562         AC_CHECK_LIB(Xcursor, XcursorImageLoadCursor,
 563           [
 564             AC_DEFINE(ECORE_XCURSOR, 1, [Build support for Xcursor])
 565             Xcursor_cflags=""
 566             Xcursor_libs="-lXcursor"
 567             use_Xcursor="yes"
 568           ], [
 569             Xcursor_cflags=""
 570             Xcursor_libs=""
 571             use_Xcursor="no"
 572           ], [
 573             $x_libs -lXrender
 574           ]
 575         )
 576       ], [
 577         Xcursor_cflags=""
 578         Xcursor_libs=""
 579         use_Xcursor="no"
 580       ], [
 581         #include <X11/Xlib.h>
 582       ]
 583     )
 584     CFLAGS=$PCFLAGS
 585
 586     AC_SUBST(Xcursor_cflags)
 587     AC_SUBST(Xcursor_libs)
 588
 589     ECORE_CHECK_X_EXTENSION([Xkb], [XKB.h], [X11], [XkbSetDetectableAutoRepeat])
 590     ECORE_CHECK_X_EXTENSION([Xcomposite], [Xcomposite.h], [Xcomposite], [XCompositeQueryExtension])
 591     ECORE_CHECK_X_EXTENSION([Xdamage], [Xdamage.h], [Xdamage], [XDamageSubtract])
 592     ECORE_CHECK_X_EXTENSION([Xdpms], [dpms.h], [Xdpms], [DPMSQueryExtension])
 593     if test "x$use_xdpms" = "xno" ; then
 594       ECORE_CHECK_X_EXTENSION([Xdpms], [dpms.h], [Xext], [DPMSQueryExtension])
 595     fi
 596     ECORE_CHECK_X_EXTENSION([Xfixes], [Xfixes.h], [Xfixes], [XFixesExpandRegion])
 597     ECORE_CHECK_X_EXTENSION([Xinerama], [Xinerama.h], [Xinerama], [XineramaQueryScreens])
 598     ECORE_CHECK_X_EXTENSION([Xprint], [Print.h], [Xp], [XpQueryScreens])
 599     ECORE_CHECK_X_EXTENSION([Xrandr], [Xrandr.h], [Xrandr], [XRRSizes])
 600     ECORE_CHECK_X_EXTENSION([Xrender], [Xrender.h], [Xrender], [XRenderFindVisualFormat])
 601     ECORE_CHECK_X_EXTENSION([Xtest], [XTest.h], [Xtst], [XTestFakeKeyEvent])
 602     ECORE_CHECK_X_EXTENSION([Xss], [scrnsaver.h], [Xss], [XScreenSaverSelectInput])
 603
 604     AC_DEFINE(HAVE_ECORE_X_XLIB, 1, [Defined to 1 if Xlib is enabled.])
 605     have_x="yes"
 606
 607     have_ecore_x_xlib="yes"
 608   fi
 609 fi
 610
 611 AC_SUBST(x_cflags)
 612 AC_SUBST(x_includes)
 613 AC_SUBST(x_libs)
 614
 615 AM_CONDITIONAL(BUILD_ECORE_X_XLIB, test $have_ecore_x_xlib = yes)
 616 AM_CONDITIONAL(BUILD_ECORE_X_XCB, test $have_ecore_x_xcb = yes)
 617
 618
 619 # Evas library (ecore_evas and ecore_imf_evas)
 620
 621 PKG_CHECK_MODULES([EVAS], [evas >= 0.9.9],
 622    [
 623     have_evas="yes"
 624     requirements_ecore_evas="evas ${requirements_ecore_evas}"
 625    ],
 626    [have_evas="no"])
 627
 628
 629 ### Checks for header files
 630
 631 AC_HEADER_SYS_WAIT
 632
 633 case "$host_os" in
 634    mingw* | cegcc*)
 635       AC_DEFINE(HAVE_DLFCN_H, 1, [Define to 1 if you have the <dlfcn.h> header file.])
 636       AC_DEFINE(HAVE_SYS_MMAN_H, 1, [Define to 1 if you have the <sys/mman.h> header file.])
 637       AC_DEFINE(HAVE_SYS_TIME_H, 1, [Define to 1 if you have the <sys/time.h> header file.])
 638       ;;
 639    *)
 640       AC_CHECK_HEADERS([dlfcn.h features.h langinfo.h locale.h netdb.h netinet/in.h sys/time.h sys/mman.h signal.h sys/resource.h])
 641       ;;
 642 esac
 643
 644 # Framebuffer (ecore_fb)
 645 have_fb="no"
 646 AC_CHECK_HEADER([linux/fb.h],
 647    [AC_CHECK_HEADER([linux/input.h], [have_fb="yes"])])
 648
 649 # Quartz header files (ecore_quartz)
 650
 651 quartz_ldflags="";
 652 have_quartz="no"
 653
 654 if test "x${have_gnu_objc}" = "xyes" ; then
 655    AC_LANG_PUSH([Objective C])
 656    AC_CHECK_HEADER([Cocoa/Cocoa.h],
 657       [
 658        have_quartz="yes"
 659        quartz_ldflags="-framework Cocoa"
 660       ],
 661       [have_quartz="no"])
 662    AC_LANG_POP([Objective C])
 663 fi
 664
 665 AC_SUBST(quartz_ldflags)
 666
 667 # basic pthread support
 668 AC_CHECK_HEADER(pthread.h,
 669   [
 670      AC_DEFINE(BUILD_PTHREAD, 1, [Build thread worker])
 671   ]
 672 )
 673
 674 ### Checks for types
 675 AC_CHECK_SIZEOF(int, 4)
 676 AC_CHECK_SIZEOF(long, 4)
 677
 678
 679 ### Checks for structures
 680
 681
 682 ### Checks for compiler characteristics
 683 AM_PROG_CC_STDC
 684 AC_C_CONST
 685 AC_C_BIGENDIAN
 686 AC_HEADER_STDC
 687 AC_C___ATTRIBUTE__
 688
 689 WIN32_CPPFLAGS=""
 690 WIN32_CFLAGS=""
 691 case "$host_os" in
 692    mingw32ce*)
 693       WIN32_CPPFLAGS="-D_WIN32_WCE=0x0420"
 694       ;;
 695    cegcc*)
 696       WIN32_CPPFLAGS="-D_WIN32_WCE=0x0420"
 697       WIN32_CFLAGS="-mwin32"
 698       ;;
 699    mingw*)
 700       WIN32_CPPFLAGS="-D_WIN32_WINNT=0x0500"
 701       ;;
 702 esac
 703 AC_SUBST(WIN32_CPPFLAGS)
 704 AC_SUBST(WIN32_CFLAGS)
 705
 706
 707 ### Checks for linker characteristics
 708
 709 # use --enable-auto-import on Windows
 710
 711 lt_enable_auto_import=""
 712 case "$host_os" in
 713    mingw* | cegcc*)
 714       lt_enable_auto_import="-Wl,--enable-auto-import"
 715       ;;
 716 esac
 717 AC_SUBST(lt_enable_auto_import)
 718
 719 ### Checks for library functions
 720 AC_FUNC_ALLOCA
 721 AC_CHECK_FUNCS(gettimeofday strlcpy)
 722
 723 have_atfile_source=auto
 724 AC_ARG_ENABLE(atfile-source,
 725         AC_HELP_STRING([--disable-atfile-source],
 726                        [disable use of atfile source functions as openat and mkdirat @<:@default=detect@:>@]),
 727         [have_atfile_source=$enableval], [have_atfile_source=auto])
 728
 729 if test "x$have_atfile_source" != "xno"; then
 730         AC_CHECK_FUNCS(mkdirat,
 731                 [
 732                 have_atfile_source=yes
 733                 AC_DEFINE(HAVE_ATFILE_SOURCE, 1, [mkdirat exists])
 734                 ],
 735                 [
 736                 if test "x$have_atfile_source" = "xyes"; then
 737                         AC_MSG_ERROR([required atfile-source but no mkdirat()])
 738                 fi
 739                 have_atfile_source=no
 740                 ])
 741 fi
 742
 743 ### Ecore modules
 744
 745 ## Core modules
 746
 747 # ecore_job
 748 ECORE_CHECK_MODULE([Job], [${want_ecore_job}])
 749
 750 # ecore_txt
 751 ECORE_CHECK_MODULE([Txt], [${want_ecore_txt}], [$have_iconv],
 752    [ecore_txt_libs="$ecore_txt_libs $iconv_libs"])
 753
 754 # ecore_con
 755 ECORE_CHECK_MODULE([Con], [${want_ecore_con}])
 756
 757 have_curl="no"
 758 have_gnutls="no"
 759 have_openssl="no"
 760 if test "x${have_ecore_con}" = "xyes" ; then
 761    requirements_ecore_con="ecore ${requirements_ecore_con}"
 762
 763    ECORE_CHECK_CURL([${want_curl}],
 764       [
 765        requirements_ecore_con="libcurl ${requirements_ecore_con}"
 766        have_curl="yes"
 767       ],
 768       [have_curl="no"])
 769
 770    ECORE_CHECK_GNUTLS([${want_gnutls}],
 771       [have_gnutls="yes"],
 772       [have_gnutls="no"])
 773
 774    ECORE_CHECK_OPENSSL([${want_openssl}],
 775       [have_openssl="yes"],
 776       [have_openssl="no"])
 777
 778    if test "x${have_gnutls}" = "xyes" ; then
 779       requirements_ecore_con="gnutls ${requirements_ecore_con}"
 780       # no need to add it to req_ecore_ipc, since they
 781       # depends on ecore_con anyway.
 782    else
 783       if test "x${have_openssl}" = "xyes" ; then
 784          requirements_ecore_con="openssl ${requirements_ecore_con}"
 785          # no need to add it to req_ecore_ipc, since they
 786          # depends on ecore_con anyway.
 787       fi
 788    fi
 789 fi
 790
 791 # ecore_ipc
 792 ECORE_CHECK_MODULE([Ipc], [${want_ecore_ipc}], [$have_ecore_con],
 793   [requirements_ecore_ipc="ecore-con ${requirements_ecore_ipc}"])
 794
 795 # ecore_file
 796 ECORE_CHECK_MODULE([File], [${want_ecore_file}])
 797
 798 have_poll="no"
 799 have_inotify="no"
 800 if test "x${have_ecore_file}" = "xyes" ; then
 801    ECORE_CHECK_POLL([${want_poll}], [have_poll="yes"], [have_poll="no"])
 802    ECORE_CHECK_INOTIFY([${want_inotify}], [have_inotify="yes"], [have_inotify="no"])
 803
 804    if test "x${have_ecore_con}" = "xyes" ; then
 805       requirements_ecore_file="ecore-con ${requirements_ecore_file}"
 806    fi
 807 fi
 808
 809 # ecore_config
 810 ecore_config_deps="no"
 811 if test "x$have_eet" = "xyes" -a "x$have_ecore_ipc" = "xyes" ; then
 812   ecore_config_deps="yes"
 813 fi
 814
 815 ECORE_CHECK_MODULE([Config], [${want_ecore_config}], [$ecore_config_deps],
 816   [requirements_ecore_config="ecore-ipc eet ecore ${requirements_ecore_config}"])
 817
 818 # ecore_imf
 819
 820 ECORE_CHECK_MODULE([IMF], [${want_ecore_imf}])
 821
 822 # ecore_imf_evas
 823
 824 ecore_imf_evas_deps="no"
 825 if test "x${have_ecore_imf}" = "xyes" -a "x${have_evas}" = "xyes" ; then
 826    ecore_imf_evas_deps="yes"
 827 fi
 828
 829 ECORE_CHECK_MODULE([IMF_EVAS], [${want_ecore_imf}], [${ecore_imf_evas_deps}],
 830   [requirements_ecore_imf_evas="ecore-imf evas ${requirements_ecore_imf_evas}"])
 831
 832 # ecore_input
 833 ECORE_CHECK_MODULE([Input], [${want_ecore_input}], [${have_evas}],
 834   [requirements_ecore_input="evas ${requirements_ecore_input}"])
 835
 836 ## Graphic systems
 837
 838 # ecore_x{cb}
 839
 840 ecore_x_deps="no"
 841 if test "x${have_x}" = "xyes" -a \
 842         "x${have_ecore_input}" = "xyes" -a \
 843         "x${have_ecore_txt}" = "xyes" ; then
 844    ecore_x_deps="yes"
 845 fi
 846
 847 ECORE_CHECK_MODULE([X], [${want_ecore_x}], [${ecore_x_deps}],
 848   [
 849    ecore_x_libs="$ecore_x_libs $x_libs"
 850    requirements_ecore_x="ecore-input ecore-txt ${requirements_ecore_x}"
 851   ])
 852
 853 # ecore_win32
 854
 855 ECORE_CHECK_MODULE([Win32], [${want_ecore_win32}], [yes],
 856   [ecore_win32_libs="-lole32 -lgdi32"])
 857 AC_SUBST(ecore_win32_libs)
 858
 859 # ecore_quartz
 860
 861 ECORE_CHECK_MODULE([QUARTZ], [${want_ecore_quartz}], [$have_quartz])
 862
 863 # ecore_sdl
 864
 865 ecore_sdl_deps="no"
 866 if test "x${have_sdl}" = "xyes" -a "x${have_ecore_input}" = "xyes" ; then
 867    ecore_sdl_deps="yes"
 868 fi
 869
 870 ECORE_CHECK_MODULE([SDL], [${want_ecore_sdl}], [${ecore_sdl_deps}],
 871   [requirements_ecore_sdl="ecore-input ${requirements_ecore_sdl}"])
 872
 873 # ecore_fb
 874 ECORE_CHECK_MODULE([FB], [${want_ecore_fb}], [$have_fb])
 875
 876 if test "x${have_ecore_fb}" = "xyes" ; then
 877    ECORE_CHECK_TSLIB([${want_tslib}], [have_tslib="no"], [have_tslib="no"])
 878 fi
 879
 880 # ecore_directfb
 881
 882 ECORE_CHECK_MODULE([DirectFB], [${want_ecore_directfb}], [${have_directfb}],
 883   [requirements_ecore_directfb="directfb ${requirements_ecore_directfb}"])
 884
 885 # ecore_wince
 886
 887 ECORE_CHECK_MODULE([WinCE], [${want_ecore_wince}])
 888
 889 ## Ecore Evas
 890
 891 # ecore_evas
 892
 893 ECORE_CHECK_MODULE([Evas], [${want_ecore_evas}], [$have_ecore_input],
 894   [requirements_ecore_evas="ecore-input ${requirements_ecore_evas}"])
 895
 896 # ecore_evas_buffer
 897
 898 ECORE_EVAS_CHECK_MODULE([software-buffer],
 899    [${want_ecore_evas_software_buffer}],
 900    [Software Buffer],
 901    [yes])
 902
 903 # ecore_evas_x11
 904
 905 # ecore_evas_software_x11
 906
 907 ECORE_EVAS_CHECK_MODULE([software-x11],
 908    [${want_ecore_evas_software_x11}],
 909    [Software X11],
 910    [${have_ecore_x}])
 911
 912 have_ecore_evas_software_xlib=no"
 913 have_ecore_evas_software_xcb=no"
 914 if test "x$have_ecore_evas_software_x11" = "xyes" ; then
 915    have_ecore_evas_software_xlib=`${PKG_CONFIG} --variable=Xlib evas-software-x11`
 916    if test "x${have_ecore_evas_software_xlib}" = "xyes" -a "x${have_ecore_x_xlib}" = "xyes" ; then
 917       AC_DEFINE(BUILD_ECORE_EVAS_SOFTWARE_XLIB, 1, [Evas Software Xlib Engine Support])
 918    fi
 919    have_ecore_evas_software_xcb=`${PKG_CONFIG} --variable=XCB evas-software-x11`
 920    if test "x$have_ecore_evas_software_xcb" = "xyes" -a "x${have_ecore_x_xcb}" = "xyes" ; then
 921       AC_DEFINE(BUILD_ECORE_EVAS_SOFTWARE_XCB, 1, [Evas Software XCB Engine Support])
 922    fi
 923 fi
 924
 925 # ecore_evas_xrender_x11
 926
 927 ECORE_EVAS_CHECK_MODULE([xrender-x11],
 928    [${want_ecore_evas_xrender_x11}],
 929    [XRender Xlib],
 930    [${have_ecore_x_xlib}])
 931
 932 # ecore_evas_opengl_x11
 933
 934 ECORE_EVAS_CHECK_MODULE([opengl-x11],
 935    [${want_ecore_evas_opengl_x11}],
 936    [OpenGL Xlib],
 937    [${have_ecore_x_xlib}])
 938
 939 # ecore_evas_software_x11 16 bits
 940
 941 ECORE_EVAS_CHECK_MODULE([software-16-x11],
 942    [${want_ecore_evas_software_16_x11}],
 943    [Software Xlib 16 bits],
 944    [${have_ecore_x_xlib}])
 945
 946 # ecore_evas_xrender_xcb
 947
 948 ECORE_EVAS_CHECK_MODULE([xrender-xcb],
 949    [${want_ecore_evas_xrender_xcb}],
 950    [XRender XCB],
 951    [${ecore_evas_xcb_deps}])
 952
 953 if test "x$have_ecore_evas_software_x11" = "xyes" -o \
 954         "x$have_ecore_evas_xrender_x11" = "xyes" -o \
 955         "x$have_ecore_evas_opengl_x11" = "xyes" -o \
 956         "x$have_ecore_evas_software_16_x11" = "xyes" -o \
 957         "x$have_ecore_evas_software_xcb" = "xyes" -o \
 958         "x$have_ecore_evas_xrender_xcb" = "xyes"; then
 959    AC_DEFINE(BUILD_ECORE_EVAS_X11, 1, [Support for X Window Engines in Ecore_Evas])
 960    requirements_ecore_evas="ecore-x ${requirements_ecore_evas}"
 961 fi
 962
 963 # ecore_evas_win32
 964
 965 ECORE_EVAS_CHECK_MODULE([software-gdi],
 966    [${want_ecore_evas_software_gdi}],
 967    [Software GDI],
 968    [${have_ecore_win32}])
 969
 970 ECORE_EVAS_CHECK_MODULE([software-ddraw],
 971    [${want_ecore_evas_software_ddraw}],
 972    [Software DirectDraw],
 973    [${have_ecore_win32}])
 974
 975 ECORE_EVAS_CHECK_MODULE([direct3d],
 976    [${want_ecore_evas_direct3d}],
 977    [Direct3d],
 978    [${have_ecore_win32}])
 979
 980 ECORE_EVAS_CHECK_MODULE([opengl-glew],
 981    [${want_ecore_evas_opengl_glew}],
 982    [Glew OpenGL],
 983    [${have_ecore_win32}])
 984
 985 ECORE_EVAS_CHECK_MODULE([software-16-ddraw],
 986    [${want_ecore_evas_software_16_ddraw}],
 987    [16 bpp Software DirectDraw],
 988    [${have_ecore_win32}])
 989
 990 if test "x${have_ecore_evas_software_gdi}" = "xyes" -o \
 991         "x${have_ecore_evas_software_ddraw}" = "xyes" -o \
 992         "x${have_ecore_evas_direct3d}" = "xyes" -o \
 993         "x${have_ecore_evas_opengl_glew}" = "xyes" -o \
 994         "x${have_ecore_evas_software_16_ddraw}" = "xyes" ; then
 995    AC_DEFINE(BUILD_ECORE_EVAS_WIN32, 1, [Support for Win32 Engine in Ecore_Evas])
 996    requirements_ecore_evas="ecore-win32 ${requirements_ecore_evas}"
 997 fi
 998
 999 # ecore_evas_quartz
1000
1001 ECORE_EVAS_CHECK_MODULE([quartz],
1002    [${want_ecore_evas_quartz}],
1003    [Quartz],
1004    [${have_ecore_quartz}],
1005    [requirements_ecore_evas="ecore-quartz ${requirements_ecore_evas}"])
1006
1007 # ecore_evas_software_sdl
1008
1009 ECORE_EVAS_CHECK_MODULE([software-sdl],
1010    [${want_ecore_evas_software_sdl}],
1011    [Software SDL],
1012    [${have_ecore_sdl}],
1013    [requirements_ecore_evas="ecore-sdl ${requirements_ecore_evas}"])
1014
1015 # ecore_evas_directfb
1016
1017 ECORE_EVAS_CHECK_MODULE([directfb],
1018    [${want_ecore_evas_directfb}],
1019    [DirectFB],
1020    [${have_ecore_directfb}],
1021    [requirements_ecore_evas="ecore-directfb ${requirements_ecore_evas}"])
1022
1023 # ecore_evas_fb
1024
1025 ECORE_EVAS_CHECK_MODULE([fb],
1026    [${want_ecore_evas_fb}],
1027    [Linux Framebuffer],
1028    [${have_ecore_fb}],
1029    [requirements_ecore_evas="ecore-fb ${requirements_ecore_evas}"])
1030
1031 # ecore_evas_wince
1032
1033 ECORE_EVAS_CHECK_MODULE([software-16-wince],
1034    [${want_ecore_evas_software_16_wince}],
1035    [16 bpp Software Windows CE],
1036    [${have_ecore_wince}],
1037    [requirements_ecore_evas="ecore-wince ${requirements_ecore_evas}"])
1038
1039
1040
1041 ### requirements
1042
1043 AC_SUBST(requirements_ecore)
1044 AC_SUBST(requirements_ecore_con)
1045 AC_SUBST(requirements_ecore_config)
1046 AC_SUBST(requirements_ecore_directfb)
1047 AC_SUBST(requirements_ecore_evas)
1048 AC_SUBST(requirements_ecore_fb)
1049 AC_SUBST(requirements_ecore_file)
1050 AC_SUBST(requirements_ecore_imf)
1051 AC_SUBST(requirements_ecore_imf_evas)
1052 AC_SUBST(requirements_ecore_input)
1053 AC_SUBST(requirements_ecore_ipc)
1054 AC_SUBST(requirements_ecore_job)
1055 AC_SUBST(requirements_ecore_quartz)
1056 AC_SUBST(requirements_ecore_sdl)
1057 AC_SUBST(requirements_ecore_txt)
1058 AC_SUBST(requirements_ecore_x)
1059 AC_SUBST(requirements_ecore_win32)
1060 AC_SUBST(requirements_ecore_wince)
1061
1062 AC_OUTPUT([
1063 Makefile
1064 ecore-con.pc
1065 ecore-config.pc
1066 ecore-directfb.pc
1067 ecore-evas.pc
1068 ecore-fb.pc
1069 ecore-file.pc
1070 ecore-imf.pc
1071 ecore-imf-evas.pc
1072 ecore-ipc.pc
1073 ecore-job.pc
1074 ecore-txt.pc
1075 ecore-x.pc
1076 ecore-input.pc
1077 ecore-win32.pc
1078 ecore-sdl.pc
1079 ecore-quartz.pc
1080 ecore-wince.pc
1081 ecore.pc
1082 doc/ecore.dox
1083 doc/Makefile
1084 src/Makefile
1085 src/bin/Makefile
1086 src/lib/Makefile
1087 src/lib/ecore/Makefile
1088 src/lib/ecore_job/Makefile
1089 src/lib/ecore_x/Makefile
1090 src/lib/ecore_x/xlib/Makefile
1091 src/lib/ecore_x/xcb/Makefile
1092 src/lib/ecore_fb/Makefile
1093 src/lib/ecore_sdl/Makefile
1094 src/lib/ecore_quartz/Makefile
1095 src/lib/ecore_evas/Makefile
1096 src/lib/ecore_con/Makefile
1097 src/lib/ecore_imf/Makefile
1098 src/lib/ecore_imf_evas/Makefile
1099 src/lib/ecore_input/Makefile
1100 src/lib/ecore_ipc/Makefile
1101 src/lib/ecore_txt/Makefile
1102 src/lib/ecore_config/Makefile
1103 src/lib/ecore_file/Makefile
1104 src/lib/ecore_directfb/Makefile
1105 src/lib/ecore_win32/Makefile
1106 src/lib/ecore_wince/Makefile
1107 README
1108 ecore.spec
1109 ])
1110
1111 echo
1112 echo "$PACKAGE $VERSION"
1113 echo
1114 echo "Optional Modules:"
1115 echo
1116 echo " Core:"
1117 echo
1118 echo "  Ecore........................: always"
1119 echo "  Ecore_Job....................: $have_ecore_job"
1120 echo "  Ecore_Txt....................: $have_ecore_txt"
1121 echo "  Ecore_Con....................: $have_ecore_con"
1122 if test "x$have_ecore_con" = "xyes" ; then
1123   echo $ECHO_N "    OpenSSL....................: $have_openssl $ECHO_C"
1124 if test "x$have_gnutls" = "xyes" ; then
1125   echo " (disabled)"
1126 else
1127   echo
1128 fi
1129   echo "    GnuTLS.....................: $have_gnutls"
1130   echo "    CURL.......................: $have_curl"
1131   echo "    Abstract Sockets...........: $want_abstract_sockets"
1132 fi
1133 echo "  Ecore_Ipc....................: $have_ecore_ipc"
1134 if test "x$have_ecore_ipc" = "xyes" ; then
1135   echo $ECHO_N "    OpenSSL....................: $have_openssl $ECHO_C"
1136 if test "x$have_gnutls" = "xyes" ; then
1137   echo " (disabled)"
1138 else
1139   echo
1140 fi
1141   echo "    GnuTLS.....................: $have_gnutls"
1142 fi
1143 echo "  Ecore_File...................: $have_ecore_file"
1144 if test "x$have_ecore_file" = "xyes" ; then
1145   echo "    Inotify....................: $have_inotify"
1146   echo "    Poll.......................: $have_poll"
1147   echo "    CURL.......................: $have_curl"
1148 fi
1149 echo "  Ecore_Config.................: $have_ecore_config"
1150 echo "  Ecore_IMF....................: $have_ecore_imf"
1151 echo "  Ecore_IMF_Evas...............: $have_ecore_imf_evas"
1152 echo "  Ecore_Input..................: $have_ecore_input"
1153
1154 echo
1155 echo " Graphic systems:"
1156 echo
1157
1158 if test "x$have_ecore_x" = "xyes" ; then
1159   if test "x$have_ecore_x_xcb" = "xyes" ; then
1160     echo "  Ecore_X (XCB backend)........: $have_ecore_x_xcb"
1161     echo "    Xprint.....................: $have_ecore_x_xcb_xprint"
1162     echo "    Xinerama...................: $have_ecore_x_xcb_xinerama"
1163     echo "    Xrandr.....................: $have_ecore_x_xcb_randr"
1164     echo "    Xscreensaver...............: $have_ecore_x_xcb_screensaver"
1165     echo "    Xshape.....................: $have_ecore_x_xcb_shape"
1166     echo "    Xsync......................: $have_ecore_x_xcb_sync"
1167     echo "    Xrender....................: $have_ecore_x_xcb_render"
1168     echo "    Xcomposite.................: $have_ecore_x_xcb_composite"
1169     echo "    Xfixes.....................: $have_ecore_x_xcb_xfixes"
1170     echo "    Xdamage....................: $have_ecore_x_xcb_damage"
1171     echo "    Xdpms......................: $have_ecore_x_xcb_dpms"
1172     echo "    Xtest......................: $have_ecore_x_xcb_xtest"
1173   else
1174     echo "  Ecore_X (Xlib backend).......: $have_ecore_x"
1175     echo "    Xcursor....................: $use_Xcursor"
1176     echo "    Xkb........................: $use_xkb"
1177     echo "    Xprint.....................: $use_xprint"
1178     echo "    Xinerama...................: $use_xinerama"
1179     echo "    Xrandr.....................: $use_xrandr"
1180     echo "    Xscreensaver...............: $use_xss"
1181     echo "    Xrender....................: $use_xrender"
1182     echo "    Xcomposite.................: $use_xcomposite"
1183     echo "    Xfixes.....................: $use_xfixes"
1184     echo "    Xdamage....................: $use_xdamage"
1185     echo "    Xdpms......................: $use_xdpms"
1186     echo "    Xtest......................: $use_xtest"
1187   fi
1188 else
1189   echo "  Ecore_X......................: $have_ecore_x"
1190 fi
1191 echo "  Ecore_Win32..................: $have_ecore_win32"
1192 echo "  Ecore_Quartz.................: $have_ecore_quartz"
1193 echo "  Ecore_SDL....................: $have_ecore_sdl"
1194 echo "  Ecore_FB.....................: $have_ecore_fb"
1195 if test "x${have_ecore_fb}" = "xyes" ; then
1196   echo "    Touchscreen................: $have_tslib"
1197 fi
1198 echo "  Ecore_DirectFB...............: $have_ecore_directfb"
1199 echo "  Ecore_WinCE..................: $have_ecore_wince"
1200
1201 echo
1202 echo " Ecore Evas:"
1203 echo
1204
1205 echo "  Ecore_Evas...................: $have_ecore_evas"
1206 if test "x${have_ecore_evas}" = "xyes" ; then
1207   echo "    Software Memory Buffer.....: $have_ecore_evas_software_buffer"
1208   if test "x${have_ecore_evas_software_x11}" = "xyes" ; then
1209     if test "x${have_ecore_evas_software_xlib}" = "xyes" ; then
1210       echo "    Software X11...............: $have_ecore_evas_software_x11 (Xlib)"
1211     fi
1212     if test "x${have_ecore_evas_software_xcb}" = "xyes" ; then
1213       echo "    Software X11...............: $have_ecore_evas_software_x11 (XCB)"
1214     fi
1215   else
1216     echo "    Software X11...............: $have_ecore_evas_software_x11"
1217   fi
1218   echo "    XRender X11................: $have_ecore_evas_xrender_x11"
1219   echo "    OpenGL X11.................: $have_ecore_evas_opengl_x11"
1220   echo "    XRender XCB................: $have_ecore_evas_xrender_xcb"
1221   echo "    Software GDI...............: $have_ecore_evas_software_gdi"
1222   echo "    Software DirectDraw........: $have_ecore_evas_software_ddraw"
1223   echo "    Direct3D...................: $have_ecore_evas_direct3d"
1224   echo "    OpenGL Glew................: $have_ecore_evas_opengl_glew"
1225   echo "    Quartz.....................: $have_ecore_evas_quartz"
1226   echo "    Software SDL...............: $have_ecore_evas_software_sdl"
1227   echo "    DirectFB...................: $have_ecore_evas_directfb"
1228   echo "    Software Framebuffer.......: $have_ecore_evas_fb"
1229   echo "    Software 16bit X11.........: $have_ecore_evas_software_16_x11"
1230   echo "    Software 16bit DirectDraw..: $have_ecore_evas_software_16_ddraw"
1231   echo "    Software 16bit WinCE.......: $have_ecore_evas_software_16_wince"
1232 fi
1233 echo
1234 echo " Documentation.................: ${build_doc}"
1235 echo
1236 echo " Compilation...................: make (gmake on some systems)"
1237 if test "x${build_doc}" = "xyes" ; then
1238    echo " Build of the documentation....: make doc"
1239 fi
1240 echo
1241 echo " Installation..................: make install"
1242 echo
1243 echo "    prefix.....................: $prefix"
1244 echo