configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([weston],
   3         [1.0.0],
   4         [https://bugs.freedesktop.org/enter_bug.cgi?product=weston],
   5         [weston],
   6         [http://wayland.freedesktop.org/])
   7
   8 AC_CONFIG_HEADERS([config.h])
   9
  10 AM_INIT_AUTOMAKE([1.11 foreign no-dist-gzip dist-xz])
  11
  12 AM_SILENT_RULES([yes])
  13
  14 # Check for programs
  15 AC_PROG_CC
  16 AC_PROG_CXX
  17 AC_PROG_SED
  18
  19 # Initialize libtool
  20 LT_PREREQ([2.2])
  21 LT_INIT([disable-static])
  22
  23 AC_ARG_VAR([WESTON_NATIVE_BACKEND],
  24            [Set the native backend to use, if Weston is not running under Wayland nor X11. @<:@default=drm-backend.so@:>@])
  25
  26 PKG_PROG_PKG_CONFIG()
  27
  28 AC_CHECK_FUNC([dlopen], [],
  29               AC_CHECK_LIB([dl], [dlopen], DLOPEN_LIBS="-ldl"))
  30 AC_SUBST(DLOPEN_LIBS)
  31
  32 AC_CHECK_HEADERS([execinfo.h])
  33
  34 AC_CHECK_FUNCS([mkostemp strchrnul])
  35
  36 COMPOSITOR_MODULES="wayland-server xkbcommon pixman-1"
  37
  38 AC_ARG_ENABLE(egl, [  --disable-egl],,
  39               enable_egl=yes)
  40 AM_CONDITIONAL(ENABLE_EGL, test x$enable_egl = xyes)
  41 if test x$enable_egl = xyes; then
  42         AC_DEFINE([ENABLE_EGL], [1], [Build Weston with EGL support])
  43         COMPOSITOR_MODULES="$COMPOSITOR_MODULES egl >= 7.10 glesv2"
  44 fi
  45
  46 PKG_CHECK_MODULES(COMPOSITOR, [$COMPOSITOR_MODULES])
  47
  48 AC_ARG_ENABLE(setuid-install, [  --enable-setuid-install],,
  49               enable_setuid_install=yes)
  50 AM_CONDITIONAL(ENABLE_SETUID_INSTALL, test x$enable_setuid_install = xyes)
  51
  52
  53 AC_ARG_ENABLE(xwayland, [  --enable-xwayland],,
  54               enable_xwayland=yes)
  55 AM_CONDITIONAL(ENABLE_XWAYLAND, test x$enable_xwayland = xyes)
  56 if test x$enable_xwayland = xyes; then
  57   PKG_CHECK_MODULES([XWAYLAND], xcb xcb-xfixes xcursor cairo-xcb)
  58   AC_DEFINE([BUILD_XWAYLAND], [1], [Build the X server launcher])
  59
  60   AC_ARG_WITH(xserver-path, AS_HELP_STRING([--with-xserver-path=PATH],
  61               [Path to X server]), [XSERVER_PATH="$withval"],
  62               [XSERVER_PATH="$bindir/Xorg"])
  63   AC_SUBST([XSERVER_PATH])
  64 fi
  65
  66
  67 AC_ARG_ENABLE(x11-compositor, [  --enable-x11-compositor],,
  68               enable_x11_compositor=yes)
  69 AM_CONDITIONAL(ENABLE_X11_COMPOSITOR, test x$enable_x11_compositor = xyes)
  70 if test x$enable_x11_compositor = xyes; then
  71   PKG_CHECK_MODULES([XCB], xcb)
  72   xcb_save_LIBS=$LIBS
  73   xcb_save_CFLAGS=$CFLAGS
  74   CFLAGS=$XCB_CFLAGS
  75   LIBS=$XCB_LIBS
  76   AC_CHECK_FUNCS([xcb_poll_for_queued_event])
  77   LIBS=$xcb_save_LIBS
  78   CFLAGS=$xcb_save_CFLAGS
  79
  80   X11_COMPOSITOR_MODULES="x11 x11-xcb"
  81
  82   PKG_CHECK_MODULES(X11_COMPOSITOR_XKB, [xcb-xkb],
  83                     [have_xcb_xkb="yes"], [have_xcb_xkb="no"])
  84   if test "x$have_xcb_xkb" = xyes; then
  85         # Most versions of XCB have totally broken XKB bindings, where the
  86         # events don't work.  Make sure we can actually use them.
  87         xcb_xkb_save_CFLAGS=$CFLAGS
  88         CFLAGS=$X11_COMPOSITOR_XKB_CFLAGS
  89         AC_CHECK_MEMBER([struct xcb_xkb_state_notify_event_t.xkbType],
  90                         [], [have_xcb_xkb=no], [[#include <xcb/xkb.h>]])
  91         CFLAGS=$xcb_xkb_save_CFLAGS
  92   fi
  93   if test "x$have_xcb_xkb" = xyes; then
  94         X11_COMPOSITOR_MODULES="$X11_COMPOSITOR_MODULES xcb-xkb"
  95         AC_DEFINE([HAVE_XCB_XKB], [1], [libxcb supports XKB protocol])
  96   fi
  97
  98   PKG_CHECK_MODULES(X11_COMPOSITOR, [$X11_COMPOSITOR_MODULES])
  99   AC_DEFINE([BUILD_X11_COMPOSITOR], [1], [Build the X11 compositor])
 100 fi
 101
 102
 103 AC_ARG_ENABLE(drm-compositor, [  --enable-drm-compositor],,
 104               enable_drm_compositor=yes)
 105 AM_CONDITIONAL(ENABLE_DRM_COMPOSITOR, test x$enable_drm_compositor = xyes -a x$enable_egl = xyes)
 106 if test x$enable_drm_compositor = xyes -a x$enable_egl = xyes; then
 107   AC_DEFINE([BUILD_DRM_COMPOSITOR], [1], [Build the DRM compositor])
 108   PKG_CHECK_MODULES(DRM_COMPOSITOR, [libudev >= 136 libdrm >= 2.4.30 gbm mtdev >= 1.1.0])
 109 fi
 110
 111
 112 AC_ARG_ENABLE(wayland-compositor, [  --enable-wayland-compositor],,
 113               enable_wayland_compositor=yes)
 114 AM_CONDITIONAL(ENABLE_WAYLAND_COMPOSITOR,
 115                test x$enable_wayland_compositor = xyes -a x$enable_egl = xyes)
 116 if test x$enable_wayland_compositor = xyes -a x$enable_egl = xyes; then
 117   AC_DEFINE([BUILD_WAYLAND_COMPOSITOR], [1],
 118             [Build the Wayland (nested) compositor])
 119   PKG_CHECK_MODULES(WAYLAND_COMPOSITOR, [wayland-client wayland-egl])
 120 fi
 121
 122
 123 AC_ARG_ENABLE(headless-compositor, [  --enable-headless-compositor],,
 124               enable_headless_compositor=yes)
 125 AM_CONDITIONAL(ENABLE_HEADLESS_COMPOSITOR,
 126                test x$enable_headless_compositor = xyes)
 127
 128
 129 AC_ARG_ENABLE(rpi-compositor,
 130               AS_HELP_STRING([--disable-rpi-compositor],
 131                              [do not build the Raspberry Pi backend]),,
 132               enable_rpi_compositor=yes)
 133 AM_CONDITIONAL(ENABLE_RPI_COMPOSITOR, test "x$enable_rpi_compositor" = "xyes" -a "x$enable_egl" = "xyes")
 134 have_bcm_host="no"
 135 if test x$enable_rpi_compositor = xyes -a x$enable_egl = xyes; then
 136   AC_DEFINE([BUILD_RPI_COMPOSITOR], [1], [Build the compositor for Raspberry Pi])
 137   PKG_CHECK_MODULES(RPI_COMPOSITOR, [libudev >= 136 mtdev >= 1.1.0])
 138   PKG_CHECK_MODULES(RPI_BCM_HOST, [bcm_host],
 139                     [have_bcm_host="yes"
 140                      AC_DEFINE([HAVE_BCM_HOST], [1], [have Raspberry Pi BCM headers])],
 141                     [AC_MSG_WARN([Raspberry Pi BCM host libraries not found, will use stubs instead.])])
 142 fi
 143 AM_CONDITIONAL(INSTALL_RPI_COMPOSITOR, test "x$have_bcm_host" = "xyes")
 144
 145
 146 AC_ARG_WITH(cairo-glesv2,
 147             AS_HELP_STRING([--with-cairo-glesv2],
 148                            [Use GLESv2 cairo instead of full GL]))
 149 if test "x$with_cairo_glesv2" = "xyes"; then
 150   cairo_modules="cairo-glesv2"
 151   AC_DEFINE([USE_CAIRO_GLESV2], [1], [Use the GLESv2 GL cairo backend])
 152 else
 153   cairo_modules="cairo-gl"
 154 fi
 155
 156 PKG_CHECK_MODULES(PIXMAN, [pixman-1])
 157 PKG_CHECK_MODULES(PNG, [libpng])
 158 PKG_CHECK_MODULES(WEBP, [libwebp], [have_webp=yes], [have_webp=no])
 159 AS_IF([test "x$have_webp" = "xyes"],
 160       [AC_DEFINE([HAVE_WEBP], [1], [Have webp])])
 161
 162 AC_CHECK_LIB([jpeg], [jpeg_CreateDecompress], have_jpeglib=yes)
 163 if test x$have_jpeglib = xyes; then
 164   JPEG_LIBS="-ljpeg"
 165 else
 166   AC_ERROR([libjpeg not found])
 167 fi
 168 AC_SUBST(JPEG_LIBS)
 169
 170 PKG_CHECK_MODULES(CAIRO, [cairo])
 171
 172 AC_ARG_ENABLE(simple-clients,
 173               AS_HELP_STRING([--disable-simple-clients],
 174                              [do not build the simple wl_shm clients]),,
 175               enable_simple_clients=yes)
 176 AM_CONDITIONAL(BUILD_SIMPLE_CLIENTS, test "x$enable_simple_clients" = "xyes")
 177 if test x$enable_simple_clients = xyes; then
 178   PKG_CHECK_MODULES(SIMPLE_CLIENT, [wayland-client])
 179 fi
 180
 181 AC_ARG_ENABLE(simple-egl-clients,
 182               AS_HELP_STRING([--disable-simple-egl-clients],
 183                              [do not build the simple EGL clients]),,
 184               enable_simple_egl_clients=yes)
 185 AM_CONDITIONAL(BUILD_SIMPLE_EGL_CLIENTS, test "x$enable_simple_egl_clients" = "xyes" -a "x$enable_egl" = "xyes")
 186 if test x$enable_simple_egl_clients = xyes -a x$enable_egl = xyes; then
 187   PKG_CHECK_MODULES(SIMPLE_EGL_CLIENT,
 188                     [egl >= 7.10 glesv2 wayland-client wayland-egl wayland-cursor])
 189 fi
 190
 191 AC_ARG_ENABLE(clients, [  --enable-clients],, enable_clients=yes)
 192 AM_CONDITIONAL(BUILD_CLIENTS, test x$enable_clients = xyes)
 193 if test x$enable_clients = xyes; then
 194   AC_DEFINE([BUILD_CLIENTS], [1], [Build the Wayland clients])
 195
 196   PKG_CHECK_MODULES(CLIENT, [wayland-client cairo >= 1.10.0 xkbcommon wayland-cursor])
 197   PKG_CHECK_MODULES(WESTON_INFO, [wayland-client])
 198
 199   PKG_CHECK_MODULES(POPPLER, [poppler-glib glib-2.0 gobject-2.0 gio-2.0 ],
 200                              [have_poppler=yes], [have_poppler=no])
 201   PKG_CHECK_MODULES(CAIRO_EGL, [wayland-egl egl >= 7.10 cairo-egl >= 1.11.3 $cairo_modules],
 202                     [have_cairo_egl=yes], [have_cairo_egl=no])
 203   AS_IF([test "x$have_cairo_egl" = "xyes"],
 204         [AC_DEFINE([HAVE_CAIRO_EGL], [1], [Have cairo-egl])],
 205         [AC_MSG_WARN([clients will use cairo image, cairo-egl not used because $CAIRO_EGL_PKG_ERRORS])])
 206 fi
 207
 208 AC_ARG_ENABLE(weston-launch, [  --enable-weston-launch],, enable_weston_launch=yes)
 209 AM_CONDITIONAL(BUILD_WESTON_LAUNCH, test x$enable_weston_launch == xyes)
 210 if test x$enable_weston_launch == xyes; then
 211   PKG_CHECK_MODULES(WESTON_LAUNCH, [libdrm])
 212   PKG_CHECK_MODULES(SYSTEMD_LOGIN, [libsystemd-login],
 213                     [have_systemd_login=yes], [have_systemd_login=no])
 214   AS_IF([test "x$have_systemd_login" = "xyes"],
 215         [AC_DEFINE([HAVE_SYSTEMD_LOGIN], [1], [Have systemd-login])])
 216
 217   AC_CHECK_LIB([pam], [pam_open_session], [have_pam=yes], [have_pam=no])
 218   if test x$have_pam == xno; then
 219     AC_ERROR([weston-launch requires pam])
 220   fi
 221   WESTON_LAUNCH_LIBS="$WESTON_LAUNCH_LIBS -lpam"
 222 fi
 223
 224 AM_CONDITIONAL(HAVE_GLU, test "x$have_glu" = "xyes" -a "$xenable_egl" = "xyes")
 225 if test x$enable_egl = xyes; then
 226   PKG_CHECK_MODULES(GLU, [glu], [have_glu=yes], [have_glu=no])
 227 fi
 228
 229
 230 AM_CONDITIONAL(HAVE_POPPLER, test "x$have_poppler" = "xyes")
 231
 232 AM_CONDITIONAL(BUILD_FULL_GL_CLIENTS,
 233                test x$cairo_modules = "xcairo-gl" -a "x$have_cairo_egl" = "xyes" -a "x$enable_egl" = "xyes")
 234
 235 AM_CONDITIONAL(ENABLE_DESKTOP_SHELL, true)
 236
 237 AC_ARG_ENABLE(tablet-shell,
 238               AS_HELP_STRING([--disable-tablet-shell],
 239                              [do not build tablet-shell server plugin and client]),,
 240               enable_tablet_shell=yes)
 241 AM_CONDITIONAL(ENABLE_TABLET_SHELL,
 242                test "x$enable_tablet_shell" = "xyes")
 243
 244
 245 AC_ARG_ENABLE(wcap-tools, [  --disable-wcap-tools],, enable_wcap_tools=yes)
 246 AM_CONDITIONAL(BUILD_WCAP_TOOLS, test x$enable_wcap_tools = xyes)
 247 if test x$enable_wcap_tools = xyes; then
 248   AC_DEFINE([BUILD_WCAP_TOOLS], [1], [Build the wcap tools])
 249   PKG_CHECK_MODULES(WCAP, [cairo])
 250   WCAP_LIBS="$WCAP_LIBS -lm"
 251 fi
 252
 253 AC_CHECK_PROG(RSVG_CONVERT, rsvg-convert, rsvg-convert)
 254 AM_CONDITIONAL(HAVE_RSVG_CONVERT, test -n "$RSVG_CONVERT")
 255
 256 PKG_CHECK_MODULES(SETBACKLIGHT, [libudev libdrm], enable_setbacklight=yes, enable_setbacklight=no)
 257 AM_CONDITIONAL(BUILD_SETBACKLIGHT, test "x$enable_setbacklight" = "xyes")
 258
 259 if test "x$GCC" = "xyes"; then
 260         my_common_gcc_flags="-Wall -Wextra -Wno-unused-parameter \
 261                 -Wno-missing-field-initializers -g -fvisibility=hidden"
 262         GCC_CFLAGS="$my_common_gcc_flags \
 263                 -Wstrict-prototypes -Wmissing-prototypes"
 264         GCC_CXXFLAGS="$my_common_gcc_flags"
 265 fi
 266 AC_SUBST(GCC_CFLAGS)
 267 AC_SUBST(GCC_CXXFLAGS)
 268
 269 if test "x$WESTON_NATIVE_BACKEND" = "x"; then
 270         WESTON_NATIVE_BACKEND="drm-backend.so"
 271 fi
 272 AC_MSG_NOTICE([Weston's native backend: $WESTON_NATIVE_BACKEND])
 273 AC_DEFINE_UNQUOTED([WESTON_NATIVE_BACKEND], ["$WESTON_NATIVE_BACKEND"],
 274                    [The default backend to load, if not wayland nor x11.])
 275
 276 WAYLAND_SCANNER_RULES(['$(top_srcdir)/protocol'])
 277
 278 AC_CONFIG_FILES([Makefile
 279                  shared/Makefile
 280                  src/Makefile
 281                  src/xwayland/Makefile
 282                  clients/Makefile
 283                  wcap/Makefile
 284                  data/Makefile
 285                  protocol/Makefile
 286                  man/Makefile
 287                  tests/Makefile])
 288 AC_OUTPUT