configure.ac

   1 AC_PREREQ(2.69)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer libav, 1.13.90,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gst-libav)
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([ext/libav/gstav.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output by default
  34 AM_SILENT_RULES([yes])
  35
  36 dnl our libraries and install dirs use major.minor as a version
  37 GST_API_VERSION=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  38 dnl we override it here if we need to for the release candidate of new series
  39 GST_API_VERSION=1.0
  40 AC_SUBST(GST_API_VERSION)
  41
  42 dnl *** Check for external $AS vs detected by AS_LIBTOOL
  43 user_AS="$AS"
  44 AG_GST_LIBTOOL_PREPARE
  45 AS_LIBTOOL(GST, 1390, 0, 1390)
  46
  47 dnl *** required versions of GStreamer stuff ***
  48 GST_REQ=1.13.90
  49 GST_PBREQ=1.13.90
  50
  51 ORC_REQ=0.4.16
  52 ORC_CHECK([$ORC_REQ])
  53
  54 dnl *** autotools stuff ****
  55
  56 dnl allow for different autotools
  57 AS_AUTOTOOLS_ALTERNATE
  58
  59 dnl Add parameters for aclocal
  60 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  61
  62 dnl *** check for arguments to configure ***
  63
  64 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  65 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  66
  67 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  68 AG_GST_ARG_WITH_PACKAGE_NAME
  69 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  70 AG_GST_ARG_VALGRIND
  71 AG_GST_ARG_GCOV
  72
  73 dnl *** checks for platform ***
  74
  75 dnl * hardware/architecture *
  76
  77 dnl common/m4/gst-arch.m4
  78 dnl check CPU type
  79 AG_GST_ARCH
  80
  81 dnl *** checks for programs ***
  82
  83 dnl find a compiler
  84 AC_PROG_CC
  85 AC_PROG_CC_STDC
  86
  87 dnl check if the compiler supports '-c' and '-o' options
  88 AM_PROG_CC_C_O
  89
  90 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
  91 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
  92
  93 dnl check for documentation tools
  94 GTK_DOC_CHECK([1.12])
  95 AG_GST_PLUGIN_DOCS([1.12])
  96
  97 dnl *** checks for libraries ***
  98
  99 dnl check for libm, for sin()
 100 LT_LIB_M
 101 AC_SUBST(LIBM)
 102
 103 dnl check for pthreads
 104 AX_PTHREAD
 105
 106 dnl *** checks for header files ***
 107
 108 dnl check if we have ANSI C header files
 109 AC_HEADER_STDC
 110
 111 dnl *** checks for types/defines ***
 112
 113 dnl *** checks for structures ***
 114
 115 dnl *** checks for compiler characteristics ***
 116
 117 dnl *** checks for library functions ***
 118
 119 dnl *** checks for dependancy libraries ***
 120
 121 dnl GLib is required
 122 GLIB_REQ=2.40.0
 123 AC_SUBST([GLIB_REQ])
 124 AG_GST_GLIB_CHECK([$GLIB_REQ])
 125
 126 dnl checks for gstreamer
 127 dnl uninstalled is selected preferentially -- see pkg-config(1)
 128 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ])
 129 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ])
 130 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GST_PBREQ])
 131 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 132 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 133
 134 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 135 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 136
 137 dnl Check for -Bsymbolic-functions linker flag used to avoid
 138 dnl intra-library PLT jumps, if available.
 139 AC_ARG_ENABLE(Bsymbolic,
 140               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 141               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 142                AC_MSG_CHECKING([for -Bsymbolic linker flag])
 143                LDFLAGS=-Wl,-Bsymbolic
 144                LIBS=
 145                AC_TRY_LINK([], [return 0],
 146                            AC_MSG_RESULT(yes)
 147                            enable_Bsymbolic=yes,
 148                            AC_MSG_RESULT(no)
 149                            enable_Bsymbolic=no)
 150                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 151
 152 dnl *** set variables based on configure arguments ***
 153
 154 dnl set location of plugin directory
 155 AG_GST_SET_PLUGINDIR
 156
 157 dnl Detect if we are building static plugins, in which case we need to
 158 dnl generates libav .la files and install the static libraries.
 159 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static" = "xyes")
 160
 161 dnl define an ERROR_CFLAGS Makefile variable
 162 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 163     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 164     -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition
 165     -Winit-self -Wmissing-include-dirs -Waddress
 166     -Waggregate-return -Wno-multichar -Wnested-externs ])
 167
 168 dnl define correct level for debugging messages
 169 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 170
 171 dnl disable strict aliasing
 172 AS_COMPILER_FLAG([-fno-strict-aliasing], [EXTRA_CFLAGS="-fno-strict-aliasing"])
 173 AC_SUBST(EXTRA_CFLAGS)
 174
 175 dnl *** finalize CFLAGS, LDFLAGS, LIBS ***
 176
 177 dnl Overview:
 178 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 179 dnl GST_*:              flags shared by built objects to link against GStreamer
 180 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 181 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 182 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 183 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 184
 185 dnl GST_OPTION_CFLAGS
 186 if test "x$USE_DEBUG" = xyes; then
 187    PROFILE_CFLAGS="-g"
 188 fi
 189 AC_SUBST(PROFILE_CFLAGS)
 190
 191 if test "x$GST_GIT" = "xyes"; then
 192   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 193 else
 194   DEPRECATED_CFLAGS=""
 195 fi
 196 AC_SUBST(DEPRECATED_CFLAGS)
 197
 198 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 199 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 200
 201 AC_SUBST(GST_OPTION_CFLAGS)
 202
 203 dnl FIXME: do we want to rename to GST_ALL_* ?
 204 dnl prefer internal headers to already installed ones
 205 dnl also add builddir include for enumtypes and marshal
 206 dnl add GST_OPTION_CFLAGS, but overridable
 207 GST_CFLAGS="$GST_CFLAGS"
 208 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $EXTRA_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 209 AC_SUBST(GST_CFLAGS)
 210 AC_SUBST(GST_LIBS)
 211
 212 GST_ALL_LDFLAGS="-no-undefined"
 213 if test "x${enable_Bsymbolic}" = "xyes"; then
 214   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic"
 215 fi
 216 AC_SUBST(GST_ALL_LDFLAGS)
 217
 218 dnl this really should only contain flags, not libs - they get added before
 219 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 220 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 221 AC_SUBST(GST_PLUGIN_LDFLAGS)
 222
 223 dnl Add MacOSX specific flags
 224 AC_CANONICAL_HOST
 225 case $host_os in
 226      darwin*)
 227         DARWIN_LDFLAGS="-Wl,-read_only_relocs,suppress"
 228         ;;
 229      *)
 230         DARWIN_LDFLAGS=""
 231         ;;
 232 esac
 233 AC_SUBST(DARWIN_LDFLAGS)
 234
 235 AC_ARG_ENABLE(gpl,
 236               [AC_HELP_STRING([--enable-gpl], [build a GPL licensed gst-libav])])
 237 AM_CONDITIONAL(GST_LIBAV_ENABLE_GPL, test "x$enable_gpl" = "xyes")
 238 if test "x$enable_gpl" = "xyes"; then
 239   AC_DEFINE([GST_LIBAV_ENABLE_GPL], [], [Defined if building a GPL-licensed version of gst-libav])
 240 fi
 241
 242 dnl *** configure external libs ***
 243
 244 HAVE_LIBAV_UNINSTALLED=1
 245
 246 AC_ARG_WITH(system-libav,
 247             [AC_HELP_STRING([--with-system-libav], [use system Libav libraries])])
 248
 249 HAVE_LZMA="no"
 250 HAVE_BZ2="no"
 251 if test "x$with_system_libav" = "xyes"; then
 252   PKG_CHECK_MODULES(LIBAV, libavfilter libavformat libavcodec >= 57 libavutil)
 253   PKG_CHECK_MODULES(SWSCALE, libswscale libavutil)
 254   saved_CPPFLAGS="$CPPFLAGS"
 255   CPPFLAGS="$CPPFLAGS $LIBAV_CFLAGS"
 256   AC_CHECK_HEADERS([avi.h])
 257   AC_DEFINE([LIBAV_SOURCE], ["system install"], [Describes where the Libav libraries come from.])
 258   HAVE_LIBAV_UNINSTALLED=0
 259   AC_MSG_NOTICE([Using system-installed libav code])
 260   AC_MSG_CHECKING([whether libav is provided by FFmpeg])
 261   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 262     #include <libavcodec/avcodec.h>
 263     ]],[[
 264         #if LIBAVCODEC_VERSION_MICRO >= 100
 265         /* FFmpeg uses 100+ as its micro version */
 266         #else
 267         #error libav provider should be FFmpeg
 268         #endif
 269     ]])], [is_ffmpeg=yes], [is_ffmpeg=no])
 270   AC_MSG_RESULT([$is_ffmpeg])
 271   CPPFLAGS="$saved_CPPFLAGS"
 272   if test "$is_ffmpeg" = no; then
 273     AC_MSG_ERROR([Uncompatible libavcodec found])
 274   fi
 275 else
 276   AC_MSG_NOTICE([Using local Libav snapshot])
 277
 278   dnl *** Check for bz2
 279   save_LIBS=$LIBS
 280   LIBS="$LIBS -lbz2"
 281   AC_MSG_CHECKING([for BZ2_bzlibVersion in -lbz2])
 282   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <bzlib.h>]], [[const char *version = BZ2_bzlibVersion ();]])],[HAVE_BZ2=yes],[HAVE_BZ2=no])
 283   AC_MSG_RESULT($HAVE_BZ2)
 284   LIBS=$save_LIBS
 285   if test "x$HAVE_BZ2" = "xno"; then
 286     AC_WARN([libbz2 not found, matroska demuxer will not be able to read bz2 tracks])
 287     BZ2_LIBS=
 288   else
 289     BZ2_LIBS="-lbz2"
 290   fi
 291
 292   dnl *** Check for lzma
 293   save_LIBS=$LIBS
 294   LIBS="$LIBS -llzma"
 295   AC_MSG_CHECKING([for lzma_version_string in -llzma])
 296   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <lzma.h>]], [[const char *version = lzma_version_string ();]])],[HAVE_LZMA=yes],[HAVE_LZMA=no])
 297   AC_MSG_RESULT($HAVE_LZMA)
 298   LIBS=$save_LIBS
 299   if test "x$HAVE_LZMA" = "xno"; then
 300     AC_WARN([lzma not found, tiff reader will not be able to read lzma files])
 301     LZMA_LIBS=
 302   else
 303     LZMA_LIBS="-llzma"
 304   fi
 305
 306   dnl libgstlibav.la: include dirs
 307   LIBAV_CPPFLAGS="-I \$(top_srcdir)/gst-libs/ext/libav \
 308                 -I \$(top_builddir)/gst-libs/ext/libav"
 309
 310   LIBAV_CFLAGS="-Wno-deprecated-declarations"
 311
 312   LIBAV_DEPS="\$(top_builddir)/gst-libs/ext/libav/libavfilter/libavfilter.a \
 313               \$(top_builddir)/gst-libs/ext/libav/libavformat/libavformat.a \
 314               \$(top_builddir)/gst-libs/ext/libav/libavcodec/libavcodec.a \
 315               \$(top_builddir)/gst-libs/ext/libav/libswresample/libswresample.a \
 316               \$(top_builddir)/gst-libs/ext/libav/libavutil/libavutil.a"
 317
 318   LIBAV_LIBS="$ac_pwd/gst-libs/ext/libavfilter.la \
 319               $ac_pwd/gst-libs/ext/libavformat.la \
 320               $ac_pwd/gst-libs/ext/libavcodec.la \
 321               $ac_pwd/gst-libs/ext/libswresample.la \
 322               $ac_pwd/gst-libs/ext/libavutil.la"
 323
 324   dnl
 325   SWSCALE_CFLAGS="-I \$(top_srcdir)/gst-libs/ext/libav \
 326                   -I \$(top_builddir)/gst-libs/ext/libav \
 327                   -Wno-deprecated-declarations"
 328
 329   SWSCALE_DEPS="\$(top_builddir)/gst-libs/ext/libav/libswscale/libswscale.a \
 330                 \$(top_builddir)/gst-libs/ext/libav/libavutil/libavutil.a"
 331   if test "x$enable_static_plugins" = xyes; then
 332       dnl with static linking we can't use the .a archive directly as they would
 333       dnl be included in the final libgstswscale.a as a file and won't be usable.
 334       dnl libav*.a must be copied to the final destination too
 335       SWSCALE_LIBS="-lswscale -lavutil"
 336   else
 337       dnl libgstswscale.la: libs to statically link to
 338       SWSCALE_LIBS="$SWSCALE_DEPS"
 339   fi
 340
 341   LIBAV_SUBDIRS=gst-libs
 342   AC_DEFINE(HAVE_AVI_H)
 343   AC_DEFINE([LIBAV_SOURCE], ["local snapshot"], [Describes where the Libav libraries come from.])
 344
 345   AC_ARG_WITH(libav-extra-configure,
 346       AC_HELP_STRING([--with-libav-extra-configure="xxx"],
 347       [extra configure options for internal libav ./configure script]),,
 348       with_libav=no)
 349
 350   # basic arguments
 351   emblibav_configure_args="--prefix=$prefix"
 352
 353   # Enable pic and static so that we get .a files, but with PIC code.
 354   emblibav_configure_args="$emblibav_configure_args \
 355         --enable-static --enable-pic \
 356         --disable-avdevice --disable-postproc \
 357         --disable-programs --disable-ffserver --disable-ffplay --disable-ffprobe --disable-ffmpeg \
 358         --disable-encoder=flac --disable-protocols --disable-devices \
 359         --disable-network --disable-hwaccels --disable-dxva2 --disable-vdpau \
 360         --disable-filters --enable-filter=yadif --disable-doc --disable-vda --disable-d3d11va --disable-dxva2 \
 361         --disable-audiotoolbox --disable-videotoolbox --disable-vaapi --disable-crystalhd \
 362         --disable-mediacodec --disable-nvenc --disable-mmal --disable-omx \
 363         --disable-omx-rpi --disable-cuda --disable-cuvid --disable-libmfx \
 364         --disable-libnpp --disable-iconv --disable-jni --disable-v4l2_m2m --enable-optimizations"
 365
 366   if test "x$enable_gpl" == "xyes"; then
 367     emblibav_configure_args="$emblibav_configure_args --enable-gpl"
 368   fi
 369
 370   # if we are cross-compiling, tell libav so
 371   case $host in
 372       *android*)
 373         target_os=linux
 374       ;;
 375       *darwin*)
 376         target_os=darwin
 377       ;;
 378       *)
 379         target_os=`echo $host_os | sed 's/-gnu.*//'`
 380       ;;
 381   esac
 382
 383   if test "x$cross_compiling" = xyes; then
 384     emblibav_configure_args="$emblibav_configure_args --enable-cross-compile \
 385         --target-os=$target_os --arch=$host_cpu --cross-prefix=$host_alias-"
 386   fi
 387
 388   case $host_os in
 389     mingw32*)
 390       WIN32_LIBS="-lws2_32"
 391       ;;
 392     *)
 393       WIN32_LIBS=
 394       ;;
 395   esac
 396
 397   if test x"$AR" != x; then
 398     emblibav_configure_args="$emblibav_configure_args --ar=\\\"\\\$AR\\\""
 399   fi
 400
 401   if test x"$orig_AS" != x; then
 402     emblibav_configure_args="$emblibav_configure_args --as=\\\"\\\$orig_AS\\\""
 403   elif test x"$CC" != x; then
 404     dnl No external $AS - try $CC for the libav assembler
 405     emblibav_configure_args="$emblibav_configure_args --as=\\\"\\\$CC\\\""
 406   fi
 407
 408   if test x"$CC" != x; then
 409     emblibav_configure_args="$emblibav_configure_args --cc=\\\"\\\$CC\\\""
 410   fi
 411
 412   if test x"$LD" != x; then
 413     emblibav_configure_args="$emblibav_configure_args --ld=\\\"\\\$CC\\\""
 414   fi
 415
 416   if test x"$NM" != x; then
 417     emblibav_configure_args="$emblibav_configure_args --nm=\\\"\\\$NM\\\""
 418   fi
 419
 420   dnl checks for extra enable/disable flags
 421   LIBAV_OPTS=`cd $srcdir/gst-libs/ext/libav && ./configure --help`
 422   # Let's check if we can disable the building of the libav binary
 423   can_disable=`echo "$LIBAV_OPTS" | grep 'disable-ffmpeg'`
 424   if test "$can_disable" != ""; then
 425     emblibav_configure_args="$emblibav_configure_args --disable-ffmpeg"
 426   fi
 427   dnl check if libswscale needs enabling explicitly
 428   can_enable=`echo "$LIBAV_OPTS" | grep 'enable-swscale'`
 429   if test "$can_enable" != ""; then
 430     emblibav_configure_args="$emblibav_configure_args --enable-swscale"
 431   fi
 432
 433   # append extra configure options to emblibav_configure_args if needed
 434   if test "x$with_libav_extra_configure" != "xno"; then
 435     emblibav_configure_args="$emblibav_configure_args $with_libav_extra_configure"
 436   fi
 437
 438   AC_SUBST(LIBAV_CO_DIR)
 439   AC_SUBST(LIBAV_SVN)
 440   AC_SUBST(LIBAV_REVISION)
 441   AC_SUBST(LIBAV_EXTERNALS_REVISION)
 442   AC_CONFIG_COMMANDS([configure-embedded-libav],
 443     [echo "Configuring included Libav instance with args $emblibav_configure_args"
 444      origdir=`pwd`
 445      dnl Don't put path on the configure call when not needed, as FFmpeg's configure relies on it
 446      dnl to detect out-of-tree builds
 447      if test -z "$srcdir" -o "$srcdir" = .; then
 448        confcmd=./configure
 449        gasppdir=../gas-preprocessor
 450      else
 451        confcmd="$ac_abs_top_srcdir"/gst-libs/ext/libav/configure
 452        gasppdir="$ac_abs_top_srcdir"/gst-libs/ext/gas-preprocessor
 453      fi
 454
 455      AS_MKDIR_P(["$ac_top_build_prefix"gst-libs/ext/libav])
 456      oldPATH="$PATH"
 457      PATH="$gasppdir:$PATH"
 458      cd "$ac_top_build_prefix"gst-libs/ext/libav &&
 459          eval "$confcmd $emblibav_configure_args" ||
 460          AC_MSG_ERROR([Failed to configure embedded Libav tree])
 461      PATH="$oldPATH"
 462      cd "$origdir"
 463     ],
 464     [emblibav_configure_args="$emblibav_configure_args"])
 465   AC_MSG_NOTICE([Using included Libav code])
 466 fi
 467
 468 AM_CONDITIONAL(HAVE_BZ2, test "x$HAVE_BZ2" = "xyes")
 469 AM_CONDITIONAL(HAVE_LZMA, test "x$HAVE_LZMA" = "xyes")
 470
 471 AC_SUBST(LIBAV_CPPFLAGS)
 472 AC_SUBST(LIBAV_CFLAGS)
 473 AC_SUBST(LIBAV_DEPS)
 474 AC_SUBST(LIBAV_LIBS)
 475 AC_SUBST(LIBAV_SUBDIRS)
 476 AC_SUBST(SWSCALE_CFLAGS)
 477 AC_SUBST(SWSCALE_DEPS)
 478 AC_SUBST(SWSCALE_LIBS)
 479 AC_SUBST(WIN32_LIBS)
 480 AC_SUBST(BZ2_LIBS)
 481 AC_SUBST(LZMA_LIBS)
 482
 483 if test x$HAVE_LIBAV_UNINSTALLED = x1; then
 484   AC_DEFINE(HAVE_LIBAV_UNINSTALLED, [], [Defined if building against uninstalled Libav source])
 485 fi
 486 AM_CONDITIONAL(HAVE_LIBAV_UNINSTALLED, test x$HAVE_LIBAV_UNINSTALLED = x1)
 487
 488 AC_CONFIG_FILES(
 489 Makefile
 490 common/Makefile
 491 common/m4/Makefile
 492 ext/Makefile
 493 ext/libav/Makefile
 494 ext/libswscale/Makefile
 495 gst-libs/Makefile
 496 gst-libs/ext/Makefile
 497 docs/Makefile
 498 docs/plugins/Makefile
 499 docs/version.entities
 500 tests/Makefile
 501 tests/check/Makefile
 502 tests/files/Makefile
 503 pkgconfig/Makefile
 504 pkgconfig/gstreamer-plugins-libav-uninstalled.pc
 505 )
 506 AC_OUTPUT
 507
 508 ORC_OUTPUT