configure.ac

   1 m4_define([weston_major_version], [1])
   2 m4_define([weston_minor_version], [0])
   3 m4_define([weston_micro_version], [90])
   4 m4_define([weston_version],
   5           [weston_major_version.weston_minor_version.weston_micro_version])
   6
   7 AC_PREREQ([2.64])
   8 AC_INIT([weston],
   9         [weston_version],
  10         [https://bugs.freedesktop.org/enter_bug.cgi?product=Wayland&component=weston&version=weston_version],
  11         [weston],
  12         [http://wayland.freedesktop.org/])
  13
  14 AC_SUBST([WESTON_VERSION_MAJOR], [weston_major_version])
  15 AC_SUBST([WESTON_VERSION_MINOR], [weston_minor_version])
  16 AC_SUBST([WESTON_VERSION_MICRO], [weston_micro_version])
  17 AC_SUBST([WESTON_VERSION], [weston_version])
  18
  19 AC_CONFIG_HEADERS([config.h])
  20
  21 AM_INIT_AUTOMAKE([1.11 parallel-tests foreign no-dist-gzip dist-xz color-tests])
  22
  23 AM_SILENT_RULES([yes])
  24
  25 # Check for programs
  26 AC_PROG_CC
  27 AC_PROG_SED
  28
  29 # Initialize libtool
  30 LT_PREREQ([2.2])
  31 LT_INIT([disable-static])
  32
  33 AC_ARG_VAR([WESTON_NATIVE_BACKEND],
  34            [Set the native backend to use, if Weston is not running under Wayland nor X11. @<:@default=drm-backend.so@:>@])
  35
  36 PKG_PROG_PKG_CONFIG()
  37
  38 AC_CHECK_FUNC([dlopen], [],
  39               AC_CHECK_LIB([dl], [dlopen], DLOPEN_LIBS="-ldl"))
  40 AC_SUBST(DLOPEN_LIBS)
  41
  42 AC_CHECK_HEADERS([execinfo.h])
  43
  44 AC_CHECK_FUNCS([mkostemp strchrnul])
  45
  46 COMPOSITOR_MODULES="wayland-server xkbcommon pixman-1"
  47
  48 AC_ARG_ENABLE(egl, [  --disable-egl],,
  49               enable_egl=yes)
  50 AM_CONDITIONAL(ENABLE_EGL, test x$enable_egl = xyes)
  51 if test x$enable_egl = xyes; then
  52         AC_DEFINE([ENABLE_EGL], [1], [Build Weston with EGL support])
  53         COMPOSITOR_MODULES="$COMPOSITOR_MODULES egl >= 7.10 glesv2"
  54 fi
  55
  56 PKG_CHECK_MODULES(COMPOSITOR, [$COMPOSITOR_MODULES])
  57
  58 AC_ARG_ENABLE(setuid-install, [  --enable-setuid-install],,
  59               enable_setuid_install=yes)
  60 AM_CONDITIONAL(ENABLE_SETUID_INSTALL, test x$enable_setuid_install = xyes)
  61
  62
  63 AC_ARG_ENABLE(xwayland, [  --enable-xwayland],,
  64               enable_xwayland=yes)
  65 AC_ARG_ENABLE(xwayland-test, [  --enable-xwayland-test],,
  66               enable_xwayland_test=yes)
  67 AM_CONDITIONAL(ENABLE_XWAYLAND, test x$enable_xwayland = xyes)
  68 AM_CONDITIONAL(ENABLE_XWAYLAND_TEST, test x$enable_xwayland = xyes -a x$enable_xwayland_test = xyes)
  69 if test x$enable_xwayland = xyes; then
  70   PKG_CHECK_MODULES([XWAYLAND], xcb xcb-xfixes xcursor cairo-xcb)
  71   AC_DEFINE([BUILD_XWAYLAND], [1], [Build the X server launcher])
  72
  73   AC_ARG_WITH(xserver-path, AS_HELP_STRING([--with-xserver-path=PATH],
  74               [Path to X server]), [XSERVER_PATH="$withval"],
  75               [XSERVER_PATH="$bindir/Xorg"])
  76   AC_SUBST([XSERVER_PATH])
  77   if test x$enable_xwayland_test = xyes; then
  78     PKG_CHECK_MODULES([XWAYLAND_TEST], xcb xcb-dri2 libdrm)
  79   fi
  80 fi
  81
  82
  83 AC_ARG_ENABLE(x11-compositor, [  --enable-x11-compositor],,
  84               enable_x11_compositor=yes)
  85 AM_CONDITIONAL(ENABLE_X11_COMPOSITOR, test x$enable_x11_compositor = xyes)
  86 if test x$enable_x11_compositor = xyes; then
  87   PKG_CHECK_MODULES([XCB], xcb)
  88   xcb_save_LIBS=$LIBS
  89   xcb_save_CFLAGS=$CFLAGS
  90   CFLAGS=$XCB_CFLAGS
  91   LIBS=$XCB_LIBS
  92   AC_CHECK_FUNCS([xcb_poll_for_queued_event])
  93   LIBS=$xcb_save_LIBS
  94   CFLAGS=$xcb_save_CFLAGS
  95
  96   X11_COMPOSITOR_MODULES="x11 x11-xcb xcb-shm"
  97
  98   PKG_CHECK_MODULES(X11_COMPOSITOR_XKB, [xcb-xkb],
  99                     [have_xcb_xkb="yes"], [have_xcb_xkb="no"])
 100   if test "x$have_xcb_xkb" = xyes; then
 101         # Most versions of XCB have totally broken XKB bindings, where the
 102         # events don't work.  Make sure we can actually use them.
 103         xcb_xkb_save_CFLAGS=$CFLAGS
 104         CFLAGS=$X11_COMPOSITOR_XKB_CFLAGS
 105         AC_CHECK_MEMBER([struct xcb_xkb_state_notify_event_t.xkbType],
 106                         [], [have_xcb_xkb=no], [[#include <xcb/xkb.h>]])
 107         CFLAGS=$xcb_xkb_save_CFLAGS
 108   fi
 109   if test "x$have_xcb_xkb" = xyes; then
 110         X11_COMPOSITOR_MODULES="$X11_COMPOSITOR_MODULES xcb-xkb"
 111         AC_DEFINE([HAVE_XCB_XKB], [1], [libxcb supports XKB protocol])
 112   fi
 113
 114   PKG_CHECK_MODULES(X11_COMPOSITOR, [$X11_COMPOSITOR_MODULES])
 115   AC_DEFINE([BUILD_X11_COMPOSITOR], [1], [Build the X11 compositor])
 116 fi
 117
 118
 119 AC_ARG_ENABLE(drm-compositor, [  --enable-drm-compositor],,
 120               enable_drm_compositor=yes)
 121 AM_CONDITIONAL(ENABLE_DRM_COMPOSITOR, test x$enable_drm_compositor = xyes -a x$enable_egl = xyes)
 122 if test x$enable_drm_compositor = xyes -a x$enable_egl = xyes; then
 123   AC_DEFINE([BUILD_DRM_COMPOSITOR], [1], [Build the DRM compositor])
 124   PKG_CHECK_MODULES(DRM_COMPOSITOR, [libudev >= 136 libdrm >= 2.4.30 gbm mtdev >= 1.1.0])
 125 fi
 126
 127
 128 AC_ARG_ENABLE(wayland-compositor, [  --enable-wayland-compositor],,
 129               enable_wayland_compositor=yes)
 130 AM_CONDITIONAL(ENABLE_WAYLAND_COMPOSITOR,
 131                test x$enable_wayland_compositor = xyes -a x$enable_egl = xyes)
 132 if test x$enable_wayland_compositor = xyes -a x$enable_egl = xyes; then
 133   AC_DEFINE([BUILD_WAYLAND_COMPOSITOR], [1],
 134             [Build the Wayland (nested) compositor])
 135   PKG_CHECK_MODULES(WAYLAND_COMPOSITOR, [wayland-client wayland-egl])
 136 fi
 137
 138
 139 AC_ARG_ENABLE(headless-compositor, [  --enable-headless-compositor],,
 140               enable_headless_compositor=yes)
 141 AM_CONDITIONAL(ENABLE_HEADLESS_COMPOSITOR,
 142                test x$enable_headless_compositor = xyes)
 143
 144
 145 AC_ARG_ENABLE(rpi-compositor,
 146               AS_HELP_STRING([--disable-rpi-compositor],
 147                              [do not build the Raspberry Pi backend]),,
 148               enable_rpi_compositor=yes)
 149 AM_CONDITIONAL(ENABLE_RPI_COMPOSITOR, test "x$enable_rpi_compositor" = "xyes" -a "x$enable_egl" = "xyes")
 150 have_bcm_host="no"
 151 if test x$enable_rpi_compositor = xyes -a x$enable_egl = xyes; then
 152   AC_DEFINE([BUILD_RPI_COMPOSITOR], [1], [Build the compositor for Raspberry Pi])
 153   PKG_CHECK_MODULES(RPI_COMPOSITOR, [libudev >= 136 mtdev >= 1.1.0])
 154   PKG_CHECK_MODULES(RPI_BCM_HOST, [bcm_host],
 155                     [have_bcm_host="yes"
 156                      AC_DEFINE([HAVE_BCM_HOST], [1], [have Raspberry Pi BCM headers])],
 157                     [AC_MSG_WARN([Raspberry Pi BCM host libraries not found, will use stubs instead.])])
 158 fi
 159 AM_CONDITIONAL(INSTALL_RPI_COMPOSITOR, test "x$have_bcm_host" = "xyes")
 160
 161
 162 AC_ARG_ENABLE([fbdev-compositor], [  --enable-fbdev-compositor],,
 163               enable_fbdev_compositor=yes)
 164 AM_CONDITIONAL([ENABLE_FBDEV_COMPOSITOR],
 165                [test x$enable_fbdev_compositor = xyes])
 166 AS_IF([test x$enable_fbdev_compositor = xyes], [
 167   AC_DEFINE([BUILD_FBDEV_COMPOSITOR], [1], [Build the fbdev compositor])
 168   PKG_CHECK_MODULES([FBDEV_COMPOSITOR], [libudev >= 136 mtdev >= 1.1.0])
 169 ])
 170
 171 AC_ARG_ENABLE([rdp-compositor], [  --enable-rdp-compositor],,
 172               enable_rdp_compositor=no)
 173 AM_CONDITIONAL([ENABLE_RDP_COMPOSITOR],
 174                [test x$enable_rdp_compositor = xyes])
 175 if test x$enable_rdp_compositor = xyes; then
 176   PKG_CHECK_MODULES(RDP_COMPOSITOR, [freerdp >= 1.1.0])
 177 fi
 178
 179 AC_ARG_WITH(cairo-glesv2,
 180             AS_HELP_STRING([--with-cairo-glesv2],
 181                            [Use GLESv2 cairo instead of full GL]))
 182 if test "x$with_cairo_glesv2" = "xyes"; then
 183   cairo_modules="cairo-glesv2"
 184   AC_DEFINE([USE_CAIRO_GLESV2], [1], [Use the GLESv2 GL cairo backend])
 185 else
 186   cairo_modules="cairo-gl"
 187 fi
 188
 189 PKG_CHECK_MODULES(PIXMAN, [pixman-1])
 190 PKG_CHECK_MODULES(PNG, [libpng])
 191 PKG_CHECK_MODULES(WEBP, [libwebp], [have_webp=yes], [have_webp=no])
 192 AS_IF([test "x$have_webp" = "xyes"],
 193       [AC_DEFINE([HAVE_WEBP], [1], [Have webp])])
 194
 195 AC_CHECK_LIB([jpeg], [jpeg_CreateDecompress], have_jpeglib=yes)
 196 if test x$have_jpeglib = xyes; then
 197   JPEG_LIBS="-ljpeg"
 198 else
 199   AC_ERROR([libjpeg not found])
 200 fi
 201 AC_SUBST(JPEG_LIBS)
 202
 203 PKG_CHECK_MODULES(CAIRO, [cairo])
 204
 205 AC_ARG_ENABLE(simple-clients,
 206               AS_HELP_STRING([--disable-simple-clients],
 207                              [do not build the simple wl_shm clients]),,
 208               enable_simple_clients=yes)
 209 AM_CONDITIONAL(BUILD_SIMPLE_CLIENTS, test "x$enable_simple_clients" = "xyes")
 210 if test x$enable_simple_clients = xyes; then
 211   PKG_CHECK_MODULES(SIMPLE_CLIENT, [wayland-client])
 212 fi
 213
 214 AC_ARG_ENABLE(simple-egl-clients,
 215               AS_HELP_STRING([--disable-simple-egl-clients],
 216                              [do not build the simple EGL clients]),,
 217               enable_simple_egl_clients=yes)
 218 AM_CONDITIONAL(BUILD_SIMPLE_EGL_CLIENTS, test "x$enable_simple_egl_clients" = "xyes" -a "x$enable_egl" = "xyes")
 219 if test x$enable_simple_egl_clients = xyes -a x$enable_egl = xyes; then
 220   PKG_CHECK_MODULES(SIMPLE_EGL_CLIENT,
 221                     [egl >= 7.10 glesv2 wayland-client wayland-egl wayland-cursor])
 222 fi
 223
 224 AC_ARG_ENABLE(clients, [  --enable-clients],, enable_clients=yes)
 225 AM_CONDITIONAL(BUILD_CLIENTS, test x$enable_clients = xyes)
 226 if test x$enable_clients = xyes; then
 227   AC_DEFINE([BUILD_CLIENTS], [1], [Build the Wayland clients])
 228
 229   PKG_CHECK_MODULES(CLIENT, [wayland-client cairo >= 1.10.0 xkbcommon wayland-cursor])
 230   PKG_CHECK_MODULES(WESTON_INFO, [wayland-client])
 231
 232   PKG_CHECK_MODULES(POPPLER, [poppler-glib glib-2.0 gobject-2.0 gio-2.0 ],
 233                              [have_poppler=yes], [have_poppler=no])
 234   PKG_CHECK_MODULES(CAIRO_EGL, [wayland-egl egl >= 7.10 cairo-egl >= 1.11.3 $cairo_modules],
 235                     [have_cairo_egl=yes], [have_cairo_egl=no])
 236   AS_IF([test "x$have_cairo_egl" = "xyes"],
 237         [AC_DEFINE([HAVE_CAIRO_EGL], [1], [Have cairo-egl])],
 238         [AC_MSG_WARN([clients will use cairo image, cairo-egl not used because $CAIRO_EGL_PKG_ERRORS])])
 239   PKG_CHECK_MODULES(PANGO, [pangocairo], [have_pango=yes], [have_pango=no])
 240 fi
 241
 242 AC_ARG_ENABLE(weston-launch, [  --enable-weston-launch],, enable_weston_launch=yes)
 243 AM_CONDITIONAL(BUILD_WESTON_LAUNCH, test x$enable_weston_launch == xyes)
 244 if test x$enable_weston_launch == xyes; then
 245   PKG_CHECK_MODULES(WESTON_LAUNCH, [libdrm])
 246   PKG_CHECK_MODULES(SYSTEMD_LOGIN, [libsystemd-login],
 247                     [have_systemd_login=yes], [have_systemd_login=no])
 248   AS_IF([test "x$have_systemd_login" = "xyes"],
 249         [AC_DEFINE([HAVE_SYSTEMD_LOGIN], [1], [Have systemd-login])])
 250
 251   AC_CHECK_LIB([pam], [pam_open_session], [have_pam=yes], [have_pam=no])
 252   if test x$have_pam == xno; then
 253     AC_ERROR([weston-launch requires pam])
 254   fi
 255   WESTON_LAUNCH_LIBS="$WESTON_LAUNCH_LIBS -lpam"
 256 fi
 257
 258 if test x$enable_egl = xyes; then
 259   PKG_CHECK_MODULES(GLU, [glu], [have_glu=yes], [have_glu=no])
 260 fi
 261 AM_CONDITIONAL(HAVE_GLU, test "x$have_glu" = "xyes")
 262
 263
 264 AM_CONDITIONAL(HAVE_POPPLER, test "x$have_poppler" = "xyes")
 265
 266 AM_CONDITIONAL(HAVE_PANGO, test "x$have_pango" = "xyes")
 267
 268 AM_CONDITIONAL(BUILD_FULL_GL_CLIENTS,
 269                test x$cairo_modules = "xcairo-gl" -a "x$have_cairo_egl" = "xyes" -a "x$enable_egl" = "xyes")
 270
 271 AM_CONDITIONAL(ENABLE_DESKTOP_SHELL, true)
 272
 273 AC_ARG_ENABLE(tablet-shell,
 274               AS_HELP_STRING([--disable-tablet-shell],
 275                              [do not build tablet-shell server plugin and client]),,
 276               enable_tablet_shell=yes)
 277 AM_CONDITIONAL(ENABLE_TABLET_SHELL,
 278                test "x$enable_tablet_shell" = "xyes")
 279
 280
 281 AC_ARG_ENABLE(wcap-tools, [  --disable-wcap-tools],, enable_wcap_tools=yes)
 282 AM_CONDITIONAL(BUILD_WCAP_TOOLS, test x$enable_wcap_tools = xyes)
 283 if test x$enable_wcap_tools = xyes; then
 284   AC_DEFINE([BUILD_WCAP_TOOLS], [1], [Build the wcap tools])
 285   PKG_CHECK_MODULES(WCAP, [cairo])
 286   WCAP_LIBS="$WCAP_LIBS -lm"
 287 fi
 288
 289 AC_CHECK_PROG(RSVG_CONVERT, rsvg-convert, rsvg-convert)
 290 AM_CONDITIONAL(HAVE_RSVG_CONVERT, test -n "$RSVG_CONVERT")
 291
 292 PKG_CHECK_MODULES(SETBACKLIGHT, [libudev libdrm], enable_setbacklight=yes, enable_setbacklight=no)
 293 AM_CONDITIONAL(BUILD_SETBACKLIGHT, test "x$enable_setbacklight" = "xyes")
 294
 295 if test "x$GCC" = "xyes"; then
 296         GCC_CFLAGS="-Wall -Wextra -Wno-unused-parameter \
 297                 -Wno-missing-field-initializers -g -fvisibility=hidden \
 298                 -Wstrict-prototypes -Wmissing-prototypes"
 299 fi
 300 AC_SUBST(GCC_CFLAGS)
 301
 302 PKG_CHECK_MODULES(LIBUNWIND, libunwind,
 303                   [have_libunwind=yes], [have_libunwind=no])
 304 if test "x$have_libunwind" = xyes; then
 305        AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
 306 fi
 307 AM_CONDITIONAL(HAVE_LIBUNWIND, [test "x$have_libunwind" = xyes])
 308
 309 if test "x$WESTON_NATIVE_BACKEND" = "x"; then
 310         WESTON_NATIVE_BACKEND="drm-backend.so"
 311 fi
 312 AC_MSG_NOTICE([Weston's native backend: $WESTON_NATIVE_BACKEND])
 313 AC_DEFINE_UNQUOTED([WESTON_NATIVE_BACKEND], ["$WESTON_NATIVE_BACKEND"],
 314                    [The default backend to load, if not wayland nor x11.])
 315
 316 WAYLAND_SCANNER_RULES(['$(top_srcdir)/protocol'])
 317
 318 AC_CONFIG_FILES([Makefile
 319                  shared/Makefile
 320                  src/Makefile
 321                  src/xwayland/Makefile
 322                  src/version.h
 323                  src/weston.pc
 324                  clients/Makefile
 325                  wcap/Makefile
 326                  data/Makefile
 327                  protocol/Makefile
 328                  man/Makefile
 329                  tests/Makefile])
 330 AC_OUTPUT