configure.ac

   1 dnl These m4 macros are whitespace sensitive and break if moved around much.
   2 m4_define([LU_VERSION_H], m4_include([libusb/version.h]))
   3 m4_define([LU_DEFINE_VERSION_ATOM],
   4         [m4_define([$1], m4_bregexp(LU_VERSION_H,
   5         [^#define\s*$1\s*\([0-9]*\).*], [\1]))])
   6 m4_define([LU_DEFINE_VERSION_RC_ATOM],
   7         [m4_define([$1], m4_bregexp(LU_VERSION_H,
   8         [^#define\s*$1\s*"\(-rc[0-9]*\)".*], [\1]))])
   9 dnl The m4_bregexp() returns (only) the numbers following the #define named
  10 dnl in the first macro parameter. m4_define() then defines the name for use
  11 dnl in AC_INIT.
  12
  13 LU_DEFINE_VERSION_ATOM([LIBUSB_MAJOR])
  14 LU_DEFINE_VERSION_ATOM([LIBUSB_MINOR])
  15 LU_DEFINE_VERSION_ATOM([LIBUSB_MICRO])
  16 LU_DEFINE_VERSION_RC_ATOM([LIBUSB_RC])
  17
  18 AC_INIT([libusb],[LIBUSB_MAJOR[.]LIBUSB_MINOR[.]LIBUSB_MICRO[]LIBUSB_RC],[libusb-devel@lists.sourceforge.net],[libusb],[http://libusb.info])
  19
  20 dnl Library versioning
  21 dnl These numbers should be tweaked on every release. Read carefully:
  22 dnl http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  23 dnl http://sourceware.org/autobook/autobook/autobook_91.html
  24 lt_current=2
  25 lt_revision=0
  26 lt_age=2
  27 LTLDFLAGS="-version-info ${lt_current}:${lt_revision}:${lt_age}"
  28
  29 AM_INIT_AUTOMAKE
  30
  31 AC_CONFIG_SRCDIR([libusb/core.c])
  32 AC_CONFIG_MACRO_DIR([m4])
  33 AC_CONFIG_HEADERS([config.h])
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  35
  36 AC_PREREQ([2.69])
  37 AC_PROG_CC
  38 AC_PROG_CXX
  39 LT_INIT
  40 LT_LANG([Windows Resource])
  41 AC_C_INLINE
  42 AM_PROG_CC_C_O
  43 AC_DEFINE([_GNU_SOURCE], [1], [Use GNU extensions])
  44
  45 LTLDFLAGS="${LTLDFLAGS} -no-undefined"
  46
  47 AC_MSG_CHECKING([operating system])
  48 case $host in
  49 *-darwin*)
  50         AC_MSG_RESULT([Darwin/Mac OS X])
  51         backend=darwin
  52         poll=posix
  53         threads=posix
  54         ;;
  55 *-haiku*)
  56         AC_MSG_RESULT([Haiku])
  57         backend=haiku
  58         poll=posix
  59         threads=posix
  60         ;;
  61 *-linux* | *-uclinux*)
  62         dnl on linux-android platform, some functions are in different places
  63         case $host in
  64         *-linux-android*)
  65                 AC_MSG_RESULT([Linux (Android system)])
  66                 is_backend_android=yes
  67                 ;;
  68         *)
  69                 AC_MSG_RESULT([Linux])
  70                 is_backend_android=no
  71                 ;;
  72         esac
  73         backend=linux
  74         poll=posix
  75         threads=posix
  76         ;;
  77 *-netbsd*)
  78         AC_MSG_RESULT([NetBSD])
  79         backend=netbsd
  80         poll=posix
  81         threads=posix
  82         ;;
  83 *-openbsd*)
  84         AC_MSG_RESULT([OpenBSD])
  85         backend=openbsd
  86         poll=posix
  87         threads=posix
  88         ;;
  89 *-solaris*)
  90         AC_MSG_RESULT([SunOS])
  91         backend=sunos
  92         poll=posix
  93         threads=posix
  94         ;;
  95 *-cygwin*)
  96         AC_MSG_RESULT([Windows (using Cygwin)])
  97         backend=windows
  98         poll=windows
  99         threads=posix
 100         ;;
 101 *-mingw* | *msys*)
 102         AC_MSG_RESULT([Windows])
 103         backend=windows
 104         poll=windows
 105         threads=windows
 106         create_import_lib=yes
 107         AM_CFLAGS="${AM_CFLAGS} -fno-omit-frame-pointer"
 108         ;;
 109 *)
 110         AC_MSG_RESULT([Null])
 111         backend="null"
 112         poll=posix
 113         threads="posix"
 114         ;;
 115 esac
 116
 117 case $backend in
 118 darwin)
 119         AC_DEFINE([OS_DARWIN], [1], [Darwin backend])
 120         LIBS="-lobjc -Wl,-framework,IOKit -Wl,-framework,CoreFoundation"
 121         LTLDFLAGS="${LTLDFLAGS} -Wl,-prebind"
 122         ;;
 123 haiku)
 124         AC_DEFINE([OS_HAIKU], [1], [Haiku backend])
 125         LIBS="-lbe"
 126         ;;
 127 linux)
 128         AC_DEFINE([OS_LINUX], [1], [Linux backend])
 129         AC_SEARCH_LIBS([clock_gettime], [rt], [], [], [-pthread])
 130         AC_ARG_ENABLE([udev],
 131                 [AC_HELP_STRING([--enable-udev], [use udev for device enumeration and hotplug support (recommended) [default=yes]])],
 132                 [], [enable_udev=yes])
 133         if test "x$enable_udev" = xyes ; then
 134                 dnl system has udev. use it or fail!
 135                 AC_CHECK_HEADER([libudev.h], [], [AC_MSG_ERROR([udev support requested but libudev header not installed])])
 136                 AC_CHECK_LIB([udev], [udev_new], [], [AC_MSG_ERROR([udev support requested but libudev not installed])])
 137         else
 138                 AC_CHECK_HEADERS([asm/types.h])
 139                 AC_CHECK_HEADER([linux/netlink.h], [], [AC_MSG_ERROR([Linux netlink header not found])])
 140                 AC_CHECK_HEADER([sys/socket.h], [], [AC_MSG_ERROR([Linux socket header not found])])
 141         fi
 142         if test "x$is_backend_android" != xyes; then
 143                 THREAD_CFLAGS="-pthread"
 144                 LIBS="${LIBS} -pthread"
 145         fi
 146         ;;
 147 netbsd)
 148         AC_DEFINE([OS_NETBSD], [1], [NetBSD backend])
 149         THREAD_CFLAGS="-pthread"
 150         LIBS="-pthread"
 151         ;;
 152 null)
 153         AC_DEFINE([OS_NULL], [1], [Null backend])
 154         THREAD_CFLAGS="-pthread"
 155         LIBS="-pthread"
 156         ;;
 157 openbsd)
 158         AC_DEFINE([OS_OPENBSD], [1], [OpenBSD backend])
 159         THREAD_CFLAGS="-pthread"
 160         LIBS="-pthread"
 161         ;;
 162 sunos)
 163         AC_DEFINE([OS_SUNOS], [1], [SunOS backend])
 164         THREAD_CFLAGS="-pthread"
 165         LIBS="-pthread -ldevinfo"
 166         ;;
 167 windows)
 168         AC_DEFINE([OS_WINDOWS], [1], [Windows backend])
 169         AC_CHECK_TYPES([struct timespec], [], [], [[#include <time.h>]])
 170         LIBS=""
 171         LTLDFLAGS="${LTLDFLAGS} -avoid-version -Wl,--add-stdcall-alias"
 172         AC_DEFINE([_WIN32_WINNT], [_WIN32_WINNT_VISTA], [Oldest Windows version supported (Vista)])
 173         ;;
 174 *)
 175         AC_MSG_ERROR([Unknown backend])
 176         ;;
 177 esac
 178
 179 AC_SUBST(LIBS)
 180
 181 AM_CONDITIONAL([OS_DARWIN], [test "x$backend" = xdarwin])
 182 AM_CONDITIONAL([OS_HAIKU], [test "x$backend" = xhaiku])
 183 AM_CONDITIONAL([OS_LINUX], [test "x$backend" = xlinux])
 184 AM_CONDITIONAL([OS_NETBSD], [test "x$backend" = xnetbsd])
 185 AM_CONDITIONAL([OS_NULL], [test "x$backend" = xnull])
 186 AM_CONDITIONAL([OS_OPENBSD], [test "x$backend" = xopenbsd])
 187 AM_CONDITIONAL([OS_SUNOS], [test "x$backend" = xsunos])
 188 AM_CONDITIONAL([OS_WINDOWS], [test "x$backend" = xwindows])
 189 AM_CONDITIONAL([POLL_POSIX], [test "x$poll" = xposix])
 190 AM_CONDITIONAL([POLL_WINDOWS], [test "x$poll" = xwindows])
 191 AM_CONDITIONAL([THREADS_POSIX], [test "x$threads" = xposix])
 192 AM_CONDITIONAL([THREADS_WINDOWS], [test "x$threads" = xwindows])
 193 AM_CONDITIONAL([CREATE_IMPORT_LIB], [test "x$create_import_lib" = xyes])
 194 AM_CONDITIONAL([USE_UDEV], [test "x$enable_udev" = xyes])
 195
 196 if test "x$poll" = xposix; then
 197         AC_DEFINE([POLL_POSIX], [1], [Use POSIX poll() implementation])
 198         AC_CHECK_TYPES([nfds_t], [], [], [[#include <poll.h>]])
 199         AC_CHECK_FUNCS([pipe2])
 200 elif test "x$poll" = xwindows; then
 201         AC_DEFINE([POLL_WINDOWS], [1], [Use Windows poll() implementation])
 202 else
 203         AC_MSG_ERROR([Unknown poll implementation])
 204 fi
 205
 206 if test "x$threads" = xposix; then
 207         AC_DEFINE([THREADS_POSIX], [1], [Use POSIX Threads])
 208 elif test "x$threads" = xwindows; then
 209         AC_DEFINE([THREADS_WINDOWS], [1], [Use Windows Threads])
 210 else
 211         AC_MSG_ERROR([Unknown threads implementation])
 212 fi
 213
 214 dnl headers not available on all platforms but required on others
 215 AC_CHECK_HEADERS([sys/time.h])
 216
 217 dnl timerfd support
 218 if test "x$backend" = xlinux || test "x$backend" = xsunos; then
 219         AC_ARG_ENABLE([timerfd],
 220                 [AS_HELP_STRING([--enable-timerfd], [use timerfd for timing [default=auto]])],
 221                 [use_timerfd=$enableval],
 222                 [use_timerfd=auto])
 223         if test "x$use_timerfd" != xno; then
 224                 AC_CHECK_HEADER([sys/timerfd.h], [timerfd_h=yes], [timerfd_h=no])
 225                 if test "x$timerfd_h" = xyes; then
 226                         AC_CHECK_DECLS([TFD_NONBLOCK, TFD_CLOEXEC], [timerfd_h_ok=yes], [timerfd_h_ok=no], [[#include <sys/timerfd.h>]])
 227                         if test "x$timerfd_h_ok" = xyes; then
 228                                 AC_CHECK_FUNC([timerfd_create], [timerfd_ok=yes], [timerfd_ok=no])
 229                                 if test "x$timerfd_ok" = xyes; then
 230                                         AC_DEFINE([HAVE_TIMERFD], [1], [Define if the system has timerfd functionality])
 231                                 elif test "x$use_timerfd" = xyes; then
 232                                         AC_MSG_ERROR([timerfd_create() function not found; glibc 2.9+ required])
 233                                 fi
 234                         elif test "x$use_timerfd" = xyes; then
 235                                 AC_MSG_ERROR([timerfd header not usable; glibc 2.9+ required])
 236                         fi
 237                 elif test "x$use_timerfd" = xyes; then
 238                         AC_MSG_ERROR([timerfd header not available; glibc 2.9+ required])
 239                 fi
 240         fi
 241         AC_MSG_CHECKING([whether to use timerfd for timing])
 242         if test "x$use_timerfd" = xno; then
 243                 AC_MSG_RESULT([no (disabled by user)])
 244         elif test "x$timerfd_h" = xno; then
 245                 AC_MSG_RESULT([no (header not usable)])
 246         elif test "x$timerfd_h_ok" = xno; then
 247                 AC_MSG_RESULT([no (header not available)])
 248         elif test "x$timerfd_ok" = xno; then
 249                 AC_MSG_RESULT([no (functions not available)])
 250         else
 251                 AC_MSG_RESULT([yes])
 252         fi
 253 fi
 254
 255 dnl Message logging
 256 AC_ARG_ENABLE([log],
 257         [AS_HELP_STRING([--disable-log], [disable all logging])],
 258         [log_enabled=$enableval],
 259         [log_enabled=yes])
 260 if test "x$log_enabled" != xno; then
 261         AC_DEFINE([ENABLE_LOGGING], [1], [Message logging])
 262 fi
 263
 264 AC_ARG_ENABLE([debug-log],
 265         [AS_HELP_STRING([--enable-debug-log], [start with debug message logging enabled [default=no]])],
 266         [debug_log_enabled=$enableval],
 267         [debug_log_enabled=no])
 268 if test "x$debug_log_enabled" != xno; then
 269         AC_DEFINE([ENABLE_DEBUG_LOGGING], [1], [Start with debug message logging enabled])
 270 fi
 271
 272 AC_ARG_ENABLE([system-log],
 273         [AS_HELP_STRING([--enable-system-log], [output logging messages to system wide log, if supported by the OS [default=no]])],
 274         [system_log_enabled=$enableval],
 275         [system_log_enabled=no])
 276 if test "x$system_log_enabled" != xno; then
 277         AC_DEFINE([USE_SYSTEM_LOGGING_FACILITY], [1], [Enable output to system log])
 278         if test "x$backend" != xwindows && test "x$is_backend_android" != xyes; then
 279                 dnl Check if syslog is available in standard C library
 280                 AC_CHECK_HEADER([syslog.h], [syslog_h=yes], [syslog_h=no])
 281                 if test "x$syslog_h" = xyes; then
 282                         AC_CHECK_FUNCS([syslog])
 283                 fi
 284         fi
 285 fi
 286
 287 dnl Examples build
 288 AC_ARG_ENABLE([examples-build],
 289         [AS_HELP_STRING([--enable-examples-build], [build example applications [default=no]])],
 290         [build_examples=$enableval],
 291         [build_examples=no])
 292 AM_CONDITIONAL([BUILD_EXAMPLES], [test "x$build_examples" != xno])
 293
 294 dnl Tests build
 295 AC_ARG_ENABLE([tests-build],
 296         [AS_HELP_STRING([--enable-tests-build], [build test applications [default=no]])],
 297         [build_tests=$enableval],
 298         [build_tests=no])
 299 AM_CONDITIONAL([BUILD_TESTS], [test "x$build_tests" != xno])
 300
 301 dnl sigaction needed for some example programs
 302 if test "x$build_examples" != xno; then
 303         AC_CHECK_FUNC([sigaction], [have_sigaction=yes], [have_sigaction=no])
 304 fi
 305 AM_CONDITIONAL([HAVE_SIGACTION], [test "x$have_sigaction" = xyes])
 306
 307 dnl check for -fvisibility=hidden compiler support (GCC >= 3.4)
 308 saved_CFLAGS="${CFLAGS}"
 309 dnl -Werror required for cygwin
 310 CFLAGS="${CFLAGS} -Werror -fvisibility=hidden"
 311 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 312         [VISIBILITY_CFLAGS="-fvisibility=hidden"
 313          AC_DEFINE([DEFAULT_VISIBILITY], [__attribute__((visibility("default")))], [Default visibility])],
 314         [VISIBILITY_CFLAGS=""
 315          AC_DEFINE([DEFAULT_VISIBILITY], [], [Default visibility])],
 316         ])
 317 CFLAGS="${saved_CFLAGS}"
 318
 319 dnl check for -Wno-pointer-sign compiler support (GCC >= 4)
 320 saved_CFLAGS="${CFLAGS}"
 321 CFLAGS="${CFLAGS} -Wno-pointer-sign"
 322 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 323         nopointersign_cflags="-Wno-pointer-sign", nopointersign_cflags="")
 324 CFLAGS="${saved_CFLAGS}"
 325
 326 dnl check for -std=gnu11 compiler support
 327 saved_CFLAGS="${CFLAGS}"
 328 CFLAGS="-std=gnu11"
 329 AC_MSG_CHECKING([whether CC supports -std=gnu11])
 330 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 331         [AC_MSG_RESULT([yes])
 332          AM_CFLAGS="${AM_CFLAGS} -std=gnu11"],
 333         [AC_MSG_RESULT([no])])
 334 CFLAGS="${saved_CFLAGS}"
 335
 336 dnl check for _Thread_local compiler support
 337 if test "x$backend" != xwindows; then
 338         saved_CFLAGS="${CFLAGS}"
 339         saved_LDFLAGS="${LDFLAGS}"
 340         CFLAGS="${CFLAGS} -fPIC"
 341         LDFLAGS="${LDFLAGS} -shared"
 342         AC_MSG_CHECKING([whether CC supports _Thread_local])
 343         AC_LINK_IFELSE([AC_LANG_PROGRAM([], [static _Thread_local int v])],
 344                 [AC_MSG_RESULT([yes])
 345                  AC_DEFINE([HAVE_CC_THREAD_LOCAL], [1], [Define to 1 if the compiler supports _Thread_local.])],
 346                 [AC_MSG_RESULT([no])])
 347         CFLAGS="${saved_CFLAGS}"
 348         LDFLAGS="${saved_LDFLAGS}"
 349 fi
 350
 351 AM_CFLAGS="${AM_CFLAGS} -Wall -Wundef -Wunused -Wstrict-prototypes -Werror-implicit-function-declaration ${nopointersign_cflags} -Wshadow ${THREAD_CFLAGS} ${VISIBILITY_CFLAGS}"
 352
 353 AC_SUBST(AM_CFLAGS)
 354 AC_SUBST(LTLDFLAGS)
 355
 356 AC_CONFIG_FILES([libusb-1.0.pc])
 357 AC_CONFIG_FILES([Makefile])
 358 AC_CONFIG_FILES([libusb/Makefile])
 359 AC_CONFIG_FILES([examples/Makefile])
 360 AC_CONFIG_FILES([tests/Makefile])
 361 AC_CONFIG_FILES([doc/Makefile])
 362 AC_CONFIG_FILES([doc/doxygen.cfg])
 363 AC_OUTPUT