configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT([GStreamer Base Plug-ins],[1.13.91],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-base])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl
  51 dnl Keep CURRENT as MINOR * 100 + MICRO
  52 dnl Ex : 1.0.0 => 0
  53 dnl      1.0.3 => 3
  54 dnl      1.1.0 => 100
  55 dnl      1.2.5 => 205
  56 dnl      1.10.9 (who knows) => 1009
  57 dnl
  58 dnl sets GST_LT_LDFLAGS
  59 AS_LIBTOOL(GST, 1391, 0, 1391)
  60
  61 dnl *** required versions of GStreamer stuff ***
  62 GST_REQ=1.13.91
  63
  64 dnl *** autotools stuff ****
  65
  66 dnl allow for different autotools
  67 AS_AUTOTOOLS_ALTERNATE
  68
  69 dnl Add parameters for aclocal
  70 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  71
  72 dnl set up gettext
  73 dnl the version check needs to stay here because autopoint greps for it
  74 AM_GNU_GETTEXT_VERSION([0.17])
  75 AM_GNU_GETTEXT([external])
  76 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  77
  78 dnl *** check for arguments to configure ***
  79
  80 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  81 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  82
  83 AG_GST_ARG_DEBUG
  84 AG_GST_ARG_PROFILING
  85 AG_GST_ARG_VALGRIND
  86 AG_GST_ARG_GCOV
  87
  88 AG_GST_ARG_EXAMPLES
  89
  90 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  91 AG_GST_ARG_WITH_PACKAGE_NAME
  92 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  93
  94 AG_GST_PKG_CONFIG_PATH
  95
  96 dnl let distro override plugin install helper path
  97 AC_ARG_WITH(install-plugins-helper,
  98   AS_HELP_STRING([--with-install-plugins-helper],[specify path of helper script to call to install plugins]),
  99   [
 100     case "${withval}" in
 101       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 103       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 104     esac
 105   ],
 106   [
 107     dnl Default value
 108     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 109   ]
 110 )
 111 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 112 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 113     [plugin install helper script])
 114 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 115
 116 AG_GST_ARG_WITH_PLUGINS
 117
 118 AG_GST_ARG_ENABLE_EXTERNAL
 119
 120 AG_GST_ARG_ENABLE_EXPERIMENTAL
 121
 122 dnl *** checks for platform ***
 123 AG_GST_PLATFORM
 124
 125 dnl * hardware/architecture *
 126
 127 dnl common/m4/gst-arch.m4
 128 dnl check CPU type
 129 AG_GST_ARCH
 130
 131 dnl check for large file support
 132 dnl affected plugins must include config.h
 133 AC_SYS_LARGEFILE
 134
 135 dnl *** checks for programs ***
 136
 137 dnl find a compiler
 138 AC_PROG_CC
 139 AC_PROG_CC_STDC
 140
 141 dnl check if the compiler supports '-c' and '-o' options
 142 AM_PROG_CC_C_O
 143
 144 dnl determine if c++ is available on this system
 145 AC_PROG_CXX
 146 dnl CXX may be set to some default even if no c++ compiler is available
 147 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 148 AC_LANG_PUSH([C++])
 149 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 150 AC_LANG_POP([C++])
 151 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 152 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 153
 154 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 155 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 156
 157 dnl check for gobject-introspection
 158 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 159
 160 dnl check for documentation tools
 161 GTK_DOC_CHECK([1.12])
 162 AG_GST_PLUGIN_DOCS([1.12])
 163
 164 dnl *** checks for libraries ***
 165
 166 dnl libm, for sin() etc.
 167 LT_LIB_M
 168 AC_SUBST(LIBM)
 169
 170 dnl check for pthreads
 171 AX_PTHREAD
 172
 173 dnl *** checks for header files ***
 174
 175 dnl check if we have ANSI C header files
 176 AC_HEADER_STDC
 177
 178 dnl check for GCC specific SSE headers
 179 dnl these are used by the speex resampler code
 180 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h smmintrin.h])
 181
 182 dnl also check which architecture we're on for building files with intrinsics
 183 dnl separately
 184 AC_CHECK_DECLS([__i386__], [HAVE_X86=1])
 185 AC_CHECK_DECLS([__x86_64__], [HAVE_X86=1])
 186
 187 dnl check for -m* compiler flags too
 188 SSE_CFLAGS="-msse"
 189 SSE2_CFLAGS="-msse2"
 190 SSE41_CFLAGS="-msse4.1"
 191
 192 AS_COMPILER_FLAG([$SSE_CFLAGS], [HAVE_SSE=1], [HAVE_SSE=0])
 193 AS_COMPILER_FLAG([$SSE2_CFLAGS], [HAVE_SSE2=1], [HAVE_SSE2=0])
 194 AS_COMPILER_FLAG([$SSE41_CFLAGS], [HAVE_SSE41=1], [HAVE_SSE41=0])
 195
 196 AM_CONDITIONAL(HAVE_X86, [test "x${HAVE_X86}" = "x1"])
 197
 198 AC_DEFINE_UNQUOTED(HAVE_SSE, [$HAVE_SSE], [SSE support is enabled])
 199 AC_DEFINE_UNQUOTED(HAVE_SSE2, [$HAVE_SSE2], [SSE2 support is enabled])
 200 AC_DEFINE_UNQUOTED(HAVE_SSE41, [$HAVE_SSE41], [SSE4.1 support is enabled])
 201
 202 AC_SUBST(SSE_CFLAGS)
 203 AC_SUBST(SSE2_CFLAGS)
 204 AC_SUBST(SSE41_CFLAGS)
 205
 206 dnl used in gst/tcp
 207 AC_CHECK_HEADERS([sys/socket.h],
 208   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 209 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 210
 211 dnl used in gst-libs/gst/rtsp
 212 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 213 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 214 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 215   WIN32_LIBS="-lws2_32"
 216   AC_SUBST(WIN32_LIBS)
 217 fi
 218
 219 dnl used in gst-libs/gst/pbutils and associated unit test
 220 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 221
 222 dnl checks for ARM NEON support
 223 dnl this instruction set is used by the speex resampler code
 224 AC_MSG_CHECKING(for ARM NEON support in current arch/CFLAGS)
 225 AC_LINK_IFELSE([
 226 AC_LANG_PROGRAM([[
 227   #include <arm_neon.h>
 228   int32x4_t testfunc(int16_t *a, int16_t *b) {
 229       asm volatile ("vmull.s16 q0, d0, d0" : : : "q0");
 230       return vmull_s16(vld1_s16(a), vld1_s16(b));
 231   }
 232 ]])],
 233 [
 234   AC_DEFINE(HAVE_ARM_NEON,[],[ARM NEON support is enabled])
 235   AC_MSG_RESULT(yes)
 236 ],
 237 [
 238   AC_MSG_RESULT(no)
 239 ])
 240
 241 dnl also, Windows does not have long long
 242 AX_CREATE_STDINT_H
 243
 244 dnl *** checks for functions ***
 245 AC_CHECK_FUNCS([localtime_r gmtime_r])
 246
 247 dnl *** checks for math functions ***
 248 LIBS_SAVE=$LIBS
 249 LIBS="$LIBS $LIBM"
 250 AC_CHECK_FUNCS(log2)
 251 LIBS=$LIBS_SAVE
 252
 253 dnl *** checks for types/defines ***
 254
 255 dnl *** checks for structures ***
 256
 257 dnl *** checks for compiler characteristics ***
 258
 259 dnl *** checks for library functions ***
 260
 261 dnl check for fseeko()
 262 AC_FUNC_FSEEKO
 263
 264 dnl Check for fast float to int casting as defined in C99
 265 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 266 save_libs=$LIBS
 267 LIBS="$LIBS $LIBM"
 268 AC_C99_FUNC_LRINT
 269 AC_C99_FUNC_LRINTF
 270 LIBS=$save_libs
 271
 272 dnl Check for a way to display the function name in debug output
 273 AG_GST_CHECK_FUNCTION
 274
 275 dnl *** checks for dependency libraries ***
 276
 277 dnl GLib
 278 GLIB_REQ=2.40.0
 279 AG_GST_GLIB_CHECK([$GLIB_REQ])
 280
 281 ORC_CHECK([0.4.24])
 282
 283 dnl checks for gstreamer
 284 dnl uninstalled is selected preferentially -- see pkg-config(1)
 285 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 286 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 287 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 288 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 289 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 290 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 291
 292 dnl Check for documentation xrefs
 293 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 294 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 295 AC_SUBST(GLIB_PREFIX)
 296 AC_SUBST(GST_PREFIX)
 297
 298 dnl check for gudev
 299 PKG_CHECK_MODULES(G_UDEV, gudev-1.0 , [
 300         AC_DEFINE([HAVE_GUDEV], 1, [Define if gudev is installed])
 301         HAVE_GUDEV="yes" ],
 302         [HAVE_GUDEV="no"])
 303
 304 AG_GST_GL_CHECKS
 305
 306 dnl GTK is optional and only used in examples
 307 HAVE_GTK=no
 308 HAVE_GTK_X11=no
 309 HAVE_GDK_PIXBUF=no
 310 GTK_REQ=3.10
 311 if test "x$BUILD_EXAMPLES" = "xyes"; then
 312   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 313   dnl some examples need gtk+-x11
 314   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 315   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 316   AC_SUBST(GTK_LIBS)
 317   AC_SUBST(GTK_CFLAGS)
 318
 319   PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0, HAVE_GDK_PIXBUF=yes, HAVE_GDK_PIXBUF=no)
 320   AC_SUBST(GDK_PIXBUF_LIBS)
 321   AC_SUBST(GDK_PIXBUF_CFLAGS)
 322 fi
 323 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 324 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 325 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 326 AM_CONDITIONAL(HAVE_GDK_PIXBUF, test "x$HAVE_GDK_PIXBUF" = "xyes")
 327
 328 HAVE_QT=no
 329 HAVE_QT_MOC=no
 330 dnl QT is optional and only used in examples
 331 PKG_CHECK_MODULES(QT, Qt5Gui Qt5Widgets, [
 332   HAVE_QT=yes
 333 ], [
 334   HAVE_QT=no
 335 ])
 336 if test "x$HAVE_QT" = "xyes"; then
 337   AC_CHECK_TOOL(QT_MOC, moc)
 338   AC_MSG_CHECKING([for Qt5 moc])
 339   mocversion=`$QT_MOC -v 2>&1`
 340   mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 341   if test x"$mocversiongrep" != x"$mocversion"; then
 342     AC_MSG_RESULT([no])
 343     # moc was not the qt5 one, try with moc-qt5
 344     AC_CHECK_TOOL(QT_MOC, moc-qt5)
 345     AC_MSG_CHECKING([for Qt5 moc-qt5])
 346     mocversion=`$QT_MOC -v 2>&1`
 347     mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 348     if test x"$mocversiongrep" != x"$mocversion"; then
 349       AC_CHECK_TOOL(QTCHOOSER, qtchooser)
 350       AC_MSG_CHECKING([for qtchooser])
 351       qt5tooldir=`QT_SELECT=qt5 qtchooser -print-env | grep QTTOOLDIR | cut -d '=' -f 2 | cut -d \" -f 2`
 352       mocversion=`$qt5tooldir/moc -v 2>&1`
 353       mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 354       if test x"$mocversiongrep" != x"$mocversion"; then
 355         # no valid moc found
 356         QT_MOC="no"
 357       else
 358         QT_MOC=$qt5tooldir/moc
 359       fi
 360     else
 361       QT_MOC=$QT_MOC
 362     fi
 363   fi
 364   AC_SUBST(QT_MOC)
 365   AC_MSG_RESULT([$QT_MOC])
 366 fi
 367 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 368 AM_CONDITIONAL(HAVE_QT_MOC, test "x$HAVE_QT_MOC" != "xno")
 369
 370 dnl Check for OpenGL example dependencies (clutter, sdl, etc.)
 371 AG_GST_GL_EXAMPLES_CHECKS
 372
 373 dnl chck for linux headers needed by the joystick seek example
 374 AC_COMPILE_IFELSE(
 375 [
 376   AC_LANG_PROGRAM([
 377     #include <linux/input.h>
 378     #include <linux/joystick.h>
 379   ],[
 380     struct js_event js;
 381     js.type = JS_EVENT_AXIS;
 382   ])
 383 ], [
 384   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 385 ], [
 386   HAVE_LINUX_JOYSTICK_HEADERS="no"
 387 ])
 388 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 389
 390 dnl Check for -Bsymbolic-functions linker flag used to avoid
 391 dnl intra-library PLT jumps, if available.
 392 AC_ARG_ENABLE(Bsymbolic,
 393               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 394               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 395                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 396                LDFLAGS=-Wl,-Bsymbolic-functions
 397                LIBS=
 398                AC_TRY_LINK([], [return 0],
 399                            AC_MSG_RESULT(yes)
 400                            enable_Bsymbolic=yes,
 401                            AC_MSG_RESULT(no)
 402                            enable_Bsymbolic=no)
 403                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 404
 405
 406 dnl *** set variables based on configure arguments ***
 407
 408 dnl set license and copyright notice
 409 GST_LICENSE="LGPL"
 410 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 411 AC_SUBST(GST_LICENSE)
 412
 413 dnl set location of plugin directory
 414 AG_GST_SET_PLUGINDIR
 415
 416 dnl set release date/time
 417 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 418   ["${srcdir}/gst-plugins-base.doap"],
 419   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 420
 421 dnl If only building static libraries, define GST_STATIC_COMPILATION. This is
 422 dnl needed only on Windows, but it doesn't hurt to have it everywhere.
 423 if test x$enable_static = xyes -a x$enable_shared = xno; then
 424   GST_STATIC_CFLAGS="-DGST_STATIC_COMPILATION"
 425 fi
 426
 427 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 428 dnl make sure it doesn't complain about unused variables if debugging is disabled
 429 NO_WARNINGS=""
 430 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 431
 432 dnl define an ERROR_CFLAGS Makefile variable
 433 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 434 dnl -Waggregate-return - xcb_intern_atom() returns an aggregate value
 435 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 436     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 437     -Wwrite-strings  -Wformat-nonliteral -Wformat-security
 438     -Winit-self -Wmissing-include-dirs -Waddress
 439     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 440
 441 dnl define an ERROR_CXXFLAGS Makefile variable
 442 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 443     -Wmissing-declarations -Wredundant-decls -Wundef
 444     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 445     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 446     -Wno-multichar $NO_WARNINGS])
 447
 448 dnl define correct level for debugging messages
 449 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 450
 451 dnl used in examples
 452 AG_GST_DEFAULT_ELEMENTS
 453
 454 dnl needed for encoding-target
 455 GST_DATADIR="$GST_PREFIX/share"
 456 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 457 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 458
 459 dnl behaviour of speex based audio resampler
 460 AC_MSG_CHECKING(which audio resample format to use for integer)
 461 AC_ARG_WITH([audioresample_format],
 462         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 463         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 464 AC_MSG_RESULT($ac_cv_audioresample_format)
 465 case $ac_cv_audioresample_format in
 466   int)
 467     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 468     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 469   ;;
 470   float)
 471     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 472     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 473   ;;
 474   auto)
 475     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 476     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 477 esac
 478
 479 dnl Check for mmap (needed by allocators library)
 480 AC_CHECK_FUNC([mmap], [AC_DEFINE(HAVE_MMAP, 1, [Defined if mmap is supported])])
 481
 482 dnl *** plug-ins to include ***
 483
 484 dnl these are all the gst plug-ins, compilable without additional libs
 485 AG_GST_CHECK_PLUGIN(adder)
 486 AG_GST_CHECK_PLUGIN(app)
 487 AG_GST_CHECK_PLUGIN(audioconvert)
 488 AG_GST_CHECK_PLUGIN(audiomixer)
 489 AG_GST_CHECK_PLUGIN(audiorate)
 490 AG_GST_CHECK_PLUGIN(audiotestsrc)
 491 AG_GST_CHECK_PLUGIN(encoding)
 492 AG_GST_CHECK_PLUGIN(videoconvert)
 493 AG_GST_CHECK_PLUGIN(gio)
 494 AG_GST_CHECK_PLUGIN(playback)
 495 AG_GST_CHECK_PLUGIN(audioresample)
 496 AG_GST_CHECK_PLUGIN(rawparse)
 497 AG_GST_CHECK_PLUGIN(subparse)
 498 AG_GST_CHECK_PLUGIN(tcp)
 499 AG_GST_CHECK_PLUGIN(typefind)
 500 AG_GST_CHECK_PLUGIN(videotestsrc)
 501 AG_GST_CHECK_PLUGIN(videorate)
 502 AG_GST_CHECK_PLUGIN(videoscale)
 503 AG_GST_CHECK_PLUGIN(volume)
 504
 505 dnl iso-codes is optional, used by libgsttag
 506 AC_ARG_ENABLE(iso-codes,
 507 AS_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 508 [case "${enableval}" in
 509   yes) enable_iso_codes=yes ;;
 510   no)  enable_iso_codes=no ;;
 511   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 512 esac
 513 ],
 514 [enable_iso_codes=yes]) dnl Default value
 515
 516 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 517 if test "x$enable_iso_codes" = "xyes"; then
 518   AC_MSG_RESULT([yes])
 519   have_iso_codes=no
 520   AC_MSG_CHECKING([whether iso-codes are available on this system])
 521   if $PKG_CONFIG iso-codes; then
 522     AC_MSG_RESULT([yes])
 523     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 524     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 525       AC_MSG_RESULT([yes])
 526       AC_MSG_CHECKING([for iso-codes prefix])
 527       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 528       if test -d "$ISO_CODES_PREFIX"; then
 529         AC_MSG_RESULT([yes])
 530         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 531         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 532         ISO_639_DOMAIN="iso_639"
 533         AC_MSG_CHECKING([ISO_639_DOMAIN])
 534         AC_MSG_RESULT([$ISO_639_DOMAIN])
 535         have_iso_codes=yes
 536         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 537         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 538         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 539         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 540       else
 541         AC_MSG_RESULT([no])
 542       fi
 543     else
 544       AC_MSG_RESULT([no])
 545     fi
 546   else
 547     AC_MSG_RESULT([no])
 548   fi
 549   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 550 else
 551   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 552   AM_CONDITIONAL(USE_ISO_CODES, false)
 553 fi
 554
 555 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 556 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 557 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 558   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 559       HAVE_ZLIB="yes"
 560     ], [
 561       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 562         HAVE_ZLIB="yes"
 563         ZLIB_LIBS="-lz"
 564         AC_SUBST(ZLIB_LIBS)
 565       ])
 566     ])
 567 ])
 568
 569 dnl *** sys plug-ins ***
 570
 571 echo
 572 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 573 echo
 574
 575 dnl *** X11 ***
 576 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 577 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 578                   [ximagesink], [
 579   AG_GST_PKG_CHECK_MODULES(X, x11)
 580 ])
 581
 582 dnl Check for Xv extension
 583 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 584 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 585                   [xvimagesink], [
 586   AG_GST_PKG_CHECK_MODULES(XVIDEO, x11 xv)
 587 ])
 588
 589 dnl check for X Shm
 590 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 591 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], [ ], [
 592   if test x$HAVE_X = xyes; then
 593     PKG_CHECK_MODULES(XSHM, xext, [
 594       AC_CHECK_LIB(Xext, XShmAttach, [
 595         HAVE_XSHM="yes"
 596       ], [
 597         HAVE_XSHM="no"
 598         XSHM_LIBS=""
 599       ], [ $X_LIBS ])
 600     ], [
 601       HAVE_XSHM="no"
 602     ])
 603   fi
 604 ], , [
 605   AC_SUBST(HAVE_XSHM)
 606   AC_SUBST(XSHM_LIBS)
 607 ])
 608
 609 dnl *** ext plug-ins ***
 610 dnl keep this list sorted alphabetically !
 611
 612 if test "x$BUILD_EXTERNAL" = "xyes"; then
 613
 614 echo
 615 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 616 echo
 617
 618 dnl *** alsa ***
 619 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 620 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 621   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 622     HAVE_ALSA="yes"
 623     AC_SUBST(ALSA_CFLAGS)
 624     AC_SUBST(ALSA_LIBS)
 625   ], [
 626     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 627   ])
 628 ])
 629
 630 dnl *** CDParanoia ***
 631 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 632 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 633 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 634   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 635     HAVE_CDPARANOIA="yes"
 636   ], [
 637     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 638                         cdda_open, -lm,
 639                         cdda_interface.h,
 640                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 641                         HEADER_DIR="no"
 642                         FOUND_CDPARANOIA="yes")
 643     if test "x$FOUND_CDPARANOIA" != "xyes";
 644     then
 645       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 646                           cdda_open, -lm,
 647                           cdda/cdda_interface.h,
 648                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 649                           HEADER_DIR="yes"
 650                           FOUND_CDPARANOIA="yes")
 651     fi
 652     if test "x$HEADER_DIR" = "xyes";
 653     then
 654       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 655                          defined if cdda headers are in a cdda/ directory)
 656     fi
 657     if test "x$FOUND_CDPARANOIA" = "xyes";
 658     then
 659       AC_CHECK_LIB(cdda_paranoia,
 660                    paranoia_cachemodel_size,
 661                    : ,
 662                    HAVE_CDPARANOIA=no,
 663                  [-lcdda_interface])
 664     fi
 665
 666     AC_SUBST(CDPARANOIA_LIBS)
 667   ])
 668 ])
 669 dnl FIXME : add second check somehow if that is necessary
 670 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 671 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 672
 673 dnl *** gl ***
 674 translit(dnm, m, l) AM_CONDITIONAL(USE_GL, true)
 675 AG_GST_CHECK_FEATURE(GL, [gl elements], gl, [
 676   HAVE_GL="no"
 677
 678   if test x"$USE_OPENGL" = x"yes" -o x"$USE_GLES2" = x"yes"; then
 679     HAVE_GL="yes"
 680     AG_GST_GL_PLUGIN_CHECKS
 681   fi
 682 ])
 683
 684 dnl *** ivorbis ***
 685 dnl AM_PATH_IVORBIS only takes two options
 686 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 687 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 688   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 689   if test $HAVE_IVORBIS = no
 690   then
 691     IVORBIS_LIBS=
 692     IVORBIS_CFLAGS=
 693     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 694       [IVORBIS_LIBS=-lvorbisidec
 695       HAVE_IVORBIS=yes
 696       case $host in
 697       arm-*-*)
 698         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 699       esac
 700       ],
 701       HAVE_IVORBIS=no)
 702     AC_SUBST(IVORBIS_LIBS)
 703     AC_SUBST(IVORBIS_CFLAGS)
 704   else
 705     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 706       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 707       USE_TREMOLO=no)
 708   fi
 709 ])
 710
 711 dnl *** libvisual ***
 712 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 713 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 714   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 715   if test x$HAVE_LIBVISUAL = xyes; then
 716     LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 717   fi
 718   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 719   if test x$LIBVIS_PLUGINSDIR != x; then
 720     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 721         "$LIBVIS_PLUGINSDIR",
 722         [directory in which the detected libvisual's plugins are located])
 723   fi
 724 ])
 725
 726 dnl *** ogg ***
 727 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 728 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 729   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 730 ])
 731
 732 dnl *** Opus ***
 733 translit(dnm, m, l) AM_CONDITIONAL(USE_OPUS, true)
 734 AG_GST_CHECK_FEATURE(OPUS, [opus], opus, [
 735   PKG_CHECK_MODULES(OPUS, opus >= 0.9.4, [
 736           AC_DEFINE([HAVE_OPUS], 1, [Define if Opus >= 0.9.4 is installed])
 737           HAVE_OPUS="yes"
 738   ], [
 739           HAVE_OPUS="no"
 740   ])
 741   AC_SUBST(OPUS_CFLAGS)
 742   AC_SUBST(OPUS_LIBS)
 743 ])
 744
 745 dnl *** pango ***
 746 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 747 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 748   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 749 ])
 750
 751 dnl *** theora ***
 752 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 753 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 754   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 755 ])
 756
 757 dnl *** vorbis ***
 758 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 759 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 760   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 761 ])
 762
 763 if test "x$HAVE_VORBIS" = "xyes"; then
 764   ac_cflags_save="$CFLAGS"
 765   AC_COMPILE_IFELSE([
 766     AC_LANG_PROGRAM([[
 767 #include <vorbis/codec.h>
 768                      ]],[[
 769 vorbis_dsp_state *v;
 770
 771 vorbis_synthesis_restart (v);
 772                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 773   if test "x$HAVE_VSR" = "xyes"; then
 774     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 775                        [defined if vorbis_synthesis_restart is present])
 776   fi
 777   CFLAGS="$ac_cflags_save"
 778 fi
 779
 780 else
 781
 782 dnl not building plugins with external dependencies,
 783 dnl but we still need to set the conditionals
 784 AM_CONDITIONAL(USE_ALSA, false)
 785 AM_CONDITIONAL(USE_CDPARANOIA, false)
 786 AM_CONDITIONAL(USE_GL, false)
 787 AM_CONDITIONAL(USE_IVORBIS, false)
 788 AM_CONDITIONAL(USE_LIBVISUAL, false)
 789 AM_CONDITIONAL(USE_OGG, false)
 790 AM_CONDITIONAL(USE_OPUS, false)
 791 AM_CONDITIONAL(USE_PANGO, false)
 792 AM_CONDITIONAL(USE_THEORA, false)
 793 AM_CONDITIONAL(USE_VORBIS, false)
 794
 795 fi dnl of EXT plugins
 796
 797 AM_CONDITIONAL(HAVE_GRAPHENE, test "x$HAVE_GRAPHENE" = "xyes")
 798 AM_CONDITIONAL(HAVE_PNG, test "x$HAVE_PNG" = "xyes")
 799 AM_CONDITIONAL(HAVE_JPEG, test "x$HAVE_JPEG" = "xyes")
 800
 801 dnl *** gio-unix-2.0 for tests/check/pipelines/tcp.c ***
 802 PKG_CHECK_MODULES(GIO_UNIX_2_0, gio-unix-2.0 >= 2.24,
 803     HAVE_GIO_UNIX_2_0="yes",
 804     HAVE_GIO_UNIX_2_0="no")
 805 AM_CONDITIONAL(USE_GIO_UNIX_2_0, test "x$HAVE_GIO_UNIX_2_0" = "xyes")
 806
 807 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 808
 809 dnl Overview:
 810 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 811 dnl GST_*:              flags shared by built objects to link against GStreamer
 812 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 813 dnl                          (compare to other modules) or for i18n
 814 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 815 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 816 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 817 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 818
 819 dnl GST_OPTION_CFLAGS
 820 if test "x$USE_DEBUG" = xyes; then
 821    PROFILE_CFLAGS="-g"
 822 fi
 823 AC_SUBST(PROFILE_CFLAGS)
 824
 825 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 826   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 827   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 828 else
 829   DEPRECATED_CFLAGS=""
 830 fi
 831 AC_SUBST(DEPRECATED_CFLAGS)
 832
 833 VISIBILITY_CFLAGS=""
 834 AS_COMPILER_FLAG([-fvisibility=hidden], [VISIBILITY_CFLAGS="-fvisibility=hidden"])
 835 AC_SUBST(VISIBILITY_CFLAGS)
 836
 837 VISIBILITY_CXXFLAGS=""
 838 if test "x$HAVE_CXX" = "xyes"; then
 839   AS_CXX_COMPILER_FLAG([-fvisibility=hidden], [VISIBILITY_CXXFLAGS="-fvisibility=hidden"])
 840 fi
 841 AC_SUBST(VISIBILITY_CXXFLAGS)
 842
 843 dnl disable strict aliasing
 844 AS_COMPILER_FLAG([-fno-strict-aliasing], [EXTRA_CFLAGS="-fno-strict-aliasing"])
 845 AC_SUBST(EXTRA_CFLAGS)
 846
 847 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 848 dnl at make time with e.g. make ERROR_CFLAGS=""
 849 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 850 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 851 AC_SUBST(GST_OPTION_CFLAGS)
 852 AC_SUBST(GST_OPTION_CXXFLAGS)
 853
 854 dnl our libraries need to be versioned correctly
 855 AC_SUBST(GST_LT_LDFLAGS)
 856
 857 dnl GST_PLUGINS_BASE_CFLAGS
 858 dnl prefer internal headers to already installed ones
 859 dnl also add builddir include for enumtypes and marshal
 860 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 861 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 862
 863 dnl FIXME: do we want to rename to GST_ALL_* ?
 864 dnl add GST_OPTION_CFLAGS, but overridable
 865 GST_CFLAGS="$GST_CFLAGS $GST_STATIC_CFLAGS"
 866 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS $EXTRA_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS) \$(VISIBILITY_CXXFLAGS)"
 867 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS $EXTRA_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS) \$(VISIBILITY_CFLAGS)"
 868 AC_SUBST(GST_CFLAGS)
 869 AC_SUBST(GST_CXXFLAGS)
 870 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 871 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 872 AC_SUBST(GST_LIBS)
 873
 874 dnl LDFLAGS really should only contain flags, not libs - they get added before
 875 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 876 GST_ALL_LDFLAGS="-no-undefined"
 877 if test "x${enable_Bsymbolic}" = "xyes"; then
 878   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 879 fi
 880 AC_SUBST(GST_ALL_LDFLAGS)
 881
 882 dnl GST_LIB_LDFLAGS
 883 dnl linker flags shared by all libraries
 884 dnl LDFLAGS modifier defining exported symbols from built libraries
 885 dnl (export _gst_foo but not __gst_foo)
 886 GST_LIB_LDFLAGS=""
 887 AC_SUBST(GST_LIB_LDFLAGS)
 888
 889 dnl this really should only contain flags, not libs - they get added before
 890 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 891 GST_PLUGIN_LDFLAGS="-module -avoid-version $GST_ALL_LDFLAGS"
 892 AC_SUBST(GST_PLUGIN_LDFLAGS)
 893
 894 dnl *** output files ***
 895
 896 $MKDIR_P tests/check/orc
 897
 898 AC_CONFIG_FILES(
 899 Makefile
 900 gst/Makefile
 901 gst/adder/Makefile
 902 gst/app/Makefile
 903 gst/audioconvert/Makefile
 904 gst/audiomixer/Makefile
 905 gst/audiorate/Makefile
 906 gst/audioresample/Makefile
 907 gst/audiotestsrc/Makefile
 908 gst/encoding/Makefile
 909 gst/videoconvert/Makefile
 910 gst/gio/Makefile
 911 gst/pbtypes/Makefile
 912 gst/playback/Makefile
 913 gst/rawparse/Makefile
 914 gst/subparse/Makefile
 915 gst/tcp/Makefile
 916 gst/typefind/Makefile
 917 gst/videotestsrc/Makefile
 918 gst/videorate/Makefile
 919 gst/videoscale/Makefile
 920 gst/volume/Makefile
 921 sys/Makefile
 922 sys/ximage/Makefile
 923 sys/xvimage/Makefile
 924 ext/Makefile
 925 ext/alsa/Makefile
 926 ext/cdparanoia/Makefile
 927 ext/gl/Makefile
 928 ext/libvisual/Makefile
 929 ext/ogg/Makefile
 930 ext/opus/Makefile
 931 ext/pango/Makefile
 932 ext/theora/Makefile
 933 ext/vorbis/Makefile
 934 gst-libs/Makefile
 935 gst-libs/gst/Makefile
 936 gst-libs/gst/allocators/Makefile
 937 gst-libs/gst/audio/Makefile
 938 gst-libs/gst/app/Makefile
 939 gst-libs/gst/fft/Makefile
 940 gst-libs/gst/gl/Makefile
 941 gst-libs/gst/gl/android/Makefile
 942 gst-libs/gst/gl/cocoa/Makefile
 943 gst-libs/gst/gl/dispmanx/Makefile
 944 gst-libs/gst/gl/glprototypes/Makefile
 945 gst-libs/gst/gl/eagl/Makefile
 946 gst-libs/gst/gl/egl/Makefile
 947 gst-libs/gst/gl/wayland/Makefile
 948 gst-libs/gst/gl/win32/Makefile
 949 gst-libs/gst/gl/x11/Makefile
 950 gst-libs/gst/gl/viv-fb/Makefile
 951 gst-libs/gst/gl/gbm/Makefile
 952 gst-libs/gst/riff/Makefile
 953 gst-libs/gst/rtp/Makefile
 954 gst-libs/gst/rtsp/Makefile
 955 gst-libs/gst/sdp/Makefile
 956 gst-libs/gst/tag/Makefile
 957 gst-libs/gst/pbutils/Makefile
 958 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 959 gst-libs/gst/video/Makefile
 960 tools/Makefile
 961 pkgconfig/Makefile
 962 pkgconfig/gstreamer-allocators.pc
 963 pkgconfig/gstreamer-allocators-uninstalled.pc
 964 pkgconfig/gstreamer-audio.pc
 965 pkgconfig/gstreamer-audio-uninstalled.pc
 966 pkgconfig/gstreamer-app.pc
 967 pkgconfig/gstreamer-app-uninstalled.pc
 968 pkgconfig/gstreamer-fft.pc
 969 pkgconfig/gstreamer-fft-uninstalled.pc
 970 pkgconfig/gstreamer-pbutils.pc
 971 pkgconfig/gstreamer-pbutils-uninstalled.pc
 972 pkgconfig/gstreamer-riff.pc
 973 pkgconfig/gstreamer-riff-uninstalled.pc
 974 pkgconfig/gstreamer-rtp.pc
 975 pkgconfig/gstreamer-rtp-uninstalled.pc
 976 pkgconfig/gstreamer-rtsp.pc
 977 pkgconfig/gstreamer-rtsp-uninstalled.pc
 978 pkgconfig/gstreamer-sdp.pc
 979 pkgconfig/gstreamer-sdp-uninstalled.pc
 980 pkgconfig/gstreamer-tag.pc
 981 pkgconfig/gstreamer-tag-uninstalled.pc
 982 pkgconfig/gstreamer-video.pc
 983 pkgconfig/gstreamer-video-uninstalled.pc
 984 pkgconfig/gstreamer-gl.pc
 985 pkgconfig/gstreamer-gl-uninstalled.pc
 986 pkgconfig/gstreamer-plugins-base.pc
 987 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 988 tests/Makefile
 989 tests/check/Makefile
 990 tests/examples/Makefile
 991 tests/examples/app/Makefile
 992 tests/examples/audio/Makefile
 993 tests/examples/decodebin_next/Makefile
 994 tests/examples/dynamic/Makefile
 995 tests/examples/encoding/Makefile
 996 tests/examples/fft/Makefile
 997 tests/examples/gio/Makefile
 998 tests/examples/gl/Makefile
 999 tests/examples/gl/generic/Makefile
1000 tests/examples/gl/generic/cube/Makefile
1001 tests/examples/gl/generic/doublecube/Makefile
1002 tests/examples/gl/generic/recordgraphic/Makefile
1003 tests/examples/gl/generic/cubeyuv/Makefile
1004 tests/examples/gl/qt/Makefile
1005 tests/examples/gl/gtk/Makefile
1006 tests/examples/gl/gtk/fxtest/Makefile
1007 tests/examples/gl/gtk/3dvideo/Makefile
1008 tests/examples/gl/gtk/switchvideooverlay/Makefile
1009 tests/examples/gl/gtk/filternovideooverlay/Makefile
1010 tests/examples/gl/gtk/filtervideooverlay/Makefile
1011 tests/examples/gl/cocoa/Makefile
1012 tests/examples/gl/sdl/Makefile
1013 tests/examples/gl/clutter/Makefile
1014 tests/examples/overlay/Makefile
1015 tests/examples/seek/Makefile
1016 tests/examples/snapshot/Makefile
1017 tests/examples/playback/Makefile
1018 tests/examples/playrec/Makefile
1019 tests/files/Makefile
1020 tests/icles/Makefile
1021 tests/icles/playback/Makefile
1022 docs/Makefile
1023 docs/libs/Makefile
1024 docs/plugins/Makefile
1025 docs/version.entities
1026 po/Makefile.in
1027 common/Makefile
1028 common/m4/Makefile
1029 m4/Makefile
1030 )
1031 AC_OUTPUT
1032
1033 AG_GST_OUTPUT_PLUGINS
1034 ORC_OUTPUT
1035