configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([Rygel],
   3         [m4_esyscmd(GNOME_TAG_PATTERN=RYGEL build-aux/git-version-gen .tarball-version)],
   4         [http://bugzilla.gnome.org/enter_bug.cgi?product=Rygel],
   5         [rygel],
   6         [http://live.gnome.org/Rygel])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8
   9 AC_CONFIG_SRCDIR([src/librygel-core/rygel-root-device.vala])
  10 AC_CONFIG_HEADERS([config.h])
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_SEARCH_LIBS([strerror],[cposix])
  14 AC_PROG_CC
  15 AC_HEADER_STDC
  16 AC_FUNC_MMAP
  17
  18 AC_SUBST(abs_top_builddir)
  19 AC_SUBST(VERSION)
  20
  21 dnl Initialize automake
  22 AM_INIT_AUTOMAKE([1.11.1 tar-ustar no-dist-gzip dist-xz -Wno-portability])
  23 AM_MAINTAINER_MODE([enable])
  24
  25 dnl Initialize libtool
  26 dnl Disable generation of static libraries
  27 LT_PREREQ([2.2.6])
  28 LT_INIT([dlopen disable-static])
  29
  30 dnl Required versions of library packages
  31 dnl Not all of these are actually used, depending on the configure options.
  32 GLIB_REQUIRED=2.31.13
  33 LIBXML_REQUIRED=2.7
  34 VALA_REQUIRED=0.18.0
  35 VALADOC_REQUIRED=0.2
  36 GSSDP_REQUIRED=0.13.0
  37 GUPNP_REQUIRED=0.19.0
  38 GUPNP_AV_REQUIRED=0.11.4
  39 GUPNP_DLNA_REQUIRED=0.9.4
  40 GSTREAMER_REQUIRED=1.0
  41 GSTPBU_REQUIRED=1.0
  42 GIO_REQUIRED=2.26
  43 GEE_REQUIRED=0.8.0
  44 UUID_REQUIRED=1.41.3
  45 LIBSOUP_REQUIRED=2.34.0
  46 GTK_REQUIRED=3.0
  47
  48 dnl Additional requirements for media-export plugin
  49 GSTREAMER_TAG_REQUIRED=1.0
  50 GSTREAMER_APP_REQUIRED=1.0
  51 LIBSQLITE3_REQUIRED=3.5
  52
  53 dnl Additional requirements for tracker plugin
  54 TRACKER_SPARQL_REQUIRED_MIN=0.14.0
  55
  56 VALAFLAGS="--target-glib=2.32 $VALAFLAGS"
  57
  58 RYGEL_BASE_MODULES="gupnp-1.0 >= $GUPNP_REQUIRED gee-0.8 >= $GEE_REQUIRED"
  59 PKG_CHECK_MODULES([LIBRYGEL_CORE_DEPS], [$RYGEL_BASE_MODULES uuid >= $UUID_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED gio-2.0 >= $GIO_REQUIRED gmodule-2.0 libxml-2.0 >= $LIBXML_REQUIRED])
  60 RYGEL_BASE_MODULES_VALAFLAGS='--pkg gupnp-1.0 --pkg gee-0.8'
  61 LIBRYGEL_CORE_DEPS_VALAFLAGS="$RYGEL_BASE_MODULES_VALAFLAGS --pkg gssdp-1.0 --pkg gio-2.0 --pkg gmodule-2.0"
  62 AC_SUBST([LIBRYGEL_CORE_DEPS_VALAFLAGS])
  63
  64 RYGEL_COMMON_MODULES="$RYGEL_BASE_MODULES gupnp-av-1.0 >= $GUPNP_AV_REQUIRED"
  65 PKG_CHECK_MODULES([LIBRYGEL_SERVER_DEPS], [$RYGEL_COMMON_MODULES uuid >= $UUID_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED gio-2.0 >= $GIO_REQUIRED gmodule-2.0 libxml-2.0 >= $LIBXML_REQUIRED libsoup-2.4 >= $LIBSOUP_REQUIRED])
  66 RYGEL_COMMON_MODULES_VALAFLAGS="$RYGEL_BASE_MODULES_VALAFLAGS --pkg gupnp-av-1.0"
  67 LIBRYGEL_SERVER_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gssdp-1.0 --pkg gio-2.0 --pkg libsoup-2.4 --pkg gmodule-2.0"
  68 AC_SUBST([LIBRYGEL_SERVER_DEPS_VALAFLAGS])
  69
  70 PKG_CHECK_MODULES([LIBRYGEL_RENDERER_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED libsoup-2.4 >= $LIBSOUP_REQUIRED])
  71 LIBRYGEL_RENDERER_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gio-2.0 --pkg libsoup-2.4"
  72 AC_SUBST([LIBRYGEL_RENDERER_DEPS_VALAFLAGS])
  73
  74 PKG_CHECK_MODULES([RYGEL_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED])
  75
  76 # Not all tests use all of these dependencies,
  77 # but having one set of dependencies keeps things simple.
  78 PKG_CHECK_MODULES([TEST_DEPS], [$RYGEL_COMMON_MODULES uuid >= $UUID_REQUIRED gio-2.0 >= $GIO_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED libsoup-2.4 >= $LIBSOUP_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED])
  79 TEST_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gio-2.0 --pkg gssdp-1.0 --pkg libsoup-2.4 --pkg libxml-2.0 --pkg gmodule-2.0"
  80 AC_SUBST([TEST_DEPS_VALAFLAGS])
  81
  82 PKG_CHECK_MODULES([EXAMPLE_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED])
  83
  84
  85
  86 dnl Media engine to use
  87 BUILT_ENGINES="librygel-media-engine-simple"
  88
  89 dnl Disabling the gstreamer media_engine also disables
  90 dnl anything else that uses gstreamer.
  91 AC_ARG_WITH([media_engine],
  92             AS_HELP_STRING(
  93                 [--with-media-engine=@<:@gstreamer|simple@:>@],
  94                 [Media Engine to use]),
  95             [with_media_engine="$withval"],
  96             [with_media_engine="gstreamer"])
  97
  98 AS_IF([test "x$with_media_engine" = "xgstreamer"],
  99       [
 100         enable_gstreamer="yes"
 101         BUILT_ENGINES="$BUILT_ENGINES;librygel-media-engine-gst"
 102
 103         PKG_CHECK_MODULES([RYGEL_MEDIA_ENGINE_GSTREAMER_DEPS],
 104                           [$RYGEL_COMMON_MODULES
 105                            gstreamer-pbutils-1.0 >= $GSTPBU_REQUIRED
 106                            gstreamer-app-1.0 >= $GSTREAMER_APP_REQUIRED
 107                            gupnp-dlna-2.0 >= $GUPNP_DLNA_REQUIRED
 108                            gio-2.0 >= $GIO_REQUIRED])
 109         RYGEL_MEDIA_ENGINE_GSTREAMER_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gstreamer-base-1.0 --pkg gstreamer-pbutils-1.0 --pkg gupnp-dlna-2.0"
 110         AC_SUBST([RYGEL_MEDIA_ENGINE_GSTREAMER_DEPS_VALAFLAGS])
 111
 112         PKG_CHECK_MODULES([LIBRYGEL_RENDERER_GST_DEPS], [$RYGEL_COMMON_MODULES gstreamer-1.0 >= $GSTREAMER_REQUIRED gio-2.0 >= $GIO_REQUIRED])
 113         LIBRYGEL_RENDERER_GST_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gstreamer-1.0"
 114         AC_SUBST([LIBRYGEL_RENDERER_GST_DEPS_VALAFLAGS])
 115       ],
 116       [enable_gstreamer="no"])
 117 AM_CONDITIONAL([HAVE_GSTREAMER],[test "x$enable_gstreamer" = "xyes"])
 118 AC_SUBST([BUILT_ENGINES])
 119
 120 dnl Add plugins
 121 RYGEL_ADD_PLUGIN([external],[MediaServer2 DBus consumer],[yes])
 122 AS_IF([test "x$enable_external_plugin" = "xyes"],
 123   [
 124     PKG_CHECK_MODULES([RYGEL_PLUGIN_EXTERNAL_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED])
 125   ])
 126
 127 RYGEL_ADD_PLUGIN([mpris],[MPRIS2 DBus consumer],[yes])
 128 AS_IF([test "x$enable_mpris_plugin" = "xyes"],
 129   [
 130     PKG_CHECK_MODULES([RYGEL_PLUGIN_MPRIS_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED])
 131   ])
 132
 133 RYGEL_ADD_PLUGIN([mediathek],[ZDF Mediathek],[no])
 134 AS_IF([test "x$enable_mediathek_plugin" = "xyes"],
 135   [
 136     PKG_CHECK_MODULES([RYGEL_PLUGIN_MEDIATHEK_DEPS],
 137                       [$RYGEL_COMMON_MODULES
 138                        gio-2.0 >= $GIO_REQUIRED
 139                        libsoup-2.4 >= $LIBSOUP_REQUIRED
 140                        libxml-2.0 >= $LIBXML_REQUIRED])
 141   ])
 142
 143 AS_IF([test "x$with_media_engine" = "xgstreamer"],
 144       [
 145         RYGEL_ADD_PLUGIN([playbin],[GStreamer playbin],[yes])
 146         AS_IF([test "x$enable_playbin_plugin" = "xyes"],
 147           [
 148             PKG_CHECK_MODULES([RYGEL_PLUGIN_PLAYBIN_DEPS], [$RYGEL_COMMON_MODULES gstreamer-1.0 >= $GSTREAMER_TAG_REQUIRED])
 149           ])
 150
 151         RYGEL_ADD_PLUGIN([media-export],[MediaExport],[yes])
 152         AS_IF([test "x$enable_media_export_plugin" = "xyes"],
 153           [
 154             PKG_CHECK_MODULES([RYGEL_PLUGIN_MEDIA_EXPORT_DEPS],
 155                               [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED
 156                                gupnp-dlna-2.0 >= $GUPNP_DLNA_REQUIRED
 157                                gupnp-dlna-gst-2.0 >= $GUPNP_DLNA_REQUIRED
 158                                gstreamer-app-1.0 >= $GSTREAMER_APP_REQUIRED
 159                                gstreamer-tag-1.0 >= $GSTREAMER_TAG_REQUIRED
 160                                gstreamer-pbutils-1.0 >= $GSTPBU_REQUIRED
 161                                sqlite3 >= $LIBSQLITE3_REQUIRED
 162                                uuid])
 163             RYGEL_PLUGIN_MEDIA_EXPORT_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gupnp-dlna-2.0 --pkg gupnp-dlna-gst-2.0 --pkg gstreamer-tag-1.0 --pkg gstreamer-app-1.0 --pkg gstreamer-pbutils-1.0 --pkg sqlite3"
 164             AC_SUBST([RYGEL_PLUGIN_MEDIA_EXPORT_DEPS_VALAFLAGS])
 165           ])
 166
 167         RYGEL_ADD_PLUGIN([gst-launch],[GStreamer launchline],[no])
 168         AS_IF([test "x$enable_gst_launch_plugin" = "xyes"],
 169           [
 170             PKG_CHECK_MODULES([RYGEL_PLUGIN_GST_LAUNCH_DEPS], [$RYGEL_COMMON_MODULES])
 171             RYGEL_PLUGIN_GST_LAUNCH_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS"
 172             AC_SUBST([RYGEL_PLUGIN_GST_LAUNCH_DEPS_VALAFLAGS])
 173           ])
 174
 175         RYGEL_ADD_STAMP([src/media-engines/gstreamer/librygel_media_engine_gst_la_vala.stamp])
 176         RYGEL_ADD_STAMP([src/librygel-renderer-gst/librygel_renderer_gst_2_0_la_vala.stamp])
 177       ],
 178       [
 179         RYGEL_DISABLE_PLUGIN([playbin])
 180         RYGEL_DISABLE_PLUGIN([media-export])
 181         RYGEL_DISABLE_PLUGIN([gst-launch])
 182       ])
 183
 184 dnl Example plugins:
 185 AC_ARG_ENABLE([example-plugins],
 186               AS_HELP_STRING([--enable-example-plugins],[enable example plugins]),,
 187               enable_example_plugins=no)
 188 AM_CONDITIONAL([BUILD_EXAMPLE_PLUGINS], [test "x$[]enable_example_plugins" = "xyes"])
 189
 190 dnl Explicitly add stamp files for targets that are not plugins
 191 RYGEL_ADD_STAMP([src/librygel-core/librygel_core_2_0_la_vala.stamp])
 192 RYGEL_ADD_STAMP([src/librygel-server/librygel_server_2_0_la_vala.stamp])
 193 RYGEL_ADD_STAMP([src/librygel-renderer/librygel_renderer_2_0_la_vala.stamp])
 194 RYGEL_ADD_STAMP([src/rygel/rygel_vala.stamp])
 195 RYGEL_ADD_STAMP([src/ui/rygel_preferences_vala.stamp])
 196 RYGEL_ADD_STAMP([src/media-engines/simple/librygel_media_engine_simple_la_vala.stamp])
 197
 198 AS_IF([test "x$with_media_engine" = "xgstreamer"],
 199       [
 200         RYGEL_CHECK_PACKAGES([gupnp-dlna-2.0 gstreamer-1.0
 201                               gstreamer-pbutils-1.0])
 202       ])
 203
 204 dnl Debugging
 205 AC_ARG_ENABLE(debug,
 206         AS_HELP_STRING([--enable-debug],[enable debugging]),,
 207         enable_debug=no)
 208 if test "x$enable_debug" = "xyes"; then
 209         CFLAGS="$CFLAGS -O0 -g"
 210         RYGEL_DEBUG_VALAFLAGS="-g"
 211 fi
 212
 213 AC_SUBST(RYGEL_DEBUG_VALAFLAGS)
 214
 215 dnl Strict compiler
 216 AC_ARG_ENABLE(strict-cc,
 217         AS_HELP_STRING([--enable-strict-cc],[enable strict C compiler]),,
 218         enable_strict_cc=no)
 219 if test "x$enable_strict_cc" = "xyes"; then
 220         CFLAGS="$CFLAGS -Wall -Werror"
 221 else
 222         CFLAGS="$CFLAGS -w"
 223 fi
 224
 225 dnl Run uninstalled
 226 AC_ARG_ENABLE(uninstalled,
 227     AS_HELP_STRING([--enable-uninstalled],[run uninstalled]),,
 228         enable_uninstalled=no)
 229 if test "x$enable_uninstalled" = "xyes"; then
 230         AC_MSG_WARN("You want to run the tools uninstalled only? Fine!")
 231 fi
 232 AM_CONDITIONAL([UNINSTALLED], [test "x$enable_uninstalled" = "xyes"])
 233
 234 dnl Check wether user wants to build UIs
 235 AC_ARG_WITH( ui,
 236   AS_HELP_STRING([--without-ui],[Do not build UI applications]),
 237   try_ui=$withval, try_ui=yes )
 238
 239 HAVE_GTK=no
 240 if test x$try_ui = xyes ; then
 241     dnl check for gtk
 242     PKG_CHECK_MODULES([RYGEL_UI_DEPS], [$RYGEL_BASE_MODULES gtk+-3.0 >= $GTK_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED gee-0.8 >= $GEE_REQUIRED],
 243       [
 244         RYGEL_CHECK_PACKAGES([gtk+-3.0], [HAVE_GTK=yes])
 245         RYGEL_UI_DEPS_VALAFLAGS="$RYGEL_BASE_MODULES_VALAFLAGS --pkg gtk+-3.0 --pkg gssdp-1.0 --pkg gee-0.8"
 246         AC_SUBST([RYGEL_UI_DEPS_VALAFLAGS])
 247
 248         PKG_CHECK_MODULES([EXAMPLE_UI_DEPS],
 249                           [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED
 250                            gssdp-1.0 >= $GSSDP_REQUIRED
 251                            gstreamer-video-1.0 >= $GSTREAMER_REQUIRED
 252                            gtk+-3.0 >= $GTK_REQUIRED])
 253       ],
 254       [
 255         AC_MSG_WARN([UI dependencies not found.])
 256         AC_MSG_WARN([UI applications will not be built.])
 257       ])
 258
 259 else
 260     AC_MSG_NOTICE([UI applications disabled.])
 261 fi
 262
 263 AM_CONDITIONAL(BUILD_UI, test "x$HAVE_GTK" = "xyes")
 264
 265 dnl Tests
 266 AC_ARG_ENABLE([tests],
 267               AS_HELP_STRING([--enable-tests],[always build tests]),,
 268               enable_tests=no)
 269 AM_CONDITIONAL([ALWAYS_TEST], [test "x$enable_tests" = "xyes"])
 270
 271 dnl Generate coverage data
 272 AC_ARG_ENABLE([coverage],
 273   AS_HELP_STRING([--enable-coverage],
 274                  [Generate converage reports for unit tests]),
 275   [],
 276   [enable_coverage=no])
 277 AM_CONDITIONAL([ENABLE_COVERAGE],[test "x$enable_coverage" != "xno"])
 278 AS_IF([test "x$enable_coverage" != "xno"],
 279   [
 280     AC_PATH_PROG([LCOV], [lcov])
 281     AC_PATH_PROG([GENHTML], [genhtml])
 282     AC_SUBST([COVERAGE_LIBS],["-lgcov"])
 283     AC_SUBST([COVERAGE_CFLAGS],["-fprofile-arcs -ftest-coverage"])
 284     AC_SUBST(COVERAGE_VALAFLAGS,["-g"])
 285   ]
 286 )
 287
 288 dnl Check additional requirements for MediaExport plugins
 289 if test "x$enable_media_export_plugin" = "xyes";
 290 then
 291     RYGEL_CHECK_PACKAGES([sqlite3 gstreamer-tag-1.0 gstreamer-app-1.0])
 292     AC_CHECK_HEADER([unistr.h],
 293                     AC_CHECK_LIB([unistring],
 294                                  [u8_strcoll],
 295                                  [have_unistring=yes],[have_unistring=no]))
 296     if test "x$have_unistring" = "xyes"; then
 297         AC_DEFINE([HAVE_UNISTRING],[1],[Use libunistring for collation])
 298         RYGEL_PLUGIN_MEDIA_EXPORT_DEPS_LIBS="$RYGEL_PLUGIN_MEDIA_EXPORT_DEPS_LIBS -lunistring"
 299     fi
 300 fi
 301
 302
 303 RYGEL_ADD_PLUGIN([tracker],[Tracker],[yes])
 304 AS_IF([test "x$enable_tracker_plugin" = "xyes"],
 305   [
 306     PKG_CHECK_MODULES([RYGEL_PLUGIN_TRACKER_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED])
 307
 308     tracker_api_version="0.14"
 309     PKG_CHECK_MODULES(TRACKER_SPARQL,
 310                       tracker-sparql-0.14 >= $TRACKER_SPARQL_REQUIRED_MIN,
 311                       [tracker_api_version="0.14"],
 312                       [tracker_api_version=""])
 313     AS_IF([test "x$[]tracker_api_version" = "x"],
 314           [
 315             PKG_CHECK_MODULES(TRACKER_SPARQL,
 316                               tracker-sparql-0.15 >=  $TRACKER_SPARQL_REQUIRED_MIN,
 317                               [tracker_api_version="0.15"],
 318                               [tracker_api_version=""])
 319           ])
 320     AS_IF([test "x$[]tracker_api_version" = "x"],
 321           [
 322             PKG_CHECK_MODULES(TRACKER_SPARQL,
 323                               tracker-sparql-0.16 >=  $TRACKER_SPARQL_REQUIRED_MIN,
 324                               [tracker_api_version="0.16"],
 325                               [])
 326           ])
 327     AS_IF([test "x$enable_vala" = "xyes"],
 328           [VALA_CHECK_PACKAGES([tracker-sparql-$tracker_api_version])])
 329
 330     RYGEL_PLUGIN_TRACKER_DEPS_VALAFLAGS="--pkg tracker-sparql-$tracker_api_version"
 331     AC_SUBST([RYGEL_PLUGIN_TRACKER_DEPS_VALAFLAGS])
 332   ])
 333
 334 # This should be called only after all RYGEL_CHECK_VALA() and RYGEL_ADD_PLUGIN() calls:
 335 RYGEL_CHECK_VALA([$VALA_REQUIRED],
 336                  [gupnp-1.0
 337                   gupnp-av-1.0
 338                   gio-2.0
 339                   gee-0.8
 340                   posix])
 341
 342 dnl Gettext
 343 GETTEXT_PACKAGE=rygel
 344 AC_SUBST(GETTEXT_PACKAGE)
 345 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 346   [Define the gettext package to be used])
 347
 348 AM_GLIB_GNU_GETTEXT
 349 IT_PROG_INTLTOOL([0.40.0])
 350
 351 dnl Shave the output
 352 AM_SILENT_RULES([yes])
 353
 354 dnl documenation
 355 AC_PATH_PROG([XSLTPROC], [xsltproc])
 356 AM_CONDITIONAL([HAVE_XSLTPROC], [test x"$XSLTPROC" != x])
 357
 358 dnl Use valadoc for API documentation:
 359 dnl This is on by default when using autogen.sh
 360 dnl (so it is not on by default when building from a tarball with configure.)
 361 AC_ARG_ENABLE(valadoc,
 362   AS_HELP_STRING([--enable-valadoc[=@<:@no/auto/yes@:>@]], [Enable valadoc support]),,
 363     [enable_valadoc=no])
 364
 365 found_valadoc=no
 366 AS_IF([test "x$enable_valadoc" != "xno"], [
 367     AC_PATH_PROG(VALADOC, valadoc, :)
 368     AS_IF([test -x "$VALADOC"], [
 369       found_valadoc=yes
 370       AC_SUBST(VALADOC)
 371       PKG_CHECK_MODULES([GTKDOC],[gtk-doc >= 1.0])
 372     ], [
 373       AS_IF([test "x$enable_valadoc" == "xyes"], AC_MSG_ERROR([Unable to find valadoc]))
 374     ])
 375   ])
 376
 377 AM_CONDITIONAL(ENABLE_VALADOC, test x$found_valadoc = xyes)
 378
 379 AC_SUBST([RYGEL_PLUGIN_LINKER_FLAGS],
 380          ["-shared -fPIC -module -avoid-version -Wl,-z,defs"])
 381 AC_SUBST([RYGEL_PLUGIN_DIR],
 382          [${libdir}/rygel-2.0/plugins])
 383 AC_SUBST([RYGEL_MEDIA_ENGINE_DIR],
 384          [${libdir}/rygel-2.0/engines])
 385
 386 AC_CONFIG_FILES([
 387 Makefile
 388 src/Makefile
 389 src/librygel-core/Makefile
 390 src/librygel-renderer/Makefile
 391 src/librygel-renderer-gst/Makefile
 392 src/librygel-server/Makefile
 393 src/rygel/Makefile
 394 src/ui/Makefile
 395 src/media-engines/Makefile
 396 src/media-engines/gstreamer/Makefile
 397 src/media-engines/gstreamer/media-engine-gst.plugin
 398 src/media-engines/simple/Makefile
 399 src/media-engines/simple/media-engine-simple.plugin
 400 src/plugins/Makefile
 401 data/Makefile
 402 data/xml/Makefile
 403 data/xml/MediaServer3.xml.in
 404 data/xml/MediaRenderer2.xml.in
 405 data/icons/Makefile
 406 data/icons/32x32/Makefile
 407 data/icons/48x48/Makefile
 408 data/icons/120x120/Makefile
 409 data/icons/128x128/Makefile
 410 data/icons/scalable/Makefile
 411 data/rygel.desktop.in
 412 data/rygel-preferences.desktop.in
 413 doc/Makefile
 414 doc/reference/Makefile
 415 doc/reference/librygel-core/Makefile
 416 doc/reference/librygel-renderer/Makefile
 417 doc/reference/librygel-server/Makefile
 418 doc/reference/librygel-renderer-gst/Makefile
 419 po/Makefile.in
 420 rygel-core-2.0.pc
 421 rygel-renderer-2.0.pc
 422 rygel-server-2.0.pc
 423 rygel-renderer-gst-2.0.pc
 424 tests/Makefile
 425 examples/Makefile
 426 examples/renderer-plugins/Makefile
 427 examples/renderer-plugins/vala/Makefile
 428 examples/renderer-plugins/vala/example-renderer-vala.plugin
 429 examples/renderer-plugins/C/Makefile
 430 examples/renderer-plugins/C/example-renderer-c.plugin
 431 examples/server-plugins/Makefile
 432 examples/server-plugins/vala/Makefile
 433 examples/server-plugins/vala/example-server-vala.plugin
 434 examples/server-plugins/C/Makefile
 435 examples/server-plugins/C/example-server-c.plugin
 436 ])
 437 AC_OUTPUT
 438
 439 echo "
 440
 441                     ${PACKAGE} ${VERSION}
 442                     ============
 443
 444
 445         Prefix:                 ${prefix}
 446         Source code location:   ${srcdir}
 447         Compiler:               ${CC}
 448         CFLAGS:                 ${CFLAGS}
 449         VALAFLAGS:              ${VALAFLAGS}
 450         uninstalled:            ${enable_uninstalled}
 451         preferences ui:         ${HAVE_GTK}
 452         Media Engine:           ${with_media_engine}
 453     Plugins:
 454         examples:               ${enable_example_plugins}
 455         tracker:                ${enable_tracker_plugin}
 456             version:            ${tracker_api_version}
 457         mediathek:              ${enable_mediathek_plugin}
 458         media-export            ${enable_media_export_plugin}
 459         external:               ${enable_external_plugin}
 460         MPRIS2:                 ${enable_mpris_plugin}
 461         gst-launch:             ${enable_gst_launch_plugin}
 462         playbin:                ${enable_playbin_plugin}
 463 "