configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [0])
   5 m4_define([v_mic], [999])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v export || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 dnl m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-07])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  15 m4_define([lt_cur], m4_eval(v_maj + v_min))
  16 m4_define([lt_rev], v_mic)
  17 m4_define([lt_age], v_min)
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20
  21 AC_INIT([eina], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  22 AC_PREREQ([2.59])
  23 AC_CONFIG_SRCDIR([configure.ac])
  24 AC_CONFIG_MACRO_DIR([m4])
  25
  26 AC_CONFIG_HEADERS([config.h])
  27 AH_TOP([
  28 #ifndef EFL_CONFIG_H__
  29 #define EFL_CONFIG_H__
  30 ])
  31 AH_BOTTOM([
  32 #endif /* EFL_CONFIG_H__ */
  33 ])
  34
  35 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_GNU_SOURCE
  39 AC_SYS_LARGEFILE
  40
  41 AC_LIBTOOL_WIN32_DLL
  42 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  43 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  44 AC_PROG_LIBTOOL
  45
  46 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  47 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  48 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  49 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  50 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  51 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  52 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  53 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  54 version_info="lt_cur:lt_rev:lt_age"
  55 release_info="v_rel"
  56 AC_SUBST(version_info)
  57 AC_SUBST(release_info)
  58 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  59 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  60 VMAJ=v_maj
  61 AC_SUBST(VMAJ)
  62
  63
  64 ### Needed information
  65
  66 AC_CANONICAL_BUILD
  67 AC_CANONICAL_HOST
  68
  69 requirement_eina=""
  70
  71 case "$host_os" in
  72    mingw32ce*)
  73       MODULE_ARCH="$host_os-$host_cpu"
  74       ;;
  75    *)
  76       MODULE_ARCH="$host_os-$host_cpu-v_maj.v_min.v_mic"
  77       ;;
  78 esac
  79 AC_SUBST(MODULE_ARCH)
  80 AC_DEFINE_UNQUOTED(MODULE_ARCH, "${MODULE_ARCH}", "Module architecture")
  81
  82 case "$host_os" in
  83    mingw*)
  84       MODULE_EXT=".dll"
  85       ;;
  86    *)
  87       MODULE_EXT=".so"
  88       ;;
  89 esac
  90
  91 AC_DEFINE_UNQUOTED(SHARED_LIB_SUFFIX, "${MODULE_EXT}", [Suffix for shared objects])
  92
  93 EFL_CHECK_CPU_MMX([have_mmx="yes"], [have_mmx="no"])
  94 EFL_CHECK_CPU_SSE([have_sse="yes"], [have_sse="no"])
  95 EFL_CHECK_CPU_SSE2([have_sse2="yes"], [have_sse2="no"])
  96 EFL_CHECK_CPU_ALTIVEC([have_altivec="yes"], [have_altivec="no"])
  97
  98 EFL_CHECK_THREADS(
  99    [
 100     if test "x${_efl_have_posix_threads}" = "xyes" ; then
 101        have_threads="POSIX"
 102     else
 103        if test "x${_efl_have_win32_threads}" = "xyes" ; then
 104           have_threads="Win32"
 105        else
 106           have_threads="no"
 107        fi
 108     fi
 109    ],
 110    [have_threads="no"])
 111 EFL_CHECK_SPINLOCK([have_posix_threads_spinlock="yes"], [have_posix_threads_spinlock="no"])
 112
 113 if ! test "x${have_threads}" = "xno" ; then
 114    EINA_CONFIGURE_HAVE_THREADS="#define EINA_HAVE_THREADS"
 115 fi
 116 AC_SUBST(EINA_CONFIGURE_HAVE_THREADS)
 117 AM_CONDITIONAL([EINA_HAVE_THREADS], [! test "x${have_threads}" = "xno"])
 118
 119 if ! test "x${have_debug_threads}" = "xno"; then
 120    EINA_CONFIGURE_HAVE_DEBUG_THREADS="#define EINA_HAVE_DEBUG_THREADS"
 121 fi
 122 AC_SUBST(EINA_CONFIGURE_HAVE_DEBUG_THREADS)
 123 AM_CONDITIONAL([EINA_DEBUG_THREADS], [! test "x${have_debug_threads}" = "xno"])
 124
 125 if ! test "x${have_on_off_threads}" = "xno"; then
 126    EINA_CONFIGURE_HAVE_ON_OFF_THREADS="#define EINA_HAVE_ON_OFF_THREADS"
 127 fi
 128 AC_SUBST(EINA_CONFIGURE_HAVE_ON_OFF_THREADS)
 129 AM_CONDITIONAL([EINA_ON_OFF_THREADS], [! test "x${have_on_off_threads}" = "xno"])
 130
 131 ### Additional options to configure
 132
 133 # Magic debug
 134 AC_ARG_ENABLE([magic-debug],
 135    [AC_HELP_STRING([--disable-magic-debug], [disable magic debug of eina structure @<:@default=enabled@:>@])],
 136    [
 137     if test "x${enableval}" = "xyes" ; then
 138        have_magic_debug="yes"
 139     else
 140        have_magic_debug="no"
 141     fi
 142    ],
 143    [have_magic_debug="yes"])
 144
 145 AC_MSG_CHECKING([whether magic debug is enable])
 146 AC_MSG_RESULT([${have_magic_debug}])
 147
 148 if test "x${have_magic_debug}" = "xyes" ; then
 149    EINA_CONFIGURE_MAGIC_DEBUG="#define EINA_MAGIC_DEBUG"
 150 fi
 151 AC_SUBST(EINA_CONFIGURE_MAGIC_DEBUG)
 152
 153 # Safety checks (avoid crashes on wrong api usage)
 154 AC_ARG_ENABLE(safety-checks,
 155    [AC_HELP_STRING([--disable-safety-checks], [disable safety checks for NULL pointers and like. @<:@default=enabled@:>@])],
 156    [
 157     if test "x${enableval}" = "xyes" ; then
 158        have_safety_checks="yes"
 159     else
 160        have_safety_checks="no"
 161     fi
 162    ],
 163    [have_safety_checks="yes"])
 164
 165 AC_MSG_CHECKING(whether to do safety checking on api parameters)
 166 AC_MSG_RESULT($have_safety_checks)
 167
 168 AM_CONDITIONAL(SAFETY_CHECKS, test "x$have_safety_checks" = "xyes")
 169 if test "x$have_safety_checks" = "xyes"; then
 170   AC_DEFINE(EINA_SAFETY_CHECKS, 1, [disable safety checks for NULL pointers and like.])
 171   EINA_CONFIGURE_SAFETY_CHECKS="#define EINA_SAFETY_CHECKS"
 172 fi
 173 AC_SUBST(EINA_CONFIGURE_SAFETY_CHECKS)
 174
 175 with_max_log_level="<unset>"
 176 AC_ARG_WITH(internal-maximum-log-level,
 177    [AC_HELP_STRING([--with-internal-maximum-log-level=NUMBER],
 178                    [limit eina internal log level to the given number, any call to EINA_LOG() with values greater than this will be compiled out, ignoring runtime settings, but saving function calls.])],
 179    [
 180     if test "x${withval}" != "xno"; then
 181        if echo "${withval}" | grep '^[[0-9]]\+$' >/dev/null 2>/dev/null; then
 182           AC_MSG_NOTICE([ignoring any EINA_LOG() with level greater than ${withval}])
 183           AC_DEFINE_UNQUOTED(EINA_LOG_LEVEL_MAXIMUM, ${withval}, [if set, logging is limited to this amount.])
 184           with_max_log_level="${withval}"
 185        else
 186           AC_MSG_ERROR([--with-internal-maximum-log-level takes a decimal number, got "${withval}" instead.])
 187        fi
 188     fi
 189     ], [:])
 190
 191 AC_ARG_ENABLE([amalgamation],
 192    [AC_HELP_STRING([--enable-amalgamation], [enable generation of one single file with all source code in it, helps compiler optimizations.])],
 193    [if test "x${enableval}" = "xyes"; then
 194        do_amalgamation="yes"
 195     else
 196        do_amalgamation="no"
 197     fi
 198    ],
 199    [do_amalgamation="no"]
 200 )
 201 AM_CONDITIONAL(EINA_AMALGAMATION, test "x${do_amalgamation}" = "xyes")
 202
 203 # Choose best memory pool
 204 AC_ARG_ENABLE([default-mempool],
 205    [AC_HELP_STRING([--enable-default-mempool], [Default memory allocator could be faster for some computer. @<:@default=disabled@:>@])],
 206    [
 207     if test "x${enableval}" = "xyes"; then
 208        have_default_mempool="yes"
 209     else
 210        have_default_mempool="no"
 211     fi
 212    ],
 213    [have_default_mempool="no"]
 214 )
 215 AC_MSG_CHECKING([whether to use default mempool allocator])
 216 AC_MSG_RESULT([${have_default_mempool}])
 217
 218 if test "x${have_default_mempool}" = "xyes" ; then
 219    EINA_CONFIGURE_DEFAULT_MEMPOOL="#define EINA_DEFAULT_MEMPOOL"
 220 fi
 221 AC_SUBST(EINA_CONFIGURE_DEFAULT_MEMPOOL)
 222
 223 # Report stringshare usage
 224 AC_ARG_ENABLE([stringshare-usage],
 225    [AC_HELP_STRING([--enable-stringshare-usage], [Report stringshare usage on stringshare shutdown. @<:@default=disabled@:>@])],
 226    [
 227     if test "x${enableval}" = "xyes"; then
 228        have_stringshare_usage="yes"
 229     else
 230        have_stringshare_usage="no"
 231     fi
 232    ],
 233    [have_stringshare_usage="no"]
 234 )
 235 AC_MSG_CHECKING([whether to report stringshare usage])
 236 AC_MSG_RESULT([${have_stringshare_usage}])
 237
 238 if test "x${have_stringshare_usage}" = "xyes"; then
 239    AC_DEFINE(EINA_STRINGSHARE_USAGE, 1, [Report Eina stringshare usage pattern])
 240 fi
 241
 242 # Check if we want to benchmark on real data
 243 enable_benchmark_e17="no"
 244 AC_ARG_ENABLE([e17],
 245    [AC_HELP_STRING([--enable-e17], [enable heavy benchmark @<:@default=no@:>@])],
 246    [
 247     if test "x${enableval}" = "xyes" ; then
 248        enable_benchmark_e17="yes"
 249     else
 250        enable_benchmark_e17="no"
 251     fi
 252    ],
 253    [enable_benchmark_e17="no"])
 254
 255 AC_MSG_CHECKING([whether e17 real data benchmark are built])
 256 AC_MSG_RESULT([${enable_benchmark_e17}])
 257
 258 AM_CONDITIONAL(EINA_ENABLE_BENCHMARK_E17, test "x${enable_benchmark_e17}" = "xyes")
 259
 260
 261 ### Checks for programs
 262 AC_PROG_CC
 263 AC_PROG_CXX
 264
 265 # pkg-config
 266 PKG_PROG_PKG_CONFIG
 267
 268 # Check whether pkg-config supports Requires.private
 269 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 270    pkgconfig_requires_private="Requires.private"
 271 else
 272    pkgconfig_requires_private="Requires"
 273 fi
 274 AC_SUBST(pkgconfig_requires_private)
 275
 276 # doxygen program for documentation building
 277
 278 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 279
 280
 281 ### Checks for libraries
 282
 283 # Valgrind
 284 want_valgrind="auto"
 285 have_valgrind="no"
 286
 287 AC_ARG_ENABLE([valgrind],
 288   [AC_HELP_STRING([--enable-valgrind], [improve valgrind support by hinting it of our memory usages, having it to report proper mempool leaks.])],
 289   [want_valgrind=$enableval])
 290
 291 AC_MSG_CHECKING([whether to enable build with valgrind])
 292 AC_MSG_RESULT([${want_valgrind}])
 293
 294 if test "x${want_valgrind}" = "xyes" || test "x${want_valgrind}" = "xauto"; then
 295    PKG_CHECK_MODULES([VALGRIND],
 296       [valgrind >= 2.4.0],
 297       [
 298        requirement_eina="valgrind ${requirement_eina}"
 299        have_valgrind="yes"
 300       ],
 301       [
 302        AC_DEFINE([NVALGRIND], [1], [Valgrind support disabled])
 303        if test "x${want_valgrind}" = "xyes"; then
 304           AC_MSG_ERROR([Valgrind >= 2.4.0 is required])
 305        fi
 306       ])
 307 else
 308     AC_DEFINE([NVALGRIND], [1], [Valgrind support disabled])
 309 fi
 310
 311
 312 # Evil library for compilation on Windows CE
 313
 314 EFL_EINA_BUILD=""
 315 case "$host_os" in
 316    mingw*)
 317       PKG_CHECK_MODULES([EVIL], [evil])
 318       AC_DEFINE([HAVE_EVIL], [1], [Set to 1 if evil package is installed])
 319       requirement_eina="evil"
 320       EFL_EINA_BUILD="-DEFL_EINA_BUILD"
 321    ;;
 322 esac
 323 AC_SUBST([EFL_EINA_BUILD])
 324
 325 # Check ememoa memory pool library
 326
 327 AC_ARG_ENABLE([ememoa],
 328    [AC_HELP_STRING([--enable-ememoa], [build ememoa memory pool module @<:@default=yes@:>@])],
 329    [
 330     if test "x${enableval}" = "xyes" ; then
 331        enable_ememoa="yes"
 332     else
 333        enable_ememoa="no"
 334     fi
 335    ],
 336    [enable_ememoa="yes"])
 337
 338 AC_MSG_CHECKING([whether to use ememoa for memory pool])
 339 AC_MSG_RESULT([$enable_ememoa])
 340
 341 if test "x${enable_ememoa}" = "xyes" ; then
 342    PKG_CHECK_MODULES([EMEMOA],
 343       [ememoa >= 0.0.26 ],
 344       [enable_ememoa="yes"],
 345       [enable_ememoa="no"])
 346 fi
 347
 348 PKG_CHECK_MODULES([ECORE_EVAS],
 349    [ecore-evas ecore evas],
 350    [build_tiler_example="yes"],
 351    [build_tiler_example="no"])
 352
 353 AM_CONDITIONAL([BUILD_TILER_EXAMPLE], [test "x${build_tiler_example}" = "xyes"])
 354
 355
 356 ### Checks for header files
 357 AC_HEADER_ASSERT
 358 AC_HEADER_DIRENT
 359 AC_HEADER_TIME
 360 EFL_CHECK_PATH_MAX
 361 AC_CHECK_HEADERS([unistd.h libgen.h inttypes.h stdint.h sys/types.h siginfo.h])
 362
 363 if test "x${ac_cv_header_inttypes_h}" = "xyes" ; then
 364    EINA_CONFIGURE_HAVE_INTTYPES_H="#define EINA_HAVE_INTTYPES_H"
 365    AC_DEFINE([HAVE_INTTYPES_H], [1], [Define to 1 if you have the <inttypes.h> header file.])
 366 fi
 367 AC_SUBST([EINA_CONFIGURE_HAVE_INTTYPES_H])
 368
 369 if test "x${ac_cv_header_inttypes_h}" = "xyes" ; then
 370     EINA_CONFIGURE_HAVE_STDINT_H="#define EINA_HAVE_STDINT_H"
 371     AC_DEFINE([HAVE_STDINT_H], [1], [Define to 1 if you have the <stdint.h> header file.])
 372 fi
 373 AC_SUBST([EINA_CONFIGURE_HAVE_STDINT_H])
 374
 375 ### Checks for types
 376
 377 AC_CHECK_SIZEOF([wchar_t])
 378 EINA_SIZEOF_WCHAR_T=$ac_cv_sizeof_wchar_t
 379 AC_SUBST([EINA_SIZEOF_WCHAR_T])
 380 AC_CHECK_TYPES([siginfo_t], [], [],
 381    [[#include <signal.h>
 382      #if HAVE_SIGINFO_H
 383      # include <siginfo.h>
 384      #endif
 385    ]])
 386
 387 ### Checks for structures
 388
 389
 390 ### Checks for compiler characteristics
 391 AC_C_CONST
 392 AC_C_BIGENDIAN
 393 AC_C_INLINE
 394 AC_C___ATTRIBUTE__
 395 AC_PROG_CC_STDC
 396
 397 have_wince="no"
 398 have_win32="no"
 399 EINA_CPPFLAGS=""
 400 EINA_CFLAGS=""
 401 case "$host_os" in
 402    mingw32ce*)
 403       EINA_CPPFLAGS="-D_WIN32_WCE=0x0420"
 404       EINA_CFLAGS="${EVIL_CFLAGS}"
 405       have_win32="yes"
 406       have_wince="yes"
 407       ;;
 408    mingw*)
 409       EINA_CPPFLAGS="-D_WIN32_WINNT=0x0501"
 410       EINA_CFLAGS="${EVIL_CFLAGS}"
 411       have_win32="yes"
 412       ;;
 413 esac
 414 AM_CONDITIONAL([EINA_HAVE_WINCE], [test "x$have_wince" = "xyes"])
 415 AM_CONDITIONAL([EINA_HAVE_WIN32], [test "x$have_win32" = "xyes"])
 416
 417 m4_ifdef([v_mic],
 418    [
 419     EFL_COMPILER_FLAG([-Wall])
 420     EFL_COMPILER_FLAG([-W])
 421    ])
 422
 423 EFL_COMPILER_FLAG([-Wshadow])
 424
 425 AC_SUBST([EINA_CPPFLAGS])
 426 AC_SUBST([EINA_CFLAGS])
 427
 428
 429 ### Checks for linker characteristics
 430 EINA_LIBS=
 431 lt_enable_auto_import=""
 432 case "${host_os}" in
 433    mingw*)
 434       EINA_LIBS="-ldl ${EVIL_LIBS} -lm"
 435       lt_enable_auto_import="-Wl,--enable-auto-import"
 436    ;;
 437    dragonfly*|openbsd*)
 438       EINA_LIBS="-lm"
 439    ;;
 440    freebsd*|netbsd*)
 441       EINA_LIBS="-lrt -lm"
 442    ;;
 443    darwin*)
 444       EINA_LIBS="-lm"
 445    ;;
 446    cygwin*)
 447       EINA_LIBS="-ldl -lm"
 448    ;;
 449    *)
 450       EINA_LIBS="-ldl -lrt -lm"
 451    ;;
 452 esac
 453 AC_SUBST([EINA_LIBS])
 454 AC_SUBST([lt_enable_auto_import])
 455
 456 EFL_LINKER_FLAG([-fno-strict-aliasing])
 457
 458
 459 ### Checks for library functions
 460 AC_ISC_POSIX
 461 AC_FUNC_ALLOCA
 462 AC_CHECK_FUNCS([strlcpy dirfd openat fstatat fpathconf execvp])
 463
 464 # dlopen and dladdr
 465 dlopen_libs=""
 466 case "$host_os" in
 467    mingw*)
 468 # managed by evil
 469       AC_DEFINE([HAVE_DLADDR])
 470       AC_DEFINE([HAVE_DLOPEN])
 471       ;;
 472    *)
 473       AC_CHECK_FUNCS([dlopen], [res="yes"], [res="no"])
 474       if test "x${res}" = "xyes" ; then
 475          AC_CHECK_FUNCS([dladdr], [AC_DEFINE([HAVE_DLADDR])])
 476          AC_DEFINE([HAVE_DLOPEN])
 477       else
 478          AC_CHECK_LIB([dl], [dlopen], [res="yes"], [res="no"])
 479          if test "x${res}" = "xyes" ; then
 480             AC_CHECK_LIB([dl], [dladdr], [AC_DEFINE([HAVE_DLADDR])])
 481             AC_DEFINE(HAVE_DLOPEN)
 482             dlopen_libs="-ldl"
 483          fi
 484       fi
 485       ;;
 486 esac
 487 AC_SUBST([dlopen_libs])
 488
 489 EFL_CHECK_FNMATCH([], [AC_MSG_ERROR([Cannot find fnmatch()])])
 490
 491 # iconv library
 492 have_iconv="no"
 493 AC_ARG_WITH([iconv-link],
 494    AC_HELP_STRING([--with-iconv-link=ICONV_LINK], [explicitly specify an iconv link option]),
 495    [
 496     LIBS="$withval $LIBS"
 497     have_iconv="yes"
 498     iconv_libs=$withval
 499    ])
 500
 501 AC_MSG_CHECKING(for explicit iconv link options)
 502 if test "x${iconv_libs}" = "x" ; then
 503    AC_MSG_RESULT([no explicit iconv link option])
 504 else
 505    AC_MSG_RESULT([$iconv_libs])
 506 fi
 507
 508 if test "x${have_iconv}" = "xno" ; then
 509    AC_CHECK_HEADERS([iconv.h], [have_iconv="yes"])
 510
 511    if test "x${have_iconv}" = "xyes" ; then
 512       AC_MSG_CHECKING([whether iconv() is in libc])
 513
 514       AC_LINK_IFELSE(
 515          [AC_LANG_PROGRAM(
 516              [[
 517 #include <stdlib.h>
 518 #include <iconv.h>
 519              ]],
 520              [[
 521 iconv_t ic;
 522 size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 523              ]])],
 524          [have_iconv="yes"],
 525          [have_iconv="no"])
 526
 527       AC_MSG_RESULT([${have_iconv}])
 528    fi
 529
 530    if test "x${have_iconv}" = "xno" ; then
 531       AC_MSG_CHECKING([whether iconv() is in libiconv.a])
 532
 533       LIBS_save="${LIBS}"
 534       LIBS="-liconv $LIBS"
 535       AC_LINK_IFELSE(
 536          [AC_LANG_PROGRAM(
 537              [[
 538 #include <stdlib.h>
 539 #include <iconv.h>
 540              ]],
 541              [[
 542 iconv_t ic;
 543 size_t count;
 544 count = iconv(ic, NULL, NULL, NULL, NULL);
 545              ]])],
 546          [
 547           have_iconv="yes"
 548           iconv_libs="-liconv"
 549          ],
 550          [
 551           have_iconv="no"
 552           LIBS=${LIBS_save}
 553          ])
 554
 555       AC_MSG_RESULT([${have_iconv}])
 556    fi
 557
 558    if test "x${have_iconv}" = "xno" ; then
 559       AC_MSG_CHECKING([whether iconv() is in libiconv_plug.a])
 560
 561       LIBS_save="${LIBS}"
 562       LIBS="-liconv_plug $LIBS"
 563       AC_LINK_IFELSE(
 564          [AC_LANG_PROGRAM(
 565              [[
 566 #include <stdlib.h>
 567 #include <iconv.h>
 568              ]],
 569              [[
 570 iconv_t ic;
 571 size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 572              ]])],
 573          [
 574           have_iconv="yes"
 575           iconv_libs="-liconv_plug"
 576          ],
 577          [
 578           have_iconv="no"
 579           LIBS=${LIBS_save}
 580          ])
 581
 582       AC_MSG_RESULT([${have_iconv}])
 583    fi
 584 fi
 585
 586 AC_SUBST([iconv_libs])
 587
 588 if test "x${have_iconv}" = "xyes" ; then
 589    AC_DEFINE([HAVE_ICONV], [1], [Set to 1 if iconv library is installed])
 590 fi
 591
 592 # shmopen
 593 have_shmopen=no
 594 AC_MSG_CHECKING([for shm_open availability])
 595
 596 LIBS_save="${LIBS}"
 597 LIBS="${LIBS} -lrt"
 598 AC_LINK_IFELSE(
 599    [AC_LANG_PROGRAM(
 600        [[
 601 #include <sys/mman.h>
 602 #include <sys/stat.h>        /* For mode constants */
 603 #include <fcntl.h>           /* For O_* constants */
 604        ]],
 605        [[
 606 int fd;
 607
 608 fd = shm_open("/dev/null", O_RDONLY, S_IRWXU | S_IRWXG | S_IRWXO);
 609        ]])],
 610    [have_shmopen="yes"],
 611    [have_shmopen="no"])
 612
 613 LIBS="${LIBS_save}"
 614
 615 AC_MSG_RESULT([${have_shmopen}])
 616
 617 if test "x${have_shmopen}" = "xyes"; then
 618    AC_DEFINE([HAVE_SHMOPEN], [1], [Define to 1 if you have the `shm_open' function.])
 619    rt_libs="-lrt"
 620 fi
 621
 622 AC_SUBST([rt_libs])
 623
 624 # extended attribute
 625
 626 AC_MSG_CHECKING([for extended attributes])
 627
 628 AC_COMPILE_IFELSE(
 629    [AC_LANG_PROGRAM(
 630        [[
 631 #include <stdlib.h>
 632 #include <sys/types.h>
 633 #include <sys/xattr.h>
 634        ]],
 635        [[
 636 size_t tmp = listxattr("/", NULL, 0);
 637 tmp = getxattr("/", "user.ethumb.md5", NULL, 0);
 638 setxattr("/", "user.ethumb.md5", NULL, 0, 0);
 639        ]])],
 640    [
 641     AC_DEFINE([HAVE_XATTR], [1], [Define to 1 if you have the `listxattr', `setxattr' and `getxattr' functions.])
 642     have_xattr="yes"
 643    ],
 644    [have_xattr="no"])
 645
 646 AC_MSG_RESULT([${have_xattr}])
 647
 648 ### Modules
 649
 650 if test "x${have_default_mempool}" = "xyes" ; then
 651    enable_chained_pool="no"
 652    enable_pass_through="static"
 653 else
 654    enable_chained_pool="static"
 655    enable_pass_through="no"
 656 fi
 657
 658 enable_one_big="static"
 659
 660 EINA_CHECK_MODULE([chained-pool],   [${enable_chained_pool}], [chained pool])
 661 EINA_CHECK_MODULE([ememoa-fixed],   [${enable_ememoa}],       [ememoa fixed])
 662 EINA_CHECK_MODULE([ememoa-unknown], [${enable_ememoa}],       [ememoa unknown])
 663 EINA_CHECK_MODULE([fixed-bitmap],   [no],                     [fixed bitmap])
 664 EINA_CHECK_MODULE([pass-through],   [${enable_pass_through}], [pass through])
 665 EINA_CHECK_MODULE([buddy],          [no],                     [buddy])
 666 EINA_CHECK_MODULE([one-big],        [${enable_one_big}],      [one big])
 667
 668 ### Make the debug preprocessor configurable
 669
 670 ### Unit tests, coverage and benchmarking
 671
 672 EFL_CHECK_TESTS([enable_tests="yes"], [enable_tests="no"])
 673
 674 EFL_CHECK_COVERAGE([${enable_tests}], [enable_coverage="yes"], [enable_coverage="no"])
 675 EINA_CFLAGS="${EINA_CFLAGS} ${EFL_COVERAGE_CFLAGS}"
 676 EINA_LIBS="${EINA_LIBS} ${EFL_COVERAGE_LIBS}"
 677 if test "x$enable_coverage" = "xyes" ; then
 678    EINA_CFLAGS="${EINA_CFLAGS} ${EFL_DEBUG_CFLAGS}"
 679 fi
 680
 681 EFL_CHECK_BENCHMARK([enable_benchmark="yes"], [enable_benchmark="no"])
 682 EINA_BENCH_MODULE([glib], [${enable_benchmark}], [glib-2.0], [enable_benchmark_glib="yes"], [enable_benchmark_glib="no"])
 683 if test -n "$CXX" && test "x$enable_benchmark" = "xyes" ; then
 684    AC_DEFINE_UNQUOTED([CITYHASH_BENCH], [1], [enable bench tests for google hash method])
 685 fi
 686 AM_CONDITIONAL([CITYHASH_BENCH], [test -n "$CXX" && test "x$enable_benchmark" = "xyes"])
 687
 688 AC_SUBST(requirement_eina)
 689
 690 ### Build and install examples
 691 EFL_CHECK_BUILD_EXAMPLES([enable_build_examples="yes"], [enable_build_examples="no"])
 692 EFL_CHECK_INSTALL_EXAMPLES([enable_install_examples="yes"], [enable_install_examples="no"])
 693
 694 AC_CONFIG_FILES([
 695 Makefile
 696 eina.pc
 697 eina.spec
 698 doc/Makefile
 699 doc/Doxyfile
 700 src/Makefile
 701 src/include/Makefile
 702 src/include/eina_config.h
 703 src/lib/Makefile
 704 src/modules/Makefile
 705 src/modules/mp/Makefile
 706 src/modules/mp/chained_pool/Makefile
 707 src/modules/mp/ememoa_fixed/Makefile
 708 src/modules/mp/ememoa_unknown/Makefile
 709 src/modules/mp/pass_through/Makefile
 710 src/modules/mp/fixed_bitmap/Makefile
 711 src/modules/mp/buddy/Makefile
 712 src/modules/mp/one_big/Makefile
 713 src/tests/Makefile
 714 src/examples/Makefile
 715 ])
 716
 717 AC_OUTPUT
 718
 719 #####################################################################
 720 ## Info
 721
 722 echo
 723 echo
 724 echo
 725 echo "------------------------------------------------------------------------"
 726 echo "$PACKAGE $VERSION"
 727 echo "------------------------------------------------------------------------"
 728 echo
 729 echo
 730 echo "Configuration Options Summary:"
 731 echo
 732 echo "  Magic debug..........: ${have_magic_debug}"
 733 echo "  Safety checks........: ${have_safety_checks}"
 734 echo "  Maximum log level....: ${with_max_log_level}"
 735 echo "  Report string usage..: ${have_stringshare_usage}"
 736 echo "  Valgrind support.....: ${have_valgrind}"
 737 echo "  Default mempool......: ${have_default_mempool}"
 738 echo "  Thread Support.......: ${have_threads}"
 739 if test "${have_threads}" = "POSIX" ; then
 740 echo "    spinlock...........: ${have_posix_threads_spinlock}"
 741 echo "    debug usage........: ${have_debug_threads}"
 742 echo "    on/off support.....: ${have_on_off_threads}"
 743 fi
 744 echo "  Amalgamation.........: ${do_amalgamation}"
 745 echo "  Iconv support........: ${have_iconv}"
 746 echo "  File dirfd...........: ${ac_cv_func_dirfd}"
 747 echo "  File xattr...........: ${have_xattr}"
 748 echo
 749 echo "  Documentation........: ${build_doc}"
 750 echo "  Tests................: ${enable_tests}"
 751 echo "  Coverage.............: ${enable_coverage}"
 752 echo "  Examples.............: ${enable_build_examples}"
 753 echo "  Tiler Example........: ${build_tiler_example}"
 754 echo "  Examples installed...: ${enable_install_examples}"
 755 echo "  Benchmark............: ${enable_benchmark}"
 756 if test "x${enable_benchmark}" = "xyes" ; then
 757 echo "    Glib...............: ${enable_benchmark_glib}"
 758 echo "    E17 real data......: ${enable_benchmark_e17}"
 759 fi
 760 echo
 761 echo "  CPU Specific Extensions:"
 762 echo "    MMX................: ${have_mmx}"
 763 echo "    SSE................: ${have_sse}"
 764 echo "    SSE2...............: ${have_sse2}"
 765 echo "    ALTIVEC............: ${have_altivec}"
 766 echo
 767 echo "  Memory pools:"
 768 echo "    Buddy..............: ${enable_buddy}"
 769 echo "    Chained pool.......: ${enable_chained_pool}"
 770 echo "    Ememoa fixed.......: ${enable_ememoa_fixed}"
 771 echo "    Ememoa unknown.....: ${enable_ememoa_unknown}"
 772 echo "    Fixed bitmap.......: ${enable_fixed_bitmap}"
 773 echo "    One big............: ${enable_one_big}"
 774 echo "    Pass through.......: ${enable_pass_through}"
 775 echo
 776 echo "Compilation............: make (or gmake)"
 777 echo "  CPPFLAGS.............: $CPPFLAGS"
 778 echo "  CFLAGS...............: $CFLAGS"
 779 echo "  LDFLAGS..............: $LDFLAGS"
 780 echo
 781 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 782 echo "  prefix...............: $prefix"
 783 echo
 784 EFL_FORM_VOLTRON