configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # This file is part of PulseAudio.
   5 #
   6 # Copyright 2004-2008 Lennart Poettering
   7 # Copyright 2006-2007 Pierre Ossman <ossman@cendio.se> for Cendio AB
   8 #
   9 # PulseAudio is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU Lesser General Public License as published by
  11 # the Free Software Foundation; either version 2 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # PulseAudio is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  17 # General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public License
  20 # along with PulseAudio; if not, see <http://www.gnu.org/licenses/>.
  21
  22 AC_PREREQ(2.63)
  23
  24 AC_INIT([pulseaudio],[m4_esyscmd(./git-version-gen .tarball-version)],[pulseaudio-discuss (at) lists (dot) freedesktop (dot) org],[pulseaudio],[http://pulseaudio.org/])
  25 AC_CONFIG_SRCDIR([src/daemon/main.c])
  26 AC_CONFIG_MACRO_DIR([m4])
  27 AC_CONFIG_HEADERS([config.h])
  28 AC_CONFIG_AUX_DIR([build-aux])
  29 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability subdir-objects silent-rules color-tests dist-xz tar-ustar])
  30
  31 AS_IF([! test -n "$VERSION"], [
  32    AC_MSG_ERROR([git-version-gen failed])
  33 ])
  34
  35 m4_define(pa_major, `echo $VERSION | cut -d. -f1 | cut -d- -f1`)
  36 m4_define(pa_minor, `echo $VERSION | cut -d. -f2 | cut -d- -f1`)
  37
  38 AC_SUBST(PA_MAJOR, pa_major)
  39 AC_SUBST(PA_MINOR, pa_minor)
  40 AC_SUBST(PA_MAJORMINOR, pa_major.pa_minor)
  41
  42 AC_SUBST(PA_API_VERSION, 12)
  43 AC_SUBST(PA_PROTOCOL_VERSION, 32)
  44
  45 # The stable ABI for client applications, for the version info x:y:z
  46 # always will hold y=z
  47 AC_SUBST(LIBPULSE_VERSION_INFO, [20:2:20])
  48
  49 # A simplified, synchronous, ABI-stable interface for client
  50 # applications, for the version info x:y:z always will hold y=z
  51 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [1:1:1])
  52
  53 # The ABI-stable GLib adapter for client applications, for the version
  54 # info x:y:z always will hold y=z
  55 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:5:0])
  56
  57 AC_CANONICAL_HOST
  58 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  59
  60 AC_CHECK_PROG([STOW], [stow], [yes], [no])
  61
  62 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
  63     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  64     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  65 ])
  66
  67 AM_SILENT_RULES([yes])
  68
  69
  70 #### Checks for programs. ####
  71
  72 # mkdir -p
  73
  74 AC_PROG_MKDIR_P
  75
  76 # ln -s
  77
  78 AC_PROG_LN_S
  79
  80 # CC
  81
  82 AC_PROG_CC
  83 AM_PROG_CC_C_O
  84 # Only required if you want the WebRTC canceller -- no runtime dep on
  85 # libstdc++ otherwise
  86 AC_PROG_CXX
  87 AC_PROG_GCC_TRADITIONAL
  88 AC_USE_SYSTEM_EXTENSIONS
  89 AX_CXX_COMPILE_STDCXX_11([ext],[optional])
  90
  91 # M4
  92
  93 AC_CHECK_PROGS([M4], gm4 m4, no)
  94 AS_IF([test "x$M4" = "xno"], AC_MSG_ERROR([m4 missing]))
  95
  96 # pkg-config
  97
  98 PKG_PROG_PKG_CONFIG
  99
 100 # gettext
 101
 102 if test "x$enable_nls" != "xno"; then
 103 IT_PROG_INTLTOOL([0.35.0])
 104
 105 AM_GNU_GETTEXT_VERSION([0.18.1])
 106 AM_GNU_GETTEXT([external])
 107
 108 GETTEXT_PACKAGE=pulseaudio
 109 AC_SUBST([GETTEXT_PACKAGE])
 110 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
 111 else
 112 # workaround till an intltool m4 bug is fixed upstream
 113 # (https://bugs.launchpad.net/intltool/+bug/904647)
 114 USE_NLS=no
 115 AC_SUBST(USE_NLS)
 116 fi
 117
 118
 119 #### Determine host OS ####
 120
 121 # if the host has the possibility of sys/capability.h for dropping privileges
 122 # used to determine if we should error out if it is not found
 123 host_has_caps=0
 124
 125 os_is_linux=0
 126 os_is_win32=0
 127 os_is_darwin=0
 128
 129 AC_MSG_CHECKING([host operating system])
 130 case "$host_os" in
 131     linux*)
 132         AC_MSG_RESULT([linux])
 133         host_has_caps=1
 134         os_is_linux=1
 135     ;;
 136     freebsd*)
 137         AC_MSG_RESULT([freebsd])
 138         host_has_caps=1
 139     ;;
 140     netbsd*)
 141         AC_MSG_RESULT([netbsd])
 142     ;;
 143     darwin*)
 144         AC_MSG_RESULT([darwin])
 145         os_is_darwin=1
 146         AC_DEFINE([OS_IS_DARWIN], 1, [Build target is Darwin.])
 147     ;;
 148     mingw*)
 149         AC_MSG_RESULT([win32])
 150         os_is_win32=1
 151         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 152     ;;
 153     *)
 154         AC_MSG_RESULT([unknown])
 155     ;;
 156 esac
 157
 158 AM_CONDITIONAL(OS_IS_DARWIN, test "x$os_is_darwin" = "x1")
 159 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 160 AC_SUBST([OS_IS_WIN32], [$os_is_win32])
 161
 162 # Platform specific hacks
 163 case "$host_os" in
 164     darwin* )
 165         AC_DEFINE([_DARWIN_C_SOURCE], [200112L], [Needed to get NSIG on Mac OS X])
 166     ;;
 167     mingw* )
 168         AC_DEFINE([WIN32_LEAN_AND_MEAN], 1, [Needed to avoid including unnecessary headers on Windows])
 169     ;;
 170     solaris* )
 171         AC_DEFINE(_XOPEN_SOURCE,       600, [Needed to get declarations for msg_control and msg_controllen on Solaris])
 172         AC_DEFINE(__EXTENSIONS__,        1, [Needed to get declarations for msg_control and msg_controllen on Solaris])
 173     ;;
 174 esac
 175
 176
 177 #### Compiler flags ####
 178
 179 AX_CHECK_COMPILE_FLAG([-std=gnu11],
 180    [],
 181    [AC_MSG_ERROR([*** Compiler does not support -std=gnu11])],
 182    [-pedantic -Werror])
 183
 184 AX_APPEND_COMPILE_FLAGS(
 185     [-Wall -W -Wextra -pipe -Wno-long-long -Wno-overlength-strings -Wunsafe-loop-optimizations -Wundef -Wformat=2 -Wlogical-op -Wsign-compare -Wformat-security -Wmissing-include-dirs -Wformat-nonliteral -Wold-style-definition -Wpointer-arith -Winit-self -Wdeclaration-after-statement -Wfloat-equal -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-declarations -Wmissing-noreturn -Wshadow -Wendif-labels -Wcast-align -Wstrict-aliasing -Wwrite-strings -Wno-unused-parameter -ffast-math -fno-common -fdiagnostics-show-option -fdiagnostics-color=auto],
 186     [], [-pedantic -Werror])
 187
 188 AS_CASE([" $CFLAGS "], [*" -O0 "*], [], [
 189     # Don't append the flag if it already exists.
 190     # Only enable fastpath asserts when doing a debug build, e.g. from bootstrap.sh.
 191     AX_APPEND_FLAG([-DFASTPATH], [CPPFLAGS])
 192
 193     # Cannot use AX_APPEND_FLAG here, as it assumes no space inside the added flags.
 194     # Cannot append flags with AX_APPEND_FLAG one by one, as this would destroy all fortifications
 195     # if CPPFLAGS already contain -D_FORTIFY_SOURCE=2.
 196
 197     # Warnings to be aware of that appear with -D_FORTIFY_SOURCE=2 but without -U_FORTIFY_SOURCE:
 198     # On Fedora 20 with -O0: #warning _FORTIFY_SOURCE requires compiling with optimization (-O) [-Wcpp]
 199     # On Gentoo with -O2:    "_FORTIFY_SOURCE" redefined [enabled by default]
 200     AS_VAR_APPEND([CPPFLAGS],[" -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2"])
 201 ])
 202
 203 #### Linker flags ####
 204
 205 # Check whether the linker supports the -version-script option.
 206 # The Make variable $(srcdir) needs to be in the LDFLAGS in that form,
 207 # so that it is expanded the right way in every subdir.
 208 AX_CHECK_LINK_FLAG(["-Wl,-version-script=${srcdir}/src/map-file"],
 209     [VERSIONING_LDFLAGS='-Wl,-version-script=$(abs_top_srcdir)/src/map-file'])
 210 AC_SUBST([VERSIONING_LDFLAGS])
 211
 212 # Use immediate (now) bindings; avoids the funky re-call in itself.
 213 # The -z now syntax is lifted from Sun's linker and works with GNU's too, other linkers might be added later.
 214 AX_APPEND_LINK_FLAGS([-Wl,-z,now], [IMMEDIATE_LDFLAGS])
 215 AC_SUBST([IMMEDIATE_LDFLAGS])
 216 AS_CASE([$IMMEDIATE_LDFLAGS],[*-z,now*],
 217     [AC_DEFINE([HAVE_BIND_NOW],[1],
 218                [Define to 1 if immediate binding is available])])
 219
 220 # On ELF systems we don't want the libraries to be unloaded since we don't clean them up properly,
 221 # so we request the nodelete flag to be enabled.
 222 # On other systems, we don't really know how to do that, but it's welcome if somebody can tell.
 223 AX_APPEND_LINK_FLAGS([-Wl,-z,nodelete], [NODELETE_LDFLAGS], [-shared])
 224 AC_SUBST([NODELETE_LDFLAGS])
 225
 226 # Check for the proper way to build libraries that have no undefined symbols
 227 case $host in
 228     # FreeBSD (et al.) does not complete linking for shared objects when pthreads
 229     # are requested, as different implementations are present.
 230     *-freebsd* | *-openbsd*) ;;
 231     *)
 232         for possible_flag in "-Wl,--no-undefined" "-Wl,-z,defs"; do
 233             AX_CHECK_LINK_FLAG([$possible_flag], [NOUNDEFINED_LDFLAGS="$possible_flag"; break])
 234         done
 235     ;;
 236 esac
 237 AC_SUBST([NOUNDEFINED_LDFLAGS])
 238
 239
 240 #### Atomic operations ####
 241
 242 # Native atomic operation support
 243 AC_ARG_ENABLE([atomic-arm-linux-helpers],
 244     AS_HELP_STRING([--disable-atomic-arm-linux-helpers],[use inline asm or libatomic_ops instead]))
 245
 246 AC_ARG_ENABLE([atomic-arm-memory-barrier],
 247     AS_HELP_STRING([--enable-atomic-arm-memory-barrier],[only really needed in SMP arm systems]))
 248
 249 if test "x$enable_atomic_arm_memory_barrier" = "xyes"; then
 250     AC_DEFINE_UNQUOTED(ATOMIC_ARM_MEMORY_BARRIER_ENABLED, 1, [Enable memory barriers])
 251 fi
 252
 253 # If everything else fails use libatomic_ops
 254 need_libatomic_ops=yes
 255
 256 AC_CACHE_CHECK([whether $CC knows __sync_bool_compare_and_swap()],
 257     pulseaudio_cv_sync_bool_compare_and_swap, [
 258     AC_LINK_IFELSE(
 259         [AC_LANG_PROGRAM([], [[int a = 4; __sync_bool_compare_and_swap(&a, 4, 5);]])],
 260         [pulseaudio_cv_sync_bool_compare_and_swap=yes],
 261         [pulseaudio_cv_sync_bool_compare_and_swap=no])
 262     ])
 263
 264 if test "$pulseaudio_cv_sync_bool_compare_and_swap" = "yes" ; then
 265     AC_DEFINE([HAVE_ATOMIC_BUILTINS], 1, [Have __sync_bool_compare_and_swap() and friends.])
 266     need_libatomic_ops=no
 267 else
 268     # HW specific atomic ops stuff
 269     AC_MSG_CHECKING([architecture for native atomic operations])
 270     case $host in
 271         *-netbsd*)
 272             AC_MSG_RESULT([yes])
 273             need_libatomic_ops=no
 274         ;;
 275         arm*)
 276             AC_MSG_RESULT([arm])
 277             AC_MSG_CHECKING([whether we can use Linux kernel helpers])
 278             # The Linux kernel helper functions have been there since 2.6.16. However
 279             # compile time checking for kernel version in cross compile environment
 280             # (which is usually the case for arm cpu) is tricky (or impossible).
 281             if test "x$os_is_linux" = "x1" && test "x$enable_atomic_arm_linux_helpers" != "xno"; then
 282                 AC_MSG_RESULT([yes])
 283                 AC_DEFINE_UNQUOTED(ATOMIC_ARM_LINUX_HELPERS, 1, [special arm linux implementation])
 284                 need_libatomic_ops=no
 285             else
 286                 AC_MSG_RESULT([no])
 287                 AC_CACHE_CHECK([compiler support for arm inline asm atomic operations],
 288                     pulseaudio_cv_support_arm_atomic_ops, [
 289                     AC_COMPILE_IFELSE(
 290                         [AC_LANG_PROGRAM([], [[
 291                             volatile int a=0;
 292                             int o=0, n=1, r;
 293                             asm volatile ("ldrex    %0, [%1]\n"
 294                                           "subs  %0, %0, %2\n"
 295                                           "strexeq %0, %3, [%1]\n"
 296                                           : "=&r" (r)
 297                                           : "r" (&a), "Ir" (o), "r" (n)
 298                                           : "cc");
 299                             return (a==1 ? 0 : -1);
 300                         ]])],
 301                         [pulseaudio_cv_support_arm_atomic_ops=yes],
 302                         [pulseaudio_cv_support_arm_atomic_ops=no])
 303                 ])
 304                 AS_IF([test "$pulseaudio_cv_support_arm_atomic_ops" = "yes"], [
 305                     AC_DEFINE([ATOMIC_ARM_INLINE_ASM], 1, [Have ARM atomic instructions.])
 306                     need_libatomic_ops=no
 307                 ])
 308             fi
 309         ;;
 310         *-freebsd*)
 311             AC_MSG_RESULT([yes])
 312             need_libatomic_ops=no
 313         ;;
 314         *)
 315             AC_MSG_RESULT([unknown])
 316         ;;
 317     esac
 318 fi
 319
 320 # If we're on ARM, check for the ARMV6 instructions we need */
 321 case $host in
 322   arm*)
 323     AC_CACHE_CHECK([support for required armv6 instructions],
 324       pulseaudio_cv_support_armv6,
 325       [AC_COMPILE_IFELSE(
 326          [AC_LANG_PROGRAM([],
 327            [[volatile int a = -60000, b = 0xaaaabbbb, c = 0xccccdddd;
 328              asm volatile ("ldr r0, %2 \n"
 329                            "ldr r2, %3 \n"
 330                            "ldr r3, %4 \n"
 331                            "ssat r1, #8, r0 \n"
 332                            "str r1, %0 \n"
 333                            "pkhbt r1, r3, r2, LSL #8 \n"
 334                            "str r1, %1 \n"
 335                            : "=m" (a), "=m" (b)
 336                            : "m" (a), "m" (b), "m" (c)
 337                            : "r0", "r1", "r2", "r3", "cc");
 338              return (a == -128 && b == 0xaabbdddd) ? 0 : -1;
 339            ]])],
 340          [pulseaudio_cv_support_armv6=yes],
 341          [pulseaudio_cv_support_armv6=no])
 342       ])
 343     AS_IF([test "$pulseaudio_cv_support_armv6" = "yes"], [
 344         AC_DEFINE([HAVE_ARMV6], 1, [Have ARMv6 instructions.])
 345       ])
 346   ;;
 347   *)
 348   ;;
 349 esac
 350
 351 #### NEON optimisations ####
 352 AC_ARG_ENABLE([neon-opt],
 353     AS_HELP_STRING([--enable-neon-opt], [Enable NEON optimisations on ARM CPUs that support it]))
 354
 355 AS_IF([test "x$enable_neon_opt" != "xno"],
 356     [save_CFLAGS="$CFLAGS"; CFLAGS="-mfpu=neon $CFLAGS"
 357      AC_COMPILE_IFELSE(
 358         [AC_LANG_PROGRAM([[#include <arm_neon.h>]], [])],
 359         [
 360          HAVE_NEON=1
 361          NEON_CFLAGS="-mfpu=neon"
 362         ],
 363         [
 364          HAVE_NEON=0
 365          NEON_CFLAGS=
 366         ])
 367      CFLAGS="$save_CFLAGS"
 368     ],
 369     [HAVE_NEON=0])
 370
 371 AS_IF([test "x$enable_neon_opt" = "xyes" && test "x$HAVE_NEON" = "x0"],
 372       [AC_MSG_ERROR([*** Compiler does not support -mfpu=neon or CFLAGS override -mfpu])])
 373
 374 AC_SUBST(HAVE_NEON)
 375 AC_SUBST(NEON_CFLAGS)
 376 AM_CONDITIONAL([HAVE_NEON], [test "x$HAVE_NEON" = x1])
 377 AS_IF([test "x$HAVE_NEON" = "x1"], AC_DEFINE([HAVE_NEON], 1, [Have NEON support?]))
 378
 379
 380 #### libtool stuff ####
 381
 382 LT_PREREQ(2.4)
 383 LT_INIT([dlopen win32-dll disable-static])
 384
 385 dnl As an extra safety device, check for lt_dladvise_init() which is
 386 dnl only implemented in libtool 2.x, and refine as we go if we have
 387 dnl refined requirements.
 388 dnl
 389 dnl Check the header files first since the system may have a
 390 dnl libltdl.so for runtime, but no headers, and we want to bail out as
 391 dnl soon as possible.
 392 dnl
 393 dnl We don't need any special variable for this though, since the user
 394 dnl can give the proper place to find libltdl through the standard
 395 dnl variables like LDFLAGS and CPPFLAGS.
 396
 397 AC_CHECK_HEADER([ltdl.h],
 398     [AC_CHECK_LIB([ltdl], [lt_dladvise_init], [LIBLTDL=-lltdl], [LIBLTDL=])],
 399     [LIBLTDL=])
 400
 401 AS_IF([test "x$LIBLTDL" = "x"],
 402     [AC_MSG_ERROR([Unable to find libltdl version 2. Makes sure you have libtool 2.4 or later installed.])])
 403 AC_SUBST([LIBLTDL])
 404
 405
 406 ###################################
 407 #   Basic environment checks      #
 408 ###################################
 409
 410 #### Checks for header files. ####
 411
 412 # ISO
 413 AC_HEADER_STDC
 414
 415 # POSIX
 416 AC_CHECK_HEADERS_ONCE([arpa/inet.h cpuid.h glob.h grp.h netdb.h netinet/in.h \
 417     netinet/in_systm.h netinet/tcp.h poll.h pwd.h sched.h \
 418     sys/mman.h sys/select.h sys/socket.h sys/wait.h \
 419     sys/uio.h syslog.h sys/dl.h dlfcn.h linux/sockios.h])
 420 AC_CHECK_HEADERS([netinet/ip.h], [], [],
 421                  [#include <sys/types.h>
 422                   #if HAVE_NETINET_IN_H
 423                   # include <netinet/in.h>
 424                   #endif
 425                   #if HAVE_NETINET_IN_SYSTM_H
 426                   # include <netinet/in_systm.h>
 427                   #endif
 428                  ])
 429 AC_CHECK_HEADERS([sys/resource.h], [HAVE_SYS_RESOURCE_H=1], [HAVE_SYS_RESOURCE_H=0])
 430 AC_SUBST(HAVE_SYS_RESOURCE_H)
 431 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 432 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 433 AC_SUBST(HAVE_AF_UNIX)
 434
 435 # Linux
 436 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 437 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 438
 439 AC_CHECK_HEADERS_ONCE([sys/prctl.h])
 440
 441 # Solaris
 442 AC_CHECK_HEADERS_ONCE([sys/conf.h sys/filio.h])
 443
 444 # Windows
 445 AC_CHECK_HEADERS_ONCE([windows.h winsock2.h ws2tcpip.h])
 446
 447 # NetBSD
 448 AC_CHECK_HEADERS_ONCE([sys/atomic.h])
 449
 450 # Other
 451 AC_CHECK_HEADERS_ONCE([sys/ioctl.h])
 452 AC_CHECK_HEADERS_ONCE([byteswap.h])
 453 AC_CHECK_HEADERS_ONCE([sys/syscall.h])
 454 AC_CHECK_HEADERS_ONCE([sys/eventfd.h])
 455 AC_CHECK_HEADERS_ONCE([execinfo.h])
 456 AC_CHECK_HEADERS_ONCE([langinfo.h])
 457 AC_CHECK_HEADERS_ONCE([regex.h pcreposix.h])
 458 AC_CHECK_HEADERS_ONCE([locale.h xlocale.h])
 459
 460 AM_CONDITIONAL(HAVE_SYS_EVENTFD_H, test "x$ac_cv_header_sys_eventfd_h" = "xyes")
 461
 462 #### Typdefs, structures, etc. ####
 463
 464 AC_C_CONST
 465 AC_C_BIGENDIAN
 466 AC_TYPE_PID_T
 467 AC_TYPE_SIZE_T
 468 AC_CHECK_TYPES(ssize_t, , AC_DEFINE([ssize_t], [signed long], [Define ssize_t if it is not done by the standard libs.]))
 469 AC_TYPE_OFF_T
 470
 471 AC_TYPE_UID_T
 472 AC_CHECK_DECLS(environ)
 473
 474 AC_CHECK_SIZEOF(void*)
 475
 476 fast_64bit_operations="no"
 477 # This check covers x32-ABI
 478 AC_CHECK_DECL([__x86_64__], [fast_64bit_operations="yes"], [], [])
 479 if test "x$fast_64bit_operations" = "xno"; then
 480     AS_IF([test $ac_cv_sizeof_voidp -ge 8], [fast_64bit_operations="yes"])
 481 fi
 482
 483 AS_IF([test "x$fast_64bit_operations" = "xyes"], AC_DEFINE([HAVE_FAST_64BIT_OPERATIONS], 1, [Have CPU with fast 64-bit operations?]))
 484
 485 # SIGXCPU
 486 AX_CHECK_DEFINE([signal.h], [SIGXCPU], [HAVE_SIGXCPU=1], [HAVE_SIGXCPU=0])
 487 AS_IF([test "x$HAVE_SIGXCPU" = "x1"], AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?]))
 488 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 489
 490 # INADDR_NONE, Solaris lacks this
 491 AX_CHECK_DEFINE([netinet/in.h], [INADDR_NONE], [],
 492     [AX_CHECK_DEFINE([winsock2.h], [INADDR_NONE], [],
 493         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 494
 495
 496 # _Bool
 497 AC_CACHE_CHECK([whether $CC knows _Bool],
 498     pulseaudio_cv__Bool,
 499     [AC_COMPILE_IFELSE(
 500         [AC_LANG_PROGRAM([], [[_Bool b;]])],
 501         [pulseaudio_cv__Bool=yes],
 502         [pulseaudio_cv__Bool=no])
 503     ])
 504
 505 AS_IF([test "$pulseaudio_cv__Bool" = "yes"], AC_DEFINE([HAVE_STD_BOOL], 1, [Have _Bool.]))
 506
 507
 508 #### Check for libs ####
 509
 510 # ISO
 511 AC_SEARCH_LIBS([pow], [m])
 512
 513 # POSIX
 514 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 515 AC_SEARCH_LIBS([dlopen], [dl])
 516 AC_SEARCH_LIBS([shm_open], [rt])
 517 AC_SEARCH_LIBS([inet_ntop], [nsl])
 518 AC_SEARCH_LIBS([timer_create], [rt])
 519 AC_SEARCH_LIBS([pthread_setaffinity_np], [pthread])
 520 AC_SEARCH_LIBS([pthread_getname_np], [pthread])
 521 AC_SEARCH_LIBS([pthread_setname_np], [pthread])
 522
 523 # BSD
 524 AC_SEARCH_LIBS([connect], [socket])
 525 AC_SEARCH_LIBS([backtrace], [execinfo ubacktrace])
 526
 527 # Darwin/OS X
 528 if test "x$os_is_darwin" = "x1" ; then
 529     AC_MSG_CHECKING([looking for Apple CoreService Framework])
 530     AC_CHECK_HEADER([CoreServices/CoreServices.h],
 531         [LIBS="$LIBS -framework CoreServices"],
 532         [AC_MSG_ERROR([CoreServices.h header file not found])]
 533     )
 534
 535     AC_MSG_RESULT([ok])
 536     AC_DEFINE([HAVE_CLOCK_GETTIME], 1, [Using clock_gettime() replacement])
 537     HAVE_BONJOUR=1
 538 fi
 539
 540 AM_CONDITIONAL([HAVE_BONJOUR], [test "x$HAVE_BONJOUR" = x1])
 541
 542 # Windows
 543 AC_SEARCH_LIBS([regexec], [pcreposix])
 544 # This magic is needed so we do not needlessly add static libs to the win32  build, disabling its ability to make dlls.
 545 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 546
 547
 548 #### Check for functions ####
 549
 550 # ISO
 551 AC_CHECK_FUNCS_ONCE([lrintf strtof])
 552
 553 # POSIX
 554 AC_FUNC_FORK
 555 AC_FUNC_GETGROUPS
 556 AC_CHECK_FUNCS_ONCE([chmod chown fstat fchown fchmod clock_gettime getaddrinfo getgrgid_r getgrnam_r \
 557     getpwnam_r getpwuid_r gettimeofday getuid mlock nanosleep \
 558     pipe posix_fadvise posix_madvise posix_memalign setpgid setsid shm_open \
 559     sigaction sleep symlink sysconf uname pthread_setaffinity_np pthread_getname_np pthread_setname_np])
 560 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 561 AC_SUBST(HAVE_MKFIFO)
 562 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 563
 564 # X/OPEN
 565 AC_CHECK_FUNCS_ONCE([readlink])
 566
 567 # SUSv2
 568 AC_CHECK_FUNCS_ONCE([ctime_r usleep])
 569
 570 # SUSv3
 571 AC_CHECK_FUNCS_ONCE([strerror_r])
 572
 573 # BSD
 574 AC_CHECK_FUNCS_ONCE([lstat paccept])
 575
 576 # Non-standard
 577 AC_CHECK_FUNCS_ONCE([setresuid setresgid setreuid setregid seteuid setegid ppoll strsignal sig2str strtod_l pipe2 accept4])
 578
 579 AC_FUNC_ALLOCA
 580
 581 AC_CHECK_FUNCS([regexec], [HAVE_REGEX=1], [HAVE_REGEX=0])
 582 AM_CONDITIONAL(HAVE_REGEX, [test "x$HAVE_REGEX" = "x1"])
 583
 584 # Large File-Support (LFS)
 585 AC_SYS_LARGEFILE
 586 # Check for open64 to know if the current system does have open64() and similar functions
 587 AC_CHECK_FUNCS_ONCE([open64])
 588
 589 AC_SEARCH_LIBS([dladdr], [dl], [HAVE_DLADDR=1], [HAVE_DLADDR=0])
 590 AC_DEFINE(HAVE_DLADDR, [1], [Have dladdr?])
 591
 592 ###################################
 593 #      External libraries         #
 594 ###################################
 595
 596 #### [lib]iconv ####
 597
 598 AM_ICONV
 599
 600 #### Linux memfd_create(2) SHM support ####
 601
 602 AC_ARG_ENABLE([memfd],
 603     AS_HELP_STRING([--disable-memfd], [Disable Linux memfd shared memory]))
 604
 605 AS_IF([test "x$enable_memfd" != "xno"],
 606     AC_CHECK_DECL(SYS_memfd_create, [HAVE_MEMFD=1], [HAVE_MEMFD=0], [#include <sys/syscall.h>]),
 607     [HAVE_MEMFD=0])
 608
 609 AS_IF([test "x$enable_memfd" = "xyes" && test "x$HAVE_MEMFD" = "x0"],
 610     [AC_MSG_ERROR([*** Your Linux kernel does not support memfd shared memory.
 611                   *** Use linux v3.17 or higher for such a feature.])])
 612
 613 AS_IF([test "x$HAVE_MEMFD" = "x1"],
 614     AC_CHECK_FUNCS([memfd_create]))
 615
 616 AC_SUBST(HAVE_MEMFD)
 617 AM_CONDITIONAL([HAVE_MEMFD], [test "x$HAVE_MEMFD" = x1])
 618 AS_IF([test "x$HAVE_MEMFD" = "x1"], AC_DEFINE([HAVE_MEMFD], 1, [Have memfd shared memory.]))
 619
 620 #### X11 (optional) ####
 621
 622 AC_ARG_ENABLE([x11],
 623     AS_HELP_STRING([--disable-x11],[Disable optional X11 support]))
 624
 625 AS_IF([test "x$enable_x11" != "xno"],
 626     [PKG_CHECK_MODULES(X11, [ x11-xcb xcb >= 1.6 ice sm xtst ], HAVE_X11=1, HAVE_X11=0)],
 627     HAVE_X11=0)
 628
 629 AS_IF([test "x$enable_x11" = "xyes" && test "x$HAVE_X11" = "x0"],
 630     [AC_MSG_ERROR([*** X11 not found])])
 631
 632 AC_SUBST(HAVE_X11)
 633 AM_CONDITIONAL([HAVE_X11], [test "x$HAVE_X11" = x1])
 634 AS_IF([test "x$HAVE_X11" = "x1"], AC_DEFINE([HAVE_X11], 1, [Have X11?]))
 635
 636 #### Capabilities (optional) ####
 637
 638 CAP_LIBS=''
 639
 640 AC_ARG_WITH([caps],
 641     AS_HELP_STRING([--without-caps],[Omit support for dropping capabilities.]))
 642
 643 if test "x${with_caps}" != "xno"; then
 644     AC_SEARCH_LIBS([cap_init], [cap], [], [])
 645
 646     # Only give an error on hosts that we know could support capabilities
 647     AC_CHECK_HEADERS([sys/capability.h], [], [
 648       if test "${host_has_caps}" = "1"; then
 649         AC_MSG_ERROR([*** sys/capability.h not found.  Use --without-caps to disable capabilities support.])
 650       fi])
 651 fi
 652
 653 #### Valgrind (optional) ####
 654
 655 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h])
 656
 657 #### check unit tests ####
 658
 659 AC_ARG_ENABLE([tests],
 660     AS_HELP_STRING([--disable-tests],[Disable unit tests]))
 661
 662 AS_IF([test "x$enable_tests" != "xno"],
 663     [PKG_CHECK_MODULES(LIBCHECK, [ check >= 0.9.10 ], HAVE_LIBCHECK=1, HAVE_LIBCHECK=0)],
 664     HAVE_LIBCHECK=0)
 665
 666 AS_IF([test "x$enable_tests" = "xyes" && test "x$HAVE_LIBCHECK" = "x0"],
 667     [AC_MSG_ERROR([*** check library not found or too old])])
 668
 669 AM_CONDITIONAL([HAVE_TESTS], [test "x$HAVE_LIBCHECK" = x1])
 670
 671 #### Sound file ####
 672
 673 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.20 ])
 674
 675 #### atomic-ops ####
 676
 677 AC_MSG_CHECKING([whether we need libatomic_ops])
 678 if test "x$need_libatomic_ops" = "xyes"; then
 679     AC_MSG_RESULT([yes])
 680     AC_CHECK_HEADERS([atomic_ops.h],
 681         [CFLAGS="$CFLAGS -DAO_REQUIRE_CAS"],
 682         [AC_MSG_ERROR([*** libatomic-ops headers not found])])
 683
 684     # Win32 does not need the lib and breaks horribly if we try to include it
 685     AS_IF([test "x$os_is_win32" != "x1"], [LIBS="$LIBS -latomic_ops"])
 686 else
 687     AC_MSG_RESULT([no])
 688 fi
 689
 690 #### Libsamplerate support (optional) ####
 691
 692 AC_ARG_ENABLE([samplerate],
 693     AS_HELP_STRING([--enable-samplerate],[Enable optional libsamplerate support (DEPRECATED)]))
 694
 695 AS_IF([test "x$enable_samplerate" = "xyes"],
 696     [PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ], HAVE_LIBSAMPLERATE=1, HAVE_LIBSAMPLERATE=0)],
 697     HAVE_LIBSAMPLERATE=0)
 698
 699 AS_IF([test "x$enable_samplerate" = "xyes" && test "x$HAVE_LIBSAMPLERATE" = "x0"],
 700     [AC_MSG_ERROR([*** Libsamplerate not found])])
 701
 702 AM_CONDITIONAL([HAVE_LIBSAMPLERATE], [test "x$HAVE_LIBSAMPLERATE" = x1])
 703 AS_IF([test "x$HAVE_LIBSAMPLERATE" = "x1"], AC_DEFINE([HAVE_LIBSAMPLERATE], 1, [Have libsamplerate?]))
 704
 705 AS_IF([test "x$HAVE_LIBSAMPLERATE" = "x1"], AC_MSG_WARN([Support for libsamplerate is DEPRECATED]))
 706
 707 #### Database support ####
 708
 709 AC_ARG_WITH([database],
 710     AS_HELP_STRING([--with-database=auto|tdb|gdbm|simple],[Choose database backend.]),[],[with_database=auto])
 711
 712
 713 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xtdb"],
 714     [PKG_CHECK_MODULES(TDB, [ tdb ], HAVE_TDB=1, HAVE_TDB=0)],
 715     HAVE_TDB=0)
 716 AS_IF([test "x$HAVE_TDB" = "x1"], with_database=tdb)
 717
 718 AS_IF([test "x$with_database" = "xtdb" && test "x$HAVE_TDB" = "x0"],
 719     [AC_MSG_ERROR([*** tdb not found])])
 720
 721
 722 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xgdbm"],
 723     [
 724         HAVE_GDBM=1
 725         AC_CHECK_LIB(gdbm, gdbm_open, [], HAVE_GDBM=0)
 726         AC_CHECK_HEADERS(gdbm.h, [], HAVE_GDBM=0)
 727     ],
 728     HAVE_GDBM=0)
 729 AS_IF([test "x$HAVE_GDBM" = "x1"],
 730     [
 731         with_database=gdbm
 732         GDBM_CFLAGS=
 733         GDBM_LIBS=-lgdbm
 734     ])
 735
 736 AS_IF([test "x$with_database" = "xgdbm" && test "x$HAVE_GDBM" = "x0"],
 737     [AC_MSG_ERROR([*** gdbm not found])])
 738
 739
 740 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xsimple"],
 741     HAVE_SIMPLEDB=1,
 742     HAVE_SIMPLEDB=0)
 743 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], with_database=simple)
 744
 745 AS_IF([test "x$HAVE_TDB" != x1 -a "x$HAVE_GDBM" != x1 -a "x$HAVE_SIMPLEDB" != x1],
 746     AC_MSG_ERROR([*** missing database backend]))
 747
 748
 749 AM_CONDITIONAL([HAVE_TDB], [test "x$HAVE_TDB" = x1])
 750 AS_IF([test "x$HAVE_TDB" = "x1"], AC_DEFINE([HAVE_TDB], 1, [Have tdb?]))
 751
 752 AC_SUBST(GDBM_CFLAGS)
 753 AC_SUBST(GDBM_LIBS)
 754 AM_CONDITIONAL([HAVE_GDBM], [test "x$HAVE_GDBM" = x1])
 755 AS_IF([test "x$HAVE_GDBM" = "x1"], AC_DEFINE([HAVE_GDBM], 1, [Have gdbm?]))
 756
 757 AM_CONDITIONAL([HAVE_SIMPLEDB], [test "x$HAVE_SIMPLEDB" = x1])
 758 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], AC_DEFINE([HAVE_SIMPLEDB], 1, [Have simple?]))
 759
 760 #### OSS support (optional) ####
 761
 762 AC_ARG_ENABLE([oss-output],
 763     AS_HELP_STRING([--disable-oss-output],[Disable optional OSS output support]))
 764
 765 AC_ARG_ENABLE([oss-wrapper],
 766     AS_HELP_STRING([--disable-oss-wrapper],[Disable optional OSS wrapper support]))
 767
 768 AC_ARG_WITH([pulsedsp-location],
 769     AS_HELP_STRING([--with-pulsedsp-location],[Specify location where OSS wrapper will be installed]))
 770
 771 AS_IF([test "x$enable_oss_output" != "xno" -o "x$enable_oss_wrapper" != "xno"],
 772     [AC_CHECK_HEADERS([sys/soundcard.h], HAVE_OSS=1, HAVE_OSS=0)],
 773     HAVE_OSS=0)
 774
 775 AS_IF([test "x$enable_oss_output" = "xyes" -o "x$enable_oss_wrapper" = "xyes" && test "x$HAVE_OSS" = "x0"],
 776     [AC_MSG_ERROR([*** OSS support not found])])
 777
 778 AS_IF([test "x$enable_oss_output" != "xno"],
 779     [AS_IF([test "x$HAVE_OSS" = "x1"], HAVE_OSS_OUTPUT=1, HAVE_OSS_OUTPUT=0)],
 780     HAVE_OSS_OUTPUT=0)
 781
 782 AS_IF([test "x$enable_oss_wrapper" != "xno"],
 783     [AS_IF([test "x$HAVE_OSS" = "x1"], HAVE_OSS_WRAPPER=1, HAVE_OSS_WRAPPER=0)],
 784     HAVE_OSS_WRAPPER=0)
 785
 786 AS_IF([test "x$with_pulsedsp_location" != "x"],
 787     [PULSEDSP_LOCATION="$with_pulsedsp_location"],
 788     [PULSEDSP_LOCATION="\$(pkglibdir)"])
 789
 790 AC_SUBST(HAVE_OSS_OUTPUT)
 791 AC_SUBST(PULSEDSP_LOCATION)
 792 AM_CONDITIONAL([HAVE_OSS_OUTPUT], [test "x$HAVE_OSS_OUTPUT" = "x1"])
 793 AM_CONDITIONAL([HAVE_OSS_WRAPPER], [test "x$HAVE_OSS_WRAPPER" = "x1"])
 794 AS_IF([test "x$HAVE_OSS_OUTPUT" = "x1"], AC_DEFINE([HAVE_OSS_OUTPUT], 1, [Have OSS output?]))
 795 AS_IF([test "x$HAVE_OSS_WRAPPER" = "x1"], AC_DEFINE([HAVE_OSS_WRAPPER], 1, [Have OSS wrapper (padsp)?]))
 796
 797 # Some platforms like SunOS (Illumos) may ship without SOUND_PCM_* functionality
 798 if test "x$HAVE_OSS" = "x1"; then
 799     AC_CHECK_DECLS([SOUND_PCM_READ_RATE], [], [], [[#include <sys/soundcard.h>]])
 800     AC_CHECK_DECLS([SOUND_PCM_READ_CHANNELS], [], [], [[#include <sys/soundcard.h>]])
 801     AC_CHECK_DECLS([SOUND_PCM_READ_BITS], [], [], [[#include <sys/soundcard.h>]])
 802 fi
 803
 804 #### CoreAudio support (optional) ####
 805
 806 AC_ARG_ENABLE([coreaudio-output],
 807     AS_HELP_STRING([--disable-coreaudio-output],[Disable optional CoreAudio output support]))
 808
 809 AS_IF([test "x$enable_coreaudio_output" != "xno"],
 810     [AC_CHECK_HEADERS([CoreAudio/CoreAudio.h], HAVE_COREAUDIO=1, HAVE_COREAUDIO=0)],
 811     HAVE_COREAUDIO=0)
 812
 813 AS_IF([test "x$enable_coreaudio_output" = "xyes" && test "x$HAVE_COREAUDIO" = "x0"],
 814     [AC_MSG_ERROR([*** CoreAudio output support not found])])
 815
 816 AC_SUBST(HAVE_COREAUDIO)
 817 AM_CONDITIONAL([HAVE_COREAUDIO], [test "x$HAVE_COREAUDIO" = "x1" && test "x$enable_coreaudio_output" != "xno"])
 818
 819 AS_IF([test "x$HAVE_COREAUDIO" = "x1"], AC_DEFINE([HAVE_COREAUDIO], 1, [Have CoreAudio?]))
 820
 821 #### ALSA support (optional) ####
 822
 823 AC_ARG_ENABLE([alsa],
 824     AS_HELP_STRING([--disable-alsa],[Disable optional ALSA support]))
 825
 826 AS_IF([test "x$enable_alsa" != "xno"],
 827     [PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.19 ], HAVE_ALSA=1, HAVE_ALSA=0)],
 828     HAVE_ALSA=0)
 829
 830 AS_IF([test "x$enable_alsa" = "xyes" && test "x$HAVE_ALSA" = "x0"],
 831     [AC_MSG_ERROR([*** Needed alsa >= 1.0.19 support not found])])
 832
 833 AS_IF([test "x$HAVE_ALSA" = "x1"],
 834     [
 835         save_CPPFLAGS="$CPPFLAGS"; CPPFLAGS="$CPPFLAGS $ASOUNDLIB_CFLAGS"
 836         AC_CHECK_HEADERS([use-case.h], HAVE_ALSA_UCM=1, HAVE_ALSA_UCM=0)
 837         CPPFLAGS="$save_CPPFLAGS"
 838     ],
 839     HAVE_ALSA_UCM=0)
 840
 841 AC_SUBST(HAVE_ALSA)
 842 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 843 AS_IF([test "x$HAVE_ALSA" = "x1"], AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?]))
 844 AS_IF([test "x$HAVE_ALSA_UCM" = "x1"], AC_DEFINE([HAVE_ALSA_UCM], 1, [Have ALSA UCM?]))
 845
 846 #### EsounD support (optional) ####
 847
 848 AC_ARG_ENABLE([esound],
 849     AS_HELP_STRING([--disable-esound],[Disable optional EsounD support]))
 850 AM_CONDITIONAL([HAVE_ESOUND], [test "x$enable_esound" != "xno"])
 851 AS_IF([test "x$enable_esound" != "xno"], [HAVE_ESOUND=1])
 852
 853 #### Solaris audio support (optional) ####
 854
 855 AC_ARG_ENABLE([solaris],
 856     AS_HELP_STRING([--disable-solaris],[Disable optional Solaris audio support]))
 857
 858 AS_IF([test "x$enable_solaris" != "xno"],
 859     [AC_CHECK_HEADERS([sys/audio.h], HAVE_SOLARIS=1, HAVE_SOLARIS=0)],
 860     HAVE_SOLARIS=0)
 861
 862 AS_IF([test "x$enable_solaris" = "xyes" && test "x$HAVE_SOLARIS" = "x0"],
 863     [AC_MSG_ERROR([*** Solaris audio support not found])])
 864
 865 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 866 AS_IF([test "x$HAVE_SOLARIS" = "x1"], AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?]))
 867
 868 #### WaveOut audio support (optional) ####
 869
 870 AC_ARG_ENABLE([waveout],
 871     AS_HELP_STRING([--disable-waveout],[Disable optional WaveOut audio support]))
 872
 873 AS_IF([test "x$enable_waveout" != "xno"],
 874     [AC_CHECK_HEADERS([mmsystem.h], HAVE_WAVEOUT=1, HAVE_WAVEOUT=0, [#include <windows.h>])],
 875     HAVE_WAVEOUT=0)
 876
 877 AS_IF([test "x$enable_waveout" = "xyes" && test "x$HAVE_WAVEOUT" = "x0"],
 878     [AC_MSG_ERROR([*** WaveOut audio support not found])])
 879
 880 AC_SUBST(HAVE_WAVEOUT)
 881 AM_CONDITIONAL([HAVE_WAVEOUT], [test "x$HAVE_WAVEOUT" = x1])
 882 AS_IF([test "x$HAVE_WAVEOUT" = "x1"], AC_DEFINE([HAVE_WAVEOUT], 1, [Have WaveOut audio?]))
 883
 884 #### GLib 2 support (optional) ####
 885
 886 AC_ARG_ENABLE([glib2],
 887     AS_HELP_STRING([--disable-glib2],[Disable optional GLib 2 support]))
 888
 889 AS_IF([test "x$enable_glib2" != "xno"],
 890     [PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ], HAVE_GLIB20=1, HAVE_GLIB20=0)],
 891     HAVE_GLIB20=0)
 892
 893 AS_IF([test "x$enable_glib2" = "xyes" && test "x$HAVE_GLIB20" = "x0"],
 894     [AC_MSG_ERROR([*** GLib 2 support not found])])
 895
 896 AC_SUBST(HAVE_GLIB20)
 897 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 898 AS_IF([test "x$HAVE_GLIB20" = "x1"], AC_DEFINE([HAVE_GLIB], 1, [Have GLIB?]))
 899
 900 #### GTK3 support (optional) ####
 901
 902 AC_ARG_ENABLE([gtk3],
 903     AS_HELP_STRING([--disable-gtk3],[Disable optional Gtk+ 3 support]))
 904
 905 AS_IF([test "x$enable_gtk3" != "xno"],
 906     [PKG_CHECK_MODULES(GTK30, [ gtk+-3.0 ], HAVE_GTK30=1, HAVE_GTK30=0)],
 907     HAVE_GTK30=0)
 908
 909 AS_IF([test "x$enable_gtk3" = "xyes" && test "x$HAVE_GTK30" = "x0"],
 910     [AC_MSG_ERROR([*** Gtk+ 3 support not found])])
 911
 912 AM_CONDITIONAL([HAVE_GTK30], [test "x$HAVE_GTK30" = x1])
 913 AS_IF([test "x$HAVE_GTK30" = "x1"], AC_DEFINE([HAVE_GTK], 1, [Have GTK?]))
 914
 915 #### GConf support (optional) ####
 916
 917 AC_ARG_ENABLE([gconf],
 918     AS_HELP_STRING([--disable-gconf],[Disable optional GConf support]))
 919
 920 AS_IF([test "x$enable_gconf" != "xno"],
 921     [PKG_CHECK_MODULES(GCONF, [ gconf-2.0 >= 2.4.0 gobject-2.0 ], HAVE_GCONF=1, HAVE_GCONF=0)],
 922     HAVE_GCONF=0)
 923
 924 AS_IF([test "x$enable_gconf" = "xyes" && test "x$HAVE_GCONF" = "x0"],
 925     [AC_MSG_ERROR([*** GConf support not found])])
 926
 927 AM_CONDITIONAL([HAVE_GCONF], [test "x$HAVE_GCONF" = x1])
 928 AC_SUBST([HAVE_GCONF])
 929
 930 #### GSettings support (optional) ####
 931
 932 AC_ARG_ENABLE([gsettings],
 933     AS_HELP_STRING([--enable-gsettings],[Enable optional GSettings support]))
 934
 935 AS_IF([test "x$enable_gsettings" = "xyes"],
 936     [PKG_CHECK_MODULES(GSETTINGS, [ gio-2.0 >= 2.26.0 ], [HAVE_GSETTINGS=1], [HAVE_GSETTINGS=0])],
 937     HAVE_GSETTINGS=0)
 938
 939 AS_IF([test "x$enable_gsettings" = "xyes" && test "x$HAVE_GSETTINGS" = "x0"],
 940     [AC_MSG_ERROR([*** GSettings support not found])])
 941
 942 AM_CONDITIONAL([HAVE_GSETTINGS], [test "x$HAVE_GSETTINGS" = x1])
 943 AC_SUBST([HAVE_GSETTINGS])
 944
 945 if test "x$enable_gsettings" = "xyes" && test "x$HAVE_GSETTINGS" = "x1" ; then
 946     GLIB_GSETTINGS
 947 fi
 948
 949 #### Avahi support (optional) ####
 950
 951 AC_ARG_ENABLE([avahi],
 952     AS_HELP_STRING([--disable-avahi],[Disable optional Avahi support]))
 953
 954 AS_IF([test "x$enable_avahi" != "xno"],
 955     [PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ], HAVE_AVAHI=1, HAVE_AVAHI=0)],
 956     HAVE_AVAHI=0)
 957
 958 AS_IF([test "x$enable_avahi" = "xyes" && test "x$HAVE_AVAHI" = "x0"],
 959     [AC_MSG_ERROR([*** Avahi support not found])])
 960
 961 AC_SUBST(HAVE_AVAHI)
 962 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
 963
 964 #### JACK (optional) ####
 965
 966 AC_ARG_ENABLE([jack],
 967     AS_HELP_STRING([--disable-jack],[Disable optional JACK support]))
 968
 969 AS_IF([test "x$enable_jack" != "xno"],
 970     [PKG_CHECK_MODULES(JACK, [ jack >= 0.117.0 ], HAVE_JACK=1, HAVE_JACK=0)],
 971     HAVE_JACK=0)
 972
 973 AS_IF([test "x$enable_jack" = "xyes" && test "x$HAVE_JACK" = "x0"],
 974     [AC_MSG_ERROR([*** JACK support not found])])
 975
 976 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 977
 978 #### Async DNS support (optional) ####
 979
 980 AC_ARG_ENABLE([asyncns],
 981     AS_HELP_STRING([--disable-asyncns],[Disable optional Async DNS support]))
 982
 983 AS_IF([test "x$enable_asyncns" != "xno"],
 984     [PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ], HAVE_LIBASYNCNS=1, HAVE_LIBASYNCNS=0)],
 985     HAVE_LIBASYNCNS=0)
 986
 987 AS_IF([test "x$enable_asyncns" = "xyes" && test "x$HAVE_LIBASYNCNS" = "x0"],
 988     [AC_MSG_ERROR([*** Async DNS support not found])])
 989
 990 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 991 AS_IF([test "x$HAVE_LIBASYNCNS" = "x1"], AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?]))
 992
 993 #### TCP wrappers (optional) ####
 994
 995 AC_ARG_ENABLE([tcpwrap],
 996     AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]))
 997
 998 AS_IF([test "x$enable_tcpwrap" != "xno"],
 999     [
1000         ACX_LIBWRAP
1001         AS_IF([test "x$LIBWRAP_LIBS" != "x"], HAVE_TCPWRAP=1, HAVE_TCPWRAP=0)
1002     ],
1003     HAVE_TCPWRAP=0)
1004
1005 AS_IF([test "x$enable_tcpwrap" = "xyes" && test "x$HAVE_TCPWRAP" = "x0"],
1006     [AC_MSG_ERROR([*** TCP wrappers support not found])])
1007
1008 AC_SUBST(LIBWRAP_LIBS)
1009
1010 #### LIRC support (optional) ####
1011
1012 AC_ARG_ENABLE([lirc],
1013     AS_HELP_STRING([--disable-lirc],[Disable optional LIRC support]))
1014
1015 LIRC_CFLAGS=
1016 LIRC_LIBS=
1017
1018 AS_IF([test "x$enable_lirc" != "xno"],
1019     [
1020         HAVE_LIRC=1
1021         AC_CHECK_HEADER(lirc/lirc_client.h, [], [HAVE_LIRC=0])
1022         AC_CHECK_LIB(lirc_client, lirc_init, [LIRC_LIBS=-llirc_client], [HAVE_LIRC=0])
1023     ],
1024     HAVE_LIRC=0)
1025
1026 AS_IF([test "x$enable_lirc" = "xyes" && test "x$HAVE_LIRC" = "x0"],
1027     [AC_MSG_ERROR([*** LIRC support not found])])
1028
1029 AC_SUBST(LIRC_CFLAGS)
1030 AC_SUBST(LIRC_LIBS)
1031 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
1032
1033 #### D-Bus support (optional) ####
1034
1035 AC_ARG_ENABLE([dbus],
1036     AS_HELP_STRING([--disable-dbus],[Disable optional D-Bus support]))
1037
1038 AS_IF([test "x$enable_dbus" != "xno"],
1039     [PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.4.12 ], HAVE_DBUS=1, HAVE_DBUS=0)],
1040     HAVE_DBUS=0)
1041
1042 AS_IF([test "x$enable_dbus" = "xyes" && test "x$HAVE_DBUS" = "x0"],
1043     [AC_MSG_ERROR([*** D-Bus not available or too old version])])
1044
1045 AS_IF([test "x$HAVE_DBUS" = "x1"],
1046     [
1047         save_CFLAGS="$CFLAGS"; CFLAGS="$CFLAGS $DBUS_CFLAGS"
1048         save_LIBS="$LIBS"; LIBS="$LIBS $DBUS_LIBS"
1049         AC_CHECK_FUNCS(dbus_watch_get_unix_fd)
1050         CFLAGS="$save_CFLAGS"
1051         LIBS="$save_LIBS"
1052     ])
1053
1054 AC_SUBST(HAVE_DBUS)
1055 AM_CONDITIONAL([HAVE_DBUS], [test "x$HAVE_DBUS" = x1])
1056 AS_IF([test "x$HAVE_DBUS" = "x1"], AC_DEFINE([HAVE_DBUS], 1, [Have D-Bus.]))
1057
1058 PA_MACHINE_ID="${sysconfdir}/machine-id"
1059 AX_DEFINE_DIR(PA_MACHINE_ID, PA_MACHINE_ID, [D-Bus machine-id file])
1060 PA_MACHINE_ID_FALLBACK="${localstatedir}/lib/dbus/machine-id"
1061 AX_DEFINE_DIR(PA_MACHINE_ID_FALLBACK, PA_MACHINE_ID_FALLBACK,
1062               [Fallback machine-id file])
1063
1064 #### BlueZ support (optional, dependent on D-Bus and SBC) ####
1065
1066 AC_ARG_ENABLE([bluez4],
1067     AS_HELP_STRING([--disable-bluez4],[Disable optional BlueZ 4 support]))
1068 AC_ARG_ENABLE([bluez5],
1069     AS_HELP_STRING([--disable-bluez5],[Disable optional BlueZ 5 support]))
1070
1071 ## SBC ##
1072 AS_IF([test "x$enable_bluez4" != "xno" || test "x$enable_bluez5" != "xno"],
1073     [PKG_CHECK_MODULES(SBC, [ sbc >= 1.0 ], HAVE_SBC=1, HAVE_SBC=0)],
1074     HAVE_SBC=0)
1075
1076 ## BlueZ 4 ##
1077 AS_IF([test "x$enable_bluez4" != "xno" && test "x$HAVE_DBUS" = "x1" && test "x$HAVE_SBC" = "x1"], HAVE_BLUEZ_4=1,
1078       HAVE_BLUEZ_4=0)
1079 AS_IF([test "x$enable_bluez4" = "xyes" && test "x$HAVE_BLUEZ_4" != "x1"],
1080     [AC_MSG_ERROR([*** BLUEZ 4 support not found (requires sbc and D-Bus)])])
1081 AC_SUBST(HAVE_BLUEZ_4)
1082 AM_CONDITIONAL([HAVE_BLUEZ_4], [test "x$HAVE_BLUEZ_4" = x1])
1083
1084 ## BlueZ 5 ##
1085 AS_IF([test "x$enable_bluez5" != "xno" && test "x$HAVE_DBUS" = "x1" && test "x$HAVE_SBC" = "x1"], HAVE_BLUEZ_5=1,
1086       HAVE_BLUEZ_5=0)
1087 AS_IF([test "x$enable_bluez5" = "xyes" && test "x$HAVE_BLUEZ_5" != "x1"],
1088     [AC_MSG_ERROR([*** BLUEZ 5 support not found (requires sbc and D-Bus)])])
1089 AC_SUBST(HAVE_BLUEZ_5)
1090 AM_CONDITIONAL([HAVE_BLUEZ_5], [test "x$HAVE_BLUEZ_5" = x1])
1091
1092 AS_IF([test "x$HAVE_BLUEZ_4" = "x1" || test "x$HAVE_BLUEZ_5" = "x1"], HAVE_BLUEZ=1, HAVE_BLUEZ=0)
1093 AC_SUBST(HAVE_BLUEZ)
1094 AM_CONDITIONAL([HAVE_BLUEZ], [test "x$HAVE_BLUEZ" = x1])
1095
1096 ## Bluetooth Headset profiles backend ##
1097
1098 AC_ARG_ENABLE([bluez5-ofono-headset],
1099     AS_HELP_STRING([--disable-bluez5-ofono-headset],[Disable optional ofono headset backend support (Bluez 5)]))
1100 AS_IF([test "x$HAVE_BLUEZ_5" = "x1" && test "x$enable_bluez5_ofono_headset" != "xno"], HAVE_BLUEZ_5_OFONO_HEADSET=1,
1101       HAVE_BLUEZ_5_OFONO_HEADSET=0)
1102 AC_SUBST(HAVE_BLUEZ_5_OFONO_HEADSET)
1103 AM_CONDITIONAL([HAVE_BLUEZ_5_OFONO_HEADSET], [test "x$HAVE_BLUEZ_5_OFONO_HEADSET" = x1])
1104 AS_IF([test "x$HAVE_BLUEZ_5_OFONO_HEADSET" = "x1"], AC_DEFINE([HAVE_BLUEZ_5_OFONO_HEADSET], 1, [Bluez 5 ofono headset backend enabled]))
1105
1106 AC_ARG_ENABLE([bluez5-native-headset],
1107     AS_HELP_STRING([--disable-bluez5-native-headset],[Disable optional native headset backend support (Bluez 5)]))
1108 AS_IF([test "x$HAVE_BLUEZ_5" = "x1" && test "x$enable_bluez5_native_headset" != "xno"],
1109       [PKG_CHECK_MODULES(BLUEZ, [ bluez >= 4.101 ], HAVE_BLUEZ_5_NATIVE_HEADSET=1, HAVE_BLUEZ_5_NATIVE_HEADSET=0)],
1110       HAVE_BLUEZ_5_NATIVE_HEADSET=0)
1111 AS_IF([test "x$enable_bluez5_native_headset" = "xyes" && test "x$HAVE_BLUEZ_5_NATIVE_HEADSET" = "x0"],
1112       [AC_MSG_ERROR([*** BlueZ 5 native headset backend support not available (requires the libbluetooth headers)])])
1113 AC_SUBST(HAVE_BLUEZ_5_NATIVE_HEADSET)
1114 AM_CONDITIONAL([HAVE_BLUEZ_5_NATIVE_HEADSET], [test "x$HAVE_BLUEZ_5_NATIVE_HEADSET" = x1])
1115 AS_IF([test "x$HAVE_BLUEZ_5_NATIVE_HEADSET" = "x1"], AC_DEFINE([HAVE_BLUEZ_5_NATIVE_HEADSET], 1, [Bluez 5 native headset backend enabled]))
1116
1117 #### UDEV support (optional) ####
1118
1119 AC_ARG_ENABLE([udev],
1120     AS_HELP_STRING([--disable-udev],[Disable optional UDEV support]))
1121
1122 AS_IF([test "x$enable_udev" != "xno" -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \)],
1123     [PKG_CHECK_MODULES(UDEV, [ libudev >= 143 ], HAVE_UDEV=1, HAVE_UDEV=0)],
1124     HAVE_UDEV=0)
1125
1126 AS_IF([test "x$enable_udev" = "xyes" && test "x$HAVE_UDEV" = "x0"],
1127     [AC_MSG_ERROR([*** UDEV support not found])])
1128
1129 AC_SUBST(HAVE_UDEV)
1130 AM_CONDITIONAL([HAVE_UDEV], [test "x$HAVE_UDEV" = x1])
1131 AS_IF([test "x$HAVE_UDEV" = "x1"], AC_DEFINE([HAVE_UDEV], 1, [Have UDEV.]))
1132
1133 #### HAL compat support (optional, dependent on UDEV) ####
1134
1135 AC_ARG_ENABLE([hal-compat],
1136     AS_HELP_STRING([--disable-hal-compat],[Disable optional HAL->udev transition compatibility support]))
1137
1138 AS_IF([test "x$enable_hal_compat" != "xno"],
1139     [AS_IF([test "x$HAVE_UDEV" = "x1"], HAVE_HAL_COMPAT=1, HAVE_HAL_COMPAT=0)],
1140     HAVE_HAL_COMPAT=0)
1141
1142 AM_CONDITIONAL([HAVE_HAL_COMPAT], [test "x$HAVE_HAL_COMPAT" = x1])
1143 AS_IF([test "x$HAVE_HAL_COMPAT" = "x1"], AC_DEFINE([HAVE_HAL_COMPAT], 1, [Have HAL compatibility.]))
1144
1145 #### IPv6 connection support (optional) ####
1146
1147 AC_ARG_ENABLE([ipv6],
1148     AS_HELP_STRING([--disable-ipv6],[Disable optional IPv6 support]))
1149
1150 AS_IF([test "x$enable_ipv6" != "xno"], [HAVE_IPV6=1], [HAVE_IPV6=0])
1151
1152 AS_IF([test "x$HAVE_IPV6" = "x1"], AC_DEFINE([HAVE_IPV6], 1, [Define this to enable IPv6 connection support]))
1153
1154 #### OpenSSL support (optional) ####
1155
1156 AC_ARG_ENABLE([openssl],
1157     AS_HELP_STRING([--disable-openssl],[Disable OpenSSL support (used for Airtunes/RAOP)]))
1158
1159 AS_IF([test "x$enable_openssl" != "xno"],
1160     [PKG_CHECK_MODULES(OPENSSL, [ openssl > 0.9 ], HAVE_OPENSSL=1, HAVE_OPENSSL=0)],
1161     HAVE_OPENSSL=0)
1162
1163 AS_IF([test "x$enable_openssl" = "xyes" && test "x$HAVE_OPENSSL" = "x0"],
1164     [AC_MSG_ERROR([*** OpenSSL support not found])])
1165
1166 AM_CONDITIONAL([HAVE_OPENSSL], [test "x$HAVE_OPENSSL" = x1])
1167 AS_IF([test "x$HAVE_OPENSSL" = "x1"], AC_DEFINE([HAVE_OPENSSL], 1, [Have OpenSSL]))
1168
1169 #### FFTW (optional) ####
1170
1171 AC_ARG_WITH([fftw],
1172     AS_HELP_STRING([--without-fftw],[Omit FFTW-using modules (equalizer)]))
1173
1174 AS_IF([test "x$with_fftw" != "xno"],
1175     [PKG_CHECK_MODULES(FFTW, [ fftw3f ], HAVE_FFTW=1, HAVE_FFTW=0)],
1176     HAVE_FFTW=0)
1177
1178 AS_IF([test "x$with_fftw" = "xyes" && test "x$HAVE_FFTW" = "x0"],
1179     [AC_MSG_ERROR([*** FFTW support not found])])
1180
1181 AM_CONDITIONAL([HAVE_FFTW], [test "x$HAVE_FFTW" = "x1"])
1182
1183 #### speex (optional) ####
1184
1185 AC_ARG_WITH([speex],
1186     AS_HELP_STRING([--without-speex],[Omit speex (resampling, AEC)]))
1187
1188 AS_IF([test "x$with_speex" != "xno"],
1189     [PKG_CHECK_MODULES(LIBSPEEX, [ speexdsp >= 1.2 ], HAVE_SPEEX=1, HAVE_SPEEX=0)],
1190     HAVE_SPEEX=0)
1191
1192 AS_IF([test "x$with_speex" = "xyes" && test "x$HAVE_SPEEX" = "x0"],
1193     [AC_MSG_ERROR([*** speex support not found])])
1194
1195 AM_CONDITIONAL([HAVE_SPEEX], [test "x$HAVE_SPEEX" = "x1"])
1196 AS_IF([test "x$HAVE_SPEEX" = "x1"], AC_DEFINE([HAVE_SPEEX], 1, [Have speex]))
1197
1198 #### soxr (optional) ####
1199
1200 AC_ARG_WITH([soxr],
1201     AS_HELP_STRING([--without-soxr],[Omit soxr (resampling)]))
1202
1203 AS_IF([test "x$with_soxr" != "xno"],
1204     [PKG_CHECK_MODULES(LIBSOXR, [ soxr >= 0.1.1 ], HAVE_SOXR=1, HAVE_SOXR=0)],
1205     HAVE_SOXR=0)
1206
1207 AS_IF([test "x$with_soxr" = "xyes" && test "x$HAVE_SOXR" = "x0"],
1208     [AC_MSG_ERROR([*** soxr support not found])])
1209
1210 AM_CONDITIONAL([HAVE_SOXR], [test "x$HAVE_SOXR" = "x1"])
1211 AS_IF([test "x$HAVE_SOXR" = "x1"], AC_DEFINE([HAVE_SOXR], 1, [Have soxr]))
1212
1213
1214 #### gcov support (optional) #####
1215
1216 AC_ARG_ENABLE([gcov],
1217     AS_HELP_STRING([--enable-gcov],[Enable optional gcov coverage analysis]))
1218
1219 GCOV_CFLAGS=
1220 GCOV_LIBS=" -lgcov"
1221
1222 AS_IF([test "x$enable_gcov" = "xyes"],
1223     [
1224         HAVE_GCOV=1
1225         GCOV_CFLAGS="$GCOV_CFLAGS -fprofile-arcs -ftest-coverage"
1226         GCOV_LIBS="$GCOV_LIBS -fprofile-arcs"
1227     ],
1228     HAVE_GCOV=0)
1229
1230 AC_SUBST(GCOV_CFLAGS)
1231 AC_SUBST(GCOV_LIBS)
1232 AM_CONDITIONAL([HAVE_GCOV], [test "x$HAVE_GCOV" = x1])
1233
1234 #### ORC (optional) ####
1235
1236 ORC_CHECK([0.4.11])
1237
1238 #### systemd support (optional) ####
1239
1240 AC_ARG_ENABLE([systemd-daemon],
1241     AS_HELP_STRING([--disable-systemd-daemon],[Disable optional systemd daemon (socket activation) support]))
1242
1243 AC_ARG_ENABLE([systemd-login],
1244     AS_HELP_STRING([--disable-systemd-login],[Disable optional systemd login support]))
1245
1246 AC_ARG_ENABLE([systemd-journal],
1247     AS_HELP_STRING([--disable-systemd-journal],[Disable optional systemd journal support]))
1248
1249 # Newer systemd's combine their subcomponent libraries into one
1250 # If it exists, we should use it for the further checks
1251
1252 AS_IF([test "x$enable_systemd_daemon" != "xno" || test "x$enable_systemd_login" != "xno" || test "x$enable_systemd_journal" != "xno"],
1253     [PKG_CHECK_MODULES(SYSTEMD, [ libsystemd ], HAVE_SYSTEMD=1, HAVE_SYSTEMD=0)],
1254     HAVE_SYSTEMD=0)
1255
1256 AS_IF([test "x$HAVE_SYSTEMD" = "x1"],
1257     [
1258         HAVE_SYSTEMD_DAEMON=1
1259         HAVE_SYSTEMD_LOGIN=1
1260         HAVE_SYSTEMD_JOURNAL=1
1261     ])
1262
1263 AC_ARG_WITH([systemduserunitdir],
1264         AS_HELP_STRING([--with-systemduserunitdir=DIR], [Directory for systemd user service files]),
1265         [], [with_systemduserunitdir=$($PKG_CONFIG --variable=systemduserunitdir systemd)])
1266 if test "x$with_systemduserunitdir" != xno; then
1267         AC_SUBST([systemduserunitdir], [$with_systemduserunitdir])
1268 fi
1269
1270 #### systemd daemon support (optional) ####
1271
1272 AS_IF([test "x$enable_systemd_daemon" != "xno"],
1273     [AS_IF([test "x$HAVE_SYSTEMD_DAEMON" != "x1"], [PKG_CHECK_MODULES(SYSTEMDDAEMON, [ libsystemd-daemon ], HAVE_SYSTEMD_DAEMON=1, HAVE_SYSTEMD_DAEMON=0)])],
1274     HAVE_SYSTEMD_DAEMON=0)
1275
1276 AS_IF([test "x$enable_systemd_daemon" = "xyes" && test "x$HAVE_SYSTEMD_DAEMON" = "x0"],
1277     [AC_MSG_ERROR([*** Needed systemd daemon support not found])])
1278
1279 AC_SUBST(HAVE_SYSTEMD_DAEMON)
1280 AM_CONDITIONAL([HAVE_SYSTEMD_DAEMON], [test "x$HAVE_SYSTEMD_DAEMON" = x1])
1281 AS_IF([test "x$HAVE_SYSTEMD_DAEMON" = "x1"], AC_DEFINE([HAVE_SYSTEMD_DAEMON], 1, [Have SYSTEMDDAEMON?]))
1282
1283 #### systemd login support (optional) ####
1284
1285 AS_IF([test "x$enable_systemd_login" != "xno"],
1286     [AS_IF([test "x$HAVE_SYSTEMD_LOGIN" != "x1"], [PKG_CHECK_MODULES(SYSTEMDLOGIN, [ libsystemd-login ], HAVE_SYSTEMD_LOGIN=1, HAVE_SYSTEMD_LOGIN=0)])],
1287     HAVE_SYSTEMD_LOGIN=0)
1288
1289 AS_IF([test "x$enable_systemd_login" = "xyes" && test "x$HAVE_SYSTEMD_LOGIN" = "x0"],
1290     [AC_MSG_ERROR([*** Needed systemd login support not found])])
1291
1292 AC_SUBST(HAVE_SYSTEMD_LOGIN)
1293 AM_CONDITIONAL([HAVE_SYSTEMD_LOGIN], [test "x$HAVE_SYSTEMD_LOGIN" = x1])
1294 AS_IF([test "x$HAVE_SYSTEMD_LOGIN" = "x1"], AC_DEFINE([HAVE_SYSTEMD_LOGIN], 1, [Have SYSTEMDLOGIN?]))
1295
1296 #### systemd journal support (optional) ####
1297
1298 AS_IF([test "x$enable_systemd_journal" != "xno"],
1299     [AS_IF([test "x$HAVE_SYSTEMD_JOURNAL" != "x1"], [PKG_CHECK_MODULES(SYSTEMDJOURNAL, [ libsystemd-journal ], HAVE_SYSTEMD_JOURNAL=1, HAVE_SYSTEMD_JOURNAL=0)])],
1300     HAVE_SYSTEMD_JOURNAL=0)
1301
1302 AS_IF([test "x$enable_systemd_journal" = "xyes" && test "x$HAVE_SYSTEMD_JOURNAL" = "x0"],
1303     [AC_MSG_ERROR([*** Needed systemd journal support not found])])
1304
1305 AC_SUBST(HAVE_SYSTEMD_JOURNAL)
1306 AM_CONDITIONAL([HAVE_SYSTEMD_JOURNAL], [test "x$HAVE_SYSTEMD_JOURNAL" = x1])
1307 AS_IF([test "x$HAVE_SYSTEMD_JOURNAL" = "x1"], AC_DEFINE([HAVE_SYSTEMD_JOURNAL], 1, [Have SYSTEMDJOURNAL?]))
1308
1309 #### Build and Install man pages ####
1310
1311 AC_ARG_ENABLE([manpages],
1312     AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]))
1313
1314 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$enable_manpages" != "xno"])
1315
1316 #### PulseAudio system group & user  #####
1317
1318 AC_ARG_WITH(system_user, AS_HELP_STRING([--with-system-user=<user>],[User for running the PulseAudio daemon as a system-wide instance (pulse)]))
1319 if test -z "$with_system_user" ; then
1320     PA_SYSTEM_USER=pulse
1321 else
1322     PA_SYSTEM_USER=$with_system_user
1323 fi
1324 AC_SUBST(PA_SYSTEM_USER)
1325 AC_DEFINE_UNQUOTED(PA_SYSTEM_USER,"$PA_SYSTEM_USER", [User for running the PulseAudio system daemon])
1326
1327 AC_ARG_WITH(system_group,AS_HELP_STRING([--with-system-group=<group>],[Group for running the PulseAudio daemon as a system-wide instance (pulse)]))
1328 if test -z "$with_system_group" ; then
1329     PA_SYSTEM_GROUP=pulse
1330 else
1331     PA_SYSTEM_GROUP=$with_system_group
1332 fi
1333 AC_SUBST(PA_SYSTEM_GROUP)
1334 AC_DEFINE_UNQUOTED(PA_SYSTEM_GROUP,"$PA_SYSTEM_GROUP", [Group for the PulseAudio system daemon])
1335
1336 AC_ARG_WITH(access_group,AS_HELP_STRING([--with-access-group=<group>],[Group which is allowed access to a system-wide PulseAudio daemon (pulse-access)]))
1337 if test -z "$with_access_group" ; then
1338     PA_ACCESS_GROUP=pulse-access
1339 else
1340     PA_ACCESS_GROUP=$with_access_group
1341 fi
1342 AC_SUBST(PA_ACCESS_GROUP)
1343 AC_DEFINE_UNQUOTED(PA_ACCESS_GROUP,"$PA_ACCESS_GROUP", [Access group])
1344
1345 AC_ARG_ENABLE([per-user-esound-socket],
1346     AS_HELP_STRING([--disable-per-user-esound-socket],[Use global esound socket directory /tmp/.esd/socket.]))
1347
1348 if test "x$enable_per_user_esound_socket" != "xno"; then
1349     USE_PER_USER_ESOUND_SOCKET=1
1350     AC_DEFINE([USE_PER_USER_ESOUND_SOCKET], [1], [Define this if you want per-user esound socket directories])
1351 else
1352     USE_PER_USER_ESOUND_SOCKET=0
1353 fi
1354
1355 #### PulseAudio system runtime dir ####
1356
1357 PA_SYSTEM_RUNTIME_PATH="${localstatedir}/run/pulse"
1358 AX_DEFINE_DIR(PA_SYSTEM_RUNTIME_PATH, PA_SYSTEM_RUNTIME_PATH, [System runtime dir])
1359 PA_SYSTEM_CONFIG_PATH="${localstatedir}/lib/pulse"
1360 AX_DEFINE_DIR(PA_SYSTEM_CONFIG_PATH, PA_SYSTEM_CONFIG_PATH, [System config dir])
1361 PA_SYSTEM_STATE_PATH="${localstatedir}/lib/pulse"
1362 AX_DEFINE_DIR(PA_SYSTEM_STATE_PATH, PA_SYSTEM_STATE_PATH, [System state dir])
1363
1364 PA_BINARY=${bindir}/pulseaudio${EXEEXT}
1365 AX_DEFINE_DIR(PA_BINARY, PA_BINARY, [Location of pulseaudio binary])
1366
1367 PACTL_BINARY=${bindir}/pactl${EXEEXT}
1368 AX_DEFINE_DIR(PACTL_BINARY, PACTL_BINARY, [Location of pactl binary])
1369
1370 AC_SUBST(PA_SOEXT, [.so])
1371 AC_DEFINE(PA_SOEXT, [".so"], [Shared object extension])
1372
1373 AC_SUBST(pulseconfdir, ["${sysconfdir}/pulse"])
1374 AX_DEFINE_DIR(PA_DEFAULT_CONFIG_DIR, pulseconfdir, [Location of configuration files])
1375
1376 #### Mac OSX specific stuff #####
1377
1378 AC_ARG_ENABLE(mac-universal,
1379     AS_HELP_STRING([--enable-mac-universal], [Build Mac universal binaries]),
1380     enable_mac_universal=$enableval, enable_mac_universal="no")
1381
1382 AC_ARG_WITH(mac-version-min,
1383     AS_HELP_STRING([--with-mac-version-min=<version>], [Defines the earliest version of MacOS X that the executables will run on.]),
1384     mac_version_min=$withval, mac_version_min="10.5")
1385
1386 AC_ARG_WITH(mac-sysroot,
1387     AS_HELP_STRING([--with-mac-sysroot=<path>], [SDK basedir to use as the logical root directory for headers and libraries.]),
1388     mac_sysroot=$withval)
1389
1390 if test "x$os_is_darwin" = "x1" ; then
1391     LDFLAGS="$LDFLAGS -mmacosx-version-min=$mac_version_min"
1392     CFLAGS="$CFLAGS -mmacosx-version-min=$mac_version_min"
1393
1394     if test "x$mac_sysroot" != "x" ; then
1395         LDFLAGS="$LDFLAGS -isysroot $mac_sysroot"
1396         CFLAGS="$CFLAGS -isysroot $mac_sysroot"
1397     fi
1398
1399     if test "x$enable_mac_universal" = "xyes" ; then
1400         mac_arches="-arch i386 -arch x86_64"
1401         LDFLAGS="$LDFLAGS $mac_arches"
1402         CFLAGS="$CFLAGS $mac_arches"
1403     fi
1404 fi
1405
1406 AC_ARG_ENABLE([webrtc-aec],
1407     AS_HELP_STRING([--enable-webrtc-aec], [Enable the optional WebRTC-based echo canceller]))
1408
1409 AS_IF([test "x$enable_webrtc_aec" = "xyes" && test "$HAVE_CXX11" = "0"],
1410     [AC_MSG_ERROR([*** webrtc-audio-processing needs C++11 support])])
1411
1412 AS_IF([test "x$enable_webrtc_aec" != "xno"],
1413     [PKG_CHECK_MODULES(WEBRTC, [ webrtc-audio-processing >= 0.2 ], [HAVE_WEBRTC=1], [HAVE_WEBRTC=0])],
1414     [HAVE_WEBRTC=0])
1415
1416 AS_IF([test "x$enable_webrtc_aec" = "xyes" && test "x$HAVE_WEBRTC" = "x0"],
1417     [AC_MSG_ERROR([*** webrtc-audio-processing library not found])])
1418
1419 AM_CONDITIONAL([HAVE_WEBRTC], [test "x$HAVE_WEBRTC" = "x1"])
1420
1421 AC_ARG_ENABLE([adrian-aec],
1422     AS_HELP_STRING([--enable-adrian-aec], [Enable Adrian's optional echo canceller]))
1423 AS_IF([test "x$enable_adrian_aec" != "xno"],
1424     [HAVE_ADRIAN_EC=1])
1425 AM_CONDITIONAL([HAVE_ADRIAN_EC], [test "x$HAVE_ADRIAN_EC" = "x1"])
1426
1427
1428 #### Thread support ####
1429
1430 AX_TLS
1431 AS_IF([test "$ac_cv_tls" = "__thread"],
1432     AC_DEFINE([SUPPORT_TLS___THREAD], 1, [Define this if the compiler supports __thread for Thread-Local Storage]))
1433
1434 # Win32 build breaks with win32 pthread installed
1435 AS_IF([test "x$os_is_win32" != "x1"],
1436   [AX_PTHREAD])
1437
1438 AS_IF([test "x$ax_pthread_ok" = "xyes"],
1439     AC_DEFINE([_POSIX_PTHREAD_SEMANTICS], 1, [Needed on Solaris]))
1440
1441
1442
1443 ###################################
1444 #            Output               #
1445 ###################################
1446
1447 AC_DEFINE_UNQUOTED(PA_CFLAGS, "$CFLAGS", [The CFLAGS used during compilation])
1448
1449 # Check whether to build tests by default (as compile-test) or not
1450 AC_ARG_ENABLE([default-build-tests],
1451     AS_HELP_STRING([--disable-default-build-tests], [Build test programs only during make check]))
1452 AM_CONDITIONAL([BUILD_TESTS_DEFAULT], [test "x$enable_default_build_tests" != "xno"])
1453
1454 AC_ARG_ENABLE([legacy-database-entry-format],
1455         AS_HELP_STRING([--disable-legacy-database-entry-format], [Try to load legacy (< 1.0) database files (card, device and volume restore).]))
1456 if test "x$enable_legacy_database_entry_format" != "xno" ; then
1457         AC_DEFINE(ENABLE_LEGACY_DATABASE_ENTRY_FORMAT, [1], [Legacy database entry format])
1458 fi
1459
1460 AC_ARG_ENABLE([static-bins],
1461     AS_HELP_STRING([--enable-static-bins],[Statically link executables.]))
1462 AM_CONDITIONAL([STATIC_BINS], [test "x$enable_static_bins" = "xyes"])
1463
1464 AC_ARG_WITH(
1465         [preopen-mods],
1466         AS_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
1467         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
1468 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
1469 if test "x$PREOPEN_MODS" != "xall" ; then
1470     tmpLIBS=""
1471     for mod in $PREOPEN_MODS; do
1472         tmpLIBS="$tmpLIBS module-$mod.la"
1473     done
1474     PREOPEN_MODS="$tmpLIBS"
1475     AC_SUBST(PREOPEN_MODS)
1476 fi
1477
1478 AC_ARG_WITH(
1479         [module-dir],
1480         AS_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINOR}/modules]),
1481         [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINOR}/modules"])
1482
1483 AC_SUBST(modlibexecdir)
1484 AX_DEFINE_DIR(PA_DLSEARCHPATH, modlibexecdir, [Modules dir])
1485
1486 AC_ARG_WITH(
1487         [udev-rules-dir],
1488         AS_HELP_STRING([--with-udev-rules-dir],[Directory where to install udev rules to (defaults to /lib/udev/rules.d)]),
1489         [udevrulesdir=$withval], [udevrulesdir="/lib/udev/rules.d"])
1490
1491 AC_SUBST(udevrulesdir)
1492
1493 AC_ARG_WITH([bash-completion-dir],
1494         AS_HELP_STRING([--with-bash-completion-dir=DIR], [Directory for bash completion files]),
1495         [bashcompletiondir=$withval], [bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)])
1496 if test "x$bashcompletionsdir" = "x"; then
1497         bashcompletiondir="${datadir}/bash-completion/completions"
1498 fi
1499
1500 AC_SUBST(bashcompletiondir)
1501
1502 AC_ARG_WITH(
1503         [zsh-completion-dir],
1504         AS_HELP_STRING([--with-zsh-completion-dir], [Zsh completions directory (defaults to ${datadir}/zsh/site-functions)]),
1505         [zshcompletiondir=$withval], [zshcompletiondir="${datadir}/zsh/site-functions"])
1506
1507 AC_SUBST(zshcompletiondir)
1508
1509 AC_ARG_ENABLE([force-preopen],
1510     AS_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]))
1511
1512 if test "x$enable_force_preopen" = "xyes"; then
1513     FORCE_PREOPEN=yes
1514 else
1515     FORCE_PREOPEN=no
1516 fi
1517
1518 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "xyes"])
1519
1520 AC_CONFIG_FILES([
1521 Makefile
1522 src/Makefile
1523 man/Makefile
1524 libpulse.pc
1525 libpulse-simple.pc
1526 libpulse-mainloop-glib.pc
1527 doxygen/Makefile
1528 doxygen/doxygen.conf
1529 src/pulse/version.h
1530 po/Makefile.in
1531 man/pulseaudio.1.xml
1532 man/pax11publish.1.xml
1533 man/pacat.1.xml
1534 man/pacmd.1.xml
1535 man/pactl.1.xml
1536 man/pasuspender.1.xml
1537 man/padsp.1.xml
1538 man/pulse-daemon.conf.5.xml
1539 man/pulse-client.conf.5.xml
1540 man/default.pa.5.xml
1541 man/pulse-cli-syntax.5.xml
1542 man/start-pulseaudio-x11.1.xml
1543 ])
1544
1545 AS_IF([test "x$HAVE_ESOUND" = "x1"],
1546     [
1547         AC_CONFIG_FILES([man/esdcompat.1.xml])
1548         AC_CONFIG_FILES([src/esdcompat:src/daemon/esdcompat.in], [chmod +x src/esdcompat])
1549     ])
1550
1551 AC_CONFIG_FILES([src/start-pulseaudio-x11:src/daemon/start-pulseaudio-x11.in], [chmod +x src/start-pulseaudio-x11])
1552 AC_CONFIG_FILES([src/client.conf:src/pulse/client.conf.in])
1553 AC_CONFIG_FILES([src/daemon.conf:src/daemon/daemon.conf.in],
1554     [m4 src/daemon.conf > src/daemon.conf.gen && mv src/daemon.conf.gen src/daemon.conf])
1555 AC_CONFIG_FILES([src/default.pa:src/daemon/default.pa.in],
1556     [m4 src/default.pa > src/default.pa.gen && mv src/default.pa.gen src/default.pa])
1557 AC_CONFIG_FILES([src/system.pa:src/daemon/system.pa.in],
1558     [m4 src/system.pa > src/system.pa.gen && mv src/system.pa.gen src/system.pa])
1559 AS_IF([test "x$HAVE_SYSTEMD_DAEMON" = "x1"],
1560     [
1561         AC_CONFIG_FILES([src/pulseaudio.service:src/daemon/systemd/user/pulseaudio.service.in])
1562     ])
1563
1564 # CMake related ProjectConfig files
1565 PA_LIBDIR="$libdir"
1566 AX_DEFINE_DIR(PA_LIBDIR, PA_LIBDIR, [PulseAudio library dir])
1567 PA_INCDIR="$includedir"
1568 AX_DEFINE_DIR(PA_INCDIR, PA_INCDIR, [PulseAudio include dir])
1569
1570 AC_CONFIG_FILES([PulseAudioConfig.cmake:PulseAudioConfig.cmake.in],
1571     [m4 PulseAudioConfig.cmake > PulseAudioConfig.cmake.gen && mv PulseAudioConfig.cmake.gen PulseAudioConfig.cmake])
1572 AC_CONFIG_FILES([PulseAudioConfigVersion.cmake])
1573
1574 AC_OUTPUT
1575
1576 # ==========================================================================
1577
1578 AS_IF([test "x$HAVE_MEMFD" = "x1"], ENABLE_MEMFD=yes, ENABLE_MEMFD=no)
1579 AS_IF([test "x$HAVE_X11" = "x1"], ENABLE_X11=yes, ENABLE_X11=no)
1580 AS_IF([test "x$HAVE_OSS_OUTPUT" = "x1"], ENABLE_OSS_OUTPUT=yes, ENABLE_OSS_OUTPUT=no)
1581 AS_IF([test "x$HAVE_OSS_WRAPPER" = "x1"], ENABLE_OSS_WRAPPER=yes, ENABLE_OSS_WRAPPER=no)
1582 AS_IF([test "x$HAVE_ALSA" = "x1"], ENABLE_ALSA=yes, ENABLE_ALSA=no)
1583 AS_IF([test "x$HAVE_COREAUDIO" = "x1"], ENABLE_COREAUDIO=yes, ENABLE_COREAUDIO=no)
1584 AS_IF([test "x$HAVE_SOLARIS" = "x1"], ENABLE_SOLARIS=yes, ENABLE_SOLARIS=no)
1585 AS_IF([test "x$HAVE_WAVEOUT" = "x1"], ENABLE_WAVEOUT=yes, ENABLE_WAVEOUT=no)
1586 AS_IF([test "x$HAVE_GLIB20" = "x1"], ENABLE_GLIB20=yes, ENABLE_GLIB20=no)
1587 AS_IF([test "x$HAVE_GTK30" = "x1"], ENABLE_GTK30=yes, ENABLE_GTK30=no)
1588 AS_IF([test "x$HAVE_GCONF" = "x1"], ENABLE_GCONF=yes, ENABLE_GCONF=no)
1589 AS_IF([test "x$HAVE_GSETTINGS" = "x1"], ENABLE_GSETTINGS=yes, ENABLE_GSETTINGS=no)
1590 AS_IF([test "x$HAVE_AVAHI" = "x1"], ENABLE_AVAHI=yes, ENABLE_AVAHI=no)
1591 AS_IF([test "x$HAVE_JACK" = "x1"], ENABLE_JACK=yes, ENABLE_JACK=no)
1592 AS_IF([test "x$HAVE_LIBASYNCNS" = "x1"], ENABLE_LIBASYNCNS=yes, ENABLE_LIBASYNCNS=no)
1593 AS_IF([test "x$HAVE_LIRC" = "x1"], ENABLE_LIRC=yes, ENABLE_LIRC=no)
1594 AS_IF([test "x$HAVE_DBUS" = "x1"], ENABLE_DBUS=yes, ENABLE_DBUS=no)
1595 AS_IF([test "x$HAVE_UDEV" = "x1"], ENABLE_UDEV=yes, ENABLE_UDEV=no)
1596 AS_IF([test "x$HAVE_SYSTEMD_DAEMON" = "x1"], ENABLE_SYSTEMD_DAEMON=yes, ENABLE_SYSTEMD_DAEMON=no)
1597 AS_IF([test "x$HAVE_SYSTEMD_LOGIN" = "x1"], ENABLE_SYSTEMD_LOGIN=yes, ENABLE_SYSTEMD_LOGIN=no)
1598 AS_IF([test "x$HAVE_SYSTEMD_JOURNAL" = "x1"], ENABLE_SYSTEMD_JOURNAL=yes, ENABLE_SYSTEMD_JOURNAL=no)
1599 AS_IF([test "x$HAVE_BLUEZ_4" = "x1"], ENABLE_BLUEZ_4=yes, ENABLE_BLUEZ_4=no)
1600 AS_IF([test "x$HAVE_BLUEZ_5" = "x1"], ENABLE_BLUEZ_5=yes, ENABLE_BLUEZ_5=no)
1601 AS_IF([test "x$HAVE_BLUEZ_5_OFONO_HEADSET" = "x1"], ENABLE_BLUEZ_5_OFONO_HEADSET=yes, ENABLE_BLUEZ_5_OFONO_HEADSET=no)
1602 AS_IF([test "x$HAVE_BLUEZ_5_NATIVE_HEADSET" = "x1"], ENABLE_BLUEZ_5_NATIVE_HEADSET=yes, ENABLE_BLUEZ_5_NATIVE_HEADSET=no)
1603 AS_IF([test "x$HAVE_HAL_COMPAT" = "x1"], ENABLE_HAL_COMPAT=yes, ENABLE_HAL_COMPAT=no)
1604 AS_IF([test "x$HAVE_TCPWRAP" = "x1"], ENABLE_TCPWRAP=yes, ENABLE_TCPWRAP=no)
1605 AS_IF([test "x$HAVE_LIBSAMPLERATE" = "x1"], ENABLE_LIBSAMPLERATE="yes (DEPRECATED)", ENABLE_LIBSAMPLERATE=no)
1606 AS_IF([test "x$HAVE_IPV6" = "x1"], ENABLE_IPV6=yes, ENABLE_IPV6=no)
1607 AS_IF([test "x$HAVE_OPENSSL" = "x1"], ENABLE_OPENSSL=yes, ENABLE_OPENSSL=no)
1608 AS_IF([test "x$HAVE_FFTW" = "x1"], ENABLE_FFTW=yes, ENABLE_FFTW=no)
1609 AS_IF([test "x$HAVE_ORC" = "xyes"], ENABLE_ORC=yes, ENABLE_ORC=no)
1610 AS_IF([test "x$HAVE_ADRIAN_EC" = "x1"], ENABLE_ADRIAN_EC=yes, ENABLE_ADRIAN_EC=no)
1611 AS_IF([test "x$HAVE_SPEEX" = "x1"], ENABLE_SPEEX=yes, ENABLE_SPEEX=no)
1612 AS_IF([test "x$HAVE_SOXR" = "x1"], ENABLE_SOXR=yes, ENABLE_SOXR=no)
1613 AS_IF([test "x$HAVE_WEBRTC" = "x1"], ENABLE_WEBRTC=yes, ENABLE_WEBRTC=no)
1614 AS_IF([test "x$HAVE_TDB" = "x1"], ENABLE_TDB=yes, ENABLE_TDB=no)
1615 AS_IF([test "x$HAVE_GDBM" = "x1"], ENABLE_GDBM=yes, ENABLE_GDBM=no)
1616 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], ENABLE_SIMPLEDB=yes, ENABLE_SIMPLEDB=no)
1617 AS_IF([test "x$HAVE_ESOUND" = "x1"], ENABLE_ESOUND=yes, ENABLE_ESOUND=no)
1618 AS_IF([test "x$HAVE_ESOUND" = "x1" -a "x$USE_PER_USER_ESOUND_SOCKET" = "x1"], ENABLE_PER_USER_ESOUND_SOCKET=yes, ENABLE_PER_USER_ESOUND_SOCKET=no)
1619 AS_IF([test "x$HAVE_GCOV" = "x1"], ENABLE_GCOV=yes, ENABLE_GCOV=no)
1620 AS_IF([test "x$HAVE_LIBCHECK" = "x1"], ENABLE_TESTS=yes, ENABLE_TESTS=no)
1621 AS_IF([test "x$enable_legacy_database_entry_format" != "xno"], ENABLE_LEGACY_DATABASE_ENTRY_FORMAT=yes, ENABLE_LEGACY_DATABASE_ENTRY_FORMAT=no)
1622
1623 echo "
1624  ---{ $PACKAGE_NAME $VERSION }---
1625
1626     prefix:                        ${prefix}
1627     sysconfdir:                    ${sysconfdir}
1628     localstatedir:                 ${localstatedir}
1629     modlibexecdir:                 ${modlibexecdir}
1630     System Runtime Path:           ${PA_SYSTEM_RUNTIME_PATH}
1631     System State Path:             ${PA_SYSTEM_STATE_PATH}
1632     System Config Path:            ${PA_SYSTEM_CONFIG_PATH}
1633     Zsh completions directory:     ${zshcompletiondir}
1634     Bash completions directory:    ${bashcompletiondir}
1635     Compiler:                      ${CC}
1636     CFLAGS:                        ${CFLAGS}
1637     CPPFLAGS:                      ${CPPFLAGS}
1638     LIBS:                          ${LIBS}
1639
1640     Enable memfd shared memory:    ${ENABLE_MEMFD}
1641     Enable X11:                    ${ENABLE_X11}
1642     Enable OSS Output:             ${ENABLE_OSS_OUTPUT}
1643     Enable OSS Wrapper:            ${ENABLE_OSS_WRAPPER}
1644     Enable EsounD:                 ${ENABLE_ESOUND}
1645     Enable Alsa:                   ${ENABLE_ALSA}
1646     Enable CoreAudio:              ${ENABLE_COREAUDIO}
1647     Enable Solaris:                ${ENABLE_SOLARIS}
1648     Enable WaveOut:                ${ENABLE_WAVEOUT}
1649     Enable GLib 2.0:               ${ENABLE_GLIB20}
1650     Enable Gtk+ 3.0:               ${ENABLE_GTK30}
1651     Enable GConf:                  ${ENABLE_GCONF}
1652     Enable GSettings:              ${ENABLE_GSETTINGS}
1653     Enable Avahi:                  ${ENABLE_AVAHI}
1654     Enable Jack:                   ${ENABLE_JACK}
1655     Enable Async DNS:              ${ENABLE_LIBASYNCNS}
1656     Enable LIRC:                   ${ENABLE_LIRC}
1657     Enable D-Bus:                  ${ENABLE_DBUS}
1658       Enable BlueZ 4:              ${ENABLE_BLUEZ_4}
1659       Enable BlueZ 5:              ${ENABLE_BLUEZ_5}
1660         Enable ofono headsets:     ${ENABLE_BLUEZ_5_OFONO_HEADSET}
1661         Enable native headsets:    ${ENABLE_BLUEZ_5_NATIVE_HEADSET}
1662     Enable udev:                   ${ENABLE_UDEV}
1663       Enable HAL->udev compat:     ${ENABLE_HAL_COMPAT}
1664     Enable systemd
1665       Daemon (Socket Activation):  ${ENABLE_SYSTEMD_DAEMON}
1666       Login (Session Tracking):    ${ENABLE_SYSTEMD_LOGIN}
1667       Journal (Logging):           ${ENABLE_SYSTEMD_JOURNAL}
1668     Enable TCP Wrappers:           ${ENABLE_TCPWRAP}
1669     Enable libsamplerate:          ${ENABLE_LIBSAMPLERATE}
1670     Enable IPv6:                   ${ENABLE_IPV6}
1671     Enable OpenSSL (for Airtunes): ${ENABLE_OPENSSL}
1672     Enable fftw:                   ${ENABLE_FFTW}
1673     Enable orc:                    ${ENABLE_ORC}
1674     Enable Adrian echo canceller:  ${ENABLE_ADRIAN_EC}
1675     Enable speex (resampler, AEC): ${ENABLE_SPEEX}
1676     Enable soxr (resampler):       ${ENABLE_SOXR}
1677     Enable WebRTC echo canceller:  ${ENABLE_WEBRTC}
1678     Enable gcov coverage:          ${ENABLE_GCOV}
1679     Enable unit tests:             ${ENABLE_TESTS}
1680     Database
1681       tdb:                         ${ENABLE_TDB}
1682       gdbm:                        ${ENABLE_GDBM}
1683       simple database:             ${ENABLE_SIMPLEDB}
1684
1685     System User:                   ${PA_SYSTEM_USER}
1686     System Group:                  ${PA_SYSTEM_GROUP}
1687     Access Group:                  ${PA_ACCESS_GROUP}
1688     Enable per-user EsounD socket: ${ENABLE_PER_USER_ESOUND_SOCKET}
1689     Force preopen:                 ${FORCE_PREOPEN}
1690     Preopened modules:             ${PREOPEN_MODS}
1691
1692     Legacy Database Entry Support: ${ENABLE_LEGACY_DATABASE_ENTRY_FORMAT}
1693 "
1694
1695 if test "${ENABLE_SPEEX}" = "no" && test "${ENABLE_WEBRTC}" = "no" && test "${ENABLE_ADRIAN_EC}" = "no" ; then
1696 AC_MSG_ERROR([At least one echo canceller implementation must be available.])
1697 fi
1698
1699 if test "${ENABLE_DBUS}" = "no" && test "x$os_is_win32" != "x1" ; then
1700    echo "
1701 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1702 You do not have D-Bus support enabled. It is strongly recommended
1703 that you enable D-Bus support if your platform supports it.
1704 Many parts of PulseAudio use D-Bus, from ConsoleKit interaction
1705 to the Device Reservation Protocol to speak to JACK, Bluetooth
1706 support and even a native control protocol for communicating and
1707 controling the PulseAudio daemon itself.
1708 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1709 "
1710 fi
1711
1712 if test "${ENABLE_UDEV}" = "no" && test "x$os_is_win32" != "x1" ; then
1713    echo "
1714 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1715 You do not have udev support enabled. It is strongly recommended
1716 that you enable udev support if your platform supports it as it is
1717 the primary method used to detect hardware audio devices (on Linux)
1718 and is thus a critical part of PulseAudio on that platform.
1719 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1720 "
1721 fi
1722
1723 if test "${ENABLE_SPEEX}" = "no" && test "x$os_is_win32" != "x1" ; then
1724    echo "
1725 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1726 You do not have speex support enabled. It is strongly recommended
1727 that you enable speex support if your platform supports it as it is
1728 the primary method used for audio resampling and is thus a critical
1729 part of PulseAudio on that platform.
1730 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1731 "
1732 fi