configure.ac

   1 m4_define(LIBUSB_MAJOR, [1])
   2 m4_define(LIBUSB_MINOR, [0])
   3 m4_define(LIBUSB_MICRO, [8])
   4
   5 AC_INIT([libusb], LIBUSB_MAJOR.LIBUSB_MINOR.LIBUSB_MICRO, [libusb-devel@lists.sourceforge.net], [libusb], [http://www.libusb.org/])
   6
   7 AC_SUBST([LIBUSB_VERSION_MAJOR], [LIBUSB_MAJOR])
   8 AC_SUBST([LIBUSB_VERSION_MINOR], [LIBUSB_MINOR])
   9 AC_SUBST([LIBUSB_VERSION_MICRO], [LIBUSB_MICRO])
  10
  11 # Library versioning
  12 # These numbers should be tweaked on every release. Read carefully:
  13 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  14 # http://sourceware.org/autobook/autobook/autobook_91.html
  15 lt_current="1"
  16 lt_revision="0"
  17 lt_age="1"
  18 LTLDFLAGS="-version-info ${lt_current}:${lt_revision}:${lt_age}"
  19
  20 AM_INIT_AUTOMAKE
  21 AM_MAINTAINER_MODE
  22
  23 AC_CONFIG_SRCDIR([libusb/core.c])
  24 AC_CONFIG_MACRO_DIR([m4])
  25 AM_CONFIG_HEADER([config.h])
  26 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  27
  28 AC_PREREQ([2.50])
  29 AC_PROG_CC
  30 AC_PROG_LIBTOOL
  31 AC_C_INLINE
  32 AM_PROG_CC_C_O
  33 AC_DEFINE([_GNU_SOURCE], 1, [Use GNU extensions])
  34
  35 LTLDFLAGS="${LTLDFLAGS} -no-undefined"
  36
  37 AC_MSG_CHECKING([operating system])
  38 case $host in
  39 *-linux*)
  40         AC_DEFINE(OS_LINUX, 1, [Linux backend])
  41         AC_SUBST(OS_LINUX)
  42         AC_MSG_RESULT([Linux])
  43         backend="linux"
  44         AC_CHECK_LIB(rt, clock_gettime, PC_LIBS_PRIVATE="-lrt")
  45         threads="posix"
  46         THREAD_CFLAGS="-pthread"
  47         PC_LIBS_PRIVATE="${PC_LIBS_PRIVATE} -pthread"
  48         AC_CHECK_HEADERS([poll.h])
  49         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
  50         ;;
  51 *-darwin*)
  52         AC_DEFINE(OS_DARWIN, 1, [Darwin backend])
  53         AC_SUBST(OS_DARWIN)
  54         AC_MSG_RESULT([Darwin/Mac OS X])
  55         backend="darwin"
  56         threads="posix"
  57         PC_LIBS_PRIVATE="-Wl,-framework,IOKit -Wl,-framework,CoreFoundation"
  58         LTLDFLAGS="${LTLDFLAGS} -Wl,-prebind"
  59         AC_CHECK_HEADERS([poll.h])
  60         AC_CHECK_TYPE([nfds_t],
  61                 [AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])],
  62                 [AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])],
  63                 [#include <poll.h>])
  64         ;;
  65 *-mingw*)
  66         AC_MSG_RESULT([Windows])
  67         backend="windows"
  68         ;;
  69 *-cygwin*)
  70         AC_MSG_RESULT([Cygwin (using Windows backend)])
  71         backend="windows"
  72         threads="posix"
  73         ;;
  74 *)
  75         AC_MSG_ERROR([unsupported operating system])
  76 esac
  77 if test "$backend" = windows; then
  78         AC_DEFINE(OS_WINDOWS, 1, [Windows backend])
  79         AC_SUBST(OS_WINDOWS)
  80         PC_LIBS_PRIVATE=""
  81         LTLDFLAGS="${LTLDFLAGS} -avoid-version -Wl,--add-stdcall-alias"
  82         AC_CHECK_TOOL(RC, windres, no)
  83         AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])
  84 fi
  85 AC_SUBST(THREAD_CFLAGS)
  86 AC_SUBST(PC_LIBS_PRIVATE)
  87 LIBS="${LIBS} ${PC_LIBS_PRIVATE}"
  88
  89 AM_CONDITIONAL(OS_LINUX, test "x$backend" = xlinux)
  90 AM_CONDITIONAL(OS_DARWIN, test "x$backend" = xdarwin)
  91 AM_CONDITIONAL(OS_WINDOWS, test "x$backend" = xwindows)
  92 AM_CONDITIONAL(THREADS_POSIX, test "x$threads" = xposix)
  93 if test "$threads" = posix; then
  94         AC_DEFINE(THREADS_POSIX, 1, [Use POSIX Threads])
  95 fi
  96
  97 # timerfd
  98 AC_CHECK_HEADER([sys/timerfd.h], [timerfd_h=1], [timerfd_h=0])
  99 AC_ARG_ENABLE([timerfd],
 100         [AS_HELP_STRING([--enable-timerfd],
 101                 [use timerfd for timing (default auto)])],
 102         [use_timerfd=$enableval], [use_timerfd='auto'])
 103
 104 if test "x$use_timerfd" = "xyes" -a "x$timerfd_h" = "x0"; then
 105         AC_MSG_ERROR([timerfd header not available; glibc 2.9+ required])
 106 fi
 107
 108 AC_CHECK_DECL([TFD_NONBLOCK], [tfd_hdr_ok=yes], [tfd_hdr_ok=no], [#include <sys/timerfd.h>])
 109 if test "x$use_timerfd" = "xyes" -a "x$tfd_hdr_ok" = "xno"; then
 110         AC_MSG_ERROR([timerfd header not usable; glibc 2.9+ required])
 111 fi
 112
 113 AC_MSG_CHECKING([whether to use timerfd for timing])
 114 if test "x$use_timerfd" = "xno"; then
 115         AC_MSG_RESULT([no (disabled by user)])
 116 else
 117         if test "x$timerfd_h" = "x1" -a "x$tfd_hdr_ok" = "xyes"; then
 118                 AC_MSG_RESULT([yes])
 119                 AC_DEFINE(USBI_TIMERFD_AVAILABLE, 1, [timerfd headers available])
 120         else
 121                 AC_MSG_RESULT([no (header not available)])
 122         fi
 123 fi
 124
 125 AC_CHECK_TYPES(struct timespec)
 126
 127 # Message logging
 128 AC_ARG_ENABLE([log], [AS_HELP_STRING([--disable-log], [disable all logging])],
 129         [log_enabled=$enableval],
 130         [log_enabled='yes'])
 131 if test "x$log_enabled" != "xno"; then
 132         AC_DEFINE([ENABLE_LOGGING], 1, [Message logging])
 133 fi
 134
 135 AC_ARG_ENABLE([debug-log], [AS_HELP_STRING([--enable-debug-log],
 136         [enable debug logging (default n)])],
 137         [debug_log_enabled=$enableval],
 138         [debug_log_enabled='no'])
 139 if test "x$debug_log_enabled" != "xno"; then
 140         AC_DEFINE([ENABLE_DEBUG_LOGGING], 1, [Debug message logging])
 141 fi
 142
 143 # Examples build
 144 AC_ARG_ENABLE([examples-build], [AS_HELP_STRING([--enable-examples-build],
 145         [build example applications (default n)])],
 146         [build_examples=$enableval],
 147         [build_examples='no'])
 148 AM_CONDITIONAL([BUILD_EXAMPLES], [test "x$build_examples" != "xno"])
 149
 150 # Restore gnu89 inline semantics on gcc 4.3 and newer
 151 saved_cflags="$CFLAGS"
 152 CFLAGS="$CFLAGS -fgnu89-inline"
 153 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])], inline_cflags="-fgnu89-inline", inline_cflags="")
 154 CFLAGS="$saved_cflags"
 155
 156 # check for -fvisibility=hidden compiler support (GCC >= 3.4)
 157 saved_cflags="$CFLAGS"
 158 # -Werror required for cygwin
 159 CFLAGS="$CFLAGS -Werror -fvisibility=hidden"
 160 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 161         [VISIBILITY_CFLAGS="-fvisibility=hidden"
 162          AC_DEFINE([DEFAULT_VISIBILITY], [__attribute__((visibility("default")))], [Default visibility]) ],
 163         [ VISIBILITY_CFLAGS=""
 164          AC_DEFINE([DEFAULT_VISIBILITY], [], [Default visibility]) ],
 165         ])
 166 CFLAGS="$saved_cflags"
 167
 168 # check for -Wno-pointer-sign compiler support (GCC >= 4)
 169 saved_cflags="$CFLAGS"
 170 CFLAGS="$CFLAGS -Wno-pointer-sign"
 171 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 172         nopointersign_cflags="-Wno-pointer-sign", nopointersign_cflags="")
 173 CFLAGS="$saved_cflags"
 174
 175 # sigaction not available on MinGW
 176 AC_CHECK_FUNC([sigaction], [have_sigaction=yes], [have_sigaction=no])
 177 AM_CONDITIONAL([HAVE_SIGACTION], [test "x$have_sigaction" = "xyes"])
 178
 179 # headers not available on all platforms but required on others
 180 AC_CHECK_HEADERS([sys/time.h])
 181
 182 AM_CFLAGS="-std=gnu99 $inline_cflags -Wall -Wundef -Wunused -Wstrict-prototypes -Werror-implicit-function-declaration $nopointersign_cflags -Wshadow"
 183
 184 AC_SUBST(VISIBILITY_CFLAGS)
 185 AC_SUBST(AM_CFLAGS)
 186 AC_SUBST(LTLDFLAGS)
 187
 188 AC_CONFIG_FILES([libusb-1.0.pc])
 189 AC_CONFIG_FILES([Makefile])
 190 AC_CONFIG_FILES([libusb/Makefile])
 191 AC_CONFIG_FILES([libusb/libusb-1.0.rc])
 192 AC_CONFIG_FILES([examples/Makefile])
 193 AC_CONFIG_FILES([doc/Makefile])
 194 AC_CONFIG_FILES([doc/doxygen.cfg])
 195 AC_OUTPUT