configure.ac

   1 AC_INIT([btrfs-progs],
   2         m4_esyscmd([./version.sh --configure]),
   3         [linux-btrfs@vger.kernel.org],,
   4         [http://btrfs.wiki.kernel.org])
   5
   6 dnl library version
   7 LIBBTRFS_MAJOR=0
   8 LIBBTRFS_MINOR=1
   9 LIBBTRFS_PATCHLEVEL=1
  10
  11 CFLAGS="-g -O1"
  12
  13 AC_PREREQ([2.60])
  14
  15 AC_CONFIG_AUX_DIR([config])
  16 dnl AC_USE_SYSTEM_EXTENSIONS must be called before any macros that run
  17 dnl the compiler (like AC_PROG_LIBTOOL) to avoid autoconf errors.
  18 AC_USE_SYSTEM_EXTENSIONS
  19
  20 AC_CONFIG_SRCDIR([btrfs.c])
  21 AC_PREFIX_DEFAULT([/usr])
  22
  23 AC_PROG_CC
  24 AC_CANONICAL_HOST
  25 AC_C_CONST
  26 AC_C_VOLATILE
  27 AC_C_BIGENDIAN
  28
  29 AC_SYS_LARGEFILE
  30
  31 AC_PROG_INSTALL
  32 AC_PROG_LN_S
  33 AC_PATH_PROG([AR], [ar])
  34
  35 AC_CHECK_FUNCS([openat], [],
  36         [AC_MSG_ERROR([cannot find openat() function])])
  37
  38 m4_ifndef([PKG_PROG_PKG_CONFIG],
  39   [m4_fatal([Could not locate the pkg-config autoconf
  40     macros. These are usually located in /usr/share/aclocal/pkg.m4.
  41     If your macros are in a different location, try setting the
  42     environment variable AL_OPTS="-I/other/macro/dir" before running
  43     ./autogen.sh or autoreconf again.])])
  44 PKG_PROG_PKG_CONFIG
  45
  46
  47 dnl
  48 dnl Calls pkg-config --static
  49 dnl
  50 AC_DEFUN([PKG_STATIC], [
  51   if AC_RUN_LOG([pkg-config --exists --print-errors "$2"]); then
  52     $1=`pkg-config --libs --static "$2"`
  53     AC_SUBST([$1])
  54   else
  55     AC_MSG_ERROR([pkg-config description of $2, needed for static build, is not available])
  56   fi
  57 ])
  58
  59
  60 AC_ARG_ENABLE([backtrace],
  61   AS_HELP_STRING([--disable-backtrace], [disable btrfs backtrace]),
  62   [], [enable_backtrace=yes]
  63 )
  64
  65 AS_IF([test "x$enable_backtrace" = xno], [
  66   AC_DEFINE([BTRFS_DISABLE_BACKTRACE], [1], [disable backtrace stuff in kerncompat.h ])
  67 ])
  68
  69 dnl Define <NAME>_LIBS= and <NAME>_CFLAGS= by pkg-config
  70 dnl
  71 dnl The default PKG_CHECK_MODULES() action-if-not-found is end the
  72 dnl execution with error. The static libs are optional.
  73
  74 PKG_CHECK_MODULES(BLKID, [blkid])
  75 PKG_STATIC(BLKID_LIBS_STATIC, [blkid])
  76
  77 PKG_CHECK_MODULES(UUID, [uuid])
  78 PKG_STATIC(UUID_LIBS_STATIC, [uuid])
  79
  80 PKG_CHECK_MODULES(ZLIB, [zlib])
  81 PKG_STATIC(ZLIB_LIBS_STATIC, [zlib])
  82
  83 dnl lzo library does not provide pkg-config, let use classic way
  84 AC_CHECK_LIB([lzo2], [lzo_version], [
  85         LZO2_LIBS="-llzo2"
  86         LZO2_CFLAGS=""
  87         LZO2_LIBS_STATIC="-llzo2"],[
  88         AC_MSG_ERROR([cannot find lzo2 library])
  89 ])
  90 AC_SUBST([LZO2_LIBS])
  91 AC_SUBST([LZO2_LIBS_STATIC])
  92 AC_SUBST([LZO2_CFLAGS])
  93
  94
  95 dnl library stuff
  96 AC_SUBST([LIBBTRFS_MAJOR])
  97 AC_SUBST([LIBBTRFS_MINOR])
  98 AC_SUBST([LIBBTRFS_PATCHLEVEL])
  99
 100 AC_CONFIG_HEADERS([config.h])
 101
 102 AC_CONFIG_FILES([
 103 Makefile
 104 version.h
 105 ])
 106
 107 AC_OUTPUT
 108
 109 AC_MSG_RESULT([
 110         ${PACKAGE_NAME} ${PACKAGE_VERSION}
 111
 112         prefix:            ${prefix}
 113         exec prefix:       ${exec_prefix}
 114
 115         bindir:            ${bindir}
 116         libdir:            ${libdir}
 117         includedir:        ${includedir}
 118
 119         compiler:          ${CC}
 120         cflags:            ${CFLAGS}
 121         ldflags:           ${LDFLAGS}
 122
 123         Type 'make' to compile.
 124 ])
 125