configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # in easier to understand terms:
  24 #
  25 # <mclasen> on the stable branch, interface age == micro
  26 # <mclasen> on the unstable (ie master), interface age = 0
  27
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [29])
  30 m4_define([glib_micro_version], [19])
  31 m4_define([glib_interface_age], [0])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_HEADER([config.h])
  56 AC_CONFIG_SRCDIR([glib/glib.h])
  57 AC_CONFIG_MACRO_DIR([m4macros])
  58
  59 # Save this value here, since automake will set cflags later
  60 cflags_set=${CFLAGS+set}
  61
  62 AM_INIT_AUTOMAKE([1.11 no-define no-dist-gzip dist-xz tar-ustar])
  63 AM_MAINTAINER_MODE([enable])
  64
  65 # Support silent build rules. Disable
  66 # by either passing --disable-silent-rules to configure or passing V=1
  67 # to make
  68 AM_SILENT_RULES([yes])
  69
  70 GLIB_MAJOR_VERSION=glib_major_version
  71 GLIB_MINOR_VERSION=glib_minor_version
  72 GLIB_MICRO_VERSION=glib_micro_version
  73 GLIB_INTERFACE_AGE=glib_interface_age
  74 GLIB_BINARY_AGE=glib_binary_age
  75 GLIB_VERSION=glib_version
  76
  77 AC_SUBST(GLIB_MAJOR_VERSION)
  78 AC_SUBST(GLIB_MINOR_VERSION)
  79 AC_SUBST(GLIB_MICRO_VERSION)
  80 AC_SUBST(GLIB_VERSION)
  81 AC_SUBST(GLIB_INTERFACE_AGE)
  82 AC_SUBST(GLIB_BINARY_AGE)
  83
  84 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  85           [Define to the GLIB major version])
  86 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  87           [Define to the GLIB minor version])
  88 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  89           [Define to the GLIB micro version])
  90 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  91           [Define to the GLIB interface age])
  92 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  93           [Define to the GLIB binary age])
  94
  95 # libtool versioning
  96 LT_RELEASE=glib_lt_release
  97 LT_CURRENT=glib_lt_current
  98 LT_REVISION=glib_lt_revision
  99 LT_AGE=glib_lt_age
 100 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 101 AC_SUBST(LT_RELEASE)
 102 AC_SUBST(LT_CURRENT)
 103 AC_SUBST(LT_REVISION)
 104 AC_SUBST(LT_AGE)
 105 AC_SUBST(LT_CURRENT_MINUS_AGE)
 106
 107 dnl Checks for programs.
 108 AC_PROG_CC
 109 AC_PROG_CPP
 110
 111 AC_CANONICAL_HOST
 112
 113 AC_MSG_CHECKING([for the BeOS])
 114 case $host in
 115   *-*-beos*)
 116     glib_native_beos="yes"
 117     ;;
 118   *)
 119     glib_native_beos="no"
 120     ;;
 121 esac
 122 AC_MSG_RESULT([$glib_native_beos])
 123
 124 dnl
 125
 126 AC_MSG_CHECKING([for Win32])
 127 LIB_EXE_MACHINE_FLAG=X86
 128 case "$host" in
 129   *-*-mingw*)
 130     glib_native_win32=yes
 131     glib_pid_type='void *'
 132     glib_cv_stack_grows=no
 133     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 134     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 135     # (Sorry, I don't know exactly what is the problem, but it is related to
 136     # floating point formatting and decimal point vs. comma.)
 137     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 138     # rigorous enough to notice, though.
 139     # So preset the autoconf cache variables.
 140     ac_cv_func_vsnprintf_c99=no
 141     ac_cv_func_snprintf_c99=no
 142     case "$host" in
 143     x86_64-*-*)
 144       LIB_EXE_MACHINE_FLAG=X64
 145       ;;
 146     esac
 147     ;;
 148   *)
 149     glib_native_win32=no
 150     glib_pid_type=int
 151     ;;
 152 esac
 153 case $host in
 154   *-*-linux*)
 155     glib_os_linux=yes
 156     ;;
 157 esac
 158
 159 AC_MSG_RESULT([$glib_native_win32])
 160
 161 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 162
 163 glib_have_carbon=no
 164 AC_MSG_CHECKING([for Mac OS X Carbon support])
 165 AC_TRY_CPP([
 166 #include <Carbon/Carbon.h>
 167 #include <CoreServices/CoreServices.h>
 168 ], glib_have_carbon=yes)
 169
 170 AC_MSG_RESULT([$glib_have_carbon])
 171
 172 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 173 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 174 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 175 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 176 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 177
 178 if test "$glib_native_win32" = "yes"; then
 179   AC_CHECK_TOOL(WINDRES, windres, no)
 180   if test "$WINDRES" = no; then
 181     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 182   fi
 183   AC_CHECK_TOOL(NM, nm, no)
 184   if test "$NM" = no; then
 185     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 186   fi
 187   AC_CHECK_TOOL(RANLIB, ranlib, :)
 188   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 189 fi
 190 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 191
 192 if test "$glib_native_win32" != yes; then
 193     # libtool option to control which symbols are exported
 194     # right now, symbols starting with _ are not exported
 195     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 196 else
 197     # We currently use .def files on Windows
 198     LIBTOOL_EXPORT_OPTIONS=
 199 fi
 200 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 201
 202 if test "x$glib_have_carbon" = "xyes"; then
 203   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 204   LDFLAGS="$LDFLAGS -framework Carbon"
 205 fi
 206
 207 gl_GLIBC21
 208 if test "x$GLIBC21" = "xyes"; then
 209   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 210 fi
 211
 212 dnl declare --enable-* args and collect ac_help strings
 213 AC_ARG_ENABLE(debug,
 214               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 215                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 216               enable_debug=glib_debug_default)
 217
 218 AC_ARG_ENABLE(gc_friendly,
 219               [AC_HELP_STRING([--enable-gc-friendly],
 220                               [turn on garbage collector friendliness [default=no]])],,
 221               [enable_gc_friendly=no])
 222 AC_ARG_ENABLE(mem_pools,
 223               [AC_HELP_STRING([--disable-mem-pools],
 224                               [disable all glib memory pools])],,
 225               [disable_mem_pools=no])
 226 AC_ARG_ENABLE(threads,
 227               [AC_HELP_STRING([--enable-threads],
 228                               [turn on basic thread support [default=yes]
 229 ([=no] will override --with-threads)])],,
 230               [enable_threads=yes])
 231 AC_ARG_ENABLE(rebuilds,
 232               [AC_HELP_STRING([--disable-rebuilds],
 233                               [disable all source autogeneration rules])],,
 234               [enable_rebuilds=yes])
 235
 236 if test "x$enable_threads" != "xyes"; then
 237   enable_threads=no
 238 fi
 239
 240 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 241 if test "x$enable_gc_friendly" = "xyes"; then
 242   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 243   AC_MSG_RESULT([yes])
 244 else
 245   AC_MSG_RESULT([no])
 246 fi
 247
 248 AC_MSG_CHECKING([whether to disable memory pools])
 249 if test "x$disable_mem_pools" = "xno"; then
 250   AC_MSG_RESULT([no])
 251 else
 252   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 253   AC_SUBST(DISABLE_MEM_POOLS)
 254   AC_MSG_RESULT([yes])
 255 fi
 256
 257 dnl location to install runtime libraries, e.g. ../../lib to install
 258 dnl to /lib if libdir is /usr/lib
 259 AC_ARG_WITH(runtime-libdir,
 260            [AC_HELP_STRING([--with-runtime-libdir=RELPATH],
 261                            [Install runtime libraries relative to libdir])],
 262            [],
 263            [with_runtime_libdir=""])
 264 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 265 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 266 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 267 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 268 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 269
 270 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 271 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 272 AC_LANG_SAVE
 273 AC_LANG_CPLUSPLUS
 274 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 275 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 276 AC_LANG_RESTORE
 277
 278 AM_PROG_CC_STDC
 279 AM_PROG_CC_C_O
 280 AC_PROG_INSTALL
 281
 282 AC_SYS_LARGEFILE
 283
 284 PKG_PROG_PKG_CONFIG(0.16)
 285
 286 if test "x$enable_debug" = "xyes"; then
 287   if test x$cflags_set != xset ; then
 288       case " $CFLAGS " in
 289       *[[\ \    ]]-g[[\ \       ]]*) ;;
 290       *) CFLAGS="$CFLAGS -g" ;;
 291       esac
 292   fi
 293
 294   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 295 else
 296   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 297
 298   if test "x$enable_debug" = "xno"; then
 299     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 300   fi
 301 fi
 302
 303 # Ensure MSVC-compatible struct packing convention is used when
 304 # compiling for Win32 with gcc.
 305 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 306 # gcc2 uses "-fnative-struct".
 307 if test x"$glib_native_win32" = xyes; then
 308   if test x"$GCC" = xyes; then
 309     msnative_struct=''
 310     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 311     if test -z "$ac_cv_prog_CC"; then
 312       our_gcc="$CC"
 313     else
 314       our_gcc="$ac_cv_prog_CC"
 315     fi
 316     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 317       2.)
 318         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 319           msnative_struct='-fnative-struct'
 320         fi
 321         ;;
 322       *)
 323         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 324           msnative_struct='-mms-bitfields'
 325         fi
 326         ;;
 327     esac
 328     if test x"$msnative_struct" = x ; then
 329       AC_MSG_RESULT([no way])
 330       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 331     else
 332       CFLAGS="$CFLAGS $msnative_struct"
 333       AC_MSG_RESULT([${msnative_struct}])
 334     fi
 335   fi
 336 fi
 337 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 338 AC_SUBST(GLIB_EXTRA_CFLAGS)
 339
 340 AC_EXEEXT
 341
 342 # define a MAINT-like variable REBUILD which is set if Perl
 343 # and awk are found, so autogenerated sources can be rebuilt
 344 AC_PROG_AWK
 345 AC_CHECK_PROGS(PERL, [perl5 perl])
 346 # We would like indent, but don't require it.
 347 AC_CHECK_PROG(INDENT, indent, indent)
 348 REBUILD=\#
 349 if test "x$enable_rebuilds" = "xyes" && \
 350      test -n "$PERL" && \
 351      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 352      test -n "$AWK" ; then
 353   REBUILD=
 354 fi
 355 AC_SUBST(REBUILD)
 356
 357 # Need full path to Perl for glib-mkenums
 358 #
 359 if test "x$PERL" != x ; then
 360   AC_PATH_PROG(PERL_PATH, [$PERL])
 361 fi
 362 if test "x$PERL_PATH" = x ; then
 363   PERL_PATH="/usr/bin/env perl"
 364 fi
 365 AC_SUBST(PERL_PATH)
 366
 367 # Need suitable python path for greport
 368 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 369
 370
 371 dnl ***********************
 372 dnl *** Tests for iconv ***
 373 dnl ***********************
 374 dnl
 375 dnl We do this before the gettext checks, to avoid distortion
 376
 377 dnl On Windows we use a native implementation
 378
 379 if test x"$glib_native_win32" = xyes; then
 380   with_libiconv=native
 381 else
 382   AC_ARG_WITH(libiconv,
 383               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 384                               [use the libiconv library])],,
 385               [with_libiconv=maybe])
 386
 387   found_iconv=no
 388   case $with_libiconv in
 389     maybe)
 390       # Check in the C library first
 391       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 392       # Check if we have GNU libiconv
 393       if test $found_iconv = "no"; then
 394         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 395       fi
 396       # Check if we have a iconv in -liconv, possibly from vendor
 397       if test $found_iconv = "no"; then
 398         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 399       fi
 400       ;;
 401     no)
 402       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 403       ;;
 404     gnu|yes)
 405       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 406       ;;
 407     native)
 408       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 409       ;;
 410   esac
 411
 412   if test "x$found_iconv" = "xno" ; then
 413      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 414   fi
 415 fi
 416
 417 AC_ARG_ENABLE(iconv-cache,
 418               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 419                               [cache iconv descriptors [default=auto]])],,
 420               [enable_iconv_cache=auto])
 421
 422 AC_MSG_CHECKING([whether to cache iconv descriptors])
 423 case $enable_iconv_cache in
 424   auto)
 425     if test $ac_cv_gnu_library_2_1 = yes; then
 426       enable_iconv_cache=no
 427     else
 428       enable_iconv_cache=yes
 429     fi
 430   ;;
 431   yes|no)
 432   ;;
 433   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 434   ;;
 435 esac
 436
 437 if test $enable_iconv_cache = yes; then
 438    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 439 fi
 440
 441 AC_MSG_RESULT($enable_iconv_cache)
 442
 443
 444 dnl
 445 dnl zlib support
 446 dnl
 447 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 448 if test "x$found_zlib" = "xno" ; then
 449   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 450   if test "x$found_zlib" = "xno" ; then
 451     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 452   fi
 453   ZLIB_LIBS='-lz'
 454   AC_SUBST(ZLIB_LIBS)
 455 fi
 456
 457 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 458 AC_SUBST(LIBFFI_CFLAGS)
 459 AC_SUBST(LIBFFI_LIBS)
 460
 461 dnl
 462 dnl gettext support
 463 dnl
 464
 465 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 466 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 467 GLIB_GNU_GETTEXT
 468
 469 if test "$gt_cv_have_gettext" != "yes" ; then
 470   AC_MSG_ERROR([
 471 *** You must have either have gettext support in your C library, or use the
 472 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 473 ])
 474 fi
 475
 476 LIBS="$INTLLIBS $LIBS"
 477
 478 GETTEXT_PACKAGE=glib20
 479 AC_SUBST(GETTEXT_PACKAGE)
 480 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 481   [Define the gettext package to be used])
 482
 483 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 484
 485 dnl
 486 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 487 dnl
 488
 489 if test x"$glib_native_win32" != xyes; then
 490   if test x$with_libiconv != xno ; then
 491     case " $INTLLIBS " in
 492     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 493     *) ICONV_LIBS="-liconv" ;;
 494     esac
 495   fi
 496 fi
 497 AC_SUBST(ICONV_LIBS)
 498
 499 case $with_libiconv in
 500   gnu)
 501     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 502     ;;
 503   native)
 504     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 505     ;;
 506 esac
 507
 508 dnl Initialize libtool
 509 LT_PREREQ([2.2])
 510 LT_INIT([disable-static win32-dll])
 511 dnl when using libtool 2.x create libtool early, because it's used in configure
 512 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 513
 514
 515 if test "x$GCC" = "xyes"; then
 516   case " $CFLAGS " in
 517   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 518   *) CFLAGS="$CFLAGS -Wall" ;;
 519   esac
 520 fi
 521
 522 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES"
 523
 524 if test "$glib_native_win32" = "yes"; then
 525   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 526     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 527   fi
 528   if test x$enable_static = xyes; then
 529     glib_win32_static_compilation=yes
 530     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 531 #define GOBJECT_STATIC_COMPILATION 1"
 532     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 533   fi
 534 fi
 535 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 536
 537 dnl
 538 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 539 dnl
 540 if test $cross_compiling != yes ; then
 541     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 542     glib_save_LIBS=$LIBS
 543     LIBS="$LIBS -lm"
 544     AC_TRY_RUN([#include <math.h>
 545                  int main (void) { return (log(1) != log(1.)); }],
 546          AC_MSG_RESULT(none needed),
 547          glib_save_CFLAGS=$CFLAGS
 548          CFLAGS="$CFLAGS -std1"
 549          AC_TRY_RUN([#include <math.h>
 550                      int main (void) { return (log(1) != log(1.)); }],
 551              AC_MSG_RESULT(-std1),
 552              AC_MSG_RESULT()
 553              CFLAGS=$glib_save_CFLAGS
 554              AC_MSG_WARN(
 555                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 556          )
 557     )
 558     LIBS=$glib_save_LIBS
 559 fi
 560
 561 dnl NeXTStep cc seems to need this
 562 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 563 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 564   AC_MSG_RESULT(none needed),
 565   glib_save_CFLAGS=$CFLAGS
 566   CFLAGS="$CFLAGS -posix"
 567   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 568     AC_MSG_RESULT(-posix),
 569     AC_MSG_RESULT()
 570     CFLAGS=$glib_save_CFLAGS
 571     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 572
 573 # Checks for header files.
 574 AC_HEADER_STDC
 575
 576 # Checks for library functions.
 577 AC_FUNC_VPRINTF
 578 AC_FUNC_ALLOCA
 579 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2)
 580 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 581
 582 dnl don't use AC_CHECK_FUNCS here, otherwise HAVE_QSORT_R will
 583 dnl be automatically defined, which we don't want to do
 584 dnl until we have checked this function is actually usable
 585 AC_CHECK_FUNC([qsort_r])
 586
 587 # BSD has a qsort_r with wrong argument order
 588 if test x$ac_cv_func_qsort_r = xyes ; then
 589   AC_CACHE_CHECK([if qsort_r uses glibc compatible argument order], glib_cv_have_qsort_r, [
 590   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 591   #define _GNU_SOURCE
 592   #include <stdlib.h>
 593
 594   static int
 595   cmp (const void *a, const void *b, void *c)
 596   {
 597     const int *ia = a;
 598     const int *ib = b;
 599
 600     if (*ia < *ib)
 601       return -1;
 602     else if (*ia > *ib)
 603       return 1;
 604     else
 605       return 0;
 606   }
 607
 608   int
 609   main (int argc, char **argv)
 610   {
 611     int arr[3] = { 1, 2, 0 };
 612     int d = 3;
 613
 614     qsort_r (arr, 3, sizeof (int), cmp, &d);
 615
 616     if (arr[0] == 0 && arr[1] == 1 && arr[2] == 2)
 617       return 0;
 618     else
 619       return 1;
 620   }]])],[glib_cv_have_qsort_r=yes],[glib_cv_have_qsort_r=no])])
 621 fi
 622
 623 if test x$glib_cv_have_qsort_r = xyes ; then
 624   AC_DEFINE(HAVE_QSORT_R, 1, [Define to 1 if you have the 'qsort_r' function])
 625 fi
 626
 627 AC_CHECK_SIZEOF(char)
 628 AC_CHECK_SIZEOF(short)
 629 AC_CHECK_SIZEOF(long)
 630 AC_CHECK_SIZEOF(int)
 631 AC_CHECK_SIZEOF(void *)
 632 AC_CHECK_SIZEOF(long long)
 633 AC_CHECK_SIZEOF(__int64)
 634
 635 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 636   :
 637 else
 638   AC_MSG_ERROR([
 639 *** GLib requires a 64 bit type. You might want to consider
 640 *** using the GNU C compiler.
 641 ])
 642 fi
 643
 644 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 645         # long long is a 64 bit integer.
 646         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 647         AC_CACHE_VAL(glib_cv_long_long_format,[
 648                 for format in ll q I64; do
 649                   AC_TRY_RUN([#include <stdio.h>
 650                         int main()
 651                         {
 652                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 653                           char buffer[1000];
 654                           sprintf (buffer, "%${format}u", a);
 655                           sscanf (buffer, "%${format}u", &b);
 656                           exit (b!=a);
 657                         }
 658                         ],
 659                         [glib_cv_long_long_format=${format}
 660                         break],
 661                         [],[:])
 662                 done])
 663         if test -n "$glib_cv_long_long_format"; then
 664           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 665           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 666           if test x"$glib_cv_long_long_format" = xI64; then
 667             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 668           fi
 669         else
 670           AC_MSG_RESULT(none)
 671         fi
 672 elif test x$ac_cv_sizeof___int64 = x8; then
 673         # __int64 is a 64 bit integer.
 674         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 675         # We know this is MSVCRT.DLL, and what the formats are
 676         glib_cv_long_long_format=I64
 677         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 678         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 679         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 680 fi
 681
 682 dnl long doubles were not used, and a portability problem
 683 dnl AC_C_LONG_DOUBLE
 684 AC_C_CONST
 685
 686 dnl ok, here we try to check whether the systems prototypes for
 687 dnl malloc and friends actually match the prototypes provided
 688 dnl by gmem.h (keep in sync). i currently only know how to check
 689 dnl this reliably with gcc (-Werror), improvements for other
 690 dnl compilers are apprechiated.
 691 SANE_MALLOC_PROTOS=no
 692 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 693 glib_save_CFLAGS=$CFLAGS
 694 if test "x$GCC" = "xyes"; then
 695   CFLAGS="$CFLAGS -Werror"
 696   AC_TRY_COMPILE([#include <stdlib.h>], [
 697     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 698     void* (*my_malloc_p)  (size_t)         = malloc;
 699     void  (*my_free_p)    (void*)          = free;
 700     void* (*my_realloc_p) (void*, size_t)  = realloc;
 701     my_calloc_p = 0;
 702     my_malloc_p = 0;
 703     my_free_p = 0;
 704     my_realloc_p = 0;
 705   ],
 706     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 707       [Define if you have correct malloc prototypes])
 708     SANE_MALLOC_PROTOS=yes)
 709 fi
 710 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 711 CFLAGS=$glib_save_CFLAGS
 712
 713 dnl
 714 dnl check in which direction the stack grows
 715 dnl
 716 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 717         AC_TRY_RUN([
 718         volatile int *a = 0, *b = 0;
 719         void foo (void);
 720         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 721         void foo (void) { volatile int x = 5; b = &x; }
 722         ],
 723         glib_cv_stack_grows=no
 724         ,
 725         glib_cv_stack_grows=yes
 726         ,)
 727 ])
 728
 729 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 730 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 731 dnl actually supported.
 732 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 733         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 734         __inline int foo () { return 0; }
 735         int main () { return foo (); }
 736         ]])],
 737         glib_cv_has__inline=yes
 738         ,
 739         glib_cv_has__inline=no
 740         ,)
 741 ])
 742 case x$glib_cv_has__inline in
 743 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 744 esac
 745 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 746         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 747         __inline__ int foo () { return 0; }
 748         int main () { return foo (); }
 749         ]])],
 750         glib_cv_has__inline__=yes
 751         ,
 752         glib_cv_has__inline__=no
 753         ,)
 754 ])
 755 case x$glib_cv_has__inline__ in
 756 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 757 esac
 758 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 759         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 760         #undef inline
 761         inline int foo () { return 0; }
 762         int main () { return foo (); }
 763         ]])],
 764         glib_cv_hasinline=yes
 765         ,
 766         glib_cv_hasinline=no
 767         ,)
 768 ])
 769 case x$glib_cv_hasinline in
 770 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 771 esac
 772
 773 # if we can use inline functions in headers
 774 AC_MSG_CHECKING(if inline functions in headers work)
 775 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 776 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 777 #  undef inline
 778 #  define inline __inline__
 779 #elif !defined (G_HAVE_INLINE)
 780 #  undef inline
 781 #  if defined (G_HAVE___INLINE__)
 782 #    define inline __inline__
 783 #  elif defined (G_HAVE___INLINE)
 784 #    define inline __inline
 785 #  endif
 786 #endif
 787
 788 int glib_test_func2 (int);
 789
 790 static inline int
 791 glib_test_func1 (void) {
 792   return glib_test_func2 (1);
 793 }
 794
 795 int
 796 main (void) {
 797   int i = 1;
 798 }]])],[g_can_inline=yes],[g_can_inline=no])
 799 AC_MSG_RESULT($g_can_inline)
 800
 801 dnl *** check for working do while(0) macros ***
 802 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 803         AC_TRY_COMPILE([],[
 804         #define STMT_START do
 805         #define STMT_END while(0)
 806         #define STMT_TEST STMT_START { i = 0; } STMT_END
 807         int main(void) { int i = 1; STMT_TEST; return i; }],
 808         [g_cv_support_dowhile_macros=yes],
 809         [g_cv_support_dowhile_macros=no],
 810         [g_cv_support_dowhile_macros=yes])
 811 ])
 812 if test x$g_cv_support_dowhile_macros = xyes; then
 813   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 814 fi
 815
 816 # check for flavours of varargs macros
 817 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 818 AC_TRY_COMPILE([],[
 819 int a(int p1, int p2, int p3);
 820 #define call_a(...) a(1,__VA_ARGS__)
 821 call_a(2,3);
 822 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 823 AC_MSG_RESULT($g_have_iso_c_varargs)
 824
 825 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 826 if test "$CXX" = ""; then
 827 dnl No C++ compiler
 828   g_have_iso_cxx_varargs=no
 829 else
 830   AC_LANG_CPLUSPLUS
 831   AC_TRY_COMPILE([],[
 832 int a(int p1, int p2, int p3);
 833 #define call_a(...) a(1,__VA_ARGS__)
 834 call_a(2,3);
 835 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 836   AC_LANG_C
 837 fi
 838 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 839
 840 AC_MSG_CHECKING(for GNUC varargs macros)
 841 AC_TRY_COMPILE([],[
 842 int a(int p1, int p2, int p3);
 843 #define call_a(params...) a(1,params)
 844 call_a(2,3);
 845 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 846 AC_MSG_RESULT($g_have_gnuc_varargs)
 847
 848 # check for GNUC visibility support
 849 AC_MSG_CHECKING(for GNUC visibility attribute)
 850 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 851 void
 852 __attribute__ ((visibility ("hidden")))
 853      f_hidden (void)
 854 {
 855 }
 856 void
 857 __attribute__ ((visibility ("internal")))
 858      f_internal (void)
 859 {
 860 }
 861 void
 862 __attribute__ ((visibility ("protected")))
 863      f_protected (void)
 864 {
 865 }
 866 void
 867 __attribute__ ((visibility ("default")))
 868      f_default (void)
 869 {
 870 }
 871 int main (int argc, char **argv)
 872 {
 873         f_hidden();
 874         f_internal();
 875         f_protected();
 876         f_default();
 877         return 0;
 878 }
 879 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 880 AC_MSG_RESULT($g_have_gnuc_visibility)
 881 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 882
 883 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 884 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 885 #else
 886 # include "error: this is not Sun Studio."
 887 #endif
 888 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 889 AC_MSG_RESULT($g_have_sunstudio_visibility)
 890 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 891
 892 # check for bytesex stuff
 893 AC_C_BIGENDIAN
 894 if test x$ac_cv_c_bigendian = xuniversal ; then
 895 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 896 #else
 897 #error Not a big endian.
 898 #endif],
 899     ac_cv_c_bigendian=yes
 900     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 901 #else
 902 #error Not a little endian.
 903 #endif],
 904     ac_cv_c_bigendian=no
 905     ,AC_MSG_WARN([Could not determine endianness.])))
 906 fi
 907
 908
 909 # check for header files
 910 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 911 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 912 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 913 AC_CHECK_HEADERS([sys/vfs.h sys/mount.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 914 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h sys/sysctl.h fstab.h])
 915 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 916 AC_CHECK_HEADERS([linux/magic.h])
 917
 918 # check for structure fields
 919 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 920 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 921 #include <sys/stat.h>
 922 #include <unistd.h>
 923 #ifdef HAVE_SYS_STATFS_H
 924 #include <sys/statfs.h>
 925 #endif
 926 #ifdef HAVE_SYS_PARAM_H
 927 #include <sys/param.h>
 928 #endif
 929 #ifdef HAVE_SYS_MOUNT_H
 930 #include <sys/mount.h>
 931 #endif])
 932 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 933 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 934 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 935 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 936
 937 # Checks for libcharset
 938 AM_LANGINFO_CODESET
 939 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 940 AC_CHECK_FUNCS(setlocale)
 941
 942 # check additional type sizes
 943 AC_CHECK_SIZEOF(size_t)
 944
 945 dnl Try to figure out whether gsize, gssize should be long or int
 946 AC_MSG_CHECKING([for the appropriate definition for size_t])
 947
 948 case $ac_cv_sizeof_size_t in
 949   $ac_cv_sizeof_short)
 950       glib_size_type=short
 951       ;;
 952   $ac_cv_sizeof_int)
 953       glib_size_type=int
 954       ;;
 955   $ac_cv_sizeof_long)
 956       glib_size_type=long
 957       ;;
 958   $ac_cv_sizeof_long_long)
 959       glib_size_type='long long'
 960       ;;
 961   $ac_cv_sizeof__int64)
 962       glib_size_type='__int64'
 963       ;;
 964   *)  AC_MSG_ERROR([No type matching size_t in size])
 965       ;;
 966 esac
 967
 968 dnl If int/long are the same size, we see which one produces
 969 dnl warnings when used in the location as size_t. (This matters
 970 dnl on AIX with xlc)
 971 dnl
 972 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 973    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 974   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 975 #if defined(_AIX) && !defined(__GNUC__)
 976 #pragma options langlvl=stdc89
 977 #endif
 978 #include <stddef.h>
 979 int main ()
 980 {
 981   size_t s = 1;
 982   unsigned int *size_int = &s;
 983   return (int)*size_int;
 984 }
 985     ]])],glib_size_type=int,
 986       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 987 #if defined(_AIX) && !defined(__GNUC__)
 988 #pragma options langlvl=stdc89
 989 #endif
 990 #include <stddef.h>
 991 int main ()
 992 {
 993    size_t s = 1;
 994    unsigned long *size_long = &s;
 995    return (int)*size_long;
 996 }
 997         ]])],glib_size_type=long)])
 998 fi
 999
1000 AC_MSG_RESULT(unsigned $glib_size_type)
1001
1002 # Check for some functions
1003 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
1004 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid)
1005 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
1006 # Check for high-resolution sleep functions
1007 AC_CHECK_FUNCS(splice)
1008
1009 # To avoid finding a compatibility unusable statfs, which typically
1010 # successfully compiles, but warns to use the newer statvfs interface:
1011 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1012 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1013
1014 AC_MSG_CHECKING([whether to use statfs or statvfs])
1015 # Some systems have both statfs and statvfs, pick the most "native" for these
1016 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1017    [
1018    # on solaris and irix, statfs doesn't even have the f_bavail field
1019    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1020       [ac_cv_func_statfs=no],
1021    # else, at least on linux, statfs is the actual syscall
1022       [ac_cv_func_statvfs=no])
1023    ])
1024
1025 AS_IF([test x$ac_cv_func_statfs = xyes],
1026       [
1027          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1028          AC_MSG_RESULT([statfs])
1029       ],
1030       [test x$ac_cv_func_statvfs = xyes],
1031       [
1032          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1033          AC_MSG_RESULT([statvfs])
1034       ],
1035       [  AC_MSG_RESULT([neither])])
1036
1037 AC_CHECK_HEADERS(crt_externs.h)
1038 AC_CHECK_FUNCS(_NSGetEnviron)
1039
1040 AC_FUNC_VSNPRINTF_C99
1041 AC_FUNC_PRINTF_UNIX98
1042
1043 # Internet address families
1044 if test $glib_native_win32 = yes; then
1045   glib_inet_includes=["
1046 #include <winsock2.h>
1047   "]
1048 else
1049   glib_inet_includes=["
1050 #include <sys/types.h>
1051 #include <sys/socket.h>
1052   "]
1053 fi
1054
1055 glib_failed=false
1056 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1057 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1058 # winsock defines this even though it doesn't support it
1059 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1060 if $glib_failed ; then
1061   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1062 fi
1063
1064 glib_failed=false
1065 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1066 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1067 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1068 if $glib_failed ; then
1069   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1070 fi
1071
1072 AC_CHECK_FUNCS(getprotobyname_r endservent)
1073 AC_CHECK_HEADERS([netdb.h wspiapi.h arpa/nameser_compat.h])
1074
1075 # For gio/libasyncns
1076 if test $glib_native_win32 = no; then
1077   AC_CHECK_FUNCS(strndup setresuid setreuid)
1078   AC_CHECK_HEADERS(sys/prctl.h)
1079
1080   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1081   NETWORK_LIBS=""
1082   AC_MSG_CHECKING([for res_query])
1083   AC_TRY_LINK([#include <sys/types.h>
1084                #include <netinet/in.h>
1085                #include <arpa/nameser.h>
1086                #include <resolv.h>
1087               ],[
1088                res_query("test", 0, 0, (void *)0, 0);
1089               ],[AC_MSG_RESULT([yes])],
1090               [save_libs="$LIBS"
1091                LIBS="-lresolv $LIBS"
1092                AC_TRY_LINK([#include <sys/types.h>
1093                             #include <netinet/in.h>
1094                             #include <arpa/nameser.h>
1095                             #include <resolv.h>
1096                            ],[
1097                             res_query("test", 0, 0, (void *)0, 0);
1098                            ],[AC_MSG_RESULT([in -lresolv])
1099                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1100                            [LIBS="-lbind $save_libs"
1101                             AC_TRY_LINK([#include <resolv.h>],
1102                                         [res_query("test", 0, 0, (void *)0, 0);],
1103                                         [AC_MSG_RESULT([in -lbind])
1104                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1105                                         [AC_MSG_ERROR(not found)])])
1106                LIBS="$save_libs"])
1107   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1108                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1109                                         [AC_MSG_ERROR(Could not find socket())]))
1110 fi
1111 AC_SUBST(NETWORK_LIBS)
1112
1113 case $host in
1114   *-*-solaris* )
1115      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1116      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1117      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1118      ;;
1119 esac
1120
1121 dnl
1122 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1123 dnl
1124 if test "$ac_cv_func_statfs" = yes ; then
1125   AC_MSG_CHECKING([number of arguments to statfs()])
1126   AC_TRY_COMPILE([#include <unistd.h>
1127   #ifdef HAVE_SYS_PARAM_H
1128   #include <sys/param.h>
1129   #endif
1130   #ifdef HAVE_SYS_VFS_H
1131   #include <sys/vfs.h>
1132   #endif
1133   #ifdef HAVE_SYS_MOUNT_H
1134   #include <sys/mount.h>
1135   #endif
1136   #ifdef HAVE_SYS_STATFS_H
1137   #include <sys/statfs.h>
1138   #endif], [struct statfs st;
1139   statfs(NULL, &st);],[
1140     AC_MSG_RESULT([2])
1141     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1142     AC_TRY_COMPILE([#include <unistd.h>
1143   #ifdef HAVE_SYS_PARAM_H
1144   #include <sys/param.h>
1145   #endif
1146   #ifdef HAVE_SYS_VFS_H
1147   #include <sys/vfs.h>
1148   #endif
1149   #ifdef HAVE_SYS_MOUNT_H
1150   #include <sys/mount.h>
1151   #endif
1152   #ifdef HAVE_SYS_STATFS_H
1153   #include <sys/statfs.h>
1154   #endif], [struct statfs st;
1155   statfs(NULL, &st, sizeof (st), 0);],[
1156       AC_MSG_RESULT([4])
1157       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1158       AC_MSG_RESULT(unknown)
1159       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1160 fi
1161
1162 #
1163 # Check whether to use an included printf
1164 #
1165
1166 AC_ARG_ENABLE(included-printf,
1167               [AC_HELP_STRING([--enable-included-printf],
1168                               [use included printf [default=auto]])],
1169               enable_included_printf="$enableval")
1170
1171 need_included_printf=no
1172 if test "x$enable_included_printf" = "xyes" ; then
1173   need_included_printf=yes
1174 fi
1175 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1176   need_included_printf=yes
1177 fi
1178 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1179   need_included_printf=yes
1180 fi
1181 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1182    test -z "$glib_cv_long_long_format" ; then
1183   need_included_printf=yes
1184 fi
1185
1186 if test "x$enable_included_printf" = "xno" &&
1187    test "x$need_included_printf" = "xyes" ; then
1188   AC_MSG_ERROR([
1189 *** Your C library's printf doesn't appear to have the features that
1190 *** GLib needs, but you specified --enable-included-printf=no.])
1191 fi
1192
1193 enable_included_printf=$need_included_printf
1194
1195 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1196 if test "$enable_included_printf" != "yes" ; then
1197   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1198 else
1199   if test -z "$glib_cv_long_long_format" ; then
1200     glib_cv_long_long_format="ll"
1201   fi
1202   AC_DEFINE(HAVE_VASPRINTF,1)
1203 fi
1204
1205 # Checks needed for gnulib vasnprintf
1206 bh_C_SIGNED
1207 jm_AC_TYPE_LONG_LONG
1208 gt_TYPE_LONGDOUBLE
1209 gt_TYPE_WCHAR_T
1210 gt_TYPE_WINT_T
1211 AC_TYPE_SIZE_T
1212 AC_CHECK_TYPES(ptrdiff_t)
1213 jm_AC_TYPE_INTMAX_T
1214 AC_CHECK_FUNCS([snprintf wcslen])
1215 AC_FUNC_SNPRINTF_C99
1216
1217 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1218 # The check is borrowed from the PERL Configure script.
1219 if test "$ac_cv_func_memmove" != "yes"; then
1220   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1221     glib_cv_working_bcopy,[AC_TRY_RUN([
1222       int main() {
1223         char buf[128], abc[128], *b;
1224         int len, off, align;
1225         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1226         for (align = 7; align >= 0; align--) {
1227           for (len = 36; len; len--) {
1228             b = buf+align; bcopy(abc, b, len);
1229             for (off = 1; off <= len; off++) {
1230               bcopy(b, b+off, len); bcopy(b+off, b, len);
1231                 if (bcmp(b, abc, len)) return(1);
1232             }
1233           }
1234         }
1235         return(0);
1236       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1237
1238   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1239   if test "$glib_cv_working_bcopy" = "yes"; then
1240     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1241   fi
1242 fi
1243
1244 # Check for sys_errlist
1245 AC_MSG_CHECKING(for sys_errlist)
1246 AC_TRY_LINK(, [
1247 extern char *sys_errlist[];
1248 extern int sys_nerr;
1249 sys_errlist[sys_nerr-1][0] = 0;
1250 ], glib_ok=yes, glib_ok=no)
1251 AC_MSG_RESULT($glib_ok)
1252 if test "$glib_ok" = "no"; then
1253     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
1254 fi
1255
1256 # Check for sys_siglist
1257 AC_MSG_CHECKING(for sys_siglist)
1258 AC_TRY_LINK(, [
1259 extern char *sys_siglist[];
1260 exit (sys_siglist[0]);
1261 ], glib_ok=yes, glib_ok=no)
1262 AC_MSG_RESULT($glib_ok)
1263 if test "$glib_ok" = "no"; then
1264     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
1265 fi
1266
1267 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
1268 AC_MSG_CHECKING(for sys_siglist declaration)
1269 AC_TRY_COMPILE([#include <signal.h>], [
1270 strlen (sys_siglist[0]);
1271 ], glib_ok=yes, glib_ok=no)
1272 AC_MSG_RESULT($glib_ok)
1273 if test "$glib_ok" = "no"; then
1274     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
1275 fi
1276
1277 # Check if <sys/select.h> needs to be included for fd_set
1278 AC_MSG_CHECKING([for fd_set])
1279 AC_TRY_COMPILE([#include <sys/types.h>],
1280         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1281 if test "$gtk_ok" = "yes"; then
1282     AC_MSG_RESULT([yes, found in sys/types.h])
1283 else
1284     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1285     if test "$gtk_ok" = "yes"; then
1286         # *** FIXME: give it a different name
1287         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1288         AC_MSG_RESULT([yes, found in sys/select.h])
1289     else
1290         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1291         AC_MSG_RESULT(no)
1292     fi
1293 fi
1294
1295 dnl *** check for sane realloc() ***
1296 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1297         AC_TRY_RUN([#include <stdlib.h>
1298         int main() {
1299           return realloc (0, sizeof (int)) == 0;
1300         }],
1301         [glib_cv_sane_realloc=yes],
1302         [glib_cv_sane_realloc=no],
1303         [glib_cv_sane_realloc=yes])
1304 ])
1305 if test x$glib_cv_sane_realloc = xyes; then
1306   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1307 fi
1308
1309 dnl Check for nl_langinfo and CODESET
1310 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1311         AC_TRY_COMPILE([#include <langinfo.h>],
1312                 [char *codeset = nl_langinfo (CODESET);],
1313                 [glib_cv_langinfo_codeset=yes],
1314                 [glib_cv_langinfo_codeset=no])])
1315 if test x$glib_cv_langinfo_codeset = xyes; then
1316   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1317 fi
1318
1319 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1320 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1321         AC_TRY_COMPILE([#include <langinfo.h>],
1322                 [char *str;
1323                  str = nl_langinfo (PM_STR);
1324                  str = nl_langinfo (D_FMT);
1325                  str = nl_langinfo (T_FMT);
1326                  str = nl_langinfo (MON_1);
1327                  str = nl_langinfo (ABMON_12);
1328                  str = nl_langinfo (DAY_1);
1329                  str = nl_langinfo (ABDAY_7);],
1330                 [glib_cv_langinfo_time=yes],
1331                 [glib_cv_langinfo_time=no])])
1332 if test x$glib_cv_langinfo_time = xyes; then
1333   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1334 fi
1335
1336 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_WC
1337 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_WC)], glib_cv_langinfo_outdigit,[
1338         AC_TRY_COMPILE([#include <langinfo.h>],
1339                 [char *str;
1340                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_WC);
1341                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_WC);
1342                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_WC);
1343                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_WC);
1344                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_WC);
1345                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_WC);
1346                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_WC);
1347                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_WC);
1348                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_WC);
1349                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_WC);],
1350                 [glib_cv_langinfo_outdigit=yes],
1351                 [glib_cv_langinfo_outdigit=no])])
1352 if test x$glib_cv_langinfo_outdigit = xyes; then
1353   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_WC)])
1354 fi
1355
1356 dnl ****************************************
1357 dnl *** posix_memalign                   ***
1358 dnl ****************************************
1359 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1360 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1361     glib_cv_compliant_posix_memalign=0
1362     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1363         AC_TRY_RUN([
1364                 #define _XOPEN_SOURCE 600
1365                 #include <stdlib.h> /* posix_memalign() should be defined here */
1366                 /* some systems break if #include <malloc.h> used */
1367                 static void test_memalign (size_t boundary, size_t size) {
1368                     void *mem = 0;
1369                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1370                         exit (1);
1371                     else
1372                       free (mem);
1373                 }
1374                 int main() {
1375                     test_memalign (  128,   128 - 2 * sizeof (void*));
1376                     test_memalign (  256,   256 - 2 * sizeof (void*));
1377                     test_memalign (  512,   512 - 2 * sizeof (void*));
1378                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1379                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1380                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1381                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1382                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1383                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1384                     exit (0); /* success */
1385                 }
1386                 ],
1387             [glib_cv_compliant_posix_memalign=1], [], [:])
1388       :
1389     fi
1390     ])
1391 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1392     AC_MSG_RESULT(yes)
1393     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1394 else
1395     AC_MSG_RESULT(no)
1396 fi
1397
1398
1399 dnl ****************************************
1400 dnl *** strlcpy/strlcat                  ***
1401 dnl ****************************************
1402 # Check for strlcpy
1403 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1404 AC_TRY_RUN([#include <stdlib.h>
1405 #include <string.h>
1406 int main() {
1407   char p[10];
1408   (void) strlcpy (p, "hi", 10);
1409   if (strlcat (p, "bye", 0) != 3)
1410     return 1;
1411   return 0;
1412 }], glib_cv_have_strlcpy=yes,
1413     glib_cv_have_strlcpy=no,
1414     glib_cv_have_strlcpy=no)])
1415 if test "$glib_cv_have_strlcpy" = "yes"; then
1416     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1417 fi
1418
1419
1420 dnl **********************
1421 dnl *** va_copy checks ***
1422 dnl **********************
1423 dnl we currently check for all three va_copy possibilities, so we get
1424 dnl all results in config.log for bug reports.
1425 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1426         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1427 #include <stdlib.h>
1428         void f (int i, ...) {
1429         va_list args1, args2;
1430         va_start (args1, i);
1431         va_copy (args2, args1);
1432         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1433           exit (1);
1434         va_end (args1); va_end (args2);
1435         }
1436         int main() {
1437           f (0, 42);
1438           return 0;
1439         }]])],
1440         [glib_cv_va_copy=yes],
1441         [glib_cv_va_copy=no])
1442 ])
1443 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1444         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1445 #include <stdlib.h>
1446         void f (int i, ...) {
1447         va_list args1, args2;
1448         va_start (args1, i);
1449         __va_copy (args2, args1);
1450         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1451           exit (1);
1452         va_end (args1); va_end (args2);
1453         }
1454         int main() {
1455           f (0, 42);
1456           return 0;
1457         }]])],
1458         [glib_cv___va_copy=yes],
1459         [glib_cv___va_copy=no])
1460 ])
1461
1462 if test "x$glib_cv_va_copy" = "xyes"; then
1463   g_va_copy_func=va_copy
1464 else if test "x$glib_cv___va_copy" = "xyes"; then
1465   g_va_copy_func=__va_copy
1466 fi
1467 fi
1468
1469 if test -n "$g_va_copy_func"; then
1470   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1471 fi
1472
1473 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1474         AC_TRY_RUN([#include <stdarg.h>
1475 #include <stdlib.h>
1476         void f (int i, ...) {
1477         va_list args1, args2;
1478         va_start (args1, i);
1479         args2 = args1;
1480         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1481           exit (1);
1482         va_end (args1); va_end (args2);
1483         }
1484         int main() {
1485           f (0, 42);
1486           return 0;
1487         }],
1488         [glib_cv_va_val_copy=yes],
1489         [glib_cv_va_val_copy=no],
1490         [glib_cv_va_val_copy=yes])
1491 ])
1492
1493 if test "x$glib_cv_va_val_copy" = "xno"; then
1494   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1495 fi
1496
1497 dnl ***********************
1498 dnl *** g_module checks ***
1499 dnl ***********************
1500 G_MODULE_LIBS=
1501 G_MODULE_LIBS_EXTRA=
1502 G_MODULE_PLUGIN_LIBS=
1503 if test x"$glib_native_win32" = xyes; then
1504   dnl No use for this on Win32
1505   G_MODULE_LDFLAGS=
1506 else
1507   export SED
1508   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1509 fi
1510 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1511 G_MODULE_NEED_USCORE=0
1512 G_MODULE_BROKEN_RTLD_GLOBAL=0
1513 G_MODULE_HAVE_DLERROR=0
1514 dnl *** force native WIN32 shared lib loader
1515 if test -z "$G_MODULE_IMPL"; then
1516   case "$host" in
1517   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1518   esac
1519 fi
1520 dnl *** force native AIX library loader
1521 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1522 if test -z "$G_MODULE_IMPL"; then
1523   case "$host" in
1524   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1525   esac
1526 fi
1527 dnl *** dlopen() and dlsym() in system libraries
1528 if test -z "$G_MODULE_IMPL"; then
1529         AC_CHECK_FUNC(dlopen,
1530                       [AC_CHECK_FUNC(dlsym,
1531                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1532                       [])
1533 fi
1534 dnl *** load_image (BeOS)
1535 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1536   AC_CHECK_LIB(root, load_image,
1537       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1538       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1539       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1540       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1541       [])
1542 fi
1543 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1544 if test -z "$G_MODULE_IMPL"; then
1545         AC_CHECK_FUNC(NSLinkModule,
1546                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1547                        G_MODULE_NEED_USCORE=1],
1548                       [])
1549 fi
1550 dnl *** dlopen() and dlsym() in libdl
1551 if test -z "$G_MODULE_IMPL"; then
1552         AC_CHECK_LIB(dl, dlopen,
1553                      [AC_CHECK_LIB(dl, dlsym,
1554                                    [G_MODULE_LIBS=-ldl
1555                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1556                      [])
1557 fi
1558 dnl *** shl_load() in libdld (HP-UX)
1559 if test -z "$G_MODULE_IMPL"; then
1560         AC_CHECK_LIB(dld, shl_load,
1561                 [G_MODULE_LIBS=-ldld
1562                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1563                 [])
1564 fi
1565 dnl *** additional checks for G_MODULE_IMPL_DL
1566 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1567         LIBS_orig="$LIBS"
1568         LDFLAGS_orig="$LDFLAGS"
1569         LIBS="$G_MODULE_LIBS $LIBS"
1570         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1571 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1572         echo "void glib_plugin_test(void) { }" > plugin.c
1573         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1574                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1575         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1576                 glib_cv_rtldglobal_broken,[
1577                 AC_TRY_RUN([
1578 #include <dlfcn.h>
1579 #ifndef RTLD_GLOBAL
1580 #  define RTLD_GLOBAL 0
1581 #endif
1582 #ifndef RTLD_LAZY
1583 #  define RTLD_LAZY 0
1584 #endif
1585 int glib_plugin_test;
1586 int main () {
1587     void *handle, *global, *local;
1588     global = &glib_plugin_test;
1589     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1590     if (!handle) return 0;
1591     local = dlsym (handle, "glib_plugin_test");
1592     return global == local;
1593 }                       ],
1594                         [glib_cv_rtldglobal_broken=no],
1595                         [glib_cv_rtldglobal_broken=yes],
1596                         [glib_cv_rtldglobal_broken=no])
1597                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1598                 rmdir .libs 2>/dev/null
1599         ])
1600         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1601                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1602         else
1603                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1604         fi
1605 dnl *** check whether we need preceeding underscores
1606         AC_CACHE_CHECK([for preceeding underscore in symbols],
1607                 glib_cv_uscore,[
1608                 AC_TRY_RUN([#include <dlfcn.h>
1609                 int glib_underscore_test (void) { return 42; }
1610                 int main() {
1611                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1612                   handle = dlopen ((void*)0, 0);
1613                   if (handle) {
1614                     f1 = dlsym (handle, "glib_underscore_test");
1615                     f2 = dlsym (handle, "_glib_underscore_test");
1616                   } return (!f2 || f1);
1617                 }],
1618                         [glib_cv_uscore=yes],
1619                         [glib_cv_uscore=no],
1620                         [])
1621                 rm -f plugin.c plugin.$ac_objext plugin.lo
1622         ])
1623         GLIB_ASSERT_SET(glib_cv_uscore)
1624         if test "x$glib_cv_uscore" = "xyes"; then
1625                 G_MODULE_NEED_USCORE=1
1626         else
1627                 G_MODULE_NEED_USCORE=0
1628         fi
1629
1630         LDFLAGS="$LDFLAGS_orig"
1631 dnl *** check for having dlerror()
1632         AC_CHECK_FUNC(dlerror,
1633                 [G_MODULE_HAVE_DLERROR=1],
1634                 [G_MODULE_HAVE_DLERROR=0])
1635         LIBS="$LIBS_orig"
1636 fi
1637 dnl *** done, have we got an implementation?
1638 if test -z "$G_MODULE_IMPL"; then
1639         G_MODULE_IMPL=0
1640         G_MODULE_SUPPORTED=false
1641 else
1642         G_MODULE_SUPPORTED=true
1643 fi
1644
1645 AC_MSG_CHECKING(for the suffix of module shared libraries)
1646 export SED
1647 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1648 eval $shrext_cmds
1649 module=yes eval std_shrext=$shrext_cmds
1650 # chop the initial dot
1651 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1652 AC_MSG_RESULT(.$glib_gmodule_suffix)
1653 # any reason it may fail?
1654 if test "x$glib_gmodule_suffix" = x; then
1655         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1656 fi
1657
1658 AC_SUBST(G_MODULE_SUPPORTED)
1659 AC_SUBST(G_MODULE_IMPL)
1660 AC_SUBST(G_MODULE_LIBS)
1661 AC_SUBST(G_MODULE_LIBS_EXTRA)
1662 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1663 AC_SUBST(G_MODULE_LDFLAGS)
1664 AC_SUBST(G_MODULE_HAVE_DLERROR)
1665 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1666 AC_SUBST(G_MODULE_NEED_USCORE)
1667 AC_SUBST(GLIB_DEBUG_FLAGS)
1668
1669 dnl **********************
1670 dnl *** g_spawn checks ***
1671 dnl **********************
1672
1673 AC_MSG_CHECKING(for gspawn implementation)
1674 case "$host" in
1675   *-*-mingw*)
1676     GSPAWN=gspawn-win32.lo
1677     ;;
1678   *)
1679     GSPAWN=gspawn.lo
1680     ;;
1681 esac
1682 AC_MSG_RESULT($GSPAWN)
1683 AC_SUBST(GSPAWN)
1684
1685 dnl *************************
1686 dnl *** GIOChannel checks ***
1687 dnl *************************
1688
1689 AC_MSG_CHECKING(for GIOChannel implementation)
1690 case "$host" in
1691   *-*-mingw*)
1692     GIO=giowin32.lo
1693     ;;
1694   *)
1695     GIO=giounix.lo
1696     ;;
1697 esac
1698 AC_MSG_RESULT($GIO)
1699 AC_SUBST(GIO)
1700
1701 dnl *********************************
1702 dnl *** Directory for GIO modules ***
1703 dnl *********************************
1704
1705 AC_ARG_WITH(gio-module-dir,
1706            [AC_HELP_STRING([--with-gio-module-dir=PATH],
1707                            [Load gio modules from this directory [LIBDIR/gio/modules]])],
1708            [],
1709            [with_gio_module_dir='${libdir}/gio/modules'])
1710 GIO_MODULE_DIR=$with_gio_module_dir
1711 AC_SUBST(GIO_MODULE_DIR)
1712
1713 dnl **********************************
1714 dnl *** Check for libselinux (GIO) ***
1715 dnl **********************************
1716 AC_ARG_ENABLE(selinux, [  --disable-selinux       build without selinux support])
1717 msg_selinux=no
1718 SELINUX_LIBS=
1719 if test "x$enable_selinux" != "xno"; then
1720
1721  AC_CHECK_LIB(selinux, is_selinux_enabled,
1722    [AC_CHECK_HEADERS(selinux/selinux.h,
1723      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1724        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1725         SELINUX_LIBS="-lselinux"
1726         msg_selinux=yes])
1727      ])
1728    ])
1729 fi
1730 AC_SUBST(SELINUX_LIBS)
1731
1732 dnl *****************************
1733 dnl ** Check for inotify (GIO) **
1734 dnl *****************************
1735 inotify_support=no
1736 AC_CHECK_HEADERS([sys/inotify.h],
1737 [
1738         inotify_support=yes
1739         AC_CHECK_FUNCS(inotify_init1)
1740 ])
1741
1742 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1743
1744 dnl *********************************
1745 dnl ** Check for Solaris FEN (GIO) **
1746 dnl *********************************
1747 fen_support=no
1748 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1749 #include <port.h>
1750 #ifndef PORT_SOURCE_FILE
1751 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1752 #endif
1753 int main() { return 0; } ]])],
1754 [
1755         fen_support=yes
1756 ],)
1757
1758 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1759
1760 dnl ****************************
1761 dnl *** Checks for FAM (GIO) ***
1762 dnl ****************************
1763
1764 should_disable_fam=no
1765
1766 AC_ARG_ENABLE(fam, [  --disable-fam          build without enabling fam for file system monitoring],
1767                          [
1768                                 if test "x$enable_fam" = "xno"; then
1769                                         should_disable_fam=yes
1770                                         echo "Not building FAM support"
1771                                 fi
1772                          ]
1773                          )
1774 fam_support=no
1775 FAM_LIBS=
1776 if test "x$should_disable_fam" = "xno"; then
1777 AC_CHECK_LIB(fam, FAMOpen,
1778   [AC_CHECK_HEADERS(fam.h,
1779     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1780      AC_CHECK_LIB(fam, FAMNoExists,
1781                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1782      FAM_LIBS="-lfam"]
1783      fam_support=yes,
1784     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1785   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1786 AC_SUBST(FAM_LIBS)
1787 fi
1788 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1789
1790
1791 dnl *****************************
1792 dnl *** Check for xattr (GIO) ***
1793 dnl *****************************
1794 AC_ARG_ENABLE(xattr, [  --disable-xattr           build without xattr support])
1795 msg_xattr=no
1796 XATTR_LIBS=
1797 if test "x$enable_xattr" != "xno"; then
1798
1799 dnl either glibc or libattr can provide xattr support
1800
1801 dnl for both of them, we check for getxattr being in
1802 dnl the library and a valid xattr header.
1803
1804 dnl try glibc
1805  AC_CHECK_LIB(c, getxattr,
1806    [AC_CHECK_HEADERS(sys/xattr.h,
1807      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1808       msg_xattr=yes])
1809    ])
1810
1811   if test "x$msg_xattr" != "xyes"; then
1812 dnl   failure. try libattr
1813    AC_CHECK_LIB(attr, getxattr,
1814       [AC_CHECK_HEADERS(attr/xattr.h,
1815        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1816         XATTR_LIBS="-lattr"
1817         msg_xattr=yes])
1818       ])
1819   fi
1820
1821   if test "x$msg_xattr" = "xyes"; then
1822     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1823     AC_TRY_COMPILE([
1824       #include <stdio.h>
1825       #ifdef HAVE_SYS_TYPES_H
1826       #include <sys/types.h>
1827       #endif
1828       #ifdef HAVE_SYS_XATTR_H
1829       #include <sys/xattr.h>
1830       #elif HAVE_ATTR_XATTR_H
1831       #include <attr/xattr.h>
1832       #endif
1833     ],
1834     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1835     [
1836       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1837       AC_MSG_RESULT([yes])
1838     ],
1839     [AC_MSG_RESULT([no])]
1840     )
1841   fi
1842
1843 fi
1844 AC_SUBST(XATTR_LIBS)
1845
1846 dnl ****************************************
1847 dnl *** platform dependent source checks ***
1848 dnl ****************************************
1849
1850 AC_MSG_CHECKING(for platform-dependent source)
1851 case "$host" in
1852   *-*-cygwin*|*-*-mingw*)
1853     PLATFORMDEP=gwin32.lo
1854     ;;
1855   *)
1856     PLATFORMDEP=
1857     ;;
1858 esac
1859 AC_MSG_RESULT($PLATFORMDEP)
1860 AC_SUBST(PLATFORMDEP)
1861
1862 AC_MSG_CHECKING([whether to compile timeloop])
1863 case "$host" in
1864   *-*-cygwin*|*-*-mingw*|*-*-minix)
1865     enable_timeloop=no
1866     ;;
1867   *)
1868     enable_timeloop=yes
1869     ;;
1870 esac
1871 AC_MSG_RESULT($enable_timeloop)
1872 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1873
1874 AC_MSG_CHECKING([if building for some Win32 platform])
1875 case "$host" in
1876   *-*-mingw*|*-*-cygwin*)
1877     platform_win32=yes
1878     ;;
1879   *)
1880     platform_win32=no
1881     ;;
1882 esac
1883 AC_MSG_RESULT($platform_win32)
1884 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1885
1886 dnl ***********************
1887 dnl *** g_thread checks ***
1888 dnl ***********************
1889
1890 AC_ARG_WITH(threads,
1891            [AC_HELP_STRING([--with-threads=@<:@none/posix/dce/win32@:>@],
1892                            [specify a thread implementation to use])],
1893            [if test "x$with_threads" = x; then
1894                 want_threads=yes
1895             else
1896                 want_threads=$with_threads
1897             fi],
1898            [want_threads=yes])
1899 if test "x$enable_threads" = "xno"; then
1900         want_threads=no
1901 fi
1902
1903 dnl error and warning message
1904 dnl *************************
1905
1906 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1907                 computer. GLib will not have a default thread implementation."
1908
1909 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1910                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1911                 compilation now, but then your programs might not work.
1912                 Please provide information on how it is done on your system."
1913
1914 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1915                 "
1916
1917 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1918                 provide information on your thread implementation.
1919                 You can also run 'configure --disable-threads'
1920                 to compile without thread support."
1921
1922 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1923                 functions will not be MT-safe during their first call because
1924                 there is no working 'getpwuid_r' on your system."
1925
1926 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1927                 because there is no 'localtime_r' on your system."
1928
1929 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1930                 crude surrogate will be used. If you happen to know a
1931                 yield function for your system, please inform the GLib
1932                 developers."
1933
1934 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1935                 threads on your system. Thus threads can only have the default
1936                 priority. If you happen to know these main/max
1937                 priorities, please inform the GLib developers."
1938
1939 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1940                 linking threaded applications. As GLib cannot do that
1941                 automatically, you will get an linkg error everytime you are
1942                 not using the right compiler. In that case you have to relink
1943                 with the right compiler. Ususally just '_r' is appended
1944                 to the compiler name."
1945
1946 dnl determination of thread implementation
1947 dnl ***************************************
1948
1949 # have_threads=no   means no thread support
1950 # have_threads=none means no default thread implementation
1951
1952 have_threads=no
1953 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1954                                 || test "x$want_threads" = xdce; then
1955         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1956         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1957         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1958         glib_save_CPPFLAGS="$CPPFLAGS"
1959         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1960         if test "x$have_threads" = xno; then
1961                 AC_TRY_COMPILE([#include <pthread.h>],
1962                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1963                         have_threads=posix)
1964         fi
1965         if test "x$have_threads" = xno; then
1966                 AC_TRY_COMPILE([#include <pthread.h>],
1967                         [pthread_mutex_t m;
1968                          pthread_mutex_init (&m, pthread_mutexattr_default);],
1969                         have_threads=dce)
1970         fi
1971         # Tru64Unix requires -pthread to find pthread.h. See #103020
1972         CPPFLAGS="$CPPFLAGS -pthread"
1973         if test "x$have_threads" = xno; then
1974         AC_TRY_COMPILE([#include <pthread.h>],
1975                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1976                        have_threads=posix)
1977         fi
1978         CPPFLAGS="$glib_save_CPPFLAGS"
1979 fi
1980 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1981         case $host in
1982                 *-*-mingw*)
1983                 have_threads=win32
1984                 ;;
1985         esac
1986 fi
1987 if test "x$want_threads" = xnone; then
1988         have_threads=none
1989 fi
1990
1991 AC_MSG_CHECKING(for thread implementation)
1992
1993 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1994         AC_MSG_RESULT(none available)
1995         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1996 else
1997         AC_MSG_RESULT($have_threads)
1998 fi
1999
2000
2001 dnl determination of G_THREAD_CFLAGS
2002 dnl ********************************
2003
2004 G_THREAD_LIBS=
2005 G_THREAD_LIBS_EXTRA=
2006 G_THREAD_CFLAGS=
2007
2008 dnl
2009 dnl Test program for basic POSIX threads functionality
2010 dnl
2011 m4_define([glib_thread_test],[
2012 #include <pthread.h>
2013 int check_me = 0;
2014 void* func(void* data) {check_me = 42; return &check_me;}
2015 int main()
2016  { pthread_t t;
2017    void *ret;
2018    pthread_create (&t, $1, func, 0);
2019    pthread_join (t, &ret);
2020    return (check_me != 42 || ret != &check_me);
2021 }])
2022
2023 dnl
2024 dnl Test program for sched_get_priority_min()
2025 dnl
2026 m4_define([glib_sched_priority_test],[
2027 #include <sched.h>
2028 #include <errno.h>
2029 int main() {
2030     errno = 0;
2031     return sched_get_priority_min(SCHED_OTHER)==-1
2032            && errno != 0;
2033 }])
2034
2035 if test x"$have_threads" != xno; then
2036
2037   if test x"$have_threads" = xposix; then
2038     # First we test for posix, whether -pthread or -pthreads do the trick as
2039     # both CPPFLAG and LIBS.
2040     # One of them does for most gcc versions and some other platforms/compilers
2041     # too and could be considered as the canonical way to go.
2042     case $host in
2043       *-*-cygwin*|*-*-darwin*)
2044          # skip cygwin and darwin -pthread or -pthreads test
2045          ;;
2046       *-solaris*)
2047         # These compiler/linker flags work with both Sun Studio and gcc
2048         # Sun Studio expands -mt to -D_REENTRANT and -lthread
2049         # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2050         G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2051         G_THREAD_LIBS="-lpthread -lthread"
2052         ;;
2053       *)
2054         for flag in pthread pthreads mt; do
2055           glib_save_CFLAGS="$CFLAGS"
2056           CFLAGS="$CFLAGS -$flag"
2057           AC_TRY_RUN(glib_thread_test(0),
2058                      glib_flag_works=yes,
2059                      glib_flag_works=no,
2060                      [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2061                                      glib_flag_works=yes,
2062                                      glib_flag_works=no)])
2063           CFLAGS="$glib_save_CFLAGS"
2064           if test $glib_flag_works = yes ; then
2065              G_THREAD_CFLAGS=-$flag
2066              G_THREAD_LIBS=-$flag
2067              break;
2068           fi
2069         done
2070          ;;
2071     esac
2072   fi
2073
2074   if test x"$G_THREAD_CFLAGS" = x; then
2075
2076     # The canonical -pthread[s] does not work. Try something different.
2077
2078     case $host in
2079         *-aix*)
2080                 if test x"$GCC" = xyes; then
2081                         # GCC 3.0 and above needs -pthread.
2082                         # Should be coverd by the case above.
2083                         # GCC 2.x and below needs -mthreads
2084                         G_THREAD_CFLAGS="-mthreads"
2085                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2086                 else
2087                         # We are probably using the aix compiler. Normaly a
2088                         # program would have to be compiled with the _r variant
2089                         # of the corresponding compiler, but we as GLib cannot
2090                         # do that: but the good news is that for compiling the
2091                         # only difference is the added -D_THREAD_SAFE compile
2092                         # option. This is according to the "C for AIX User's
2093                         # Guide".
2094                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2095                 fi
2096                 ;;
2097         *-dg-dgux*)  # DG/UX
2098                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2099                 ;;
2100         *-osf*)
2101                 # So we are using dce threads. posix threads are already
2102                 # catched above.
2103                 G_THREAD_CFLAGS="-threads"
2104                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2105                 ;;
2106         *-sysv5uw7*) # UnixWare 7
2107                 # We are not using gcc with -pthread. Catched above.
2108                 G_THREAD_CFLAGS="-Kthread"
2109                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2110                 ;;
2111         *-mingw*)
2112                 # No flag needed when using MSVCRT.DLL
2113                 G_THREAD_CFLAGS=""
2114                 ;;
2115         *)
2116                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2117                 ;;
2118     esac
2119
2120   fi
2121
2122     # if we are not finding the localtime_r function, then we probably are
2123     # not using the proper multithread flag
2124
2125     glib_save_CPPFLAGS="$CPPFLAGS"
2126     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2127
2128     # First we test, whether localtime_r is declared in time.h
2129     # directly. Then we test whether a macro localtime_r exists, in
2130     # which case localtime_r in the test program is replaced and thus
2131     # if we still find localtime_r in the output, it is not defined as
2132     # a macro.
2133
2134     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2135       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2136                                                            localtime_r(a,b)],
2137                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2138
2139     CPPFLAGS="$glib_save_CPPFLAGS"
2140
2141     AC_MSG_CHECKING(thread related cflags)
2142     AC_MSG_RESULT($G_THREAD_CFLAGS)
2143     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2144 fi
2145
2146 dnl determination of G_THREAD_LIBS
2147 dnl ******************************
2148
2149 mutex_has_default=no
2150 case $have_threads in
2151         posix|dce)
2152           glib_save_CPPFLAGS="$CPPFLAGS"
2153           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2154           if test x"$G_THREAD_LIBS" = x; then
2155             case $host in
2156               *-aix*)
2157                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2158                 # probably using the aix compiler.
2159                 AC_MSG_WARN($AIX_COMPILE_INFO)
2160                 ;;
2161               *)
2162                 G_THREAD_LIBS=error
2163                 glib_save_LIBS="$LIBS"
2164                 for thread_lib in "" pthread pthread32 pthreads thread dce; do
2165                         if test x"$thread_lib" = x; then
2166                                 add_thread_lib=""
2167                                 IN=""
2168                         else
2169                                 add_thread_lib="-l$thread_lib"
2170                                 IN=" in -l$thread_lib"
2171                         fi
2172                         if test x"$have_threads" = xposix; then
2173                                 defattr=0
2174                         else
2175                                 defattr=pthread_attr_default
2176                         fi
2177
2178                         LIBS="$add_thread_lib $glib_save_LIBS"
2179
2180                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2181                         AC_TRY_RUN(glib_thread_test($defattr),
2182                                    glib_result=yes,
2183                                    glib_result=no,
2184                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2185                                                    glib_result=yes,
2186                                                    glib_result=no)])
2187                         AC_MSG_RESULT($glib_result)
2188
2189                         if test "$glib_result" = "yes" ; then
2190                           G_THREAD_LIBS="$add_thread_lib"
2191                           break
2192                         fi
2193                 done
2194                 if test "x$G_THREAD_LIBS" = xerror; then
2195                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2196                 fi
2197                 LIBS="$glib_save_LIBS"
2198                 ;;
2199             esac
2200           fi
2201
2202           glib_save_LIBS="$LIBS"
2203           for thread_lib in "" rt rte; do
2204             if test x"$thread_lib" = x; then
2205               add_thread_lib=""
2206               IN=""
2207             else
2208               add_thread_lib="-l$thread_lib"
2209               IN=" in -l$thread_lib"
2210             fi
2211             LIBS="$add_thread_lib $glib_save_LIBS"
2212
2213             AC_MSG_CHECKING(for sched_get_priority_min$IN)
2214             AC_TRY_RUN(glib_sched_priority_test,
2215                        glib_result=yes,
2216                        glib_result=no,
2217                        [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_sched_priority_test)],
2218                                        glib_result=yes,
2219                                        glib_result=no)])
2220             AC_MSG_RESULT($glib_result)
2221
2222             if test "$glib_result" = "yes" ; then
2223                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
2224                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
2225                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
2226                break
2227             fi
2228           done
2229           LIBS="$glib_save_LIBS"
2230           mutex_has_default=yes
2231           mutex_default_type='pthread_mutex_t'
2232           mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
2233           mutex_header_file='pthread.h'
2234           if test "x$have_threads" = "xposix"; then
2235             g_threads_impl="POSIX"
2236           else
2237             g_threads_impl="DCE"
2238             have_threads="posix"
2239           fi
2240           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2241           CPPFLAGS="$glib_save_CPPFLAGS"
2242           ;;
2243         win32)
2244            g_threads_impl="WIN32"
2245            ;;
2246         none|no)
2247            g_threads_impl="NONE"
2248            ;;
2249         *)
2250            g_threads_impl="NONE"
2251            G_THREAD_LIBS=error
2252            ;;
2253 esac
2254
2255 if test "x$G_THREAD_LIBS" = xerror; then
2256         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2257 fi
2258
2259 case $host in
2260   *-*-beos*)
2261     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2262     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2263     ;;
2264   *)
2265     ;;
2266 esac
2267
2268 AC_MSG_CHECKING(thread related libraries)
2269 AC_MSG_RESULT($G_THREAD_LIBS)
2270
2271 dnl check for mt safe function variants and some posix functions
2272 dnl ************************************************************
2273
2274 if test x"$have_threads" != xno; then
2275         glib_save_LIBS="$LIBS"
2276         # we are not doing the following for now, as this might require glib
2277         # to always be linked with the thread libs on some platforms.
2278         # LIBS="$LIBS $G_THREAD_LIBS"
2279         AC_CHECK_FUNCS(localtime_r gmtime_r)
2280         if test "$ac_cv_header_pwd_h" = "yes"; then
2281                 AC_CACHE_CHECK([for posix getpwuid_r],
2282                         ac_cv_func_posix_getpwuid_r,
2283                         [AC_TRY_RUN([
2284 #include <errno.h>
2285 #include <pwd.h>
2286 int main () {
2287     char buffer[10000];
2288     struct passwd pwd, *pwptr = &pwd;
2289     int error;
2290     errno = 0;
2291     error = getpwuid_r (0, &pwd, buffer,
2292                         sizeof (buffer), &pwptr);
2293    return (error < 0 && errno == ENOSYS)
2294            || error == ENOSYS;
2295 }                               ],
2296                                 [ac_cv_func_posix_getpwuid_r=yes],
2297                                 [ac_cv_func_posix_getpwuid_r=no])])
2298                 GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2299                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2300                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2301                                 [Have POSIX function getpwuid_r])
2302                 else
2303                         AC_CACHE_CHECK([for nonposix getpwuid_r],
2304                                 ac_cv_func_nonposix_getpwuid_r,
2305                                 [AC_TRY_LINK([#include <pwd.h>],
2306                                         [char buffer[10000];
2307                                         struct passwd pwd;
2308                                         getpwuid_r (0, &pwd, buffer,
2309                                                         sizeof (buffer));],
2310                                         [ac_cv_func_nonposix_getpwuid_r=yes],
2311                                         [ac_cv_func_nonposix_getpwuid_r=no])])
2312                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2313                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2314                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2315                                         [Have non-POSIX function getpwuid_r])
2316                         fi
2317                 fi
2318         fi
2319         if test "$ac_cv_header_grp_h" = "yes"; then
2320                 AC_CACHE_CHECK([for posix getgrgid_r],
2321                         ac_cv_func_posix_getgrgid_r,
2322                         [AC_TRY_RUN([
2323 #include <errno.h>
2324 #include <grp.h>
2325 int main () {
2326     char buffer[10000];
2327     struct group grp, *grpptr = &grp;
2328     int error;
2329     errno = 0;
2330     error = getgrgid_r (0, &grp, buffer,
2331                         sizeof (buffer), &grpptr);
2332    return (error < 0 && errno == ENOSYS)
2333            || error == ENOSYS;
2334 }                              ],
2335                                [ac_cv_func_posix_getgrgid_r=yes],
2336                                [ac_cv_func_posix_getgrgid_r=no])])
2337                 GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2338                 if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2339                         AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2340                                 [Have POSIX function getgrgid_r])
2341                 else
2342                         AC_CACHE_CHECK([for nonposix getgrgid_r],
2343                                 ac_cv_func_nonposix_getgrgid_r,
2344                                 [AC_TRY_LINK([#include <grp.h>],
2345                                         [char buffer[10000];
2346                                         struct group grp;
2347                                         getgrgid_r (0, &grp, buffer,
2348                                         sizeof (buffer));],
2349                                 [ac_cv_func_nonposix_getgrgid_r=yes],
2350                                 [ac_cv_func_nonposix_getgrgid_r=no])])
2351                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2352                         if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2353                                 AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2354                                         [Have non-POSIX function getgrgid_r])
2355                         fi
2356                 fi
2357         fi
2358         LIBS="$G_THREAD_LIBS $LIBS"
2359         if test x"$have_threads" = xposix; then
2360                 glib_save_CPPFLAGS="$CPPFLAGS"
2361                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2362                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
2363                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
2364                 # This is not AC_CHECK_FUNC to also work with function
2365                 # name mangling in header files.
2366                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
2367                 AC_TRY_LINK([#include <pthread.h>],
2368                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
2369                         [AC_MSG_RESULT(yes)
2370                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2371                                   [Have function pthread_attr_setstacksize])],
2372                         [AC_MSG_RESULT(no)])
2373                 AC_MSG_CHECKING(for minimal/maximal thread priority)
2374                 if test x"$posix_priority_min" = x; then
2375                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
2376                                 PX_PRIO_MIN],,[
2377                                 posix_priority_min=PX_PRIO_MIN
2378                                 posix_priority_max=PX_PRIO_MAX])
2379                 fi
2380                 if test x"$posix_priority_min" = x; then
2381                         # AIX
2382                         AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
2383                                 PTHREAD_PRIO_MIN],,[
2384                                 posix_priority_min=PTHREAD_PRIO_MIN
2385                                 posix_priority_max=PTHREAD_PRIO_MAX])
2386                 fi
2387                 if test x"$posix_priority_min" = x; then
2388                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
2389                                 PRI_OTHER_MIN],,[
2390                                 posix_priority_min=PRI_OTHER_MIN
2391                                 posix_priority_max=PRI_OTHER_MAX])
2392                 fi
2393                 if test x"$posix_priority_min" = x; then
2394                         AC_MSG_RESULT(none found)
2395                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
2396                         posix_priority_min=-1
2397                         posix_priority_max=-1
2398                 else
2399                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
2400                         AC_MSG_CHECKING(for pthread_setschedparam)
2401                         AC_TRY_LINK([#include <pthread.h>],
2402                           [pthread_t t; pthread_setschedparam(t, 0, NULL)],
2403                           [AC_MSG_RESULT(yes)
2404                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
2405                            AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
2406                           [AC_MSG_RESULT(no)
2407                            AC_MSG_WARN($POSIX_NO_PRIORITIES)])
2408                 fi
2409                 posix_yield_func=none
2410                 AC_MSG_CHECKING(for posix yield function)
2411                 for yield_func in sched_yield pthread_yield_np pthread_yield \
2412                                                         thr_yield; do
2413                         AC_TRY_LINK([#include <pthread.h>],
2414                                 [$yield_func()],
2415                                 [posix_yield_func="$yield_func"
2416                                 break])
2417                 done
2418                 if test x"$posix_yield_func" = xnone; then
2419                         AC_MSG_RESULT(none found)
2420                         AC_MSG_WARN($POSIX_NO_YIELD)
2421                         posix_yield_func="g_usleep(1000)"
2422                 else
2423                         AC_MSG_RESULT($posix_yield_func)
2424                         posix_yield_func="$posix_yield_func()"
2425                 fi
2426                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
2427                 CPPFLAGS="$glib_save_CPPFLAGS"
2428
2429         elif test x"$have_threads" = xwin32; then
2430                 # It's a pointer to a private struct
2431                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
2432         fi
2433
2434         LIBS="$glib_save_LIBS"
2435
2436         # now spit out all the warnings.
2437         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2438            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2439                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2440         fi
2441         if test "$ac_cv_func_localtime_r" != "yes"; then
2442                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2443         fi
2444 fi
2445
2446 if test x"$glib_cv_sizeof_system_thread" = x; then
2447    # use a pointer as a fallback.
2448    GLIB_SIZEOF(,void *, system_thread)
2449 fi
2450
2451 #
2452 # Hack to deal with:
2453 #
2454 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2455 #     building shared libraries with linux.
2456 #  b) FreeBSD doesn't do this either.
2457 #
2458 case $host in
2459   *-*-freebsd*|*-*-linux*)
2460     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2461     ;;
2462   *)
2463     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2464     ;;
2465 esac
2466
2467 AM_CONDITIONAL(HAVE_THREADS, [test "$have_threads" != "none"])
2468 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
2469                    [Source file containing theread implementation])
2470 AC_SUBST(G_THREAD_CFLAGS)
2471 AC_SUBST(G_THREAD_LIBS)
2472 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2473 AC_SUBST(G_THREAD_LIBS_EXTRA)
2474
2475 dnl **********************************************
2476 dnl *** GDefaultMutex setup and initialization ***
2477 dnl **********************************************
2478 dnl
2479 dnl if mutex_has_default = yes, we also got
2480 dnl mutex_default_type, mutex_default_init and mutex_header_file
2481 if test $mutex_has_default = yes ; then
2482         glib_save_CPPFLAGS="$CPPFLAGS"
2483         glib_save_LIBS="$LIBS"
2484         LIBS="$G_THREAD_LIBS $LIBS"
2485         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2486         GLIB_SIZEOF([#include <$mutex_header_file>],
2487                     $mutex_default_type,
2488                     gmutex)
2489         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
2490                            $mutex_default_type,
2491                            gmutex,
2492                            $glib_cv_sizeof_gmutex,
2493                            $mutex_default_init)
2494         if test x"$glib_cv_byte_contents_gmutex" = xno; then
2495                 mutex_has_default=no
2496         fi
2497         CPPFLAGS="$glib_save_CPPFLAGS"
2498         LIBS="$glib_save_LIBS"
2499 fi
2500
2501 AC_CHECK_FUNCS(clock_gettime, [], [
2502   AC_CHECK_LIB(rt, clock_gettime, [
2503     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2504     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2505     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2506     GLIB_RT_LIBS="-lrt"
2507   ])
2508 ])
2509 AC_SUBST(GLIB_RT_LIBS)
2510
2511 AC_CACHE_CHECK(for monotonic clocks,
2512     glib_cv_monotonic_clock,AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
2513 #include <time.h>
2514 #include <unistd.h>
2515 int main() {
2516 #if !(defined(_POSIX_MONOTONIC_CLOCK) && _POSIX_MONOTONIC_CLOCK >= 0 && defined(CLOCK_MONOTONIC))
2517         #error No monotonic clock
2518 #endif
2519         return 0;
2520 }
2521 ]])],glib_cv_monotonic_clock=yes,glib_cv_monotonic_clock=no))
2522 if test "$glib_cv_monotonic_clock" = "yes"; then
2523   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
2524 fi
2525
2526
2527 dnl ************************
2528 dnl *** g_atomic_* tests ***
2529 dnl ************************
2530
2531 AC_MSG_CHECKING([whether to use assembler code for atomic operations])
2532     case $host_cpu in
2533       i386)
2534         AC_MSG_RESULT([none])
2535         glib_memory_barrier_needed=no
2536         ;;
2537       i?86)
2538         AC_MSG_RESULT([i486])
2539         AC_DEFINE_UNQUOTED(G_ATOMIC_I486, 1,
2540                            [i486 atomic implementation])
2541         glib_memory_barrier_needed=no
2542         ;;
2543       sparc*)
2544         SPARCV9_WARNING="Try to rerun configure with CFLAGS='-mcpu=v9',
2545                          when you are using a sparc with v9 instruction set (most
2546                          sparcs nowadays). This will make the code for atomic
2547                          operations much faster. The resulting code will not run
2548                          on very old sparcs though."
2549
2550         AC_LINK_IFELSE([AC_LANG_SOURCE([[
2551           main ()
2552           {
2553             int tmp1, tmp2, tmp3;
2554             __asm__ __volatile__("casx [%2], %0, %1"
2555                                  : "=&r" (tmp1), "=&r" (tmp2) : "r" (&tmp3));
2556           }]])],
2557           AC_MSG_RESULT([sparcv9])
2558           AC_DEFINE_UNQUOTED(G_ATOMIC_SPARCV9, 1,
2559                              [sparcv9 atomic implementation]),
2560           AC_MSG_RESULT([no])
2561           AC_MSG_WARN([[$SPARCV9_WARNING]]))
2562         glib_memory_barrier_needed=yes
2563         ;;
2564       alpha*)
2565         AC_MSG_RESULT([alpha])
2566         AC_DEFINE_UNQUOTED(G_ATOMIC_ALPHA, 1,
2567                            [alpha atomic implementation])
2568         glib_memory_barrier_needed=yes
2569         ;;
2570       x86_64)
2571         AC_MSG_RESULT([x86_64])
2572         AC_DEFINE_UNQUOTED(G_ATOMIC_X86_64, 1,
2573                            [x86_64 atomic implementation])
2574         glib_memory_barrier_needed=no
2575        ;;
2576       powerpc*)
2577         AC_MSG_RESULT([powerpc])
2578         AC_DEFINE_UNQUOTED(G_ATOMIC_POWERPC, 1,
2579                            [powerpc atomic implementation])
2580         glib_memory_barrier_needed=yes
2581         AC_MSG_CHECKING([whether asm supports numbered local labels])
2582         AC_TRY_COMPILE(
2583                        ,[
2584                        __asm__ __volatile__ ("1:       nop\n"
2585                                "         bne-    1b")
2586                        ],[
2587                        AC_DEFINE_UNQUOTED(ASM_NUMERIC_LABELS, 1, [define if asm blocks can use numeric local labels])
2588                        AC_MSG_RESULT([yes])
2589                        ],[
2590                        AC_MSG_RESULT([no])
2591                        ])
2592         ;;
2593       ia64)
2594         AC_MSG_RESULT([ia64])
2595         AC_DEFINE_UNQUOTED(G_ATOMIC_IA64, 1,
2596                            [ia64 atomic implementation])
2597         glib_memory_barrier_needed=yes
2598         ;;
2599       s390|s390x)
2600         AC_MSG_RESULT([s390])
2601         AC_DEFINE_UNQUOTED(G_ATOMIC_S390, 1,
2602                            [s390 atomic implementation])
2603         glib_memory_barrier_needed=no
2604         ;;
2605       arm*)
2606         AC_MSG_RESULT([arm])
2607         AC_DEFINE_UNQUOTED(G_ATOMIC_ARM, 1,
2608                            [arm atomic implementation])
2609         glib_memory_barrier_needed=no
2610         ;;
2611       crisv32*|etraxfs*)
2612         AC_MSG_RESULT([crisv32])
2613         AC_DEFINE_UNQUOTED(G_ATOMIC_CRISV32, 1,
2614                            [crisv32 atomic implementation])
2615         glib_memory_barrier_needed=no
2616         ;;
2617       cris*|etrax*)
2618         AC_MSG_RESULT([cris])
2619         AC_DEFINE_UNQUOTED(G_ATOMIC_CRIS, 1,
2620                            [cris atomic implementation])
2621         glib_memory_barrier_needed=no
2622         ;;
2623       *)
2624         AC_MSG_RESULT([none])
2625         glib_memory_barrier_needed=yes
2626         ;;
2627     esac
2628
2629 glib_cv_gcc_has_builtin_atomic_operations=no
2630 if test x"$GCC" = xyes; then
2631   AC_MSG_CHECKING([whether GCC supports built-in atomic intrinsics])
2632   AC_TRY_LINK([],
2633               [int i;
2634                __sync_synchronize ();
2635                __sync_bool_compare_and_swap (&i, 0, 1);
2636                __sync_fetch_and_add (&i, 1);
2637               ],
2638               [glib_cv_gcc_has_builtin_atomic_operations=yes],
2639               [glib_cv_gcc_has_builtin_atomic_operations=no])
2640
2641   AC_MSG_RESULT($glib_cv_gcc_has_builtin_atomic_operations)
2642 fi
2643 AM_CONDITIONAL(HAVE_GCC_BUILTINS_FOR_ATOMIC_OPERATIONS,
2644                [test $glib_cv_gcc_has_builtin_atomic_operations = yes])
2645
2646 AC_MSG_CHECKING([for Win32 atomic intrinsics])
2647 glib_cv_has_win32_atomic_operations=no
2648 AC_TRY_LINK([],
2649         [int i; _InterlockedExchangeAdd (&i, 0);],
2650         [glib_cv_has_win32_atomic_operations=yes],
2651         [glib_cv_has_win32_atomic_operations=no])
2652 AC_MSG_RESULT($glib_cv_has_win32_atomic_operations)
2653 if test "x$glib_cv_has_win32_atomic_operations" = xyes; then
2654         AC_DEFINE(HAVE_WIN32_BUILTINS_FOR_ATOMIC_OPERATIONS,1,[Have Win32 atomic intrinsics])
2655 fi
2656
2657 dnl ************************
2658 dnl ** Check for futex(2) **
2659 dnl ************************
2660 AC_CACHE_CHECK(for futex(2) system call,
2661     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2662 #include <linux/futex.h>
2663 #include <sys/syscall.h>
2664 #include <unistd.h>
2665 ],[
2666 int
2667 main (void)
2668 {
2669   /* it is not like this actually runs or anything... */
2670   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2671   return 0;
2672 }
2673 ])],glib_cv_futex=yes,glib_cv_futex=no))
2674 if test x"$glib_cv_futex" = xyes; then
2675   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2676 fi
2677
2678 AC_CACHE_CHECK(for eventfd(2) system call,
2679     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2680 #include <sys/eventfd.h>
2681 #include <unistd.h>
2682 ],[
2683 int
2684 main (void)
2685 {
2686   eventfd (0, EFD_CLOEXEC);
2687   return 0;
2688 }
2689 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2690 if test x"$glib_cv_eventfd" = x"yes"; then
2691   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2692 fi
2693 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2694
2695 dnl ****************************************
2696 dnl *** GLib POLL* compatibility defines ***
2697 dnl ****************************************
2698
2699 glib_poll_includes=["
2700 #include <sys/types.h>
2701 #include <sys/poll.h>
2702 "]
2703
2704 if test $ac_cv_header_sys_types_h = yes &&
2705    test $ac_cv_header_sys_poll_h = yes ; then
2706   glib_failed=false
2707   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2708   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2709   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2710   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2711   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2712   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2713   if $glib_failed ; then
2714     AC_MSG_ERROR([Could not determine values for POLL* constants])
2715   fi
2716 else
2717   glib_cv_value_POLLIN=1
2718   glib_cv_value_POLLOUT=4
2719   glib_cv_value_POLLPRI=2
2720   glib_cv_value_POLLERR=8
2721   glib_cv_value_POLLHUP=16
2722   glib_cv_value_POLLNVAL=32
2723 fi
2724
2725 AC_MSG_CHECKING([for broken poll])
2726 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2727         #include <stdlib.h>
2728         #include <fcntl.h>
2729         #include <poll.h>
2730         #ifdef HAVE_SYS_POLL_H
2731         #include <sys/poll.h>
2732         #endif
2733         int main(void) {
2734           struct pollfd fds[1];
2735           int fd;
2736           fd = open("/dev/null", 1);
2737           fds[0].fd = fd;
2738           fds[0].events = POLLIN;
2739           fds[0].revents = 0;
2740           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2741                 exit(1);  /* Does not work for devices -- fail */
2742           }
2743           exit(0);
2744         }]])],
2745   [broken_poll=no],
2746   [broken_poll=yes
2747    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2748   [broken_poll="no (cross compiling)"])
2749 AC_MSG_RESULT($broken_poll)
2750
2751 dnl *********************
2752 dnl *** GRegex checks ***
2753 dnl *********************
2754 PCRE_REQUIRED_VERSION=8.11
2755
2756 # Check if we should compile GRegex
2757 AC_ARG_ENABLE(regex, AC_HELP_STRING([--disable-regex],
2758               [disable the compilation of GRegex]),
2759 [case "${enableval}" in
2760   yes) enable_regex=true ;;
2761   no)  enable_regex=false ;;
2762   *) AC_MSG_ERROR(bad value ${enableval} for --enable-regex) ;;
2763 esac],
2764 [enable_regex=true])
2765
2766 AM_CONDITIONAL(ENABLE_REGEX, $enable_regex)
2767
2768 if test x$enable_regex = xtrue; then
2769   AC_DEFINE(ENABLE_REGEX, [], [include GRegex])
2770   # Check if we should use the internal or the system-supplied pcre
2771   AC_ARG_WITH(pcre,
2772              [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2773                              [specify whether to use the internal or the
2774                               system-supplied PCRE library])])
2775
2776   AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2777
2778   if test "x$with_pcre" = xsystem; then
2779     PKG_CHECK_MODULES(PCRE,
2780                       libpcre >= $PCRE_REQUIRED_VERSION)
2781     AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2782                    glib_save_CFLAGS="$CFLAGS"
2783                    glib_save_LIBS="$LIBS"
2784                    CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2785                    AC_TRY_RUN([#include <pcre.h>
2786                                int main () {
2787                                  int support;
2788                                  pcre_config (PCRE_CONFIG_UTF8, &support);
2789                                  if (!support)
2790                                    return 1;
2791                                  pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2792                                  if (!support)
2793                                    return 1;
2794                                  return 0;
2795                                }],
2796                    glib_cv_pcre_has_unicode=yes,
2797                    glib_cv_pcre_has_unicode=no,
2798                    glib_cv_pcre_has_unicode=yes)
2799                    CFLAGS="$glib_save_CFLAGS"
2800                    LIBS="$glib_save_LIBS"
2801         ])
2802     if test "$glib_cv_pcre_has_unicode" = "no"; then
2803       AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2804     fi
2805     AC_SUBST(PCRE_CFLAGS)
2806     AC_SUBST(PCRE_LIBS)
2807     AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2808     PCRE_REQUIRES=libpcre
2809     AC_SUBST(PCRE_REQUIRES)
2810   else
2811     # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2812     if test x"$GCC" = xyes; then
2813       AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2814       save_CFLAGS="$CFLAGS"
2815       CFLAGS="$CFLAGS -Wno-pointer-sign"
2816       AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2817                             AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2818       CFLAGS="$save_CFLAGS"
2819     fi
2820   fi
2821   AC_SUBST(PCRE_WARN_CFLAGS)
2822 else
2823   AM_CONDITIONAL(USE_SYSTEM_PCRE, false])
2824 fi
2825
2826 dnl **********************
2827 dnl *** Win32 API libs ***
2828 dnl **********************
2829
2830 case $host in
2831   *-*-cygwin*)
2832         G_LIBS_EXTRA="-luser32 -lkernel32"
2833     ;;
2834   *-*-mingw*)
2835         G_LIBS_EXTRA="-lws2_32 -lole32"
2836     ;;
2837   *)
2838         G_LIBS_EXTRA=""
2839     ;;
2840 esac
2841 AC_SUBST(G_LIBS_EXTRA)
2842
2843 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2844 dnl since we need it for g_iconv()
2845
2846 AC_MSG_CHECKING([for EILSEQ])
2847 AC_TRY_COMPILE([
2848 #include <errno.h>
2849 ],
2850 [
2851 int error = EILSEQ;
2852 ], have_eilseq=yes, have_eilseq=no);
2853 AC_MSG_RESULT($have_eilseq)
2854
2855 dnl ******************************************************************
2856 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2857 dnl *** glib-compile-schemas in PATH                               ***
2858 dnl ******************************************************************
2859
2860 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2861
2862 if test $cross_compiling = yes; then
2863   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2864   if test x$GLIB_GENMARSHAL = xno; then
2865     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2866   fi
2867
2868   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2869   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2870     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2871   fi
2872 fi
2873
2874 dnl **************************
2875 dnl *** Checks for gtk-doc ***
2876 dnl **************************
2877
2878 GTK_DOC_CHECK([1.15])
2879
2880 AC_ARG_ENABLE(man,
2881               [AC_HELP_STRING([--enable-man],
2882                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2883               enable_man=no)
2884
2885 if test "${enable_man}" != no; then
2886 dnl
2887 dnl Check for xsltproc
2888 dnl
2889 AC_PATH_PROG([XSLTPROC], [xsltproc])
2890   if test -z "$XSLTPROC"; then
2891     enable_man=no
2892   fi
2893
2894   dnl check for DocBook DTD and stylesheets in the local catalog.
2895   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2896      [DocBook XML DTD V4.1.2],,enable_man=no)
2897   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2898      [DocBook XSL Stylesheets],,enable_man=no)
2899 fi
2900
2901 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2902
2903 dnl
2904 dnl Tracing
2905 dnl
2906
2907 AC_ARG_ENABLE([dtrace],
2908              [AS_HELP_STRING([--enable-dtrace],
2909                               [Enable inclusion of dtrace trace support])])
2910 have_dtrace=no
2911 AC_MSG_CHECKING([whether to include dtrace tracing support])
2912 if test "x$enable_dtrace" != xno; then
2913   if test x$glib_have_carbon = xyes; then
2914     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2915   else
2916     AC_MSG_RESULT([yes])
2917     AC_CHECK_PROGS(DTRACE, dtrace)
2918     if test -z "$DTRACE"; then
2919       if test "x$enable_dtrace" = xyes; then
2920         AC_MSG_ERROR([dtrace not found])
2921       fi
2922     else
2923       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2924                       [if test "x$enable_dtrace" = xyes; then
2925                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2926                        fi])
2927     fi
2928   fi
2929 else
2930   AC_MSG_RESULT([no])
2931 fi
2932 if test "x$have_dtrace" = xyes; then
2933   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2934 fi
2935 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2936
2937 AC_MSG_CHECKING([whether to include systemtap tracing support])
2938 AC_ARG_ENABLE([systemtap],
2939              [AS_HELP_STRING([--enable-systemtap],
2940                               [Enable inclusion of systemtap trace support])])
2941 have_systemtap=no
2942 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2943   have_systemtap=yes
2944 fi
2945 AC_MSG_RESULT(${have_systemtap})
2946
2947 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2948
2949 AC_ARG_WITH([tapset-install-dir],
2950             [AS_HELP_STRING([--with-tapset-install-dir],
2951             [The absolute path where the systemtap tapsets will be installed])],
2952             [if test "x${withval}" = x; then
2953                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2954              else
2955                ABS_TAPSET_DIR="${withval}"
2956               fi],
2957             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2958 AC_SUBST(ABS_TAPSET_DIR)
2959
2960 dnl ************************************
2961 dnl *** Enable lcov coverage reports ***
2962 dnl ************************************
2963
2964 AC_ARG_ENABLE(gcov,
2965   AS_HELP_STRING([--enable-gcov],
2966                  [Enable gcov]),
2967   [use_gcov=$enableval], [use_gcov=no])
2968
2969 if test "x$use_gcov" = "xyes"; then
2970   dnl we need gcc:
2971   if test "$GCC" != "yes"; then
2972     AC_MSG_ERROR([GCC is required for --enable-gcov])
2973   fi
2974
2975   dnl Check if ccache is being used
2976   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2977   case `$SHTOOL path $CC` in
2978     *ccache*[)] gcc_ccache=yes;;
2979     *[)] gcc_ccache=no;;
2980   esac
2981
2982   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2983     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2984   fi
2985
2986   ltp_version_list="1.6 1.7 1.8 1.9"
2987   AC_CHECK_PROG(LTP, lcov, lcov)
2988   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2989
2990   if test "$LTP"; then
2991     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2992       glib_cv_ltp_version=invalid
2993       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2994       for ltp_check_version in $ltp_version_list; do
2995         if test "$ltp_version" = "$ltp_check_version"; then
2996           glib_cv_ltp_version="$ltp_check_version (ok)"
2997         fi
2998       done
2999     ])
3000   else
3001     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
3002     AC_MSG_ERROR([$ltp_msg])
3003   fi
3004
3005   case $glib_cv_ltp_version in
3006     ""|invalid[)]
3007       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
3008       AC_MSG_ERROR([$ltp_msg])
3009       LTP="exit 0;"
3010       ;;
3011   esac
3012
3013   if test -z "$LTP_GENHTML"; then
3014     AC_MSG_ERROR([Could not find genhtml from the LTP package])
3015   fi
3016
3017   AC_DEFINE(HAVE_GCOV, 1, [Whether you have gcov])
3018
3019   dnl Remove all optimization flags from CFLAGS
3020   changequote({,})
3021   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
3022   changequote([,])
3023
3024   dnl Add the special gcc flags
3025   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
3026   LDFLAGS="$LDFLAGS -lgcov"
3027 fi
3028
3029 dnl ******************************
3030 dnl *** output the whole stuff ***
3031 dnl ******************************
3032
3033 dnl this section will only be run if config.status is invoked with no
3034 dnl arguments, or with "glib/glibconfig.h" as an argument.
3035 AC_CONFIG_COMMANDS([glib/glibconfig.h],
3036 [
3037         outfile=glib/glibconfig.h-tmp
3038         cat > $outfile <<\_______EOF
3039 /* glibconfig.h
3040  *
3041  * This is a generated file.  Please modify 'configure.ac'
3042  */
3043
3044 #ifndef __G_LIBCONFIG_H__
3045 #define __G_LIBCONFIG_H__
3046
3047 #include <glib/gmacros.h>
3048
3049 _______EOF
3050
3051         if test x$glib_limits_h = xyes; then
3052           echo '#include <limits.h>' >> $outfile
3053         fi
3054         if test x$glib_float_h = xyes; then
3055           echo '#include <float.h>' >> $outfile
3056         fi
3057         if test x$glib_values_h = xyes; then
3058           echo '#include <values.h>' >> $outfile
3059         fi
3060         if test "$glib_header_alloca_h" = "yes"; then
3061           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
3062         fi
3063         if test x$glib_sys_poll_h = xyes; then
3064           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
3065         fi
3066         if test x$glib_included_printf != xyes; then
3067           echo "
3068 /* Specifies that GLib's g_print*() functions wrap the
3069  * system printf functions.  This is useful to know, for example,
3070  * when using glibc's register_printf_function().
3071  */" >> $outfile
3072           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
3073         fi
3074
3075         cat >> $outfile <<_______EOF
3076
3077 G_BEGIN_DECLS
3078
3079 #define G_MINFLOAT      $glib_mf
3080 #define G_MAXFLOAT      $glib_Mf
3081 #define G_MINDOUBLE     $glib_md
3082 #define G_MAXDOUBLE     $glib_Md
3083 #define G_MINSHORT      $glib_ms
3084 #define G_MAXSHORT      $glib_Ms
3085 #define G_MAXUSHORT     $glib_Mus
3086 #define G_MININT        $glib_mi
3087 #define G_MAXINT        $glib_Mi
3088 #define G_MAXUINT       $glib_Mui
3089 #define G_MINLONG       $glib_ml
3090 #define G_MAXLONG       $glib_Ml
3091 #define G_MAXULONG      $glib_Mul
3092
3093 _______EOF
3094
3095
3096         ### this should always be true in a modern C/C++ compiler
3097         cat >>$outfile <<_______EOF
3098 typedef signed char gint8;
3099 typedef unsigned char guint8;
3100 _______EOF
3101
3102
3103         if test -n "$gint16"; then
3104           cat >>$outfile <<_______EOF
3105 typedef signed $gint16 gint16;
3106 typedef unsigned $gint16 guint16;
3107 #define G_GINT16_MODIFIER $gint16_modifier
3108 #define G_GINT16_FORMAT $gint16_format
3109 #define G_GUINT16_FORMAT $guint16_format
3110 _______EOF
3111         fi
3112
3113
3114         if test -n "$gint32"; then
3115           cat >>$outfile <<_______EOF
3116 typedef signed $gint32 gint32;
3117 typedef unsigned $gint32 guint32;
3118 #define G_GINT32_MODIFIER $gint32_modifier
3119 #define G_GINT32_FORMAT $gint32_format
3120 #define G_GUINT32_FORMAT $guint32_format
3121 _______EOF
3122         fi
3123
3124         cat >>$outfile <<_______EOF
3125 #define G_HAVE_GINT64 1          /* deprecated, always true */
3126
3127 ${glib_extension}typedef signed $gint64 gint64;
3128 ${glib_extension}typedef unsigned $gint64 guint64;
3129
3130 #define G_GINT64_CONSTANT(val)  $gint64_constant
3131 #define G_GUINT64_CONSTANT(val) $guint64_constant
3132 _______EOF
3133
3134         if test x$gint64_format != x ; then
3135           cat >>$outfile <<_______EOF
3136 #define G_GINT64_MODIFIER $gint64_modifier
3137 #define G_GINT64_FORMAT $gint64_format
3138 #define G_GUINT64_FORMAT $guint64_format
3139 _______EOF
3140         else
3141           cat >>$outfile <<_______EOF
3142 #undef G_GINT64_MODIFIER
3143 #undef G_GINT64_FORMAT
3144 #undef G_GUINT64_FORMAT
3145 _______EOF
3146         fi
3147
3148         cat >>$outfile <<_______EOF
3149
3150 #define GLIB_SIZEOF_VOID_P $glib_void_p
3151 #define GLIB_SIZEOF_LONG   $glib_long
3152 #define GLIB_SIZEOF_SIZE_T $glib_size_t
3153
3154 _______EOF
3155
3156         cat >>$outfile <<_______EOF
3157 typedef signed $glib_size_type_define gssize;
3158 typedef unsigned $glib_size_type_define gsize;
3159 #define G_GSIZE_MODIFIER $gsize_modifier
3160 #define G_GSSIZE_FORMAT $gssize_format
3161 #define G_GSIZE_FORMAT $gsize_format
3162
3163 #define G_MAXSIZE       G_MAXU$glib_msize_type
3164 #define G_MINSSIZE      G_MIN$glib_msize_type
3165 #define G_MAXSSIZE      G_MAX$glib_msize_type
3166
3167 typedef gint64 goffset;
3168 #define G_MINOFFSET     G_MININT64
3169 #define G_MAXOFFSET     G_MAXINT64
3170
3171 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
3172 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
3173 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
3174
3175 _______EOF
3176
3177         if test -z "$glib_unknown_void_p"; then
3178           cat >>$outfile <<_______EOF
3179
3180 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
3181 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
3182
3183 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
3184 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
3185
3186 typedef signed $glib_intptr_type_define gintptr;
3187 typedef unsigned $glib_intptr_type_define guintptr;
3188
3189 #define G_GINTPTR_MODIFIER      $gintptr_modifier
3190 #define G_GINTPTR_FORMAT        $gintptr_format
3191 #define G_GUINTPTR_FORMAT       $guintptr_format
3192 _______EOF
3193         else
3194           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
3195         fi
3196
3197
3198
3199         cat >>$outfile <<_______EOF
3200 $glib_atexit
3201 $glib_memmove
3202 $glib_defines
3203 $glib_os
3204 $glib_static_compilation
3205
3206 $glib_vacopy
3207
3208 #ifdef  __cplusplus
3209 #define G_HAVE_INLINE   1
3210 #else   /* !__cplusplus */
3211 $glib_inline
3212 #endif  /* !__cplusplus */
3213
3214 #ifdef  __cplusplus
3215 #define G_CAN_INLINE    1
3216 _______EOF
3217
3218         if test x$g_can_inline = xyes ; then
3219                 cat >>$outfile <<_______EOF
3220 #else   /* !__cplusplus */
3221 #define G_CAN_INLINE    1
3222 _______EOF
3223         fi
3224
3225         cat >>$outfile <<_______EOF
3226 #endif
3227
3228 _______EOF
3229
3230         if test x$g_have_iso_c_varargs = xyes ; then
3231                 cat >>$outfile <<_______EOF
3232 #ifndef __cplusplus
3233 # define G_HAVE_ISO_VARARGS 1
3234 #endif
3235 _______EOF
3236         fi
3237         if test x$g_have_iso_cxx_varargs = xyes ; then
3238                 cat >>$outfile <<_______EOF
3239 #ifdef __cplusplus
3240 # define G_HAVE_ISO_VARARGS 1
3241 #endif
3242 _______EOF
3243         fi
3244         if test x$g_have_gnuc_varargs = xyes ; then
3245                 cat >>$outfile <<_______EOF
3246
3247 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3248  * is passed ISO vararg support is turned off, and there is no work
3249  * around to turn it on, so we unconditionally turn it off.
3250  */
3251 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3252 #  undef G_HAVE_ISO_VARARGS
3253 #endif
3254
3255 #define G_HAVE_GNUC_VARARGS 1
3256 _______EOF
3257         fi
3258
3259         case x$g_stack_grows in
3260         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3261         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3262         esac
3263
3264
3265         echo >>$outfile
3266         if test x$g_have_eilseq = xno; then
3267                 cat >>$outfile <<_______EOF
3268 #ifndef EILSEQ
3269 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3270  * The correspondence between this and the corresponding definition
3271  * in libiconv is essential.
3272  */
3273 #  define EILSEQ ENOENT
3274 #endif
3275 _______EOF
3276
3277         fi
3278
3279         if test x$g_have_gnuc_visibility = xyes; then
3280                 cat >>$outfile <<_______EOF
3281 #define G_HAVE_GNUC_VISIBILITY 1
3282 _______EOF
3283         fi
3284                 cat >>$outfile <<_______EOF
3285 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3286 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3287 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3288 #define G_GNUC_INTERNAL __hidden
3289 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3290 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3291 #else
3292 #define G_GNUC_INTERNAL
3293 #endif
3294 _______EOF
3295
3296
3297         echo >>$outfile
3298         if test x$g_mutex_has_default = xyes; then
3299                 cat >>$outfile <<_______EOF
3300 $g_enable_threads_def G_THREADS_ENABLED
3301 #define G_THREADS_IMPL_$g_threads_impl_def
3302 typedef struct _GStaticMutex GStaticMutex;
3303 struct _GStaticMutex
3304 {
3305   struct _GMutex *runtime_mutex;
3306   union {
3307     char   pad[[$g_mutex_sizeof]];
3308     double dummy_double;
3309     void  *dummy_pointer;
3310     long   dummy_long;
3311   } static_mutex;
3312 };
3313 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
3314 #define g_static_mutex_get_mutex(mutex) \\
3315   (g_thread_use_default_impl ? ((GMutex*)(gpointer) ((mutex)->static_mutex.pad)) : \\
3316    g_static_mutex_get_mutex_impl_shortcut (&((mutex)->runtime_mutex)))
3317 _______EOF
3318         else
3319                 cat >>$outfile <<_______EOF
3320 $g_enable_threads_def G_THREADS_ENABLED
3321 #define G_THREADS_IMPL_$g_threads_impl_def
3322 typedef struct _GMutex* GStaticMutex;
3323 #define G_STATIC_MUTEX_INIT NULL
3324 #define g_static_mutex_get_mutex(mutex) \\
3325   (g_static_mutex_get_mutex_impl_shortcut (mutex))
3326 _______EOF
3327         fi
3328
3329         cat >>$outfile <<_______EOF
3330 /* This represents a system thread as used by the implementation. An
3331  * alien implementaion, as loaded by g_thread_init can only count on
3332  * "sizeof (gpointer)" bytes to store their info. We however need more
3333  * for some of our native implementations. */
3334 typedef union _GSystemThread GSystemThread;
3335 union _GSystemThread
3336 {
3337   char   data[[$g_system_thread_sizeof]];
3338   double dummy_double;
3339   void  *dummy_pointer;
3340   long   dummy_long;
3341 };
3342 _______EOF
3343         if test x"$g_memory_barrier_needed" != xno; then
3344           echo >>$outfile
3345           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3346         fi
3347         if test x"$g_gcc_atomic_ops" != xno; then
3348           echo >>$outfile
3349           echo "#define G_ATOMIC_OP_USE_GCC_BUILTINS 1" >>$outfile
3350         fi
3351         echo >>$outfile
3352         g_bit_sizes="16 32 64"
3353         for bits in $g_bit_sizes; do
3354           cat >>$outfile <<_______EOF
3355 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3356 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3357 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3358 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3359 _______EOF
3360         done
3361
3362         cat >>$outfile <<_______EOF
3363 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3364 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3365 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3366 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3367 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3368 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3369 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3370 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3371 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3372 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3373 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3374 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3375 #define G_BYTE_ORDER $g_byte_order
3376
3377 #define GLIB_SYSDEF_POLLIN =$g_pollin
3378 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3379 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3380 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3381 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3382 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3383
3384 #define G_MODULE_SUFFIX "$g_module_suffix"
3385
3386 /* A GPid is an abstraction for a process "handle". It is *not* an
3387  * abstraction for a process identifier in general. GPid is used in
3388  * GLib only for descendant processes spawned with the g_spawn*
3389  * functions. On POSIX there is no "process handle" concept as such,
3390  * but on Windows a GPid is a handle to a process, a kind of pointer,
3391  * not a process identifier.
3392  */
3393 typedef $g_pid_type GPid;
3394
3395 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3396 #define GLIB_SYSDEF_AF_INET $g_af_inet
3397 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3398
3399 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3400 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3401 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3402
3403 G_END_DECLS
3404
3405 #endif /* GLIBCONFIG_H */
3406 _______EOF
3407
3408
3409         if cmp -s $outfile glib/glibconfig.h; then
3410           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3411           rm -f $outfile
3412         else
3413           mv $outfile glib/glibconfig.h
3414         fi
3415 ],[
3416
3417 # Note that if two cases are the same, case goes with the first one.
3418 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3419 # on variable expansion in case labels.  Look at the generated config.status
3420 # for a hint.
3421
3422 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3423   glib_header_alloca_h="$ac_cv_working_alloca_h"
3424 else
3425   glib_header_alloca_h="$ac_cv_header_alloca_h"
3426 fi
3427
3428 case xyes in
3429 x$ac_cv_header_float_h)
3430   glib_float_h=yes
3431   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3432   glib_md=DBL_MIN glib_Md=DBL_MAX
3433   ;;
3434 x$ac_cv_header_values_h)
3435   glib_values_h=yes
3436   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3437   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3438   ;;
3439 esac
3440
3441 case xyes in
3442 x$ac_cv_header_limits_h)
3443   glib_limits_h=yes
3444   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3445   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3446   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3447   ;;
3448 x$ac_cv_header_values_h)
3449   glib_values_h=yes
3450   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3451   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3452   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3453   ;;
3454 esac
3455
3456 if test x$ac_cv_header_sys_poll_h = xyes ; then
3457   glib_sys_poll_h=yes
3458 fi
3459
3460 if test x$enable_included_printf = xyes ; then
3461   glib_included_printf=yes
3462 fi
3463
3464 case 2 in
3465 $ac_cv_sizeof_short)
3466   gint16=short
3467   gint16_modifier='"h"'
3468   gint16_format='"hi"'
3469   guint16_format='"hu"'
3470   ;;
3471 $ac_cv_sizeof_int)
3472   gint16=int
3473   gint16_modifier='""'
3474   gint16_format='"i"'
3475   guint16_format='"u"'
3476   ;;
3477 esac
3478 case 4 in
3479 $ac_cv_sizeof_short)
3480   gint32=short
3481   gint32_modifier='"h"'
3482   gint32_format='"hi"'
3483   guint32_format='"hu"'
3484   ;;
3485 $ac_cv_sizeof_int)
3486   gint32=int
3487   gint32_modifier='""'
3488   gint32_format='"i"'
3489   guint32_format='"u"'
3490   ;;
3491 $ac_cv_sizeof_long)
3492   gint32=long
3493   gint32_modifier='"l"'
3494   gint32_format='"li"'
3495   guint32_format='"lu"'
3496   ;;
3497 esac
3498 case 8 in
3499 $ac_cv_sizeof_int)
3500   gint64=int
3501   gint64_modifier='""'
3502   gint64_format='"i"'
3503   guint64_format='"u"'
3504   glib_extension=
3505   gint64_constant='(val)'
3506   guint64_constant='(val)'
3507   ;;
3508 $ac_cv_sizeof_long)
3509   gint64=long
3510   gint64_modifier='"l"'
3511   gint64_format='"li"'
3512   guint64_format='"lu"'
3513   glib_extension=
3514   gint64_constant='(val##L)'
3515   guint64_constant='(val##UL)'
3516   ;;
3517 $ac_cv_sizeof_long_long)
3518   gint64='long long'
3519   if test -n "$glib_cv_long_long_format"; then
3520     gint64_modifier='"'$glib_cv_long_long_format'"'
3521     gint64_format='"'$glib_cv_long_long_format'i"'
3522     guint64_format='"'$glib_cv_long_long_format'u"'
3523   fi
3524   glib_extension='G_GNUC_EXTENSION '
3525   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3526   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3527   ;;
3528 $ac_cv_sizeof___int64)
3529   gint64='__int64'
3530   if test -n "$glib_cv_long_long_format"; then
3531     gint64_modifier='"'$glib_cv_long_long_format'"'
3532     gint64_format='"'$glib_cv_long_long_format'i"'
3533     guint64_format='"'$glib_cv_long_long_format'u"'
3534   fi
3535   glib_extension=
3536   gint64_constant='(val##i64)'
3537   guint64_constant='(val##ui64)'
3538   ;;
3539 esac
3540 glib_size_t=$ac_cv_sizeof_size_t
3541 glib_size_type_define="$glib_size_type"
3542 glib_void_p=$ac_cv_sizeof_void_p
3543 glib_long=$ac_cv_sizeof_long
3544
3545 case "$glib_size_type" in
3546 short)
3547   gsize_modifier='"h"'
3548   gsize_format='"hu"'
3549   gssize_format='"hi"'
3550   glib_msize_type='SHRT'
3551   ;;
3552 int)
3553   gsize_modifier='""'
3554   gsize_format='"u"'
3555   gssize_format='"i"'
3556   glib_msize_type='INT'
3557   ;;
3558 long)
3559   gsize_modifier='"l"'
3560   gsize_format='"lu"'
3561   gssize_format='"li"'
3562   glib_msize_type='LONG'
3563   ;;
3564 "long long"|__int64)
3565   gsize_modifier='"I64"'
3566   gsize_format='"I64u"'
3567   gssize_format='"I64i"'
3568   glib_msize_type='INT64'
3569   ;;
3570 esac
3571
3572 gintbits=`expr $ac_cv_sizeof_int \* 8`
3573 glongbits=`expr $ac_cv_sizeof_long \* 8`
3574 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3575
3576 case $ac_cv_sizeof_void_p in
3577 $ac_cv_sizeof_int)
3578   glib_intptr_type_define=int
3579   gintptr_modifier='""'
3580   gintptr_format='"i"'
3581   guintptr_format='"u"'
3582   glib_gpi_cast=''
3583   glib_gpui_cast=''
3584   ;;
3585 $ac_cv_sizeof_long)
3586   glib_intptr_type_define=long
3587   gintptr_modifier='"l"'
3588   gintptr_format='"li"'
3589   guintptr_format='"lu"'
3590   glib_gpi_cast='(glong)'
3591   glib_gpui_cast='(gulong)'
3592   ;;
3593 $ac_cv_sizeof_long_long)
3594   glib_intptr_type_define='long long'
3595   gintptr_modifier='"I64"'
3596   gintptr_format='"I64i"'
3597   guintptr_format='"I64u"'
3598   glib_gpi_cast='(gint64)'
3599   glib_gpui_cast='(guint64)'
3600   ;;
3601 $ac_cv_sizeof___int64)
3602   glib_intptr_type_define=__int64
3603   gintptr_modifier='"I64"'
3604   gintptr_format='"I64i"'
3605   guintptr_format='"I64u"'
3606   glib_gpi_cast='(gint64)'
3607   glib_gpui_cast='(guint64)'
3608   ;;
3609 *)
3610   glib_unknown_void_p=yes
3611   ;;
3612 esac
3613
3614
3615 case xyes in
3616 x$ac_cv_func_atexit)
3617   glib_atexit="
3618 #ifdef NeXT /* @#%@! NeXTStep */
3619 # define g_ATEXIT(proc) (!atexit (proc))
3620 #else
3621 # define g_ATEXIT(proc) (atexit (proc))
3622 #endif"
3623   ;;
3624 x$ac_cv_func_on_exit)
3625   glib_atexit="
3626 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3627   ;;
3628 esac
3629
3630 case xyes in
3631 x$ac_cv_func_memmove)
3632   glib_memmove='
3633 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3634   ;;
3635 x$glib_cv_working_bcopy)
3636   glib_memmove="
3637 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3638 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3639   ;;
3640 *)
3641   glib_memmove="
3642 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3643  * so we have to roll our own copy routine. */
3644 void g_memmove (void* dest, const void * src, unsigned long len);"
3645   ;;
3646 esac
3647
3648 glib_defines="
3649 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3650 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3651 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3652 "
3653
3654 case xyes in
3655 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3656 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3657 *)                      glib_vacopy=''
3658 esac
3659
3660 if test x$glib_cv_va_val_copy = xno; then
3661   glib_vacopy="\$glib_vacopy
3662 #define G_VA_COPY_AS_ARRAY 1"
3663 fi
3664
3665 if test x$glib_cv_hasinline = xyes; then
3666     glib_inline='#define G_HAVE_INLINE 1'
3667 fi
3668 if test x$glib_cv_has__inline = xyes; then
3669     glib_inline="\$glib_inline
3670 #define G_HAVE___INLINE 1"
3671 fi
3672 if test x$glib_cv_has__inline__ = xyes; then
3673     glib_inline="\$glib_inline
3674 #define G_HAVE___INLINE__ 1"
3675 fi
3676
3677 g_have_gnuc_varargs=$g_have_gnuc_varargs
3678 g_have_iso_c_varargs=$g_have_iso_c_varargs
3679 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3680
3681 g_can_inline=$g_can_inline
3682 g_have_gnuc_visibility=$g_have_gnuc_visibility
3683 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3684
3685 if test x$ac_cv_c_bigendian = xyes; then
3686   g_byte_order=G_BIG_ENDIAN
3687   g_bs_native=BE
3688   g_bs_alien=LE
3689 else
3690   g_byte_order=G_LITTLE_ENDIAN
3691   g_bs_native=LE
3692   g_bs_alien=BE
3693 fi
3694
3695 g_pollin=$glib_cv_value_POLLIN
3696 g_pollout=$glib_cv_value_POLLOUT
3697 g_pollpri=$glib_cv_value_POLLPRI
3698 g_pollhup=$glib_cv_value_POLLHUP
3699 g_pollerr=$glib_cv_value_POLLERR
3700 g_pollnval=$glib_cv_value_POLLNVAL
3701
3702 g_af_unix=$glib_cv_value_AF_UNIX
3703 g_af_inet=$glib_cv_value_AF_INET
3704 g_af_inet6=$glib_cv_value_AF_INET6
3705
3706 g_msg_peek=$glib_cv_value_MSG_PEEK
3707 g_msg_oob=$glib_cv_value_MSG_OOB
3708 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3709
3710 g_stack_grows=$glib_cv_stack_grows
3711
3712 g_have_eilseq=$have_eilseq
3713
3714 case x$have_threads in
3715 xno)    g_enable_threads_def="#undef";;
3716 *)      g_enable_threads_def="#define";;
3717 esac
3718
3719 g_threads_impl_def=$g_threads_impl
3720
3721 g_mutex_has_default="$mutex_has_default"
3722 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
3723 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
3724 g_mutex_contents="$glib_cv_byte_contents_gmutex"
3725
3726 g_memory_barrier_needed="$glib_memory_barrier_needed"
3727 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3728
3729 g_module_suffix="$glib_gmodule_suffix"
3730
3731 g_pid_type="$glib_pid_type"
3732 case $host in
3733   *-*-beos*)
3734     glib_os="#define G_OS_BEOS"
3735     ;;
3736   *-*-cygwin*)
3737     glib_os="#define G_OS_UNIX
3738 #define G_PLATFORM_WIN32
3739 #define G_WITH_CYGWIN"
3740     ;;
3741   *-*-mingw*)
3742     glib_os="#define G_OS_WIN32
3743 #define G_PLATFORM_WIN32"
3744     ;;
3745   *)
3746     glib_os="#define G_OS_UNIX"
3747     ;;
3748 esac
3749 glib_static_compilation=""
3750 if test x$glib_win32_static_compilation = xyes; then
3751   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3752 #define GOBJECT_STATIC_COMPILATION 1"
3753 fi
3754 ])
3755
3756 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3757 #
3758 # 1.2.14 required for dbus_message_set_serial
3759 PKG_CHECK_MODULES(DBUS1,
3760                   dbus-1 >= 1.2.14,
3761                   [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3762                   have_dbus1=no)
3763 AC_SUBST(DBUS1_CFLAGS)
3764 AC_SUBST(DBUS1_LIBS)
3765 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3766
3767 dnl
3768 dnl Check for -Bsymbolic-functions linker flag used to avoid
3769 dnl intra-library PLT jumps, if available.
3770 dnl
3771
3772 AC_ARG_ENABLE(Bsymbolic,
3773               [AC_HELP_STRING([--disable-Bsymbolic],
3774                               [avoid linking with -Bsymbolic])],,
3775               [SAVED_LDFLAGS="${LDFLAGS}"
3776                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3777                LDFLAGS=-Wl,-Bsymbolic-functions
3778                AC_TRY_LINK([], [int main (void) { return 0; }],
3779                            AC_MSG_RESULT(yes)
3780                            enable_Bsymbolic=yes,
3781                            AC_MSG_RESULT(no)
3782                            enable_Bsymbolic=no)
3783                LDFLAGS="${SAVED_LDFLAGS}"])
3784
3785 if test "x${enable_Bsymbolic}" == "xyes"; then
3786   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3787 fi
3788
3789 AC_SUBST(GLIB_LINK_FLAGS)
3790
3791 #
3792 # Define variables corresponding to the correct include paths to use for
3793 # in-tree building.
3794 #
3795
3796 # for config.h:
3797 config_h_INCLUDES='-I$(top_builddir)'
3798 AC_SUBST(config_h_INCLUDES)
3799
3800 # glib:
3801 #   config.h
3802 #   $(top_builddir)/glib: for glibconfig.h
3803 #   $(top_srcdir)/glib:   for glib.h
3804 #   $(top_srcdir):        for everything
3805 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3806 AC_SUBST(glib_INCLUDES)
3807
3808 # gthread:
3809 #   same as glib
3810 gthread_INCLUDES='$(glib_INCLUDES)'
3811 AC_SUBST(gthread_INCLUDES)
3812
3813 # gobject:
3814 #   same as gthread
3815 gobject_INCLUDES='$(gthread_INCLUDES)'
3816 AC_SUBST(gobject_INCLUDES)
3817
3818 # gmodule:
3819 #   glib includes
3820 #   $(top_srcdir)/gmodule: for gmodule.h
3821 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3822 AC_SUBST(gmodule_INCLUDES)
3823
3824 # gio:
3825 #   same as gmodule
3826 gio_INCLUDES='$(gmodule_INCLUDES)'
3827 AC_SUBST(gio_INCLUDES)
3828
3829
3830 AC_CONFIG_FILES([
3831 glib-2.0.pc
3832 glib-2.0-uninstalled.pc
3833 gmodule-2.0.pc
3834 gmodule-export-2.0.pc
3835 gmodule-no-export-2.0.pc
3836 gmodule-2.0-uninstalled.pc
3837 gmodule-no-export-2.0-uninstalled.pc
3838 gthread-2.0.pc
3839 gthread-2.0-uninstalled.pc
3840 gobject-2.0.pc
3841 gobject-2.0-uninstalled.pc
3842 gio-2.0.pc
3843 gio-unix-2.0.pc
3844 gio-windows-2.0.pc
3845 gio-2.0-uninstalled.pc
3846 gio-unix-2.0-uninstalled.pc
3847 glib-zip
3848 glib-gettextize
3849 Makefile
3850 build/Makefile
3851 build/win32/Makefile
3852 build/win32/dirent/Makefile
3853 build/win32/vs9/Makefile
3854 build/win32/vs10/Makefile
3855 glib/Makefile
3856 glib/glib.stp
3857 glib/libcharset/Makefile
3858 glib/gnulib/Makefile
3859 glib/pcre/Makefile
3860 glib/update-pcre/Makefile
3861 glib/tests/Makefile
3862 gmodule/Makefile
3863 gmodule/gmoduleconf.h
3864 gobject/Makefile
3865 gobject/gobject.stp
3866 gobject/glib-mkenums
3867 gobject/tests/Makefile
3868 gthread/Makefile
3869 gthread/tests/Makefile
3870 gio/Makefile
3871 gio/gdbus-2.0/codegen/Makefile
3872 gio/gdbus-2.0/codegen/config.py
3873 gio/xdgmime/Makefile
3874 gio/inotify/Makefile
3875 gio/libasyncns/Makefile
3876 gio/fen/Makefile
3877 gio/fam/Makefile
3878 gio/win32/Makefile
3879 gio/tests/Makefile
3880 gio/tests/gdbus-object-manager-example/Makefile
3881 po/Makefile.in
3882 docs/Makefile
3883 docs/reference/Makefile
3884 docs/reference/glib/Makefile
3885 docs/reference/glib/version.xml
3886 docs/reference/gobject/Makefile
3887 docs/reference/gobject/version.xml
3888 docs/reference/gio/Makefile
3889 docs/reference/gio/gdbus-object-manager-example/Makefile
3890 docs/reference/gio/version.xml
3891 tests/Makefile
3892 tests/gobject/Makefile
3893 tests/refcount/Makefile
3894 m4macros/Makefile
3895 ])
3896
3897 AC_CONFIG_COMMANDS([chmod-scripts],
3898 [chmod 0755 glib-zip
3899 chmod 0755 glib-gettextize
3900 chmod 0755 gobject/glib-mkenums])
3901
3902 # we want to invoke this macro solely so that the config.status script
3903 # and automake generated makefiles know about these generated files.
3904 # They are only needed to distcheck the package
3905 if false; then
3906   AC_CONFIG_FILES([
3907     INSTALL
3908     README
3909     config.h.win32
3910     glib/glibconfig.h.win32
3911     glib/makefile.msc
3912     glib/glib.rc
3913     gmodule/makefile.msc
3914     gmodule/gmodule.rc
3915     gobject/makefile.msc
3916     gobject/gobject.rc
3917     gthread/makefile.msc
3918     gthread/gthread.rc
3919     gio/gio.rc
3920     tests/makefile.msc
3921   ])
3922 fi
3923
3924 AC_OUTPUT