configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.11.0.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.11
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 AG_GST_LIBTOOL_PREPARE
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AC_LIBTOOL_WIN32_DLL
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=0.11.0
  58 GSTPB_REQ=0.11.0
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67
  68 dnl set up gettext
  69 dnl the version check needs to stay here because autopoint greps for it
  70 AM_GNU_GETTEXT_VERSION([0.17])
  71 AM_GNU_GETTEXT([external])
  72 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  73
  74 dnl *** check for arguments to configure ***
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 AG_GST_ARG_WITH_PLUGINS
  88
  89 AG_GST_ARG_ENABLE_EXTERNAL
  90
  91 AG_GST_ARG_ENABLE_EXPERIMENTAL
  92
  93 dnl *** checks for platform ***
  94
  95 dnl * hardware/architecture *
  96
  97 dnl common/m4/gst-arch.m4
  98 dnl check CPU type
  99 AG_GST_ARCH
 100
 101 dnl Determine endianness
 102 AC_C_BIGENDIAN
 103
 104 dnl *** checks for programs ***
 105
 106 dnl find a compiler
 107 AC_PROG_CC
 108 AC_PROG_CC_STDC
 109
 110 dnl determine c++ compiler
 111 AC_PROG_CXX
 112 dnl determine if c++ is available on this system
 113 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 114
 115 dnl determine c++ preprocessor
 116 dnl FIXME: do we need this ?
 117 AC_PROG_CXXCPP
 118
 119 AS_PROG_OBJC
 120
 121 dnl check if the compiler supports '-c' and '-o' options
 122 AM_PROG_CC_C_O
 123
 124 dnl find an assembler
 125 AM_PROG_AS
 126
 127 dnl check if the compiler supports do while(0) macros
 128 AG_GST_CHECK_DOWHILE_MACROS
 129
 130 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 131 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 132
 133 dnl check for documentation tools
 134 GTK_DOC_CHECK([1.3])
 135 AS_PATH_PYTHON([2.1])
 136 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 137
 138 dnl *** checks for libraries ***
 139
 140 dnl check for libm, for sin()
 141 AC_CHECK_LIBM
 142 AC_SUBST(LIBM)
 143
 144 dnl *** checks for header files ***
 145
 146 dnl check if we have ANSI C header files
 147 AC_HEADER_STDC
 148
 149 dnl used by ext/wavpack
 150 AX_CREATE_STDINT_H
 151
 152 dnl used in gst/rtp/gstasteriskh263.c
 153 AC_CHECK_HEADERS([netinet/in.h])
 154 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 155 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 156
 157 dnl used in gst/udp
 158 AC_CHECK_HEADERS([sys/time.h])
 159
 160 dnl *** checks for types/defines ***
 161
 162 dnl Check for FIONREAD ioctl declaration.  This check is needed
 163 dnl for the UDP plugin to build on Solaris
 164 GST_CHECK_FIONREAD
 165
 166 dnl *** checks for structures ***
 167
 168 dnl *** checks for compiler characteristics ***
 169
 170 dnl check if we have GCC inline-asm
 171 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 172 if test x$HAVE_GCC_ASM = xyes ; then
 173   AC_DEFINE(HAVE_GCC_ASM, 1,
 174     [Define if compiler supports gcc inline assembly])
 175 fi
 176 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 177
 178 dnl *** checks for library functions ***
 179
 180 LIBS_SAVE=$LIBS
 181 LIBS="$LIBS $LIBM"
 182 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 183 LIBS=$LIBS_SAVE
 184
 185 dnl Check whether isinf() is defined by math.h
 186 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 187     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 188 if test "$ac_cv_have_isinf" = "yes"
 189 then
 190     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 191 fi
 192
 193 dnl Check for mmap (needed by electricfence plugin)
 194 AC_FUNC_MMAP
 195 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 196
 197 dnl Check for mmap (needed by electricfence plugin)
 198
 199 AC_CHECK_TYPE([struct ip_mreqn], [
 200               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 201               [#include <netinet/in.h>])
 202
 203 dnl *** checks for dependency libraries ***
 204
 205 dnl GLib is required
 206 AG_GST_GLIB_CHECK([2.20])
 207
 208 dnl Orc
 209 ORC_CHECK([0.4.11])
 210
 211 dnl checks for gstreamer
 212 dnl uninstalled is selected preferentially -- see pkg-config(1)
 213 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 214 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 215 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 216 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 217 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 218 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 219
 220 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 221 if test -z $GST_TOOLS_DIR; then
 222   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 223 fi
 224 AC_SUBST(GST_TOOLS_DIR)
 225
 226 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 227 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 228
 229 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 230
 231 dnl Check for documentation xrefs
 232 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 233 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 234 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 235 AC_SUBST(GLIB_PREFIX)
 236 AC_SUBST(GST_PREFIX)
 237 AC_SUBST(GSTPB_PREFIX)
 238
 239 dnl GTK is optional and used in examples
 240 HAVE_GTK=no
 241 GTK2_REQ=2.14.0
 242 GTK3_REQ=2.91.3
 243 if test "x$BUILD_EXAMPLES" = "xyes"; then
 244   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 245   AC_ARG_WITH([gtk],
 246     AC_HELP_STRING([--with-gtk=3.0|2.0],
 247                    [which gtk+ version to compile against (default: 2.0)]),
 248     [case "$with_gtk" in
 249         2.0) GTK_REQ=$GTK2_REQ ;;
 250         3.0) GTK_REQ=$GTK3_REQ ;;
 251         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 252     esac],
 253     [with_gtk=2.0
 254      GTK_REQ=$GTK2_REQ])
 255   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 256   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 257   dnl some examples need gtk+-x11
 258   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 259   AC_SUBST(GTK_LIBS)
 260   AC_SUBST(GTK_CFLAGS)
 261 fi
 262 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 263 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 264
 265 dnl *** set variables based on configure arguments ***
 266
 267 dnl set license and copyright notice
 268 GST_LICENSE="LGPL"
 269 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 270 AC_SUBST(GST_LICENSE)
 271
 272 dnl set location of plugin directory
 273 AG_GST_SET_PLUGINDIR
 274
 275 dnl set release date/time
 276 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 277   ["${srcdir}/gst-plugins-good.doap"],
 278   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 279
 280 dnl define an ERROR_CFLAGS Makefile variable
 281 dnl -Wundef: too many broken headers
 282 if test "x$HAVE_OSX_VIDEO" != "xyes"; then
 283   AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 284         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 285         -Wwrite-strings -Wold-style-definition -Waggregate-return
 286         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 287         -Wnested-externs ])
 288 else
 289   dnl work-around for us passing GST_CFLAGS to the ObjC-compiler, which
 290   dnl doesn't understand all warning flags that the C compiler knows about
 291   dnl (e.g. -Waddress) or causes problems with some flags (-Waggregate-return)
 292   AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 293         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 294         -Wwrite-strings -Wold-style-definition
 295         -Winit-self -Wmissing-include-dirs -Wno-multichar
 296         -Wnested-externs ])
 297 fi
 298
 299 dnl define an ERROR_CXXFLAGS Makefile variable
 300 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 301         -Wmissing-declarations -Wredundant-decls
 302         -Wwrite-strings
 303         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar ])
 304
 305 dnl define correct level for debugging messages
 306 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 307
 308 dnl used in examples
 309 AG_GST_DEFAULT_ELEMENTS
 310
 311 dnl *** plug-ins to include ***
 312
 313 dnl Non ported plugins (non-dependant, then dependant)
 314 dnl Make sure you have a space before and after all plugins
 315 GST_PLUGINS_NONPORTED="deinterlace flx goom2k1 icydemux id3demux \
 316  imagefreeze interleave matroska monoscope smpte \
 317  videobox videocrop videomixer \
 318  annodex apetag cairo cairo_gobject dv1394 gdk_pixbuf libdv libpng \
 319  oss oss4 shout2 \
 320  taglib wavpack "
 321 AC_SUBST(GST_PLUGINS_NONPORTED)
 322
 323 dnl these are all the gst plug-ins, compilable without additional libs
 324 dnl videofilter is at the top because others depend on it
 325 AG_GST_CHECK_PLUGIN(alpha)
 326 AG_GST_CHECK_PLUGIN(apetag)
 327 AG_GST_CHECK_PLUGIN(audiofx)
 328 AG_GST_CHECK_PLUGIN(audioparsers)
 329 AG_GST_CHECK_PLUGIN(auparse)
 330 AG_GST_CHECK_PLUGIN(autodetect)
 331 AG_GST_CHECK_PLUGIN(avi)
 332 AG_GST_CHECK_PLUGIN(cutter)
 333 AG_GST_CHECK_PLUGIN(debugutils)
 334 AG_GST_CHECK_PLUGIN(deinterlace)
 335 AG_GST_CHECK_PLUGIN(effectv)
 336 AG_GST_CHECK_PLUGIN(equalizer)
 337 AG_GST_CHECK_PLUGIN(flv)
 338 AG_GST_CHECK_PLUGIN(flx)
 339 AG_GST_CHECK_PLUGIN(goom)
 340 AG_GST_CHECK_PLUGIN(goom2k1)
 341 AG_GST_CHECK_PLUGIN(icydemux)
 342 AG_GST_CHECK_PLUGIN(id3demux)
 343 AG_GST_CHECK_PLUGIN(imagefreeze)
 344 AG_GST_CHECK_PLUGIN(interleave)
 345 AG_GST_CHECK_PLUGIN(isomp4)
 346 AG_GST_CHECK_PLUGIN(law)
 347 AG_GST_CHECK_PLUGIN(level)
 348 AG_GST_CHECK_PLUGIN(matroska)
 349 AG_GST_CHECK_PLUGIN(monoscope)
 350 AG_GST_CHECK_PLUGIN(multifile)
 351 AG_GST_CHECK_PLUGIN(multipart)
 352 AG_GST_CHECK_PLUGIN(replaygain)
 353 AG_GST_CHECK_PLUGIN(rtp)
 354 AG_GST_CHECK_PLUGIN(rtpmanager)
 355 AG_GST_CHECK_PLUGIN(rtsp)
 356 AG_GST_CHECK_PLUGIN(shapewipe)
 357 AG_GST_CHECK_PLUGIN(smpte)
 358 AG_GST_CHECK_PLUGIN(spectrum)
 359 AG_GST_CHECK_PLUGIN(udp)
 360 AG_GST_CHECK_PLUGIN(videobox)
 361 AG_GST_CHECK_PLUGIN(videocrop)
 362 AG_GST_CHECK_PLUGIN(videofilter)
 363 AG_GST_CHECK_PLUGIN(videomixer)
 364 AG_GST_CHECK_PLUGIN(wavenc)
 365 AG_GST_CHECK_PLUGIN(wavparse)
 366 AG_GST_CHECK_PLUGIN(y4m)
 367
 368 dnl *** checks for socket and nsl libraries ***
 369 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 370
 371 dnl disable gst plugins we might not be able to build on this
 372 dnl platform: udp and rtsp (ugly but minimally invasive)
 373 dnl FIXME: maybe move to sys
 374 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 375 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 376
 377 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 378   AG_GST_DISABLE_PLUGIN(udp)
 379   AG_GST_DISABLE_PLUGIN(rtsp)
 380 fi
 381
 382 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 383   WIN32_LIBS="-lws2_32"
 384   AC_SUBST(WIN32_LIBS)
 385 fi
 386
 387 dnl disable experimental plug-ins
 388 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 389   AG_GST_DISABLE_PLUGIN(monoscope)
 390 fi
 391
 392 dnl *** sys plug-ins ***
 393
 394 echo
 395 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 396 echo
 397
 398 dnl DirectSound
 399 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 400 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 401   HAVE_DIRECTSOUND="no"
 402   save_CFLAGS="$CFLAGS"
 403   save_LDFLAGS="$LDFLAGS"
 404   save_LIBS="$LIBS"
 405   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 406   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 407   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 408   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 409   AC_LINK_IFELSE([
 410 #include <windows.h>
 411 #include <dxerr9.h>
 412 #include <dsound.h>
 413
 414 int main ()
 415 {
 416   DXGetErrorString9 (0);
 417   DirectSoundCreate(NULL, NULL, NULL);
 418
 419   return 0;
 420 }
 421 ],
 422     [HAVE_DIRECTSOUND="yes"],
 423     [HAVE_DIRECTSOUND="no"])
 424   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 425   CFLAGS=$save_CFLAGS
 426   LDFLAGS=$save_LDFLAGS
 427   LIBS=$save_LIBS
 428
 429   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 430     dnl this is much more than we want
 431     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 432     AC_SUBST(DIRECTSOUND_CFLAGS)
 433     AC_SUBST(DIRECTSOUND_LDFLAGS)
 434     AC_SUBST(DIRECTSOUND_LIBS)
 435   fi
 436   AC_SUBST(HAVE_DIRECTSOUND)
 437 ])
 438
 439 dnl *** OSS audio *** (Linux, *BSD)
 440 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 441 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 442  HAVE_OSS="yes"
 443 dnl Linux and newer BSD versions :
 444  AC_CHECK_HEADER(sys/soundcard.h, [
 445    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 446    ] , [
 447 dnl Some old BSD versions and also newer OpenBSD versions :
 448    AC_CHECK_HEADER(soundcard.h, [
 449      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 450      ], [
 451   dnl Some old BSD versions :
 452      AC_CHECK_HEADER(machine/soundcard.h, [
 453        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 454          [Define if OSS includes are in /machine/])
 455        ], [
 456        HAVE_OSS="no"
 457      ])
 458    ])
 459  ])
 460 ])
 461
 462 dnl *** oss4 ***
 463 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 464 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 465   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 466   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 467       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 468       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 469 ])
 470
 471 dnl *** Sun Audio ***
 472 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 473 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 474   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 475 ])
 476
 477 dnl *** OSX Audio ***
 478 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 479 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 480   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 481 ])
 482
 483 dnl *** OS X video ***
 484 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 485 HAVE_OSX_VIDEO="no"
 486 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 487   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 488 ])
 489 dnl in case header OpenGL/gl.h is found on other platforms
 490 case "$host" in
 491   *-*darwin*)
 492     dnl do nothing
 493     ;;
 494   *)
 495     HAVE_OSX_VIDEO="no"
 496     ;;
 497 esac
 498
 499
 500 dnl *** Video 4 Linux 2 ***
 501 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 502 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 503 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 504 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 505   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 506   AC_TRY_COMPILE([
 507 #include <sys/types.h>
 508 #ifdef __sun /* Solaris */
 509 #include <sys/types.h>
 510 #include <sys/videodev2.h>
 511 #else /* Linux */
 512 #include <linux/types.h>
 513 #define _LINUX_TIME_H
 514 #define __user
 515 #include <linux/videodev2.h>
 516 #endif
 517 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 518 #error too early v4l2 version or no v4l2 at all
 519 #endif
 520     ], [
 521 return 0;
 522     ], [
 523       HAVE_GST_V4L2="yes"
 524       AC_MSG_RESULT(yes)
 525     ], [
 526       HAVE_GST_V4L2="no"
 527       AC_MSG_RESULT(no)
 528
 529       HAVE_VIDEODEV=no
 530       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 531       [
 532         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 533       ])
 534
 535       if test "x$HAVE_VIDEODEV" = "xyes"; then
 536         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 537         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 538       else
 539         AC_MSG_WARN([video4linux2 was not found])
 540       fi
 541     ])
 542
 543   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 544     dnl check for missing v4l2_buffer declaration (see #135919)
 545     MISSING_DECL=0
 546     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 547     AC_TRY_COMPILE([
 548 #include <sys/types.h>
 549 #ifdef __sun /* Solaris */
 550 #include <sys/types.h>
 551 #include <sys/videodev2.h>
 552 #else /* Linux */
 553 #include <linux/types.h>
 554 #define _LINUX_TIME_H
 555 #define __user
 556 #include <linux/videodev2.h>
 557 #endif
 558     ],[
 559 struct v4l2_buffer buf;
 560 buf.index = 0;
 561 return 0;
 562     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 563     if [ test x$MISSING_DECL = x1 ]; then
 564       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 565     fi
 566
 567     dnl check for XOverlay libraries
 568     AG_GST_CHECK_XV
 569   fi
 570 ])
 571
 572 # Optional gudev for device probing
 573 AC_ARG_WITH([gudev],
 574   AC_HELP_STRING([--with-gudev],
 575     [device detection with gudev]),
 576   [],
 577   [with_gudev=check])
 578 if test x$HAVE_GST_V4L2 = xyes; then
 579   if test x$with_gudev != xno; then
 580       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 581           [ have_gudev=yes
 582             AC_DEFINE(HAVE_GUDEV, 1,
 583                [Whether gudev is available for device detection])
 584             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 585           ], [
 586           have_gudev=no
 587           ])
 588   else
 589     have_gudev=no
 590   fi
 591 fi
 592 AC_SUBST(GUDEV_CFLAGS)
 593 AC_SUBST(GUDEV_LIBS)
 594
 595 # Make libv4l2 non-automagic
 596 AC_ARG_WITH([libv4l2],
 597   AC_HELP_STRING([--with-libv4l2],
 598     [support video buffer conversion using libv4l2]),
 599   [],
 600   [with_libv4l2=check])
 601 if test x$HAVE_GST_V4L2 = xyes; then
 602   if test x$with_libv4l2 != xno; then
 603       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 604           [ have_libv4l2=yes
 605             AC_DEFINE(HAVE_LIBV4L2, 1,
 606                 [Whether libv4l2 is available for video buffer conversion])
 607           ], [
 608           have_libv4l2=no
 609           ])
 610   else
 611     have_libv4l2=no
 612   fi
 613 fi
 614
 615 dnl Check for X11
 616 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 617 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 618                   [ximagesrc], [
 619   AC_PATH_XTRA
 620
 621   dnl now try to find the HEADER
 622   ac_cflags_save="$CFLAGS"
 623   ac_cppflags_save="$CPPFLAGS"
 624   CFLAGS="$CFLAGS $X_CFLAGS"
 625   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 626   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 627
 628   if test "x$HAVE_X" = "xno"
 629   then
 630     AC_MSG_NOTICE([cannot find X11 development files])
 631   else
 632     dnl this is much more than we want
 633     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 634     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 635     dnl it does not add the libs; therefore we add them here
 636     X_LIBS="$X_LIBS -lX11"
 637     AC_SUBST(X_CFLAGS)
 638     AC_SUBST(X_LIBS)
 639
 640     dnl check for Xfixes
 641     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 642     if test "x$HAVE_XFIXES" = "xyes"
 643     then
 644         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 645     fi
 646     AC_SUBST(XFIXES_LIBS)
 647     AC_SUBST(XFIXES_CFLAGS)
 648
 649     dnl check for Xdamage
 650     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 651     if test "x$HAVE_XDAMAGE" = "xyes"
 652     then
 653         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 654     fi
 655     AC_SUBST(XDAMAGE_LIBS)
 656     AC_SUBST(XDAMAGE_CFLAGS)
 657   fi
 658   AC_SUBST(HAVE_X)
 659   CFLAGS="$ac_cflags_save"
 660   CPPFLAGS="$ac_cppflags_save"
 661 ])
 662
 663 dnl FIXME: this should be rolled into the test above, it's just an additional
 664 dnl feature of the ximagesrc plug-in
 665 dnl This is the same as in gst-plugins-base
 666 dnl check for X Shm
 667 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 668 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 669   if test x$HAVE_X = xyes; then
 670     AC_CHECK_LIB(Xext, XShmAttach,
 671                  HAVE_XSHM="yes", HAVE_XSHM="no",
 672                  $X_LIBS)
 673     if test "x$HAVE_XSHM" = "xyes"; then
 674       XSHM_LIBS="-lXext"
 675     else
 676       dnl On AIX, it is in XextSam instead, but we still need -lXext
 677       AC_CHECK_LIB(XextSam, XShmAttach,
 678                    HAVE_XSHM="yes", HAVE_XSHM="no",
 679                    $X_LIBS)
 680       if test "x$HAVE_XSHM" = "xyes"; then
 681         XSHM_LIBS="-lXext -lXextSam"
 682       fi
 683     fi
 684   fi
 685 ], ,[
 686   AC_SUBST(HAVE_XSHM)
 687   AC_SUBST(XSHM_LIBS)
 688 ])
 689
 690 dnl for V4L2, we also need to know if we have XVIDEO
 691 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 692 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 693                   [], [
 694   AG_GST_CHECK_XV
 695 ])
 696
 697 dnl *** ext plug-ins ***
 698 dnl keep this list sorted alphabetically !
 699
 700 if test "x$BUILD_EXTERNAL" = "xyes"; then
 701
 702 echo
 703 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 704 echo
 705
 706 dnl *** aalib ***
 707 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 708 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 709   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 710   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 711 ])
 712
 713 dnl *** annodex ***
 714 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 715 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 716   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 717 ])
 718
 719 dnl *** cairo ***
 720 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 721 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 722   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 723 ])
 724
 725 dnl *** cairo-gobject ***
 726 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO_GOBJECT, true)
 727 AG_GST_CHECK_FEATURE(CAIRO_GOBJECT,
 728   [Cairo graphics rendering gobject bindings], cairooverlay, [
 729   AG_GST_PKG_CHECK_MODULES(CAIRO_GOBJECT, cairo-gobject >= 1.10.0)
 730 ])
 731
 732 dnl *** FLAC ***
 733 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 734 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 735   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 736 ])
 737
 738 dnl *** GDK pixbuf ***
 739 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 740 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 741   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 742 ])
 743
 744 dnl *** Jack ***
 745 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 746 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 747   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 748   AC_SUBST(JACK_CFLAGS)
 749   AC_SUBST(JACK_LIBS)
 750
 751   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 752   if test x$HAVE_JACK_0_120_1 = xyes; then
 753     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 754   fi
 755   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 756   if test x$HAVE_JACK_1_9_7 = xyes; then
 757     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 758   fi
 759
 760 ])
 761
 762 dnl *** jpeg ***
 763 dnl FIXME: we could use header checks here as well IMO
 764 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 765 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 766   AC_ARG_WITH(jpeg-mmx,
 767     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 768   OLD_LIBS="$LIBS"
 769   if test x$with_jpeg_mmx != x; then
 770     LIBS="$LIBS -L$with_jpeg_mmx"
 771   fi
 772   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 773   JPEG_LIBS="$LIBS -ljpeg-mmx"
 774   LIBS="$OLD_LIBS"
 775   if test x$HAVE_JPEG != xyes; then
 776     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 777     JPEG_LIBS="-ljpeg"
 778   fi
 779   AC_SUBST(JPEG_LIBS)
 780 ])
 781
 782 dnl *** libcaca ***
 783 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 784 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 785   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 786 ])
 787
 788 dnl *** libdv ***
 789 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 790 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 791   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 792 ])
 793
 794 dnl *** libpng ***
 795 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 796 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 797   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 798 ])
 799
 800 dnl *** pulseaudio ***
 801 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 802 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 803
 804   dnl used in ext/pulse/pulseutil.c
 805   AC_CHECK_HEADERS([process.h])
 806
 807   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 0.9.16)
 808   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_20, libpulse >= 0.9.20)
 809   if test x$HAVE_PULSE_0_9_20 = xyes; then
 810     AC_DEFINE(HAVE_PULSE_0_9_20, 1, [defined if pulseaudio >= 0.9.20 is available])
 811   fi
 812   AG_GST_PKG_CHECK_MODULES(PULSE_1_0, libpulse >= 0.98)
 813   if test x$HAVE_PULSE_1_0 = xyes; then
 814     AC_DEFINE(HAVE_PULSE_1_0, 1, [defined if pulseaudio >= 1.0 is available])
 815   fi
 816 ])
 817
 818 dnl *** dv1394 ***
 819 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 820 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 821   dnl first test for libraw1394 >= 2.0.0
 822   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 823   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 824   dnl now see how far we got
 825   if test x$HAVE_RAW1394 = xyes && \
 826      test x$HAVE_LIBIEC61883 = xyes; then
 827        AG_GST_CHECK_LIBHEADER(AVC1394,
 828         avc1394, avc1394_send_command, $RAW1394_LIBS,
 829         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 830        AG_GST_CHECK_LIBHEADER(ROM1394,
 831         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 832         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 833        if test x$HAVE_AVC1394 = xyes && \
 834           test x$HAVE_AVC1394 = xyes && \
 835           test x$HAVE_ROM1394 = xyes; then
 836           HAVE_DV1394=yes
 837           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 838           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 839           AC_SUBST(DV1394_CFLAGS)
 840           AC_SUBST(DV1394_LIBS)
 841         fi
 842   else
 843        if test x$HAVE_RAW1394 = xno; then
 844           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 845           AG_GST_CHECK_LIBHEADER(AVC1394,
 846            avc1394, avc1394_send_command, $RAW1394_LIBS,
 847            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 848           AG_GST_CHECK_LIBHEADER(ROM1394,
 849            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 850            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 851           if test x$HAVE_RAW1394 = xyes && \
 852              test x$HAVE_AVC1394 = xyes && \
 853              test x$HAVE_ROM1394 = xyes; then
 854              HAVE_DV1394=yes
 855              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 856              DV1394_CFLAGS="$RAW1394_CFLAGS"
 857              if test x$HAVE_LIBIEC61883 = xyes; then
 858                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 859                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 860              fi
 861              AC_SUBST(DV1394_CFLAGS)
 862              AC_SUBST(DV1394_LIBS)
 863            fi
 864          fi
 865   fi
 866 ])
 867 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 868
 869 dnl *** shout2 ***
 870 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 871 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 872   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 873 ])
 874
 875 dnl *** soup ***
 876 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 877 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 878   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 879     HAVE_SOUP="yes"
 880     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 881   ],[
 882     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 883       HAVE_SOUP="no"
 884     ])
 885   ])
 886   AC_SUBST(SOUP_CFLAGS)
 887   AC_SUBST(SOUP_LIBS)
 888 ])
 889
 890 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 891 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 892 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 893 dnl   speex_jitter.h is 1.1.x only
 894 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 895 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 896   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 897   if test $HAVE_SPEEX = no
 898   then
 899     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 900       AC_CHECK_HEADER(speex/speex_jitter.h, [
 901         dnl speex 1.1.x :
 902         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 903           dnl speex 1.1.5 or + :
 904           HAVE_SPEEX="yes"
 905           SPEEX_LIBS="-lspeex"
 906           AC_SUBST(SPEEX_CFLAGS)
 907           AC_SUBST(SPEEX_LIBS)
 908         ],[
 909           HAVE_SPEEX="no"
 910         ])
 911       ],[
 912         dnl speex 1.0.x :
 913           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 914             dnl speex 1.0.4
 915             HAVE_SPEEX="yes"
 916             SPEEX_LIBS="-lspeex"
 917             AC_SUBST(SPEEX_CFLAGS)
 918             AC_SUBST(SPEEX_LIBS)
 919
 920             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 921               [defined if speex 1.0.x API detected])
 922         ],[
 923             HAVE_SPEEX="no"
 924             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 925         ], [
 926 #include <speex/speex.h>
 927         ])
 928       ])
 929     ])
 930   fi
 931 ])
 932
 933 dnl *** taglib ***
 934 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 935 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 936   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 937   if test "x$HAVE_CXX" != "xyes"; then
 938     USE_TAGLIB=false
 939     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 940   else
 941     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 942     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 943         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 944       ], [
 945         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 946     ])
 947     AC_SUBST(TAGLIB_CXXFLAGS)
 948   fi
 949 ])
 950
 951 dnl *** wavpack ***
 952 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 953 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 954   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 955     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 956       HAVE_WAVPACK=yes
 957       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 958     ],[
 959       HAVE_WAVPACK=no
 960     ])
 961   ])
 962   AC_SUBST(WAVPACK_CFLAGS)
 963   AC_SUBST(WAVPACK_LIBS)
 964 ])
 965
 966 dnl *** qtdemux & matroska prefer to have zlib ***
 967 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 968 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 969   AG_GST_CHECK_LIBHEADER(ZLIB,
 970     z, uncompress,, zlib.h, [
 971     HAVE_ZLIB="yes"
 972     ZLIB_LIBS="-lz"
 973     AC_SUBST(ZLIB_LIBS)
 974   ])
 975 ])
 976
 977 dnl *** matroska prefers to have bz2 ***
 978 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 979 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 980   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 981   AC_SUBST(BZ2_LIBS)
 982 ])
 983
 984 else
 985
 986 dnl not building plugins with external dependencies,
 987 dnl but we still need to set the conditionals
 988 AM_CONDITIONAL(USE_AALIB, false)
 989 AM_CONDITIONAL(USE_ANNODEX, false)
 990 AM_CONDITIONAL(USE_BZ2, false)
 991 AM_CONDITIONAL(USE_CAIRO, false)
 992 AM_CONDITIONAL(USE_CAIRO_GOBJECT, false)
 993 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 994 AM_CONDITIONAL(USE_DV1394, false)
 995 AM_CONDITIONAL(USE_FLAC, false)
 996 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 997 AM_CONDITIONAL(USE_GST_V4L2, false)
 998 AM_CONDITIONAL(USE_JACK, false)
 999 AM_CONDITIONAL(USE_JPEG, false)
1000 AM_CONDITIONAL(USE_LIBCACA, false)
1001 AM_CONDITIONAL(USE_LIBDV, false)
1002 AM_CONDITIONAL(USE_LIBIEC61883, false)
1003 AM_CONDITIONAL(USE_LIBPNG, false)
1004 AM_CONDITIONAL(USE_OSS, false)
1005 AM_CONDITIONAL(USE_OSS4, false)
1006 AM_CONDITIONAL(USE_OSX_AUDIO, false)
1007 AM_CONDITIONAL(USE_OSX_VIDEO, false)
1008 AM_CONDITIONAL(USE_PULSE, false)
1009 AM_CONDITIONAL(USE_SHOUT2, false)
1010 AM_CONDITIONAL(USE_SOUP, false)
1011 AM_CONDITIONAL(USE_SPEEX, false)
1012 AM_CONDITIONAL(USE_SUNAUDIO, false)
1013 AM_CONDITIONAL(USE_TAGLIB, false)
1014 AM_CONDITIONAL(USE_WAVPACK, false)
1015 AM_CONDITIONAL(USE_X, false)
1016 AM_CONDITIONAL(USE_XSHM, false)
1017 AM_CONDITIONAL(USE_XVIDEO, false)
1018 AM_CONDITIONAL(USE_ZLIB, false)
1019
1020 fi dnl of EXT plugins
1021
1022 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1023
1024 dnl Overview:
1025 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1026 dnl GST_*:              flags shared by all built objects
1027 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1028 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1029 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1030 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1031
1032 dnl GST_OPTION_CFLAGS
1033 if test "x$USE_DEBUG" = xyes; then
1034    PROFILE_CFLAGS="-g"
1035 fi
1036 AC_SUBST(PROFILE_CFLAGS)
1037
1038 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1039   dnl Define _only_ for git (not pre-releases or releases)
1040   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1041 else
1042   DEPRECATED_CFLAGS=""
1043 fi
1044 AC_SUBST(DEPRECATED_CFLAGS)
1045
1046 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1047 dnl at make time with e.g. make ERROR_CFLAGS=""
1048 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1049 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1050 AC_SUBST(GST_OPTION_CFLAGS)
1051 AC_SUBST(GST_OPTION_CXXFLAGS)
1052
1053 dnl our libraries need to be versioned correctly
1054 AC_SUBST(GST_LT_LDFLAGS)
1055
1056 dnl FIXME: do we want to rename to GST_ALL_* ?
1057 dnl prefer internal headers to already installed ones
1058 dnl also add builddir include for enumtypes and marshal
1059 dnl add ERROR_CFLAGS, but overridable
1060 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
1061 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1062 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1063 AC_SUBST(GST_CFLAGS)
1064 AC_SUBST(GST_CXXFLAGS)
1065 AC_SUBST(GST_LIBS)
1066
1067 dnl LDFLAGS really should only contain flags, not libs - they get added before
1068 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1069 GST_ALL_LDFLAGS="-no-undefined"
1070 AC_SUBST(GST_ALL_LDFLAGS)
1071
1072 dnl this really should only contain flags, not libs - they get added before
1073 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1074 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
1075 AC_SUBST(GST_PLUGIN_LDFLAGS)
1076
1077 dnl *** output files ***
1078
1079 dnl keep this alphabetic per directory, please
1080 AC_CONFIG_FILES(
1081 Makefile
1082 gst/Makefile
1083 gst/alpha/Makefile
1084 gst/apetag/Makefile
1085 gst/audiofx/Makefile
1086 gst/audioparsers/Makefile
1087 gst/auparse/Makefile
1088 gst/autodetect/Makefile
1089 gst/avi/Makefile
1090 gst/cutter/Makefile
1091 gst/deinterlace/Makefile
1092 gst/debugutils/Makefile
1093 gst/effectv/Makefile
1094 gst/equalizer/Makefile
1095 gst/flv/Makefile
1096 gst/goom/Makefile
1097 gst/goom2k1/Makefile
1098 gst/id3demux/Makefile
1099 gst/icydemux/Makefile
1100 gst/imagefreeze/Makefile
1101 gst/interleave/Makefile
1102 gst/isomp4/Makefile
1103 gst/law/Makefile
1104 gst/level/Makefile
1105 gst/matroska/Makefile
1106 gst/monoscope/Makefile
1107 gst/multifile/Makefile
1108 gst/multipart/Makefile
1109 gst/replaygain/Makefile
1110 gst/rtp/Makefile
1111 gst/rtpmanager/Makefile
1112 gst/rtsp/Makefile
1113 gst/shapewipe/Makefile
1114 gst/smpte/Makefile
1115 gst/spectrum/Makefile
1116 gst/udp/Makefile
1117 gst/videobox/Makefile
1118 gst/videocrop/Makefile
1119 gst/videofilter/Makefile
1120 gst/videomixer/Makefile
1121 gst/wavenc/Makefile
1122 gst/wavparse/Makefile
1123 gst/flx/Makefile
1124 gst/y4m/Makefile
1125 ext/Makefile
1126 ext/aalib/Makefile
1127 ext/annodex/Makefile
1128 ext/cairo/Makefile
1129 ext/dv/Makefile
1130 ext/flac/Makefile
1131 ext/gdk_pixbuf/Makefile
1132 ext/jack/Makefile
1133 ext/jpeg/Makefile
1134 ext/libcaca/Makefile
1135 ext/libpng/Makefile
1136 ext/pulse/Makefile
1137 ext/raw1394/Makefile
1138 ext/shout2/Makefile
1139 ext/soup/Makefile
1140 ext/speex/Makefile
1141 ext/taglib/Makefile
1142 ext/wavpack/Makefile
1143 sys/Makefile
1144 sys/directsound/Makefile
1145 sys/oss/Makefile
1146 sys/oss4/Makefile
1147 sys/osxaudio/Makefile
1148 sys/osxvideo/Makefile
1149 sys/sunaudio/Makefile
1150 sys/v4l2/Makefile
1151 sys/waveform/Makefile
1152 sys/ximage/Makefile
1153 po/Makefile.in
1154 tests/Makefile
1155 tests/check/Makefile
1156 tests/examples/Makefile
1157 tests/examples/audiofx/Makefile
1158 tests/examples/cairo/Makefile
1159 tests/examples/equalizer/Makefile
1160 tests/examples/jack/Makefile
1161 tests/examples/level/Makefile
1162 tests/examples/pulse/Makefile
1163 tests/examples/rtp/Makefile
1164 tests/examples/shapewipe/Makefile
1165 tests/examples/spectrum/Makefile
1166 tests/examples/v4l2/Makefile
1167 tests/files/Makefile
1168 tests/icles/Makefile
1169 common/Makefile
1170 common/m4/Makefile
1171 m4/Makefile
1172 docs/Makefile
1173 docs/plugins/Makefile
1174 docs/version.entities
1175 pkgconfig/Makefile
1176 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1177 gst-plugins-good.spec
1178 )
1179
1180 dnl Create the config.h file for Visual Studio builds
1181 dnl Beware of spaces and /'s in some of the shell variable contents.
1182 sed \
1183     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1184     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1185     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1186     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1187     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1188     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1189     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1190     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1191     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1192     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1193     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1194     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1195     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1196     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1197     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1198     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1199     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1200     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1201     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1202     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1203     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1204     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1205     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1206     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1207     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1208     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1209     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1210     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1211     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1212     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1213     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1214     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1215     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1216     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1217     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1218     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1219     config.h.in >win32/common/config.h-new
1220
1221 AC_OUTPUT
1222
1223 AG_GST_OUTPUT_PLUGINS
1224 ORC_OUTPUT
1225