configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [35])
  34 m4_define([glib_micro_version], [2])
  35 m4_define([glib_interface_age], [0])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  58
  59 AC_CONFIG_HEADER([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS+set}
  65
  66 AM_INIT_AUTOMAKE([1.11 no-define no-dist-gzip dist-xz tar-ustar])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114
 115 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 116
 117 AC_CANONICAL_HOST
 118
 119 AC_MSG_CHECKING([for the BeOS])
 120 case $host in
 121   *-*-beos*)
 122     glib_native_beos="yes"
 123     ;;
 124   *)
 125     glib_native_beos="no"
 126     ;;
 127 esac
 128 AC_MSG_RESULT([$glib_native_beos])
 129
 130 dnl
 131
 132 AC_MSG_CHECKING([for Win32])
 133 LIB_EXE_MACHINE_FLAG=X86
 134 case "$host" in
 135   *-*-mingw*)
 136     glib_native_win32=yes
 137     glib_pid_type='void *'
 138     glib_cv_stack_grows=no
 139     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 140     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 141     # (Sorry, I don't know exactly what is the problem, but it is related to
 142     # floating point formatting and decimal point vs. comma.)
 143     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 144     # rigorous enough to notice, though.
 145     # So preset the autoconf cache variables.
 146     ac_cv_func_vsnprintf_c99=no
 147     ac_cv_func_snprintf_c99=no
 148     case "$host" in
 149     x86_64-*-*)
 150       LIB_EXE_MACHINE_FLAG=X64
 151       ;;
 152     esac
 153     ;;
 154   *)
 155     glib_native_win32=no
 156     glib_pid_type=int
 157     ;;
 158 esac
 159 case $host in
 160   *-*-linux*)
 161     glib_os_linux=yes
 162     ;;
 163 esac
 164
 165 AC_MSG_RESULT([$glib_native_win32])
 166
 167 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 168
 169 glib_have_carbon=no
 170 AC_MSG_CHECKING([for Mac OS X Carbon support])
 171 AC_TRY_CPP([
 172 #include <Carbon/Carbon.h>
 173 #include <CoreServices/CoreServices.h>
 174 ], glib_have_carbon=yes)
 175
 176 AC_MSG_RESULT([$glib_have_carbon])
 177
 178 glib_have_cocoa=no
 179 AC_MSG_CHECKING([for Mac OS X Cocoa support])
 180 AC_TRY_CPP([
 181 #include <Cocoa/Cocoa.h>
 182 #ifdef GNUSTEP_BASE_VERSION
 183 #error "Detected GNUstep, not Cocoa"
 184 #endif
 185 ], glib_have_cocoa=yes)
 186
 187 AC_MSG_RESULT([$glib_have_cocoa])
 188
 189 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 190 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 191 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 192 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 193 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 194 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
 195
 196 AS_IF([test "$glib_native_win32" = "yes"], [
 197   AC_CHECK_TOOL(WINDRES, windres, no)
 198   if test "$WINDRES" = no; then
 199     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 200   fi
 201   AC_CHECK_TOOL(NM, nm, no)
 202   if test "$NM" = no; then
 203     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 204   fi
 205   AC_CHECK_TOOL(RANLIB, ranlib, :)
 206   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 207 ])
 208 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 209
 210 if test "$glib_native_win32" != yes; then
 211     # libtool option to control which symbols are exported
 212     # right now, symbols starting with _ are not exported
 213     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 214 else
 215     # We currently use .def files on Windows
 216     LIBTOOL_EXPORT_OPTIONS=
 217 fi
 218 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 219
 220 AS_IF([test "x$glib_have_carbon" = "xyes"], [
 221   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 222   LDFLAGS="$LDFLAGS -Wl,-framework,Carbon"
 223 ])
 224
 225 if test "x$glib_have_cocoa" = "xyes"; then
 226   AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
 227   LDFLAGS="$LDFLAGS -Wl,-framework,Foundation"
 228 fi
 229
 230 gl_GLIBC21
 231 AS_IF([test "x$GLIBC21" = "xyes"], [
 232   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 233 ])
 234
 235 dnl declare --enable-* args and collect ac_help strings
 236 AC_ARG_ENABLE(debug,
 237               AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 238                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 239               enable_debug=glib_debug_default)
 240
 241 AC_ARG_ENABLE(gc_friendly,
 242               [AS_HELP_STRING([--enable-gc-friendly],
 243                               [turn on garbage collector friendliness [default=no]])],,
 244               [enable_gc_friendly=no])
 245 AC_ARG_ENABLE(mem_pools,
 246               [AS_HELP_STRING([--disable-mem-pools],
 247                               [disable all glib memory pools])],,
 248               [disable_mem_pools=no])
 249 AC_ARG_ENABLE(rebuilds,
 250               [AS_HELP_STRING([--disable-rebuilds],
 251                               [disable all source autogeneration rules])],,
 252               [enable_rebuilds=yes])
 253 AC_ARG_ENABLE(modular_tests,
 254               AS_HELP_STRING([--disable-modular-tests],
 255                              [Disable build of test programs (default: no)]),,
 256               [enable_modular_tests=yes])
 257 AM_CONDITIONAL(BUILD_MODULAR_TESTS, test x$enable_modular_tests = xyes)
 258
 259 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 260 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
 261   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 262   AC_MSG_RESULT([yes])
 263 ], [ AC_MSG_RESULT([no]) ])
 264
 265 AC_MSG_CHECKING([whether to disable memory pools])
 266 AS_IF([test "x$disable_mem_pools" = "xno"], [
 267   AC_MSG_RESULT([no])
 268 ], [
 269   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 270   AC_MSG_RESULT([yes])
 271 ])
 272
 273 dnl location to install runtime libraries, e.g. ../../lib to install
 274 dnl to /lib if libdir is /usr/lib
 275 AC_ARG_WITH(runtime-libdir,
 276            [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
 277                            [install runtime libraries relative to libdir])],
 278            [],
 279            [with_runtime_libdir=""])
 280 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 281 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 282 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 283 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 284 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 285
 286 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 287 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 288 AC_LANG_SAVE
 289 AC_LANG_CPLUSPLUS
 290 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 291 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 292 AC_LANG_RESTORE
 293
 294 AM_PROG_CC_STDC
 295 AM_PROG_CC_C_O
 296 AC_PROG_INSTALL
 297
 298 AC_SYS_LARGEFILE
 299
 300 PKG_PROG_PKG_CONFIG(0.16)
 301
 302 if test "x$enable_debug" = "xyes"; then
 303   if test x$cflags_set != xset ; then
 304       case " $CFLAGS " in
 305       *[[\ \    ]]-g[[\ \       ]]*) ;;
 306       *) CFLAGS="$CFLAGS -g" ;;
 307       esac
 308   fi
 309   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 310 else
 311   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 312
 313   if test "x$enable_debug" = "xno"; then
 314     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 315   fi
 316 fi
 317
 318 # Ensure MSVC-compatible struct packing convention is used when
 319 # compiling for Win32 with gcc.
 320 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 321 # gcc2 uses "-fnative-struct".
 322 if test x"$glib_native_win32" = xyes; then
 323   if test x"$GCC" = xyes; then
 324     msnative_struct=''
 325     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 326     if test -z "$ac_cv_prog_CC"; then
 327       our_gcc="$CC"
 328     else
 329       our_gcc="$ac_cv_prog_CC"
 330     fi
 331     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 332       2.)
 333         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 334           msnative_struct='-fnative-struct'
 335         fi
 336         ;;
 337       *)
 338         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 339           msnative_struct='-mms-bitfields'
 340         fi
 341         ;;
 342     esac
 343     if test x"$msnative_struct" = x ; then
 344       AC_MSG_RESULT([no way])
 345       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 346     else
 347       CFLAGS="$CFLAGS $msnative_struct"
 348       AC_MSG_RESULT([${msnative_struct}])
 349     fi
 350   fi
 351 fi
 352 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 353 AC_SUBST(GLIB_EXTRA_CFLAGS)
 354
 355 AC_EXEEXT
 356
 357 # define a MAINT-like variable REBUILD which is set if Perl
 358 # and awk are found, so autogenerated sources can be rebuilt
 359 AC_PROG_AWK
 360 AC_CHECK_PROGS(PERL, [perl5 perl])
 361 # We would like indent, but don't require it.
 362 AC_CHECK_PROG(INDENT, indent, indent)
 363 REBUILD=\#
 364 if test "x$enable_rebuilds" = "xyes" && \
 365      test -n "$PERL" && \
 366      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 367      test -n "$AWK" ; then
 368   REBUILD=
 369 fi
 370 AC_SUBST(REBUILD)
 371
 372 # Need full path to Perl for glib-mkenums
 373 #
 374 if test "x$PERL" != x ; then
 375   AC_PATH_PROG(PERL_PATH, [$PERL])
 376 fi
 377 if test "x$PERL_PATH" = x ; then
 378   PERL_PATH="/usr/bin/env perl"
 379 fi
 380 AC_SUBST(PERL_PATH)
 381
 382 # Need suitable python path for greport
 383 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 384
 385
 386 dnl ***********************
 387 dnl *** Tests for iconv ***
 388 dnl ***********************
 389 dnl
 390 dnl We do this before the gettext checks, to avoid distortion
 391
 392 dnl On Windows we use a native implementation
 393
 394 AS_IF([ test x"$glib_native_win32" = xyes], [
 395   with_libiconv=native
 396 ], [
 397   AC_ARG_WITH(libiconv,
 398               [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 399                               [use the libiconv library])],,
 400               [with_libiconv=maybe])
 401
 402   found_iconv=no
 403   case $with_libiconv in
 404     maybe)
 405       # Check in the C library first
 406       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 407       # Check if we have GNU libiconv
 408       if test $found_iconv = "no"; then
 409         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 410       fi
 411       # Check if we have a iconv in -liconv, possibly from vendor
 412       if test $found_iconv = "no"; then
 413         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 414       fi
 415       ;;
 416     no)
 417       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 418       ;;
 419     gnu|yes)
 420       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 421       ;;
 422     native)
 423       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 424       ;;
 425   esac
 426
 427   if test "x$found_iconv" = "xno" ; then
 428      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 429   fi
 430 ])
 431
 432 AC_ARG_ENABLE(iconv-cache,
 433               [AS_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 434                               [cache iconv descriptors [default=auto]])],,
 435               [enable_iconv_cache=auto])
 436
 437 AC_MSG_CHECKING([whether to cache iconv descriptors])
 438 case $enable_iconv_cache in
 439   auto)
 440     if test $ac_cv_gnu_library_2_1 = yes; then
 441       enable_iconv_cache=no
 442     else
 443       enable_iconv_cache=yes
 444     fi
 445   ;;
 446   yes|no)
 447   ;;
 448   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 449   ;;
 450 esac
 451
 452 if test $enable_iconv_cache = yes; then
 453    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 454 fi
 455
 456 AC_MSG_RESULT($enable_iconv_cache)
 457
 458
 459 dnl
 460 dnl zlib support
 461 dnl
 462 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 463 AS_IF([test "x$found_zlib" = "xno"], [
 464   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 465   if test "x$found_zlib" = "xno" ; then
 466     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 467   fi
 468   ZLIB_LIBS='-lz'
 469   AC_SUBST(ZLIB_LIBS)
 470 ])
 471
 472 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 473 AC_SUBST(LIBFFI_CFLAGS)
 474 AC_SUBST(LIBFFI_LIBS)
 475
 476 dnl
 477 dnl gettext support
 478 dnl
 479
 480 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 481 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 482 GLIB_GNU_GETTEXT
 483
 484 if test "$gt_cv_have_gettext" != "yes" ; then
 485   AC_MSG_ERROR([
 486 *** You must have either have gettext support in your C library, or use the
 487 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 488 ])
 489 fi
 490
 491 LIBS="$INTLLIBS $LIBS"
 492
 493 GETTEXT_PACKAGE=glib20
 494 AC_SUBST(GETTEXT_PACKAGE)
 495 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 496   [Define the gettext package to be used])
 497
 498 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 499
 500 dnl
 501 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 502 dnl
 503
 504 AS_IF([test x"$glib_native_win32" != xyes], [
 505   if test x$with_libiconv != xno ; then
 506     case " $INTLLIBS " in
 507     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 508     *) ICONV_LIBS="-liconv" ;;
 509     esac
 510   fi
 511 ])
 512 AC_SUBST(ICONV_LIBS)
 513
 514 case $with_libiconv in
 515   gnu)
 516     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 517     ;;
 518   native)
 519     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 520     ;;
 521 esac
 522
 523 dnl Initialize libtool
 524 LT_PREREQ([2.2])
 525 LT_INIT([disable-static win32-dll])
 526 dnl when using libtool 2.x create libtool early, because it's used in configure
 527 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 528
 529
 530 AS_IF([test "$glib_native_win32" = "yes"], [
 531   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 532     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 533   fi
 534   if test x$enable_static = xyes; then
 535     glib_win32_static_compilation=yes
 536     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 537 #define GOBJECT_STATIC_COMPILATION 1"
 538     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 539   fi
 540 ])
 541 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 542
 543 dnl
 544 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 545 dnl
 546 AS_IF([test $cross_compiling != yes], [
 547     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 548     glib_save_LIBS=$LIBS
 549     LIBS="$LIBS -lm"
 550     AC_TRY_RUN([#include <math.h>
 551                  int main (void) { return (log(1) != log(1.)); }],
 552          AC_MSG_RESULT(none needed),
 553          glib_save_CFLAGS=$CFLAGS
 554          CFLAGS="$CFLAGS -std1"
 555          AC_TRY_RUN([#include <math.h>
 556                      int main (void) { return (log(1) != log(1.)); }],
 557              AC_MSG_RESULT(-std1),
 558              AC_MSG_RESULT()
 559              CFLAGS=$glib_save_CFLAGS
 560              AC_MSG_WARN(
 561                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 562          )
 563     )
 564     LIBS=$glib_save_LIBS
 565 ])
 566
 567 dnl NeXTStep cc seems to need this
 568 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 569 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 570   AC_MSG_RESULT(none needed),
 571   glib_save_CFLAGS=$CFLAGS
 572   CFLAGS="$CFLAGS -posix"
 573   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 574     AC_MSG_RESULT(-posix),
 575     AC_MSG_RESULT()
 576     CFLAGS=$glib_save_CFLAGS
 577     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 578
 579 # Checks for library functions.
 580 AC_FUNC_VPRINTF
 581 AC_FUNC_ALLOCA
 582 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
 583 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 584
 585 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
 586   [AC_TRY_LINK([#include <unistd.h>
 587     extern int __libc_enable_secure;],
 588     [return __libc_enable_secure;],
 589    glib_cv_have_libc_enable_secure=yes,
 590    glib_cv_have_libc_enable_secure=no)])
 591 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
 592    AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
 593      [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
 594 ])
 595
 596 AC_CHECK_SIZEOF(char)
 597 AC_CHECK_SIZEOF(short)
 598 AC_CHECK_SIZEOF(long)
 599 AC_CHECK_SIZEOF(int)
 600 AC_CHECK_SIZEOF(void *)
 601 AC_CHECK_SIZEOF(long long)
 602 AC_CHECK_SIZEOF(__int64)
 603
 604 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
 605   [AC_TRY_LINK([#include <signal.h>
 606      #include <sys/types.h>
 607      sig_atomic_t val = 42;],
 608     [return val == 42 ? 0 : 1],
 609    ac_cv_type_sig_atomic_t=yes,
 610    ac_cv_type_sig_atomic_t=no)])
 611 if test x$ac_cv_type_sig_atomic_t = xyes; then
 612    AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
 613      [Define if you have the 'sig_atomic_t' type.])
 614 fi
 615
 616 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 617   :
 618 else
 619   AC_MSG_ERROR([
 620 *** GLib requires a 64 bit type. You might want to consider
 621 *** using the GNU C compiler.
 622 ])
 623 fi
 624
 625 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
 626         # long long is a 64 bit integer.
 627         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 628         AC_CACHE_VAL(glib_cv_long_long_format,[
 629                 for format in ll q I64; do
 630                   AC_TRY_RUN([#include <stdio.h>
 631                         int main()
 632                         {
 633                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 634                           char buffer[1000];
 635                           sprintf (buffer, "%${format}u", a);
 636                           sscanf (buffer, "%${format}u", &b);
 637                           exit (b!=a);
 638                         }
 639                         ],
 640                         [glib_cv_long_long_format=${format}
 641                         break],
 642                         [],[:])
 643                 done])
 644         AS_IF([ test -n "$glib_cv_long_long_format"], [
 645           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 646           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 647           if test x"$glib_cv_long_long_format" = xI64; then
 648             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 649           fi
 650         ], [AC_MSG_RESULT(none)])
 651 ],[ test x$ac_cv_sizeof___int64 = x8], [
 652         # __int64 is a 64 bit integer.
 653         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 654         # We know this is MSVCRT.DLL, and what the formats are
 655         glib_cv_long_long_format=I64
 656         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 657         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 658         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 659 ])
 660
 661 AC_C_CONST
 662
 663 dnl ok, here we try to check whether the systems prototypes for
 664 dnl malloc and friends actually match the prototypes provided
 665 dnl by gmem.h (keep in sync). i currently only know how to check
 666 dnl this reliably with gcc (-Werror), improvements for other
 667 dnl compilers are apprechiated.
 668 SANE_MALLOC_PROTOS=no
 669 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 670 glib_save_CFLAGS=$CFLAGS
 671 AS_IF([test "x$GCC" = "xyes"], [
 672   CFLAGS="$CFLAGS -Werror"
 673   AC_TRY_COMPILE([#include <stdlib.h>], [
 674     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 675     void* (*my_malloc_p)  (size_t)         = malloc;
 676     void  (*my_free_p)    (void*)          = free;
 677     void* (*my_realloc_p) (void*, size_t)  = realloc;
 678     my_calloc_p = 0;
 679     my_malloc_p = 0;
 680     my_free_p = 0;
 681     my_realloc_p = 0;
 682   ],
 683     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 684       [Define if you have correct malloc prototypes])
 685     SANE_MALLOC_PROTOS=yes)
 686 ])
 687 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 688 CFLAGS=$glib_save_CFLAGS
 689
 690 dnl
 691 dnl check in which direction the stack grows
 692 dnl
 693 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 694         AC_TRY_RUN([
 695         volatile int *a = 0, *b = 0;
 696         void foo (void);
 697         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 698         void foo (void) { volatile int x = 5; b = &x; }
 699         ],
 700         glib_cv_stack_grows=no
 701         ,
 702         glib_cv_stack_grows=yes
 703         ,)
 704 ])
 705
 706 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 707 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 708 dnl actually supported.
 709 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 710         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 711         __inline int foo () { return 0; }
 712         int main () { return foo (); }
 713         ]])],
 714         glib_cv_has__inline=yes
 715         ,
 716         glib_cv_has__inline=no
 717         ,)
 718 ])
 719 case x$glib_cv_has__inline in
 720 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 721 esac
 722 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 723         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 724         __inline__ int foo () { return 0; }
 725         int main () { return foo (); }
 726         ]])],
 727         glib_cv_has__inline__=yes
 728         ,
 729         glib_cv_has__inline__=no
 730         ,)
 731 ])
 732 case x$glib_cv_has__inline__ in
 733 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 734 esac
 735 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 736         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 737         #undef inline
 738         inline int foo () { return 0; }
 739         int main () { return foo (); }
 740         ]])],
 741         glib_cv_hasinline=yes
 742         ,
 743         glib_cv_hasinline=no
 744         ,)
 745 ])
 746 case x$glib_cv_hasinline in
 747 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 748 esac
 749
 750 # if we can use inline functions in headers
 751 AC_MSG_CHECKING(if inline functions in headers work)
 752 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 753 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 754 #  undef inline
 755 #  define inline __inline__
 756 #elif !defined (G_HAVE_INLINE)
 757 #  undef inline
 758 #  if defined (G_HAVE___INLINE__)
 759 #    define inline __inline__
 760 #  elif defined (G_HAVE___INLINE)
 761 #    define inline __inline
 762 #  endif
 763 #endif
 764
 765 int glib_test_func2 (int);
 766
 767 static inline int
 768 glib_test_func1 (void) {
 769   return glib_test_func2 (1);
 770 }
 771
 772 int
 773 main (void) {
 774   int i = 1;
 775 }]])],[g_can_inline=yes],[g_can_inline=no])
 776 AC_MSG_RESULT($g_can_inline)
 777
 778 dnl *** check for working do while(0) macros ***
 779 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 780         AC_TRY_COMPILE([],[
 781         #define STMT_START do
 782         #define STMT_END while(0)
 783         #define STMT_TEST STMT_START { i = 0; } STMT_END
 784         int main(void) { int i = 1; STMT_TEST; return i; }],
 785         [g_cv_support_dowhile_macros=yes],
 786         [g_cv_support_dowhile_macros=no],
 787         [g_cv_support_dowhile_macros=yes])
 788 ])
 789 if test x$g_cv_support_dowhile_macros = xyes; then
 790   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 791 fi
 792
 793 # check for flavours of varargs macros
 794 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 795 AC_TRY_COMPILE([],[
 796 int a(int p1, int p2, int p3);
 797 #define call_a(...) a(1,__VA_ARGS__)
 798 call_a(2,3);
 799 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 800 AC_MSG_RESULT($g_have_iso_c_varargs)
 801
 802 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 803 AS_IF([test "$CXX" = ""], [
 804 dnl No C++ compiler
 805   g_have_iso_cxx_varargs=no
 806 else
 807   AC_LANG_CPLUSPLUS
 808   AC_TRY_COMPILE([],[
 809 int a(int p1, int p2, int p3);
 810 #define call_a(...) a(1,__VA_ARGS__)
 811 call_a(2,3);
 812 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 813   AC_LANG_C
 814 ])
 815 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 816
 817 AC_MSG_CHECKING(for GNUC varargs macros)
 818 AC_TRY_COMPILE([],[
 819 int a(int p1, int p2, int p3);
 820 #define call_a(params...) a(1,params)
 821 call_a(2,3);
 822 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 823 AC_MSG_RESULT($g_have_gnuc_varargs)
 824
 825 # check for GNUC visibility support
 826 AC_MSG_CHECKING(for GNUC visibility attribute)
 827 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 828 void
 829 __attribute__ ((visibility ("hidden")))
 830      f_hidden (void)
 831 {
 832 }
 833 void
 834 __attribute__ ((visibility ("internal")))
 835      f_internal (void)
 836 {
 837 }
 838 void
 839 __attribute__ ((visibility ("protected")))
 840      f_protected (void)
 841 {
 842 }
 843 void
 844 __attribute__ ((visibility ("default")))
 845      f_default (void)
 846 {
 847 }
 848 int main (int argc, char **argv)
 849 {
 850         f_hidden();
 851         f_internal();
 852         f_protected();
 853         f_default();
 854         return 0;
 855 }
 856 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 857 AC_MSG_RESULT($g_have_gnuc_visibility)
 858 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 859
 860 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 861 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 862 #else
 863 # include "error: this is not Sun Studio."
 864 #endif
 865 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 866 AC_MSG_RESULT($g_have_sunstudio_visibility)
 867 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 868
 869 # check for bytesex stuff
 870 AC_C_BIGENDIAN
 871 if test x$ac_cv_c_bigendian = xuniversal ; then
 872 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 873 #else
 874 #error Not a big endian.
 875 #endif],
 876     ac_cv_c_bigendian=yes
 877     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 878 #else
 879 #error Not a little endian.
 880 #endif],
 881     ac_cv_c_bigendian=no
 882     ,AC_MSG_WARN([Could not determine endianness.])))
 883 fi
 884
 885
 886 # check for header files
 887 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 888 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 889 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 890 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
 891 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 892 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 893 AC_CHECK_HEADERS([linux/magic.h])
 894 AC_CHECK_HEADERS([sys/prctl.h])
 895
 896 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 897 [#if HAVE_SYS_PARAM_H
 898  #include <sys/param.h>
 899  #endif
 900 ])
 901
 902 AC_CHECK_HEADERS([xlocale.h])
 903
 904 # check for structure fields
 905 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 906 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 907 #include <sys/stat.h>
 908 #include <unistd.h>
 909 #ifdef HAVE_SYS_STATFS_H
 910 #include <sys/statfs.h>
 911 #endif
 912 #ifdef HAVE_SYS_PARAM_H
 913 #include <sys/param.h>
 914 #endif
 915 #ifdef HAVE_SYS_MOUNT_H
 916 #include <sys/mount.h>
 917 #endif])
 918 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 919 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 920 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 921 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 922
 923 AC_STRUCT_DIRENT_D_TYPE
 924
 925 # Checks for libcharset
 926 AM_LANGINFO_CODESET
 927 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 928 AC_CHECK_FUNCS(setlocale)
 929
 930 # check additional type sizes
 931 AC_CHECK_SIZEOF(size_t)
 932
 933 dnl Try to figure out whether gsize, gssize should be long or int
 934 AC_MSG_CHECKING([for the appropriate definition for size_t])
 935
 936 case $ac_cv_sizeof_size_t in
 937   $ac_cv_sizeof_short)
 938       glib_size_type=short
 939       ;;
 940   $ac_cv_sizeof_int)
 941       glib_size_type=int
 942       ;;
 943   $ac_cv_sizeof_long)
 944       glib_size_type=long
 945       ;;
 946   $ac_cv_sizeof_long_long)
 947       glib_size_type='long long'
 948       ;;
 949   $ac_cv_sizeof__int64)
 950       glib_size_type='__int64'
 951       ;;
 952   *)  AC_MSG_ERROR([No type matching size_t in size])
 953       ;;
 954 esac
 955
 956 dnl If int/long are the same size, we see which one produces
 957 dnl warnings when used in the location as size_t. (This matters
 958 dnl on AIX with xlc)
 959 dnl
 960 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 961        test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
 962   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 963 #if defined(_AIX) && !defined(__GNUC__)
 964 #pragma options langlvl=stdc89
 965 #endif
 966 #include <stddef.h>
 967 int main ()
 968 {
 969   size_t s = 1;
 970   unsigned int *size_int = &s;
 971   return (int)*size_int;
 972 }
 973     ]])],glib_size_type=int,
 974       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 975 #if defined(_AIX) && !defined(__GNUC__)
 976 #pragma options langlvl=stdc89
 977 #endif
 978 #include <stddef.h>
 979 int main ()
 980 {
 981    size_t s = 1;
 982    unsigned long *size_long = &s;
 983    return (int)*size_long;
 984 }
 985         ]])],glib_size_type=long)])
 986 ])
 987
 988 AC_MSG_RESULT(unsigned $glib_size_type)
 989
 990 # Check for some functions
 991 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 992 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid getresuid waitid)
 993 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
 994 # Check for high-resolution sleep functions
 995 AC_CHECK_FUNCS(splice)
 996 AC_CHECK_FUNCS(prlimit)
 997
 998 # To avoid finding a compatibility unusable statfs, which typically
 999 # successfully compiles, but warns to use the newer statvfs interface:
1000 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1001 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1002
1003 AC_MSG_CHECKING([whether to use statfs or statvfs])
1004 # Some systems have both statfs and statvfs, pick the most "native" for these
1005 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1006    [
1007    # on solaris and irix, statfs doesn't even have the f_bavail field
1008    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1009       [ac_cv_func_statfs=no],
1010    # else, at least on linux, statfs is the actual syscall
1011       [ac_cv_func_statvfs=no])
1012    ])
1013
1014 AS_IF([test x$ac_cv_func_statfs = xyes],
1015       [
1016          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1017          AC_MSG_RESULT([statfs])
1018       ],
1019       [test x$ac_cv_func_statvfs = xyes],
1020       [
1021          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1022          AC_MSG_RESULT([statvfs])
1023       ],
1024       [  AC_MSG_RESULT([neither])])
1025
1026 AC_CHECK_HEADERS(crt_externs.h)
1027 AC_CHECK_FUNCS(_NSGetEnviron)
1028
1029 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1030
1031 AC_FUNC_VSNPRINTF_C99
1032 AC_FUNC_PRINTF_UNIX98
1033
1034 # Internet address families
1035 if test $glib_native_win32 = yes; then
1036   glib_inet_includes=["
1037 #include <winsock2.h>
1038   "]
1039 else
1040   glib_inet_includes=["
1041 #include <sys/types.h>
1042 #include <sys/socket.h>
1043   "]
1044 fi
1045
1046 glib_failed=false
1047 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1048 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1049 # winsock defines this even though it doesn't support it
1050 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1051 if $glib_failed ; then
1052   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1053 fi
1054
1055 glib_failed=false
1056 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1057 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1058 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1059 if $glib_failed ; then
1060   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1061 fi
1062
1063 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex)
1064 AC_CHECK_HEADERS([netdb.h wspiapi.h arpa/nameser_compat.h])
1065
1066 AS_IF([test $glib_native_win32 = no], [
1067   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1068   NETWORK_LIBS=""
1069   AC_MSG_CHECKING([for res_query])
1070   AC_TRY_LINK([#include <sys/types.h>
1071                #include <netinet/in.h>
1072                #include <arpa/nameser.h>
1073                #include <resolv.h>
1074               ],[
1075                res_query("test", 0, 0, (void *)0, 0);
1076               ],[AC_MSG_RESULT([yes])],
1077               [save_libs="$LIBS"
1078                LIBS="-lresolv $LIBS"
1079                AC_TRY_LINK([#include <sys/types.h>
1080                             #include <netinet/in.h>
1081                             #include <arpa/nameser.h>
1082                             #include <resolv.h>
1083                            ],[
1084                             res_query("test", 0, 0, (void *)0, 0);
1085                            ],[AC_MSG_RESULT([in -lresolv])
1086                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1087                            [LIBS="-lbind $save_libs"
1088                             AC_TRY_LINK([#include <resolv.h>],
1089                                         [res_query("test", 0, 0, (void *)0, 0);],
1090                                         [AC_MSG_RESULT([in -lbind])
1091                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1092                                         [AC_MSG_ERROR(not found)])])
1093                LIBS="$save_libs"])
1094   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1095                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1096                                         [AC_MSG_ERROR(Could not find socket())]))
1097 ])
1098 AC_SUBST(NETWORK_LIBS)
1099
1100 AC_CHECK_HEADER([linux/netlink.h],
1101                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1102                 [#include <sys/socket.h>])
1103 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1104
1105 AC_CHECK_TYPE([struct ip_mreqn], [
1106               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1107               [#include <netinet/in.h>])
1108
1109 case $host in
1110   *-*-solaris* )
1111      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1112      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1113      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1114      ;;
1115 esac
1116
1117 dnl
1118 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1119 dnl
1120 AS_IF([test "$ac_cv_func_statfs" = yes], [
1121   AC_MSG_CHECKING([number of arguments to statfs()])
1122   AC_TRY_COMPILE([#include <unistd.h>
1123   #ifdef HAVE_SYS_PARAM_H
1124   #include <sys/param.h>
1125   #endif
1126   #ifdef HAVE_SYS_VFS_H
1127   #include <sys/vfs.h>
1128   #endif
1129   #ifdef HAVE_SYS_MOUNT_H
1130   #include <sys/mount.h>
1131   #endif
1132   #ifdef HAVE_SYS_STATFS_H
1133   #include <sys/statfs.h>
1134   #endif], [struct statfs st;
1135   statfs(NULL, &st);],[
1136     AC_MSG_RESULT([2])
1137     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1138     AC_TRY_COMPILE([#include <unistd.h>
1139   #ifdef HAVE_SYS_PARAM_H
1140   #include <sys/param.h>
1141   #endif
1142   #ifdef HAVE_SYS_VFS_H
1143   #include <sys/vfs.h>
1144   #endif
1145   #ifdef HAVE_SYS_MOUNT_H
1146   #include <sys/mount.h>
1147   #endif
1148   #ifdef HAVE_SYS_STATFS_H
1149   #include <sys/statfs.h>
1150   #endif], [struct statfs st;
1151   statfs(NULL, &st, sizeof (st), 0);],[
1152       AC_MSG_RESULT([4])
1153       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1154       AC_MSG_RESULT(unknown)
1155       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1156 ])
1157
1158 #
1159 # Check whether to use an included printf
1160 #
1161
1162 AC_ARG_ENABLE(included-printf,
1163               [AS_HELP_STRING([--enable-included-printf],
1164                               [use included printf [default=auto]])],
1165               enable_included_printf="$enableval")
1166
1167 need_included_printf=no
1168 if test "x$enable_included_printf" = "xyes" ; then
1169   need_included_printf=yes
1170 fi
1171 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1172   need_included_printf=yes
1173 fi
1174 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1175   need_included_printf=yes
1176 fi
1177 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1178    test -z "$glib_cv_long_long_format" ; then
1179   need_included_printf=yes
1180 fi
1181
1182 if test "x$enable_included_printf" = "xno" &&
1183    test "x$need_included_printf" = "xyes" ; then
1184   AC_MSG_ERROR([
1185 *** Your C library's printf doesn't appear to have the features that
1186 *** GLib needs, but you specified --enable-included-printf=no.])
1187 fi
1188
1189 enable_included_printf=$need_included_printf
1190
1191 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1192 AS_IF([test "$enable_included_printf" != "yes"], [
1193   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1194 ], [
1195   if test -z "$glib_cv_long_long_format" ; then
1196     glib_cv_long_long_format="ll"
1197   fi
1198   AC_DEFINE(HAVE_VASPRINTF,1)
1199 ])
1200
1201 # Checks needed for gnulib vasnprintf
1202 bh_C_SIGNED
1203 jm_AC_TYPE_LONG_LONG
1204 gt_TYPE_LONGDOUBLE
1205 gt_TYPE_WCHAR_T
1206 gt_TYPE_WINT_T
1207 AC_TYPE_SIZE_T
1208 AC_CHECK_TYPES(ptrdiff_t)
1209 jm_AC_TYPE_INTMAX_T
1210 AC_CHECK_FUNCS([snprintf wcslen])
1211 AC_FUNC_SNPRINTF_C99
1212
1213 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1214 # The check is borrowed from the PERL Configure script.
1215 AS_IF([test "$ac_cv_func_memmove" != "yes"],
1216   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1217     glib_cv_working_bcopy,[AC_TRY_RUN([
1218       int main() {
1219         char buf[128], abc[128], *b;
1220         int len, off, align;
1221         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1222         for (align = 7; align >= 0; align--) {
1223           for (len = 36; len; len--) {
1224             b = buf+align; bcopy(abc, b, len);
1225             for (off = 1; off <= len; off++) {
1226               bcopy(b, b+off, len); bcopy(b+off, b, len);
1227                 if (bcmp(b, abc, len)) return(1);
1228             }
1229           }
1230         }
1231         return(0);
1232       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1233
1234   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1235   if test "$glib_cv_working_bcopy" = "yes"; then
1236     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1237   fi
1238 ])
1239
1240 # Check if <sys/select.h> needs to be included for fd_set
1241 AC_MSG_CHECKING([for fd_set])
1242 AC_TRY_COMPILE([#include <sys/types.h>],
1243         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1244 AS_IF([test "$gtk_ok" = "yes"], [
1245     AC_MSG_RESULT([yes, found in sys/types.h])
1246 ], [
1247     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1248     if test "$gtk_ok" = "yes"; then
1249         # *** FIXME: give it a different name
1250         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1251         AC_MSG_RESULT([yes, found in sys/select.h])
1252     else
1253         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1254         AC_MSG_RESULT(no)
1255     fi
1256 ])
1257
1258 dnl *** check for sane realloc() ***
1259 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1260         AC_TRY_RUN([#include <stdlib.h>
1261         int main() {
1262           return realloc (0, sizeof (int)) == 0;
1263         }],
1264         [glib_cv_sane_realloc=yes],
1265         [glib_cv_sane_realloc=no],
1266         [glib_cv_sane_realloc=yes])
1267 ])
1268 AS_IF([test x$glib_cv_sane_realloc = xyes], [
1269   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1270 ])
1271
1272 dnl Check for nl_langinfo and CODESET
1273 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1274         AC_TRY_COMPILE([#include <langinfo.h>],
1275                 [char *codeset = nl_langinfo (CODESET);],
1276                 [glib_cv_langinfo_codeset=yes],
1277                 [glib_cv_langinfo_codeset=no])])
1278 if test x$glib_cv_langinfo_codeset = xyes; then
1279   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1280 fi
1281
1282 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1283 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1284         AC_TRY_COMPILE([#include <langinfo.h>],
1285                 [char *str;
1286                  str = nl_langinfo (PM_STR);
1287                  str = nl_langinfo (D_T_FMT);
1288                  str = nl_langinfo (D_FMT);
1289                  str = nl_langinfo (T_FMT);
1290                  str = nl_langinfo (T_FMT_AMPM);
1291                  str = nl_langinfo (MON_1);
1292                  str = nl_langinfo (ABMON_12);
1293                  str = nl_langinfo (DAY_1);
1294                  str = nl_langinfo (ABDAY_7);],
1295                 [glib_cv_langinfo_time=yes],
1296                 [glib_cv_langinfo_time=no])])
1297 if test x$glib_cv_langinfo_time = xyes; then
1298   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1299 fi
1300
1301 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1302 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1303         AC_TRY_COMPILE([#include <langinfo.h>],
1304                 [char *str;
1305                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1306                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1307                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1308                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1309                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1310                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1311                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1312                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1313                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1314                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);],
1315                 [glib_cv_langinfo_outdigit=yes],
1316                 [glib_cv_langinfo_outdigit=no])])
1317 if test x$glib_cv_langinfo_outdigit = xyes; then
1318   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1319 fi
1320
1321 dnl ****************************************
1322 dnl *** posix_memalign                   ***
1323 dnl ****************************************
1324 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1325 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1326     glib_cv_compliant_posix_memalign=0
1327     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1328         AC_TRY_RUN([
1329                 #define _XOPEN_SOURCE 600
1330                 #include <stdlib.h> /* posix_memalign() should be defined here */
1331                 /* some systems break if #include <malloc.h> used */
1332                 static void test_memalign (size_t boundary, size_t size) {
1333                     void *mem = 0;
1334                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1335                         exit (1);
1336                     else
1337                       free (mem);
1338                 }
1339                 int main() {
1340                     test_memalign (  128,   128 - 2 * sizeof (void*));
1341                     test_memalign (  256,   256 - 2 * sizeof (void*));
1342                     test_memalign (  512,   512 - 2 * sizeof (void*));
1343                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1344                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1345                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1346                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1347                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1348                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1349                     exit (0); /* success */
1350                 }
1351                 ],
1352             [glib_cv_compliant_posix_memalign=1], [], [:])
1353       :
1354     fi
1355     ])
1356 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1357     AC_MSG_RESULT(yes)
1358     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1359 ], [
1360     AC_MSG_RESULT(no)
1361 ])
1362
1363
1364 dnl ****************************************
1365 dnl *** strlcpy/strlcat                  ***
1366 dnl ****************************************
1367 # Check for strlcpy
1368 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1369 AC_TRY_RUN([#include <stdlib.h>
1370 #include <string.h>
1371 int main() {
1372   char p[10];
1373   (void) strlcpy (p, "hi", 10);
1374   if (strlcat (p, "bye", 0) != 3)
1375     return 1;
1376   return 0;
1377 }], glib_cv_have_strlcpy=yes,
1378     glib_cv_have_strlcpy=no,
1379     glib_cv_have_strlcpy=no)])
1380 if test "$glib_cv_have_strlcpy" = "yes"; then
1381     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1382 fi
1383
1384
1385 dnl **********************
1386 dnl *** va_copy checks ***
1387 dnl **********************
1388 dnl we currently check for all three va_copy possibilities, so we get
1389 dnl all results in config.log for bug reports.
1390 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1391         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1392 #include <stdlib.h>
1393         void f (int i, ...) {
1394         va_list args1, args2;
1395         va_start (args1, i);
1396         va_copy (args2, args1);
1397         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1398           exit (1);
1399         va_end (args1); va_end (args2);
1400         }
1401         int main() {
1402           f (0, 42);
1403           return 0;
1404         }]])],
1405         [glib_cv_va_copy=yes],
1406         [glib_cv_va_copy=no])
1407 ])
1408 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1409         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1410 #include <stdlib.h>
1411         void f (int i, ...) {
1412         va_list args1, args2;
1413         va_start (args1, i);
1414         __va_copy (args2, args1);
1415         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1416           exit (1);
1417         va_end (args1); va_end (args2);
1418         }
1419         int main() {
1420           f (0, 42);
1421           return 0;
1422         }]])],
1423         [glib_cv___va_copy=yes],
1424         [glib_cv___va_copy=no])
1425 ])
1426
1427 if test "x$glib_cv_va_copy" = "xyes"; then
1428   g_va_copy_func=va_copy
1429 else if test "x$glib_cv___va_copy" = "xyes"; then
1430   g_va_copy_func=__va_copy
1431 fi
1432 fi
1433
1434 if test -n "$g_va_copy_func"; then
1435   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1436 fi
1437
1438 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1439         AC_TRY_RUN([#include <stdarg.h>
1440 #include <stdlib.h>
1441         void f (int i, ...) {
1442         va_list args1, args2;
1443         va_start (args1, i);
1444         args2 = args1;
1445         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1446           exit (1);
1447         va_end (args1); va_end (args2);
1448         }
1449         int main() {
1450           f (0, 42);
1451           return 0;
1452         }],
1453         [glib_cv_va_val_copy=yes],
1454         [glib_cv_va_val_copy=no],
1455         [glib_cv_va_val_copy=yes])
1456 ])
1457
1458 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1459   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1460 ])
1461
1462 dnl ***********************
1463 dnl *** g_module checks ***
1464 dnl ***********************
1465 G_MODULE_LIBS=
1466 G_MODULE_LIBS_EXTRA=
1467 G_MODULE_PLUGIN_LIBS=
1468 if test x"$glib_native_win32" = xyes; then
1469   dnl No use for this on Win32
1470   G_MODULE_LDFLAGS=
1471 else
1472   export SED
1473   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1474 fi
1475 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1476 G_MODULE_NEED_USCORE=0
1477 G_MODULE_BROKEN_RTLD_GLOBAL=0
1478 G_MODULE_HAVE_DLERROR=0
1479 dnl *** force native WIN32 shared lib loader
1480 if test -z "$G_MODULE_IMPL"; then
1481   case "$host" in
1482   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1483   esac
1484 fi
1485 dnl *** force native AIX library loader
1486 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1487 if test -z "$G_MODULE_IMPL"; then
1488   case "$host" in
1489   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1490   esac
1491 fi
1492 dnl *** dlopen() and dlsym() in system libraries
1493 AS_IF([ test -z "$G_MODULE_IMPL"], [
1494         AC_CHECK_FUNC(dlopen,
1495                       [AC_CHECK_FUNC(dlsym,
1496                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1497                       [])
1498 ])
1499 dnl *** load_image (BeOS)
1500 AS_IF([test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"], [
1501   AC_CHECK_LIB(root, load_image,
1502       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1503       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1504       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1505       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1506       [])
1507 ])
1508 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1509 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1510         AC_CHECK_FUNC(NSLinkModule,
1511                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1512                        G_MODULE_NEED_USCORE=1],
1513                       [])
1514 ])
1515 dnl *** dlopen() and dlsym() in libdl
1516 AS_IF([ test -z "$G_MODULE_IMPL"], [
1517         AC_CHECK_LIB(dl, dlopen,
1518                      [AC_CHECK_LIB(dl, dlsym,
1519                                    [G_MODULE_LIBS=-ldl
1520                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1521                      [])
1522 ])
1523 dnl *** shl_load() in libdld (HP-UX)
1524 AS_IF([ test -z "$G_MODULE_IMPL"], [
1525         AC_CHECK_LIB(dld, shl_load,
1526                 [G_MODULE_LIBS=-ldld
1527                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1528                 [])
1529 ])
1530 dnl *** additional checks for G_MODULE_IMPL_DL
1531 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1532         LIBS_orig="$LIBS"
1533         LDFLAGS_orig="$LDFLAGS"
1534         LIBS="$G_MODULE_LIBS $LIBS"
1535         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1536 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1537         echo "void glib_plugin_test(void) { }" > plugin.c
1538         ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1539                 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1540         ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1541                 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1542                 -shrext ".o" -avoid-version plugin.lo \
1543                 -rpath /dont/care >/dev/null 2>&1
1544         eval `./libtool --config | grep ^objdir`
1545         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1546                 glib_cv_rtldglobal_broken,[
1547                 AC_TRY_RUN([
1548 #include <dlfcn.h>
1549 #ifndef RTLD_GLOBAL
1550 #  define RTLD_GLOBAL 0
1551 #endif
1552 #ifndef RTLD_LAZY
1553 #  define RTLD_LAZY 0
1554 #endif
1555 int glib_plugin_test;
1556 int main () {
1557     void *handle, *global, *local;
1558     global = &glib_plugin_test;
1559     handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1560     if (!handle) return 0;
1561     local = dlsym (handle, "glib_plugin_test");
1562     return global == local;
1563 }                       ],
1564                         [glib_cv_rtldglobal_broken=no],
1565                         [glib_cv_rtldglobal_broken=yes],
1566                         [glib_cv_rtldglobal_broken=no])
1567                 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1568                 rmdir ${objdir} 2>/dev/null
1569         ])
1570         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1571                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1572         else
1573                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1574         fi
1575 dnl *** check whether we need preceeding underscores
1576         AC_CACHE_CHECK([for preceeding underscore in symbols],
1577                 glib_cv_uscore,[
1578                 AC_TRY_RUN([#include <dlfcn.h>
1579                 int glib_underscore_test (void) { return 42; }
1580                 int main() {
1581                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1582                   handle = dlopen ((void*)0, 0);
1583                   if (handle) {
1584                     f1 = dlsym (handle, "glib_underscore_test");
1585                     f2 = dlsym (handle, "_glib_underscore_test");
1586                   } return (!f2 || f1);
1587                 }],
1588                         [glib_cv_uscore=yes],
1589                         [glib_cv_uscore=no],
1590                         [])
1591                 rm -f plugin.c plugin.$ac_objext plugin.lo
1592         ])
1593         GLIB_ASSERT_SET(glib_cv_uscore)
1594         if test "x$glib_cv_uscore" = "xyes"; then
1595                 G_MODULE_NEED_USCORE=1
1596         else
1597                 G_MODULE_NEED_USCORE=0
1598         fi
1599
1600         LDFLAGS="$LDFLAGS_orig"
1601 dnl *** check for having dlerror()
1602         AC_CHECK_FUNC(dlerror,
1603                 [G_MODULE_HAVE_DLERROR=1],
1604                 [G_MODULE_HAVE_DLERROR=0])
1605         LIBS="$LIBS_orig"
1606 ])
1607 dnl *** done, have we got an implementation?
1608 if test -z "$G_MODULE_IMPL"; then
1609         G_MODULE_IMPL=0
1610         G_MODULE_SUPPORTED=false
1611 else
1612         G_MODULE_SUPPORTED=true
1613 fi
1614
1615 AC_MSG_CHECKING(for the suffix of module shared libraries)
1616 export SED
1617 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1618 eval $shrext_cmds
1619 module=yes eval std_shrext=$shrext_cmds
1620 # chop the initial dot
1621 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1622 AC_MSG_RESULT(.$glib_gmodule_suffix)
1623 # any reason it may fail?
1624 if test "x$glib_gmodule_suffix" = x; then
1625         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1626 fi
1627
1628 AC_SUBST(G_MODULE_SUPPORTED)
1629 AC_SUBST(G_MODULE_IMPL)
1630 AC_SUBST(G_MODULE_LIBS)
1631 AC_SUBST(G_MODULE_LIBS_EXTRA)
1632 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1633 AC_SUBST(G_MODULE_LDFLAGS)
1634 AC_SUBST(G_MODULE_HAVE_DLERROR)
1635 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1636 AC_SUBST(G_MODULE_NEED_USCORE)
1637 AC_SUBST(GLIB_DEBUG_FLAGS)
1638
1639 dnl **********************
1640 dnl *** g_spawn checks ***
1641 dnl **********************
1642
1643 AC_MSG_CHECKING(for gspawn implementation)
1644 case "$host" in
1645   *-*-mingw*)
1646     GSPAWN=gspawn-win32.lo
1647     ;;
1648   *)
1649     GSPAWN=gspawn.lo
1650     ;;
1651 esac
1652 AC_MSG_RESULT($GSPAWN)
1653 AC_SUBST(GSPAWN)
1654
1655 dnl *************************
1656 dnl *** GIOChannel checks ***
1657 dnl *************************
1658
1659 AC_MSG_CHECKING(for GIOChannel implementation)
1660 case "$host" in
1661   *-*-mingw*)
1662     GIO=giowin32.lo
1663     ;;
1664   *)
1665     GIO=giounix.lo
1666     ;;
1667 esac
1668 AC_MSG_RESULT($GIO)
1669 AC_SUBST(GIO)
1670
1671 dnl *********************************
1672 dnl *** Directory for GIO modules ***
1673 dnl *********************************
1674
1675 AC_ARG_WITH(gio-module-dir,
1676            [AS_HELP_STRING([--with-gio-module-dir=DIR],
1677                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1678            [],
1679            [with_gio_module_dir='${libdir}/gio/modules'])
1680 GIO_MODULE_DIR=$with_gio_module_dir
1681 AC_SUBST(GIO_MODULE_DIR)
1682
1683 dnl **********************************
1684 dnl *** Check for libselinux (GIO) ***
1685 dnl **********************************
1686 AC_ARG_ENABLE(selinux,
1687               AS_HELP_STRING([--disable-selinux],
1688                              [build without selinux support]))
1689 msg_selinux=no
1690 SELINUX_LIBS=
1691 AS_IF([ test "x$enable_selinux" != "xno"], [
1692
1693  AC_CHECK_LIB(selinux, is_selinux_enabled,
1694    [AC_CHECK_HEADERS(selinux/selinux.h,
1695      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1696        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1697         SELINUX_LIBS="-lselinux"
1698         msg_selinux=yes])
1699      ])
1700    ])
1701 ])
1702 AC_SUBST(SELINUX_LIBS)
1703
1704 dnl *****************************
1705 dnl ** Check for inotify (GIO) **
1706 dnl *****************************
1707 inotify_support=no
1708 AC_CHECK_HEADERS([sys/inotify.h],
1709 [
1710         inotify_support=yes
1711         AC_CHECK_FUNCS(inotify_init1)
1712 ])
1713
1714 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1715
1716 dnl ****************************
1717 dnl ** Check for kqueue (GIO) **
1718 dnl ****************************
1719 kqueue_support=no
1720 AC_CHECK_HEADERS([sys/event.h],
1721 [
1722         AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1723 ])
1724
1725 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1726
1727 dnl *********************************
1728 dnl ** Check for Solaris FEN (GIO) **
1729 dnl *********************************
1730 fen_support=no
1731 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1732 #include <port.h>
1733 #ifndef PORT_SOURCE_FILE
1734 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1735 #endif
1736 int main() { return 0; } ]])],
1737 [
1738         fen_support=yes
1739 ],)
1740
1741 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1742
1743 dnl ****************************
1744 dnl *** Checks for FAM (GIO) ***
1745 dnl ****************************
1746
1747 should_disable_fam=no
1748
1749 AC_ARG_ENABLE(fam,
1750               AS_HELP_STRING([--disable-fam],
1751                              [don't use fam for file system monitoring]),
1752                          [
1753                                 if test "x$enable_fam" = "xno"; then
1754                                         should_disable_fam=yes
1755                                 fi
1756                          ]
1757                          )
1758 fam_support=no
1759 FAM_LIBS=
1760 if test "x$should_disable_fam" = "xno"; then
1761 AC_CHECK_LIB(fam, FAMOpen,
1762   [AC_CHECK_HEADERS(fam.h,
1763     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1764      AC_CHECK_LIB(fam, FAMNoExists,
1765                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1766      FAM_LIBS="-lfam"]
1767      fam_support=yes,
1768     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1769   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1770 AC_SUBST(FAM_LIBS)
1771 fi
1772 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1773
1774
1775 dnl *****************************
1776 dnl *** Check for xattr (GIO) ***
1777 dnl *****************************
1778 AC_ARG_ENABLE(xattr,
1779               AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1780 msg_xattr=no
1781 XATTR_LIBS=
1782 AS_IF([ test "x$enable_xattr" != "xno"], [
1783
1784 dnl either glibc or libattr can provide xattr support
1785
1786 dnl for both of them, we check for getxattr being in
1787 dnl the library and a valid xattr header.
1788
1789 dnl try glibc
1790  AC_CHECK_LIB(c, getxattr,
1791    [AC_CHECK_HEADERS(sys/xattr.h,
1792      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1793       msg_xattr=yes])
1794    ])
1795
1796   AS_IF([ test "x$msg_xattr" != "xyes"], [
1797 dnl   failure. try libattr
1798    AC_CHECK_LIB(attr, getxattr,
1799       [AC_CHECK_HEADERS(attr/xattr.h,
1800        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1801         XATTR_LIBS="-lattr"
1802         msg_xattr=yes])
1803       ])
1804   ])
1805
1806   AS_IF([ test "x$msg_xattr" = "xyes"], [
1807     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1808     AC_TRY_COMPILE([
1809       #include <stdio.h>
1810       #ifdef HAVE_SYS_TYPES_H
1811       #include <sys/types.h>
1812       #endif
1813       #ifdef HAVE_SYS_XATTR_H
1814       #include <sys/xattr.h>
1815       #elif HAVE_ATTR_XATTR_H
1816       #include <attr/xattr.h>
1817       #endif
1818     ],
1819     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1820     [
1821       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1822       AC_MSG_RESULT([yes])
1823     ],
1824     [AC_MSG_RESULT([no])]
1825     )
1826   ])
1827 ])
1828 AC_SUBST(XATTR_LIBS)
1829
1830 dnl ************************
1831 dnl *** check for libelf ***
1832 dnl ************************
1833 AC_ARG_ENABLE(libelf,
1834               AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1835 AS_IF([ test "x$enable_libelf" != "xno"],[
1836 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1837 AS_IF([ test $have_libelf = maybe ], [
1838   glib_save_LIBS=$LIBS
1839   AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1840   AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1841   AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1842   AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1843   LIBS=$glib_save_LIBS
1844
1845   if test $have_libelf != no; then
1846     LIBELF_LIBS=-lelf
1847     have_libelf=yes
1848   fi
1849 ])
1850 ])
1851
1852 if test x$have_libelf = xyes; then
1853   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1854 fi
1855
1856 dnl ****************************************
1857 dnl *** platform dependent source checks ***
1858 dnl ****************************************
1859
1860 AC_MSG_CHECKING(for platform-dependent source)
1861 case "$host" in
1862   *-*-cygwin*|*-*-mingw*)
1863     PLATFORMDEP=gwin32.lo
1864     ;;
1865   *)
1866     PLATFORMDEP=
1867     ;;
1868 esac
1869 AC_MSG_RESULT($PLATFORMDEP)
1870 AC_SUBST(PLATFORMDEP)
1871
1872 AC_MSG_CHECKING([whether to compile timeloop])
1873 case "$host" in
1874   *-*-cygwin*|*-*-mingw*|*-*-minix)
1875     enable_timeloop=no
1876     ;;
1877   *)
1878     enable_timeloop=yes
1879     ;;
1880 esac
1881 AC_MSG_RESULT($enable_timeloop)
1882 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1883
1884 AC_MSG_CHECKING([if building for some Win32 platform])
1885 case "$host" in
1886   *-*-mingw*|*-*-cygwin*)
1887     platform_win32=yes
1888     ;;
1889   *)
1890     platform_win32=no
1891     ;;
1892 esac
1893 AC_MSG_RESULT($platform_win32)
1894 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1895
1896 dnl ***********************
1897 dnl *** g_thread checks ***
1898 dnl ***********************
1899
1900 AC_ARG_WITH(threads,
1901            [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1902                            [specify a thread implementation to use])],
1903            [],
1904            [with_threads=yes])
1905
1906 dnl error and warning message
1907 dnl *************************
1908
1909 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1910
1911 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1912                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1913                 compilation now, but then your programs might not work.
1914                 Please provide information on how it is done on your system."
1915
1916 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1917                  "
1918
1919 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1920                   provide information on your thread implementation."
1921
1922 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1923                 functions will not be MT-safe during their first call because
1924                 there is no working 'getpwuid_r' on your system."
1925
1926 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1927                 because there is no 'localtime_r' on your system."
1928
1929 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1930                 linking threaded applications. As GLib cannot do that
1931                 automatically, you will get an linkg error everytime you are
1932                 not using the right compiler. In that case you have to relink
1933                 with the right compiler. Ususally just '_r' is appended
1934                 to the compiler name."
1935
1936 dnl determination of thread implementation
1937 dnl ***************************************
1938
1939 AC_MSG_CHECKING(for thread implementation)
1940
1941 have_threads=no
1942 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1943         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1944         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1945         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1946         glib_save_CPPFLAGS="$CPPFLAGS"
1947         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1948         AS_IF([ test "x$have_threads" = xno], [
1949                 AC_TRY_COMPILE([#include <pthread.h>],
1950                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1951                         have_threads=posix)
1952         ])
1953         # Tru64Unix requires -pthread to find pthread.h. See #103020
1954         CPPFLAGS="$CPPFLAGS -pthread"
1955         if test "x$have_threads" = xno; then
1956         AC_TRY_COMPILE([#include <pthread.h>],
1957                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1958                        have_threads=posix)
1959         fi
1960         CPPFLAGS="$glib_save_CPPFLAGS"
1961 ])
1962 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1963         case $host in
1964                 *-*-mingw*)
1965                 have_threads=win32
1966                 ;;
1967         esac
1968 fi
1969
1970 if test "x$have_threads" = xno; then
1971         AC_MSG_RESULT(none available)
1972         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1973 else
1974         AC_MSG_RESULT($have_threads)
1975 fi
1976
1977
1978 dnl determination of G_THREAD_CFLAGS
1979 dnl ********************************
1980
1981 G_THREAD_LIBS=
1982 G_THREAD_LIBS_EXTRA=
1983 G_THREAD_CFLAGS=
1984
1985 dnl
1986 dnl Test program for basic POSIX threads functionality
1987 dnl
1988 m4_define([glib_thread_test],[
1989 #include <pthread.h>
1990 int check_me = 0;
1991 void* func(void* data) {check_me = 42; return &check_me;}
1992 int main()
1993  { pthread_t t;
1994    void *ret;
1995    pthread_create (&t, $1, func, 0);
1996    pthread_join (t, &ret);
1997    return (check_me != 42 || ret != &check_me);
1998 }])
1999
2000 AS_IF([ test x"$have_threads" = xposix], [
2001   # First we test for posix, whether -pthread or -pthreads do the trick as
2002   # both CPPFLAG and LIBS.
2003   # One of them does for most gcc versions and some other platforms/compilers
2004   # too and could be considered as the canonical way to go.
2005   case $host in
2006     *-*-cygwin*|*-*-darwin*)
2007        # skip cygwin and darwin -pthread or -pthreads test
2008        ;;
2009     *-solaris*)
2010       # These compiler/linker flags work with both Sun Studio and gcc
2011       # Sun Studio expands -mt to -D_REENTRANT and -lthread
2012       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2013       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2014       G_THREAD_LIBS="-lpthread -lthread"
2015       ;;
2016     *)
2017       for flag in pthread pthreads mt; do
2018         glib_save_CFLAGS="$CFLAGS"
2019         CFLAGS="$CFLAGS -$flag"
2020         AC_TRY_RUN(glib_thread_test(0),
2021                    glib_flag_works=yes,
2022                    glib_flag_works=no,
2023                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2024                                    glib_flag_works=yes,
2025                                    glib_flag_works=no)])
2026         CFLAGS="$glib_save_CFLAGS"
2027         if test $glib_flag_works = yes ; then
2028            G_THREAD_CFLAGS=-$flag
2029         G_THREAD_LIBS=-$flag
2030         break;
2031         fi
2032       done
2033        ;;
2034   esac
2035 ])
2036
2037 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
2038
2039   # The canonical -pthread[s] does not work. Try something different.
2040
2041   case $host in
2042         *-aix*)
2043                 if test x"$GCC" = xyes; then
2044                         # GCC 3.0 and above needs -pthread.
2045                         # Should be coverd by the case above.
2046                         # GCC 2.x and below needs -mthreads
2047                         G_THREAD_CFLAGS="-mthreads"
2048                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2049                 else
2050                         # We are probably using the aix compiler. Normaly a
2051                         # program would have to be compiled with the _r variant
2052                         # of the corresponding compiler, but we as GLib cannot
2053                         # do that: but the good news is that for compiling the
2054                         # only difference is the added -D_THREAD_SAFE compile
2055                         # option. This is according to the "C for AIX User's
2056                         # Guide".
2057                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2058                 fi
2059                 ;;
2060         *-dg-dgux*)  # DG/UX
2061                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2062                 ;;
2063         *-sysv5uw7*) # UnixWare 7
2064                 # We are not using gcc with -pthread. Catched above.
2065                 G_THREAD_CFLAGS="-Kthread"
2066                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2067                 ;;
2068         *-mingw*)
2069                 # No flag needed when using MSVCRT.DLL
2070                 G_THREAD_CFLAGS=""
2071                 ;;
2072         *)
2073                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2074                 ;;
2075   esac
2076 ])
2077
2078 # if we are not finding the localtime_r function, then we probably are
2079 # not using the proper multithread flag
2080
2081 glib_save_CPPFLAGS="$CPPFLAGS"
2082 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2083
2084 # First we test, whether localtime_r is declared in time.h
2085 # directly. Then we test whether a macro localtime_r exists, in
2086 # which case localtime_r in the test program is replaced and thus
2087 # if we still find localtime_r in the output, it is not defined as
2088 # a macro.
2089
2090 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2091   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2092                                                            localtime_r(a,b)],
2093                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2094
2095 CPPFLAGS="$glib_save_CPPFLAGS"
2096
2097 AC_MSG_CHECKING(thread related cflags)
2098 AC_MSG_RESULT($G_THREAD_CFLAGS)
2099 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2100
2101 dnl determination of G_THREAD_LIBS
2102 dnl ******************************
2103
2104 AS_IF([test x$have_threads = xposix], [
2105           glib_save_CPPFLAGS="$CPPFLAGS"
2106           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2107           AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2108             case $host in
2109               *-aix*)
2110                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2111                 # probably using the aix compiler.
2112                 AC_MSG_WARN($AIX_COMPILE_INFO)
2113                 ;;
2114               *)
2115                 G_THREAD_LIBS=error
2116                 glib_save_LIBS="$LIBS"
2117                 for thread_lib in "" pthread pthread32 pthreads thread; do
2118                         if test x"$thread_lib" = x; then
2119                                 add_thread_lib=""
2120                                 IN=""
2121                         else
2122                                 add_thread_lib="-l$thread_lib"
2123                                 IN=" in -l$thread_lib"
2124                         fi
2125                         if test x"$have_threads" = xposix; then
2126                                 defattr=0
2127                         else
2128                                 defattr=pthread_attr_default
2129                         fi
2130
2131                         LIBS="$add_thread_lib $glib_save_LIBS"
2132
2133                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2134                         AC_TRY_RUN(glib_thread_test($defattr),
2135                                    glib_result=yes,
2136                                    glib_result=no,
2137                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2138                                                    glib_result=yes,
2139                                                    glib_result=no)])
2140                         AC_MSG_RESULT($glib_result)
2141
2142                         if test "$glib_result" = "yes" ; then
2143                           G_THREAD_LIBS="$add_thread_lib"
2144                           break
2145                         fi
2146                 done
2147                 if test "x$G_THREAD_LIBS" = xerror; then
2148                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2149                 fi
2150                 LIBS="$glib_save_LIBS"
2151                 ;;
2152             esac
2153           ])
2154
2155           g_threads_impl="POSIX"
2156           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2157           CPPFLAGS="$glib_save_CPPFLAGS"
2158 ], [test x$have_threads = xwin32], [
2159            g_threads_impl="WIN32"
2160 ], [
2161            g_threads_impl="NONE"
2162            G_THREAD_LIBS=error
2163 ])
2164
2165 if test "x$G_THREAD_LIBS" = xerror; then
2166         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2167 fi
2168
2169 case $host in
2170   *-*-beos*)
2171     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2172     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2173     ;;
2174   *)
2175     ;;
2176 esac
2177
2178 AC_MSG_CHECKING(thread related libraries)
2179 AC_MSG_RESULT($G_THREAD_LIBS)
2180
2181 dnl check for mt safe function variants and some posix functions
2182 dnl ************************************************************
2183
2184 glib_save_LIBS="$LIBS"
2185 # we are not doing the following for now, as this might require glib
2186 # to always be linked with the thread libs on some platforms.
2187 # LIBS="$LIBS $G_THREAD_LIBS"
2188 AC_CHECK_FUNCS(localtime_r gmtime_r)
2189 AS_IF([ test "$ac_cv_header_pwd_h" = "yes"], [
2190         AC_CACHE_CHECK([for posix getpwuid_r],
2191                 ac_cv_func_posix_getpwuid_r,
2192                 [AC_TRY_RUN([
2193 #include <errno.h>
2194 #include <pwd.h>
2195 int main () {
2196     char buffer[10000];
2197     struct passwd pwd, *pwptr = &pwd;
2198     int error;
2199     errno = 0;
2200     error = getpwuid_r (0, &pwd, buffer,
2201                         sizeof (buffer), &pwptr);
2202    return (error < 0 && errno == ENOSYS)
2203            || error == ENOSYS;
2204 }                               ],
2205                         [ac_cv_func_posix_getpwuid_r=yes],
2206                         [ac_cv_func_posix_getpwuid_r=no])])
2207         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2208         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2209                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2210                         [Have POSIX function getpwuid_r])
2211         else
2212                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2213                         ac_cv_func_nonposix_getpwuid_r,
2214                         [AC_TRY_LINK([#include <pwd.h>],
2215                                 [char buffer[10000];
2216                                 struct passwd pwd;
2217                                 getpwuid_r (0, &pwd, buffer,
2218                                                 sizeof (buffer));],
2219                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2220                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2221                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2222                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2223                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2224                                 [Have non-POSIX function getpwuid_r])
2225                 fi
2226         fi
2227 ])
2228 AS_IF([ test "$ac_cv_header_grp_h" = "yes"], [
2229         AC_CACHE_CHECK([for posix getgrgid_r],
2230                 ac_cv_func_posix_getgrgid_r,
2231                 [AC_TRY_RUN([
2232 #include <errno.h>
2233 #include <grp.h>
2234 int main () {
2235     char buffer[10000];
2236     struct group grp, *grpptr = &grp;
2237     int error;
2238     errno = 0;
2239     error = getgrgid_r (0, &grp, buffer,
2240                         sizeof (buffer), &grpptr);
2241    return (error < 0 && errno == ENOSYS)
2242            || error == ENOSYS;
2243 }                              ],
2244                        [ac_cv_func_posix_getgrgid_r=yes],
2245                        [ac_cv_func_posix_getgrgid_r=no])])
2246         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2247         AS_IF([ test "$ac_cv_func_posix_getgrgid_r" = yes ], [
2248                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2249                         [Have POSIX function getgrgid_r])
2250         ], [
2251                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2252                         ac_cv_func_nonposix_getgrgid_r,
2253                         [AC_TRY_LINK([#include <grp.h>],
2254                                 [char buffer[10000];
2255                                 struct group grp;
2256                                 getgrgid_r (0, &grp, buffer,
2257                                 sizeof (buffer));],
2258                         [ac_cv_func_nonposix_getgrgid_r=yes],
2259                         [ac_cv_func_nonposix_getgrgid_r=no])])
2260                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2261                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2262                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2263                                 [Have non-POSIX function getgrgid_r])
2264                 fi
2265         ])
2266 ])
2267 LIBS="$G_THREAD_LIBS $LIBS"
2268 AS_IF([ test x"$have_threads" = xposix], [
2269         glib_save_CPPFLAGS="$CPPFLAGS"
2270         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2271         # This is not AC_CHECK_FUNC to also work with function
2272         # name mangling in header files.
2273         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2274         AC_LINK_IFELSE(
2275             [AC_LANG_PROGRAM(
2276                 [#include <pthread.h>],
2277                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2278             [AC_MSG_RESULT(yes)
2279              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2280                 [Have function pthread_attr_setstacksize])],
2281             [AC_MSG_RESULT(no)])
2282         AC_MSG_CHECKING(for pthread_condattr_setclock)
2283         AC_LINK_IFELSE(
2284             [AC_LANG_PROGRAM(
2285                 [#include <pthread.h>],
2286                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2287             [AC_MSG_RESULT(yes)
2288              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2289                 [Have function pthread_condattr_setclock])],
2290             [AC_MSG_RESULT(no)])
2291         CPPFLAGS="$glib_save_CPPFLAGS"
2292 ])
2293
2294 LIBS="$glib_save_LIBS"
2295
2296 # now spit out all the warnings.
2297 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2298    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2299         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2300 fi
2301 if test "$ac_cv_func_localtime_r" != "yes"; then
2302         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2303 fi
2304
2305 #
2306 # Hack to deal with:
2307 #
2308 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2309 #     building shared libraries with linux.
2310 #  b) FreeBSD doesn't do this either.
2311 #
2312 case $host in
2313   *-*-freebsd*|*-*-linux*)
2314     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2315     ;;
2316   *-*-openbsd*)
2317     LDFLAGS="$LDFLAGS -pthread"
2318     ;;
2319   *)
2320     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2321     ;;
2322 esac
2323
2324 AC_SUBST(G_THREAD_CFLAGS)
2325 AC_SUBST(G_THREAD_LIBS)
2326 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2327 AC_SUBST(G_THREAD_LIBS_EXTRA)
2328
2329 AC_CHECK_FUNCS(clock_gettime, [], [
2330   AC_CHECK_LIB(rt, clock_gettime, [
2331     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2332     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2333     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2334   ])
2335 ])
2336
2337
2338 dnl ************************
2339 dnl *** g_atomic_* tests ***
2340 dnl ************************
2341
2342 dnl We need to decide at configure time if GLib will use real atomic
2343 dnl operations ("lock free") or emulated ones with a mutex.  This is
2344 dnl because we must put this information in glibconfig.h so we know if
2345 dnl it is safe or not to inline using compiler intrinsics directly from
2346 dnl the header.
2347 dnl
2348 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2349 dnl user is interested in knowing if they can use the atomic ops across
2350 dnl processes.
2351 dnl
2352 dnl We can currently support the atomic ops natively when building GLib
2353 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2354 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2355 dnl we are using GCC.
2356 dnl
2357 dnl Note that the atomic ops are only available with GCC on x86 when
2358 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2359 dnl not available but would be available given the right flags, we want
2360 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2361 dnl that then to silently fall back on emulated atomic ops just because
2362 dnl the user had the wrong build environment.
2363
2364 dnl We may add other compilers here in the future...
2365
2366 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2367   AC_TRY_COMPILE([],
2368                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2369                  [glib_cv_g_atomic_lock_free=yes],
2370                  [glib_cv_g_atomic_lock_free=no])])
2371
2372 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2373   SAVE_CFLAGS="${CFLAGS}"
2374   CFLAGS="-march=i486"
2375   AC_TRY_COMPILE([],
2376                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2377                  [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2378                  [])
2379   CFLAGS="${SAVE_CFLAGS}"
2380 fi
2381
2382 dnl We need a more robust approach here...
2383 case $host_cpu in
2384   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2385     glib_memory_barrier_needed=no
2386     ;;
2387   sparc*|alpha*|powerpc*|ia64)
2388     glib_memory_barrier_needed=yes
2389     ;;
2390   *)
2391     glib_memory_barrier_needed=yes
2392     ;;
2393 esac
2394
2395 dnl ************************
2396 dnl ** Check for futex(2) **
2397 dnl ************************
2398 AC_CACHE_CHECK(for futex(2) system call,
2399     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2400 #include <linux/futex.h>
2401 #include <sys/syscall.h>
2402 #include <unistd.h>
2403 ],[
2404 int
2405 main (void)
2406 {
2407   /* it is not like this actually runs or anything... */
2408   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2409   return 0;
2410 }
2411 ])],glib_cv_futex=yes,glib_cv_futex=no))
2412 if test x"$glib_cv_futex" = xyes; then
2413   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2414 fi
2415
2416 AC_CACHE_CHECK(for eventfd(2) system call,
2417     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2418 #include <sys/eventfd.h>
2419 #include <unistd.h>
2420 ],[
2421 int
2422 main (void)
2423 {
2424   eventfd (0, EFD_CLOEXEC);
2425   return 0;
2426 }
2427 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2428 if test x"$glib_cv_eventfd" = x"yes"; then
2429   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2430 fi
2431 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2432
2433 dnl ****************************************
2434 dnl *** GLib POLL* compatibility defines ***
2435 dnl ****************************************
2436
2437 glib_poll_includes=["
2438 #include <sys/types.h>
2439 #include <sys/poll.h>
2440 "]
2441
2442 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2443    test $ac_cv_header_sys_poll_h = yes ], [
2444   glib_failed=false
2445   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2446   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2447   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2448   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2449   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2450   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2451   if $glib_failed ; then
2452     AC_MSG_ERROR([Could not determine values for POLL* constants])
2453   fi
2454 ], [
2455   glib_cv_value_POLLIN=1
2456   glib_cv_value_POLLOUT=4
2457   glib_cv_value_POLLPRI=2
2458   glib_cv_value_POLLERR=8
2459   glib_cv_value_POLLHUP=16
2460   glib_cv_value_POLLNVAL=32
2461 ])
2462
2463 AC_MSG_CHECKING([for broken poll])
2464 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2465         #include <stdlib.h>
2466         #include <fcntl.h>
2467         #include <poll.h>
2468         #ifdef HAVE_SYS_POLL_H
2469         #include <sys/poll.h>
2470         #endif
2471         int main(void) {
2472           struct pollfd fds[1];
2473           int fd;
2474           fd = open("/dev/null", 1);
2475           fds[0].fd = fd;
2476           fds[0].events = POLLIN;
2477           fds[0].revents = 0;
2478           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2479                 exit(1);  /* Does not work for devices -- fail */
2480           }
2481           exit(0);
2482         }]])],
2483   [broken_poll=no],
2484   [broken_poll=yes
2485    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2486   [broken_poll="no (cross compiling)"])
2487 AC_MSG_RESULT($broken_poll)
2488
2489 dnl *********************
2490 dnl *** GRegex checks ***
2491 dnl *********************
2492
2493 PCRE_REQUIRED_VERSION=8.13
2494
2495 # Check if we should use the internal or the system-supplied pcre
2496 AC_ARG_WITH(pcre,
2497             [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2498                             [whether to use system PCRE [default=internal]])])
2499
2500 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2501
2502 AS_IF([ test "x$with_pcre" = xsystem], [
2503   PKG_CHECK_MODULES(PCRE,
2504                     libpcre >= $PCRE_REQUIRED_VERSION)
2505   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2506                   glib_save_CFLAGS="$CFLAGS"
2507                   glib_save_LIBS="$LIBS"
2508                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2509                   AC_TRY_RUN([#include <pcre.h>
2510                               int main () {
2511                                 int support;
2512                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2513                                 if (!support)
2514                                   return 1;
2515                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2516                                 if (!support)
2517                                   return 1;
2518                                 return 0;
2519                               }],
2520                   glib_cv_pcre_has_unicode=yes,
2521                   glib_cv_pcre_has_unicode=no,
2522                   glib_cv_pcre_has_unicode=yes)
2523                   CFLAGS="$glib_save_CFLAGS"
2524                   LIBS="$glib_save_LIBS"
2525       ])
2526   if test "$glib_cv_pcre_has_unicode" = "no"; then
2527     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2528   fi
2529   AC_SUBST(PCRE_CFLAGS)
2530   AC_SUBST(PCRE_LIBS)
2531   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2532   PCRE_REQUIRES=libpcre
2533   AC_SUBST(PCRE_REQUIRES)
2534 ], [
2535   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2536   AS_IF([ test x"$GCC" = xyes], [
2537     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2538     save_CFLAGS="$CFLAGS"
2539     CFLAGS="$CFLAGS -Wno-pointer-sign"
2540     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2541                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2542     CFLAGS="$save_CFLAGS"
2543   ])
2544 ])
2545 AC_SUBST(PCRE_WARN_CFLAGS)
2546
2547 dnl **********************
2548 dnl *** Win32 API libs ***
2549 dnl **********************
2550
2551 case $host in
2552   *-*-cygwin*)
2553         G_LIBS_EXTRA="-luser32 -lkernel32"
2554     ;;
2555   *-*-mingw*)
2556         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2557     ;;
2558   *)
2559         G_LIBS_EXTRA=""
2560     ;;
2561 esac
2562 AC_SUBST(G_LIBS_EXTRA)
2563
2564 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2565 dnl since we need it for g_iconv()
2566
2567 AC_MSG_CHECKING([for EILSEQ])
2568 AC_TRY_COMPILE([
2569 #include <errno.h>
2570 ],
2571 [
2572 int error = EILSEQ;
2573 ], have_eilseq=yes, have_eilseq=no);
2574 AC_MSG_RESULT($have_eilseq)
2575
2576 dnl ******************************************************************
2577 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2578 dnl *** glib-compile-schemas in PATH                               ***
2579 dnl ******************************************************************
2580
2581 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2582
2583 AS_IF([ test $cross_compiling = yes && test x$enable_modular_tests = xyes], [
2584   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2585   if test x$GLIB_GENMARSHAL = xno; then
2586     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2587   fi
2588
2589   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2590   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2591     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2592   fi
2593
2594   AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources, no)
2595   if test x$GLIB_COMPILE_RESOURCES = xno; then
2596     AC_MSG_ERROR(Could not find a glib-compile-resources in your PATH)
2597   fi
2598 ])
2599
2600 dnl **************************
2601 dnl *** Checks for gtk-doc ***
2602 dnl **************************
2603 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2604 # it on it's own line.
2605 m4_ifdef([GTK_DOC_CHECK], [
2606 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2607 ],[
2608 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2609 ])
2610
2611 AC_ARG_ENABLE(man,
2612               [AS_HELP_STRING([--enable-man],
2613                               [generate man pages [default=auto]])],,
2614               enable_man=maybe)
2615
2616 AS_IF([test "$enable_man" != no], [
2617   AC_PATH_PROG([XSLTPROC], [xsltproc])
2618   AS_IF([test -z "$XSLTPROC"], [
2619     AS_IF([test "$enable_man" = yes], [
2620       AC_MSG_ERROR([xsltproc is required for --enable-man])
2621     ])
2622     enable_man=no
2623   ])
2624 ])
2625
2626 AS_IF([ test "$enable_man" != no ], [
2627   dnl check for DocBook DTD in the local catalog
2628   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2629      [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2630   AS_IF([test "$have_docbook_dtd" != yes], [
2631     AS_IF([test "$enable_man" = yes ], [
2632       AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2633     ])
2634     enable_man=no
2635   ])
2636 ])
2637
2638 AS_IF([test "$enable_man" != no], [
2639   dnl check for DocBook XSL stylesheets in the local catalog
2640   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2641      [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2642   AS_IF([ test "$have_docbook_dtd" != yes ], [
2643     AS_IF([ test "$enable_man" = yes ], [
2644       AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2645     ])
2646     enable_man=no
2647   ])
2648 ])
2649
2650 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2651
2652 AC_MSG_CHECKING([whether to generate man pages])
2653 AS_IF([ test "$enable_man" != no ], [
2654   AC_MSG_RESULT([yes])
2655 ], [
2656   AC_MSG_RESULT([no])
2657 ])
2658
2659 dnl
2660 dnl Tracing
2661 dnl
2662
2663 AC_ARG_ENABLE([dtrace],
2664              [AS_HELP_STRING([--enable-dtrace],
2665                               [include tracing support for dtrace])])
2666 have_dtrace=no
2667 AC_MSG_CHECKING([whether to include dtrace tracing support])
2668 AS_IF([ test "x$enable_dtrace" != xno], [
2669   if test x$glib_have_carbon = xyes; then
2670     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2671   else
2672     AC_MSG_RESULT([yes])
2673     AC_CHECK_PROGS(DTRACE, dtrace)
2674     if test -z "$DTRACE"; then
2675       if test "x$enable_dtrace" = xyes; then
2676         AC_MSG_ERROR([dtrace not found])
2677       fi
2678     else
2679       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2680                       [if test "x$enable_dtrace" = xyes; then
2681                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2682                        fi])
2683     fi
2684   fi
2685 ], [
2686   AC_MSG_RESULT([no])
2687 ])
2688 if test "x$have_dtrace" = xyes; then
2689   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2690 fi
2691 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2692
2693 AC_MSG_CHECKING([whether to include systemtap tracing support])
2694 AC_ARG_ENABLE([systemtap],
2695              [AS_HELP_STRING([--enable-systemtap],
2696                               [include tracing support for systemtap])])
2697 have_systemtap=no
2698 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2699   have_systemtap=yes
2700 fi
2701 AC_MSG_RESULT(${have_systemtap})
2702
2703 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2704
2705 AC_ARG_WITH([tapset-install-dir],
2706             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2707                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2708             [if test "x${withval}" = x; then
2709                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2710              else
2711                ABS_TAPSET_DIR="${withval}"
2712               fi],
2713             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2714 AC_SUBST(ABS_TAPSET_DIR)
2715
2716 dnl ************************************
2717 dnl *** Enable lcov coverage reports ***
2718 dnl ************************************
2719
2720 AC_ARG_ENABLE(gcov,
2721   AS_HELP_STRING([--enable-gcov],
2722                  [enable coverage testing with gcov]),
2723   [use_gcov=$enableval], [use_gcov=no])
2724
2725 AS_IF([ test "x$use_gcov" = "xyes"], [
2726   dnl we need gcc:
2727   if test "$GCC" != "yes"; then
2728     AC_MSG_ERROR([GCC is required for --enable-gcov])
2729   fi
2730
2731   dnl Check if ccache is being used
2732   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2733   case `$SHTOOL path $CC` in
2734     *ccache*[)] gcc_ccache=yes;;
2735     *[)] gcc_ccache=no;;
2736   esac
2737
2738   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2739     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2740   fi
2741
2742   ltp_version_list="1.6 1.7 1.8 1.9"
2743   AC_CHECK_PROG(LTP, lcov, lcov)
2744   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2745
2746   AS_IF([ test "$LTP" ], [
2747     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2748       glib_cv_ltp_version=invalid
2749       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2750       for ltp_check_version in $ltp_version_list; do
2751         if test "$ltp_version" = "$ltp_check_version"; then
2752           glib_cv_ltp_version="$ltp_check_version (ok)"
2753         fi
2754       done
2755     ])
2756   ], [
2757     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2758     AC_MSG_ERROR([$ltp_msg])
2759   ])
2760
2761   case $glib_cv_ltp_version in
2762     ""|invalid[)]
2763       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2764       AC_MSG_ERROR([$ltp_msg])
2765       LTP="exit 0;"
2766       ;;
2767   esac
2768
2769   if test -z "$LTP_GENHTML"; then
2770     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2771   fi
2772
2773   dnl Remove all optimization flags from CFLAGS
2774   changequote({,})
2775   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2776   changequote([,])
2777
2778   dnl Add the special gcc flags
2779   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2780   LDFLAGS="$LDFLAGS -lgcov"
2781 ])
2782
2783 dnl ******************************
2784 dnl *** output the whole stuff ***
2785 dnl ******************************
2786
2787 dnl this section will only be run if config.status is invoked with no
2788 dnl arguments, or with "glib/glibconfig.h" as an argument.
2789 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2790 [
2791         outfile=glib/glibconfig.h-tmp
2792         cat > $outfile <<\_______EOF
2793 /* glibconfig.h
2794  *
2795  * This is a generated file.  Please modify 'configure.ac'
2796  */
2797
2798 #ifndef __GLIBCONFIG_H__
2799 #define __GLIBCONFIG_H__
2800
2801 #include <glib/gmacros.h>
2802
2803 _______EOF
2804
2805         if test x$glib_limits_h = xyes; then
2806           echo '#include <limits.h>' >> $outfile
2807         fi
2808         if test x$glib_float_h = xyes; then
2809           echo '#include <float.h>' >> $outfile
2810         fi
2811         if test x$glib_values_h = xyes; then
2812           echo '#include <values.h>' >> $outfile
2813         fi
2814         if test "$glib_header_alloca_h" = "yes"; then
2815           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2816         fi
2817         if test x$glib_sys_poll_h = xyes; then
2818           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2819         fi
2820         if test x$glib_included_printf != xyes; then
2821           echo "
2822 /* Specifies that GLib's g_print*() functions wrap the
2823  * system printf functions.  This is useful to know, for example,
2824  * when using glibc's register_printf_function().
2825  */" >> $outfile
2826           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2827         fi
2828
2829         cat >> $outfile <<_______EOF
2830
2831 G_BEGIN_DECLS
2832
2833 #define G_MINFLOAT      $glib_mf
2834 #define G_MAXFLOAT      $glib_Mf
2835 #define G_MINDOUBLE     $glib_md
2836 #define G_MAXDOUBLE     $glib_Md
2837 #define G_MINSHORT      $glib_ms
2838 #define G_MAXSHORT      $glib_Ms
2839 #define G_MAXUSHORT     $glib_Mus
2840 #define G_MININT        $glib_mi
2841 #define G_MAXINT        $glib_Mi
2842 #define G_MAXUINT       $glib_Mui
2843 #define G_MINLONG       $glib_ml
2844 #define G_MAXLONG       $glib_Ml
2845 #define G_MAXULONG      $glib_Mul
2846
2847 _______EOF
2848
2849
2850         ### this should always be true in a modern C/C++ compiler
2851         cat >>$outfile <<_______EOF
2852 typedef signed char gint8;
2853 typedef unsigned char guint8;
2854 _______EOF
2855
2856
2857         if test -n "$gint16"; then
2858           cat >>$outfile <<_______EOF
2859 typedef signed $gint16 gint16;
2860 typedef unsigned $gint16 guint16;
2861 #define G_GINT16_MODIFIER $gint16_modifier
2862 #define G_GINT16_FORMAT $gint16_format
2863 #define G_GUINT16_FORMAT $guint16_format
2864 _______EOF
2865         fi
2866
2867
2868         if test -n "$gint32"; then
2869           cat >>$outfile <<_______EOF
2870 typedef signed $gint32 gint32;
2871 typedef unsigned $gint32 guint32;
2872 #define G_GINT32_MODIFIER $gint32_modifier
2873 #define G_GINT32_FORMAT $gint32_format
2874 #define G_GUINT32_FORMAT $guint32_format
2875 _______EOF
2876         fi
2877
2878         cat >>$outfile <<_______EOF
2879 #define G_HAVE_GINT64 1          /* deprecated, always true */
2880
2881 ${glib_extension}typedef signed $gint64 gint64;
2882 ${glib_extension}typedef unsigned $gint64 guint64;
2883
2884 #define G_GINT64_CONSTANT(val)  $gint64_constant
2885 #define G_GUINT64_CONSTANT(val) $guint64_constant
2886 _______EOF
2887
2888         if test x$gint64_format != x ; then
2889           cat >>$outfile <<_______EOF
2890 #define G_GINT64_MODIFIER $gint64_modifier
2891 #define G_GINT64_FORMAT $gint64_format
2892 #define G_GUINT64_FORMAT $guint64_format
2893 _______EOF
2894         else
2895           cat >>$outfile <<_______EOF
2896 #undef G_GINT64_MODIFIER
2897 #undef G_GINT64_FORMAT
2898 #undef G_GUINT64_FORMAT
2899 _______EOF
2900         fi
2901
2902         cat >>$outfile <<_______EOF
2903
2904 #define GLIB_SIZEOF_VOID_P $glib_void_p
2905 #define GLIB_SIZEOF_LONG   $glib_long
2906 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2907
2908 _______EOF
2909
2910         cat >>$outfile <<_______EOF
2911 typedef signed $glib_size_type_define gssize;
2912 typedef unsigned $glib_size_type_define gsize;
2913 #define G_GSIZE_MODIFIER $gsize_modifier
2914 #define G_GSSIZE_FORMAT $gssize_format
2915 #define G_GSIZE_FORMAT $gsize_format
2916
2917 #define G_MAXSIZE       G_MAXU$glib_msize_type
2918 #define G_MINSSIZE      G_MIN$glib_msize_type
2919 #define G_MAXSSIZE      G_MAX$glib_msize_type
2920
2921 typedef gint64 goffset;
2922 #define G_MINOFFSET     G_MININT64
2923 #define G_MAXOFFSET     G_MAXINT64
2924
2925 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2926 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2927 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2928
2929 _______EOF
2930
2931         if test -z "$glib_unknown_void_p"; then
2932           cat >>$outfile <<_______EOF
2933
2934 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2935 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2936
2937 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2938 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2939
2940 typedef signed $glib_intptr_type_define gintptr;
2941 typedef unsigned $glib_intptr_type_define guintptr;
2942
2943 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2944 #define G_GINTPTR_FORMAT        $gintptr_format
2945 #define G_GUINTPTR_FORMAT       $guintptr_format
2946 _______EOF
2947         else
2948           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2949         fi
2950
2951
2952
2953         cat >>$outfile <<_______EOF
2954 $glib_atexit
2955 $glib_memmove
2956 $glib_defines
2957 $glib_os
2958 $glib_static_compilation
2959
2960 $glib_vacopy
2961
2962 #ifdef  __cplusplus
2963 #define G_HAVE_INLINE   1
2964 #else   /* !__cplusplus */
2965 $glib_inline
2966 #endif  /* !__cplusplus */
2967
2968 #ifdef  __cplusplus
2969 #define G_CAN_INLINE    1
2970 _______EOF
2971
2972         if test x$g_can_inline = xyes ; then
2973                 cat >>$outfile <<_______EOF
2974 #else   /* !__cplusplus */
2975 #define G_CAN_INLINE    1
2976 _______EOF
2977         fi
2978
2979         cat >>$outfile <<_______EOF
2980 #endif
2981
2982 _______EOF
2983
2984         if test x$g_have_iso_c_varargs = xyes ; then
2985                 cat >>$outfile <<_______EOF
2986 #ifndef __cplusplus
2987 # define G_HAVE_ISO_VARARGS 1
2988 #endif
2989 _______EOF
2990         fi
2991         if test x$g_have_iso_cxx_varargs = xyes ; then
2992                 cat >>$outfile <<_______EOF
2993 #ifdef __cplusplus
2994 # define G_HAVE_ISO_VARARGS 1
2995 #endif
2996 _______EOF
2997         fi
2998         if test x$g_have_gnuc_varargs = xyes ; then
2999                 cat >>$outfile <<_______EOF
3000
3001 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3002  * is passed ISO vararg support is turned off, and there is no work
3003  * around to turn it on, so we unconditionally turn it off.
3004  */
3005 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3006 #  undef G_HAVE_ISO_VARARGS
3007 #endif
3008
3009 #define G_HAVE_GNUC_VARARGS 1
3010 _______EOF
3011         fi
3012
3013         case x$g_stack_grows in
3014         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3015         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3016         esac
3017
3018
3019         echo >>$outfile
3020         if test x$g_have_eilseq = xno; then
3021                 cat >>$outfile <<_______EOF
3022 #ifndef EILSEQ
3023 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3024  * The correspondence between this and the corresponding definition
3025  * in libiconv is essential.
3026  */
3027 #  define EILSEQ ENOENT
3028 #endif
3029 _______EOF
3030
3031         fi
3032
3033         if test x$g_have_gnuc_visibility = xyes; then
3034                 cat >>$outfile <<_______EOF
3035 #define G_HAVE_GNUC_VISIBILITY 1
3036 _______EOF
3037         fi
3038                 cat >>$outfile <<_______EOF
3039 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3040 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3041 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3042 #define G_GNUC_INTERNAL __hidden
3043 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3044 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3045 #else
3046 #define G_GNUC_INTERNAL
3047 #endif
3048 _______EOF
3049
3050         echo >>$outfile
3051         cat >>$outfile <<_______EOF
3052 #define G_THREADS_ENABLED
3053 #define G_THREADS_IMPL_$g_threads_impl_def
3054 _______EOF
3055
3056         if test x"$g_memory_barrier_needed" != xno; then
3057           echo >>$outfile
3058           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3059         fi
3060         if test x"$g_atomic_lock_free" = xyes; then
3061           echo >>$outfile
3062           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3063         fi
3064         echo >>$outfile
3065         g_bit_sizes="16 32 64"
3066         for bits in $g_bit_sizes; do
3067           cat >>$outfile <<_______EOF
3068 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3069 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3070 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3071 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3072 _______EOF
3073         done
3074
3075         cat >>$outfile <<_______EOF
3076 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3077 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3078 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3079 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3080 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3081 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3082 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3083 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3084 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3085 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3086 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3087 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3088 #define G_BYTE_ORDER $g_byte_order
3089
3090 #define GLIB_SYSDEF_POLLIN =$g_pollin
3091 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3092 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3093 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3094 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3095 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3096
3097 #define G_MODULE_SUFFIX "$g_module_suffix"
3098
3099 typedef $g_pid_type GPid;
3100
3101 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3102 #define GLIB_SYSDEF_AF_INET $g_af_inet
3103 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3104
3105 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3106 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3107 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3108
3109 G_END_DECLS
3110
3111 #endif /* __GLIBCONFIG_H__ */
3112 _______EOF
3113
3114
3115         if cmp -s $outfile glib/glibconfig.h; then
3116           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3117           rm -f $outfile
3118         else
3119           mv $outfile glib/glibconfig.h
3120         fi
3121 ],[
3122
3123 # Note that if two cases are the same, case goes with the first one.
3124 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3125 # on variable expansion in case labels.  Look at the generated config.status
3126 # for a hint.
3127
3128 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3129   glib_header_alloca_h="$ac_cv_working_alloca_h"
3130 else
3131   glib_header_alloca_h="$ac_cv_header_alloca_h"
3132 fi
3133
3134 case xyes in
3135 x$ac_cv_header_float_h)
3136   glib_float_h=yes
3137   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3138   glib_md=DBL_MIN glib_Md=DBL_MAX
3139   ;;
3140 x$ac_cv_header_values_h)
3141   glib_values_h=yes
3142   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3143   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3144   ;;
3145 esac
3146
3147 case xyes in
3148 x$ac_cv_header_limits_h)
3149   glib_limits_h=yes
3150   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3151   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3152   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3153   ;;
3154 x$ac_cv_header_values_h)
3155   glib_values_h=yes
3156   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3157   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3158   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3159   ;;
3160 esac
3161
3162 if test x$ac_cv_header_sys_poll_h = xyes ; then
3163   glib_sys_poll_h=yes
3164 fi
3165
3166 if test x$enable_included_printf = xyes ; then
3167   glib_included_printf=yes
3168 fi
3169
3170 case 2 in
3171 $ac_cv_sizeof_short)
3172   gint16=short
3173   gint16_modifier='"h"'
3174   gint16_format='"hi"'
3175   guint16_format='"hu"'
3176   ;;
3177 $ac_cv_sizeof_int)
3178   gint16=int
3179   gint16_modifier='""'
3180   gint16_format='"i"'
3181   guint16_format='"u"'
3182   ;;
3183 esac
3184 case 4 in
3185 $ac_cv_sizeof_short)
3186   gint32=short
3187   gint32_modifier='"h"'
3188   gint32_format='"hi"'
3189   guint32_format='"hu"'
3190   ;;
3191 $ac_cv_sizeof_int)
3192   gint32=int
3193   gint32_modifier='""'
3194   gint32_format='"i"'
3195   guint32_format='"u"'
3196   ;;
3197 $ac_cv_sizeof_long)
3198   gint32=long
3199   gint32_modifier='"l"'
3200   gint32_format='"li"'
3201   guint32_format='"lu"'
3202   ;;
3203 esac
3204 case 8 in
3205 $ac_cv_sizeof_int)
3206   gint64=int
3207   gint64_modifier='""'
3208   gint64_format='"i"'
3209   guint64_format='"u"'
3210   glib_extension=
3211   gint64_constant='(val)'
3212   guint64_constant='(val)'
3213   ;;
3214 $ac_cv_sizeof_long)
3215   gint64=long
3216   gint64_modifier='"l"'
3217   gint64_format='"li"'
3218   guint64_format='"lu"'
3219   glib_extension=
3220   gint64_constant='(val##L)'
3221   guint64_constant='(val##UL)'
3222   ;;
3223 $ac_cv_sizeof_long_long)
3224   gint64='long long'
3225   if test -n "$glib_cv_long_long_format"; then
3226     gint64_modifier='"'$glib_cv_long_long_format'"'
3227     gint64_format='"'$glib_cv_long_long_format'i"'
3228     guint64_format='"'$glib_cv_long_long_format'u"'
3229   fi
3230   glib_extension='G_GNUC_EXTENSION '
3231   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3232   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3233   ;;
3234 $ac_cv_sizeof___int64)
3235   gint64='__int64'
3236   if test -n "$glib_cv_long_long_format"; then
3237     gint64_modifier='"'$glib_cv_long_long_format'"'
3238     gint64_format='"'$glib_cv_long_long_format'i"'
3239     guint64_format='"'$glib_cv_long_long_format'u"'
3240   fi
3241   glib_extension=
3242   gint64_constant='(val##i64)'
3243   guint64_constant='(val##ui64)'
3244   ;;
3245 esac
3246 glib_size_t=$ac_cv_sizeof_size_t
3247 glib_size_type_define="$glib_size_type"
3248 glib_void_p=$ac_cv_sizeof_void_p
3249 glib_long=$ac_cv_sizeof_long
3250
3251 case "$glib_size_type" in
3252 short)
3253   gsize_modifier='"h"'
3254   gsize_format='"hu"'
3255   gssize_format='"hi"'
3256   glib_msize_type='SHRT'
3257   ;;
3258 int)
3259   gsize_modifier='""'
3260   gsize_format='"u"'
3261   gssize_format='"i"'
3262   glib_msize_type='INT'
3263   ;;
3264 long)
3265   gsize_modifier='"l"'
3266   gsize_format='"lu"'
3267   gssize_format='"li"'
3268   glib_msize_type='LONG'
3269   ;;
3270 "long long"|__int64)
3271   gsize_modifier='"I64"'
3272   gsize_format='"I64u"'
3273   gssize_format='"I64i"'
3274   glib_msize_type='INT64'
3275   ;;
3276 esac
3277
3278 gintbits=`expr $ac_cv_sizeof_int \* 8`
3279 glongbits=`expr $ac_cv_sizeof_long \* 8`
3280 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3281
3282 case $ac_cv_sizeof_void_p in
3283 $ac_cv_sizeof_int)
3284   glib_intptr_type_define=int
3285   gintptr_modifier='""'
3286   gintptr_format='"i"'
3287   guintptr_format='"u"'
3288   glib_gpi_cast='(gint)'
3289   glib_gpui_cast='(guint)'
3290   ;;
3291 $ac_cv_sizeof_long)
3292   glib_intptr_type_define=long
3293   gintptr_modifier='"l"'
3294   gintptr_format='"li"'
3295   guintptr_format='"lu"'
3296   glib_gpi_cast='(glong)'
3297   glib_gpui_cast='(gulong)'
3298   ;;
3299 $ac_cv_sizeof_long_long)
3300   glib_intptr_type_define='long long'
3301   gintptr_modifier='"I64"'
3302   gintptr_format='"I64i"'
3303   guintptr_format='"I64u"'
3304   glib_gpi_cast='(gint64)'
3305   glib_gpui_cast='(guint64)'
3306   ;;
3307 $ac_cv_sizeof___int64)
3308   glib_intptr_type_define=__int64
3309   gintptr_modifier='"I64"'
3310   gintptr_format='"I64i"'
3311   guintptr_format='"I64u"'
3312   glib_gpi_cast='(gint64)'
3313   glib_gpui_cast='(guint64)'
3314   ;;
3315 *)
3316   glib_unknown_void_p=yes
3317   ;;
3318 esac
3319
3320
3321 case xyes in
3322 x$ac_cv_func_atexit)
3323   glib_atexit="
3324 #ifdef NeXT /* @#%@! NeXTStep */
3325 # define g_ATEXIT(proc) (!atexit (proc))
3326 #else
3327 # define g_ATEXIT(proc) (atexit (proc))
3328 #endif"
3329   ;;
3330 x$ac_cv_func_on_exit)
3331   glib_atexit="
3332 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3333   ;;
3334 esac
3335
3336 case xyes in
3337 x$ac_cv_func_memmove)
3338   glib_memmove='
3339 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3340   ;;
3341 x$glib_cv_working_bcopy)
3342   glib_memmove="
3343 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3344 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3345   ;;
3346 *)
3347   glib_memmove="
3348 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3349  * so we have to roll our own copy routine. */
3350 void g_memmove (void* dest, const void * src, unsigned long len);"
3351   ;;
3352 esac
3353
3354 glib_defines="
3355 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3356 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3357 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3358 "
3359
3360 case xyes in
3361 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3362 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3363 *)                      glib_vacopy=''
3364 esac
3365
3366 if test x$glib_cv_va_val_copy = xno; then
3367   glib_vacopy="\$glib_vacopy
3368 #define G_VA_COPY_AS_ARRAY 1"
3369 fi
3370
3371 if test x$glib_cv_hasinline = xyes; then
3372     glib_inline='#define G_HAVE_INLINE 1'
3373 fi
3374 if test x$glib_cv_has__inline = xyes; then
3375     glib_inline="\$glib_inline
3376 #define G_HAVE___INLINE 1"
3377 fi
3378 if test x$glib_cv_has__inline__ = xyes; then
3379     glib_inline="\$glib_inline
3380 #define G_HAVE___INLINE__ 1"
3381 fi
3382
3383 g_have_gnuc_varargs=$g_have_gnuc_varargs
3384 g_have_iso_c_varargs=$g_have_iso_c_varargs
3385 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3386
3387 g_can_inline=$g_can_inline
3388 g_have_gnuc_visibility=$g_have_gnuc_visibility
3389 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3390
3391 if test x$ac_cv_c_bigendian = xyes; then
3392   g_byte_order=G_BIG_ENDIAN
3393   g_bs_native=BE
3394   g_bs_alien=LE
3395 else
3396   g_byte_order=G_LITTLE_ENDIAN
3397   g_bs_native=LE
3398   g_bs_alien=BE
3399 fi
3400
3401 g_pollin=$glib_cv_value_POLLIN
3402 g_pollout=$glib_cv_value_POLLOUT
3403 g_pollpri=$glib_cv_value_POLLPRI
3404 g_pollhup=$glib_cv_value_POLLHUP
3405 g_pollerr=$glib_cv_value_POLLERR
3406 g_pollnval=$glib_cv_value_POLLNVAL
3407
3408 # If a family is not found on the system, define that family to
3409 # a negative value, picking a different one for each undefined
3410 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3411 # This is needed because glib-mkenums doesn't handle optional
3412 # values in enums, and thus we have to have all existing values
3413 # defined in the enum.
3414 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3415   g_af_unix=$glib_cv_value_AF_UNIX
3416 else
3417   g_af_unix=-1
3418 fi
3419 g_af_inet=$glib_cv_value_AF_INET
3420 g_af_inet6=$glib_cv_value_AF_INET6
3421
3422 g_msg_peek=$glib_cv_value_MSG_PEEK
3423 g_msg_oob=$glib_cv_value_MSG_OOB
3424 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3425
3426 g_stack_grows=$glib_cv_stack_grows
3427
3428 g_have_eilseq=$have_eilseq
3429
3430 g_threads_impl_def=$g_threads_impl
3431
3432 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3433 g_memory_barrier_needed="$glib_memory_barrier_needed"
3434 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3435
3436 g_module_suffix="$glib_gmodule_suffix"
3437
3438 g_pid_type="$glib_pid_type"
3439 case $host in
3440   *-*-beos*)
3441     glib_os="#define G_OS_BEOS"
3442     ;;
3443   *-*-cygwin*)
3444     glib_os="#define G_OS_UNIX
3445 #define G_PLATFORM_WIN32
3446 #define G_WITH_CYGWIN"
3447     ;;
3448   *-*-mingw*)
3449     glib_os="#define G_OS_WIN32
3450 #define G_PLATFORM_WIN32"
3451     ;;
3452   *)
3453     glib_os="#define G_OS_UNIX"
3454     ;;
3455 esac
3456 glib_static_compilation=""
3457 if test x$glib_win32_static_compilation = xyes; then
3458   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3459 #define GOBJECT_STATIC_COMPILATION 1"
3460 fi
3461 ])
3462
3463 # Redo enough to get guint32 and guint64 for the alignment checks below
3464 case 4 in
3465 $ac_cv_sizeof_short)
3466   gint32=short
3467   ;;
3468 $ac_cv_sizeof_int)
3469   gint32=int
3470   ;;
3471 $ac_cv_sizeof_long)
3472   gint32=long
3473   ;;
3474 esac
3475 case 8 in
3476 $ac_cv_sizeof_int)
3477   gint64=int
3478   ;;
3479 $ac_cv_sizeof_long)
3480   gint64=long
3481   ;;
3482 $ac_cv_sizeof_long_long)
3483   gint64='long long'
3484   ;;
3485 $ac_cv_sizeof___int64)
3486   gint64='__int64'
3487   ;;
3488 esac
3489
3490 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3491 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3492 typedef unsigned $gint32 guint32;])
3493 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3494 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3495 typedef unsigned $gint64 guint64;])
3496 AC_CHECK_TYPE([unsigned long])
3497 AC_CHECK_ALIGNOF([unsigned long])
3498
3499 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3500 #
3501 # 1.2.14 required for dbus_message_set_serial
3502 AS_IF([ test x$enable_modular_tests = xyes], [
3503    PKG_CHECK_MODULES(DBUS1,
3504                      dbus-1 >= 1.2.14,
3505                      [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3506                      have_dbus1=no)
3507    AC_SUBST(DBUS1_CFLAGS)
3508    AC_SUBST(DBUS1_LIBS)
3509 ])
3510 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3511
3512 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3513 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3514
3515 dnl
3516 dnl Check for -Bsymbolic-functions linker flag used to avoid
3517 dnl intra-library PLT jumps, if available.
3518 dnl
3519
3520 AC_ARG_ENABLE(Bsymbolic,
3521               [AS_HELP_STRING([--disable-Bsymbolic],
3522                               [avoid linking with -Bsymbolic])],,
3523               [SAVED_LDFLAGS="${LDFLAGS}"
3524                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3525                LDFLAGS=-Wl,-Bsymbolic-functions
3526                AC_TRY_LINK([], [int main (void) { return 0; }],
3527                            AC_MSG_RESULT(yes)
3528                            enable_Bsymbolic=yes,
3529                            AC_MSG_RESULT(no)
3530                            enable_Bsymbolic=no)
3531                LDFLAGS="${SAVED_LDFLAGS}"])
3532
3533 if test "x${enable_Bsymbolic}" = "xyes"; then
3534   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3535 fi
3536
3537 AC_SUBST(GLIB_LINK_FLAGS)
3538
3539 dnl Compiler flags; macro originates from systemd
3540 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3541 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
3542    -Wall -Wstrict-prototypes -Werror=declaration-after-statement \
3543    -Werror=missing-prototypes -Werror=implicit-function-declaration \
3544    -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3545    -Werror=format=2 -Werror=missing-include-dirs])
3546 CFLAGS="$CFLAGS $with_cflags"
3547
3548 #
3549 # Define variables corresponding to the correct include paths to use for
3550 # in-tree building.
3551 #
3552
3553 # for config.h:
3554 config_h_INCLUDES='-I$(top_builddir)'
3555 AC_SUBST(config_h_INCLUDES)
3556
3557 # glib:
3558 #   config.h
3559 #   $(top_builddir)/glib: for glibconfig.h
3560 #   $(top_srcdir)/glib:   for glib.h
3561 #   $(top_srcdir):        for everything
3562 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3563 AC_SUBST(glib_INCLUDES)
3564
3565 # gthread:
3566 #   same as glib
3567 gthread_INCLUDES='$(glib_INCLUDES)'
3568 AC_SUBST(gthread_INCLUDES)
3569
3570 # gobject:
3571 #   same as gthread
3572 gobject_INCLUDES='$(gthread_INCLUDES)'
3573 AC_SUBST(gobject_INCLUDES)
3574
3575 # gmodule:
3576 #   glib includes
3577 #   $(top_srcdir)/gmodule: for gmodule.h
3578 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3579 AC_SUBST(gmodule_INCLUDES)
3580
3581 # gio:
3582 #   same as gmodule
3583 gio_INCLUDES='$(gmodule_INCLUDES)'
3584 AC_SUBST(gio_INCLUDES)
3585
3586
3587 AC_CONFIG_FILES([
3588 glib-2.0.pc
3589 gmodule-2.0.pc
3590 gmodule-export-2.0.pc
3591 gmodule-no-export-2.0.pc
3592 gthread-2.0.pc
3593 gobject-2.0.pc
3594 gio-2.0.pc
3595 gio-unix-2.0.pc
3596 gio-windows-2.0.pc
3597 glib-zip
3598 glib-gettextize
3599 Makefile
3600 build/Makefile
3601 build/win32/Makefile
3602 build/win32/dirent/Makefile
3603 build/win32/vs9/Makefile
3604 build/win32/vs10/Makefile
3605 glib/Makefile
3606 glib/glib.stp
3607 glib/libcharset/Makefile
3608 glib/gnulib/Makefile
3609 glib/pcre/Makefile
3610 glib/update-pcre/Makefile
3611 glib/tests/Makefile
3612 gmodule/Makefile
3613 gmodule/gmoduleconf.h
3614 gobject/Makefile
3615 gobject/gobject.stp
3616 gobject/glib-mkenums
3617 gobject/tests/Makefile
3618 gthread/Makefile
3619 gio/Makefile
3620 gio/gdbus-2.0/codegen/Makefile
3621 gio/gdbus-2.0/codegen/config.py
3622 gio/xdgmime/Makefile
3623 gio/inotify/Makefile
3624 gio/kqueue/Makefile
3625 gio/fen/Makefile
3626 gio/fam/Makefile
3627 gio/win32/Makefile
3628 gio/tests/Makefile
3629 gio/tests/gdbus-object-manager-example/Makefile
3630 po/Makefile.in
3631 docs/Makefile
3632 docs/reference/Makefile
3633 docs/reference/glib/Makefile
3634 docs/reference/glib/version.xml
3635 docs/reference/gobject/Makefile
3636 docs/reference/gobject/version.xml
3637 docs/reference/gio/Makefile
3638 docs/reference/gio/gdbus-object-manager-example/Makefile
3639 docs/reference/gio/version.xml
3640 tests/Makefile
3641 tests/gobject/Makefile
3642 tests/refcount/Makefile
3643 m4macros/Makefile
3644 ])
3645
3646 AC_CONFIG_COMMANDS([chmod-scripts],
3647 [chmod 0755 glib-zip
3648 chmod 0755 glib-gettextize
3649 chmod 0755 gobject/glib-mkenums])
3650
3651 # we want to invoke this macro solely so that the config.status script
3652 # and automake generated makefiles know about these generated files.
3653 # They are only needed to distcheck the package
3654 if false; then
3655   AC_CONFIG_FILES([
3656     INSTALL
3657     README
3658     config.h.win32
3659     glib/glibconfig.h.win32
3660     glib/makefile.msc
3661     glib/glib.rc
3662     gmodule/makefile.msc
3663     gmodule/gmodule.rc
3664     gobject/makefile.msc
3665     gobject/gobject.rc
3666     gthread/makefile.msc
3667     gthread/gthread.rc
3668     gio/gio.rc
3669     tests/makefile.msc
3670   ])
3671 fi
3672
3673 AC_OUTPUT