configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Note we do not use AC_PREREQ here!  See aclocal.m4 for what we use instead.
   3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
   4 AC_CONFIG_SRCDIR([include/features.h])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([scripts])
   7
   8 ACX_PKGVERSION([GNU libc])
   9 ACX_BUGURL([http://www.gnu.org/software/libc/bugs.html])
  10 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
  11                    [Package description])
  12 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
  13                    [Bug reporting address])
  14
  15 # Glibc should not depend on any header files
  16 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  17   [m4_divert_text([DEFAULTS],
  18     [ac_includes_default='/* none */'])])
  19
  20 # We require GCC, and by default use its preprocessor.  Override AC_PROG_CPP
  21 # here to work around the Autoconf issue discussed in
  22 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
  23 AC_DEFUN([AC_PROG_CPP],
  24 [AC_REQUIRE([AC_PROG_CC])dnl
  25 AC_ARG_VAR([CPP],      [C preprocessor])dnl
  26 _AC_ARG_VAR_CPPFLAGS()dnl
  27 # On Suns, sometimes $CPP names a directory.
  28 if test -n "$CPP" && test -d "$CPP"; then
  29   CPP=
  30 fi
  31 if test -z "$CPP"; then
  32   CPP="$CC -E"
  33 fi
  34 AC_SUBST(CPP)dnl
  35 ])# AC_PROG_CPP
  36
  37 # We require GCC.  Override _AC_PROG_CC_C89 here to work around the Autoconf
  38 # issue discussed in
  39 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
  40 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
  41
  42 dnl This is here so we can set $subdirs directly based on configure fragments.
  43 AC_CONFIG_SUBDIRS()
  44
  45 AC_CANONICAL_HOST
  46
  47 AC_PROG_CC
  48 if test $host != $build; then
  49   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  50 fi
  51 AC_SUBST(cross_compiling)
  52 AC_PROG_CPP
  53 # We need the C++ compiler only for testing.
  54 AC_PROG_CXX
  55 AC_CHECK_TOOL(READELF, readelf, false)
  56
  57 if test "`cd $srcdir; /bin/pwd`" = "`/bin/pwd`"; then
  58   AC_MSG_ERROR([you must configure in a separate build directory])
  59 fi
  60
  61 # This will get text that should go into config.make.
  62 config_vars=
  63
  64 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  65 AC_ARG_WITH([gd],
  66             AC_HELP_STRING([--with-gd=DIR],
  67                            [find libgd include dir and library with prefix DIR]),
  68             [dnl
  69 case "$with_gd" in
  70 yes|''|no) ;;
  71 *) libgd_include="-I$withval/include"
  72    libgd_ldflags="-L$withval/lib" ;;
  73 esac
  74 ])
  75 AC_ARG_WITH([gd-include],
  76             AC_HELP_STRING([--with-gd-include=DIR],
  77                            [find libgd include files in DIR]),
  78             [dnl
  79 case "$with_gd_include" in
  80 ''|no) ;;
  81 *) libgd_include="-I$withval" ;;
  82 esac
  83 ])
  84 AC_ARG_WITH([gd-lib],
  85             AC_HELP_STRING([--with-gd-lib=DIR],
  86                            [find libgd library files in DIR]),
  87             [dnl
  88 case "$with_gd_lib" in
  89 ''|no) ;;
  90 *) libgd_ldflags="-L$withval" ;;
  91 esac
  92 ])
  93
  94 if test -n "$libgd_include"; then
  95   config_vars="$config_vars
  96 CFLAGS-memusagestat.c = $libgd_include"
  97 fi
  98 if test -n "$libgd_ldflags"; then
  99   config_vars="$config_vars
 100 libgd-LDFLAGS = $libgd_ldflags"
 101 fi
 102
 103 dnl Arguments to specify presence of other packages/features.
 104 AC_ARG_WITH([fp],
 105             AC_HELP_STRING([--with-fp],
 106                            [if using floating-point hardware @<:@default=yes@:>@]),
 107             [with_fp=$withval],
 108             [with_fp=yes])
 109 AC_SUBST(with_fp)
 110 AC_ARG_WITH([binutils],
 111             AC_HELP_STRING([--with-binutils=PATH],
 112                            [specify location of binutils (as and ld)]),
 113             [path_binutils=$withval],
 114             [path_binutils=''])
 115 AC_ARG_WITH([selinux],
 116             AC_HELP_STRING([--with-selinux],
 117                            [if building with SELinux support]),
 118             [with_selinux=$withval],
 119             [with_selinux=auto])
 120
 121 AC_ARG_WITH([headers],
 122             AC_HELP_STRING([--with-headers=PATH],
 123                            [location of system headers to use
 124                             (for example /usr/src/linux/include)
 125                             @<:@default=compiler default@:>@]),
 126             [sysheaders=$withval],
 127             [sysheaders=''])
 128 AC_SUBST(sysheaders)
 129
 130 AC_SUBST(use_default_link)
 131 AC_ARG_WITH([default-link],
 132             AC_HELP_STRING([--with-default-link],
 133                            [do not use explicit linker scripts]),
 134             [use_default_link=$withval],
 135             [use_default_link=default])
 136
 137 AC_ARG_ENABLE([sanity-checks],
 138               AC_HELP_STRING([--disable-sanity-checks],
 139                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 140               [enable_sanity=$enableval],
 141               [enable_sanity=yes])
 142
 143 AC_ARG_ENABLE([shared],
 144               AC_HELP_STRING([--enable-shared],
 145                              [build shared library @<:@default=yes if GNU ld@:>@]),
 146               [shared=$enableval],
 147               [shared=yes])
 148 AC_ARG_ENABLE([profile],
 149               AC_HELP_STRING([--enable-profile],
 150                              [build profiled library @<:@default=no@:>@]),
 151               [profile=$enableval],
 152               [profile=no])
 153
 154 AC_ARG_ENABLE([oldest-abi],
 155               AC_HELP_STRING([--enable-oldest-abi=ABI],
 156                              [configure the oldest ABI supported @<:@e.g. 2.2@:>@ @<:@default=glibc default@:>@]),
 157               [oldest_abi=$enableval],
 158               [oldest_abi=no])
 159 if test "$oldest_abi" = yes || test "$oldest_abi" = no; then
 160   oldest_abi=default
 161 else
 162   AC_DEFINE_UNQUOTED(GLIBC_OLDEST_ABI, "$oldest_abi")
 163 fi
 164 AC_SUBST(oldest_abi)
 165
 166 AC_ARG_ENABLE([hardcoded-path-in-tests],
 167               AC_HELP_STRING([--enable-hardcoded-path-in-tests],
 168                              [hardcode newly built glibc path in tests @<:@default=no@:>@]),
 169               [hardcoded_path_in_tests=$enableval],
 170               [hardcoded_path_in_tests=no])
 171 AC_SUBST(hardcoded_path_in_tests)
 172
 173 AC_ARG_ENABLE([stackguard-randomization],
 174               AC_HELP_STRING([--enable-stackguard-randomization],
 175                              [initialize __stack_chk_guard canary with a random number at program start]),
 176               [enable_stackguard_randomize=$enableval],
 177               [enable_stackguard_randomize=no])
 178 if test "$enable_stackguard_randomize" = yes; then
 179   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 180 fi
 181
 182 AC_ARG_ENABLE([lock-elision],
 183               AC_HELP_STRING([--enable-lock-elision[=yes/no]],
 184                              [Enable lock elision for pthread mutexes by default]),
 185               [enable_lock_elision=$enableval],
 186               [enable_lock_elision=no])
 187 AC_SUBST(enable_lock_elision)
 188 if test "$enable_lock_elision" = yes ; then
 189   AC_DEFINE(ENABLE_LOCK_ELISION)
 190 fi
 191
 192 dnl Generic infrastructure for drop-in additions to libc.
 193 AC_ARG_ENABLE([add-ons],
 194               AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
 195                              [configure and build add-ons in DIR1,DIR2,...
 196                               search for add-ons if no parameter given]),
 197                              , [enable_add_ons=yes])
 198
 199 AC_ARG_ENABLE([hidden-plt],
 200               AC_HELP_STRING([--disable-hidden-plt],
 201                              [do not hide internal function calls to avoid PLT]),
 202               [hidden=$enableval],
 203               [hidden=yes])
 204 if test "x$hidden" = xno; then
 205   AC_DEFINE(NO_HIDDEN)
 206 fi
 207
 208 AC_ARG_ENABLE([bind-now],
 209               AC_HELP_STRING([--enable-bind-now],
 210                              [disable lazy relocations in DSOs]),
 211               [bindnow=$enableval],
 212               [bindnow=no])
 213 AC_SUBST(bindnow)
 214
 215 dnl On some platforms we cannot use dynamic loading.  We must provide
 216 dnl static NSS modules.
 217 AC_ARG_ENABLE([static-nss],
 218               AC_HELP_STRING([--enable-static-nss],
 219                              [build static NSS modules @<:@default=no@:>@]),
 220               [static_nss=$enableval],
 221               [static_nss=no])
 222 dnl Enable static NSS also if we build no shared objects.
 223 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 224   static_nss=yes
 225   AC_DEFINE(DO_STATIC_NSS)
 226 fi
 227
 228 AC_ARG_ENABLE([force-install],
 229               AC_HELP_STRING([--disable-force-install],
 230                              [don't force installation of files from this package, even if they are older than the installed files]),
 231               [force_install=$enableval],
 232               [force_install=yes])
 233 AC_SUBST(force_install)
 234
 235 AC_ARG_ENABLE([maintainer-mode],
 236               AC_HELP_STRING([--enable-maintainer-mode],
 237                              [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
 238               [maintainer=$enableval],
 239               [maintainer=no])
 240
 241 dnl On some platforms we allow dropping compatibility with all kernel
 242 dnl versions.
 243 AC_ARG_ENABLE([kernel],
 244               AC_HELP_STRING([--enable-kernel=VERSION],
 245                              [compile for compatibility with kernel not older than VERSION]),
 246               [minimum_kernel=$enableval],
 247               [])
 248 dnl Prevent unreasonable values.
 249 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 250   # Better nothing than this.
 251   minimum_kernel=""
 252 else
 253   if test "$minimum_kernel" = current; then
 254     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 255   fi
 256 fi
 257
 258 dnl For the development we sometimes want gcc to issue even more warnings.
 259 dnl This is not the default since many of the extra warnings are not
 260 dnl appropriate.
 261 AC_ARG_ENABLE([all-warnings],
 262               AC_HELP_STRING([--enable-all-warnings],
 263                              [enable all useful warnings gcc can issue]),
 264               [all_warnings=$enableval],
 265               [])
 266 AC_SUBST(all_warnings)
 267
 268 AC_ARG_ENABLE([multi-arch],
 269               AC_HELP_STRING([--enable-multi-arch],
 270                              [enable single DSO with optimizations for multiple architectures]),
 271               [multi_arch=$enableval],
 272               [multi_arch=default])
 273
 274 AC_ARG_ENABLE([nss-crypt],
 275               AC_HELP_STRING([--enable-nss-crypt],
 276                              [enable libcrypt to use nss]),
 277               [nss_crypt=$enableval],
 278               [nss_crypt=no])
 279 if test x$nss_crypt = xyes; then
 280   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 281   if test $? -ne 0; then
 282     AC_MSG_ERROR([cannot find include directory with nss-config])
 283   fi
 284   old_CFLAGS="$CFLAGS"
 285   CFLAGS="$CFLAGS $nss_includes"
 286   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 287 #include <hasht.h>
 288 #include <nsslowhash.h>
 289 void f (void) { NSSLOW_Init (); }])],
 290              libc_cv_nss_crypt=yes,
 291              AC_MSG_ERROR([
 292 cannot find NSS headers with lowlevel hash function interfaces]))
 293   old_LIBS="$LIBS"
 294   LIBS="$LIBS -lfreebl3"
 295   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 296 #include <hasht.h>
 297 #include <nsslowhash.h>],
 298                                   [NSSLOW_Init();])],
 299                  libc_cv_nss_crypt=yes,
 300                  AC_MSG_ERROR([
 301 cannot link program using lowlevel NSS hash functions]))
 302   CFLAGS="$old_CFLAGS"
 303   LIBS="$old_LIBS"
 304 else
 305   libc_cv_nss_crypt=no
 306 fi
 307 AC_SUBST(libc_cv_nss_crypt)
 308
 309
 310 AC_ARG_ENABLE([obsolete-rpc],
 311               AC_HELP_STRING([--enable-obsolete-rpc],
 312                              [build and install the obsolete RPC code for link-time usage]),
 313               [link_obsolete_rpc=$enableval],
 314               [link_obsolete_rpc=no])
 315 AC_SUBST(link_obsolete_rpc)
 316
 317 if test "$link_obsolete_rpc" = yes; then
 318   AC_DEFINE(LINK_OBSOLETE_RPC)
 319 fi
 320
 321 AC_ARG_ENABLE([systemtap],
 322               [AS_HELP_STRING([--enable-systemtap],
 323                [enable systemtap static probe points @<:@default=no@:>@])],
 324               [systemtap=$enableval],
 325               [systemtap=no])
 326 if test "x$systemtap" != xno; then
 327   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
 328   old_CFLAGS="$CFLAGS"
 329   CFLAGS="-std=gnu99 $CFLAGS"
 330   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
 331 void foo (int i, void *p)
 332 {
 333   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
 334        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
 335 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
 336   CFLAGS="$old_CFLAGS"])
 337   if test $libc_cv_sdt = yes; then
 338     AC_DEFINE([USE_STAP_PROBE])
 339   elif test "x$systemtap" != xauto; then
 340     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
 341   fi
 342 fi
 343
 344 AC_ARG_ENABLE([build-nscd],
 345               [AS_HELP_STRING([--disable-build-nscd],
 346                [disable building and installing the nscd daemon])],
 347               [build_nscd=$enableval],
 348               [build_nscd=default])
 349 AC_SUBST(build_nscd)
 350
 351 # Note the use of $use_nscd is near the bottom of the file.
 352 AC_ARG_ENABLE([nscd],
 353               [AS_HELP_STRING([--disable-nscd],
 354                [library functions will not contact the nscd daemon])],
 355               [use_nscd=$enableval],
 356               [use_nscd=yes])
 357
 358 AC_ARG_ENABLE([pt_chown],
 359               [AS_HELP_STRING([--enable-pt_chown],
 360                [Enable building and installing pt_chown])],
 361               [build_pt_chown=$enableval],
 362               [build_pt_chown=no])
 363 AC_SUBST(build_pt_chown)
 364 if test "$build_pt_chown" = yes; then
 365   AC_DEFINE(HAVE_PT_CHOWN)
 366 fi
 367
 368 # The way shlib-versions is used to generate soversions.mk uses a
 369 # fairly simplistic model for name recognition that can't distinguish
 370 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 371 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 372 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 373 case "$host_os" in
 374 linux*)
 375   ;;
 376 gnu*)
 377   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 378   ;;
 379 esac
 380
 381 # We keep the original values in `$config_*' and never modify them, so we
 382 # can write them unchanged into config.make.  Everything else uses
 383 # $machine, $vendor, and $os, and changes them whenever convenient.
 384 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 385
 386 # Don't allow vendor == "unknown"
 387 test "$config_vendor" = unknown && config_vendor=
 388 config_os="`echo $config_os | sed 's/^unknown-//'`"
 389
 390 # Some configurations imply other options.
 391 elf=yes
 392
 393 # The configure fragment of an add-on port can modify these to supplement
 394 # or override the table in the case statement below.  No fragment should
 395 # ever change the config_* variables, however.
 396 machine=$config_machine
 397 vendor=$config_vendor
 398 os=$config_os
 399 base_os=''
 400
 401 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
 402 # Unify this here.
 403 if test "$machine" = rs6000; then
 404   machine="powerpc"
 405 fi
 406
 407 # Braindead PowerPC box with absolutely no FPU.
 408 case "$machine-$host_os" in
 409   powerpc*-*soft)
 410     with_fp=no
 411     ;;
 412 esac
 413
 414 submachine=
 415 AC_ARG_WITH([cpu],
 416             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 417             [dnl
 418   case "$withval" in
 419   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 420   no) ;;
 421   *) submachine="$withval" ;;
 422   esac
 423 ])
 424
 425 dnl Let sysdeps/*/preconfigure act here, like they can in add-ons.
 426 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 427
 428 # An add-on can set this when it wants to disable the sanity check below.
 429 libc_config_ok=no
 430
 431 dnl Having this here, though empty, makes sure that if add-ons' fragments
 432 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
 433 dnl our AC_OUTPUT will actually use it.
 434 AC_CONFIG_SUBDIRS()
 435
 436 case "$enable_add_ons" in
 437 ''|no) add_ons= ;;
 438 yes|'*')
 439  add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
 440           sed 's@/[[^/]]*$@@' | sort | uniq`
 441          add_ons_automatic=yes
 442          ;;
 443 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
 444        add_ons_automatic=no ;;
 445 esac
 446
 447 configured_add_ons=
 448 add_ons_sfx=
 449 add_ons_pfx=
 450 if test x"$add_ons" != x; then
 451   for f in $add_ons; do
 452     # Some sanity checks
 453     case "$f" in
 454     crypt)
 455       AC_MSG_ERROR([
 456 *** It seems that you're using an old \`crypt' add-on.  crypt is now
 457 *** part of glibc and using the old add-on will not work with this
 458 *** release.  Start again with fresh sources and without the old
 459 *** \`crypt' add-on.])
 460     ;;
 461     localedata)
 462       AC_MSG_ERROR([
 463 *** It seems that you're using an old \`localedata' add-on.  localedata
 464 *** is now part of glibc and using the old add-on will not work with
 465 *** this release.  Start again with fresh sources and without the old
 466 *** \`localedata' add-on.])
 467     ;;
 468     esac
 469   done
 470
 471   # Now source each add-on's configure fragment.
 472   # The fragments can use $srcdir/$libc_add_on to find themselves,
 473   # and test $add_ons_automatic to see if they were explicitly requested.
 474   # A fragment can clear (or even change) $libc_add_on to affect
 475   # whether it goes into the list to be actually used in the build.
 476   use_add_ons=
 477   for libc_add_on in $add_ons; do
 478     # Test whether such a directory really exists.
 479     # It can be absolute, or relative to $srcdir, or relative to the build dir.
 480     case "$libc_add_on" in
 481     /*)
 482       libc_add_on_srcdir=$libc_add_on
 483       ;;
 484     *)
 485       test -d "$srcdir/$libc_add_on" || {
 486         if test -d "$libc_add_on"; then
 487           libc_add_on="`pwd`/$libc_add_on"
 488         else
 489           AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
 490         fi
 491       }
 492       libc_add_on_srcdir=$srcdir/$libc_add_on
 493       ;;
 494     esac
 495
 496     libc_add_on_frag=$libc_add_on_srcdir/configure
 497     libc_add_on_canonical=
 498     libc_add_on_config_subdirs=
 499     if test -r "$libc_add_on_frag"; then
 500       AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
 501       libc_add_on_canonical=unknown
 502       libc_add_on_subdirs=
 503       . "$libc_add_on_frag"
 504       test -z "$libc_add_on" || {
 505         configured_add_ons="$configured_add_ons $libc_add_on"
 506         if test "x$libc_add_on_canonical" = xunknown; then
 507           AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
 508         fi
 509         for d in $libc_add_on_subdirs; do
 510           case "$libc_add_on" in
 511           /*) subdir_srcdir="$libc_add_on" ;;
 512           *) subdir_srcdir="\$(..)$libc_add_on" ;;
 513           esac
 514           case "$d" in
 515           .)
 516             d="${libc_add_on_canonical:-$libc_add_on}"
 517             ;;
 518           /*)
 519             subdir_srcdir="$d"
 520             ;;
 521           *)
 522             subdir_srcdir="$subdir_srcdir/$d"
 523             ;;
 524           esac
 525           d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
 526           add_on_subdirs="$add_on_subdirs $d"
 527           test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
 528 $d-srcdir = $subdir_srcdir"
 529         done
 530         for d in $libc_add_on_config_subdirs; do
 531           case "$d" in
 532           /*) AC_MSG_ERROR(dnl
 533 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
 534           esac
 535           if test ! -d "$libc_add_on_srcdir/$d"; then
 536             AC_MSG_ERROR(fragment wants to configure missing directory $d)
 537           fi
 538           case "$libc_add_on" in
 539           /*) AC_MSG_ERROR(dnl
 540 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
 541           esac
 542           subdirs="$subdirs $libc_add_on/$d"
 543         done
 544       }
 545     fi
 546     if test -n "$libc_add_on"; then
 547       LIBC_PRECONFIGURE([$libc_add_on_srcdir], [add-on $libc_add_on for])
 548       use_add_ons="$use_add_ons $libc_add_on"
 549       add_ons_pfx="$add_ons_pfx $libc_add_on/"
 550       test -z "$libc_add_on_canonical" ||
 551       add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
 552     fi
 553   done
 554   # Use echo to strip excess whitespace.
 555   add_ons="`echo $use_add_ons`"
 556 fi
 557 AC_SUBST(add_ons)
 558 AC_SUBST(add_on_subdirs)
 559
 560
 561 ###
 562 ### I put this here to prevent those annoying emails from people who cannot
 563 ### read and try to compile glibc on unsupported platforms.  --drepper
 564 ###
 565 ### By using the undocumented --enable-hacker-mode option for configure
 566 ### one can skip this test to make the configuration not fail for unsupported
 567 ### platforms.
 568 ###
 569 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 570   case "$machine-$host_os" in
 571   *-linux* | *-gnu*)
 572     ;;
 573   *)
 574     echo "*** The GNU C library is currently not available for this platform."
 575     echo "*** So far nobody cared to port it and if there is no volunteer it"
 576     echo "*** might never happen.  So, if you have interest to see glibc on"
 577     echo "*** this platform visit"
 578     echo "***   http://www.gnu.org/software/libc/porting.html"
 579     echo "*** and join the group of porters"
 580     exit 1
 581     ;;
 582   esac
 583 fi
 584
 585 # Set base_machine if not set by a preconfigure fragment.
 586 test -n "$base_machine" || base_machine=$machine
 587 AC_SUBST(base_machine)
 588
 589 # For the multi-arch option we need support in the assembler & linker.
 590 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
 591                libc_cv_ld_gnu_indirect_function, [dnl
 592 cat > conftest.S <<EOF
 593 .type foo,%gnu_indirect_function
 594 foo:
 595 .globl _start
 596 _start:
 597 .globl __start
 598 __start:
 599 .data
 600 #ifdef _LP64
 601 .quad foo
 602 #else
 603 .long foo
 604 #endif
 605 EOF
 606 libc_cv_ld_gnu_indirect_function=no
 607 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 608             -nostartfiles -nostdlib \
 609             -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 610   # Do a link to see if the backend supports IFUNC relocs.
 611   $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
 612   LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
 613     libc_cv_ld_gnu_indirect_function=yes
 614   }
 615 fi
 616 rm -f conftest*])
 617
 618 AC_MSG_CHECKING(whether .text pseudo-op must be used)
 619 AC_CACHE_VAL(libc_cv_dot_text, [dnl
 620 cat > conftest.s <<EOF
 621 .text
 622 EOF
 623 libc_cv_dot_text=
 624 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
 625   libc_cv_dot_text=.text
 626 fi
 627 rm -f conftest*])
 628 if test -z "$libc_cv_dot_text"; then
 629   AC_MSG_RESULT(no)
 630 else
 631   AC_MSG_RESULT(yes)
 632 fi
 633
 634 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
 635   if test x"$multi_arch" = xyes; then
 636     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 637   else
 638     multi_arch=no
 639   fi
 640 fi
 641 multi_arch_d=
 642 if test x"$multi_arch" != xno; then
 643   multi_arch_d=/multiarch
 644 fi
 645
 646 # Compute the list of sysdep directories for this configuration.
 647 # This can take a while to compute.
 648 sysdep_dir=$srcdir/sysdeps
 649 AC_MSG_CHECKING(sysdep dirs)
 650 dnl We need to use [ and ] for other purposes for a while now.
 651 changequote(,)dnl
 652 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 653 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 654
 655 test "x$base_os" != x || case "$os" in
 656 gnu*)
 657   base_os=mach/hurd ;;
 658 linux*)
 659   base_os=unix/sysv ;;
 660 esac
 661
 662 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 663 tail=$os
 664 ostry=$os
 665 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 666   ostry="$ostry /$o"
 667   tail=$o
 668 done
 669 o=`echo $tail | sed 's/[0-9]*$//'`
 670 if test $o != $tail; then
 671   ostry="$ostry /$o"
 672 fi
 673 # For linux-gnu, try linux-gnu, then linux.
 674 o=`echo $tail | sed 's/-.*$//'`
 675 if test $o != $tail; then
 676   ostry="$ostry /$o"
 677 fi
 678
 679 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 680 base=
 681 tail=$base_os
 682 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 683   set $b
 684   base="$base /$1"
 685   tail="$2"
 686 done
 687
 688 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 689 mach=
 690 tail=$machine${submachine:+/$submachine}
 691 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 692   set $m
 693   # Prepend the machine's FPU directory unless --without-fp.
 694   if test "$with_fp" = yes; then
 695     maybe_fpu=/fpu
 696   else
 697     maybe_fpu=/nofpu
 698   fi
 699   # For each machine term, try it with and then without /multiarch.
 700   for try_fpu in $maybe_fpu ''; do
 701     for try_multi in $multi_arch_d ''; do
 702       mach="$mach /$1$try_fpu$try_multi"
 703     done
 704   done
 705   tail="$2"
 706 done
 707
 708 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 709 changequote([,])dnl
 710
 711 # Find what sysdep directories exist.
 712 sysnames_add_ons=
 713 sysnames=
 714 for b in $base ''; do
 715   for m0 in $mach ''; do
 716     for v in /$vendor ''; do
 717       test "$v" = / && continue
 718       for o in /$ostry ''; do
 719         test "$o" = / && continue
 720         for m in $mach ''; do
 721           for d in $add_ons_pfx ''; do
 722             for a in $add_ons_sfx ''; do
 723               try_suffix="$m0$b$v$o$m"
 724               if test -n "$try_suffix"; then
 725                 try_srcdir="${srcdir}/"
 726                 case "$d" in
 727                 /*) try_srcdir= ;;
 728                 esac
 729                 try="${d}sysdeps$try_suffix$a"
 730                 test -n "$enable_debug_configure" &&
 731                 echo "$0 [DEBUG]: try $try" >&2
 732                 if test -d "$try_srcdir$try"; then
 733                   sysnames="$sysnames $try"
 734                   { test -n "$o" || test -n "$b"; } && os_used=t
 735                   { test -n "$m" || test -n "$m0"; } && machine_used=t
 736                   case x${m0:-$m} in
 737                   x*/$submachine) submachine_used=t ;;
 738                   esac
 739                   if test -n "$d"; then
 740                     case "$sysnames_add_ons" in
 741                     *" $d "*) ;;
 742                     *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 743                     esac
 744                   fi
 745                 fi
 746               fi
 747             done
 748           done
 749         done
 750       done
 751     done
 752   done
 753 done
 754
 755 # If the assembler supports gnu_indirect_function symbol type and the
 756 # architecture supports multi-arch, we enable multi-arch by default.
 757 case $sysnames_add_ons$sysnames in
 758 *"$multi_arch_d"*)
 759   ;;
 760 *)
 761   test x"$multi_arch" = xdefault && multi_arch=no
 762   ;;
 763 esac
 764 if test x"$multi_arch" != xno; then
 765   AC_DEFINE(USE_MULTIARCH)
 766 fi
 767 AC_SUBST(multi_arch)
 768
 769 if test -z "$os_used" && test "$os" != none; then
 770   AC_MSG_ERROR(Operating system $os is not supported.)
 771 fi
 772 if test -z "$machine_used" && test "$machine" != none; then
 773   AC_MSG_ERROR(The $machine is not supported.)
 774 fi
 775 if test -z "$submachine_used" && test -n "$submachine"; then
 776   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 777 fi
 778 AC_SUBST(submachine)
 779
 780 # We have now validated the configuration.
 781
 782 # Expand the list of system names into a full list of directories
 783 # from each element's parent name and Implies file (if present).
 784 set $sysnames
 785 names=
 786 while test $# -gt 0; do
 787   name=$1
 788   shift
 789
 790   case " $names " in *" $name "*)
 791     # Already in the list.
 792     continue
 793   esac
 794
 795   # Report each name as we discover it, so there is no long pause in output.
 796   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 797
 798   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 799
 800   case $name in
 801     /*) xsrcdir= ;;
 802     *)  xsrcdir=$srcdir/ ;;
 803   esac
 804   test -n "$enable_debug_configure" &&
 805   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 806
 807   for implies_file in Implies Implies-before Implies-after; do
 808     implies_type=`echo $implies_file | sed s/-/_/`
 809     eval ${implies_type}=
 810     if test -f $xsrcdir$name/$implies_file; then
 811       # Collect more names from the `Implies' file (removing comments).
 812       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
 813       for x in $implied_candidate; do
 814         found=no
 815         if test -d $xsrcdir$name_base/$x; then
 816           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
 817           found=yes
 818         fi
 819         for d in $add_ons_pfx ''; do
 820           try="${d}sysdeps/$x"
 821           case $d in
 822            /*) try_srcdir= ;;
 823            *) try_srcdir=$srcdir/ ;;
 824           esac
 825           test -n "$enable_debug_configure" &&
 826            echo "[DEBUG]: $name $implies_file $x try($d) {$try_srcdir}$try" >&2
 827           if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 828           then
 829             eval "${implies_type}=\"\$${implies_type} \$try\""
 830             found=yes
 831             case "$sysnames_add_ons" in
 832             *" $d "*) ;;
 833             *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 834             esac
 835           fi
 836         done
 837         if test $found = no; then
 838           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
 839         fi
 840       done
 841     fi
 842   done
 843
 844   # Add NAME to the list of names.
 845   names="$names $name"
 846
 847   # Find the parent of NAME, using the empty string if it has none.
 848 changequote(,)dnl
 849   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 850 changequote([,])dnl
 851
 852   test -n "$enable_debug_configure" &&
 853     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
 854 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
 855
 856   # Add the names implied by NAME, and NAME's parent (if it has one), to
 857   # the list of names to be processed (the argument list).  We prepend the
 858   # implied names to the list and append the parent.  We want implied
 859   # directories to come before further directories inferred from the
 860   # configuration components; this ensures that for sysv4, unix/common
 861   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 862   # after sysv4).
 863   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
 864   test -n "$sysnames" && set $sysnames
 865 done
 866
 867 # Add the default directories.
 868 default_sysnames="sysdeps/generic"
 869 sysnames="$names $default_sysnames"
 870 AC_SUBST(sysnames)
 871 # The other names were emitted during the scan.
 872 AC_MSG_RESULT($default_sysnames)
 873
 874 # Collect the list of add-ons that supply partial sysdeps trees.
 875 sysdeps_add_ons=
 876 for add_on in $add_ons; do
 877   case "$add_on" in
 878   /*) xsrcdir= ;;
 879   *) xsrcdir="$srcdir/" ;;
 880   esac
 881
 882   test -d "$xsrcdir$add_on/sysdeps" || {
 883     case "$configured_add_ons " in
 884     *" $add_on "*) ;;
 885     *|'')
 886       AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
 887       ;;
 888     esac
 889     continue
 890   }
 891
 892   sysdeps_add_ons="$sysdeps_add_ons $add_on"
 893   case "$sysnames_add_ons" in
 894   *" $add_on/ "*) ;;
 895   *|'')
 896     AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
 897     continue ;;
 898   esac
 899
 900   found=no
 901   for d in $sysnames; do
 902     case "$d" in
 903     $add_on/sysdeps/*) ;;
 904     *) continue ;;
 905     esac
 906     (cd "$xsrcdir$d" && for f in *[[!~]]; do
 907        case "$f" in
 908        sys|bits)
 909          for ff in $f/*.h; do
 910            test -d "$ff" || { test -e "$ff" && exit 88; }
 911          done
 912          ;;
 913        *)
 914          test -d "$f" || { test -e "$f" && exit 88; }
 915          ;;
 916        esac
 917      done)
 918     if test $? -eq 88; then
 919       found=yes
 920       break
 921     fi
 922   done
 923   if test $found = no; then
 924     AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
 925   fi
 926 done
 927 AC_SUBST(sysdeps_add_ons)
 928
 929
 930 ### Locate tools.
 931
 932 AC_PROG_INSTALL
 933 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 934   # The makefiles need to use a different form to find it in $srcdir.
 935   INSTALL='\$(..)./scripts/install-sh -c'
 936 fi
 937 AC_PROG_LN_S
 938
 939 LIBC_PROG_BINUTILS
 940
 941 # Accept binutils 2.20 or newer.
 942 AC_CHECK_PROG_VER(AS, $AS, --version,
 943                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 944                   [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], AS=: critic_missing="$critic_missing as")
 945 AC_CHECK_PROG_VER(LD, $LD, --version,
 946                   [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 947                   [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], LD=: critic_missing="$critic_missing ld")
 948
 949 # These programs are version sensitive.
 950 AC_CHECK_TOOL_PREFIX
 951 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 952   [version \([egcygnustpi-]*[0-9.]*\)], [4.[4-9].* | 4.[1-9][0-9].* | [5-9].* ],
 953   critic_missing="$critic_missing gcc")
 954 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 955   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 956   [3.79* | 3.[89]* | [4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
 957
 958 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 959   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 960   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
 961   MSGFMT=: aux_missing="$aux_missing msgfmt")
 962 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 963   [GNU texinfo.* \([0-9][0-9.]*\)],
 964   [4.[5-9]*|4.[1-9][0-9]*|[5-9].*],
 965   MAKEINFO=: aux_missing="$aux_missing makeinfo")
 966 AC_CHECK_PROG_VER(SED, sed, --version,
 967   [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
 968   [3.0[2-9]*|3.[1-9]*|[4-9]*],
 969   SED=: aux_missing="$aux_missing sed")
 970 AC_CHECK_PROG_VER(AWK, gawk, --version,
 971   [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
 972   [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
 973
 974 AC_CHECK_TOOL(NM, nm, false)
 975
 976 if test "x$maintainer" = "xyes"; then
 977   AC_CHECK_PROGS(AUTOCONF, autoconf, no)
 978   case "x$AUTOCONF" in
 979   xno|x|x:) AUTOCONF=no ;;
 980   *)
 981     AC_CACHE_CHECK(dnl
 982   whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
 983     if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
 984       libc_cv_autoconf_works=yes
 985     else
 986       libc_cv_autoconf_works=no
 987     fi])
 988     test $libc_cv_autoconf_works = yes || AUTOCONF=no
 989     ;;
 990   esac
 991   if test "x$AUTOCONF" = xno; then
 992     aux_missing="$aux_missing autoconf"
 993   fi
 994 else
 995   AUTOCONF=no
 996 fi
 997
 998 test -n "$critic_missing" && AC_MSG_ERROR([
 999 *** These critical programs are missing or too old:$critic_missing
1000 *** Check the INSTALL file for required versions.])
1001
1002 test -n "$aux_missing" && AC_MSG_WARN([
1003 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1004 *** some features will be disabled.
1005 *** Check the INSTALL file for required versions.])
1006
1007 # if using special system headers, find out the compiler's sekrit
1008 # header directory and add that to the list.  NOTE: Only does the right
1009 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
1010 if test -n "$sysheaders"; then
1011   SYSINCLUDES=-nostdinc
1012   for d in include include-fixed; do
1013     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1014     SYSINCLUDES="$SYSINCLUDES -isystem $i"
1015   done
1016   SYSINCLUDES="$SYSINCLUDES \
1017 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1018   if test -n "$CXX"; then
1019     CXX_SYSINCLUDES=
1020     for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1021     | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1022       test "x$cxxheaders" != x &&
1023       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1024     done
1025   fi
1026 fi
1027 AC_SUBST(SYSINCLUDES)
1028 AC_SUBST(CXX_SYSINCLUDES)
1029
1030 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1031 # since this would lead to problems installing/building glibc.
1032 # LD_LIBRARY_PATH contains the current directory if one of the following
1033 # is true:
1034 # - one of the terminals (":" and ";") is the first or last sign
1035 # - two terminals occur directly after each other
1036 # - the path contains an element with a dot in it
1037 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1038 changequote(,)dnl
1039 case ${LD_LIBRARY_PATH} in
1040   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1041     ld_library_path_setting="contains current directory"
1042     ;;
1043   *)
1044     ld_library_path_setting="ok"
1045     ;;
1046 esac
1047 changequote([,])dnl
1048 AC_MSG_RESULT($ld_library_path_setting)
1049 if test "$ld_library_path_setting" != "ok"; then
1050 AC_MSG_ERROR([
1051 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1052 *** building glibc. Please change the environment variable
1053 *** and run configure again.])
1054 fi
1055
1056 AC_CACHE_CHECK(whether GCC supports -static-libgcc, libc_cv_gcc_static_libgcc, [dnl
1057 if $CC -v -static-libgcc 2>&1 | grep 'unrecognized option.*static-libgcc' >/dev/null; then
1058   libc_cv_gcc_static_libgcc=
1059 else
1060   libc_cv_gcc_static_libgcc=-static-libgcc
1061 fi])
1062 AC_SUBST(libc_cv_gcc_static_libgcc)
1063
1064 AC_PATH_PROG(BASH_SHELL, bash, no)
1065
1066 AC_PATH_PROG(PERL, perl, no)
1067 if test "$PERL" != no &&
1068    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1069   PERL=no
1070 fi
1071 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1072              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1073 AC_PATH_PROG(BISON, bison, no, $PATH:/usr/local/bin:/usr/bin:/bin)
1074
1075 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
1076 AC_TRY_COMPILE(dnl
1077 [#define __need_size_t
1078 #define __need_wchar_t
1079 #include <stddef.h>
1080 #define __need_NULL
1081 #include <stddef.h>], [size_t size; wchar_t wchar;
1082 #ifdef offsetof
1083 #error stddef.h ignored __need_*
1084 #endif
1085 if (&size == NULL || &wchar == NULL) abort ();],
1086                libc_cv_friendly_stddef=yes,
1087                libc_cv_friendly_stddef=no)])
1088 if test $libc_cv_friendly_stddef = yes; then
1089   config_vars="$config_vars
1090 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
1091 fi
1092
1093 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
1094                libc_cv_need_minus_P, [dnl
1095 cat > conftest.S <<EOF
1096 #include "confdefs.h"
1097 /* Nothing whatsoever.  */
1098 EOF
1099 if AC_TRY_COMMAND(${CC-cc} $CPPFLAGS $ASFLAGS -c conftest.S 1>&AS_MESSAGE_LOG_FD); then
1100   libc_cv_need_minus_P=no
1101 else
1102   libc_cv_need_minus_P=yes
1103 fi
1104 rm -f conftest*])
1105 if test $libc_cv_need_minus_P = yes; then
1106   config_vars="$config_vars
1107 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
1108 fi
1109
1110 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1111 cat > conftest.s <<EOF
1112 ${libc_cv_dot_text}
1113 foo:
1114 .set glibc_conftest_frobozz,foo
1115 .globl glibc_conftest_frobozz
1116 EOF
1117 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1118 # (but it doesn't work), so we must do a linking check to be sure.
1119 cat > conftest1.c <<\EOF
1120 extern int glibc_conftest_frobozz;
1121 void _start() { glibc_conftest_frobozz = 1; }
1122 EOF
1123 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1124             -nostartfiles -nostdlib \
1125             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1126   libc_cv_asm_set_directive=yes
1127 else
1128   libc_cv_asm_set_directive=no
1129 fi
1130 rm -f conftest*])
1131 if test $libc_cv_asm_set_directive = yes; then
1132   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1133 fi
1134
1135 AC_CACHE_CHECK(for assembler gnu_unique_object symbol type,
1136                libc_cv_asm_unique_object, [dnl
1137 cat > conftest.s <<EOF
1138 ${libc_cv_dot_text}
1139 _sym:
1140 .type _sym, %gnu_unique_object
1141 EOF
1142 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1143   libc_cv_asm_unique_object=yes
1144 else
1145   libc_cv_asm_unique_object=no
1146 fi
1147 rm -f conftest*])
1148 if test $libc_cv_asm_unique_object = yes; then
1149   AC_DEFINE(HAVE_ASM_UNIQUE_OBJECT)
1150 fi
1151
1152 AC_CACHE_CHECK(for .previous assembler directive,
1153                libc_cv_asm_previous_directive, [dnl
1154 cat > conftest.s <<EOF
1155 .section foo_section
1156 .previous
1157 EOF
1158 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1159   libc_cv_asm_previous_directive=yes
1160 else
1161   libc_cv_asm_previous_directive=no
1162 fi
1163 rm -f conftest*])
1164 if test $libc_cv_asm_previous_directive = yes; then
1165   AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
1166 else
1167   AC_CACHE_CHECK(for .popsection assembler directive,
1168                  libc_cv_asm_popsection_directive, [dnl
1169   cat > conftest.s <<EOF
1170 .pushsection foo_section
1171 .popsection
1172 EOF
1173   if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1174     libc_cv_asm_popsection_directive=yes
1175   else
1176     libc_cv_asm_popsection_directive=no
1177   fi
1178   rm -f conftest*])
1179   if test $libc_cv_asm_popsection_directive = yes; then
1180     AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
1181   fi
1182 fi
1183 AC_CACHE_CHECK(for .protected and .hidden assembler directive,
1184                libc_cv_asm_protected_directive, [dnl
1185 cat > conftest.s <<EOF
1186 .protected foo
1187 foo:
1188 .hidden bar
1189 bar:
1190 EOF
1191 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1192   libc_cv_asm_protected_directive=yes
1193 else
1194   AC_MSG_ERROR(assembler support for symbol visibility is required)
1195 fi
1196 rm -f conftest*])
1197
1198 if test $libc_cv_asm_protected_directive = yes; then
1199   AC_CACHE_CHECK(whether __attribute__((visibility())) is supported,
1200                  libc_cv_visibility_attribute,
1201                  [cat > conftest.c <<EOF
1202                   int foo __attribute__ ((visibility ("hidden"))) = 1;
1203                   int bar __attribute__ ((visibility ("protected"))) = 1;
1204 EOF
1205                   libc_cv_visibility_attribute=no
1206                   if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1207                     if grep '\.hidden.*foo' conftest.s >/dev/null; then
1208                       if grep '\.protected.*bar' conftest.s >/dev/null; then
1209                         libc_cv_visibility_attribute=yes
1210                       fi
1211                     fi
1212                   fi
1213                   rm -f conftest.{c,s}
1214                  ])
1215   if test $libc_cv_visibility_attribute != yes; then
1216     AC_MSG_ERROR(compiler support for visibility attribute is required)
1217   fi
1218 fi
1219
1220 if test $libc_cv_visibility_attribute = yes; then
1221   AC_CACHE_CHECK(for broken __attribute__((visibility())),
1222                  libc_cv_broken_visibility_attribute,
1223                  [cat > conftest.c <<EOF
1224                   int foo (int x);
1225                   int bar (int x) __asm__ ("foo") __attribute__ ((visibility ("hidden")));
1226                   int bar (int x) { return x; }
1227 EOF
1228                   libc_cv_broken_visibility_attribute=yes
1229                   if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1230 changequote(,)dnl
1231                     if grep '\.hidden[  _]foo' conftest.s >/dev/null; then
1232 changequote([,])dnl
1233                       libc_cv_broken_visibility_attribute=no
1234                     fi
1235                   fi
1236                   rm -f conftest.c conftest.s
1237                  ])
1238   if test $libc_cv_broken_visibility_attribute = yes; then
1239     AC_MSG_ERROR(working compiler support for visibility attribute is required)
1240   fi
1241 fi
1242
1243 AC_CACHE_CHECK(for broken __attribute__((alias())),
1244                libc_cv_broken_alias_attribute,
1245                [cat > conftest.c <<EOF
1246                extern int foo (int x) __asm ("xyzzy");
1247                int bar (int x) { return x; }
1248                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1249                extern int dfoo;
1250                extern __typeof (dfoo) dfoo __asm ("abccb");
1251                int dfoo = 1;
1252 EOF
1253                libc_cv_broken_alias_attribute=yes
1254                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1255                  if grep 'xyzzy' conftest.s >/dev/null &&
1256                     grep 'abccb' conftest.s >/dev/null; then
1257                    libc_cv_broken_alias_attribute=no
1258                  fi
1259                fi
1260                rm -f conftest.c conftest.s
1261                ])
1262 if test $libc_cv_broken_alias_attribute = yes; then
1263   AC_MSG_ERROR(working alias attribute support required)
1264 fi
1265
1266 if test $libc_cv_visibility_attribute = yes; then
1267   AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1268                  libc_cv_have_sdata_section,
1269                  [echo "int i;" > conftest.c
1270                   libc_cv_have_sdata_section=no
1271                   if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1272                      | grep '\.sdata' >/dev/null; then
1273                     libc_cv_have_sdata_section=yes
1274                   fi
1275                   rm -f conftest.c conftest.so
1276                  ])
1277   if test $libc_cv_have_sdata_section = yes; then
1278     AC_DEFINE(HAVE_SDATA_SECTION)
1279   fi
1280 fi
1281
1282 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
1283                libc_cv_initfini_array, [dnl
1284 LIBC_TRY_LINK_STATIC([
1285 int foo (void) { return 1; }
1286 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;
1287 ],
1288   [if $READELF -S conftest | fgrep INIT_ARRAY > /dev/null; then
1289     libc_cv_initfini_array=yes
1290   else
1291     libc_cv_initfini_array=no
1292   fi],
1293   [libc_cv_initfini_array=no])
1294 ])
1295 if test $libc_cv_initfini_array != yes; then
1296   AC_MSG_ERROR([Need linker with .init_array/.fini_array support.])
1297 fi
1298
1299 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1300                libc_cv_ctors_header, [dnl
1301   libc_cv_ctors_header=yes
1302   LIBC_TRY_LINK_STATIC([
1303 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1304 __attribute__ ((destructor))  void dtor (void) { asm (""); }
1305 ],
1306               [dnl
1307       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1308         { gsub(/\@<:@ */, "@<:@") }
1309         $2 == ".ctors" || $2 == ".dtors" {
1310           size = strtonum("0x" $6)
1311           align = strtonum("0x" $NF)
1312           seen@<:@$2@:>@ = 1
1313           stub@<:@$2@:>@ = size == align * 2
1314         }
1315         END {
1316           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1317           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1318           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1319         }
1320       '], [libc_cv_ctors_header=no])
1321     ], [dnl
1322       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1323     ])
1324 ])
1325 if test $libc_cv_ctors_header = no; then
1326   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1327 fi
1328
1329 AC_CACHE_CHECK(for libunwind-support in compiler,
1330                libc_cv_cc_with_libunwind, [
1331   cat > conftest.c <<EOF
1332 int main (void) { return 0; }
1333 EOF
1334   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1335      conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1336     libc_cv_cc_with_libunwind=yes
1337   else
1338     libc_cv_cc_with_libunwind=no
1339   fi
1340   rm -f conftest*])
1341 AC_SUBST(libc_cv_cc_with_libunwind)
1342 if test $libc_cv_cc_with_libunwind = yes; then
1343   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1344 fi
1345
1346 LIBC_LINKER_FEATURE([-z nodelete], [-Wl,--enable-new-dtags,-z,nodelete],
1347                     [libc_cv_z_nodelete=yes],
1348                     [AC_MSG_ERROR(linker with -z nodelete support required)])
1349
1350 LIBC_LINKER_FEATURE([-z nodlopen], [-Wl,--enable-new-dtags,-z,nodlopen],
1351                     [libc_cv_z_nodlopen=yes],
1352                     [AC_MSG_ERROR(linker with -z nodlopen support required)])
1353
1354 LIBC_LINKER_FEATURE([-z initfirst], [-Wl,--enable-new-dtags,-z,initfirst],
1355                     [libc_cv_z_initfirst=yes],
1356                     [AC_MSG_ERROR(linker with -z initfirst support required)])
1357
1358 # Add-on fragments can set these for other machines.
1359 libc_commonpagesize=${libc_commonpagesize:-no}
1360 libc_relro_required=${libc_relro_required:-no}
1361 case "$base_machine" in
1362   i[[34567]]86 | x86_64 | powerpc* | s390*)
1363     libc_commonpagesize=0x1000
1364     libc_relro_required=yes
1365     ;;
1366   sparc*)
1367     libc_commonpagesize=0x2000
1368     libc_relro_required=yes
1369     ;;
1370 esac
1371
1372 if test $libc_commonpagesize != no; then
1373   AC_CACHE_CHECK(for -z relro option,
1374                  libc_cv_z_relro, [dnl
1375   libc_cv_z_relro=no
1376   AC_LANG_CONFTEST([AC_LANG_SOURCE([[
1377 int _start (void) { return 42; }
1378 extern void _exit (int);
1379 /* Since these pointers are const, they should go in rodata.
1380    Since they refer to functions that have to be resolved by
1381    dynamic linking, they should instead go in RELRO data.  */
1382 const void *const relro[] = { &_start, &_exit, 0 };
1383 /* GNU ld fails to produce RELRO data when it's very small and there is no
1384    normal writable data following it, or if only uninitialized (.bss) data
1385    follows it, or only very small writable data.  */
1386 int data[0x10000] = { 1, };
1387 ]])])
1388   cat > conftest.awk <<\EOF
1389 BEGIN {
1390   result = "no"
1391   commonpagesize = strtonum(commonpagesize)
1392 }
1393 { print "LINE:", $0 > "/dev/stderr" }
1394 $1 == "GNU_RELRO" {
1395   vaddr = strtonum($3)
1396   memsz = strtonum($6)
1397   end = vaddr + memsz
1398   printf "vaddr %#x memsz %#x end %#x commonpagesize %#x\n", \
1399     vaddr, memsz, end, commonpagesize > "/dev/stderr"
1400   result = (end % commonpagesize == 0) ? "yes" : "broken"
1401 }
1402 END { print result }
1403 EOF
1404   AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1405                     -fPIC -shared -o conftest.so conftest.c
1406                     -nostartfiles -nostdlib
1407                     -Wl,-z,relro 1>&AS_MESSAGE_LOG_FD]) &&
1408   AC_TRY_COMMAND([$READELF -Wl conftest.so > conftest.ph]) &&
1409   AC_TRY_COMMAND([
1410       $AWK -v commonpagesize=$libc_commonpagesize -f conftest.awk
1411            conftest.ph > conftest.cps
1412     ]) &&
1413   libc_cv_z_relro=`cat conftest.cps 2>&AS_MESSAGE_LOG_FD`
1414   rm -f conftest*])
1415   if { test "x$libc_relro_required" = xyes &&
1416        test "x$libc_cv_z_relro" != xyes
1417      }
1418   then
1419     AC_MSG_ERROR(linker with -z relro support required)
1420   fi
1421 else
1422   AC_MSG_WARN([missing architecture parameter to check for working -z relro])
1423 fi
1424
1425 AC_CACHE_CHECK(for -Bgroup option,
1426                libc_cv_Bgroup, [dnl
1427 cat > conftest.c <<EOF
1428 int _start (void) { return 42; }
1429 EOF
1430 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1431                             -fPIC -shared -o conftest.so conftest.c
1432                             -Wl,-Bgroup -nostdlib 1>&AS_MESSAGE_LOG_FD])
1433 then
1434   libc_cv_Bgroup=yes
1435 else
1436   libc_cv_Bgroup=no
1437 fi
1438 rm -f conftest*])
1439 AC_SUBST(libc_cv_Bgroup)
1440
1441 ASFLAGS_config=
1442 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1443                libc_cv_as_noexecstack, [dnl
1444 cat > conftest.c <<EOF
1445 void foo (void) { }
1446 EOF
1447 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1448                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1449    && grep .note.GNU-stack conftest.s >/dev/null \
1450    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1451                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1452 then
1453   libc_cv_as_noexecstack=yes
1454 else
1455   libc_cv_as_noexecstack=no
1456 fi
1457 rm -f conftest*])
1458 if test $libc_cv_as_noexecstack = yes; then
1459   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1460 fi
1461 AC_SUBST(ASFLAGS_config)
1462
1463 AC_CACHE_CHECK(for -z combreloc,
1464                libc_cv_z_combreloc, [dnl
1465 cat > conftest.c <<EOF
1466 extern int bar (int);
1467 extern int mumble;
1468 int foo (void) { return bar (mumble); }
1469 EOF
1470 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1471                         -fPIC -shared -o conftest.so conftest.c
1472                         -nostdlib -nostartfiles
1473                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1474 then
1475 dnl The following test is a bit weak.  We must use a tool which can test
1476 dnl cross-platform since the gcc used can be a cross compiler.  Without
1477 dnl introducing new options this is not easily doable.  Instead use a tool
1478 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1479 dnl look for a section named .rel.dyn.
1480   if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1481     libc_cv_z_combreloc=yes
1482   else
1483     libc_cv_z_combreloc=no
1484   fi
1485 else
1486   libc_cv_z_combreloc=no
1487 fi
1488 rm -f conftest*])
1489 if test "$libc_cv_z_combreloc" = yes; then
1490   AC_DEFINE(HAVE_Z_COMBRELOC)
1491 fi
1492 AC_SUBST(libc_cv_z_combreloc)
1493
1494 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1495                     [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1496 AC_SUBST(libc_cv_z_execstack)
1497
1498 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1499 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1500 ])
1501
1502 AC_SUBST(libc_cv_fpie)
1503
1504 AC_CACHE_CHECK(for --hash-style option,
1505                libc_cv_hashstyle, [dnl
1506 cat > conftest.c <<EOF
1507 int _start (void) { return 42; }
1508 EOF
1509 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1510                             -fPIC -shared -o conftest.so conftest.c
1511                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1512 then
1513   libc_cv_hashstyle=yes
1514 else
1515   libc_cv_hashstyle=no
1516 fi
1517 rm -f conftest*])
1518 AC_SUBST(libc_cv_hashstyle)
1519
1520 # The linker's default -shared behavior is good enough if it
1521 # does these things that our custom linker scripts ensure that
1522 # all allocated NOTE sections come first.
1523 if test "$use_default_link" = default; then
1524   AC_CACHE_CHECK([for sufficient default -shared layout],
1525                   libc_cv_use_default_link, [dnl
1526   libc_cv_use_default_link=no
1527   cat > conftest.s <<\EOF
1528           .section .note.a,"a",%note
1529           .balign 4
1530           .long 4,4,9
1531           .string "GNU"
1532           .string "foo"
1533           .section .note.b,"a",%note
1534           .balign 4
1535           .long 4,4,9
1536           .string "GNU"
1537           .string "bar"
1538 EOF
1539   if AC_TRY_COMMAND([dnl
1540   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1541        ac_try=`$READELF -S conftest.so | sed -n \
1542          ['${x;p;}
1543           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1544           t a
1545           b
1546           : a
1547           H']`
1548   then
1549     libc_seen_a=no libc_seen_b=no
1550     set -- $ac_try
1551     while test $# -ge 2 -a "$1" = NOTE; do
1552       case "$2" in
1553       .note.a) libc_seen_a=yes ;;
1554       .note.b) libc_seen_b=yes ;;
1555       esac
1556       shift 2
1557     done
1558     case "$libc_seen_a$libc_seen_b" in
1559     yesyes)
1560       libc_cv_use_default_link=yes
1561       ;;
1562     *)
1563       echo >&AS_MESSAGE_LOG_FD "\
1564 $libc_seen_a$libc_seen_b from:
1565 $ac_try"
1566       ;;
1567     esac
1568   fi
1569   rm -f conftest*])
1570   use_default_link=$libc_cv_use_default_link
1571 fi
1572
1573 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1574 if libc_cv_output_format=`
1575 ${CC-cc} -nostartfiles -nostdlib -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1576 then
1577   :
1578 else
1579   libc_cv_output_format=
1580 fi
1581 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1582 AC_SUBST(libc_cv_output_format)
1583
1584 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1585 cat > conftest.c <<EOF
1586 int foo;
1587 EOF
1588 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1589                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1590 then
1591   libc_cv_fno_toplevel_reorder=yes
1592 else
1593   libc_cv_fno_toplevel_reorder=no
1594 fi
1595 rm -f conftest*])
1596 if test $libc_cv_fno_toplevel_reorder = yes; then
1597   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1598 else
1599   fno_unit_at_a_time=-fno-unit-at-a-time
1600 fi
1601 AC_SUBST(fno_unit_at_a_time)
1602
1603 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1604 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
1605                    [libc_cv_ssp=yes],
1606                    [libc_cv_ssp=no])
1607 ])
1608 AC_SUBST(libc_cv_ssp)
1609
1610 AC_CACHE_CHECK(for -fgnu89-inline, libc_cv_gnu89_inline, [dnl
1611 cat > conftest.c <<EOF
1612 int foo;
1613 #ifdef __GNUC_GNU_INLINE__
1614 main () { return 0;}
1615 #else
1616 #error
1617 #endif
1618 EOF
1619 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -std=gnu99 -fgnu89-inline
1620                             -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD])
1621 then
1622   libc_cv_gnu89_inline=yes
1623 else
1624   libc_cv_gnu89_inline=no
1625 fi
1626 rm -f conftest*])
1627 if test $libc_cv_gnu89_inline = yes; then
1628   gnu89_inline=-fgnu89-inline
1629 else
1630   gnu89_inline=
1631 fi
1632 AC_SUBST(gnu89_inline)
1633
1634 AC_CACHE_CHECK(whether cc puts quotes around section names,
1635                libc_cv_have_section_quotes,
1636                [cat > conftest.c <<EOF
1637                 static const int foo
1638                 __attribute__ ((section ("bar"))) = 1;
1639 EOF
1640                 if ${CC-cc} -S conftest.c -o conftest.s; then
1641                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1642                     libc_cv_have_section_quotes=yes
1643                   else
1644                     libc_cv_have_section_quotes=no
1645                   fi
1646                 else
1647                   libc_cv_have_section_quotes=unknown
1648                 fi
1649                 rm -f conftest.{c,s}
1650                 ])
1651 if test $libc_cv_have_section_quotes = yes; then
1652   AC_DEFINE(HAVE_SECTION_QUOTES)
1653 fi
1654
1655 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1656                [dnl
1657 cat > conftest.s <<EOF
1658 ${libc_cv_dot_text}
1659 .globl foo
1660 foo:
1661 .weak foo
1662 .weak bar; bar = foo
1663 EOF
1664 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1665   libc_cv_asm_weak_directive=yes
1666 else
1667   libc_cv_asm_weak_directive=no
1668 fi
1669 rm -f conftest*])
1670
1671 if test $libc_cv_asm_weak_directive = no; then
1672   AC_CACHE_CHECK(for assembler .weakext directive,
1673                  libc_cv_asm_weakext_directive,
1674                  [dnl
1675 cat > conftest.s <<EOF
1676 ${libc_cv_dot_text}
1677 .globl foo
1678 foo:
1679 .weakext bar foo
1680 .weakext baz
1681 .globl baz
1682 baz:
1683 EOF
1684   if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1685     libc_cv_asm_weakext_directive=yes
1686   else
1687     libc_cv_asm_weakext_directive=no
1688   fi
1689   rm -f conftest*])
1690
1691 fi # no .weak
1692
1693 if test $libc_cv_asm_weak_directive = yes; then
1694   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1695 elif test $libc_cv_asm_weakext_directive = yes; then
1696   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1697 fi
1698
1699 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1700 cat > conftest.c <<\EOF
1701 _start () {}
1702 int __eh_pc;
1703 __throw () {}
1704 EOF
1705 dnl No \ in command here because it ends up inside ''.
1706 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1707                             -nostdlib -nostartfiles -Wl,--no-whole-archive
1708                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1709   libc_cv_ld_no_whole_archive=yes
1710 else
1711   libc_cv_ld_no_whole_archive=no
1712 fi
1713 rm -f conftest*])
1714 if test $libc_cv_ld_no_whole_archive = no; then
1715   AC_MSG_ERROR([support for --no-whole-archive is needed])
1716 fi
1717
1718 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1719 cat > conftest.c <<\EOF
1720 _start () {}
1721 int __eh_pc;
1722 __throw () {}
1723 EOF
1724 dnl No \ in command here because it ends up inside ''.
1725 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1726                             -nostdlib -nostartfiles -fexceptions
1727                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1728   libc_cv_gcc_exceptions=yes
1729 else
1730   libc_cv_gcc_exceptions=no
1731 fi
1732 rm -f conftest*])
1733 if test $libc_cv_gcc_exceptions = yes; then
1734   exceptions=-fexceptions
1735 fi
1736 AC_SUBST(exceptions)dnl
1737
1738 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1739 cat > conftest.c <<\EOF
1740 void zero (void *x)
1741 {
1742   __builtin_memset (x, 0, 1000);
1743 }
1744 EOF
1745 dnl
1746 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1747 then
1748   libc_cv_gcc_builtin_memset=no
1749 else
1750   libc_cv_gcc_builtin_memset=yes
1751 fi
1752 rm -f conftest* ])
1753 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1754   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1755 fi
1756
1757 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1758 cat > conftest.c <<\EOF
1759 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1760 char *foo (const char *a, const char *b)
1761 {
1762   return __builtin_strstr (a, b);
1763 }
1764 EOF
1765 dnl
1766 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
1767 then
1768   libc_cv_gcc_builtin_redirection=yes
1769 else
1770   libc_cv_gcc_builtin_redirection=no
1771 fi
1772 rm -f conftest* ])
1773 if test "$libc_cv_gcc_builtin_redirection" = no; then
1774   AC_MSG_ERROR([support for the symbol redirection needed])
1775 fi
1776
1777 dnl Check whether the compiler supports the __thread keyword.
1778 AC_CACHE_CHECK([for __thread], libc_cv_gcc___thread,
1779 [cat > conftest.c <<\EOF
1780 __thread int a = 42;
1781 EOF
1782 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
1783   libc_cv_gcc___thread=yes
1784 else
1785   libc_cv_gcc___thread=no
1786 fi
1787 rm -f conftest*])
1788 if test "$libc_cv_gcc___thread" = no; then
1789   AC_MSG_ERROR([support for the __thread keyword is required])
1790 fi
1791
1792 dnl Check whether the compiler supports the tls_model attribute.
1793 AC_CACHE_CHECK([for tls_model attribute], libc_cv_gcc_tls_model_attr, [dnl
1794 cat > conftest.c <<\EOF
1795 extern __thread int a __attribute__((tls_model ("initial-exec")));
1796 EOF
1797 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -Werror conftest.c >&AS_MESSAGE_LOG_FD]); then
1798   libc_cv_gcc_tls_model_attr=yes
1799 else
1800   libc_cv_gcc_tls_model_attr=no
1801 fi
1802 rm -f conftest*])
1803 if test "$libc_cv_gcc_tls_model_attr" = no; then
1804   AC_MSG_ERROR([support for the tls_model attribute is required])
1805 fi
1806
1807 dnl Determine how to disable generation of FMA instructions.
1808 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1809                libc_cv_cc_nofma, [dnl
1810 libc_cv_cc_nofma=
1811 for opt in -ffp-contract=off -mno-fused-madd; do
1812   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1813 done])
1814 AC_SUBST(libc_cv_cc_nofma)
1815
1816 if test -n "$submachine"; then
1817   AC_CACHE_CHECK([for compiler option for CPU variant],
1818                  libc_cv_cc_submachine, [dnl
1819   libc_cv_cc_submachine=no
1820   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1821     LIBC_TRY_CC_OPTION([$opt], [
1822       libc_cv_cc_submachine="$opt"
1823       break], [])
1824   done])
1825   if test "x$libc_cv_cc_submachine" = xno; then
1826     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1827   fi
1828 fi
1829 AC_SUBST(libc_cv_cc_submachine)
1830
1831 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1832 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1833 cat > conftest.c <<EOF
1834 void
1835 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1836 foo (void) {}
1837 EOF
1838 libc_cv_cc_loop_to_function=no
1839 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1840 then
1841   libc_cv_cc_loop_to_function=yes
1842 fi
1843 rm -f conftest*])
1844 if test $libc_cv_cc_loop_to_function = yes; then
1845   AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1846 fi
1847 AC_SUBST(libc_cv_cc_loop_to_function)
1848
1849 dnl Check whether we have the gd library available.
1850 AC_MSG_CHECKING(for libgd)
1851 if test "$with_gd" != "no"; then
1852   old_CFLAGS="$CFLAGS"
1853   CFLAGS="$CFLAGS $libgd_include"
1854   old_LDFLAGS="$LDFLAGS"
1855   LDFLAGS="$LDFLAGS $libgd_ldflags"
1856   old_LIBS="$LIBS"
1857   LIBS="$LIBS -lgd -lpng -lz -lm"
1858   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1859   CFLAGS="$old_CFLAGS"
1860   LDFLAGS="$old_LDFLAGS"
1861   LIBS="$old_LIBS"
1862 else
1863   LIBGD=no
1864 fi
1865 AC_MSG_RESULT($LIBGD)
1866 AC_SUBST(LIBGD)
1867
1868 # SELinux detection
1869 if test x$with_selinux = xno ; then
1870   have_selinux=no;
1871 else
1872   # See if we have the SELinux library
1873   AC_CHECK_LIB(selinux, is_selinux_enabled,
1874                have_selinux=yes, have_selinux=no)
1875   if test x$with_selinux = xyes ; then
1876     if test x$have_selinux = xno ; then
1877       AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1878     fi
1879   fi
1880 fi
1881 # Check if we're building with SELinux support.
1882 if test "x$have_selinux" = xyes; then
1883   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1884
1885   # See if we have the libaudit library
1886   AC_CHECK_LIB(audit, audit_log_user_avc_message,
1887                have_libaudit=yes, have_libaudit=no)
1888   if test "x$have_libaudit" = xyes; then
1889     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1890   fi
1891   AC_SUBST(have_libaudit)
1892
1893   # See if we have the libcap library
1894   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1895   if test "x$have_libcap" = xyes; then
1896     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1897   fi
1898   AC_SUBST(have_libcap)
1899 fi
1900 AC_SUBST(have_selinux)
1901
1902 dnl check for the size of 'long double'.
1903 AC_CHECK_SIZEOF(long double, 0)
1904 sizeof_long_double=$ac_cv_sizeof_long_double
1905 AC_SUBST(sizeof_long_double)
1906
1907 CPPUNDEFS=
1908 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1909 dnl Since we are building the implementations of the fortified functions here,
1910 dnl having the macro defined interacts very badly.
1911 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1912 [AC_TRY_COMPILE([], [
1913 #ifdef _FORTIFY_SOURCE
1914 # error bogon
1915 #endif],
1916                 [libc_cv_predef_fortify_source=no],
1917                 [libc_cv_predef_fortify_source=yes])])
1918 if test $libc_cv_predef_fortify_source = yes; then
1919   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1920 fi
1921 AC_SUBST(CPPUNDEFS)
1922
1923 dnl Check for silly hacked compilers inserting -fstack-protector.
1924 dnl This breaks badly for the early startup code we compile, since
1925 dnl the compiled code can refer to a magic machine-dependent location
1926 dnl for the canary value before we have sufficient setup for that to
1927 dnl work.  It's also questionable to build all of libc with this flag
1928 dnl even when you're doing that for most applications you build, since
1929 dnl libc's code is so heavily-used and performance-sensitive.  If we
1930 dnl ever really want to make that work, it should be enabled explicitly
1931 dnl in the libc build, not inherited from implicit compiler settings.
1932 AC_CACHE_CHECK([whether $CC implicitly enables -fstack-protector],
1933                libc_cv_predef_stack_protector, [
1934 AC_TRY_COMPILE([extern void foobar (char *);],
1935                [char large_array[2048]; foobar (large_array);], [
1936 libc_undefs=`$NM -u conftest.o |
1937   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1938     2>&AS_MESSAGE_LOG_FD` || {
1939   AC_MSG_ERROR([confusing output from $NM -u])
1940 }
1941 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1942 # On some architectures, there are architecture-specific undefined
1943 # symbols (resolved by the linker), so filter out unknown symbols.
1944 # This will fail to produce the correct result if the compiler
1945 # defaults to -fstack-protector but this produces an undefined symbol
1946 # other than __stack_chk_fail.  However, compilers like that have not
1947 # been encountered in practice.
1948 libc_undefs=`echo "$libc_undefs" | egrep '^(foobar|__stack_chk_fail)$'`
1949 case "$libc_undefs" in
1950 foobar) libc_cv_predef_stack_protector=no ;;
1951 '__stack_chk_fail
1952 foobar') libc_cv_predef_stack_protector=yes ;;
1953 *) AC_MSG_ERROR([unexpected symbols in test: $libc_undefs]) ;;
1954 esac],
1955                [AC_MSG_ERROR([test compilation failed])])
1956 ])
1957 libc_extra_cflags=
1958 if test $libc_cv_predef_stack_protector = yes; then
1959   libc_extra_cflags="$libc_extra_cflags -fno-stack-protector"
1960 fi
1961 libc_extra_cppflags=
1962
1963 AC_CACHE_CHECK([whether the linker provides __ehdr_start],
1964                libc_cv_ehdr_start, [
1965 old_CFLAGS="$CFLAGS"
1966 old_LDFLAGS="$LDFLAGS"
1967 old_LIBS="$LIBS"
1968 CFLAGS="$CFLAGS -fPIC"
1969 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared"
1970 LIBS=
1971 AC_LINK_IFELSE([AC_LANG_SOURCE([
1972 extern const char __ehdr_start __attribute__ ((visibility ("hidden")));
1973 const char *ehdr (void) { return &__ehdr_start; }
1974 ])],
1975                [libc_cv_ehdr_start=yes], [libc_cv_ehdr_start=no])
1976 CFLAGS="$old_CFLAGS"
1977 LDFLAGS="$old_LDFLAGS"
1978 LIBS="$old_LIBS"
1979 ])
1980 if test $libc_cv_ehdr_start = yes; then
1981   AC_DEFINE([HAVE_EHDR_START])
1982 fi
1983
1984 ### End of automated tests.
1985 ### Now run sysdeps configure fragments.
1986
1987 # They also can set these variables.
1988 use_ldconfig=no
1989 ldd_rewrite_script=no
1990 libc_cv_sysconfdir=$sysconfdir
1991 libc_cv_localstatedir=$localstatedir
1992 libc_cv_gcc_unwind_find_fde=no
1993 libc_cv_idn=no
1994
1995 # Iterate over all the sysdep directories we will use, running their
1996 # configure fragments.
1997 for dir in $sysnames; do
1998   case $dir in
1999     /*) dest=$dir ;;
2000     *)  dest=$srcdir/$dir ;;
2001   esac
2002   if test -r $dest/configure; then
2003     AC_MSG_RESULT(running configure fragment for $dir)
2004     . $dest/configure
2005   fi
2006 done
2007
2008 AC_SUBST(libc_extra_cflags)
2009 AC_SUBST(libc_extra_cppflags)
2010
2011 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
2012   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
2013 fi
2014 AC_SUBST(libc_cv_gcc_unwind_find_fde)
2015
2016 # A sysdeps configure fragment can reset this if IFUNC is not actually
2017 # usable even though the assembler knows how to generate the symbol type.
2018 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
2019   AC_DEFINE(HAVE_IFUNC)
2020 fi
2021
2022 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
2023 # configure fragment can override the value to prevent this AC_DEFINE.
2024 AC_SUBST(use_nscd)
2025 if test "x$use_nscd" != xno; then
2026   AC_DEFINE([USE_NSCD])
2027 fi
2028 if test "x$build_nscd" = xdefault; then
2029   build_nscd=$use_nscd
2030 fi
2031
2032 # Test for old glibc 2.0.x headers so that they can be removed properly
2033 # Search only in includedir.
2034 AC_MSG_CHECKING(for old glibc 2.0.x headers)
2035 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
2036 then
2037   old_glibc_headers=yes
2038 else
2039   old_glibc_headers=no
2040 fi
2041 AC_MSG_RESULT($old_glibc_headers)
2042 if test ${old_glibc_headers} = yes; then
2043   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
2044   AC_MSG_WARN(*** be removed.)
2045 fi
2046 AC_SUBST(old_glibc_headers)
2047
2048 AC_SUBST(libc_cv_slibdir)
2049 AC_SUBST(libc_cv_rtlddir)
2050 AC_SUBST(libc_cv_localedir)
2051 AC_SUBST(libc_cv_sysconfdir)
2052 AC_SUBST(libc_cv_localstatedir)
2053 AC_SUBST(libc_cv_rootsbindir)
2054 AC_SUBST(libc_cv_forced_unwind)
2055
2056 if test x$use_ldconfig = xyes; then
2057   AC_DEFINE(USE_LDCONFIG)
2058 fi
2059 AC_SUBST(use_ldconfig)
2060 AC_SUBST(ldd_rewrite_script)
2061
2062 AC_SUBST(static)
2063 AC_SUBST(shared)
2064
2065 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
2066 [libc_cv_pic_default=yes
2067 cat > conftest.c <<EOF
2068 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
2069 # error PIC is default.
2070 #endif
2071 EOF
2072 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
2073   libc_cv_pic_default=no
2074 fi
2075 rm -f conftest.*])
2076 AC_SUBST(libc_cv_pic_default)
2077
2078 AC_SUBST(profile)
2079 AC_SUBST(static_nss)
2080
2081 AC_SUBST(DEFINES)
2082
2083 dnl See sysdeps/mach/configure.ac for this variable.
2084 AC_SUBST(mach_interface_list)
2085
2086 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
2087 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
2088 AC_SUBST(VERSION)
2089 AC_SUBST(RELEASE)
2090
2091 AC_CONFIG_FILES([config.make Makefile])
2092 AC_CONFIG_COMMANDS([default],[[
2093 case $CONFIG_FILES in *config.make*)
2094 echo "$config_vars" >> config.make;;
2095 esac
2096 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
2097 AC_OUTPUT