configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT([GStreamer Good Plug-ins],[1.9.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-good])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 AG_GST_LIBTOOL_PREPARE
  46 AS_LIBTOOL(GST, 901, 0, 901)
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=1.9.1
  50 GSTPB_REQ=1.9.1
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.17])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  69 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  70
  71 AG_GST_ARG_DEBUG
  72 AG_GST_ARG_PROFILING
  73 AG_GST_ARG_VALGRIND
  74 AG_GST_ARG_GCOV
  75
  76 AG_GST_ARG_EXAMPLES
  77
  78 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  79 AG_GST_ARG_WITH_PACKAGE_NAME
  80 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  81
  82 AG_GST_ARG_WITH_PLUGINS
  83
  84 AG_GST_ARG_ENABLE_EXTERNAL
  85
  86 AG_GST_ARG_ENABLE_EXPERIMENTAL
  87
  88 dnl *** checks for platform ***
  89
  90 dnl * hardware/architecture *
  91
  92 dnl common/m4/gst-arch.m4
  93 dnl check CPU type
  94 AG_GST_ARCH
  95
  96 dnl Determine endianness
  97 AC_C_BIGENDIAN
  98
  99 dnl *** checks for programs ***
 100
 101 dnl find a compiler
 102 AC_PROG_CC
 103 AC_PROG_CC_STDC
 104
 105 dnl determine c++ compiler
 106 AC_PROG_CXX
 107 dnl determine if c++ is available on this system
 108 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 109
 110 dnl determine c++ preprocessor
 111 dnl FIXME: do we need this ?
 112 AC_PROG_CXXCPP
 113
 114 AC_PROG_OBJC
 115
 116 dnl check if the compiler supports '-c' and '-o' options
 117 AM_PROG_CC_C_O
 118
 119 dnl find an assembler
 120 AM_PROG_AS
 121
 122 dnl check if the compiler supports do while(0) macros
 123 AG_GST_CHECK_DOWHILE_MACROS
 124
 125 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 126 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 127
 128 dnl check for documentation tools
 129 GTK_DOC_CHECK([1.12])
 130 AG_GST_PLUGIN_DOCS([1.12])
 131
 132 dnl *** checks for libraries ***
 133
 134 dnl check for libm, for sin()
 135 LT_LIB_M
 136 AC_SUBST(LIBM)
 137
 138 AC_CHECK_FUNCS(clock_gettime, [], [
 139   AC_CHECK_LIB(rt, clock_gettime, [
 140     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 141     LIBRT="-lrt"
 142     AC_SUBST([LIBRT])
 143   ])
 144 ])
 145
 146 dnl *** checks for header files ***
 147
 148 dnl check if we have ANSI C header files
 149 AC_HEADER_STDC
 150
 151 dnl used by ext/wavpack
 152 AX_CREATE_STDINT_H
 153
 154 dnl used in gst/udp
 155 AC_CHECK_HEADERS([sys/time.h])
 156
 157 dnl used in gst/udp
 158 AC_CHECK_HEADERS([sys/socket.h])
 159
 160 dnl *** checks for types/defines ***
 161
 162 dnl Check for FIONREAD ioctl declaration.  This check is needed
 163 dnl for the UDP plugin to build on Solaris
 164 GST_CHECK_FIONREAD
 165
 166 dnl *** checks for structures ***
 167
 168 dnl *** checks for compiler characteristics ***
 169
 170 dnl check if we have GCC inline-asm
 171 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 172 if test x$HAVE_GCC_ASM = xyes ; then
 173   AC_DEFINE(HAVE_GCC_ASM, 1,
 174     [Define if compiler supports gcc inline assembly])
 175 fi
 176 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 177
 178 dnl *** checks for library functions ***
 179
 180 LIBS_SAVE=$LIBS
 181 LIBS="$LIBS $LIBM"
 182 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 183 LIBS=$LIBS_SAVE
 184
 185 dnl Check whether isinf() is defined by math.h
 186 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 187     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 188 if test "$ac_cv_have_isinf" = "yes"
 189 then
 190     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 191 fi
 192
 193 dnl Check for mmap (needed by electricfence plugin)
 194 AC_FUNC_MMAP
 195 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 196
 197 dnl Check for mmap (needed by electricfence plugin)
 198
 199 AC_CHECK_TYPE([struct ip_mreqn], [
 200               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 201               [#include <netinet/in.h>])
 202
 203 dnl *** checks for dependency libraries ***
 204
 205
 206 dnl GLib
 207 GLIB_REQ=2.40.0
 208 AG_GST_GLIB_CHECK([$GLIB_REQ])
 209
 210 dnl Orc
 211 ORC_CHECK([0.4.17])
 212
 213 dnl checks for gstreamer
 214 dnl uninstalled is selected preferentially -- see pkg-config(1)
 215 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 216 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 217 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 219 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 220 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 221
 222 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 223 if test -z $GST_TOOLS_DIR; then
 224   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 225 fi
 226 AC_SUBST(GST_TOOLS_DIR)
 227
 228 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 229 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 230
 231 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 232
 233 dnl Check for documentation xrefs
 234 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 235 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 236 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 237 AC_SUBST(GLIB_PREFIX)
 238 AC_SUBST(GST_PREFIX)
 239 AC_SUBST(GSTPB_PREFIX)
 240
 241 dnl GTK is optional and used in examples
 242 HAVE_GTK=no
 243 GTK_REQ=3.0.0
 244 if test "x$BUILD_EXAMPLES" = "xyes"; then
 245   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 246   dnl some examples need gtk+-x11
 247   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 248   AC_SUBST(GTK_LIBS)
 249   AC_SUBST(GTK_CFLAGS)
 250 fi
 251 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 252 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 253
 254 dnl Check for -Bsymbolic-functions linker flag used to avoid
 255 dnl intra-library PLT jumps, if available.
 256 AC_ARG_ENABLE(Bsymbolic,
 257               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 258               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 259                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 260                LDFLAGS=-Wl,-Bsymbolic-functions
 261                LIBS=
 262                AC_TRY_LINK([], [return 0],
 263                            AC_MSG_RESULT(yes)
 264                            enable_Bsymbolic=yes,
 265                            AC_MSG_RESULT(no)
 266                            enable_Bsymbolic=no)
 267                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 268
 269 dnl *** set variables based on configure arguments ***
 270
 271 dnl set license and copyright notice
 272 GST_LICENSE="LGPL"
 273 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 274 AC_SUBST(GST_LICENSE)
 275
 276 dnl set location of plugin directory
 277 AG_GST_SET_PLUGINDIR
 278
 279 dnl set release date/time
 280 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 281   ["${srcdir}/gst-plugins-good.doap"],
 282   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 283
 284 dnl build static plugins or not
 285 AC_MSG_CHECKING([whether to build static plugins or not])
 286 AC_ARG_ENABLE(
 287   static-plugins,
 288   AC_HELP_STRING(
 289     [--enable-static-plugins],
 290     [build static plugins @<:@default=no@:>@]),
 291   [AS_CASE(
 292     [$enableval], [no], [], [yes], [],
 293     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 294   [enable_static_plugins=no])
 295 AC_MSG_RESULT([$enable_static_plugins])
 296 if test "x$enable_static_plugins" = xyes; then
 297   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 298     [Define if static plugins should be built])
 299   GST_PLUGIN_LIBTOOLFLAGS=""
 300 else
 301   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 302 fi
 303 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 304 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 305
 306 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 307 dnl make sure it doesn't complain about unused variables if debugging is disabled
 308 NO_WARNINGS=""
 309 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 310
 311 dnl define an ERROR_CFLAGS Makefile variable
 312 dnl -Wundef: too many broken headers
 313 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 314       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 315       -Wwrite-strings -Wold-style-definition -Waggregate-return
 316       -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 317       -Wnested-externs $NO_WARNINGS])
 318
 319 dnl define an ERROR_CXXFLAGS Makefile variable
 320 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 321         -Wmissing-declarations -Wredundant-decls
 322         -Wwrite-strings
 323         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 324         $NO_WARNINGS])
 325
 326 dnl define an ERROR_OBJCFLAGS Makefile variable
 327 AG_GST_SET_ERROR_OBJCFLAGS($FATAL_WARNINGS, [
 328       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 329       -Wwrite-strings -Wold-style-definition
 330       -Winit-self -Wmissing-include-dirs -Wno-multichar
 331       -Wnested-externs $NO_WARNINGS])
 332
 333 dnl define correct level for debugging messages
 334 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 335
 336 dnl used in examples
 337 AG_GST_DEFAULT_ELEMENTS
 338
 339 dnl *** plug-ins to include ***
 340
 341 dnl these are all the gst plug-ins, compilable without additional libs
 342 dnl videofilter is at the top because others depend on it
 343 AG_GST_CHECK_PLUGIN(alpha)
 344 AG_GST_CHECK_PLUGIN(apetag)
 345 AG_GST_CHECK_PLUGIN(audiofx)
 346 AG_GST_CHECK_PLUGIN(audioparsers)
 347 AG_GST_CHECK_PLUGIN(auparse)
 348 AG_GST_CHECK_PLUGIN(autodetect)
 349 AG_GST_CHECK_PLUGIN(avi)
 350 AG_GST_CHECK_PLUGIN(cutter)
 351 AG_GST_CHECK_PLUGIN(debugutils)
 352 AG_GST_CHECK_PLUGIN(deinterlace)
 353 AG_GST_CHECK_PLUGIN(dtmf)
 354 AG_GST_CHECK_PLUGIN(effectv)
 355 AG_GST_CHECK_PLUGIN(equalizer)
 356 AG_GST_CHECK_PLUGIN(flv)
 357 AG_GST_CHECK_PLUGIN(flx)
 358 AG_GST_CHECK_PLUGIN(goom)
 359 AG_GST_CHECK_PLUGIN(goom2k1)
 360 AG_GST_CHECK_PLUGIN(icydemux)
 361 AG_GST_CHECK_PLUGIN(id3demux)
 362 AG_GST_CHECK_PLUGIN(imagefreeze)
 363 AG_GST_CHECK_PLUGIN(interleave)
 364 AG_GST_CHECK_PLUGIN(isomp4)
 365 AG_GST_CHECK_PLUGIN(law)
 366 AG_GST_CHECK_PLUGIN(level)
 367 AG_GST_CHECK_PLUGIN(matroska)
 368 AG_GST_CHECK_PLUGIN(monoscope)
 369 AG_GST_CHECK_PLUGIN(multifile)
 370 AG_GST_CHECK_PLUGIN(multipart)
 371 AG_GST_CHECK_PLUGIN(replaygain)
 372 AG_GST_CHECK_PLUGIN(rtp)
 373 AG_GST_CHECK_PLUGIN(rtpmanager)
 374 AG_GST_CHECK_PLUGIN(rtsp)
 375 AG_GST_CHECK_PLUGIN(shapewipe)
 376 AG_GST_CHECK_PLUGIN(smpte)
 377 AG_GST_CHECK_PLUGIN(spectrum)
 378 AG_GST_CHECK_PLUGIN(udp)
 379 AG_GST_CHECK_PLUGIN(videobox)
 380 AG_GST_CHECK_PLUGIN(videocrop)
 381 AG_GST_CHECK_PLUGIN(videofilter)
 382 AG_GST_CHECK_PLUGIN(videomixer)
 383 AG_GST_CHECK_PLUGIN(wavenc)
 384 AG_GST_CHECK_PLUGIN(wavparse)
 385 AG_GST_CHECK_PLUGIN(y4m)
 386
 387 dnl disable experimental plug-ins
 388 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 389   AG_GST_DISABLE_PLUGIN(monoscope)
 390 fi
 391
 392 dnl *** sys plug-ins ***
 393
 394 echo
 395 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 396 echo
 397
 398 dnl DirectSound
 399 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 400 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 401   HAVE_DIRECTSOUND="no"
 402   save_CFLAGS="$CFLAGS"
 403   save_LDFLAGS="$LDFLAGS"
 404   save_LIBS="$LIBS"
 405   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 406   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 407   LIBS="$LIBS -ldsound -ldxerr9 -luser32 -lole32"
 408   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 409   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 410 #include <windows.h>
 411 #include <dxerr9.h>
 412 #include <dsound.h>
 413 ]], [[
 414   DXGetErrorString9 (0);
 415   DirectSoundCreate(NULL, NULL, NULL);
 416   CLSIDFromString(NULL, NULL);
 417 ]])
 418 ],
 419     [HAVE_DIRECTSOUND="yes"],
 420     [HAVE_DIRECTSOUND="no"])
 421   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 422   CFLAGS=$save_CFLAGS
 423   LDFLAGS=$save_LDFLAGS
 424   LIBS=$save_LIBS
 425
 426   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 427     dnl this is much more than we want
 428     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32 -lole32"
 429     AC_SUBST(DIRECTSOUND_CFLAGS)
 430     AC_SUBST(DIRECTSOUND_LDFLAGS)
 431     AC_SUBST(DIRECTSOUND_LIBS)
 432   fi
 433   AC_SUBST(HAVE_DIRECTSOUND)
 434 ])
 435
 436 dnl *** Win32 WaveOut ***
 437 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 438 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 439   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 440 ])
 441
 442 dnl *** OSS audio *** (Linux, *BSD)
 443 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 444 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 445  HAVE_OSS="yes"
 446 dnl Linux and newer BSD versions :
 447  AC_CHECK_HEADER(sys/soundcard.h, [
 448    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 449    ] , [
 450 dnl Some old BSD versions and also newer OpenBSD versions :
 451    AC_CHECK_HEADER(soundcard.h, [
 452      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 453      ], [
 454   dnl Some old BSD versions :
 455      AC_CHECK_HEADER(machine/soundcard.h, [
 456        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 457          [Define if OSS includes are in /machine/])
 458        ], [
 459        HAVE_OSS="no"
 460      ])
 461    ])
 462  ])
 463 ])
 464
 465 dnl *** oss4 ***
 466 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 467 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 468   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 469   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 470       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 471       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 472 ])
 473
 474 dnl *** Sun Audio ***
 475 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 476 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 477   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 478 ])
 479
 480 dnl *** OSX Audio ***
 481 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 482 HAVE_IOS="no"
 483 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 484   AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 485     [HAVE_OSX_AUDIO="yes"],
 486     [AC_CHECK_HEADER(CoreAudio/CoreAudioTypes.h,
 487     [
 488       HAVE_OSX_AUDIO="yes"
 489       HAVE_IOS="yes"
 490     ], [
 491       HAVE_OSX_AUDIO="no"
 492       HAVE_IOS="no"
 493     ])]
 494   )
 495 ])
 496 if test "x$HAVE_IOS" = "xyes"; then
 497   AC_DEFINE(HAVE_IOS, 1, [building for iOS platofrm])
 498 fi
 499 AM_CONDITIONAL(HAVE_IOS, test "x$HAVE_IOS" = "xyes")
 500
 501 dnl *** OS X video ***
 502 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 503 HAVE_OSX_VIDEO="no"
 504 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 505   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 506
 507   dnl in case header OpenGL/gl.h is found on other platforms (or older, unsupported OS X)
 508   dnl also require Snow Leopard or newer
 509
 510   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 511         #include <AvailabilityMacros.h>
 512         #if MAC_OS_X_VERSION_MIN_REQUIRED < 1060
 513         #error Too old OSX version
 514         #endif
 515       ]], [[return 0;]])],[HAVE_OSX_VIDEO="yes"],[HAVE_OSX_VIDEO="no"])
 516 ])
 517
 518 dnl *** Video 4 Linux 2 ***
 519 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 520 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 521 HAVE_GST_V4L2=no
 522 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], video4linux2, [
 523   AC_MSG_CHECKING([Checking for video4linux2 header ...])
 524   AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_GST_V4L2=yes ],
 525   [
 526     AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_GST_V4L2=yes ],
 527     [
 528       AC_CHECK_HEADER(sys/videoio.h, [ HAVE_GST_V4L2=yes ])
 529     ])
 530   ])
 531   if test "x$HAVE_VIDEODEV" = "xno"; then
 532      AC_MSG_WARN([video4linux2 was not found])
 533   fi
 534 ])
 535
 536 # Optional gudev for device probing
 537 AC_ARG_WITH([gudev],
 538   AS_HELP_STRING([--with-gudev],[device detection with gudev]),
 539   [],
 540   [with_gudev=check])
 541 if test x$HAVE_GST_V4L2 = xyes; then
 542   if test x$with_gudev != xno; then
 543     PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 147 ],
 544       [ AC_DEFINE(HAVE_GUDEV, 1,
 545           [Whether gudev is available for device detection])
 546       ],
 547       [true])
 548   fi
 549 fi
 550
 551 AC_SUBST(GUDEV_CFLAGS)
 552 AC_SUBST(GUDEV_LIBS)
 553
 554 # Make libv4l2 non-automagic
 555 AC_ARG_WITH([libv4l2],
 556   AS_HELP_STRING([--with-libv4l2],[support video buffer conversion using libv4l2]),
 557   [],
 558   [with_libv4l2=check])
 559 if test x$HAVE_GST_V4L2 = xyes; then
 560   if test x$with_libv4l2 != xno; then
 561       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 562           [ have_libv4l2=yes
 563             AC_DEFINE(HAVE_LIBV4L2, 1,
 564                 [Whether libv4l2 is available for video buffer conversion])
 565           ], [
 566           have_libv4l2=no
 567           ])
 568   else
 569     have_libv4l2=no
 570   fi
 571 fi
 572
 573 dnl Allow enabling v4l2 device probing
 574 AC_ARG_ENABLE(
 575   v4l2-probe,
 576   AC_HELP_STRING(
 577     [--enable-v4l2-probe],
 578     [enable V4L2 plugin to probe devices @<:@default=no@:>@]))
 579 if test "x$enable_v4l2_probe" = xyes; then
 580   AC_DEFINE(GST_V4L2_ENABLE_PROBE, 1,
 581     [Define if Video4Linux probe shall be run at plugin load])
 582 fi
 583
 584 dnl Check for X11
 585 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 586 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 587                   [ximagesrc], [
 588   PKG_CHECK_MODULES([X], [x11], [
 589     HAVE_X="yes"
 590     dnl check for Xfixes
 591     PKG_CHECK_MODULES([XFIXES], [ xfixes ], [
 592       AC_DEFINE(HAVE_XFIXES, 1, [Defined if Xfixes is available])
 593     ], [ HAVE_XFIXES="no" ])
 594
 595     dnl check for Xdamage
 596     PKG_CHECK_MODULES([XDAMAGE], [ xdamage ], [
 597       AC_DEFINE(HAVE_XDAMAGE, 1, [Defined if Xdamage is available])
 598     ], [ HAVE_XDAMAGE="no" ])
 599
 600     dnl check for X Shm
 601     PKG_CHECK_MODULES([XEXT], [ xext ], [
 602       AC_CHECK_LIB([Xext], [ XShmAttach ], [
 603         AC_DEFINE(HAVE_XSHM, 1, [Defined if XShm is available])
 604         XSHM_LIBS="$XEXT_LIBS"
 605         XSHM_CFLAGS="$XEXT_CFLAGS"
 606       ], [ HAVE_XEXT="no" ] , [ $X_LIBS ])
 607     ])
 608     AC_SUBST(XSHM_LIBS)
 609     AC_SUBST(XSHM_CFLAGS)
 610   ], [ HAVE_X="no" ])
 611 ])
 612
 613 dnl *** ext plug-ins ***
 614 dnl keep this list sorted alphabetically !
 615
 616 if test "x$BUILD_EXTERNAL" = "xyes"; then
 617
 618 echo
 619 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 620 echo
 621
 622 dnl *** aalib ***
 623 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 624 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 625   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 626 ])
 627
 628 dnl *** cairo ***
 629 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 630 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering and gobject bindings], cairo, [
 631   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.10.0 cairo-gobject >= 1.10.0)
 632 ])
 633
 634 dnl *** FLAC ***
 635 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 636 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 637   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 638 ])
 639
 640 dnl *** GDK pixbuf ***
 641 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 642 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 643   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 644 ])
 645
 646 dnl *** Jack ***
 647 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 648 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 649   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 650   AC_SUBST(JACK_CFLAGS)
 651   AC_SUBST(JACK_LIBS)
 652
 653   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 654   if test x$HAVE_JACK_0_120_1 = xyes; then
 655     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 656   fi
 657   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 658   if test x$HAVE_JACK_1_9_7 = xyes; then
 659     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 660   fi
 661
 662 ])
 663
 664 dnl *** jpeg ***
 665 dnl FIXME: we could use header checks here as well IMO
 666 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 667 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 668   AC_ARG_WITH(jpeg-mmx,
 669     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 670   OLD_LIBS="$LIBS"
 671   if test x$with_jpeg_mmx != x; then
 672     LIBS="$LIBS -L$with_jpeg_mmx"
 673   fi
 674   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 675   JPEG_LIBS="$LIBS -ljpeg-mmx"
 676   LIBS="$OLD_LIBS"
 677   if test x$HAVE_JPEG != xyes; then
 678     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 679     JPEG_LIBS="-ljpeg"
 680   fi
 681   AC_SUBST(JPEG_LIBS)
 682 ])
 683
 684 dnl *** libcaca ***
 685 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 686 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 687   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 688 ])
 689
 690 dnl *** libdv ***
 691 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 692 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 693   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 694 ])
 695
 696 dnl *** libpng ***
 697 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 698 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 699   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 700 ])
 701
 702 dnl *** pulseaudio ***
 703 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 704 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 705
 706   dnl used in ext/pulse/pulseutil.c
 707   AC_CHECK_HEADERS([process.h])
 708
 709   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 2.0)
 710 ])
 711
 712 dnl *** dv1394 ***
 713 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 714 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 715   dnl first test for libraw1394 >= 2.0.0
 716   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 717   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 718   dnl now see how far we got
 719   if test x$HAVE_RAW1394 = xyes && \
 720      test x$HAVE_LIBIEC61883 = xyes; then
 721        AG_GST_CHECK_LIBHEADER(AVC1394,
 722         avc1394, avc1394_send_command, $RAW1394_LIBS,
 723         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 724        AG_GST_CHECK_LIBHEADER(ROM1394,
 725         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 726         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 727        if test x$HAVE_AVC1394 = xyes && \
 728           test x$HAVE_AVC1394 = xyes && \
 729           test x$HAVE_ROM1394 = xyes; then
 730           HAVE_DV1394=yes
 731           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 732           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 733           AC_SUBST(DV1394_CFLAGS)
 734           AC_SUBST(DV1394_LIBS)
 735         fi
 736   else
 737        if test x$HAVE_RAW1394 = xno; then
 738           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 739           AG_GST_CHECK_LIBHEADER(AVC1394,
 740            avc1394, avc1394_send_command, $RAW1394_LIBS,
 741            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 742           AG_GST_CHECK_LIBHEADER(ROM1394,
 743            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 744            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 745           if test x$HAVE_RAW1394 = xyes && \
 746              test x$HAVE_AVC1394 = xyes && \
 747              test x$HAVE_ROM1394 = xyes; then
 748              HAVE_DV1394=yes
 749              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 750              DV1394_CFLAGS="$RAW1394_CFLAGS"
 751              if test x$HAVE_LIBIEC61883 = xyes; then
 752                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 753                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 754              fi
 755              AC_SUBST(DV1394_CFLAGS)
 756              AC_SUBST(DV1394_LIBS)
 757            fi
 758          fi
 759   fi
 760 ])
 761 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 762
 763 dnl *** shout2 ***
 764 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 765 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 766   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 767 ])
 768
 769 dnl *** soup ***
 770 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 771 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 772   PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.48, [HAVE_SOUP="yes"], [HAVE_SOUP="no"])
 773   AC_SUBST(SOUP_CFLAGS)
 774   AC_SUBST(SOUP_LIBS)
 775 ])
 776
 777 dnl *** speex ***
 778 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 779 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 780   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 781 ])
 782
 783 dnl *** taglib ***
 784 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 785 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 786   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 787   if test "x$HAVE_CXX" != "xyes"; then
 788     USE_TAGLIB=false
 789     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 790   else
 791     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 792     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 793         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 794       ], [
 795         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 796     ])
 797     AC_SUBST(TAGLIB_CXXFLAGS)
 798   fi
 799 ])
 800
 801 dnl *** vpx ***
 802 translit(dnm, m, l) AM_CONDITIONAL(USE_VPX, vpx)
 803 AG_GST_CHECK_FEATURE(VPX, [VPX decoder], vpx, [
 804   PKG_CHECK_MODULES(VPX, vpx >= 1.1.0, [HAVE_VPX="yes"], [HAVE_VPX="no"])
 805   HAVE_VP8=no
 806   HAVE_VP9=no
 807
 808   if test $HAVE_VPX = "yes"; then
 809     OLD_LIBS="$LIBS"
 810     OLD_CFLAGS="$CFLAGS"
 811     CFLAGS="$CFLAGS $VPX_CFLAGS"
 812     LIBS="$LIBS $VPX_LIBS"
 813     AC_CHECK_LIB(vpx, vpx_codec_vp8_cx_algo, [
 814       HAVE_VP8=yes
 815       AC_DEFINE(HAVE_VP8_ENCODER, 1, [Defined if the VP8 encoder is available])
 816     ])
 817     AC_CHECK_LIB(vpx, vpx_codec_vp8_dx_algo, [
 818       HAVE_VP8=yes
 819       AC_DEFINE(HAVE_VP8_DECODER, 1, [Defined if the VP8 decoder is available])
 820     ])
 821
 822     PKG_CHECK_MODULES(VPX_130, vpx >= 1.3.0, [
 823       AC_CHECK_LIB(vpx, vpx_codec_vp9_cx_algo, [
 824         HAVE_VP9=yes
 825         AC_DEFINE(HAVE_VP9_ENCODER, 1, [Defined if the VP9 encoder is available])
 826       ])
 827       AC_CHECK_LIB(vpx, vpx_codec_vp9_dx_algo, [
 828         HAVE_VP9=yes
 829         AC_DEFINE(HAVE_VP9_DECODER, 1, [Defined if the VP9 decoder is available])
 830       ])
 831     ], [true])
 832
 833     PKG_CHECK_MODULES(VPX_140, vpx >= 1.4.0, [
 834       AC_DEFINE(HAVE_VPX_1_4, 1, [Defined if the VPX library version is 1.4 or bigger])
 835     ], [true])
 836
 837     LIBS="$OLD_LIBS"
 838     CFLAGS="$OLD_CFLAGS"
 839   fi
 840   AC_SUBST(VPX_LIBS)
 841   AC_SUBST(VPX_CFLAGS)
 842 ])
 843
 844 dnl *** wavpack ***
 845 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 846 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 847   AG_GST_PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.60.0)
 848 ])
 849
 850 dnl *** qtdemux & matroska prefer to have zlib ***
 851 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 852 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 853   AG_GST_CHECK_LIBHEADER(ZLIB,
 854     z, uncompress,, zlib.h, [
 855     HAVE_ZLIB="yes"
 856     ZLIB_LIBS="-lz"
 857     AC_SUBST(ZLIB_LIBS)
 858   ])
 859 ])
 860
 861 dnl *** matroska prefers to have bz2 ***
 862 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 863 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 864   save_LIBS=$LIBS
 865   LIBS="$LIBS -lbz2"
 866   AC_MSG_CHECKING([for BZ2_bzlibVersion in -lbz2])
 867   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <bzlib.h>]], [[const char *version = BZ2_bzlibVersion ();]])],[HAVE_BZ2=yes],[HAVE_BZ2=no])
 868   AC_MSG_RESULT($HAVE_BZ2)
 869   LIBS=$save_LIBS
 870   if test "x$HAVE_BZ2" = "xyes"; then
 871     BZ2_LIBS="-lbz2"
 872   fi
 873   AC_SUBST(BZ2_LIBS)
 874 ])
 875
 876 else
 877
 878 dnl not building plugins with external dependencies,
 879 dnl but we still need to set the conditionals
 880 AM_CONDITIONAL(USE_AALIB, false)
 881 AM_CONDITIONAL(USE_BZ2, false)
 882 AM_CONDITIONAL(USE_CAIRO, false)
 883 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 884 AM_CONDITIONAL(USE_DV1394, false)
 885 AM_CONDITIONAL(USE_FLAC, false)
 886 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 887 AM_CONDITIONAL(USE_JACK, false)
 888 AM_CONDITIONAL(USE_JPEG, false)
 889 AM_CONDITIONAL(USE_LIBCACA, false)
 890 AM_CONDITIONAL(USE_LIBDV, false)
 891 AM_CONDITIONAL(USE_LIBIEC61883, false)
 892 AM_CONDITIONAL(USE_LIBPNG, false)
 893 AM_CONDITIONAL(USE_OSS, false)
 894 AM_CONDITIONAL(USE_OSS4, false)
 895 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 896 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 897 AM_CONDITIONAL(USE_PULSE, false)
 898 AM_CONDITIONAL(USE_SHOUT2, false)
 899 AM_CONDITIONAL(USE_SOUP, false)
 900 AM_CONDITIONAL(USE_SPEEX, false)
 901 AM_CONDITIONAL(USE_SUNAUDIO, false)
 902 AM_CONDITIONAL(USE_TAGLIB, false)
 903 AM_CONDITIONAL(USE_VPX, false)
 904 AM_CONDITIONAL(USE_WAVEFORM, false)
 905 AM_CONDITIONAL(USE_WAVPACK, false)
 906 AM_CONDITIONAL(USE_X, false)
 907 AM_CONDITIONAL(USE_ZLIB, false)
 908
 909 fi dnl of EXT plugins
 910
 911 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 912
 913 dnl Overview:
 914 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 915 dnl GST_*:              flags shared by all built objects
 916 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 917 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 918 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 919 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 920
 921 dnl GST_OPTION_CFLAGS
 922 if test "x$USE_DEBUG" = xyes; then
 923    PROFILE_CFLAGS="-g"
 924 fi
 925 AC_SUBST(PROFILE_CFLAGS)
 926
 927 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 928   dnl Define _only_ for git (not pre-releases or releases)
 929   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 930 else
 931   DEPRECATED_CFLAGS=""
 932 fi
 933 AC_SUBST(DEPRECATED_CFLAGS)
 934
 935 dnl every flag in GST_OPTION_CFLAGS, GST_OPTION_CXXFLAGS and GST_OPTION_OBJCFLAGS can be overridden
 936 dnl at make time with e.g. make ERROR_CFLAGS=""
 937 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 938 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 939 GST_OPTION_OBJCFLAGS="\$(WARNING_OBJCFLAGS) \$(ERROR_OBJCFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 940 AC_SUBST(GST_OPTION_CFLAGS)
 941 AC_SUBST(GST_OPTION_CXXFLAGS)
 942 AC_SUBST(GST_OPTION_OBJCFLAGS)
 943
 944 dnl our libraries need to be versioned correctly
 945 AC_SUBST(GST_LT_LDFLAGS)
 946
 947 dnl FIXME: do we want to rename to GST_ALL_* ?
 948 dnl prefer internal headers to already installed ones
 949 dnl also add builddir include for enumtypes and marshal
 950 dnl add ERROR_CFLAGS, but overridable
 951 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
 952 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 953 GST_OBJCFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_OBJCFLAGS)"
 954 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 955 AC_SUBST(GST_CFLAGS)
 956 AC_SUBST(GST_CXXFLAGS)
 957 AC_SUBST(GST_OBJCFLAGS)
 958 AC_SUBST(GST_LIBS)
 959
 960 dnl LDFLAGS really should only contain flags, not libs - they get added before
 961 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 962 GST_ALL_LDFLAGS="-no-undefined"
 963 if test "x${enable_Bsymbolic}" = "xyes"; then
 964   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 965 fi
 966 AC_SUBST(GST_ALL_LDFLAGS)
 967
 968 dnl this really should only contain flags, not libs - they get added before
 969 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 970 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 971 AC_SUBST(GST_PLUGIN_LDFLAGS)
 972
 973 dnl *** output files ***
 974
 975 $MKDIR_P tests/check/orc
 976
 977 dnl keep this alphabetic per directory, please
 978 AC_CONFIG_FILES(
 979 Makefile
 980 gst/Makefile
 981 gst/alpha/Makefile
 982 gst/apetag/Makefile
 983 gst/audiofx/Makefile
 984 gst/audioparsers/Makefile
 985 gst/auparse/Makefile
 986 gst/autodetect/Makefile
 987 gst/avi/Makefile
 988 gst/cutter/Makefile
 989 gst/deinterlace/Makefile
 990 gst/dtmf/Makefile
 991 gst/debugutils/Makefile
 992 gst/effectv/Makefile
 993 gst/equalizer/Makefile
 994 gst/flv/Makefile
 995 gst/goom/Makefile
 996 gst/goom2k1/Makefile
 997 gst/id3demux/Makefile
 998 gst/icydemux/Makefile
 999 gst/imagefreeze/Makefile
1000 gst/interleave/Makefile
1001 gst/isomp4/Makefile
1002 gst/law/Makefile
1003 gst/level/Makefile
1004 gst/matroska/Makefile
1005 gst/monoscope/Makefile
1006 gst/multifile/Makefile
1007 gst/multipart/Makefile
1008 gst/replaygain/Makefile
1009 gst/rtp/Makefile
1010 gst/rtpmanager/Makefile
1011 gst/rtsp/Makefile
1012 gst/shapewipe/Makefile
1013 gst/smpte/Makefile
1014 gst/spectrum/Makefile
1015 gst/udp/Makefile
1016 gst/videobox/Makefile
1017 gst/videocrop/Makefile
1018 gst/videofilter/Makefile
1019 gst/videomixer/Makefile
1020 gst/wavenc/Makefile
1021 gst/wavparse/Makefile
1022 gst/flx/Makefile
1023 gst/y4m/Makefile
1024 ext/Makefile
1025 ext/aalib/Makefile
1026 ext/cairo/Makefile
1027 ext/dv/Makefile
1028 ext/flac/Makefile
1029 ext/gdk_pixbuf/Makefile
1030 ext/jack/Makefile
1031 ext/jpeg/Makefile
1032 ext/libcaca/Makefile
1033 ext/libpng/Makefile
1034 ext/pulse/Makefile
1035 ext/raw1394/Makefile
1036 ext/shout2/Makefile
1037 ext/soup/Makefile
1038 ext/speex/Makefile
1039 ext/taglib/Makefile
1040 ext/vpx/Makefile
1041 ext/wavpack/Makefile
1042 sys/Makefile
1043 sys/directsound/Makefile
1044 sys/oss/Makefile
1045 sys/oss4/Makefile
1046 sys/osxaudio/Makefile
1047 sys/osxvideo/Makefile
1048 sys/sunaudio/Makefile
1049 sys/v4l2/Makefile
1050 sys/waveform/Makefile
1051 sys/ximage/Makefile
1052 po/Makefile.in
1053 tests/Makefile
1054 tests/check/Makefile
1055 tests/examples/Makefile
1056 tests/examples/audiofx/Makefile
1057 tests/examples/cairo/Makefile
1058 tests/examples/equalizer/Makefile
1059 tests/examples/jack/Makefile
1060 tests/examples/level/Makefile
1061 tests/examples/pulse/Makefile
1062 tests/examples/rtp/Makefile
1063 tests/examples/shapewipe/Makefile
1064 tests/examples/spectrum/Makefile
1065 tests/examples/v4l2/Makefile
1066 tests/files/Makefile
1067 tests/icles/Makefile
1068 common/Makefile
1069 common/m4/Makefile
1070 m4/Makefile
1071 docs/Makefile
1072 docs/plugins/Makefile
1073 docs/version.entities
1074 pkgconfig/Makefile
1075 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1076 gst-plugins-good.spec
1077 )
1078
1079 dnl Create the config.h file for Visual Studio builds
1080 dnl Beware of spaces and /'s in some of the shell variable contents.
1081 sed \
1082     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1083     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1084     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1085     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1086     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1087     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
1088     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1089     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1090     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1091     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1092     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1093     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1094     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1095     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1096     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1097     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1098     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1099     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1100     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1101     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1102     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1103     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1104     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1105     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1106     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1107     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1108     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1109     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1110     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1111     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1112     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1113     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1114     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1115     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1116     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1117     config.h.in >win32/common/config.h-new
1118
1119 AC_OUTPUT
1120
1121 AG_GST_OUTPUT_PLUGINS
1122 ORC_OUTPUT
1123