configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # This file is part of PulseAudio.
   5 #
   6 # Copyright 2004-2008 Lennart Poettering
   7 # Copyright 2006-2007 Pierre Ossman <ossman@cendio.se> for Cendio AB
   8 #
   9 # PulseAudio is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU Lesser General Public License as published by
  11 # the Free Software Foundation; either version 2 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # PulseAudio is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  17 # General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public License
  20 # along with PulseAudio; if not, write to the Free Software Foundation,
  21 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  22
  23 AC_PREREQ(2.60)
  24
  25 m4_define(PA_MAJOR, [0])
  26 m4_define(PA_MINOR, [9])
  27 m4_define(PA_MICRO, [11])
  28
  29 AC_INIT([pulseaudio], PA_MAJOR.PA_MINOR.PA_MICRO,[mzchyfrnhqvb (at) 0pointer (dot) net])
  30 AC_CONFIG_SRCDIR([src/daemon/main.c])
  31 AC_CONFIG_HEADERS([config.h])
  32 AM_INIT_AUTOMAKE([foreign 1.10 -Wall])
  33
  34 AC_SUBST(PA_MAJORMINOR, "PA_MAJOR.PA_MINOR")
  35 AC_SUBST(PACKAGE_URL, [http://pulseaudio.org/])
  36
  37 AC_SUBST(PA_API_VERSION, 12)
  38 AC_SUBST(PA_PROTOCOL_VERSION, 14)
  39
  40 # The stable ABI for client applications, for the version info x:y:z
  41 # always will hold y=z
  42 AC_SUBST(LIBPULSE_VERSION_INFO, [5:0:5])
  43
  44 # A simplified, synchronous, ABI-stable interface for client
  45 # applications, for the version info x:y:z always will hold y=z
  46 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [0:1:0])
  47
  48 # The ABI-stable network browsing interface for client applications,
  49 # for the version info x:y:z always will hold y=z
  50 AC_SUBST(LIBPULSE_BROWSE_VERSION_INFO, [1:1:1])
  51
  52 # The ABI-stable GLib adapter for client applications, for the version
  53 # info x:y:z always will hold y=z
  54 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:3:0])
  55
  56 # An internally used, ABI-unstable library that contains the
  57 # PulseAudio core, SONAMEs are bumped on every release, version info
  58 # suffix will always be 0:0
  59 AC_SUBST(LIBPULSECORE_VERSION_INFO, [6:0:0])
  60
  61 AC_CANONICAL_HOST
  62 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  63
  64 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  65    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  66    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  67 fi
  68
  69 #### Platform hacks ####
  70
  71 case $host in
  72    *-*-solaris* )
  73       AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  74       AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
  75       AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  76       ;;
  77 esac
  78
  79 #### Checks for programs. ####
  80
  81 # mkdir -p
  82
  83 AC_PROG_MKDIR_P
  84
  85 # CC
  86
  87 AC_PROG_CC
  88 AM_PROG_CC_C_O
  89 AC_PROG_GCC_TRADITIONAL
  90 AC_GNU_SOURCE
  91
  92 # M4
  93
  94 AC_PATH_PROG([M4], [m4 gm4], [no])
  95 if test "x$M4" = xno ; then
  96    AC_MSG_ERROR([m4 missing])
  97 fi
  98
  99 # GCC flags
 100
 101 test_gcc_flag() {
 102     AC_LANG_CONFTEST([int main(int argc, char*argv[]) {}])
 103     $CC -c conftest.c $CFLAGS -o conftest.o > /dev/null 2> /dev/null
 104     ret=$?
 105     rm -f conftest.o
 106     return $ret
 107 }
 108
 109 # If using GCC specify some additional parameters
 110 if test "x$GCC" = "xyes" ; then
 111
 112     # We use gnu99 instead of c99 because many have interpreted the standard
 113     # in a way that int64_t isn't defined on non-64 bit platforms.
 114     DESIRED_FLAGS="-std=gnu99 -Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter -ffast-math"
 115
 116     for flag in $DESIRED_FLAGS ; do
 117         AC_MSG_CHECKING([whether $CC accepts $flag])
 118         if test_gcc_flag $flag ; then
 119            CFLAGS="$CFLAGS $flag"
 120            AC_MSG_RESULT([yes])
 121         else
 122            AC_MSG_RESULT([no])
 123         fi
 124     done
 125 fi
 126
 127 # Native atomic operation support
 128 AC_ARG_ENABLE([atomic-arm-linux-helpers],
 129     AC_HELP_STRING([--disable-atomic-arm-linux-helpers], [use inline asm or libatomic_ops instead]),
 130         [
 131             case "${enableval}" in
 132                 yes) atomic_arm_linux_helpers=yes ;;
 133                 no) atomic_arm_linux_helpers=no ;;
 134                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-atomic-arm-linux-helpers) ;;
 135             esac
 136         ],
 137         [atomic_arm_linux_helpers=auto])
 138
 139 AC_ARG_ENABLE([atomic-arm-memory-barrier],
 140     AC_HELP_STRING([--enable-atomic-arm-memory-barrier], [only really needed in SMP arm systems]),
 141         [
 142             case "${enableval}" in
 143                 yes) AC_DEFINE_UNQUOTED(ATOMIC_ARM_MEMORY_BARRIER_ENABLED, 1, [Enable memory barriers]) ;;
 144                 no) ;;
 145                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-atomic-arm-linux-helpers) ;;
 146             esac
 147         ],)
 148
 149 AC_MSG_CHECKING([target operating system])
 150 case $host in
 151         *-*-linux*)
 152             AC_MSG_RESULT([linux])
 153             pulse_target_os=linux
 154         ;;
 155         *)
 156             AC_MSG_RESULT([unknown])
 157             pulse_target_os=unknown
 158         ;;
 159 esac
 160
 161 # If everything else fails use libatomic_ops
 162 need_libatomic_ops=yes
 163
 164 AC_MSG_CHECKING([whether $CC knows __sync_bool_compare_and_swap()])
 165 AC_LANG_CONFTEST([int main() { int a = 4; __sync_bool_compare_and_swap(&a, 4, 5); }])
 166 $CC conftest.c $CFLAGS -o conftest > /dev/null 2> /dev/null
 167 ret=$?
 168 rm -f conftest.o conftest
 169 if test $ret -eq 0 ; then
 170     AC_DEFINE([HAVE_ATOMIC_BUILTINS], 1, [Have __sync_bool_compare_and_swap() and friends.])
 171     AC_MSG_RESULT([yes])
 172     need_libatomic_ops=no
 173 else
 174     AC_MSG_RESULT([no])
 175     # HW specific atomic ops stuff
 176     AC_MSG_CHECKING([architecture for native atomic operations])
 177     case $host_cpu in
 178         arm*)
 179             AC_MSG_RESULT([arm])
 180             AC_MSG_CHECKING([whether we can use Linux kernel helpers])
 181             # The Linux kernel helper functions have been there since 2.6.16. However
 182             # compile time checking for kernel version in cross compile environment
 183             # (which is usually the case for arm cpu) is tricky (or impossible).
 184             if test "x$pulse_target_os" = "xlinux" && test "x$atomic_arm_linux_helpers" != "xno"; then
 185                 AC_MSG_RESULT([yes])
 186                 AC_DEFINE_UNQUOTED(ATOMIC_ARM_LINUX_HELPERS, 1, [special arm linux implementation])
 187                 need_libatomic_ops=no
 188             else
 189                AC_MSG_RESULT([no])
 190                AC_MSG_CHECKING([compiler support for arm inline asm atomic operations])
 191                AC_LANG_CONFTEST([[int main()
 192                {
 193                    volatile int a=0;
 194                    int o=0, n=1, r;
 195                    asm volatile ("ldrex %0, [%1]\n"
 196                                  "subs  %0, %0, %2\n"
 197                                  "strexeq %0, %3, [%1]\n"
 198                                  : "=&r" (r)
 199                                  : "r" (&a), "Ir" (o), "r" (n)
 200                                  : "cc");
 201                    return (a==1 ? 0 : -1);
 202                }]])
 203                $CC conftest.c $CFLAGS -o conftest > /dev/null 2>&1
 204                ret=$?
 205                rm -f conftest.o conftest
 206                if test $ret -eq 0 ; then
 207                    AC_DEFINE([ATOMIC_ARM_INLINE_ASM], 1, [Have ARMv6 instructions.])
 208                    AC_MSG_RESULT([yes])
 209                    need_libatomic_ops=no
 210                else
 211                    AC_MSG_RESULT([no])
 212                fi
 213            fi
 214         ;;
 215         *)
 216             AC_MSG_RESULT([unknown])
 217         ;;
 218     esac
 219 fi
 220
 221 AC_MSG_CHECKING([whether $CC knows __thread])
 222 AC_LANG_CONFTEST([static __thread int a = 6; int main() { a = 5; }])
 223 $CC conftest.c $CFLAGS -o conftest > /dev/null 2> /dev/null
 224 ret=$?
 225 rm -f conftest.o conftest
 226 if test $ret -eq 0 ; then
 227     AC_DEFINE([HAVE_TLS_BUILTIN], 1, [Have __thread().])
 228     AC_MSG_RESULT([yes])
 229 else
 230     AC_MSG_RESULT([no])
 231 fi
 232
 233 AC_MSG_CHECKING([whether $CC knows _Bool])
 234 AC_LANG_CONFTEST([int main() { _Bool b; }])
 235 $CC conftest.c $CFLAGS -o conftest > /dev/null 2> /dev/null
 236 ret=$?
 237 rm -f conftest.o conftest
 238 if test $ret -eq 0 ; then
 239     AC_DEFINE([HAVE_STD_BOOL], 1, [Have _Bool.])
 240     AC_MSG_RESULT([yes])
 241 else
 242     AC_MSG_RESULT([no])
 243 fi
 244
 245 #### libtool stuff ####
 246
 247 AC_LTDL_ENABLE_INSTALL
 248 AC_LIBLTDL_INSTALLABLE
 249 AC_LIBTOOL_DLOPEN
 250 AC_LIBTOOL_WIN32_DLL
 251 AC_PROG_LIBTOOL
 252 AC_SUBST(LTDLINCL)
 253 AC_SUBST(LIBLTDL)
 254 AC_CONFIG_SUBDIRS(libltdl)
 255
 256 old_LIBS=$LIBS
 257 LIBS="$LIBS $LIBLTDL"
 258 AC_CHECK_FUNCS([lt_dlmutex_register])
 259 LIBS=$old_LIBS
 260 AC_CHECK_TYPES([struct lt_user_dlloader, lt_dladvise], , , [#include <ltdl.h>])
 261
 262 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 263     AC_MSG_ERROR([[
 264
 265         *** Cannot find the libltdl development files.
 266         *** Maybe you need to install the libltdl-dev package.
 267         ]])
 268 fi
 269
 270 #### Determine build environment ####
 271
 272 os_is_win32=0
 273
 274 case "$host_os" in
 275         mingw*)
 276         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 277         os_is_win32=1
 278                 ;;
 279         esac
 280
 281 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 282
 283 ###################################
 284 #   Basic environment checks      #
 285 ###################################
 286
 287 #### Checks for header files. ####
 288
 289 # ISO
 290 AC_HEADER_STDC
 291
 292 # POSIX
 293 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 294     netinet/in_systm.h netinet/tcp.h poll.h pwd.h sched.h \
 295     sys/mman.h sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 296     syslog.h sys/dl.h dlfcn.h linux/sockios.h])
 297 AC_CHECK_HEADERS([netinet/ip.h], [], [],
 298                  [#include <sys/types.h>
 299                   #if HAVE_NETINET_IN_H
 300                   # include <netinet/in.h>
 301                   #endif
 302                   #if HAVE_NETINET_IN_SYSTM_H
 303                   # include <netinet/in_systm.h>
 304                   #endif
 305                  ])
 306 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 307 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 308
 309 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 310 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 311
 312 # Linux
 313 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 314
 315 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 316
 317 AC_CHECK_HEADERS([sys/prctl.h])
 318
 319 # Solaris
 320 AC_CHECK_HEADERS([sys/filio.h])
 321
 322 # Windows
 323 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 324
 325 # Other
 326 AC_CHECK_HEADERS([sys/ioctl.h])
 327 AC_CHECK_HEADERS([byteswap.h])
 328 AC_CHECK_HEADERS([sys/syscall.h])
 329
 330 #### Typdefs, structures, etc. ####
 331
 332 AC_C_CONST
 333 AC_C_BIGENDIAN
 334 AC_TYPE_PID_T
 335 AC_TYPE_SIZE_T
 336 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 337     [Define ssize_t if it is not done by the standard libs.])])
 338 AC_TYPE_OFF_T
 339 AC_TYPE_SIGNAL
 340 AC_TYPE_UID_T
 341 AC_CHECK_DECLS(environ)
 342
 343 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [
 344 HAVE_SIGXCPU=1
 345 AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?])
 346 ], [HAVE_SIGXCPU=0])
 347 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 348
 349 # Solaris lacks this
 350 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 351     [AC_CHECK_DEFINE([INADDR_NONE], [winsock2.h], [],
 352         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 353
 354 #### POSIX threads ####
 355
 356 ACX_PTHREAD
 357
 358 #### Check for libs ####
 359
 360 # ISO
 361 AC_SEARCH_LIBS([pow], [m])
 362
 363 # POSIX
 364 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 365 AC_SEARCH_LIBS([dlopen], [dl])
 366 AC_SEARCH_LIBS([shm_open], [rt])
 367 AC_SEARCH_LIBS([inet_ntop], [nsl])
 368 AC_SEARCH_LIBS([timer_create], [rt])
 369
 370 # BSD
 371 AC_SEARCH_LIBS([connect], [socket])
 372
 373 # Non-standard
 374
 375 # This magic is needed so we do not needlessly add static libs to the win32
 376 # build, disabling its ability to make dlls.
 377 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 378
 379 AC_CHECK_LIB(gdbm, gdbm_open)
 380 AC_CHECK_HEADERS(gdbm.h, [], [AC_MSG_ERROR([gdbm.h not found])])
 381
 382 #### Check for functions ####
 383
 384 # ISO
 385 AC_CHECK_FUNCS([lrintf strtof])
 386
 387 # POSIX
 388 AC_FUNC_FORK
 389 AC_FUNC_GETGROUPS
 390 AC_FUNC_SELECT_ARGTYPES
 391 AC_CHECK_FUNCS([chmod chown clock_gettime getaddrinfo getgrgid_r \
 392     getpwuid_r gettimeofday getuid inet_ntop inet_pton mlock nanosleep \
 393     pipe posix_fadvise posix_madvise posix_memalign setpgid setsid shm_open \
 394     sigaction sleep sysconf])
 395 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 396
 397 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 398
 399 # X/OPEN
 400 AC_CHECK_FUNCS([readlink])
 401
 402 # SUSv2
 403 AC_CHECK_FUNCS([ctime_r usleep])
 404
 405 # SUSv3
 406 AC_CHECK_FUNCS([strerror_r])
 407
 408 # BSD
 409 AC_CHECK_FUNCS([lstat])
 410
 411 # Non-standard
 412
 413 AC_CHECK_FUNCS([setresuid setresgid setreuid setregid seteuid setegid ppoll strsignal sig2str strtof_l])
 414
 415 AC_FUNC_ALLOCA
 416
 417 AC_MSG_CHECKING([for PTHREAD_PRIO_INHERIT])
 418 AC_LANG_CONFTEST([AC_LANG_SOURCE([[
 419 #include <pthread.h>
 420 int main() { int i = PTHREAD_PRIO_INHERIT; }]])])
 421 $PTHREAD_CC conftest.c $PTHREAD_CFLAGS $CFLAGS $PTHREAD_LIBS -o conftest > /dev/null 2> /dev/null
 422 ret=$?
 423 rm -f conftest.o conftest
 424
 425 if test $ret -eq 0 ; then
 426     AC_DEFINE([HAVE_PTHREAD_PRIO_INHERIT], 1, [Have PTHREAD_PRIO_INHERIT.])
 427     AC_MSG_RESULT([yes])
 428 else
 429     AC_MSG_RESULT([no])
 430 fi
 431
 432 #### Large File-Support (LFS) ####
 433
 434 AC_SYS_LARGEFILE
 435
 436 # Check for open64 to know if the current system does have open64() and similar functions
 437 AC_CHECK_FUNCS([open64])
 438
 439 #### [lib]iconv ####
 440
 441 AM_ICONV
 442
 443 ###################################
 444 #      External libraries         #
 445 ###################################
 446
 447 #### X11 (optional) ####
 448
 449 HAVE_X11=0
 450
 451 # The macro tests the host, not the build target
 452 if test "x$os_is_win32" != "x1" ; then
 453     AC_PATH_XTRA
 454     test "x$no_x" != "xyes" && HAVE_X11=1
 455 fi
 456
 457 AC_SUBST(HAVE_X11)
 458 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 459 if test "x$HAVE_X11" = "x1" ; then
 460     AC_DEFINE([HAVE_X11], 1, [Have X11])
 461 fi
 462
 463 #### Capabilities (optional) ####
 464
 465 CAP_LIBS=''
 466
 467 AC_ARG_WITH(
 468         [caps],
 469         AC_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 470
 471 if test "x${with_caps}" != "xno"; then
 472     AC_SEARCH_LIBS([cap_init], [cap], [], [
 473                     if test "x${with_caps}" = "xyes" ; then
 474                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 475                     fi])
 476     AC_CHECK_HEADERS([sys/capability.h], [], [
 477                     if test "x${with_caps}" = "xyes" ; then
 478                         AC_MSG_ERROR([*** POSIX caps headers not found])
 479                     fi])
 480 fi
 481
 482 #### pkg-config ####
 483
 484 # Check for pkg-config manually first, as if its not installed the
 485 # PKG_PROG_PKG_CONFIG macro won't be defined.
 486 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 487
 488 if test x"$have_pkg_config" = "xno"; then
 489     AC_MSG_ERROR(pkg-config is required to install this program)
 490 fi
 491
 492 PKG_PROG_PKG_CONFIG
 493
 494 #### Sound file ####
 495
 496 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 497 AC_SUBST(LIBSNDFILE_CFLAGS)
 498 AC_SUBST(LIBSNDFILE_LIBS)
 499
 500 PKG_CHECK_MODULES(LIBSPEEX, [ speexdsp >= 1.2 ])
 501 AC_SUBST(LIBSPEEX_CFLAGS)
 502 AC_SUBST(LIBSPEEX_LIBS)
 503
 504 #### atomic-ops ###
 505
 506 AC_MSG_CHECKING([whether we need libatomic_ops])
 507 if test "x$need_libatomic_ops" = "xyes"; then
 508    AC_MSG_RESULT([yes])
 509    AC_CHECK_HEADERS([atomic_ops.h], [], [
 510    AC_MSG_ERROR([*** libatomic-ops headers not found])
 511    ])
 512
 513    # Win32 does not need the lib and breaks horribly if we try to include it
 514    if test "x$os_is_win32" != "x1" ; then
 515        LIBS="$LIBS -latomic_ops"
 516    fi
 517 else
 518    AC_MSG_RESULT([no])
 519 fi
 520
 521 #### Libsamplerate support (optional) ####
 522
 523 AC_ARG_ENABLE([samplerate],
 524     AC_HELP_STRING([--disable-samplerate], [Disable optional libsamplerate support]),
 525         [
 526             case "${enableval}" in
 527                 yes) samplerate=yes ;;
 528                 no) samplerate=no ;;
 529                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-samplerate) ;;
 530             esac
 531         ],
 532         [samplerate=auto])
 533
 534 if test "x${samplerate}" != xno ; then
 535     PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ],
 536         HAVE_LIBSAMPLERATE=1,
 537         [
 538             HAVE_LIBSAMPLERATE=0
 539             if test "x$samplerate" = xyes ; then
 540                 AC_MSG_ERROR([*** Libsamplerate not found])
 541             fi
 542         ])
 543 else
 544     HAVE_LIBSAMPLERATE=0
 545 fi
 546
 547 if test "x${HAVE_LIBSAMPLERATE}" = x1 ; then
 548    AC_DEFINE([HAVE_LIBSAMPLERATE], 1, [Have libsamplerate?])
 549 fi
 550
 551 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 552 AC_SUBST(LIBSAMPLERATE_LIBS)
 553 AC_SUBST(HAVE_LIBSAMPLERATE)
 554 AM_CONDITIONAL([HAVE_LIBSAMPLERATE], [test "x$HAVE_LIBSAMPLERATE" = x1])
 555
 556 #### OSS support (optional) ####
 557
 558 AC_ARG_ENABLE([oss],
 559     AC_HELP_STRING([--disable-oss], [Disable optional OSS support]),
 560         [
 561             case "${enableval}" in
 562                 yes) oss=yes ;;
 563                 no) oss=no ;;
 564                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-oss) ;;
 565             esac
 566         ],
 567         [oss=auto])
 568
 569 if test "x${oss}" != xno ; then
 570     AC_CHECK_HEADERS([sys/soundcard.h],
 571         [
 572             HAVE_OSS=1
 573             AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 574         ],
 575         [
 576             HAVE_OSS=0
 577             if test "x$oss" = xyes ; then
 578                 AC_MSG_ERROR([*** OSS support not found])
 579             fi
 580         ])
 581 else
 582     HAVE_OSS=0
 583 fi
 584
 585 AC_SUBST(HAVE_OSS)
 586 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 587
 588
 589 #### ALSA support (optional) ####
 590
 591 AC_ARG_ENABLE([alsa],
 592     AC_HELP_STRING([--disable-alsa], [Disable optional ALSA support]),
 593         [
 594             case "${enableval}" in
 595                 yes) alsa=yes ;;
 596                 no) alsa=no ;;
 597                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-alsa) ;;
 598             esac
 599         ],
 600         [alsa=auto])
 601
 602 if test "x${alsa}" != xno ; then
 603     PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.17 ],
 604         [
 605             HAVE_ALSA=1
 606             AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 607         ],
 608         [
 609             HAVE_ALSA=0
 610             if test "x$alsa" = xyes ; then
 611                 AC_MSG_ERROR([*** Needed alsa >= 1.0.17 support not found])
 612             fi
 613         ])
 614 else
 615     HAVE_ALSA=0
 616 fi
 617
 618 AC_SUBST(ASOUNDLIB_CFLAGS)
 619 AC_SUBST(ASOUNDLIB_LIBS)
 620 AC_SUBST(HAVE_ALSA)
 621 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 622
 623 #### Solaris audio support (optional) ####
 624
 625 AC_ARG_ENABLE([solaris],
 626     AC_HELP_STRING([--disable-solaris], [Disable optional Solaris audio support]),
 627         [
 628             case "${enableval}" in
 629                 yes) solaris=yes ;;
 630                 no) solaris=no ;;
 631                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-solaris) ;;
 632             esac
 633         ],
 634         [solaris=auto])
 635
 636 if test "x${solaris}" != xno ; then
 637     AC_CHECK_HEADERS([sys/audio.h],
 638         [
 639             HAVE_SOLARIS=1
 640             AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 641         ],
 642         [
 643             HAVE_SOLARIS=0
 644             if test "x$solaris" = xyes ; then
 645                 AC_MSG_ERROR([*** Solaris audio support not found])
 646             fi
 647         ])
 648 else
 649     HAVE_SOLARIS=0
 650 fi
 651
 652 AC_SUBST(HAVE_SOLARIS)
 653 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 654
 655 #### GLib 2 support (optional) ####
 656
 657 AC_ARG_ENABLE([glib2],
 658     AC_HELP_STRING([--disable-glib2], [Disable optional GLib 2 support]),
 659         [
 660             case "${enableval}" in
 661                 yes) glib2=yes ;;
 662                 no) glib2=no ;;
 663                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib2) ;;
 664             esac
 665         ],
 666         [glib2=auto])
 667
 668 if test "x${glib2}" != xno ; then
 669     PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ],
 670         HAVE_GLIB20=1,
 671         [
 672             HAVE_GLIB20=0
 673             if test "x$glib2" = xyes ; then
 674                 AC_MSG_ERROR([*** GLib 2 support not found])
 675             fi
 676         ])
 677 else
 678     HAVE_GLIB20=0
 679 fi
 680
 681 AC_SUBST(GLIB20_CFLAGS)
 682 AC_SUBST(GLIB20_LIBS)
 683 AC_SUBST(HAVE_GLIB20)
 684 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 685
 686 #### GConf support (optional) ####
 687
 688 AC_ARG_ENABLE([gconf],
 689     AC_HELP_STRING([--disable-gconf], [Disable optional GConf support]),
 690         [
 691             case "${enableval}" in
 692                 yes) gconf=yes ;;
 693                 no) gconf=no ;;
 694                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-gconf) ;;
 695             esac
 696         ],
 697         [gconf=auto])
 698
 699 if test "x${gconf}" != xno ; then
 700     PKG_CHECK_MODULES(GCONF, [ gconf-2.0 >= 2.4.0 ],
 701         HAVE_GCONF=1,
 702         [
 703             HAVE_GCONF=0
 704             if test "x$gconf" = xyes ; then
 705                 AC_MSG_ERROR([*** GConf support not found])
 706             fi
 707         ])
 708 else
 709     HAVE_GCONF=0
 710 fi
 711
 712 AC_SUBST(GCONF_CFLAGS)
 713 AC_SUBST(GCONF_LIBS)
 714 AC_SUBST(HAVE_GCONF)
 715 AM_CONDITIONAL([HAVE_GCONF], [test "x$HAVE_GCONF" = x1])
 716
 717 #### Avahi support (optional) ####
 718
 719 AC_ARG_ENABLE([avahi],
 720     AC_HELP_STRING([--disable-avahi], [Disable optional Avahi support]),
 721         [
 722             case "${enableval}" in
 723                 yes) avahi=yes ;;
 724                 no) avahi=no ;;
 725                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-avahi) ;;
 726             esac
 727         ],
 728         [avahi=auto])
 729
 730 if test "x${avahi}" != xno ; then
 731     PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ],
 732         HAVE_AVAHI=1,
 733         [
 734                 HAVE_AVAHI=0
 735                 if test "x$avahi" = xyes ; then
 736                         AC_MSG_ERROR([*** Avahi support not found])
 737                 fi
 738         ])
 739 else
 740     HAVE_AVAHI=0
 741 fi
 742
 743 AC_SUBST(AVAHI_CFLAGS)
 744 AC_SUBST(AVAHI_LIBS)
 745 AC_SUBST(HAVE_AVAHI)
 746 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
 747
 748 ### LIBOIL ####
 749
 750 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 751 AC_SUBST(LIBOIL_CFLAGS)
 752 AC_SUBST(LIBOIL_LIBS)
 753
 754 ### JACK (optional) ####
 755
 756 AC_ARG_ENABLE([jack],
 757     AC_HELP_STRING([--disable-jack], [Disable optional JACK support]),
 758         [
 759             case "${enableval}" in
 760                 yes) jack=yes ;;
 761                 no) jack=no ;;
 762                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-jack) ;;
 763             esac
 764         ],
 765         [jack=auto])
 766
 767 if test "x${jack}" != xno ; then
 768     PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ],
 769         HAVE_JACK=1,
 770         [
 771             HAVE_JACK=0
 772             if test "x$jack" = xyes ; then
 773                 AC_MSG_ERROR([*** JACK support not found])
 774             fi
 775         ])
 776 else
 777     HAVE_JACK=0
 778 fi
 779
 780 AC_SUBST(JACK_CFLAGS)
 781 AC_SUBST(JACK_LIBS)
 782 AC_SUBST(HAVE_JACK)
 783 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 784
 785 #### Async DNS support (optional) ####
 786
 787 AC_ARG_ENABLE([asyncns],
 788     AC_HELP_STRING([--disable-asyncns], [Disable optional Async DNS support]),
 789         [
 790             case "${enableval}" in
 791                 yes) asyncns=yes ;;
 792                 no) asyncns=no ;;
 793                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-asyncns) ;;
 794             esac
 795         ],
 796         [asyncns=auto])
 797
 798 if test "x${asyncns}" != xno ; then
 799     PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ],
 800         HAVE_LIBASYNCNS=1,
 801         [
 802             HAVE_LIBASYNCNS=0
 803             if test "x$asyncns" = xyes ; then
 804                 AC_MSG_ERROR([*** Async DNS support not found])
 805             fi
 806         ])
 807 else
 808     HAVE_LIBASYNCNS=0
 809 fi
 810
 811 AC_SUBST(LIBASYNCNS_CFLAGS)
 812 AC_SUBST(LIBASYNCNS_LIBS)
 813 AC_SUBST(HAVE_LIBASYNCNS)
 814 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 815
 816 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 817    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 818 fi
 819
 820 #### TCP wrappers (optional) ####
 821
 822 AC_ARG_ENABLE([tcpwrap],
 823     AC_HELP_STRING([--disable-tcpwrap], [Disable optional TCP wrappers support]),
 824         [
 825             case "${enableval}" in
 826                 yes) tcpwrap=yes ;;
 827                 no) tcpwrap=no ;;
 828                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 829             esac
 830         ],
 831         [tcpwrap=auto])
 832
 833 if test "x${tcpwrap}" != xno ; then
 834     ACX_LIBWRAP
 835     if test "x${LIBWRAP_LIBS}" = x && test "x$tcpwrap" = xyes ; then
 836         AC_MSG_ERROR([*** TCP wrappers support not found])
 837     fi
 838 else
 839     LIBWRAP_LIBS=
 840 fi
 841
 842 AC_SUBST(LIBWRAP_LIBS)
 843
 844 #### LIRC support (optional) ####
 845
 846 AC_ARG_ENABLE([lirc],
 847     AC_HELP_STRING([--disable-lirc], [Disable optional LIRC support]),
 848         [
 849             case "${enableval}" in
 850                 yes) lirc=yes ;;
 851                 no) lirc=no ;;
 852                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-lirc) ;;
 853             esac
 854         ],
 855         [lirc=auto])
 856
 857 if test "x${lirc}" != xno ; then
 858     ACX_LIRC
 859     if test "x${HAVE_LIRC}" = x0 && test "x$lirc" = xyes ; then
 860         AC_MSG_ERROR([*** LIRC support not found])
 861     fi
 862 else
 863     HAVE_LIRC=0
 864 fi
 865
 866 AC_SUBST(LIRC_CFLAGS)
 867 AC_SUBST(LIRC_LIBS)
 868 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 869
 870 #### HAL support (optional) ####
 871
 872 AC_ARG_ENABLE([hal],
 873     AC_HELP_STRING([--disable-hal], [Disable optional HAL support]),
 874         [
 875             case "${enableval}" in
 876                 yes) hal=yes ;;
 877                 no) hal=no ;;
 878                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-hal) ;;
 879             esac
 880         ],
 881         [hal=auto])
 882 if test "x${hal}" != xno -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \) ; then
 883     PKG_CHECK_MODULES(HAL, [ hal >= 0.5.7 ],
 884         HAVE_HAL=1,
 885         [
 886             HAVE_HAL=0
 887             if test "x$hal" = xyes ; then
 888                 AC_MSG_ERROR([*** HAL support not found])
 889             fi
 890         ])
 891 else
 892     HAVE_HAL=0
 893 fi
 894
 895 AC_SUBST(HAL_CFLAGS)
 896 AC_SUBST(HAL_LIBS)
 897 AC_SUBST(HAVE_HAL)
 898 AM_CONDITIONAL([HAVE_HAL], [test "x$HAVE_HAL" = x1])
 899
 900 #### BlueZ support (optional) ####
 901
 902 AC_ARG_ENABLE([bluez],
 903     AC_HELP_STRING([--disable-bluez], [Disable optional BlueZ support]),
 904         [
 905             case "${enableval}" in
 906                 yes) bluez=yes ;;
 907                 no) bluez=no ;;
 908                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-bluez) ;;
 909             esac
 910         ],
 911         [bluez=auto])
 912 if test "x${bluez}" != xno ; then
 913     PKG_CHECK_MODULES(BLUEZ, [ bluez >= 3.0 ],
 914         HAVE_BLUEZ=1,
 915         [
 916             HAVE_BLUEZ=0
 917             if test "x$bluez" = xyes ; then
 918                 AC_MSG_ERROR([*** BLUEZ support not found])
 919             fi
 920         ])
 921 else
 922     HAVE_BLUEZ=0
 923 fi
 924
 925 AC_SUBST(BLUEZ_CFLAGS)
 926 AC_SUBST(BLUEZ_LIBS)
 927 AC_SUBST(HAVE_BLUEZ)
 928 AM_CONDITIONAL([HAVE_BLUEZ], [test "x$HAVE_BLUEZ" = x1])
 929
 930 #### D-Bus support (optional) ####
 931
 932 AC_ARG_ENABLE([dbus],
 933     AC_HELP_STRING([--disable-dbus], [Disable optional D-Bus support]),
 934         [
 935             case "${enableval}" in
 936                 yes) dbus=yes ;;
 937                 no) dbus=no ;;
 938                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-dbus) ;;
 939             esac
 940         ],
 941         [dbus=auto])
 942
 943 if test "x$HAVE_HAL" = x1 ; then
 944    dbus=yes
 945 fi
 946
 947 if test "x${dbus}" != xno || test "x${bluez}" != xno || "x${hal}" != xno ; then
 948
 949     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.0.0 ],
 950         [
 951             HAVE_DBUS=1
 952             saved_LIBS="$LIBS"
 953             LIBS="$LIBS $DBUS_LIBS"
 954             AC_CHECK_FUNCS(dbus_watch_get_unix_fd)
 955             LIBS="$saved_LIBS"
 956             AC_DEFINE([HAVE_DBUS], 1, [Have D-Bus.])
 957         ],
 958         [
 959             HAVE_DBUS=0
 960             if test "x$dbus" = xyes ; then
 961                 AC_MSG_ERROR([*** D-Bus support not found])
 962             fi
 963         ])
 964 else
 965     HAVE_DBUS=0
 966 fi
 967
 968 AC_SUBST(DBUS_CFLAGS)
 969 AC_SUBST(DBUS_LIBS)
 970 AC_SUBST(HAVE_DBUS)
 971 AM_CONDITIONAL([HAVE_DBUS], [test "x$HAVE_DBUS" = x1])
 972
 973 #### PolicyKit support (optional) ####
 974
 975 AC_ARG_ENABLE([polkit],
 976     AC_HELP_STRING([--disable-polkit], [Disable optional PolicyKit support]),
 977         [
 978             case "${enableval}" in
 979                 yes) polkit=yes ;;
 980                 no) polkit=no ;;
 981                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-polkit) ;;
 982             esac
 983         ],
 984         [polkit=auto])
 985
 986 if test "x${polkit}" != xno ; then
 987
 988     PKG_CHECK_MODULES(POLKIT, [ polkit-dbus >= 0.7 ],
 989         [
 990             HAVE_POLKIT=1
 991             AC_DEFINE([HAVE_POLKIT], 1, [Have PolicyKit])
 992             policydir=`pkg-config polkit-dbus --variable prefix`/share/PolicyKit/policy/
 993             AC_SUBST(policydir)
 994         ],
 995         [
 996             HAVE_POLKIT=0
 997             if test "x$polkit" = xyes ; then
 998                 AC_MSG_ERROR([*** PolicyKit support not found])
 999             fi
1000         ])
1001 else
1002     HAVE_POLKIT=0
1003 fi
1004
1005 AC_SUBST(POLKIT_CFLAGS)
1006 AC_SUBST(POLKIT_LIBS)
1007 AC_SUBST(HAVE_POLKIT)
1008 AM_CONDITIONAL([HAVE_POLKIT], [test "x$HAVE_POLKIT" = x1])
1009
1010 ### Build and Install man pages ###
1011 AC_ARG_ENABLE(manpages,
1012         AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]),
1013 [case "${enableval}" in
1014   yes) manpages=yes ;;
1015   no)  manpages=no ;;
1016   *) AC_MSG_ERROR([bad value ${enableval} for --disable-manpages]) ;;
1017 esac],[manpages=yes])
1018
1019 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$manpages" = xyes])
1020
1021 #### PulseAudio system group & user  #####
1022
1023 AC_ARG_WITH(system_user, AS_HELP_STRING([--with-system-user=<user>],[User for running the PulseAudio daemon as a system-wide instance (pulse)]))
1024 if test -z "$with_system_user" ; then
1025     PA_SYSTEM_USER=pulse
1026 else
1027     PA_SYSTEM_USER=$with_system_user
1028 fi
1029 AC_SUBST(PA_SYSTEM_USER)
1030 AC_DEFINE_UNQUOTED(PA_SYSTEM_USER,"$PA_SYSTEM_USER", [User for running the PulseAudio system daemon])
1031
1032 AC_ARG_WITH(system_group,AS_HELP_STRING([--with-system-group=<group>],[Group for running the PulseAudio daemon as a system-wide instance (pulse)]))
1033 if test -z "$with_system_group" ; then
1034     PA_SYSTEM_GROUP=pulse
1035 else
1036     PA_SYSTEM_GROUP=$with_system_group
1037 fi
1038 AC_SUBST(PA_SYSTEM_GROUP)
1039 AC_DEFINE_UNQUOTED(PA_SYSTEM_GROUP,"$PA_SYSTEM_GROUP", [Group for the PulseAudio system daemon])
1040
1041 AC_ARG_WITH(realtime_group,AS_HELP_STRING([--with-realtime-group=<group>],[Group for users that are allowed to start the PulseAudio daemon with realtime scheduling (realtime)]))
1042 if test -z "$with_realtime_group" ; then
1043     PA_REALTIME_GROUP=pulse-rt
1044 else
1045     PA_REALTIME_GROUP=$with_realtime_group
1046 fi
1047 AC_SUBST(PA_REALTIME_GROUP)
1048 AC_DEFINE_UNQUOTED(PA_REALTIME_GROUP,"$PA_REALTIME_GROUP", [Realtime group])
1049
1050 AC_ARG_WITH(access_group,AS_HELP_STRING([--with-access-group=<group>],[Group which is allowed access to a system-wide PulseAudio daemon (pulse-access)]))
1051 if test -z "$with_access_group" ; then
1052     PA_ACCESS_GROUP=pulse-access
1053 else
1054     PA_ACCESS_GROUP=$with_access_group
1055 fi
1056 AC_SUBST(PA_ACCESS_GROUP)
1057 AC_DEFINE_UNQUOTED(PA_ACCESS_GROUP,"$PA_ACCESS_GROUP", [Access group])
1058
1059 AC_ARG_ENABLE(
1060         per_user_esound_socket,
1061         AS_HELP_STRING([--disable-per-user-esound-socket], [Use global esound socket directory /tmp/.esd/socket.]),
1062         [
1063             case "${enableval}" in
1064                 yes) per_user_esound_socket=1 ;;
1065                 no) per_user_esound_socket=0 ;;
1066                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-per-user-esound-socket) ;;
1067             esac
1068         ],
1069         [per_user_esound_socket=1])
1070
1071 if test "x$per_user_esound_socket" = "x1"; then
1072    AC_DEFINE([USE_PER_USER_ESOUND_SOCKET], [1], [Define this if you want per-user esound socket directories])
1073 fi
1074
1075 #### PulseAudio system runtime dir ####
1076 PA_SYSTEM_RUNTIME_PATH="${localstatedir}/run/pulse"
1077 AC_SUBST(PA_SYSTEM_RUNTIME_PATH)
1078 PA_SYSTEM_CONFIG_PATH="${localstatedir}/lib/pulse"
1079 AC_SUBST(PA_SYSTEM_CONFIG_PATH)
1080 PA_SYSTEM_STATE_PATH="${localstatedir}/lib/pulse"
1081 AC_SUBST(PA_SYSTEM_STATE_PATH)
1082
1083 ###################################
1084 #            Output               #
1085 ###################################
1086
1087 AC_ARG_ENABLE(
1088         [static-bins],
1089         AC_HELP_STRING([--enable-static-bins],[Statically link executables.]),
1090         [STATIC_BINS=1], [STATIC_BINS=0])
1091 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
1092
1093 AC_ARG_WITH(
1094         [preopen-mods],
1095         AC_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
1096         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
1097 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
1098 if test "x$PREOPEN_MODS" != "xall" ; then
1099     tmpLIBS=""
1100     for mod in $PREOPEN_MODS; do
1101         tmpLIBS="$tmpLIBS module-$mod.la"
1102     done
1103     PREOPEN_MODS="$tmpLIBS"
1104     AC_SUBST(PREOPEN_MODS)
1105 fi
1106
1107 AC_ARG_WITH(
1108         [module-dir],
1109         AC_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINOR}/modules/]),
1110         [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINOR}/modules/"])
1111
1112 AC_SUBST(modlibexecdir)
1113
1114 AC_ARG_ENABLE(
1115         [force-preopen],
1116         AC_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]),
1117         [FORCE_PREOPEN=1], [FORCE_PREOPEN=0])
1118 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "x1"])
1119
1120 AC_CONFIG_FILES([
1121 Makefile
1122 src/Makefile
1123 man/Makefile
1124 libpulse.pc
1125 libpulse-simple.pc
1126 libpulse-browse.pc
1127 libpulse-mainloop-glib.pc
1128 doxygen/Makefile
1129 doxygen/doxygen.conf
1130 src/pulse/version.h
1131 ])
1132 AC_OUTPUT
1133
1134 # ==========================================================================
1135 ENABLE_X11=no
1136 if test "x$HAVE_X11" = "x1" ; then
1137    ENABLE_X11=yes
1138 fi
1139
1140 ENABLE_OSS=no
1141 if test "x$HAVE_OSS" = "x1" ; then
1142    ENABLE_OSS=yes
1143 fi
1144
1145 ENABLE_ALSA=no
1146 if test "x$HAVE_ALSA" = "x1" ; then
1147    ENABLE_ALSA=yes
1148 fi
1149
1150 ENABLE_SOLARIS=no
1151 if test "x$HAVE_SOLARIS" = "x1" ; then
1152    ENABLE_SOLARIS=yes
1153 fi
1154
1155 ENABLE_GLIB20=no
1156 if test "x$HAVE_GLIB20" = "x1" ; then
1157    ENABLE_GLIB20=yes
1158 fi
1159
1160 ENABLE_GCONF=no
1161 if test "x$HAVE_GCONF" = "x1" ; then
1162    ENABLE_GCONF=yes
1163 fi
1164
1165 ENABLE_AVAHI=no
1166 if test "x$HAVE_AVAHI" = "x1" ; then
1167    ENABLE_AVAHI=yes
1168 fi
1169
1170 ENABLE_JACK=no
1171 if test "x$HAVE_JACK" = "x1" ; then
1172    ENABLE_JACK=yes
1173 fi
1174
1175 ENABLE_LIBASYNCNS=no
1176 if test "x$HAVE_LIBASYNCNS" = "x1" ; then
1177    ENABLE_LIBASYNCNS=yes
1178 fi
1179
1180 ENABLE_LIRC=no
1181 if test "x$HAVE_LIRC" = "x1" ; then
1182    ENABLE_LIRC=yes
1183 fi
1184
1185 ENABLE_HAL=no
1186 if test "x$HAVE_HAL" = "x1" ; then
1187    ENABLE_HAL=yes
1188 fi
1189
1190 ENABLE_TCPWRAP=no
1191 if test "x${LIBWRAP_LIBS}" != x ; then
1192    ENABLE_TCPWRAP=yes
1193 fi
1194
1195 ENABLE_LIBSAMPLERATE=no
1196 if test "x${HAVE_LIBSAMPLERATE}" = "x1" ; then
1197    ENABLE_LIBSAMPLERATE=yes
1198 fi
1199
1200 ENABLE_BLUEZ=no
1201 if test "x${HAVE_BLUEZ}" = "x1" ; then
1202    ENABLE_BLUEZ=yes
1203 fi
1204
1205 ENABLE_POLKIT=no
1206 if test "x${HAVE_POLKIT}" = "x1" ; then
1207    ENABLE_POLKIT=yes
1208 fi
1209
1210 ENABLE_PER_USER_ESOUND_SOCKET=no
1211 if test "x$per_user_esound_socket" = "x1" ; then
1212    ENABLE_PER_USER_ESOUND_SOCKET=yes
1213 fi
1214
1215 echo "
1216  ---{ $PACKAGE_NAME $VERSION }---
1217
1218     prefix:                        ${prefix}
1219     sysconfdir:                    ${sysconfdir}
1220     localstatedir:                 ${localstatedir}
1221     System Runtime Path:           ${PA_SYSTEM_RUNTIME_PATH}
1222     System State Path:             ${PA_SYSTEM_STATE_PATH}
1223     System Config Path:            ${PA_SYSTEM_CONFIG_PATH}
1224     Compiler:                      ${CC}
1225     CFLAGS:                        ${CFLAGS}
1226     Have X11:                      ${ENABLE_X11}
1227     Enable OSS:                    ${ENABLE_OSS}
1228     Enable Alsa:                   ${ENABLE_ALSA}
1229     Enable Solaris:                ${ENABLE_SOLARIS}
1230     Enable GLib 2.0:               ${ENABLE_GLIB20}
1231     Enable GConf:                  ${ENABLE_GCONF}
1232     Enable Avahi:                  ${ENABLE_AVAHI}
1233     Enable Jack:                   ${ENABLE_JACK}
1234     Enable Async DNS:              ${ENABLE_LIBASYNCNS}
1235     Enable LIRC:                   ${ENABLE_LIRC}
1236     Enable HAL:                    ${ENABLE_HAL}
1237     Enable BlueZ:                  ${ENABLE_BLUEZ}
1238     Enable TCP Wrappers:           ${ENABLE_TCPWRAP}
1239     Enable libsamplerate:          ${ENABLE_LIBSAMPLERATE}
1240     Enable PolicyKit:              ${ENABLE_POLKIT}
1241     System User:                   ${PA_SYSTEM_USER}
1242     System Group:                  ${PA_SYSTEM_GROUP}
1243     Realtime Group:                ${PA_REALTIME_GROUP}
1244     Access Group:                  ${PA_ACCESS_GROUP}
1245     Enable per-user EsounD socket: ${ENABLE_PER_USER_ESOUND_SOCKET}
1246 "