configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [32])
  34 m4_define([glib_micro_version], [2])
  35 m4_define([glib_interface_age], [2])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  58
  59 AC_CONFIG_HEADER([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS+set}
  65
  66 AM_INIT_AUTOMAKE([1.11 no-define no-dist-gzip dist-xz tar-ustar])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114
 115 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 116
 117 AC_CANONICAL_HOST
 118
 119 AC_MSG_CHECKING([for the BeOS])
 120 case $host in
 121   *-*-beos*)
 122     glib_native_beos="yes"
 123     ;;
 124   *)
 125     glib_native_beos="no"
 126     ;;
 127 esac
 128 AC_MSG_RESULT([$glib_native_beos])
 129
 130 dnl
 131
 132 AC_MSG_CHECKING([for Win32])
 133 LIB_EXE_MACHINE_FLAG=X86
 134 case "$host" in
 135   *-*-mingw*)
 136     glib_native_win32=yes
 137     glib_pid_type='void *'
 138     glib_cv_stack_grows=no
 139     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 140     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 141     # (Sorry, I don't know exactly what is the problem, but it is related to
 142     # floating point formatting and decimal point vs. comma.)
 143     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 144     # rigorous enough to notice, though.
 145     # So preset the autoconf cache variables.
 146     ac_cv_func_vsnprintf_c99=no
 147     ac_cv_func_snprintf_c99=no
 148     case "$host" in
 149     x86_64-*-*)
 150       LIB_EXE_MACHINE_FLAG=X64
 151       ;;
 152     esac
 153     ;;
 154   *)
 155     glib_native_win32=no
 156     glib_pid_type=int
 157     ;;
 158 esac
 159 case $host in
 160   *-*-linux*)
 161     glib_os_linux=yes
 162     ;;
 163 esac
 164
 165 AC_MSG_RESULT([$glib_native_win32])
 166
 167 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 168
 169 glib_have_carbon=no
 170 AC_MSG_CHECKING([for Mac OS X Carbon support])
 171 AC_TRY_CPP([
 172 #include <Carbon/Carbon.h>
 173 #include <CoreServices/CoreServices.h>
 174 ], glib_have_carbon=yes)
 175
 176 AC_MSG_RESULT([$glib_have_carbon])
 177
 178 glib_have_cocoa=no
 179 AC_MSG_CHECKING([for Mac OS X Cocoa support])
 180 AC_TRY_CPP([
 181 #include <Cocoa/Cocoa.h>
 182 #ifdef GNUSTEP_BASE_VERSION
 183 #error "Detected GNUstep, not Cocoa"
 184 #endif
 185 ], glib_have_cocoa=yes)
 186
 187 AC_MSG_RESULT([$glib_have_cocoa])
 188
 189 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 190 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 191 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 192 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 193 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 194 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
 195
 196 if test "$glib_native_win32" = "yes"; then
 197   AC_CHECK_TOOL(WINDRES, windres, no)
 198   if test "$WINDRES" = no; then
 199     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 200   fi
 201   AC_CHECK_TOOL(NM, nm, no)
 202   if test "$NM" = no; then
 203     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 204   fi
 205   AC_CHECK_TOOL(RANLIB, ranlib, :)
 206   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 207 fi
 208 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 209
 210 if test "$glib_native_win32" != yes; then
 211     # libtool option to control which symbols are exported
 212     # right now, symbols starting with _ are not exported
 213     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 214 else
 215     # We currently use .def files on Windows
 216     LIBTOOL_EXPORT_OPTIONS=
 217 fi
 218 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 219
 220 if test "x$glib_have_carbon" = "xyes"; then
 221   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 222   LDFLAGS="$LDFLAGS -framework Carbon"
 223 fi
 224
 225 if test "x$glib_have_cocoa" = "xyes"; then
 226   AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
 227   LDFLAGS="$LDFLAGS -framework Foundation"
 228 fi
 229
 230 gl_GLIBC21
 231 if test "x$GLIBC21" = "xyes"; then
 232   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 233 fi
 234
 235 dnl declare --enable-* args and collect ac_help strings
 236 AC_ARG_ENABLE(debug,
 237               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 238                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 239               enable_debug=glib_debug_default)
 240
 241 AC_ARG_ENABLE(gc_friendly,
 242               [AC_HELP_STRING([--enable-gc-friendly],
 243                               [turn on garbage collector friendliness [default=no]])],,
 244               [enable_gc_friendly=no])
 245 AC_ARG_ENABLE(mem_pools,
 246               [AC_HELP_STRING([--disable-mem-pools],
 247                               [disable all glib memory pools])],,
 248               [disable_mem_pools=no])
 249 AC_ARG_ENABLE(rebuilds,
 250               [AC_HELP_STRING([--disable-rebuilds],
 251                               [disable all source autogeneration rules])],,
 252               [enable_rebuilds=yes])
 253 AC_ARG_ENABLE(modular_tests,
 254               AC_HELP_STRING([--disable-modular-tests],
 255                              [Disable build of test programs (default: no)]),,
 256               [enable_modular_tests=yes])
 257 AM_CONDITIONAL(BUILD_MODULAR_TESTS, test x$enable_modular_tests = xyes)
 258
 259 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 260 if test "x$enable_gc_friendly" = "xyes"; then
 261   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 262   AC_MSG_RESULT([yes])
 263 else
 264   AC_MSG_RESULT([no])
 265 fi
 266
 267 AC_MSG_CHECKING([whether to disable memory pools])
 268 if test "x$disable_mem_pools" = "xno"; then
 269   AC_MSG_RESULT([no])
 270 else
 271   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 272   AC_MSG_RESULT([yes])
 273 fi
 274
 275 dnl location to install runtime libraries, e.g. ../../lib to install
 276 dnl to /lib if libdir is /usr/lib
 277 AC_ARG_WITH(runtime-libdir,
 278            [AC_HELP_STRING([--with-runtime-libdir=RELPATH],
 279                            [install runtime libraries relative to libdir])],
 280            [],
 281            [with_runtime_libdir=""])
 282 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 283 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 284 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 285 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 286 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 287
 288 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 289 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 290 AC_LANG_SAVE
 291 AC_LANG_CPLUSPLUS
 292 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 293 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 294 AC_LANG_RESTORE
 295
 296 AM_PROG_CC_STDC
 297 AM_PROG_CC_C_O
 298 AC_PROG_INSTALL
 299
 300 AC_SYS_LARGEFILE
 301
 302 PKG_PROG_PKG_CONFIG(0.16)
 303
 304 if test "x$enable_debug" = "xyes"; then
 305   if test x$cflags_set != xset ; then
 306       case " $CFLAGS " in
 307       *[[\ \    ]]-g[[\ \       ]]*) ;;
 308       *) CFLAGS="$CFLAGS -g" ;;
 309       esac
 310   fi
 311   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 312 else
 313   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 314
 315   if test "x$enable_debug" = "xno"; then
 316     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 317   fi
 318 fi
 319
 320 # Ensure MSVC-compatible struct packing convention is used when
 321 # compiling for Win32 with gcc.
 322 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 323 # gcc2 uses "-fnative-struct".
 324 if test x"$glib_native_win32" = xyes; then
 325   if test x"$GCC" = xyes; then
 326     msnative_struct=''
 327     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 328     if test -z "$ac_cv_prog_CC"; then
 329       our_gcc="$CC"
 330     else
 331       our_gcc="$ac_cv_prog_CC"
 332     fi
 333     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 334       2.)
 335         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 336           msnative_struct='-fnative-struct'
 337         fi
 338         ;;
 339       *)
 340         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 341           msnative_struct='-mms-bitfields'
 342         fi
 343         ;;
 344     esac
 345     if test x"$msnative_struct" = x ; then
 346       AC_MSG_RESULT([no way])
 347       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 348     else
 349       CFLAGS="$CFLAGS $msnative_struct"
 350       AC_MSG_RESULT([${msnative_struct}])
 351     fi
 352   fi
 353 fi
 354 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 355 AC_SUBST(GLIB_EXTRA_CFLAGS)
 356
 357 AC_EXEEXT
 358
 359 # define a MAINT-like variable REBUILD which is set if Perl
 360 # and awk are found, so autogenerated sources can be rebuilt
 361 AC_PROG_AWK
 362 AC_CHECK_PROGS(PERL, [perl5 perl])
 363 # We would like indent, but don't require it.
 364 AC_CHECK_PROG(INDENT, indent, indent)
 365 REBUILD=\#
 366 if test "x$enable_rebuilds" = "xyes" && \
 367      test -n "$PERL" && \
 368      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 369      test -n "$AWK" ; then
 370   REBUILD=
 371 fi
 372 AC_SUBST(REBUILD)
 373
 374 # Need full path to Perl for glib-mkenums
 375 #
 376 if test "x$PERL" != x ; then
 377   AC_PATH_PROG(PERL_PATH, [$PERL])
 378 fi
 379 if test "x$PERL_PATH" = x ; then
 380   PERL_PATH="/usr/bin/env perl"
 381 fi
 382 AC_SUBST(PERL_PATH)
 383
 384 # Need suitable python path for greport
 385 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 386
 387
 388 dnl ***********************
 389 dnl *** Tests for iconv ***
 390 dnl ***********************
 391 dnl
 392 dnl We do this before the gettext checks, to avoid distortion
 393
 394 dnl On Windows we use a native implementation
 395
 396 if test x"$glib_native_win32" = xyes; then
 397   with_libiconv=native
 398 else
 399   AC_ARG_WITH(libiconv,
 400               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 401                               [use the libiconv library])],,
 402               [with_libiconv=maybe])
 403
 404   found_iconv=no
 405   case $with_libiconv in
 406     maybe)
 407       # Check in the C library first
 408       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 409       # Check if we have GNU libiconv
 410       if test $found_iconv = "no"; then
 411         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 412       fi
 413       # Check if we have a iconv in -liconv, possibly from vendor
 414       if test $found_iconv = "no"; then
 415         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 416       fi
 417       ;;
 418     no)
 419       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 420       ;;
 421     gnu|yes)
 422       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 423       ;;
 424     native)
 425       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 426       ;;
 427   esac
 428
 429   if test "x$found_iconv" = "xno" ; then
 430      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 431   fi
 432 fi
 433
 434 AC_ARG_ENABLE(iconv-cache,
 435               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 436                               [cache iconv descriptors [default=auto]])],,
 437               [enable_iconv_cache=auto])
 438
 439 AC_MSG_CHECKING([whether to cache iconv descriptors])
 440 case $enable_iconv_cache in
 441   auto)
 442     if test $ac_cv_gnu_library_2_1 = yes; then
 443       enable_iconv_cache=no
 444     else
 445       enable_iconv_cache=yes
 446     fi
 447   ;;
 448   yes|no)
 449   ;;
 450   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 451   ;;
 452 esac
 453
 454 if test $enable_iconv_cache = yes; then
 455    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 456 fi
 457
 458 AC_MSG_RESULT($enable_iconv_cache)
 459
 460
 461 dnl
 462 dnl zlib support
 463 dnl
 464 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 465 if test "x$found_zlib" = "xno" ; then
 466   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 467   if test "x$found_zlib" = "xno" ; then
 468     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 469   fi
 470   ZLIB_LIBS='-lz'
 471   AC_SUBST(ZLIB_LIBS)
 472 fi
 473
 474 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 475 AC_SUBST(LIBFFI_CFLAGS)
 476 AC_SUBST(LIBFFI_LIBS)
 477
 478 dnl
 479 dnl gettext support
 480 dnl
 481
 482 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 483 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 484 GLIB_GNU_GETTEXT
 485
 486 if test "$gt_cv_have_gettext" != "yes" ; then
 487   AC_MSG_ERROR([
 488 *** You must have either have gettext support in your C library, or use the
 489 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 490 ])
 491 fi
 492
 493 LIBS="$INTLLIBS $LIBS"
 494
 495 GETTEXT_PACKAGE=glib20
 496 AC_SUBST(GETTEXT_PACKAGE)
 497 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 498   [Define the gettext package to be used])
 499
 500 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 501
 502 dnl
 503 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 504 dnl
 505
 506 if test x"$glib_native_win32" != xyes; then
 507   if test x$with_libiconv != xno ; then
 508     case " $INTLLIBS " in
 509     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 510     *) ICONV_LIBS="-liconv" ;;
 511     esac
 512   fi
 513 fi
 514 AC_SUBST(ICONV_LIBS)
 515
 516 case $with_libiconv in
 517   gnu)
 518     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 519     ;;
 520   native)
 521     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 522     ;;
 523 esac
 524
 525 dnl Initialize libtool
 526 LT_PREREQ([2.2])
 527 LT_INIT([disable-static win32-dll])
 528 dnl when using libtool 2.x create libtool early, because it's used in configure
 529 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 530
 531
 532 if test "x$GCC" = "xyes"; then
 533   case " $CFLAGS " in
 534   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 535   *) CFLAGS="$CFLAGS -Wall" ;;
 536   esac
 537 fi
 538
 539 if test "$glib_native_win32" = "yes"; then
 540   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 541     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 542   fi
 543   if test x$enable_static = xyes; then
 544     glib_win32_static_compilation=yes
 545     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 546 #define GOBJECT_STATIC_COMPILATION 1"
 547     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 548   fi
 549 fi
 550 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 551
 552 dnl
 553 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 554 dnl
 555 if test $cross_compiling != yes ; then
 556     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 557     glib_save_LIBS=$LIBS
 558     LIBS="$LIBS -lm"
 559     AC_TRY_RUN([#include <math.h>
 560                  int main (void) { return (log(1) != log(1.)); }],
 561          AC_MSG_RESULT(none needed),
 562          glib_save_CFLAGS=$CFLAGS
 563          CFLAGS="$CFLAGS -std1"
 564          AC_TRY_RUN([#include <math.h>
 565                      int main (void) { return (log(1) != log(1.)); }],
 566              AC_MSG_RESULT(-std1),
 567              AC_MSG_RESULT()
 568              CFLAGS=$glib_save_CFLAGS
 569              AC_MSG_WARN(
 570                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 571          )
 572     )
 573     LIBS=$glib_save_LIBS
 574 fi
 575
 576 dnl NeXTStep cc seems to need this
 577 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 578 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 579   AC_MSG_RESULT(none needed),
 580   glib_save_CFLAGS=$CFLAGS
 581   CFLAGS="$CFLAGS -posix"
 582   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 583     AC_MSG_RESULT(-posix),
 584     AC_MSG_RESULT()
 585     CFLAGS=$glib_save_CFLAGS
 586     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 587
 588 # Checks for library functions.
 589 AC_FUNC_VPRINTF
 590 AC_FUNC_ALLOCA
 591 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2)
 592 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 593
 594 AC_CHECK_SIZEOF(char)
 595 AC_CHECK_SIZEOF(short)
 596 AC_CHECK_SIZEOF(long)
 597 AC_CHECK_SIZEOF(int)
 598 AC_CHECK_SIZEOF(void *)
 599 AC_CHECK_SIZEOF(long long)
 600 AC_CHECK_SIZEOF(__int64)
 601
 602 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
 603   [AC_TRY_LINK([#include <signal.h>
 604      #include <sys/types.h>
 605      sig_atomic_t val = 42;],
 606     [return val == 42 ? 0 : 1],
 607    ac_cv_type_sig_atomic_t=yes,
 608    ac_cv_type_sig_atomic_t=no)])
 609 if test x$ac_cv_type_sig_atomic_t = xyes; then
 610    AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
 611      [Define if you have the 'sig_atomic_t' type.])
 612 fi
 613
 614 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 615   :
 616 else
 617   AC_MSG_ERROR([
 618 *** GLib requires a 64 bit type. You might want to consider
 619 *** using the GNU C compiler.
 620 ])
 621 fi
 622
 623 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 624         # long long is a 64 bit integer.
 625         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 626         AC_CACHE_VAL(glib_cv_long_long_format,[
 627                 for format in ll q I64; do
 628                   AC_TRY_RUN([#include <stdio.h>
 629                         int main()
 630                         {
 631                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 632                           char buffer[1000];
 633                           sprintf (buffer, "%${format}u", a);
 634                           sscanf (buffer, "%${format}u", &b);
 635                           exit (b!=a);
 636                         }
 637                         ],
 638                         [glib_cv_long_long_format=${format}
 639                         break],
 640                         [],[:])
 641                 done])
 642         if test -n "$glib_cv_long_long_format"; then
 643           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 644           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 645           if test x"$glib_cv_long_long_format" = xI64; then
 646             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 647           fi
 648         else
 649           AC_MSG_RESULT(none)
 650         fi
 651 elif test x$ac_cv_sizeof___int64 = x8; then
 652         # __int64 is a 64 bit integer.
 653         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 654         # We know this is MSVCRT.DLL, and what the formats are
 655         glib_cv_long_long_format=I64
 656         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 657         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 658         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 659 fi
 660
 661 AC_C_CONST
 662
 663 dnl ok, here we try to check whether the systems prototypes for
 664 dnl malloc and friends actually match the prototypes provided
 665 dnl by gmem.h (keep in sync). i currently only know how to check
 666 dnl this reliably with gcc (-Werror), improvements for other
 667 dnl compilers are apprechiated.
 668 SANE_MALLOC_PROTOS=no
 669 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 670 glib_save_CFLAGS=$CFLAGS
 671 if test "x$GCC" = "xyes"; then
 672   CFLAGS="$CFLAGS -Werror"
 673   AC_TRY_COMPILE([#include <stdlib.h>], [
 674     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 675     void* (*my_malloc_p)  (size_t)         = malloc;
 676     void  (*my_free_p)    (void*)          = free;
 677     void* (*my_realloc_p) (void*, size_t)  = realloc;
 678     my_calloc_p = 0;
 679     my_malloc_p = 0;
 680     my_free_p = 0;
 681     my_realloc_p = 0;
 682   ],
 683     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 684       [Define if you have correct malloc prototypes])
 685     SANE_MALLOC_PROTOS=yes)
 686 fi
 687 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 688 CFLAGS=$glib_save_CFLAGS
 689
 690 dnl
 691 dnl check in which direction the stack grows
 692 dnl
 693 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 694         AC_TRY_RUN([
 695         volatile int *a = 0, *b = 0;
 696         void foo (void);
 697         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 698         void foo (void) { volatile int x = 5; b = &x; }
 699         ],
 700         glib_cv_stack_grows=no
 701         ,
 702         glib_cv_stack_grows=yes
 703         ,)
 704 ])
 705
 706 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 707 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 708 dnl actually supported.
 709 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 710         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 711         __inline int foo () { return 0; }
 712         int main () { return foo (); }
 713         ]])],
 714         glib_cv_has__inline=yes
 715         ,
 716         glib_cv_has__inline=no
 717         ,)
 718 ])
 719 case x$glib_cv_has__inline in
 720 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 721 esac
 722 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 723         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 724         __inline__ int foo () { return 0; }
 725         int main () { return foo (); }
 726         ]])],
 727         glib_cv_has__inline__=yes
 728         ,
 729         glib_cv_has__inline__=no
 730         ,)
 731 ])
 732 case x$glib_cv_has__inline__ in
 733 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 734 esac
 735 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 736         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 737         #undef inline
 738         inline int foo () { return 0; }
 739         int main () { return foo (); }
 740         ]])],
 741         glib_cv_hasinline=yes
 742         ,
 743         glib_cv_hasinline=no
 744         ,)
 745 ])
 746 case x$glib_cv_hasinline in
 747 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 748 esac
 749
 750 # if we can use inline functions in headers
 751 AC_MSG_CHECKING(if inline functions in headers work)
 752 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 753 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 754 #  undef inline
 755 #  define inline __inline__
 756 #elif !defined (G_HAVE_INLINE)
 757 #  undef inline
 758 #  if defined (G_HAVE___INLINE__)
 759 #    define inline __inline__
 760 #  elif defined (G_HAVE___INLINE)
 761 #    define inline __inline
 762 #  endif
 763 #endif
 764
 765 int glib_test_func2 (int);
 766
 767 static inline int
 768 glib_test_func1 (void) {
 769   return glib_test_func2 (1);
 770 }
 771
 772 int
 773 main (void) {
 774   int i = 1;
 775 }]])],[g_can_inline=yes],[g_can_inline=no])
 776 AC_MSG_RESULT($g_can_inline)
 777
 778 dnl *** check for working do while(0) macros ***
 779 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 780         AC_TRY_COMPILE([],[
 781         #define STMT_START do
 782         #define STMT_END while(0)
 783         #define STMT_TEST STMT_START { i = 0; } STMT_END
 784         int main(void) { int i = 1; STMT_TEST; return i; }],
 785         [g_cv_support_dowhile_macros=yes],
 786         [g_cv_support_dowhile_macros=no],
 787         [g_cv_support_dowhile_macros=yes])
 788 ])
 789 if test x$g_cv_support_dowhile_macros = xyes; then
 790   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 791 fi
 792
 793 # check for flavours of varargs macros
 794 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 795 AC_TRY_COMPILE([],[
 796 int a(int p1, int p2, int p3);
 797 #define call_a(...) a(1,__VA_ARGS__)
 798 call_a(2,3);
 799 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 800 AC_MSG_RESULT($g_have_iso_c_varargs)
 801
 802 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 803 if test "$CXX" = ""; then
 804 dnl No C++ compiler
 805   g_have_iso_cxx_varargs=no
 806 else
 807   AC_LANG_CPLUSPLUS
 808   AC_TRY_COMPILE([],[
 809 int a(int p1, int p2, int p3);
 810 #define call_a(...) a(1,__VA_ARGS__)
 811 call_a(2,3);
 812 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 813   AC_LANG_C
 814 fi
 815 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 816
 817 AC_MSG_CHECKING(for GNUC varargs macros)
 818 AC_TRY_COMPILE([],[
 819 int a(int p1, int p2, int p3);
 820 #define call_a(params...) a(1,params)
 821 call_a(2,3);
 822 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 823 AC_MSG_RESULT($g_have_gnuc_varargs)
 824
 825 # check for GNUC visibility support
 826 AC_MSG_CHECKING(for GNUC visibility attribute)
 827 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 828 void
 829 __attribute__ ((visibility ("hidden")))
 830      f_hidden (void)
 831 {
 832 }
 833 void
 834 __attribute__ ((visibility ("internal")))
 835      f_internal (void)
 836 {
 837 }
 838 void
 839 __attribute__ ((visibility ("protected")))
 840      f_protected (void)
 841 {
 842 }
 843 void
 844 __attribute__ ((visibility ("default")))
 845      f_default (void)
 846 {
 847 }
 848 int main (int argc, char **argv)
 849 {
 850         f_hidden();
 851         f_internal();
 852         f_protected();
 853         f_default();
 854         return 0;
 855 }
 856 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 857 AC_MSG_RESULT($g_have_gnuc_visibility)
 858 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 859
 860 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 861 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 862 #else
 863 # include "error: this is not Sun Studio."
 864 #endif
 865 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 866 AC_MSG_RESULT($g_have_sunstudio_visibility)
 867 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 868
 869 # check for bytesex stuff
 870 AC_C_BIGENDIAN
 871 if test x$ac_cv_c_bigendian = xuniversal ; then
 872 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 873 #else
 874 #error Not a big endian.
 875 #endif],
 876     ac_cv_c_bigendian=yes
 877     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 878 #else
 879 #error Not a little endian.
 880 #endif],
 881     ac_cv_c_bigendian=no
 882     ,AC_MSG_WARN([Could not determine endianness.])))
 883 fi
 884
 885
 886 # check for header files
 887 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 888 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 889 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 890 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 891 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 892 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 893 AC_CHECK_HEADERS([linux/magic.h])
 894 AC_CHECK_HEADERS([sys/prctl.h])
 895
 896 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 897 [#if HAVE_SYS_PARAM_H
 898  #include <sys/param.h>
 899  #endif
 900 ])
 901
 902 AC_CHECK_HEADERS([xlocale.h])
 903
 904 # check for structure fields
 905 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 906 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 907 #include <sys/stat.h>
 908 #include <unistd.h>
 909 #ifdef HAVE_SYS_STATFS_H
 910 #include <sys/statfs.h>
 911 #endif
 912 #ifdef HAVE_SYS_PARAM_H
 913 #include <sys/param.h>
 914 #endif
 915 #ifdef HAVE_SYS_MOUNT_H
 916 #include <sys/mount.h>
 917 #endif])
 918 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 919 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 920 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 921 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 922
 923 AC_STRUCT_DIRENT_D_TYPE
 924
 925 # Checks for libcharset
 926 AM_LANGINFO_CODESET
 927 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 928 AC_CHECK_FUNCS(setlocale)
 929
 930 # check additional type sizes
 931 AC_CHECK_SIZEOF(size_t)
 932
 933 dnl Try to figure out whether gsize, gssize should be long or int
 934 AC_MSG_CHECKING([for the appropriate definition for size_t])
 935
 936 case $ac_cv_sizeof_size_t in
 937   $ac_cv_sizeof_short)
 938       glib_size_type=short
 939       ;;
 940   $ac_cv_sizeof_int)
 941       glib_size_type=int
 942       ;;
 943   $ac_cv_sizeof_long)
 944       glib_size_type=long
 945       ;;
 946   $ac_cv_sizeof_long_long)
 947       glib_size_type='long long'
 948       ;;
 949   $ac_cv_sizeof__int64)
 950       glib_size_type='__int64'
 951       ;;
 952   *)  AC_MSG_ERROR([No type matching size_t in size])
 953       ;;
 954 esac
 955
 956 dnl If int/long are the same size, we see which one produces
 957 dnl warnings when used in the location as size_t. (This matters
 958 dnl on AIX with xlc)
 959 dnl
 960 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 961    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 962   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 963 #if defined(_AIX) && !defined(__GNUC__)
 964 #pragma options langlvl=stdc89
 965 #endif
 966 #include <stddef.h>
 967 int main ()
 968 {
 969   size_t s = 1;
 970   unsigned int *size_int = &s;
 971   return (int)*size_int;
 972 }
 973     ]])],glib_size_type=int,
 974       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 975 #if defined(_AIX) && !defined(__GNUC__)
 976 #pragma options langlvl=stdc89
 977 #endif
 978 #include <stddef.h>
 979 int main ()
 980 {
 981    size_t s = 1;
 982    unsigned long *size_long = &s;
 983    return (int)*size_long;
 984 }
 985         ]])],glib_size_type=long)])
 986 fi
 987
 988 AC_MSG_RESULT(unsigned $glib_size_type)
 989
 990 # Check for some functions
 991 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 992 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid)
 993 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
 994 # Check for high-resolution sleep functions
 995 AC_CHECK_FUNCS(splice)
 996 AC_CHECK_FUNCS(prlimit)
 997
 998 # To avoid finding a compatibility unusable statfs, which typically
 999 # successfully compiles, but warns to use the newer statvfs interface:
1000 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1001 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1002
1003 AC_MSG_CHECKING([whether to use statfs or statvfs])
1004 # Some systems have both statfs and statvfs, pick the most "native" for these
1005 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1006    [
1007    # on solaris and irix, statfs doesn't even have the f_bavail field
1008    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1009       [ac_cv_func_statfs=no],
1010    # else, at least on linux, statfs is the actual syscall
1011       [ac_cv_func_statvfs=no])
1012    ])
1013
1014 AS_IF([test x$ac_cv_func_statfs = xyes],
1015       [
1016          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1017          AC_MSG_RESULT([statfs])
1018       ],
1019       [test x$ac_cv_func_statvfs = xyes],
1020       [
1021          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1022          AC_MSG_RESULT([statvfs])
1023       ],
1024       [  AC_MSG_RESULT([neither])])
1025
1026 AC_CHECK_HEADERS(crt_externs.h)
1027 AC_CHECK_FUNCS(_NSGetEnviron)
1028
1029 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1030
1031 AC_FUNC_VSNPRINTF_C99
1032 AC_FUNC_PRINTF_UNIX98
1033
1034 # Internet address families
1035 if test $glib_native_win32 = yes; then
1036   glib_inet_includes=["
1037 #include <winsock2.h>
1038   "]
1039 else
1040   glib_inet_includes=["
1041 #include <sys/types.h>
1042 #include <sys/socket.h>
1043   "]
1044 fi
1045
1046 glib_failed=false
1047 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1048 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1049 # winsock defines this even though it doesn't support it
1050 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1051 if $glib_failed ; then
1052   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1053 fi
1054
1055 glib_failed=false
1056 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1057 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1058 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1059 if $glib_failed ; then
1060   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1061 fi
1062
1063 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex)
1064 AC_CHECK_HEADERS([netdb.h wspiapi.h arpa/nameser_compat.h])
1065
1066 if test $glib_native_win32 = no; then
1067   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1068   NETWORK_LIBS=""
1069   AC_MSG_CHECKING([for res_query])
1070   AC_TRY_LINK([#include <sys/types.h>
1071                #include <netinet/in.h>
1072                #include <arpa/nameser.h>
1073                #include <resolv.h>
1074               ],[
1075                res_query("test", 0, 0, (void *)0, 0);
1076               ],[AC_MSG_RESULT([yes])],
1077               [save_libs="$LIBS"
1078                LIBS="-lresolv $LIBS"
1079                AC_TRY_LINK([#include <sys/types.h>
1080                             #include <netinet/in.h>
1081                             #include <arpa/nameser.h>
1082                             #include <resolv.h>
1083                            ],[
1084                             res_query("test", 0, 0, (void *)0, 0);
1085                            ],[AC_MSG_RESULT([in -lresolv])
1086                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1087                            [LIBS="-lbind $save_libs"
1088                             AC_TRY_LINK([#include <resolv.h>],
1089                                         [res_query("test", 0, 0, (void *)0, 0);],
1090                                         [AC_MSG_RESULT([in -lbind])
1091                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1092                                         [AC_MSG_ERROR(not found)])])
1093                LIBS="$save_libs"])
1094   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1095                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1096                                         [AC_MSG_ERROR(Could not find socket())]))
1097 fi
1098 AC_SUBST(NETWORK_LIBS)
1099
1100 AC_CHECK_HEADER([linux/netlink.h],
1101                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1102                 [#include <sys/socket.h>])
1103 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1104
1105 AC_CHECK_TYPE([struct ip_mreqn], [
1106               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1107               [#include <netinet/in.h>])
1108
1109 case $host in
1110   *-*-solaris* )
1111      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1112      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1113      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1114      ;;
1115 esac
1116
1117 dnl
1118 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1119 dnl
1120 if test "$ac_cv_func_statfs" = yes ; then
1121   AC_MSG_CHECKING([number of arguments to statfs()])
1122   AC_TRY_COMPILE([#include <unistd.h>
1123   #ifdef HAVE_SYS_PARAM_H
1124   #include <sys/param.h>
1125   #endif
1126   #ifdef HAVE_SYS_VFS_H
1127   #include <sys/vfs.h>
1128   #endif
1129   #ifdef HAVE_SYS_MOUNT_H
1130   #include <sys/mount.h>
1131   #endif
1132   #ifdef HAVE_SYS_STATFS_H
1133   #include <sys/statfs.h>
1134   #endif], [struct statfs st;
1135   statfs(NULL, &st);],[
1136     AC_MSG_RESULT([2])
1137     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1138     AC_TRY_COMPILE([#include <unistd.h>
1139   #ifdef HAVE_SYS_PARAM_H
1140   #include <sys/param.h>
1141   #endif
1142   #ifdef HAVE_SYS_VFS_H
1143   #include <sys/vfs.h>
1144   #endif
1145   #ifdef HAVE_SYS_MOUNT_H
1146   #include <sys/mount.h>
1147   #endif
1148   #ifdef HAVE_SYS_STATFS_H
1149   #include <sys/statfs.h>
1150   #endif], [struct statfs st;
1151   statfs(NULL, &st, sizeof (st), 0);],[
1152       AC_MSG_RESULT([4])
1153       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1154       AC_MSG_RESULT(unknown)
1155       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1156 fi
1157
1158 #
1159 # Check whether to use an included printf
1160 #
1161
1162 AC_ARG_ENABLE(included-printf,
1163               [AC_HELP_STRING([--enable-included-printf],
1164                               [use included printf [default=auto]])],
1165               enable_included_printf="$enableval")
1166
1167 need_included_printf=no
1168 if test "x$enable_included_printf" = "xyes" ; then
1169   need_included_printf=yes
1170 fi
1171 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1172   need_included_printf=yes
1173 fi
1174 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1175   need_included_printf=yes
1176 fi
1177 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1178    test -z "$glib_cv_long_long_format" ; then
1179   need_included_printf=yes
1180 fi
1181
1182 if test "x$enable_included_printf" = "xno" &&
1183    test "x$need_included_printf" = "xyes" ; then
1184   AC_MSG_ERROR([
1185 *** Your C library's printf doesn't appear to have the features that
1186 *** GLib needs, but you specified --enable-included-printf=no.])
1187 fi
1188
1189 enable_included_printf=$need_included_printf
1190
1191 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1192 if test "$enable_included_printf" != "yes" ; then
1193   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1194 else
1195   if test -z "$glib_cv_long_long_format" ; then
1196     glib_cv_long_long_format="ll"
1197   fi
1198   AC_DEFINE(HAVE_VASPRINTF,1)
1199 fi
1200
1201 # Checks needed for gnulib vasnprintf
1202 bh_C_SIGNED
1203 jm_AC_TYPE_LONG_LONG
1204 gt_TYPE_LONGDOUBLE
1205 gt_TYPE_WCHAR_T
1206 gt_TYPE_WINT_T
1207 AC_TYPE_SIZE_T
1208 AC_CHECK_TYPES(ptrdiff_t)
1209 jm_AC_TYPE_INTMAX_T
1210 AC_CHECK_FUNCS([snprintf wcslen])
1211 AC_FUNC_SNPRINTF_C99
1212
1213 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1214 # The check is borrowed from the PERL Configure script.
1215 if test "$ac_cv_func_memmove" != "yes"; then
1216   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1217     glib_cv_working_bcopy,[AC_TRY_RUN([
1218       int main() {
1219         char buf[128], abc[128], *b;
1220         int len, off, align;
1221         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1222         for (align = 7; align >= 0; align--) {
1223           for (len = 36; len; len--) {
1224             b = buf+align; bcopy(abc, b, len);
1225             for (off = 1; off <= len; off++) {
1226               bcopy(b, b+off, len); bcopy(b+off, b, len);
1227                 if (bcmp(b, abc, len)) return(1);
1228             }
1229           }
1230         }
1231         return(0);
1232       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1233
1234   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1235   if test "$glib_cv_working_bcopy" = "yes"; then
1236     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1237   fi
1238 fi
1239
1240 # Check if <sys/select.h> needs to be included for fd_set
1241 AC_MSG_CHECKING([for fd_set])
1242 AC_TRY_COMPILE([#include <sys/types.h>],
1243         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1244 if test "$gtk_ok" = "yes"; then
1245     AC_MSG_RESULT([yes, found in sys/types.h])
1246 else
1247     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1248     if test "$gtk_ok" = "yes"; then
1249         # *** FIXME: give it a different name
1250         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1251         AC_MSG_RESULT([yes, found in sys/select.h])
1252     else
1253         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1254         AC_MSG_RESULT(no)
1255     fi
1256 fi
1257
1258 dnl *** check for sane realloc() ***
1259 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1260         AC_TRY_RUN([#include <stdlib.h>
1261         int main() {
1262           return realloc (0, sizeof (int)) == 0;
1263         }],
1264         [glib_cv_sane_realloc=yes],
1265         [glib_cv_sane_realloc=no],
1266         [glib_cv_sane_realloc=yes])
1267 ])
1268 if test x$glib_cv_sane_realloc = xyes; then
1269   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1270 fi
1271
1272 dnl Check for nl_langinfo and CODESET
1273 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1274         AC_TRY_COMPILE([#include <langinfo.h>],
1275                 [char *codeset = nl_langinfo (CODESET);],
1276                 [glib_cv_langinfo_codeset=yes],
1277                 [glib_cv_langinfo_codeset=no])])
1278 if test x$glib_cv_langinfo_codeset = xyes; then
1279   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1280 fi
1281
1282 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1283 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1284         AC_TRY_COMPILE([#include <langinfo.h>],
1285                 [char *str;
1286                  str = nl_langinfo (PM_STR);
1287                  str = nl_langinfo (D_T_FMT);
1288                  str = nl_langinfo (D_FMT);
1289                  str = nl_langinfo (T_FMT);
1290                  str = nl_langinfo (T_FMT_AMPM);
1291                  str = nl_langinfo (MON_1);
1292                  str = nl_langinfo (ABMON_12);
1293                  str = nl_langinfo (DAY_1);
1294                  str = nl_langinfo (ABDAY_7);],
1295                 [glib_cv_langinfo_time=yes],
1296                 [glib_cv_langinfo_time=no])])
1297 if test x$glib_cv_langinfo_time = xyes; then
1298   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1299 fi
1300
1301 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1302 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1303         AC_TRY_COMPILE([#include <langinfo.h>],
1304                 [char *str;
1305                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1306                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1307                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1308                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1309                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1310                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1311                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1312                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1313                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1314                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);],
1315                 [glib_cv_langinfo_outdigit=yes],
1316                 [glib_cv_langinfo_outdigit=no])])
1317 if test x$glib_cv_langinfo_outdigit = xyes; then
1318   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1319 fi
1320
1321 dnl ****************************************
1322 dnl *** posix_memalign                   ***
1323 dnl ****************************************
1324 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1325 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1326     glib_cv_compliant_posix_memalign=0
1327     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1328         AC_TRY_RUN([
1329                 #define _XOPEN_SOURCE 600
1330                 #include <stdlib.h> /* posix_memalign() should be defined here */
1331                 /* some systems break if #include <malloc.h> used */
1332                 static void test_memalign (size_t boundary, size_t size) {
1333                     void *mem = 0;
1334                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1335                         exit (1);
1336                     else
1337                       free (mem);
1338                 }
1339                 int main() {
1340                     test_memalign (  128,   128 - 2 * sizeof (void*));
1341                     test_memalign (  256,   256 - 2 * sizeof (void*));
1342                     test_memalign (  512,   512 - 2 * sizeof (void*));
1343                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1344                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1345                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1346                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1347                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1348                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1349                     exit (0); /* success */
1350                 }
1351                 ],
1352             [glib_cv_compliant_posix_memalign=1], [], [:])
1353       :
1354     fi
1355     ])
1356 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1357     AC_MSG_RESULT(yes)
1358     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1359 else
1360     AC_MSG_RESULT(no)
1361 fi
1362
1363
1364 dnl ****************************************
1365 dnl *** strlcpy/strlcat                  ***
1366 dnl ****************************************
1367 # Check for strlcpy
1368 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1369 AC_TRY_RUN([#include <stdlib.h>
1370 #include <string.h>
1371 int main() {
1372   char p[10];
1373   (void) strlcpy (p, "hi", 10);
1374   if (strlcat (p, "bye", 0) != 3)
1375     return 1;
1376   return 0;
1377 }], glib_cv_have_strlcpy=yes,
1378     glib_cv_have_strlcpy=no,
1379     glib_cv_have_strlcpy=no)])
1380 if test "$glib_cv_have_strlcpy" = "yes"; then
1381     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1382 fi
1383
1384
1385 dnl **********************
1386 dnl *** va_copy checks ***
1387 dnl **********************
1388 dnl we currently check for all three va_copy possibilities, so we get
1389 dnl all results in config.log for bug reports.
1390 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1391         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1392 #include <stdlib.h>
1393         void f (int i, ...) {
1394         va_list args1, args2;
1395         va_start (args1, i);
1396         va_copy (args2, args1);
1397         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1398           exit (1);
1399         va_end (args1); va_end (args2);
1400         }
1401         int main() {
1402           f (0, 42);
1403           return 0;
1404         }]])],
1405         [glib_cv_va_copy=yes],
1406         [glib_cv_va_copy=no])
1407 ])
1408 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1409         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1410 #include <stdlib.h>
1411         void f (int i, ...) {
1412         va_list args1, args2;
1413         va_start (args1, i);
1414         __va_copy (args2, args1);
1415         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1416           exit (1);
1417         va_end (args1); va_end (args2);
1418         }
1419         int main() {
1420           f (0, 42);
1421           return 0;
1422         }]])],
1423         [glib_cv___va_copy=yes],
1424         [glib_cv___va_copy=no])
1425 ])
1426
1427 if test "x$glib_cv_va_copy" = "xyes"; then
1428   g_va_copy_func=va_copy
1429 else if test "x$glib_cv___va_copy" = "xyes"; then
1430   g_va_copy_func=__va_copy
1431 fi
1432 fi
1433
1434 if test -n "$g_va_copy_func"; then
1435   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1436 fi
1437
1438 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1439         AC_TRY_RUN([#include <stdarg.h>
1440 #include <stdlib.h>
1441         void f (int i, ...) {
1442         va_list args1, args2;
1443         va_start (args1, i);
1444         args2 = args1;
1445         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1446           exit (1);
1447         va_end (args1); va_end (args2);
1448         }
1449         int main() {
1450           f (0, 42);
1451           return 0;
1452         }],
1453         [glib_cv_va_val_copy=yes],
1454         [glib_cv_va_val_copy=no],
1455         [glib_cv_va_val_copy=yes])
1456 ])
1457
1458 if test "x$glib_cv_va_val_copy" = "xno"; then
1459   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1460 fi
1461
1462 dnl ***********************
1463 dnl *** g_module checks ***
1464 dnl ***********************
1465 G_MODULE_LIBS=
1466 G_MODULE_LIBS_EXTRA=
1467 G_MODULE_PLUGIN_LIBS=
1468 if test x"$glib_native_win32" = xyes; then
1469   dnl No use for this on Win32
1470   G_MODULE_LDFLAGS=
1471 else
1472   export SED
1473   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1474 fi
1475 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1476 G_MODULE_NEED_USCORE=0
1477 G_MODULE_BROKEN_RTLD_GLOBAL=0
1478 G_MODULE_HAVE_DLERROR=0
1479 dnl *** force native WIN32 shared lib loader
1480 if test -z "$G_MODULE_IMPL"; then
1481   case "$host" in
1482   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1483   esac
1484 fi
1485 dnl *** force native AIX library loader
1486 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1487 if test -z "$G_MODULE_IMPL"; then
1488   case "$host" in
1489   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1490   esac
1491 fi
1492 dnl *** dlopen() and dlsym() in system libraries
1493 if test -z "$G_MODULE_IMPL"; then
1494         AC_CHECK_FUNC(dlopen,
1495                       [AC_CHECK_FUNC(dlsym,
1496                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1497                       [])
1498 fi
1499 dnl *** load_image (BeOS)
1500 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1501   AC_CHECK_LIB(root, load_image,
1502       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1503       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1504       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1505       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1506       [])
1507 fi
1508 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1509 if test -z "$G_MODULE_IMPL"; then
1510         AC_CHECK_FUNC(NSLinkModule,
1511                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1512                        G_MODULE_NEED_USCORE=1],
1513                       [])
1514 fi
1515 dnl *** dlopen() and dlsym() in libdl
1516 if test -z "$G_MODULE_IMPL"; then
1517         AC_CHECK_LIB(dl, dlopen,
1518                      [AC_CHECK_LIB(dl, dlsym,
1519                                    [G_MODULE_LIBS=-ldl
1520                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1521                      [])
1522 fi
1523 dnl *** shl_load() in libdld (HP-UX)
1524 if test -z "$G_MODULE_IMPL"; then
1525         AC_CHECK_LIB(dld, shl_load,
1526                 [G_MODULE_LIBS=-ldld
1527                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1528                 [])
1529 fi
1530 dnl *** additional checks for G_MODULE_IMPL_DL
1531 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1532         LIBS_orig="$LIBS"
1533         LDFLAGS_orig="$LDFLAGS"
1534         LIBS="$G_MODULE_LIBS $LIBS"
1535         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1536 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1537         echo "void glib_plugin_test(void) { }" > plugin.c
1538         ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1539                 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1540         ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1541                 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1542                 -shrext ".o" -avoid-version plugin.lo \
1543                 -rpath /dont/care >/dev/null 2>&1
1544         eval `./libtool --config | grep ^objdir`
1545         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1546                 glib_cv_rtldglobal_broken,[
1547                 AC_TRY_RUN([
1548 #include <dlfcn.h>
1549 #ifndef RTLD_GLOBAL
1550 #  define RTLD_GLOBAL 0
1551 #endif
1552 #ifndef RTLD_LAZY
1553 #  define RTLD_LAZY 0
1554 #endif
1555 int glib_plugin_test;
1556 int main () {
1557     void *handle, *global, *local;
1558     global = &glib_plugin_test;
1559     handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1560     if (!handle) return 0;
1561     local = dlsym (handle, "glib_plugin_test");
1562     return global == local;
1563 }                       ],
1564                         [glib_cv_rtldglobal_broken=no],
1565                         [glib_cv_rtldglobal_broken=yes],
1566                         [glib_cv_rtldglobal_broken=no])
1567                 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1568                 rmdir ${objdir} 2>/dev/null
1569         ])
1570         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1571                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1572         else
1573                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1574         fi
1575 dnl *** check whether we need preceeding underscores
1576         AC_CACHE_CHECK([for preceeding underscore in symbols],
1577                 glib_cv_uscore,[
1578                 AC_TRY_RUN([#include <dlfcn.h>
1579                 int glib_underscore_test (void) { return 42; }
1580                 int main() {
1581                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1582                   handle = dlopen ((void*)0, 0);
1583                   if (handle) {
1584                     f1 = dlsym (handle, "glib_underscore_test");
1585                     f2 = dlsym (handle, "_glib_underscore_test");
1586                   } return (!f2 || f1);
1587                 }],
1588                         [glib_cv_uscore=yes],
1589                         [glib_cv_uscore=no],
1590                         [])
1591                 rm -f plugin.c plugin.$ac_objext plugin.lo
1592         ])
1593         GLIB_ASSERT_SET(glib_cv_uscore)
1594         if test "x$glib_cv_uscore" = "xyes"; then
1595                 G_MODULE_NEED_USCORE=1
1596         else
1597                 G_MODULE_NEED_USCORE=0
1598         fi
1599
1600         LDFLAGS="$LDFLAGS_orig"
1601 dnl *** check for having dlerror()
1602         AC_CHECK_FUNC(dlerror,
1603                 [G_MODULE_HAVE_DLERROR=1],
1604                 [G_MODULE_HAVE_DLERROR=0])
1605         LIBS="$LIBS_orig"
1606 fi
1607 dnl *** done, have we got an implementation?
1608 if test -z "$G_MODULE_IMPL"; then
1609         G_MODULE_IMPL=0
1610         G_MODULE_SUPPORTED=false
1611 else
1612         G_MODULE_SUPPORTED=true
1613 fi
1614
1615 AC_MSG_CHECKING(for the suffix of module shared libraries)
1616 export SED
1617 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1618 eval $shrext_cmds
1619 module=yes eval std_shrext=$shrext_cmds
1620 # chop the initial dot
1621 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1622 AC_MSG_RESULT(.$glib_gmodule_suffix)
1623 # any reason it may fail?
1624 if test "x$glib_gmodule_suffix" = x; then
1625         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1626 fi
1627
1628 AC_SUBST(G_MODULE_SUPPORTED)
1629 AC_SUBST(G_MODULE_IMPL)
1630 AC_SUBST(G_MODULE_LIBS)
1631 AC_SUBST(G_MODULE_LIBS_EXTRA)
1632 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1633 AC_SUBST(G_MODULE_LDFLAGS)
1634 AC_SUBST(G_MODULE_HAVE_DLERROR)
1635 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1636 AC_SUBST(G_MODULE_NEED_USCORE)
1637 AC_SUBST(GLIB_DEBUG_FLAGS)
1638
1639 dnl **********************
1640 dnl *** g_spawn checks ***
1641 dnl **********************
1642
1643 AC_MSG_CHECKING(for gspawn implementation)
1644 case "$host" in
1645   *-*-mingw*)
1646     GSPAWN=gspawn-win32.lo
1647     ;;
1648   *)
1649     GSPAWN=gspawn.lo
1650     ;;
1651 esac
1652 AC_MSG_RESULT($GSPAWN)
1653 AC_SUBST(GSPAWN)
1654
1655 dnl *************************
1656 dnl *** GIOChannel checks ***
1657 dnl *************************
1658
1659 AC_MSG_CHECKING(for GIOChannel implementation)
1660 case "$host" in
1661   *-*-mingw*)
1662     GIO=giowin32.lo
1663     ;;
1664   *)
1665     GIO=giounix.lo
1666     ;;
1667 esac
1668 AC_MSG_RESULT($GIO)
1669 AC_SUBST(GIO)
1670
1671 dnl *********************************
1672 dnl *** Directory for GIO modules ***
1673 dnl *********************************
1674
1675 AC_ARG_WITH(gio-module-dir,
1676            [AC_HELP_STRING([--with-gio-module-dir=DIR],
1677                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1678            [],
1679            [with_gio_module_dir='${libdir}/gio/modules'])
1680 GIO_MODULE_DIR=$with_gio_module_dir
1681 AC_SUBST(GIO_MODULE_DIR)
1682
1683 dnl **********************************
1684 dnl *** Check for libselinux (GIO) ***
1685 dnl **********************************
1686 AC_ARG_ENABLE(selinux,
1687               AC_HELP_STRING([--disable-selinux],
1688                              [build without selinux support]))
1689 msg_selinux=no
1690 SELINUX_LIBS=
1691 if test "x$enable_selinux" != "xno"; then
1692
1693  AC_CHECK_LIB(selinux, is_selinux_enabled,
1694    [AC_CHECK_HEADERS(selinux/selinux.h,
1695      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1696        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1697         SELINUX_LIBS="-lselinux"
1698         msg_selinux=yes])
1699      ])
1700    ])
1701 fi
1702 AC_SUBST(SELINUX_LIBS)
1703
1704 dnl *****************************
1705 dnl ** Check for inotify (GIO) **
1706 dnl *****************************
1707 inotify_support=no
1708 AC_CHECK_HEADERS([sys/inotify.h],
1709 [
1710         inotify_support=yes
1711         AC_CHECK_FUNCS(inotify_init1)
1712 ])
1713
1714 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1715
1716 dnl *********************************
1717 dnl ** Check for Solaris FEN (GIO) **
1718 dnl *********************************
1719 fen_support=no
1720 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1721 #include <port.h>
1722 #ifndef PORT_SOURCE_FILE
1723 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1724 #endif
1725 int main() { return 0; } ]])],
1726 [
1727         fen_support=yes
1728 ],)
1729
1730 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1731
1732 dnl ****************************
1733 dnl *** Checks for FAM (GIO) ***
1734 dnl ****************************
1735
1736 should_disable_fam=no
1737
1738 AC_ARG_ENABLE(fam,
1739               AC_HELP_STRING([--disable-fam],
1740                              [don't use fam for file system monitoring]),
1741                          [
1742                                 if test "x$enable_fam" = "xno"; then
1743                                         should_disable_fam=yes
1744                                 fi
1745                          ]
1746                          )
1747 fam_support=no
1748 FAM_LIBS=
1749 if test "x$should_disable_fam" = "xno"; then
1750 AC_CHECK_LIB(fam, FAMOpen,
1751   [AC_CHECK_HEADERS(fam.h,
1752     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1753      AC_CHECK_LIB(fam, FAMNoExists,
1754                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1755      FAM_LIBS="-lfam"]
1756      fam_support=yes,
1757     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1758   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1759 AC_SUBST(FAM_LIBS)
1760 fi
1761 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1762
1763
1764 dnl *****************************
1765 dnl *** Check for xattr (GIO) ***
1766 dnl *****************************
1767 AC_ARG_ENABLE(xattr,
1768               AC_HELP_STRING([--disable-xattr], [build without xattr support]))
1769 msg_xattr=no
1770 XATTR_LIBS=
1771 if test "x$enable_xattr" != "xno"; then
1772
1773 dnl either glibc or libattr can provide xattr support
1774
1775 dnl for both of them, we check for getxattr being in
1776 dnl the library and a valid xattr header.
1777
1778 dnl try glibc
1779  AC_CHECK_LIB(c, getxattr,
1780    [AC_CHECK_HEADERS(sys/xattr.h,
1781      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1782       msg_xattr=yes])
1783    ])
1784
1785   if test "x$msg_xattr" != "xyes"; then
1786 dnl   failure. try libattr
1787    AC_CHECK_LIB(attr, getxattr,
1788       [AC_CHECK_HEADERS(attr/xattr.h,
1789        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1790         XATTR_LIBS="-lattr"
1791         msg_xattr=yes])
1792       ])
1793   fi
1794
1795   if test "x$msg_xattr" = "xyes"; then
1796     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1797     AC_TRY_COMPILE([
1798       #include <stdio.h>
1799       #ifdef HAVE_SYS_TYPES_H
1800       #include <sys/types.h>
1801       #endif
1802       #ifdef HAVE_SYS_XATTR_H
1803       #include <sys/xattr.h>
1804       #elif HAVE_ATTR_XATTR_H
1805       #include <attr/xattr.h>
1806       #endif
1807     ],
1808     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1809     [
1810       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1811       AC_MSG_RESULT([yes])
1812     ],
1813     [AC_MSG_RESULT([no])]
1814     )
1815   fi
1816
1817 fi
1818 AC_SUBST(XATTR_LIBS)
1819
1820 dnl ************************
1821 dnl *** check for libelf ***
1822 dnl ************************
1823
1824 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=maybe])
1825
1826 if test $have_libelf = maybe; then
1827   AC_CHECK_LIB([elf], [elf_begin], , [have_libelf=no])
1828   AC_CHECK_LIB([elf], [elf_getshdrstrndx], , [have_libelf=no])
1829   AC_CHECK_LIB([elf], [elf_getshdrnum], , [have_libelf=no])
1830   AC_CHECK_HEADER([libelf.h], , [have_libelf=no])
1831
1832   if test $have_libelf != no; then
1833     LIBELF_LIBS=-lelf
1834     have_libelf=yes
1835   fi
1836 fi
1837
1838 if test $have_libelf = yes; then
1839   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1840 fi
1841
1842 dnl ****************************************
1843 dnl *** platform dependent source checks ***
1844 dnl ****************************************
1845
1846 AC_MSG_CHECKING(for platform-dependent source)
1847 case "$host" in
1848   *-*-cygwin*|*-*-mingw*)
1849     PLATFORMDEP=gwin32.lo
1850     ;;
1851   *)
1852     PLATFORMDEP=
1853     ;;
1854 esac
1855 AC_MSG_RESULT($PLATFORMDEP)
1856 AC_SUBST(PLATFORMDEP)
1857
1858 AC_MSG_CHECKING([whether to compile timeloop])
1859 case "$host" in
1860   *-*-cygwin*|*-*-mingw*|*-*-minix)
1861     enable_timeloop=no
1862     ;;
1863   *)
1864     enable_timeloop=yes
1865     ;;
1866 esac
1867 AC_MSG_RESULT($enable_timeloop)
1868 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1869
1870 AC_MSG_CHECKING([if building for some Win32 platform])
1871 case "$host" in
1872   *-*-mingw*|*-*-cygwin*)
1873     platform_win32=yes
1874     ;;
1875   *)
1876     platform_win32=no
1877     ;;
1878 esac
1879 AC_MSG_RESULT($platform_win32)
1880 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1881
1882 dnl ***********************
1883 dnl *** g_thread checks ***
1884 dnl ***********************
1885
1886 AC_ARG_WITH(threads,
1887            [AC_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1888                            [specify a thread implementation to use])],
1889            [],
1890            [with_threads=yes])
1891
1892 dnl error and warning message
1893 dnl *************************
1894
1895 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1896
1897 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1898                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1899                 compilation now, but then your programs might not work.
1900                 Please provide information on how it is done on your system."
1901
1902 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1903                  "
1904
1905 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1906                   provide information on your thread implementation."
1907
1908 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1909                 functions will not be MT-safe during their first call because
1910                 there is no working 'getpwuid_r' on your system."
1911
1912 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1913                 because there is no 'localtime_r' on your system."
1914
1915 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1916                 linking threaded applications. As GLib cannot do that
1917                 automatically, you will get an linkg error everytime you are
1918                 not using the right compiler. In that case you have to relink
1919                 with the right compiler. Ususally just '_r' is appended
1920                 to the compiler name."
1921
1922 dnl determination of thread implementation
1923 dnl ***************************************
1924
1925 AC_MSG_CHECKING(for thread implementation)
1926
1927 have_threads=no
1928 if test "x$with_threads" = xyes || test "x$with_threads" = xposix; then
1929         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1930         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1931         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1932         glib_save_CPPFLAGS="$CPPFLAGS"
1933         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1934         if test "x$have_threads" = xno; then
1935                 AC_TRY_COMPILE([#include <pthread.h>],
1936                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1937                         have_threads=posix)
1938         fi
1939         # Tru64Unix requires -pthread to find pthread.h. See #103020
1940         CPPFLAGS="$CPPFLAGS -pthread"
1941         if test "x$have_threads" = xno; then
1942         AC_TRY_COMPILE([#include <pthread.h>],
1943                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1944                        have_threads=posix)
1945         fi
1946         CPPFLAGS="$glib_save_CPPFLAGS"
1947 fi
1948 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1949         case $host in
1950                 *-*-mingw*)
1951                 have_threads=win32
1952                 ;;
1953         esac
1954 fi
1955
1956 if test "x$have_threads" = xno; then
1957         AC_MSG_RESULT(none available)
1958         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1959 else
1960         AC_MSG_RESULT($have_threads)
1961 fi
1962
1963
1964 dnl determination of G_THREAD_CFLAGS
1965 dnl ********************************
1966
1967 G_THREAD_LIBS=
1968 G_THREAD_LIBS_EXTRA=
1969 G_THREAD_CFLAGS=
1970
1971 dnl
1972 dnl Test program for basic POSIX threads functionality
1973 dnl
1974 m4_define([glib_thread_test],[
1975 #include <pthread.h>
1976 int check_me = 0;
1977 void* func(void* data) {check_me = 42; return &check_me;}
1978 int main()
1979  { pthread_t t;
1980    void *ret;
1981    pthread_create (&t, $1, func, 0);
1982    pthread_join (t, &ret);
1983    return (check_me != 42 || ret != &check_me);
1984 }])
1985
1986 if test x"$have_threads" = xposix; then
1987   # First we test for posix, whether -pthread or -pthreads do the trick as
1988   # both CPPFLAG and LIBS.
1989   # One of them does for most gcc versions and some other platforms/compilers
1990   # too and could be considered as the canonical way to go.
1991   case $host in
1992     *-*-cygwin*|*-*-darwin*)
1993        # skip cygwin and darwin -pthread or -pthreads test
1994        ;;
1995     *-solaris*)
1996       # These compiler/linker flags work with both Sun Studio and gcc
1997       # Sun Studio expands -mt to -D_REENTRANT and -lthread
1998       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1999       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2000       G_THREAD_LIBS="-lpthread -lthread"
2001       ;;
2002     *)
2003       for flag in pthread pthreads mt; do
2004         glib_save_CFLAGS="$CFLAGS"
2005         CFLAGS="$CFLAGS -$flag"
2006         AC_TRY_RUN(glib_thread_test(0),
2007                    glib_flag_works=yes,
2008                    glib_flag_works=no,
2009                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2010                                    glib_flag_works=yes,
2011                                    glib_flag_works=no)])
2012         CFLAGS="$glib_save_CFLAGS"
2013         if test $glib_flag_works = yes ; then
2014            G_THREAD_CFLAGS=-$flag
2015         G_THREAD_LIBS=-$flag
2016         break;
2017         fi
2018       done
2019        ;;
2020   esac
2021 fi
2022
2023 if test x"$G_THREAD_CFLAGS" = x; then
2024
2025   # The canonical -pthread[s] does not work. Try something different.
2026
2027   case $host in
2028         *-aix*)
2029                 if test x"$GCC" = xyes; then
2030                         # GCC 3.0 and above needs -pthread.
2031                         # Should be coverd by the case above.
2032                         # GCC 2.x and below needs -mthreads
2033                         G_THREAD_CFLAGS="-mthreads"
2034                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2035                 else
2036                         # We are probably using the aix compiler. Normaly a
2037                         # program would have to be compiled with the _r variant
2038                         # of the corresponding compiler, but we as GLib cannot
2039                         # do that: but the good news is that for compiling the
2040                         # only difference is the added -D_THREAD_SAFE compile
2041                         # option. This is according to the "C for AIX User's
2042                         # Guide".
2043                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2044                 fi
2045                 ;;
2046         *-dg-dgux*)  # DG/UX
2047                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2048                 ;;
2049         *-sysv5uw7*) # UnixWare 7
2050                 # We are not using gcc with -pthread. Catched above.
2051                 G_THREAD_CFLAGS="-Kthread"
2052                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2053                 ;;
2054         *-mingw*)
2055                 # No flag needed when using MSVCRT.DLL
2056                 G_THREAD_CFLAGS=""
2057                 ;;
2058         *)
2059                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2060                 ;;
2061   esac
2062
2063 fi
2064
2065 # if we are not finding the localtime_r function, then we probably are
2066 # not using the proper multithread flag
2067
2068 glib_save_CPPFLAGS="$CPPFLAGS"
2069 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2070
2071 # First we test, whether localtime_r is declared in time.h
2072 # directly. Then we test whether a macro localtime_r exists, in
2073 # which case localtime_r in the test program is replaced and thus
2074 # if we still find localtime_r in the output, it is not defined as
2075 # a macro.
2076
2077 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2078   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2079                                                            localtime_r(a,b)],
2080                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2081
2082 CPPFLAGS="$glib_save_CPPFLAGS"
2083
2084 AC_MSG_CHECKING(thread related cflags)
2085 AC_MSG_RESULT($G_THREAD_CFLAGS)
2086 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2087
2088 dnl determination of G_THREAD_LIBS
2089 dnl ******************************
2090
2091 case $have_threads in
2092         posix)
2093           glib_save_CPPFLAGS="$CPPFLAGS"
2094           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2095           if test x"$G_THREAD_LIBS" = x; then
2096             case $host in
2097               *-aix*)
2098                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2099                 # probably using the aix compiler.
2100                 AC_MSG_WARN($AIX_COMPILE_INFO)
2101                 ;;
2102               *)
2103                 G_THREAD_LIBS=error
2104                 glib_save_LIBS="$LIBS"
2105                 for thread_lib in "" pthread pthread32 pthreads thread; do
2106                         if test x"$thread_lib" = x; then
2107                                 add_thread_lib=""
2108                                 IN=""
2109                         else
2110                                 add_thread_lib="-l$thread_lib"
2111                                 IN=" in -l$thread_lib"
2112                         fi
2113                         if test x"$have_threads" = xposix; then
2114                                 defattr=0
2115                         else
2116                                 defattr=pthread_attr_default
2117                         fi
2118
2119                         LIBS="$add_thread_lib $glib_save_LIBS"
2120
2121                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2122                         AC_TRY_RUN(glib_thread_test($defattr),
2123                                    glib_result=yes,
2124                                    glib_result=no,
2125                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2126                                                    glib_result=yes,
2127                                                    glib_result=no)])
2128                         AC_MSG_RESULT($glib_result)
2129
2130                         if test "$glib_result" = "yes" ; then
2131                           G_THREAD_LIBS="$add_thread_lib"
2132                           break
2133                         fi
2134                 done
2135                 if test "x$G_THREAD_LIBS" = xerror; then
2136                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2137                 fi
2138                 LIBS="$glib_save_LIBS"
2139                 ;;
2140             esac
2141           fi
2142
2143           g_threads_impl="POSIX"
2144           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2145           CPPFLAGS="$glib_save_CPPFLAGS"
2146           ;;
2147         win32)
2148            g_threads_impl="WIN32"
2149            ;;
2150         *)
2151            g_threads_impl="NONE"
2152            G_THREAD_LIBS=error
2153            ;;
2154 esac
2155
2156 if test "x$G_THREAD_LIBS" = xerror; then
2157         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2158 fi
2159
2160 case $host in
2161   *-*-beos*)
2162     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2163     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2164     ;;
2165   *)
2166     ;;
2167 esac
2168
2169 AC_MSG_CHECKING(thread related libraries)
2170 AC_MSG_RESULT($G_THREAD_LIBS)
2171
2172 dnl check for mt safe function variants and some posix functions
2173 dnl ************************************************************
2174
2175 glib_save_LIBS="$LIBS"
2176 # we are not doing the following for now, as this might require glib
2177 # to always be linked with the thread libs on some platforms.
2178 # LIBS="$LIBS $G_THREAD_LIBS"
2179 AC_CHECK_FUNCS(localtime_r gmtime_r)
2180 if test "$ac_cv_header_pwd_h" = "yes"; then
2181         AC_CACHE_CHECK([for posix getpwuid_r],
2182                 ac_cv_func_posix_getpwuid_r,
2183                 [AC_TRY_RUN([
2184 #include <errno.h>
2185 #include <pwd.h>
2186 int main () {
2187     char buffer[10000];
2188     struct passwd pwd, *pwptr = &pwd;
2189     int error;
2190     errno = 0;
2191     error = getpwuid_r (0, &pwd, buffer,
2192                         sizeof (buffer), &pwptr);
2193    return (error < 0 && errno == ENOSYS)
2194            || error == ENOSYS;
2195 }                               ],
2196                         [ac_cv_func_posix_getpwuid_r=yes],
2197                         [ac_cv_func_posix_getpwuid_r=no])])
2198         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2199         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2200                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2201                         [Have POSIX function getpwuid_r])
2202         else
2203                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2204                         ac_cv_func_nonposix_getpwuid_r,
2205                         [AC_TRY_LINK([#include <pwd.h>],
2206                                 [char buffer[10000];
2207                                 struct passwd pwd;
2208                                 getpwuid_r (0, &pwd, buffer,
2209                                                 sizeof (buffer));],
2210                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2211                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2212                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2213                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2214                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2215                                 [Have non-POSIX function getpwuid_r])
2216                 fi
2217         fi
2218 fi
2219 if test "$ac_cv_header_grp_h" = "yes"; then
2220         AC_CACHE_CHECK([for posix getgrgid_r],
2221                 ac_cv_func_posix_getgrgid_r,
2222                 [AC_TRY_RUN([
2223 #include <errno.h>
2224 #include <grp.h>
2225 int main () {
2226     char buffer[10000];
2227     struct group grp, *grpptr = &grp;
2228     int error;
2229     errno = 0;
2230     error = getgrgid_r (0, &grp, buffer,
2231                         sizeof (buffer), &grpptr);
2232    return (error < 0 && errno == ENOSYS)
2233            || error == ENOSYS;
2234 }                              ],
2235                        [ac_cv_func_posix_getgrgid_r=yes],
2236                        [ac_cv_func_posix_getgrgid_r=no])])
2237         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2238         if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2239                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2240                         [Have POSIX function getgrgid_r])
2241         else
2242                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2243                         ac_cv_func_nonposix_getgrgid_r,
2244                         [AC_TRY_LINK([#include <grp.h>],
2245                                 [char buffer[10000];
2246                                 struct group grp;
2247                                 getgrgid_r (0, &grp, buffer,
2248                                 sizeof (buffer));],
2249                         [ac_cv_func_nonposix_getgrgid_r=yes],
2250                         [ac_cv_func_nonposix_getgrgid_r=no])])
2251                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2252                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2253                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2254                                 [Have non-POSIX function getgrgid_r])
2255                 fi
2256         fi
2257 fi
2258 LIBS="$G_THREAD_LIBS $LIBS"
2259 if test x"$have_threads" = xposix; then
2260         glib_save_CPPFLAGS="$CPPFLAGS"
2261         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2262         # This is not AC_CHECK_FUNC to also work with function
2263         # name mangling in header files.
2264         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2265         AC_LINK_IFELSE(
2266             [AC_LANG_PROGRAM(
2267                 [#include <pthread.h>],
2268                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2269             [AC_MSG_RESULT(yes)
2270              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2271                 [Have function pthread_attr_setstacksize])],
2272             [AC_MSG_RESULT(no)])
2273         AC_MSG_CHECKING(for pthread_condattr_setclock)
2274         AC_LINK_IFELSE(
2275             [AC_LANG_PROGRAM(
2276                 [#include <pthread.h>],
2277                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2278             [AC_MSG_RESULT(yes)
2279              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2280                 [Have function pthread_condattr_setclock])],
2281             [AC_MSG_RESULT(no)])
2282         CPPFLAGS="$glib_save_CPPFLAGS"
2283 fi
2284
2285 LIBS="$glib_save_LIBS"
2286
2287 # now spit out all the warnings.
2288 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2289    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2290         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2291 fi
2292 if test "$ac_cv_func_localtime_r" != "yes"; then
2293         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2294 fi
2295
2296 #
2297 # Hack to deal with:
2298 #
2299 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2300 #     building shared libraries with linux.
2301 #  b) FreeBSD doesn't do this either.
2302 #
2303 case $host in
2304   *-*-freebsd*|*-*-linux*)
2305     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2306     ;;
2307   *-*-openbsd*)
2308     LDFLAGS="$LDFLAGS -pthread"
2309     ;;
2310   *)
2311     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2312     ;;
2313 esac
2314
2315 AC_SUBST(G_THREAD_CFLAGS)
2316 AC_SUBST(G_THREAD_LIBS)
2317 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2318 AC_SUBST(G_THREAD_LIBS_EXTRA)
2319
2320 AC_CHECK_FUNCS(clock_gettime, [], [
2321   AC_CHECK_LIB(rt, clock_gettime, [
2322     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2323     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2324     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2325   ])
2326 ])
2327
2328
2329 dnl ************************
2330 dnl *** g_atomic_* tests ***
2331 dnl ************************
2332
2333 dnl We need to decide at configure time if GLib will use real atomic
2334 dnl operations ("lock free") or emulated ones with a mutex.  This is
2335 dnl because we must put this information in glibconfig.h so we know if
2336 dnl it is safe or not to inline using compiler intrinsics directly from
2337 dnl the header.
2338 dnl
2339 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2340 dnl user is interested in knowing if they can use the atomic ops across
2341 dnl processes.
2342 dnl
2343 dnl We can currently support the atomic ops natively when building GLib
2344 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2345 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2346 dnl we are using GCC.
2347 dnl
2348 dnl Note that the atomic ops are only available with GCC on x86 when
2349 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2350 dnl not available but would be available given the right flags, we want
2351 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2352 dnl that then to silently fall back on emulated atomic ops just because
2353 dnl the user had the wrong build environment.
2354
2355 dnl We may add other compilers here in the future...
2356
2357 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2358   AC_TRY_COMPILE([],
2359                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2360                  [glib_cv_g_atomic_lock_free=yes],
2361                  [glib_cv_g_atomic_lock_free=no])])
2362
2363 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2364   SAVE_CFLAGS="${CFLAGS}"
2365   CFLAGS="-march=i486"
2366   AC_TRY_COMPILE([],
2367                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2368                  [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2369                  [])
2370   CFLAGS="${SAVE_CFLAGS}"
2371 fi
2372
2373 dnl We need a more robust approach here...
2374 case $host_cpu in
2375   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2376     glib_memory_barrier_needed=no
2377     ;;
2378   sparc*|alpha*|powerpc*|ia64)
2379     glib_memory_barrier_needed=yes
2380     ;;
2381   *)
2382     glib_memory_barrier_needed=yes
2383     ;;
2384 esac
2385
2386 dnl ************************
2387 dnl ** Check for futex(2) **
2388 dnl ************************
2389 AC_CACHE_CHECK(for futex(2) system call,
2390     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2391 #include <linux/futex.h>
2392 #include <sys/syscall.h>
2393 #include <unistd.h>
2394 ],[
2395 int
2396 main (void)
2397 {
2398   /* it is not like this actually runs or anything... */
2399   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2400   return 0;
2401 }
2402 ])],glib_cv_futex=yes,glib_cv_futex=no))
2403 if test x"$glib_cv_futex" = xyes; then
2404   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2405 fi
2406
2407 AC_CACHE_CHECK(for eventfd(2) system call,
2408     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2409 #include <sys/eventfd.h>
2410 #include <unistd.h>
2411 ],[
2412 int
2413 main (void)
2414 {
2415   eventfd (0, EFD_CLOEXEC);
2416   return 0;
2417 }
2418 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2419 if test x"$glib_cv_eventfd" = x"yes"; then
2420   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2421 fi
2422 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2423
2424 dnl ****************************************
2425 dnl *** GLib POLL* compatibility defines ***
2426 dnl ****************************************
2427
2428 glib_poll_includes=["
2429 #include <sys/types.h>
2430 #include <sys/poll.h>
2431 "]
2432
2433 if test $ac_cv_header_sys_types_h = yes &&
2434    test $ac_cv_header_sys_poll_h = yes ; then
2435   glib_failed=false
2436   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2437   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2438   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2439   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2440   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2441   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2442   if $glib_failed ; then
2443     AC_MSG_ERROR([Could not determine values for POLL* constants])
2444   fi
2445 else
2446   glib_cv_value_POLLIN=1
2447   glib_cv_value_POLLOUT=4
2448   glib_cv_value_POLLPRI=2
2449   glib_cv_value_POLLERR=8
2450   glib_cv_value_POLLHUP=16
2451   glib_cv_value_POLLNVAL=32
2452 fi
2453
2454 AC_MSG_CHECKING([for broken poll])
2455 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2456         #include <stdlib.h>
2457         #include <fcntl.h>
2458         #include <poll.h>
2459         #ifdef HAVE_SYS_POLL_H
2460         #include <sys/poll.h>
2461         #endif
2462         int main(void) {
2463           struct pollfd fds[1];
2464           int fd;
2465           fd = open("/dev/null", 1);
2466           fds[0].fd = fd;
2467           fds[0].events = POLLIN;
2468           fds[0].revents = 0;
2469           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2470                 exit(1);  /* Does not work for devices -- fail */
2471           }
2472           exit(0);
2473         }]])],
2474   [broken_poll=no],
2475   [broken_poll=yes
2476    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2477   [broken_poll="no (cross compiling)"])
2478 AC_MSG_RESULT($broken_poll)
2479
2480 dnl *********************
2481 dnl *** GRegex checks ***
2482 dnl *********************
2483
2484 PCRE_REQUIRED_VERSION=8.11
2485
2486 # Check if we should use the internal or the system-supplied pcre
2487 AC_ARG_WITH(pcre,
2488             [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2489                             [whether to use system PCRE [default=internal]])])
2490
2491 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2492
2493 if test "x$with_pcre" = xsystem; then
2494   PKG_CHECK_MODULES(PCRE,
2495                     libpcre >= $PCRE_REQUIRED_VERSION)
2496   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2497                   glib_save_CFLAGS="$CFLAGS"
2498                   glib_save_LIBS="$LIBS"
2499                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2500                   AC_TRY_RUN([#include <pcre.h>
2501                               int main () {
2502                                 int support;
2503                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2504                                 if (!support)
2505                                   return 1;
2506                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2507                                 if (!support)
2508                                   return 1;
2509                                 return 0;
2510                               }],
2511                   glib_cv_pcre_has_unicode=yes,
2512                   glib_cv_pcre_has_unicode=no,
2513                   glib_cv_pcre_has_unicode=yes)
2514                   CFLAGS="$glib_save_CFLAGS"
2515                   LIBS="$glib_save_LIBS"
2516       ])
2517   if test "$glib_cv_pcre_has_unicode" = "no"; then
2518     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2519   fi
2520   AC_SUBST(PCRE_CFLAGS)
2521   AC_SUBST(PCRE_LIBS)
2522   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2523   PCRE_REQUIRES=libpcre
2524   AC_SUBST(PCRE_REQUIRES)
2525 else
2526   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2527   if test x"$GCC" = xyes; then
2528     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2529     save_CFLAGS="$CFLAGS"
2530     CFLAGS="$CFLAGS -Wno-pointer-sign"
2531     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2532                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2533     CFLAGS="$save_CFLAGS"
2534   fi
2535 fi
2536 AC_SUBST(PCRE_WARN_CFLAGS)
2537
2538 dnl **********************
2539 dnl *** Win32 API libs ***
2540 dnl **********************
2541
2542 case $host in
2543   *-*-cygwin*)
2544         G_LIBS_EXTRA="-luser32 -lkernel32"
2545     ;;
2546   *-*-mingw*)
2547         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2548     ;;
2549   *)
2550         G_LIBS_EXTRA=""
2551     ;;
2552 esac
2553 AC_SUBST(G_LIBS_EXTRA)
2554
2555 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2556 dnl since we need it for g_iconv()
2557
2558 AC_MSG_CHECKING([for EILSEQ])
2559 AC_TRY_COMPILE([
2560 #include <errno.h>
2561 ],
2562 [
2563 int error = EILSEQ;
2564 ], have_eilseq=yes, have_eilseq=no);
2565 AC_MSG_RESULT($have_eilseq)
2566
2567 dnl ******************************************************************
2568 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2569 dnl *** glib-compile-schemas in PATH                               ***
2570 dnl ******************************************************************
2571
2572 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2573
2574 if test $cross_compiling = yes && test x$enable_modular_tests = xyes; then
2575   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2576   if test x$GLIB_GENMARSHAL = xno; then
2577     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2578   fi
2579
2580   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2581   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2582     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2583   fi
2584
2585   AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources, no)
2586   if test x$GLIB_COMPILE_RESOURCES = xno; then
2587     AC_MSG_ERROR(Could not find a glib-compile-resources in your PATH)
2588   fi
2589 fi
2590
2591 dnl **************************
2592 dnl *** Checks for gtk-doc ***
2593 dnl **************************
2594
2595 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2596
2597 AC_ARG_ENABLE(man,
2598               [AC_HELP_STRING([--enable-man],
2599                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2600               enable_man=no)
2601
2602 if test "${enable_man}" != no; then
2603 dnl
2604 dnl Check for xsltproc
2605 dnl
2606 AC_PATH_PROG([XSLTPROC], [xsltproc])
2607   if test -z "$XSLTPROC"; then
2608     enable_man=no
2609   fi
2610
2611   dnl check for DocBook DTD and stylesheets in the local catalog.
2612   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2613      [DocBook XML DTD V4.1.2],,enable_man=no)
2614   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2615      [DocBook XSL Stylesheets],,enable_man=no)
2616 fi
2617
2618 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2619
2620 dnl
2621 dnl Tracing
2622 dnl
2623
2624 AC_ARG_ENABLE([dtrace],
2625              [AS_HELP_STRING([--enable-dtrace],
2626                               [include tracing support for dtrace])])
2627 have_dtrace=no
2628 AC_MSG_CHECKING([whether to include dtrace tracing support])
2629 if test "x$enable_dtrace" != xno; then
2630   if test x$glib_have_carbon = xyes; then
2631     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2632   else
2633     AC_MSG_RESULT([yes])
2634     AC_CHECK_PROGS(DTRACE, dtrace)
2635     if test -z "$DTRACE"; then
2636       if test "x$enable_dtrace" = xyes; then
2637         AC_MSG_ERROR([dtrace not found])
2638       fi
2639     else
2640       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2641                       [if test "x$enable_dtrace" = xyes; then
2642                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2643                        fi])
2644     fi
2645   fi
2646 else
2647   AC_MSG_RESULT([no])
2648 fi
2649 if test "x$have_dtrace" = xyes; then
2650   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2651 fi
2652 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2653
2654 AC_MSG_CHECKING([whether to include systemtap tracing support])
2655 AC_ARG_ENABLE([systemtap],
2656              [AS_HELP_STRING([--enable-systemtap],
2657                               [include tracing support for systemtap])])
2658 have_systemtap=no
2659 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2660   have_systemtap=yes
2661 fi
2662 AC_MSG_RESULT(${have_systemtap})
2663
2664 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2665
2666 AC_ARG_WITH([tapset-install-dir],
2667             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2668                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2669             [if test "x${withval}" = x; then
2670                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2671              else
2672                ABS_TAPSET_DIR="${withval}"
2673               fi],
2674             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2675 AC_SUBST(ABS_TAPSET_DIR)
2676
2677 dnl ************************************
2678 dnl *** Enable lcov coverage reports ***
2679 dnl ************************************
2680
2681 AC_ARG_ENABLE(gcov,
2682   AS_HELP_STRING([--enable-gcov],
2683                  [enable coverage testing with gcov]),
2684   [use_gcov=$enableval], [use_gcov=no])
2685
2686 if test "x$use_gcov" = "xyes"; then
2687   dnl we need gcc:
2688   if test "$GCC" != "yes"; then
2689     AC_MSG_ERROR([GCC is required for --enable-gcov])
2690   fi
2691
2692   dnl Check if ccache is being used
2693   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2694   case `$SHTOOL path $CC` in
2695     *ccache*[)] gcc_ccache=yes;;
2696     *[)] gcc_ccache=no;;
2697   esac
2698
2699   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2700     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2701   fi
2702
2703   ltp_version_list="1.6 1.7 1.8 1.9"
2704   AC_CHECK_PROG(LTP, lcov, lcov)
2705   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2706
2707   if test "$LTP"; then
2708     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2709       glib_cv_ltp_version=invalid
2710       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2711       for ltp_check_version in $ltp_version_list; do
2712         if test "$ltp_version" = "$ltp_check_version"; then
2713           glib_cv_ltp_version="$ltp_check_version (ok)"
2714         fi
2715       done
2716     ])
2717   else
2718     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2719     AC_MSG_ERROR([$ltp_msg])
2720   fi
2721
2722   case $glib_cv_ltp_version in
2723     ""|invalid[)]
2724       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2725       AC_MSG_ERROR([$ltp_msg])
2726       LTP="exit 0;"
2727       ;;
2728   esac
2729
2730   if test -z "$LTP_GENHTML"; then
2731     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2732   fi
2733
2734   dnl Remove all optimization flags from CFLAGS
2735   changequote({,})
2736   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2737   changequote([,])
2738
2739   dnl Add the special gcc flags
2740   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2741   LDFLAGS="$LDFLAGS -lgcov"
2742 fi
2743
2744 dnl ******************************
2745 dnl *** output the whole stuff ***
2746 dnl ******************************
2747
2748 dnl this section will only be run if config.status is invoked with no
2749 dnl arguments, or with "glib/glibconfig.h" as an argument.
2750 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2751 [
2752         outfile=glib/glibconfig.h-tmp
2753         cat > $outfile <<\_______EOF
2754 /* glibconfig.h
2755  *
2756  * This is a generated file.  Please modify 'configure.ac'
2757  */
2758
2759 #ifndef __GLIBCONFIG_H__
2760 #define __GLIBCONFIG_H__
2761
2762 #include <glib/gmacros.h>
2763
2764 _______EOF
2765
2766         if test x$glib_limits_h = xyes; then
2767           echo '#include <limits.h>' >> $outfile
2768         fi
2769         if test x$glib_float_h = xyes; then
2770           echo '#include <float.h>' >> $outfile
2771         fi
2772         if test x$glib_values_h = xyes; then
2773           echo '#include <values.h>' >> $outfile
2774         fi
2775         if test "$glib_header_alloca_h" = "yes"; then
2776           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2777         fi
2778         if test x$glib_sys_poll_h = xyes; then
2779           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2780         fi
2781         if test x$glib_included_printf != xyes; then
2782           echo "
2783 /* Specifies that GLib's g_print*() functions wrap the
2784  * system printf functions.  This is useful to know, for example,
2785  * when using glibc's register_printf_function().
2786  */" >> $outfile
2787           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2788         fi
2789
2790         cat >> $outfile <<_______EOF
2791
2792 G_BEGIN_DECLS
2793
2794 #define G_MINFLOAT      $glib_mf
2795 #define G_MAXFLOAT      $glib_Mf
2796 #define G_MINDOUBLE     $glib_md
2797 #define G_MAXDOUBLE     $glib_Md
2798 #define G_MINSHORT      $glib_ms
2799 #define G_MAXSHORT      $glib_Ms
2800 #define G_MAXUSHORT     $glib_Mus
2801 #define G_MININT        $glib_mi
2802 #define G_MAXINT        $glib_Mi
2803 #define G_MAXUINT       $glib_Mui
2804 #define G_MINLONG       $glib_ml
2805 #define G_MAXLONG       $glib_Ml
2806 #define G_MAXULONG      $glib_Mul
2807
2808 _______EOF
2809
2810
2811         ### this should always be true in a modern C/C++ compiler
2812         cat >>$outfile <<_______EOF
2813 typedef signed char gint8;
2814 typedef unsigned char guint8;
2815 _______EOF
2816
2817
2818         if test -n "$gint16"; then
2819           cat >>$outfile <<_______EOF
2820 typedef signed $gint16 gint16;
2821 typedef unsigned $gint16 guint16;
2822 #define G_GINT16_MODIFIER $gint16_modifier
2823 #define G_GINT16_FORMAT $gint16_format
2824 #define G_GUINT16_FORMAT $guint16_format
2825 _______EOF
2826         fi
2827
2828
2829         if test -n "$gint32"; then
2830           cat >>$outfile <<_______EOF
2831 typedef signed $gint32 gint32;
2832 typedef unsigned $gint32 guint32;
2833 #define G_GINT32_MODIFIER $gint32_modifier
2834 #define G_GINT32_FORMAT $gint32_format
2835 #define G_GUINT32_FORMAT $guint32_format
2836 _______EOF
2837         fi
2838
2839         cat >>$outfile <<_______EOF
2840 #define G_HAVE_GINT64 1          /* deprecated, always true */
2841
2842 ${glib_extension}typedef signed $gint64 gint64;
2843 ${glib_extension}typedef unsigned $gint64 guint64;
2844
2845 #define G_GINT64_CONSTANT(val)  $gint64_constant
2846 #define G_GUINT64_CONSTANT(val) $guint64_constant
2847 _______EOF
2848
2849         if test x$gint64_format != x ; then
2850           cat >>$outfile <<_______EOF
2851 #define G_GINT64_MODIFIER $gint64_modifier
2852 #define G_GINT64_FORMAT $gint64_format
2853 #define G_GUINT64_FORMAT $guint64_format
2854 _______EOF
2855         else
2856           cat >>$outfile <<_______EOF
2857 #undef G_GINT64_MODIFIER
2858 #undef G_GINT64_FORMAT
2859 #undef G_GUINT64_FORMAT
2860 _______EOF
2861         fi
2862
2863         cat >>$outfile <<_______EOF
2864
2865 #define GLIB_SIZEOF_VOID_P $glib_void_p
2866 #define GLIB_SIZEOF_LONG   $glib_long
2867 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2868
2869 _______EOF
2870
2871         cat >>$outfile <<_______EOF
2872 typedef signed $glib_size_type_define gssize;
2873 typedef unsigned $glib_size_type_define gsize;
2874 #define G_GSIZE_MODIFIER $gsize_modifier
2875 #define G_GSSIZE_FORMAT $gssize_format
2876 #define G_GSIZE_FORMAT $gsize_format
2877
2878 #define G_MAXSIZE       G_MAXU$glib_msize_type
2879 #define G_MINSSIZE      G_MIN$glib_msize_type
2880 #define G_MAXSSIZE      G_MAX$glib_msize_type
2881
2882 typedef gint64 goffset;
2883 #define G_MINOFFSET     G_MININT64
2884 #define G_MAXOFFSET     G_MAXINT64
2885
2886 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2887 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2888 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2889
2890 _______EOF
2891
2892         if test -z "$glib_unknown_void_p"; then
2893           cat >>$outfile <<_______EOF
2894
2895 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2896 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2897
2898 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2899 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2900
2901 typedef signed $glib_intptr_type_define gintptr;
2902 typedef unsigned $glib_intptr_type_define guintptr;
2903
2904 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2905 #define G_GINTPTR_FORMAT        $gintptr_format
2906 #define G_GUINTPTR_FORMAT       $guintptr_format
2907 _______EOF
2908         else
2909           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2910         fi
2911
2912
2913
2914         cat >>$outfile <<_______EOF
2915 $glib_atexit
2916 $glib_memmove
2917 $glib_defines
2918 $glib_os
2919 $glib_static_compilation
2920
2921 $glib_vacopy
2922
2923 #ifdef  __cplusplus
2924 #define G_HAVE_INLINE   1
2925 #else   /* !__cplusplus */
2926 $glib_inline
2927 #endif  /* !__cplusplus */
2928
2929 #ifdef  __cplusplus
2930 #define G_CAN_INLINE    1
2931 _______EOF
2932
2933         if test x$g_can_inline = xyes ; then
2934                 cat >>$outfile <<_______EOF
2935 #else   /* !__cplusplus */
2936 #define G_CAN_INLINE    1
2937 _______EOF
2938         fi
2939
2940         cat >>$outfile <<_______EOF
2941 #endif
2942
2943 _______EOF
2944
2945         if test x$g_have_iso_c_varargs = xyes ; then
2946                 cat >>$outfile <<_______EOF
2947 #ifndef __cplusplus
2948 # define G_HAVE_ISO_VARARGS 1
2949 #endif
2950 _______EOF
2951         fi
2952         if test x$g_have_iso_cxx_varargs = xyes ; then
2953                 cat >>$outfile <<_______EOF
2954 #ifdef __cplusplus
2955 # define G_HAVE_ISO_VARARGS 1
2956 #endif
2957 _______EOF
2958         fi
2959         if test x$g_have_gnuc_varargs = xyes ; then
2960                 cat >>$outfile <<_______EOF
2961
2962 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2963  * is passed ISO vararg support is turned off, and there is no work
2964  * around to turn it on, so we unconditionally turn it off.
2965  */
2966 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2967 #  undef G_HAVE_ISO_VARARGS
2968 #endif
2969
2970 #define G_HAVE_GNUC_VARARGS 1
2971 _______EOF
2972         fi
2973
2974         case x$g_stack_grows in
2975         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2976         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2977         esac
2978
2979
2980         echo >>$outfile
2981         if test x$g_have_eilseq = xno; then
2982                 cat >>$outfile <<_______EOF
2983 #ifndef EILSEQ
2984 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
2985  * The correspondence between this and the corresponding definition
2986  * in libiconv is essential.
2987  */
2988 #  define EILSEQ ENOENT
2989 #endif
2990 _______EOF
2991
2992         fi
2993
2994         if test x$g_have_gnuc_visibility = xyes; then
2995                 cat >>$outfile <<_______EOF
2996 #define G_HAVE_GNUC_VISIBILITY 1
2997 _______EOF
2998         fi
2999                 cat >>$outfile <<_______EOF
3000 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3001 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3002 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3003 #define G_GNUC_INTERNAL __hidden
3004 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3005 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3006 #else
3007 #define G_GNUC_INTERNAL
3008 #endif
3009 _______EOF
3010
3011         echo >>$outfile
3012         cat >>$outfile <<_______EOF
3013 #define G_THREADS_ENABLED
3014 #define G_THREADS_IMPL_$g_threads_impl_def
3015 _______EOF
3016
3017         if test x"$g_memory_barrier_needed" != xno; then
3018           echo >>$outfile
3019           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3020         fi
3021         if test x"$g_atomic_lock_free" = xyes; then
3022           echo >>$outfile
3023           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3024         fi
3025         echo >>$outfile
3026         g_bit_sizes="16 32 64"
3027         for bits in $g_bit_sizes; do
3028           cat >>$outfile <<_______EOF
3029 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3030 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3031 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3032 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3033 _______EOF
3034         done
3035
3036         cat >>$outfile <<_______EOF
3037 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3038 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3039 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3040 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3041 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3042 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3043 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3044 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3045 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3046 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3047 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3048 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3049 #define G_BYTE_ORDER $g_byte_order
3050
3051 #define GLIB_SYSDEF_POLLIN =$g_pollin
3052 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3053 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3054 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3055 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3056 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3057
3058 #define G_MODULE_SUFFIX "$g_module_suffix"
3059
3060 typedef $g_pid_type GPid;
3061
3062 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3063 #define GLIB_SYSDEF_AF_INET $g_af_inet
3064 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3065
3066 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3067 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3068 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3069
3070 G_END_DECLS
3071
3072 #endif /* __GLIBCONFIG_H__ */
3073 _______EOF
3074
3075
3076         if cmp -s $outfile glib/glibconfig.h; then
3077           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3078           rm -f $outfile
3079         else
3080           mv $outfile glib/glibconfig.h
3081         fi
3082 ],[
3083
3084 # Note that if two cases are the same, case goes with the first one.
3085 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3086 # on variable expansion in case labels.  Look at the generated config.status
3087 # for a hint.
3088
3089 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3090   glib_header_alloca_h="$ac_cv_working_alloca_h"
3091 else
3092   glib_header_alloca_h="$ac_cv_header_alloca_h"
3093 fi
3094
3095 case xyes in
3096 x$ac_cv_header_float_h)
3097   glib_float_h=yes
3098   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3099   glib_md=DBL_MIN glib_Md=DBL_MAX
3100   ;;
3101 x$ac_cv_header_values_h)
3102   glib_values_h=yes
3103   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3104   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3105   ;;
3106 esac
3107
3108 case xyes in
3109 x$ac_cv_header_limits_h)
3110   glib_limits_h=yes
3111   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3112   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3113   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3114   ;;
3115 x$ac_cv_header_values_h)
3116   glib_values_h=yes
3117   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3118   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3119   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3120   ;;
3121 esac
3122
3123 if test x$ac_cv_header_sys_poll_h = xyes ; then
3124   glib_sys_poll_h=yes
3125 fi
3126
3127 if test x$enable_included_printf = xyes ; then
3128   glib_included_printf=yes
3129 fi
3130
3131 case 2 in
3132 $ac_cv_sizeof_short)
3133   gint16=short
3134   gint16_modifier='"h"'
3135   gint16_format='"hi"'
3136   guint16_format='"hu"'
3137   ;;
3138 $ac_cv_sizeof_int)
3139   gint16=int
3140   gint16_modifier='""'
3141   gint16_format='"i"'
3142   guint16_format='"u"'
3143   ;;
3144 esac
3145 case 4 in
3146 $ac_cv_sizeof_short)
3147   gint32=short
3148   gint32_modifier='"h"'
3149   gint32_format='"hi"'
3150   guint32_format='"hu"'
3151   ;;
3152 $ac_cv_sizeof_int)
3153   gint32=int
3154   gint32_modifier='""'
3155   gint32_format='"i"'
3156   guint32_format='"u"'
3157   ;;
3158 $ac_cv_sizeof_long)
3159   gint32=long
3160   gint32_modifier='"l"'
3161   gint32_format='"li"'
3162   guint32_format='"lu"'
3163   ;;
3164 esac
3165 case 8 in
3166 $ac_cv_sizeof_int)
3167   gint64=int
3168   gint64_modifier='""'
3169   gint64_format='"i"'
3170   guint64_format='"u"'
3171   glib_extension=
3172   gint64_constant='(val)'
3173   guint64_constant='(val)'
3174   ;;
3175 $ac_cv_sizeof_long)
3176   gint64=long
3177   gint64_modifier='"l"'
3178   gint64_format='"li"'
3179   guint64_format='"lu"'
3180   glib_extension=
3181   gint64_constant='(val##L)'
3182   guint64_constant='(val##UL)'
3183   ;;
3184 $ac_cv_sizeof_long_long)
3185   gint64='long long'
3186   if test -n "$glib_cv_long_long_format"; then
3187     gint64_modifier='"'$glib_cv_long_long_format'"'
3188     gint64_format='"'$glib_cv_long_long_format'i"'
3189     guint64_format='"'$glib_cv_long_long_format'u"'
3190   fi
3191   glib_extension='G_GNUC_EXTENSION '
3192   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3193   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3194   ;;
3195 $ac_cv_sizeof___int64)
3196   gint64='__int64'
3197   if test -n "$glib_cv_long_long_format"; then
3198     gint64_modifier='"'$glib_cv_long_long_format'"'
3199     gint64_format='"'$glib_cv_long_long_format'i"'
3200     guint64_format='"'$glib_cv_long_long_format'u"'
3201   fi
3202   glib_extension=
3203   gint64_constant='(val##i64)'
3204   guint64_constant='(val##ui64)'
3205   ;;
3206 esac
3207 glib_size_t=$ac_cv_sizeof_size_t
3208 glib_size_type_define="$glib_size_type"
3209 glib_void_p=$ac_cv_sizeof_void_p
3210 glib_long=$ac_cv_sizeof_long
3211
3212 case "$glib_size_type" in
3213 short)
3214   gsize_modifier='"h"'
3215   gsize_format='"hu"'
3216   gssize_format='"hi"'
3217   glib_msize_type='SHRT'
3218   ;;
3219 int)
3220   gsize_modifier='""'
3221   gsize_format='"u"'
3222   gssize_format='"i"'
3223   glib_msize_type='INT'
3224   ;;
3225 long)
3226   gsize_modifier='"l"'
3227   gsize_format='"lu"'
3228   gssize_format='"li"'
3229   glib_msize_type='LONG'
3230   ;;
3231 "long long"|__int64)
3232   gsize_modifier='"I64"'
3233   gsize_format='"I64u"'
3234   gssize_format='"I64i"'
3235   glib_msize_type='INT64'
3236   ;;
3237 esac
3238
3239 gintbits=`expr $ac_cv_sizeof_int \* 8`
3240 glongbits=`expr $ac_cv_sizeof_long \* 8`
3241 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3242
3243 case $ac_cv_sizeof_void_p in
3244 $ac_cv_sizeof_int)
3245   glib_intptr_type_define=int
3246   gintptr_modifier='""'
3247   gintptr_format='"i"'
3248   guintptr_format='"u"'
3249   glib_gpi_cast='(gint)'
3250   glib_gpui_cast='(guint)'
3251   ;;
3252 $ac_cv_sizeof_long)
3253   glib_intptr_type_define=long
3254   gintptr_modifier='"l"'
3255   gintptr_format='"li"'
3256   guintptr_format='"lu"'
3257   glib_gpi_cast='(glong)'
3258   glib_gpui_cast='(gulong)'
3259   ;;
3260 $ac_cv_sizeof_long_long)
3261   glib_intptr_type_define='long long'
3262   gintptr_modifier='"I64"'
3263   gintptr_format='"I64i"'
3264   guintptr_format='"I64u"'
3265   glib_gpi_cast='(gint64)'
3266   glib_gpui_cast='(guint64)'
3267   ;;
3268 $ac_cv_sizeof___int64)
3269   glib_intptr_type_define=__int64
3270   gintptr_modifier='"I64"'
3271   gintptr_format='"I64i"'
3272   guintptr_format='"I64u"'
3273   glib_gpi_cast='(gint64)'
3274   glib_gpui_cast='(guint64)'
3275   ;;
3276 *)
3277   glib_unknown_void_p=yes
3278   ;;
3279 esac
3280
3281
3282 case xyes in
3283 x$ac_cv_func_atexit)
3284   glib_atexit="
3285 #ifdef NeXT /* @#%@! NeXTStep */
3286 # define g_ATEXIT(proc) (!atexit (proc))
3287 #else
3288 # define g_ATEXIT(proc) (atexit (proc))
3289 #endif"
3290   ;;
3291 x$ac_cv_func_on_exit)
3292   glib_atexit="
3293 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3294   ;;
3295 esac
3296
3297 case xyes in
3298 x$ac_cv_func_memmove)
3299   glib_memmove='
3300 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3301   ;;
3302 x$glib_cv_working_bcopy)
3303   glib_memmove="
3304 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3305 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3306   ;;
3307 *)
3308   glib_memmove="
3309 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3310  * so we have to roll our own copy routine. */
3311 void g_memmove (void* dest, const void * src, unsigned long len);"
3312   ;;
3313 esac
3314
3315 glib_defines="
3316 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3317 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3318 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3319 "
3320
3321 case xyes in
3322 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3323 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3324 *)                      glib_vacopy=''
3325 esac
3326
3327 if test x$glib_cv_va_val_copy = xno; then
3328   glib_vacopy="\$glib_vacopy
3329 #define G_VA_COPY_AS_ARRAY 1"
3330 fi
3331
3332 if test x$glib_cv_hasinline = xyes; then
3333     glib_inline='#define G_HAVE_INLINE 1'
3334 fi
3335 if test x$glib_cv_has__inline = xyes; then
3336     glib_inline="\$glib_inline
3337 #define G_HAVE___INLINE 1"
3338 fi
3339 if test x$glib_cv_has__inline__ = xyes; then
3340     glib_inline="\$glib_inline
3341 #define G_HAVE___INLINE__ 1"
3342 fi
3343
3344 g_have_gnuc_varargs=$g_have_gnuc_varargs
3345 g_have_iso_c_varargs=$g_have_iso_c_varargs
3346 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3347
3348 g_can_inline=$g_can_inline
3349 g_have_gnuc_visibility=$g_have_gnuc_visibility
3350 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3351
3352 if test x$ac_cv_c_bigendian = xyes; then
3353   g_byte_order=G_BIG_ENDIAN
3354   g_bs_native=BE
3355   g_bs_alien=LE
3356 else
3357   g_byte_order=G_LITTLE_ENDIAN
3358   g_bs_native=LE
3359   g_bs_alien=BE
3360 fi
3361
3362 g_pollin=$glib_cv_value_POLLIN
3363 g_pollout=$glib_cv_value_POLLOUT
3364 g_pollpri=$glib_cv_value_POLLPRI
3365 g_pollhup=$glib_cv_value_POLLHUP
3366 g_pollerr=$glib_cv_value_POLLERR
3367 g_pollnval=$glib_cv_value_POLLNVAL
3368
3369 # If a family is not found on the system, define that family to
3370 # a negative value, picking a different one for each undefined
3371 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3372 # This is needed because glib-mkenums doesn't handle optional
3373 # values in enums, and thus we have to have all existing values
3374 # defined in the enum.
3375 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3376   g_af_unix=$glib_cv_value_AF_UNIX
3377 else
3378   g_af_unix=-1
3379 fi
3380 g_af_inet=$glib_cv_value_AF_INET
3381 g_af_inet6=$glib_cv_value_AF_INET6
3382
3383 g_msg_peek=$glib_cv_value_MSG_PEEK
3384 g_msg_oob=$glib_cv_value_MSG_OOB
3385 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3386
3387 g_stack_grows=$glib_cv_stack_grows
3388
3389 g_have_eilseq=$have_eilseq
3390
3391 g_threads_impl_def=$g_threads_impl
3392
3393 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3394 g_memory_barrier_needed="$glib_memory_barrier_needed"
3395 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3396
3397 g_module_suffix="$glib_gmodule_suffix"
3398
3399 g_pid_type="$glib_pid_type"
3400 case $host in
3401   *-*-beos*)
3402     glib_os="#define G_OS_BEOS"
3403     ;;
3404   *-*-cygwin*)
3405     glib_os="#define G_OS_UNIX
3406 #define G_PLATFORM_WIN32
3407 #define G_WITH_CYGWIN"
3408     ;;
3409   *-*-mingw*)
3410     glib_os="#define G_OS_WIN32
3411 #define G_PLATFORM_WIN32"
3412     ;;
3413   *)
3414     glib_os="#define G_OS_UNIX"
3415     ;;
3416 esac
3417 glib_static_compilation=""
3418 if test x$glib_win32_static_compilation = xyes; then
3419   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3420 #define GOBJECT_STATIC_COMPILATION 1"
3421 fi
3422 ])
3423
3424 # Redo enough to get guint32 and guint64 for the alignment checks below
3425 case 4 in
3426 $ac_cv_sizeof_short)
3427   gint32=short
3428   ;;
3429 $ac_cv_sizeof_int)
3430   gint32=int
3431   ;;
3432 $ac_cv_sizeof_long)
3433   gint32=long
3434   ;;
3435 esac
3436 case 8 in
3437 $ac_cv_sizeof_int)
3438   gint64=int
3439   ;;
3440 $ac_cv_sizeof_long)
3441   gint64=long
3442   ;;
3443 $ac_cv_sizeof_long_long)
3444   gint64='long long'
3445   ;;
3446 $ac_cv_sizeof___int64)
3447   gint64='__int64'
3448   ;;
3449 esac
3450
3451 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3452 typedef unsigned $gint32 guint32;])
3453 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3454 typedef unsigned $gint64 guint64;])
3455 AC_CHECK_ALIGNOF([unsigned long])
3456
3457 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3458 #
3459 # 1.2.14 required for dbus_message_set_serial
3460 if test x$enable_modular_tests = xyes; then
3461    PKG_CHECK_MODULES(DBUS1,
3462                      dbus-1 >= 1.2.14,
3463                      [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3464                      have_dbus1=no)
3465    AC_SUBST(DBUS1_CFLAGS)
3466    AC_SUBST(DBUS1_LIBS)
3467 fi
3468 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3469
3470 dnl
3471 dnl Check for -Bsymbolic-functions linker flag used to avoid
3472 dnl intra-library PLT jumps, if available.
3473 dnl
3474
3475 AC_ARG_ENABLE(Bsymbolic,
3476               [AC_HELP_STRING([--disable-Bsymbolic],
3477                               [avoid linking with -Bsymbolic])],,
3478               [SAVED_LDFLAGS="${LDFLAGS}"
3479                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3480                LDFLAGS=-Wl,-Bsymbolic-functions
3481                AC_TRY_LINK([], [int main (void) { return 0; }],
3482                            AC_MSG_RESULT(yes)
3483                            enable_Bsymbolic=yes,
3484                            AC_MSG_RESULT(no)
3485                            enable_Bsymbolic=no)
3486                LDFLAGS="${SAVED_LDFLAGS}"])
3487
3488 if test "x${enable_Bsymbolic}" = "xyes"; then
3489   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3490 fi
3491
3492 AC_SUBST(GLIB_LINK_FLAGS)
3493
3494 #
3495 # Define variables corresponding to the correct include paths to use for
3496 # in-tree building.
3497 #
3498
3499 # for config.h:
3500 config_h_INCLUDES='-I$(top_builddir)'
3501 AC_SUBST(config_h_INCLUDES)
3502
3503 # glib:
3504 #   config.h
3505 #   $(top_builddir)/glib: for glibconfig.h
3506 #   $(top_srcdir)/glib:   for glib.h
3507 #   $(top_srcdir):        for everything
3508 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3509 AC_SUBST(glib_INCLUDES)
3510
3511 # gthread:
3512 #   same as glib
3513 gthread_INCLUDES='$(glib_INCLUDES)'
3514 AC_SUBST(gthread_INCLUDES)
3515
3516 # gobject:
3517 #   same as gthread
3518 gobject_INCLUDES='$(gthread_INCLUDES)'
3519 AC_SUBST(gobject_INCLUDES)
3520
3521 # gmodule:
3522 #   glib includes
3523 #   $(top_srcdir)/gmodule: for gmodule.h
3524 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3525 AC_SUBST(gmodule_INCLUDES)
3526
3527 # gio:
3528 #   same as gmodule
3529 gio_INCLUDES='$(gmodule_INCLUDES)'
3530 AC_SUBST(gio_INCLUDES)
3531
3532
3533 AC_CONFIG_FILES([
3534 glib-2.0.pc
3535 gmodule-2.0.pc
3536 gmodule-export-2.0.pc
3537 gmodule-no-export-2.0.pc
3538 gthread-2.0.pc
3539 gobject-2.0.pc
3540 gio-2.0.pc
3541 gio-unix-2.0.pc
3542 gio-windows-2.0.pc
3543 glib-zip
3544 glib-gettextize
3545 Makefile
3546 build/Makefile
3547 build/win32/Makefile
3548 build/win32/dirent/Makefile
3549 build/win32/vs9/Makefile
3550 build/win32/vs10/Makefile
3551 glib/Makefile
3552 glib/glib.stp
3553 glib/libcharset/Makefile
3554 glib/gnulib/Makefile
3555 glib/pcre/Makefile
3556 glib/update-pcre/Makefile
3557 glib/tests/Makefile
3558 gmodule/Makefile
3559 gmodule/gmoduleconf.h
3560 gobject/Makefile
3561 gobject/gobject.stp
3562 gobject/glib-mkenums
3563 gobject/tests/Makefile
3564 gthread/Makefile
3565 gio/Makefile
3566 gio/gdbus-2.0/codegen/Makefile
3567 gio/gdbus-2.0/codegen/config.py
3568 gio/xdgmime/Makefile
3569 gio/inotify/Makefile
3570 gio/fen/Makefile
3571 gio/fam/Makefile
3572 gio/win32/Makefile
3573 gio/tests/Makefile
3574 gio/tests/gdbus-object-manager-example/Makefile
3575 po/Makefile.in
3576 docs/Makefile
3577 docs/reference/Makefile
3578 docs/reference/glib/Makefile
3579 docs/reference/glib/version.xml
3580 docs/reference/gobject/Makefile
3581 docs/reference/gobject/version.xml
3582 docs/reference/gio/Makefile
3583 docs/reference/gio/gdbus-object-manager-example/Makefile
3584 docs/reference/gio/version.xml
3585 tests/Makefile
3586 tests/gobject/Makefile
3587 tests/refcount/Makefile
3588 m4macros/Makefile
3589 ])
3590
3591 AC_CONFIG_COMMANDS([chmod-scripts],
3592 [chmod 0755 glib-zip
3593 chmod 0755 glib-gettextize
3594 chmod 0755 gobject/glib-mkenums])
3595
3596 # we want to invoke this macro solely so that the config.status script
3597 # and automake generated makefiles know about these generated files.
3598 # They are only needed to distcheck the package
3599 if false; then
3600   AC_CONFIG_FILES([
3601     INSTALL
3602     README
3603     config.h.win32
3604     glib/glibconfig.h.win32
3605     glib/makefile.msc
3606     glib/glib.rc
3607     gmodule/makefile.msc
3608     gmodule/gmodule.rc
3609     gobject/makefile.msc
3610     gobject/gobject.rc
3611     gthread/makefile.msc
3612     gthread/gthread.rc
3613     gio/gio.rc
3614     tests/makefile.msc
3615   ])
3616 fi
3617
3618 AC_OUTPUT