configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Configure input file for elfutils.                     -*-autoconf-*-
   3 dnl
   4 dnl Copyright (C) 1996-2016 Red Hat, Inc.
   5 dnl
   6 dnl This file is part of elfutils.
   7 dnl
   8 dnl  This file is free software; you can redistribute it and/or modify
   9 dnl  it under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 3 of the License, or
  11 dnl  (at your option) any later version.
  12 dnl
  13 dnl  elfutils is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl  GNU General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 AC_INIT([elfutils],[0.167],[https://bugzilla.redhat.com/],[elfutils])
  21
  22 # We want eu- as default program prefix if none was given by the user.
  23 # But if the user explicitly provided --program-prefix="" then pretend
  24 # it wasn't set at all (NONE). We want to test this really early before
  25 # configure has a chance to use the value.
  26
  27 if test "x$program_prefix" = "xNONE"; then
  28   AC_MSG_NOTICE([No --program-prefix given, using "eu-"])
  29   program_prefix="eu-"
  30 elif test "x$program_prefix" = "x"; then
  31   AC_MSG_NOTICE([Using no program-prefix])
  32   program_prefix=NONE
  33 fi
  34
  35 AC_CONFIG_AUX_DIR([config])
  36 AC_CONFIG_FILES([config/Makefile])
  37
  38 AC_COPYRIGHT([Copyright (C) 1996-2016 Red Hat, Inc.])
  39 AC_PREREQ(2.63)                 dnl Minimum Autoconf version required.
  40
  41 dnl We use GNU make extensions; automake 1.10 defaults to -Wportability.
  42 AM_INIT_AUTOMAKE([gnits 1.11 -Wno-portability dist-bzip2 no-dist-gzip parallel-tests])
  43 AM_MAINTAINER_MODE
  44
  45 AM_SILENT_RULES([yes])
  46
  47 AC_CONFIG_SRCDIR([libelf/libelf.h])
  48 AC_CONFIG_FILES([Makefile])
  49 AC_CONFIG_HEADERS([config.h])
  50
  51 AC_CONFIG_MACRO_DIR([m4])
  52 AC_CONFIG_FILES([m4/Makefile])
  53
  54 dnl The RPM spec file.  We substitute a few values in the file.
  55 AC_CONFIG_FILES([elfutils.spec:config/elfutils.spec.in])
  56
  57
  58 AC_CANONICAL_HOST
  59
  60 AC_ARG_ENABLE(deterministic-archives,
  61 [AS_HELP_STRING([--enable-deterministic-archives],
  62                 [ar and ranlib default to -D behavior])], [
  63 if test "${enableval}" = no; then
  64   default_ar_deterministic=false
  65 else
  66   default_ar_deterministic=true
  67 fi], [default_ar_deterministic=false])
  68 AC_DEFINE_UNQUOTED(DEFAULT_AR_DETERMINISTIC, $default_ar_deterministic,
  69                    [Should ar and ranlib use -D behavior by default?])
  70
  71 AC_ARG_ENABLE([thread-safety],
  72 AS_HELP_STRING([--enable-thread-safety],
  73                [enable thread safety of libraries EXPERIMENTAL]),
  74                use_locks=$enableval, use_locks=no)
  75 AM_CONDITIONAL(USE_LOCKS, test "$use_locks" = yes)
  76 AS_IF([test "$use_locks" = yes], [AC_DEFINE(USE_LOCKS)])
  77 AS_IF([test "$use_locks" = yes],
  78       [AC_MSG_WARN([thread-safety is EXPERIMENTAL tests might fail.])])
  79
  80 AH_TEMPLATE([USE_LOCKS], [Defined if libraries should be thread-safe.])
  81
  82 AC_PROG_CC
  83 AC_PROG_RANLIB
  84 AC_PROG_YACC
  85 AM_PROG_LEX
  86 # Only available since automake 1.12
  87 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  88 AC_CHECK_TOOL([READELF], [readelf])
  89 AC_CHECK_TOOL([NM], [nm])
  90
  91 # We use -std=gnu99 but have explicit checks for some language constructs
  92 # and GNU extensions since some compilers claim GNU99 support, but don't
  93 # really support all language extensions. In particular we need
  94 # Mixed Declarations and Code
  95 # https://gcc.gnu.org/onlinedocs/gcc/Mixed-Declarations.html
  96 # Nested Functions
  97 # https://gcc.gnu.org/onlinedocs/gcc/Nested-Functions.html
  98 # Arrays of Variable Length
  99 # https://gcc.gnu.org/onlinedocs/gcc/Variable-Length.html
 100 AC_CACHE_CHECK([for gcc with GNU99 support], ac_cv_c99, [dnl
 101 old_CFLAGS="$CFLAGS"
 102 CFLAGS="$CFLAGS -std=gnu99"
 103 AC_COMPILE_IFELSE([AC_LANG_SOURCE([dnl
 104 int foo (int a)
 105 {
 106   for (int i = 0; i < a; ++i) if (i % 4) break; int s = a; return s;
 107 }
 108
 109 double bar (double a, double b)
 110 {
 111   double square (double z) { return z * z; }
 112   return square (a) + square (b);
 113 }
 114
 115 void baz (int n)
 116 {
 117   struct S { int x[[n]]; };
 118 }])],
 119                   ac_cv_c99=yes, ac_cv_c99=no)
 120 CFLAGS="$old_CFLAGS"])
 121 AS_IF([test "x$ac_cv_c99" != xyes],
 122       AC_MSG_ERROR([gcc with GNU99 support required]))
 123
 124 AC_CACHE_CHECK([for __thread support], ac_cv_tls, [dnl
 125 # Use the same flags that we use for our DSOs, so the test is representative.
 126 # Some old compiler/linker/libc combinations fail some ways and not others.
 127 save_CFLAGS="$CFLAGS"
 128 save_LDFLAGS="$LDFLAGS"
 129 CFLAGS="-fPIC $CFLAGS"
 130 LDFLAGS="-shared -Wl,-z,defs,-z,relro $LDFLAGS"
 131 AC_LINK_IFELSE([dnl
 132 AC_LANG_PROGRAM([[#include <stdlib.h>
 133 #undef __thread
 134 static __thread int a; int foo (int b) { return a + b; }]],
 135                 [[exit (foo (0));]])],
 136                ac_cv_tls=yes, ac_cv_tls=no)
 137 CFLAGS="$save_CFLAGS"
 138 LDFLAGS="$save_LDFLAGS"])
 139 AS_IF([test "x$ac_cv_tls" != xyes],
 140       AC_MSG_ERROR([__thread support required]))
 141
 142 dnl This test must come as early as possible after the compiler configuration
 143 dnl tests, because the choice of the file model can (in principle) affect
 144 dnl whether functions and headers are available, whether they work, etc.
 145 AC_SYS_LARGEFILE
 146
 147 dnl enable debugging of branch prediction.
 148 AC_ARG_ENABLE([debugpred],
 149 AS_HELP_STRING([--enable-debugpred],[build binaries with support to debug branch prediction]),
 150 [use_debugpred=$enableval], [use_debugpred=no])
 151 case $use_debugpred in
 152  yes) use_debugpred_val=1 ;;
 153  *)   use_debugpred_val=0 ;;
 154 esac
 155 AC_SUBST([DEBUGPRED], $use_debugpred_val)
 156
 157 dnl Enable gprof suport.
 158 AC_ARG_ENABLE([gprof],
 159 AS_HELP_STRING([--enable-gprof],[build binaries with gprof support]), [use_gprof=$enableval], [use_gprof=no])
 160 if test "$use_gprof" = yes; then
 161   CFLAGS="$CFLAGS -pg"
 162   LDFLAGS="$LDFLAGS -pg"
 163 fi
 164 AM_CONDITIONAL(GPROF, test "$use_gprof" = yes)
 165
 166 # Enable gcov suport.
 167 AC_ARG_ENABLE([gcov],
 168 AS_HELP_STRING([--enable-gcov],[build binaries with gcov support]), [use_gcov=$enableval], [use_gcov=no])
 169 if test "$use_gcov" = yes; then
 170   CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 171   LDFLAGS="$LDFLAGS -fprofile-arcs"
 172 fi
 173 AM_CONDITIONAL(GCOV, test "$use_gcov" = yes)
 174
 175 AC_ARG_ENABLE([sanitize-undefined],
 176               AS_HELP_STRING([--enable-sanitize-undefined],
 177                              [Use gcc undefined behaviour sanitizer]),
 178                              [use_undefined=$enableval], [use_undefined=no])
 179 if test "$use_undefined" = yes; then
 180   old_CFLAGS="$CFLAGS"
 181   old_CXXFLAGS="$CXXFLAGS"
 182   # We explicitly use unaligned access when possible (see ALLOW_UNALIGNED)
 183   # We want to fail immediately on first error, don't try to recover.
 184   CFLAGS="$CFLAGS -fsanitize=undefined -fno-sanitize-recover"
 185   CXXFLAGS="$CXXFLAGS -fsanitize=undefined -fno-sanitize-recover"
 186   AC_LINK_IFELSE([AC_LANG_SOURCE([int main (int argc, char **argv) { return 0; }])], use_undefined=yes, use_undefined=no)
 187   AS_IF([test "x$use_undefined" != xyes],
 188         AC_MSG_WARN([gcc undefined behaviour sanitizer not available])
 189         CFLAGS="$old_CFLAGS" CXXFLAGS="$old_CXXFLAGS")
 190 fi
 191 case $use_undefined in
 192  yes) check_undefined_val=1 ;;
 193  *)   check_undefined_val=0 ;;
 194 esac
 195 AC_DEFINE_UNQUOTED(CHECK_UNDEFINED, $check_undefined_val,
 196                    [Building with -fsanitize=undefined or not])
 197
 198 AC_ARG_ENABLE([valgrind],
 199 AS_HELP_STRING([--enable-valgrind],[run all tests under valgrind]),
 200 [use_valgrind=$enableval], [use_valgrind=no])
 201 if test "$use_valgrind" = yes; then
 202   AC_CHECK_PROG(HAVE_VALGRIND, valgrind, yes, no)
 203   if test "$HAVE_VALGRIND" = "no"; then
 204     AC_MSG_ERROR([valgrind not found])
 205   fi
 206 fi
 207 AM_CONDITIONAL(USE_VALGRIND, test "$use_valgrind" = yes)
 208
 209 AM_CONDITIONAL(BUILD_STATIC, [dnl
 210 test "$use_gprof" = yes -o "$use_gcov" = yes])
 211
 212 AC_ARG_ENABLE([tests-rpath],
 213 AS_HELP_STRING([--enable-tests-rpath],[build $ORIGIN-using rpath into tests]),
 214                [tests_use_rpath=$enableval], [tests_use_rpath=no])
 215 AM_CONDITIONAL(TESTS_RPATH, test "$tests_use_rpath" = yes)
 216
 217 LIBEBL_SUBDIR="$PACKAGE"
 218 AC_ARG_ENABLE([libebl-subdir],
 219 AS_HELP_STRING([--enable-libebl-subdir=DIR],
 220 [install libebl_CPU modules in $(libdir)/DIR]), [dnl
 221 LIBEBL_SUBDIR="$enable_libebl_subdir"])
 222 AC_SUBST([LIBEBL_SUBDIR])
 223 AC_DEFINE_UNQUOTED(LIBEBL_SUBDIR, "$LIBEBL_SUBDIR")
 224 AH_TEMPLATE([LIBEBL_SUBDIR], [$libdir subdirectory containing libebl modules.])
 225
 226 dnl zlib is mandatory.
 227 save_LIBS="$LIBS"
 228 LIBS=
 229 eu_ZIPLIB(zlib,ZLIB,z,gzdirect,gzip)
 230 AS_IF([test "x$with_zlib" = xno], [AC_MSG_ERROR([zlib not found but is required])])
 231 LIBS="$save_LIBS"
 232
 233 dnl Test for bzlib and xz/lzma, gives BZLIB/LZMALIB .am
 234 dnl conditional and config.h USE_BZLIB/USE_LZMALIB #define.
 235 save_LIBS="$LIBS"
 236 LIBS=
 237 eu_ZIPLIB(bzlib,BZLIB,bz2,BZ2_bzdopen,bzip2)
 238 # We need this since bzip2 doesn't have a pkgconfig file.
 239 BZ2_LIB="$LIBS"
 240 AC_SUBST([BZ2_LIB])
 241 eu_ZIPLIB(lzma,LZMA,lzma,lzma_auto_decoder,[LZMA (xz)])
 242 AS_IF([test "x$with_lzma" = xyes], [LIBLZMA="liblzma"], [LIBLZMA=""])
 243 AC_SUBST([LIBLZMA])
 244 zip_LIBS="$LIBS"
 245 LIBS="$save_LIBS"
 246 AC_SUBST([zip_LIBS])
 247
 248 AC_CHECK_DECLS([memrchr, rawmemchr],[],[],
 249                [#define _GNU_SOURCE
 250                 #include <string.h>])
 251 AC_CHECK_DECLS([powerof2],[],[],[#include <sys/param.h>])
 252
 253 AC_CHECK_LIB([stdc++], [__cxa_demangle], [dnl
 254 AC_DEFINE([USE_DEMANGLE], [1], [Defined if demangling is enabled])])
 255 AM_CONDITIONAL(DEMANGLE, test "x$ac_cv_lib_stdcpp___cxa_demangle" = "xyes")
 256 AS_IF([test "x$ac_cv_lib_stdcpp___cxa_demangle" = "xyes"],
 257       [enable_demangler=yes],[enable_demangler=no])
 258
 259 AC_ARG_ENABLE([textrelcheck],
 260 AS_HELP_STRING([--disable-textrelcheck],
 261                [Disable textrelcheck being a fatal error]))
 262 AM_CONDITIONAL(FATAL_TEXTREL, [test "x$enable_textrelcheck" != "xno"])
 263 AS_IF([test "x$enable_textrelcheck" != "xno"],
 264       [enable_textrelcheck=yes],[enable_textrelcheck=no])
 265
 266 AC_ARG_ENABLE([symbol-versioning],
 267 AS_HELP_STRING([--disable-symbol-versioning],
 268                [Disable symbol versioning in shared objects]))
 269 AM_CONDITIONAL(SYMBOL_VERSIONING, [test "x$enable_symbol_versioning" != "xno"])
 270 AS_IF([test "x$enable_symbol_versioning" = "xno"],
 271       [AC_MSG_WARN([Disabling symbol versioning breaks ABI compatibility.])
 272        enable_symbol_versioning=no],[enable_symbol_versioning=yes])
 273
 274 AC_CACHE_CHECK([whether gcc accepts -Wstack-usage], ac_cv_stack_usage, [dnl
 275 old_CFLAGS="$CFLAGS"
 276 CFLAGS="$CFLAGS -Wstack-usage=262144 -Werror"
 277 AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 278                   ac_cv_stack_usage=yes, ac_cv_stack_usage=no)
 279 CFLAGS="$old_CFLAGS"])
 280 AM_CONDITIONAL(ADD_STACK_USAGE_WARNING, [test "x$ac_cv_stack_usage" != "xno"])
 281
 282 # -Wlogical-op was too fragile in the past, make sure we get a sane one.
 283 AC_CACHE_CHECK([whether gcc has a sane -Wlogical-op], ac_cv_logical_op, [dnl
 284 old_CFLAGS="$CFLAGS"
 285 CFLAGS="$CFLAGS -Wlogical-op -Werror"
 286 AC_COMPILE_IFELSE([AC_LANG_SOURCE(
 287         [#define FLAG 1
 288         int f (int r, int f) { return (r && (FLAG || (FLAG & f))); }])],
 289                   ac_cv_logical_op=yes, ac_cv_logical_op=no)
 290 CFLAGS="$old_CFLAGS"])
 291 AM_CONDITIONAL(SANE_LOGICAL_OP_WARNING,
 292                [test "x$ac_cv_logical_op" != "xno"])
 293
 294 # -Wduplicated-cond was added by GCC6
 295 AC_CACHE_CHECK([whether gcc accepts -Wduplicated-cond], ac_cv_duplicated_cond, [dnl
 296 old_CFLAGS="$CFLAGS"
 297 CFLAGS="$CFLAGS -Wduplicated-cond -Werror"
 298 AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 299                   ac_cv_duplicated_cond=yes, ac_cv_duplicated_cond=no)
 300 CFLAGS="$old_CFLAGS"])
 301 AM_CONDITIONAL(HAVE_DUPLICATED_COND_WARNING,
 302                [test "x$ac_cv_duplicated_cond" != "xno"])
 303
 304 # -Wnull-dereference was added by GCC6
 305 AC_CACHE_CHECK([whether gcc accepts -Wnull-dereference], ac_cv_null_dereference, [dnl
 306 old_CFLAGS="$CFLAGS"
 307 CFLAGS="$CFLAGS -Wnull-dereference -Werror"
 308 AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 309                   ac_cv_null_dereference=yes, ac_cv_null_dereference=no)
 310 CFLAGS="$old_CFLAGS"])
 311 AM_CONDITIONAL(HAVE_NULL_DEREFERENCE_WARNING,
 312                [test "x$ac_cv_null_dereference" != "xno"])
 313
 314 dnl Check if we have argp available from our libc
 315 AC_LINK_IFELSE(
 316         [AC_LANG_PROGRAM(
 317                 [#include <argp.h>],
 318                 [int argc=1; char *argv[]={"test"}; argp_parse(0,argc,&argv,0,0,0); return 0;]
 319                 )],
 320         [libc_has_argp="true"],
 321         [libc_has_argp="false"]
 322 )
 323
 324 dnl If our libc doesn't provide argp, then test for libargp
 325 if test "$libc_has_argp" = "false" ; then
 326         AC_MSG_WARN("libc does not have argp")
 327         AC_CHECK_LIB([argp], [argp_parse], [have_argp="true"], [have_argp="false"])
 328
 329         if test "$have_argp" = "false"; then
 330                 AC_MSG_ERROR("no libargp found")
 331         else
 332                 argp_LDADD="-largp"
 333         fi
 334 else
 335         argp_LDADD=""
 336 fi
 337 AC_SUBST([argp_LDADD])
 338
 339 dnl Check if we have <linux/bpf.h> for EM_BPF disassembly.
 340 AC_CHECK_HEADERS(linux/bpf.h)
 341 AM_CONDITIONAL(HAVE_LINUX_BPF_H, [test "x$ac_cv_header_linux_bpf_h" = "xyes"])
 342
 343 dnl The directories with content.
 344
 345 dnl Documentation.
 346 dnl Commented out for now.
 347 dnl AC_CONFIG_FILES([doc/Makefile])
 348
 349 dnl Support library.
 350 AC_CONFIG_FILES([lib/Makefile])
 351
 352 dnl ELF library.
 353 AC_CONFIG_FILES([libelf/Makefile])
 354
 355 dnl Higher-level ELF support library.
 356 AC_CONFIG_FILES([libebl/Makefile])
 357
 358 dnl DWARF-ELF Lower-level Functions support library.
 359 AC_CONFIG_FILES([libdwelf/Makefile])
 360
 361 dnl DWARF library.
 362 AC_CONFIG_FILES([libdw/Makefile])
 363
 364 dnl Higher-level DWARF support library.
 365 AC_CONFIG_FILES([libdwfl/Makefile])
 366
 367 dnl CPU handling library.
 368 AC_CONFIG_FILES([libcpu/Makefile])
 369
 370 dnl Assembler library.
 371 AM_CONDITIONAL(HAVE_LIBASM, true)dnl Used in tests/Makefile.am, which see.
 372 AC_CONFIG_FILES([libasm/Makefile])
 373
 374 dnl CPU-specific backend libraries.
 375 AC_CONFIG_FILES([backends/Makefile])
 376
 377 dnl Tools.
 378 AC_CONFIG_FILES([src/Makefile po/Makefile.in])
 379
 380 dnl Test suite.
 381 AM_CONDITIONAL(STANDALONE, false)dnl Used in tests/Makefile.am, which see.
 382 AC_CONFIG_FILES([tests/Makefile])
 383
 384 dnl pkgconfig files
 385 AC_CONFIG_FILES([config/libelf.pc config/libdw.pc])
 386
 387 # Get the definitions necessary to create the Makefiles in the po
 388 # subdirectories.  This is a small subset of the gettext rules.
 389 AC_SUBST(USE_NLS, yes)
 390 AM_PO_SUBDIRS
 391
 392 dnl Appended to the config.h file.
 393 dnl We hide all kinds of configuration magic in lib/eu-config.h.
 394 AH_BOTTOM([#include <eu-config.h>])
 395
 396 dnl Version compatibility header.
 397 AC_CONFIG_FILES([version.h:config/version.h.in])
 398 AC_SUBST([eu_version])
 399
 400 # 1.234<whatever> -> 1234<whatever>
 401 case "$PACKAGE_VERSION" in
 402 [[0-9]].*) eu_version=`echo "$PACKAGE_VERSION" | sed 's@\.@@'` ;;
 403 *)         AC_MSG_ERROR([confused by version number '$PACKAGE_VERSION']) ;;
 404 esac
 405 case "$eu_version" in
 406 *.*)
 407   # 1234.567 -> "1234", "567"
 408   eu_extra_version="${eu_version#*.}"
 409   eu_version="${eu_version%%.*}"
 410   case "$eu_extra_version" in
 411   [[0-9]][[0-9]][[0-9]]) ;;
 412   [[0-9]][[0-9]])       eu_extra_version="${eu_extra_version}0" ;;
 413   [[0-9]])              eu_extra_version="${eu_extra_version}00" ;;
 414   *) AC_MSG_ERROR([confused by version number '$PACKAGE_VERSION']) ;;
 415   esac
 416   ;;
 417 *)
 418   eu_extra_version=000
 419   ;;
 420 esac
 421
 422 case "$eu_version" in
 423       0[[0-9]][[0-9]][[0-9]]) eu_version="${eu_version#0}$eu_extra_version" ;;
 424 [[0-9]][[0-9]][[0-9]][[0-9]]) eu_version="${eu_version}$eu_extra_version" ;;
 425 [[0-9]][[0-9]][[0-9]])        eu_version="${eu_version}0$eu_extra_version" ;;
 426 [[0-9]][[0-9]])               eu_version="${eu_version}00$eu_extra_version";;
 427 *) AC_MSG_ERROR([confused by version number '$PACKAGE_VERSION']) ;;
 428 esac
 429
 430 # Round up to the next release API (x.y) version.
 431 eu_version=$(( (eu_version + 999) / 1000 ))
 432
 433 dnl Unique ID for this build.
 434 MODVERSION="Build for ${LIBEBL_SUBDIR} ${eu_version} ${ac_cv_build}"
 435 AC_SUBST([MODVERSION])
 436 AC_DEFINE_UNQUOTED(MODVERSION, "$MODVERSION")
 437 AH_TEMPLATE([MODVERSION], [Identifier for modules in the build.])
 438
 439 AC_CHECK_SIZEOF(long)
 440
 441 # On aarch64 before glibc 2.20 we would get the kernel user_pt_regs instead
 442 # of the user_regs_struct from sys/user.h. They are structurally the same
 443 # but we get either one or the other.
 444 AC_CHECK_TYPE([struct user_regs_struct],
 445               [sys_user_has_user_regs=yes], [sys_user_has_user_regs=no],
 446               [[#include <sys/ptrace.h>]
 447                [#include <sys/time.h>]
 448                [#include <sys/user.h>]])
 449 if test "$sys_user_has_user_regs" = "yes"; then
 450   AC_DEFINE(HAVE_SYS_USER_REGS, 1,
 451             [Define to 1 if <sys/user.h> defines struct user_regs_struct])
 452 fi
 453
 454 # On a 64-bit host where can can use $CC -m32, we'll run two sets of tests.
 455 # Likewise in a 32-bit build on a host where $CC -m64 works.
 456 utrace_BIARCH
 457 # `$utrace_biarch' will be `-m64' even on an uniarch i386 machine.
 458 CC_BIARCH="$CC $utrace_biarch"
 459 AC_SUBST([CC_BIARCH])
 460
 461 # In maintainer mode we really need flex and bison.
 462 # Otherwise we really need a release dir with maintainer files generated.
 463 if test "x$enable_maintainer_mode" = xyes; then
 464   AC_CHECK_PROG(HAVE_FLEX, flex, yes, no)
 465   if test "$HAVE_FLEX" = "no"; then
 466     AC_MSG_ERROR([flex needed in maintainer mode])
 467   fi
 468   AC_CHECK_PROG(HAVE_BISON, bison, yes, no)
 469   if test "$HAVE_BISON" = "no"; then
 470     AC_MSG_ERROR([bison needed in maintainer mode])
 471   fi
 472 else
 473   if test ! -f ${srcdir}/libdw/known-dwarf.h; then
 474     AC_MSG_ERROR([No libdw/known-dwarf.h. configure --enable-maintainer-mode])
 475   fi
 476 fi
 477
 478 # The testfiles are all compressed, we need bunzip2 when running make check
 479 AC_CHECK_PROG(HAVE_BUNZIP2, bunzip2, yes, no)
 480 if test "$HAVE_BUNZIP2" = "no"; then
 481   AC_MSG_WARN([No bunzip2, needed to run make check])
 482 fi
 483
 484 AC_OUTPUT
 485
 486 AC_MSG_NOTICE([
 487 =====================================================================
 488         elfutils: ${PACKAGE_VERSION} (eu_version: ${eu_version})
 489 =====================================================================
 490
 491     Prefix                             : ${prefix}
 492     Program prefix ("eu-" recommended) : ${program_prefix}
 493     Source code location               : ${srcdir}
 494     Maintainer mode                    : ${enable_maintainer_mode}
 495     libebl modules subdirectory        : ${LIBEBL_SUBDIR}
 496     build arch                         : ${ac_cv_build}
 497
 498   RECOMMENDED FEATURES (should all be yes)
 499     gzip support                       : ${with_zlib}
 500     bzip2 support                      : ${with_bzlib}
 501     lzma/xz support                    : ${with_lzma}
 502     libstdc++ demangle support         : ${enable_demangler}
 503     File textrel check                 : ${enable_textrelcheck}
 504     Symbol versioning                  : ${enable_symbol_versioning}
 505
 506   NOT RECOMMENDED FEATURES (should all be no)
 507     Experimental thread safety         : ${use_locks}
 508
 509   OTHER FEATURES
 510     Deterministic archives by default  : ${default_ar_deterministic}
 511     Native language support            : ${USE_NLS}
 512
 513   EXTRA TEST FEATURES (used with make check)
 514     have bunzip2 installed (required)  : ${HAVE_BUNZIP2}
 515     debug branch prediction            : ${use_debugpred}
 516     gprof support                      : ${use_gprof}
 517     gcov support                       : ${use_gcov}
 518     run all tests under valgrind       : ${use_valgrind}
 519     gcc undefined behaviour sanitizer  : ${use_undefined}
 520     use rpath in tests                 : ${tests_use_rpath}
 521     test biarch                        : ${utrace_cv_cc_biarch}
 522 ])