configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.7.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl FIXME: this macro doesn't actually work;
  42 dnl the generated libtool script has no support for the listed tags.
  43 dnl So this needs to be fixed first if we want to use this
  44 dnl AS_LIBTOOL_TAGS
  45
  46 AC_LIBTOOL_WIN32_DLL
  47 AM_PROG_LIBTOOL
  48
  49 dnl *** required versions of GStreamer stuff ***
  50 GST_REQ=0.10.18
  51 GSTPB_REQ=0.10.18
  52
  53 dnl *** autotools stuff ****
  54
  55 dnl allow for different autotools
  56 AS_AUTOTOOLS_ALTERNATE
  57
  58 dnl Add parameters for aclocal
  59 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  60
  61 dnl set up gettext
  62 dnl the version check needs to stay here because autopoint greps for it
  63 AM_GNU_GETTEXT_VERSION([0.11.5])
  64 AM_GNU_GETTEXT([external])
  65 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  66
  67 dnl *** check for arguments to configure ***
  68
  69 AG_GST_ARG_DEBUG
  70 AG_GST_ARG_PROFILING
  71 AG_GST_ARG_VALGRIND
  72 AG_GST_ARG_GCOV
  73
  74 AG_GST_ARG_EXAMPLES
  75
  76 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  77 AG_GST_ARG_WITH_PACKAGE_NAME
  78 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  79
  80 AG_GST_ARG_WITH_PLUGINS
  81
  82 AG_GST_ARG_ENABLE_EXTERNAL
  83
  84 AG_GST_ARG_ENABLE_EXPERIMENTAL
  85
  86 dnl *** checks for platform ***
  87
  88 dnl * hardware/architecture *
  89
  90 dnl common/m4/gst-arch.m4
  91 dnl check CPU type
  92 AG_GST_ARCH
  93
  94 dnl Determine endianness
  95 AC_C_BIGENDIAN
  96
  97 dnl *** checks for programs ***
  98
  99 dnl find a compiler
 100 AC_PROG_CC
 101
 102 dnl determine c++ compiler
 103 AC_PROG_CXX
 104 dnl determine if c++ is available on this system
 105 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 106
 107 dnl determine c++ preprocessor
 108 dnl FIXME: do we need this ?
 109 AC_PROG_CXXCPP
 110
 111 AS_PROG_OBJC
 112
 113 dnl check if the compiler supports '-c' and '-o' options
 114 AM_PROG_CC_C_O
 115
 116 dnl find an assembler
 117 AM_PROG_AS
 118
 119 dnl we require flex and bison for building the goom plugin
 120 AG_GST_BISON_CHECK
 121 AG_GST_FLEX_CHECK
 122
 123 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 124 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 125
 126 dnl check for gconftool-2
 127 dnl this macro defines an am conditional, so it needs to be run always
 128 AM_GCONF_SOURCE_2
 129
 130 dnl check for documentation tools
 131 GTK_DOC_CHECK([1.3])
 132 AS_PATH_PYTHON([2.1])
 133 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 134
 135 dnl *** checks for libraries ***
 136
 137 dnl check for libm, for sin()
 138 AC_CHECK_LIBM
 139 AC_SUBST(LIBM)
 140
 141 dnl *** checks for header files ***
 142
 143 dnl check if we have ANSI C header files
 144 AC_HEADER_STDC
 145
 146 dnl used by ext/wavpack
 147 AX_CREATE_STDINT_H
 148
 149 dnl used in gst/rtp/gstasteriskh263.c
 150 AC_CHECK_HEADERS([netinet/in.h])
 151 AC_CHECK_HEADERS([winsock2.h])
 152 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 153
 154 dnl used in gst/udp
 155 AC_CHECK_HEADERS([sys/time.h])
 156
 157 dnl *** checks for types/defines ***
 158
 159 dnl Check for FIONREAD ioctl declaration.  This check is needed
 160 dnl for the UDP plugin to build on Solaris
 161 GST_CHECK_FIONREAD
 162
 163 dnl *** checks for structures ***
 164
 165 dnl *** checks for compiler characteristics ***
 166
 167 dnl check if we have GCC inline-asm
 168 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 169 if test x$HAVE_GCC_ASM = xyes ; then
 170   AC_DEFINE(HAVE_GCC_ASM, 1,
 171     [Define if compiler supports gcc inline assembly])
 172 fi
 173 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 174
 175 dnl *** checks for library functions ***
 176
 177 LIBS_SAVE=$LIBS
 178 LIBS="$LIBS $LIBM"
 179 AC_CHECK_FUNCS(rint sinh cosh asinh)
 180 LIBS=$LIBS_SAVE
 181
 182 dnl Check for mmap (needed by electricfence plugin)
 183 AC_FUNC_MMAP
 184 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" == "xyes")
 185
 186 dnl *** checks for dependency libraries ***
 187
 188 dnl GLib is required
 189 AG_GST_GLIB_CHECK([2.12])
 190
 191 dnl liboil is required
 192 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 193 if test "x$HAVE_LIBOIL" != "xyes"; then
 194   AC_ERROR([liboil-0.3.8 or later is required])
 195 fi
 196
 197 dnl checks for gstreamer
 198 dnl uninstalled is selected preferentially -- see pkg-config(1)
 199 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 200 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 201 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 202 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 203 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 204 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ])
 205
 206 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 207 if test -z $GST_TOOLS_DIR; then
 208   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 209 fi
 210 AC_SUBST(GST_TOOLS_DIR)
 211
 212 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 213 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 214
 215 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 216
 217 dnl Check for documentation xrefs
 218 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 219 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 220 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 221 AC_SUBST(GLIB_PREFIX)
 222 AC_SUBST(GST_PREFIX)
 223 AC_SUBST(GSTPB_PREFIX)
 224
 225 dnl GTK is optional and used in examples
 226 HAVE_GTK=NO
 227 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 228 if test "x$HAVE_GTK_22" = "xyes"; then
 229   HAVE_GTK=yes
 230   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 231   AC_SUBST(GTK_VERSION)
 232   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 233   AC_SUBST(GTK_BASE_DIR)
 234   GDK_PIXBUF_LIBDIR=`$PKG_CONFIG --variable=libdir gdk-pixbuf-2.0`
 235   GDK_PIXBUF_PREFIXDIR=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 236   AC_SUBST(GTK_BASE_DIR)
 237 else
 238   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 239 fi
 240 if test "x$HAVE_GTK_20" = "xyes"; then
 241   HAVE_GTK=yes
 242 fi
 243 GTK_CFLAGS=$GTK2_CFLAGS
 244 GTK_LIBS=$GTK2_LIBS
 245 AC_SUBST(GTK_LIBS)
 246 AC_SUBST(GTK_CFLAGS)
 247 AC_SUBST(HAVE_GTK)
 248 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 249
 250 dnl should we install schemas ?
 251 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 252 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 253   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 254   if test x$GCONFTOOL = xno; then
 255     AC_MSG_WARN(Not installing GConf schemas)
 256     HAVE_GCONFTOOL="no"
 257   else
 258     HAVE_GCONFTOOL="yes"
 259   fi
 260   AC_SUBST(HAVE_GCONFTOOL)
 261 ])
 262
 263 dnl *** set variables based on configure arguments ***
 264
 265 dnl set license and copyright notice
 266 GST_LICENSE="LGPL"
 267 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 268 AC_SUBST(GST_LICENSE)
 269
 270 dnl set location of plugin directory
 271 AG_GST_SET_PLUGINDIR
 272
 273 dnl define an ERROR_CFLAGS Makefile variable
 274 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 275
 276 dnl define an ERROR_CXXFLAGS Makefile variable
 277 AG_GST_SET_ERROR_CXXFLAGS($GST_CVS)
 278
 279 dnl define correct level for debugging messages
 280 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 281
 282 dnl used in examples
 283 AG_GST_DEFAULT_ELEMENTS
 284
 285 dnl *** plug-ins to include ***
 286
 287 dnl these are all the gst plug-ins, compilable without additional libs
 288 dnl videofilter is at the top because others depend on it
 289 AG_GST_CHECK_PLUGIN(videofilter)
 290 AG_GST_CHECK_PLUGIN(alpha)
 291 AG_GST_CHECK_PLUGIN(apetag)
 292 AG_GST_CHECK_PLUGIN(audiofx)
 293 AG_GST_CHECK_PLUGIN(auparse)
 294 AG_GST_CHECK_PLUGIN(autodetect)
 295 AG_GST_CHECK_PLUGIN(avi)
 296 AG_GST_CHECK_PLUGIN(cutter)
 297 AG_GST_CHECK_PLUGIN(debug)
 298 AG_GST_CHECK_PLUGIN(effectv)
 299 AG_GST_CHECK_PLUGIN(equalizer)
 300 AG_GST_CHECK_PLUGIN(id3demux)
 301 AG_GST_CHECK_PLUGIN(icydemux)
 302 AG_GST_CHECK_PLUGIN(flx)
 303 AG_GST_CHECK_PLUGIN(goom)
 304 AG_GST_CHECK_PLUGIN(goom2k1)
 305 AG_GST_CHECK_PLUGIN(law)
 306 AG_GST_CHECK_PLUGIN(level)
 307 AG_GST_CHECK_PLUGIN(matroska)
 308 AG_GST_CHECK_PLUGIN(monoscope)
 309 AG_GST_CHECK_PLUGIN(multifile)
 310 AG_GST_CHECK_PLUGIN(multipart)
 311 AG_GST_CHECK_PLUGIN(qtdemux)
 312 AG_GST_CHECK_PLUGIN(rtp)
 313 AG_GST_CHECK_PLUGIN(rtsp)
 314 AG_GST_CHECK_PLUGIN(smpte)
 315 AG_GST_CHECK_PLUGIN(spectrum)
 316 AG_GST_CHECK_PLUGIN(udp)
 317 AG_GST_CHECK_PLUGIN(videobox)
 318 AG_GST_CHECK_PLUGIN(videocrop)
 319 AG_GST_CHECK_PLUGIN(videomixer)
 320 AG_GST_CHECK_PLUGIN(wavenc)
 321 AG_GST_CHECK_PLUGIN(wavparse)
 322
 323 dnl disable gst plugins we might not be able to build on this
 324 dnl platform: udp and rtsp (ugly but minimally invasive)
 325 dnl FIXME: maybe move to sys
 326 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 327 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 328
 329 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 330   AG_GST_DISABLE_PLUGIN(udp)
 331   AG_GST_DISABLE_PLUGIN(rtsp)
 332 fi
 333
 334 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 335   WIN32_LIBS="-lws2_32"
 336   AC_SUBST(WIN32_LIBS)
 337 fi
 338
 339 dnl disable experimental plug-ins
 340 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 341   AG_GST_DISABLE_PLUGIN(monoscope)
 342 fi
 343
 344 dnl *** sys plug-ins ***
 345
 346 echo
 347 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 348 echo
 349
 350 dnl DirectDraw
 351 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTDRAW, true)
 352 AG_GST_CHECK_FEATURE(DIRECTDRAW, [DirectDraw plug-in], directdrawsink, [
 353   HAVE_DIRECTDRAW="no"
 354   save_CFLAGS="$CFLAGS"
 355   save_LDFLAGS="$LDFLAGS"
 356   save_LIBS="$LIBS"
 357   CFLAGS="$CFLAGS $DIRECTDRAW_CFLAGS"
 358   LDFLAGS="$LDFLAGS $DIRECTDRAW_LDFLAGS"
 359   LIBS="$LIBS -lddraw -lgdi32"
 360   AC_MSG_CHECKING(for DirectDraw LDFLAGS)
 361   AC_LINK_IFELSE([
 362 #include <windows.h>
 363 #include <ddraw.h>
 364
 365 int main ()
 366 {
 367   GetStockObject(0);
 368   DirectDrawCreate(NULL, NULL, NULL);
 369
 370   return 0;
 371 }
 372 ],
 373     [HAVE_DIRECTDRAW="yes"],
 374     [HAVE_DIRECTDRAW="no"])
 375   AC_MSG_RESULT($HAVE_DIRECTDRAW)
 376   CFLAGS=$save_CFLAGS
 377   LDFLAGS=$save_LDFLAGS
 378   LIBS=$save_LIBS
 379
 380   if test "x$HAVE_DIRECTDRAW" = "xyes";  then
 381     dnl this is much more than we want
 382     DIRECTDRAW_LIBS="-lddraw -ldxguid -lgdi32"
 383     AC_SUBST(DIRECTDRAW_CFLAGS)
 384     AC_SUBST(DIRECTDRAW_LDFLAGS)
 385     AC_SUBST(DIRECTDRAW_LIBS)
 386   fi
 387   AC_SUBST(HAVE_DIRECTDRAW)
 388 ])
 389
 390 dnl DirectSound
 391 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 392 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 393   HAVE_DIRECTSOUND="no"
 394   save_CFLAGS="$CFLAGS"
 395   save_LDFLAGS="$LDFLAGS"
 396   save_LIBS="$LIBS"
 397   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 398   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 399   LIBS="$LIBS -ldsound -ldxerr9"
 400   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 401   AC_LINK_IFELSE([
 402 #include <windows.h>
 403 #include <dxerr9.h>
 404 #include <dsound.h>
 405
 406 int main ()
 407 {
 408   DXGetErrorString9 (0);
 409   DirectSoundCreate(NULL, NULL, NULL);
 410
 411   return 0;
 412 }
 413 ],
 414     [HAVE_DIRECTSOUND="yes"],
 415     [HAVE_DIRECTSOUND="no"])
 416   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 417   CFLAGS=$save_CFLAGS
 418   LDFLAGS=$save_LDFLAGS
 419   LIBS=$save_LIBS
 420
 421   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 422     dnl this is much more than we want
 423     DIRECTSOUND_LIBS="-ldsound -ldxerr9"
 424     AC_SUBST(DIRECTSOUND_CFLAGS)
 425     AC_SUBST(DIRECTSOUND_LDFLAGS)
 426     AC_SUBST(DIRECTSOUND_LIBS)
 427   fi
 428   AC_SUBST(HAVE_DIRECTSOUND)
 429 ])
 430
 431 dnl *** OSS audio *** (Linux, *BSD)
 432 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 433 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 434  HAVE_OSS="yes"
 435 dnl Linux and newer BSD versions :
 436  AC_CHECK_HEADER(sys/soundcard.h, [
 437    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 438    ] , [
 439 dnl Some old BSD versions and also newer OpenBSD versions :
 440    AC_CHECK_HEADER(soundcard.h, [
 441      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 442      ], [
 443   dnl Some old BSD versions :
 444      AC_CHECK_HEADER(machine/soundcard.h, [
 445        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 446          [Define if OSS includes are in /machine/])
 447        ], [
 448        HAVE_OSS="no"
 449      ])
 450    ])
 451  ])
 452 ])
 453
 454 dnl *** Sun Audio ***
 455 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 456 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 457   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 458 ])
 459
 460 dnl *** OSX Audio ***
 461 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 462 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 463   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 464 ])
 465
 466 dnl *** OS X video ***
 467 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 468 HAVE_OSX_VIDEO="no"
 469 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 470   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 471 ])
 472 dnl in case header OpenGL/gl.h is found on other platforms
 473 case "$host" in
 474   *-*darwin*)
 475     dnl do nothing
 476     ;;
 477   *)
 478     HAVE_OSX_VIDEO="no"
 479     ;;
 480 esac
 481
 482
 483 dnl *** Video 4 Linux 2 ***
 484 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 485 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 486 USE_GST_V4L2=$BUILD_EXPERIMENTAL
 487 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 488 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 489   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 490   AC_TRY_COMPILE([
 491 #include <sys/types.h>
 492 #ifdef __sun /* Solaris */
 493 #include <sys/types.h>
 494 #include <sys/videodev2.h>
 495 #else /* Linux */
 496 #include <linux/types.h>
 497 #define _LINUX_TIME_H
 498 #define __user
 499 #include <linux/videodev2.h>
 500 #endif
 501 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 502 #error too early v4l2 version or no v4l2 at all
 503 #endif
 504     ], [
 505 return 0;
 506     ], [
 507       HAVE_GST_V4L2="yes"
 508       AC_MSG_RESULT(yes)
 509     ], [
 510       HAVE_GST_V4L2="no"
 511       AC_MSG_RESULT(no)
 512
 513       HAVE_VIDEODEV=no
 514       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 515       [
 516         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 517       ])
 518
 519       if test "x$HAVE_VIDEODEV" = "xyes"; then
 520         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 521         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 522       else
 523         AC_MSG_WARN([video4linux2 was not found])
 524       fi
 525     ])
 526
 527   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 528     dnl check for missing v4l2_buffer declaration (see #135919)
 529     MISSING_DECL=0
 530     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 531     AC_TRY_COMPILE([
 532 #include <sys/types.h>
 533 #ifdef __sun /* Solaris */
 534 #include <sys/types.h>
 535 #include <sys/videodev2.h>
 536 #else /* Linux */
 537 #include <linux/types.h>
 538 #define _LINUX_TIME_H
 539 #define __user
 540 #include <linux/videodev2.h>
 541 #endif
 542     ],[
 543 struct v4l2_buffer buf;
 544 buf.index = 0;
 545 return 0;
 546     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 547     if [ test x$MISSING_DECL = x1 ]; then
 548       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 549     fi
 550
 551     dnl check for XOverlay libraries
 552     AG_GST_CHECK_XV
 553   fi
 554 ])
 555
 556 dnl Check for X11
 557 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 558 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 559                   [ximagesrc], [
 560   AC_PATH_XTRA
 561
 562   dnl now try to find the HEADER
 563   ac_cflags_save="$CFLAGS"
 564   ac_cppflags_save="$CPPFLAGS"
 565   CFLAGS="$CFLAGS $X_CFLAGS"
 566   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 567   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 568
 569   if test "x$HAVE_X" = "xno"
 570   then
 571     AC_MSG_NOTICE([cannot find X11 development files])
 572   else
 573     dnl this is much more than we want
 574     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 575     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 576     dnl it does not add the libs; therefore we add them here
 577     X_LIBS="$X_LIBS -lX11"
 578     AC_SUBST(X_CFLAGS)
 579     AC_SUBST(X_LIBS)
 580
 581     dnl check for Xfixes
 582     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 583     if test "x$HAVE_XFIXES" = "xyes"
 584     then
 585         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 586     fi
 587     AC_SUBST(XFIXES_LIBS)
 588     AC_SUBST(XFIXES_CFLAGS)
 589
 590     dnl check for Xdamage
 591     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 592     if test "x$HAVE_XDAMAGE" = "xyes"
 593     then
 594         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 595     fi
 596     AC_SUBST(XDAMAGE_LIBS)
 597     AC_SUBST(XDAMAGE_CFLAGS)
 598   fi
 599   AC_SUBST(HAVE_X)
 600   CFLAGS="$ac_cflags_save"
 601   CPPFLAGS="$ac_cppflags_save"
 602 ])
 603
 604 dnl FIXME: this should be rolled into the test above, it's just an additional
 605 dnl feature of the ximagesrc plug-in
 606 dnl This is the same as in gst-plugins-base
 607 dnl check for X Shm
 608 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 609 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 610   if test x$HAVE_X = xyes; then
 611     AC_CHECK_LIB(Xext, XShmAttach,
 612                  HAVE_XSHM="yes", HAVE_XSHM="no",
 613                  $X_LIBS)
 614     if test "x$HAVE_XSHM" = "xyes"; then
 615       XSHM_LIBS="-lXext"
 616     else
 617       dnl On AIX, it is in XextSam instead, but we still need -lXext
 618       AC_CHECK_LIB(XextSam, XShmAttach,
 619                    HAVE_XSHM="yes", HAVE_XSHM="no",
 620                    $X_LIBS)
 621       if test "x$HAVE_XSHM" = "xyes"; then
 622         XSHM_LIBS="-lXext -lXextSam"
 623       fi
 624     fi
 625   fi
 626 ], ,[
 627   AC_SUBST(HAVE_XSHM)
 628   AC_SUBST(XSHM_LIBS)
 629 ])
 630
 631 dnl for V4L2, we also need to know if we have XVIDEO
 632 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 633 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 634                   [], [
 635   AG_GST_CHECK_XV
 636 ])
 637
 638 dnl *** ext plug-ins ***
 639 dnl keep this list sorted alphabetically !
 640
 641 if test "x$BUILD_EXTERNAL" = "xyes"; then
 642
 643 echo
 644 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 645 echo
 646
 647 dnl *** aalib ***
 648 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 649 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 650   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 651   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 652 ])
 653
 654 dnl *** annodex ***
 655 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 656 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 657   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 658 ])
 659
 660 dnl *** cairo ***
 661 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 662 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 663   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 664 ])
 665
 666 dnl *** cdio ***
 667 translit(dnm, m, l) AM_CONDITIONAL(USE_CDIO, true)
 668 AG_GST_CHECK_FEATURE(CDIO, [cdio library], cdio, [
 669   AG_GST_PKG_CHECK_MODULES(CDIO, libcdio >= 0.71)
 670 ])
 671
 672 dnl **** ESound ****
 673 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 674 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 675   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 676   if test $HAVE_ESD = no
 677   then
 678     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 679     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 680   fi
 681 ])
 682
 683 dnl *** FLAC ***
 684 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 685 AC_TRY_COMPILE([#include <FLAC/export.h>], [
 686   #if FLAC_API_VERSION_CURRENT < 8
 687   #error "legacy flac API"
 688   #endif
 689   ], [ legacy_flac=no ], [ legacy_flac=yes ], [ legacy_flac=no ])
 690
 691 if test "x$legacy_flac" = "xyes"; then
 692 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 693   AG_GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__seekable_stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC -lm")
 694   dnl API change in FLAC 1.1.1, so require that...
 695   dnl (this check will also fail with FLAC 1.1.3 which changed API again)
 696   if test x$HAVE_FLAC = xyes; then
 697     AC_CHECK_DECL(FLAC__SEEKABLE_STREAM_ENCODER_TELL_ERROR,
 698                   HAVE_FLAC="yes", HAVE_FLAC="no", [
 699 #include <FLAC/seekable_stream_encoder.h>
 700                   ])
 701   fi
 702   AC_SUBST(FLAC_LIBS)
 703 ])
 704 else
 705 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 706   AG_GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC -lm")
 707   dnl API change in FLAC 1.1.3, so require that...
 708   if test x$HAVE_FLAC = xyes; then
 709     AC_CHECK_DECL(FLAC__STREAM_ENCODER_TELL_STATUS_ERROR,
 710                   HAVE_FLAC="yes", HAVE_FLAC="no", [
 711 #include <FLAC/stream_encoder.h>
 712                   ])
 713   fi
 714   AC_SUBST(FLAC_LIBS)
 715 ])
 716 fi
 717
 718 dnl *** GConf ***
 719 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 720 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 721   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 722 ])
 723
 724 dnl *** GDK pixbuf ***
 725 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 726 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 727   if test $HAVE_GTK_22 = "yes"; then HAVE_GDK_PIXBUF=yes; fi;
 728 ])
 729
 730 dnl *** HAL ***
 731 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 732 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 733   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 734 ])
 735
 736 dnl *** jpeg ***
 737 dnl FIXME: we could use header checks here as well IMO
 738 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 739 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 740   AC_ARG_WITH(jpeg-mmx,
 741     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 742   OLD_LIBS="$LIBS"
 743   if test x$with_jpeg_mmx != x; then
 744     LIBS="$LIBS -L$with_jpeg_mmx"
 745   fi
 746   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 747   JPEG_LIBS="$LIBS -ljpeg-mmx"
 748   LIBS="$OLD_LIBS"
 749   if test x$HAVE_JPEG != xyes; then
 750     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 751     JPEG_LIBS="-ljpeg"
 752   fi
 753   AC_SUBST(JPEG_LIBS)
 754 ])
 755
 756 dnl *** ladspa ***
 757 translit(dnm, m, l) AM_CONDITIONAL(USE_LADSPA, true)
 758 AG_GST_CHECK_FEATURE(LADSPA, [ladspa], ladspa, [
 759   AC_CHECK_HEADER(ladspa.h, HAVE_LADSPA="yes", HAVE_LADSPA="no")
 760 ], disabled)
 761
 762 dnl *** libcaca ***
 763 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 764 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 765   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 766   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 767   if test "x$HAVE_LIBCACA" != "xyes"; then
 768     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 769     dnl see if it compilation works too, might not if we are cross-compiling
 770     if test "x$HAVE_LIBCACA" = "xyes"; then
 771       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 772                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 773     fi
 774   fi
 775 ])
 776
 777 dnl *** libdv ***
 778 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 779 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 780   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 781 ])
 782
 783 dnl *** libpng ***
 784 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 785 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 786   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng12)
 787 ])
 788
 789 dnl *** dv1394 ***
 790 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 791 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 792   dnl first test for libraw1394 >= 1.2.1
 793   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.2.1)
 794   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 795   dnl now see how far we got
 796   if test x$HAVE_RAW1394 = xyes && \
 797      test x$HAVE_LIBIEC61883 = xyes; then
 798        AG_GST_CHECK_LIBHEADER(AVC1394,
 799         avc1394, avc1394_send_command, $RAW1394_LIBS,
 800         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 801        AG_GST_CHECK_LIBHEADER(ROM1394,
 802         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 803         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 804        if test x$HAVE_AVC1394 = xyes && \
 805           test x$HAVE_AVC1394 = xyes && \
 806           test x$HAVE_ROM1394 = xyes; then
 807           HAVE_DV1394=yes
 808           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 809           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 810           AC_SUBST(DV1394_CFLAGS)
 811           AC_SUBST(DV1394_LIBS)
 812         fi
 813   else
 814        if test x$HAVE_RAW1394 = xno; then
 815           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 816           AG_GST_CHECK_LIBHEADER(AVC1394,
 817            avc1394, avc1394_send_command, $RAW1394_LIBS,
 818            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 819           AG_GST_CHECK_LIBHEADER(ROM1394,
 820            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 821            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 822           if test x$HAVE_RAW1394 = xyes && \
 823              test x$HAVE_AVC1394 = xyes && \
 824              test x$HAVE_ROM1394 = xyes; then
 825              HAVE_DV1394=yes
 826              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 827              DV1394_CFLAGS="$RAW1394_CFLAGS"
 828              if test x$HAVE_LIBIEC61883 = xyes; then
 829                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 830                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 831              fi
 832              AC_SUBST(DV1394_CFLAGS)
 833              AC_SUBST(DV1394_LIBS)
 834            fi
 835          fi
 836   fi
 837 ])
 838
 839 dnl *** shout2 ***
 840 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 841 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 842   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 843   if test $HAVE_SHOUT2 = no
 844   then
 845     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 846     AC_SUBST(SHOUT2_CFLAGS)
 847     AC_SUBST(SHOUT2_LIBS)
 848   fi
 849 ])
 850
 851 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 852 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 853 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 854 dnl   speex_jitter.h is 1.1.x only
 855 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 856 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 857   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 858   if test $HAVE_SPEEX = no
 859   then
 860     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 861       AC_CHECK_HEADER(speex/speex_jitter.h, [
 862         dnl speex 1.1.x :
 863         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 864           dnl speex 1.1.5 or + :
 865           HAVE_SPEEX="yes"
 866           SPEEX_LIBS="-lspeex"
 867           AC_SUBST(SPEEX_CFLAGS)
 868           AC_SUBST(SPEEX_LIBS)
 869         ],[
 870           HAVE_SPEEX="no"
 871         ])
 872       ],[
 873         dnl speex 1.0.x :
 874           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 875             dnl speex 1.0.4
 876             HAVE_SPEEX="yes"
 877             SPEEX_LIBS="-lspeex"
 878             AC_SUBST(SPEEX_CFLAGS)
 879             AC_SUBST(SPEEX_LIBS)
 880
 881             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 882               [defined if speex 1.0.x API detected])
 883         ],[
 884             HAVE_SPEEX="no"
 885             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 886         ], [
 887 #include <speex/speex.h>
 888         ])
 889       ])
 890     ])
 891   fi
 892 ])
 893
 894 dnl *** taglib ***
 895 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 896 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 897   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.4)
 898   if test "x$HAVE_CXX" != "xyes"; then
 899     USE_TAGLIB=false
 900     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 901   fi
 902 ])
 903
 904 dnl *** wavpack ***
 905 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 906 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 907   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 908     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 909       HAVE_WAVPACK=yes
 910       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 911     ],[
 912       HAVE_WAVPACK=no
 913       AC_MSG_RESULT(no)
 914     ])
 915   ])
 916   AC_SUBST(WAVPACK_CFLAGS)
 917   AC_SUBST(WAVPACK_LIBS)
 918 ])
 919
 920 dnl *** qtdemux & id3demux prefer to have zlib ***
 921 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 922 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux],, [
 923   AG_GST_CHECK_LIBHEADER(ZLIB,
 924     z, uncompress,, zlib.h, [
 925     HAVE_ZLIB="yes"
 926     ZLIB_LIBS="-lz"
 927     AC_SUBST(ZLIB_LIBS)
 928   ])
 929 ])
 930
 931 else
 932
 933 dnl not building plugins with external dependencies,
 934 dnl but we still need to set the conditionals
 935 AM_CONDITIONAL(USE_GCONFTOOL, false)
 936 AM_CONDITIONAL(USE_DIRECTDRAW, false)
 937 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 938 AM_CONDITIONAL(USE_OSS, false)
 939 AM_CONDITIONAL(USE_SUNAUDIO, false)
 940 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 941 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 942 AM_CONDITIONAL(USE_X, false)
 943 AM_CONDITIONAL(USE_XSHM, false)
 944 AM_CONDITIONAL(USE_AALIB, false)
 945 AM_CONDITIONAL(USE_ANNODEX, false)
 946 AM_CONDITIONAL(USE_CAIRO, false)
 947 AM_CONDITIONAL(USE_CDIO, false)
 948 AM_CONDITIONAL(USE_ESD, false)
 949 AM_CONDITIONAL(USE_FLAC, false)
 950 AM_CONDITIONAL(USE_GCONF, false)
 951 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 952 AM_CONDITIONAL(USE_HAL, false)
 953 AM_CONDITIONAL(USE_JPEG, false)
 954 AM_CONDITIONAL(USE_LADSPA, false)
 955 AM_CONDITIONAL(USE_LIBCACA, false)
 956 AM_CONDITIONAL(USE_LIBDV, false)
 957 AM_CONDITIONAL(USE_LIBPNG, false)
 958 AM_CONDITIONAL(USE_DV1394, false)
 959 AM_CONDITIONAL(USE_SHOUT2, false)
 960 AM_CONDITIONAL(USE_SPEEX, false)
 961 AM_CONDITIONAL(USE_TAGLIB, false)
 962 AM_CONDITIONAL(USE_WAVPACK, false)
 963 AM_CONDITIONAL(USE_ZLIB, false)
 964
 965 fi dnl of EXT plugins
 966
 967 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 968
 969 dnl Overview:
 970 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 971 dnl GST_*:              flags shared by all built objects
 972 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 973 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 974 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 975 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 976
 977 dnl GST_OPTION_CFLAGS
 978 if test "x$USE_DEBUG" = xyes; then
 979    PROFILE_CFLAGS="-g"
 980 fi
 981 AC_SUBST(PROFILE_CFLAGS)
 982
 983 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 984   dnl Define _only_ during CVS (not pre-releases or releases)
 985   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 986 else
 987   DEPRECATED_CFLAGS=""
 988 fi
 989 AC_SUBST(DEPRECATED_CFLAGS)
 990
 991 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 992 dnl at make time with e.g. make ERROR_CFLAGS=""
 993 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 994 GST_OPTION_CXXFLAGS="\$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 995 AC_SUBST(GST_OPTION_CFLAGS)
 996 AC_SUBST(GST_OPTION_CXXFLAGS)
 997
 998 dnl our libraries need to be versioned correctly
 999 AC_SUBST(GST_LT_LDFLAGS)
1000
1001 dnl FIXME: do we want to rename to GST_ALL_* ?
1002 dnl prefer internal headers to already installed ones
1003 dnl also add builddir include for enumtypes and marshal
1004 dnl add ERROR_CFLAGS, but overridable
1005 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
1006 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1007 AC_SUBST(GST_CFLAGS)
1008 AC_SUBST(GST_CXXFLAGS)
1009 AC_SUBST(GST_LIBS)
1010
1011 dnl LDFLAGS really should only contain flags, not libs - they get added before
1012 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1013 GST_ALL_LDFLAGS="-no-undefined"
1014 AC_SUBST(GST_ALL_LDFLAGS)
1015
1016 dnl this really should only contain flags, not libs - they get added before
1017 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1018 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
1019 AC_SUBST(GST_PLUGIN_LDFLAGS)
1020
1021 dnl *** output files ***
1022
1023 dnl keep this alphabetic per directory, please
1024 AC_CONFIG_FILES(
1025 Makefile
1026 gst/Makefile
1027 gst/alpha/Makefile
1028 gst/apetag/Makefile
1029 gst/audiofx/Makefile
1030 gst/auparse/Makefile
1031 gst/autodetect/Makefile
1032 gst/avi/Makefile
1033 gst/cutter/Makefile
1034 gst/debug/Makefile
1035 gst/effectv/Makefile
1036 gst/equalizer/Makefile
1037 gst/id3demux/Makefile
1038 gst/icydemux/Makefile
1039 gst/goom/Makefile
1040 gst/goom2k1/Makefile
1041 gst/law/Makefile
1042 gst/level/Makefile
1043 gst/matroska/Makefile
1044 gst/monoscope/Makefile
1045 gst/multifile/Makefile
1046 gst/multipart/Makefile
1047 gst/qtdemux/Makefile
1048 gst/rtp/Makefile
1049 gst/rtsp/Makefile
1050 gst/smpte/Makefile
1051 gst/spectrum/Makefile
1052 gst/udp/Makefile
1053 gst/videobox/Makefile
1054 gst/videocrop/Makefile
1055 gst/videofilter/Makefile
1056 gst/videomixer/Makefile
1057 gst/wavenc/Makefile
1058 gst/wavparse/Makefile
1059 gst/flx/Makefile
1060 ext/jpeg/Makefile
1061 ext/Makefile
1062 ext/aalib/Makefile
1063 ext/annodex/Makefile
1064 ext/cairo/Makefile
1065 ext/cdio/Makefile
1066 ext/dv/Makefile
1067 ext/esd/Makefile
1068 ext/flac/Makefile
1069 ext/gconf/Makefile
1070 ext/gdk_pixbuf/Makefile
1071 ext/hal/Makefile
1072 ext/ladspa/Makefile
1073 ext/libcaca/Makefile
1074 ext/libpng/Makefile
1075 ext/raw1394/Makefile
1076 ext/shout2/Makefile
1077 ext/speex/Makefile
1078 ext/taglib/Makefile
1079 ext/wavpack/Makefile
1080 sys/Makefile
1081 sys/directdraw/Makefile
1082 sys/directsound/Makefile
1083 sys/oss/Makefile
1084 sys/sunaudio/Makefile
1085 sys/osxaudio/Makefile
1086 sys/osxvideo/Makefile
1087 sys/v4l2/Makefile
1088 sys/waveform/Makefile
1089 sys/ximage/Makefile
1090 po/Makefile.in
1091 tests/Makefile
1092 tests/check/Makefile
1093 tests/examples/Makefile
1094 tests/examples/equalizer/Makefile
1095 tests/examples/level/Makefile
1096 tests/examples/rtp/Makefile
1097 tests/examples/spectrum/Makefile
1098 tests/files/Makefile
1099 tests/icles/Makefile
1100 gconf/Makefile
1101 gconf/gstreamer.schemas
1102 common/Makefile
1103 common/m4/Makefile
1104 m4/Makefile
1105 docs/Makefile
1106 docs/plugins/Makefile
1107 docs/version.entities
1108 win32/common/config.h
1109 pkgconfig/Makefile
1110 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1111 gst-plugins-good.spec
1112 )
1113 AC_OUTPUT
1114
1115 AG_GST_OUTPUT_PLUGINS