configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [7])
   5 m4_define([v_mic], [3])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v '\(export\|Unversioned directory\)' || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-07])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  15 m4_define([lt_cur], m4_eval(v_maj + v_min))
  16 m4_define([lt_rev], v_mic)
  17 m4_define([lt_age], v_min)
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20
  21 AC_INIT([eina], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  22 AC_PREREQ([2.59])
  23 AC_CONFIG_SRCDIR([configure.ac])
  24 AC_CONFIG_MACRO_DIR([m4])
  25
  26 AC_CONFIG_HEADERS([config.h])
  27 AH_TOP([
  28 #ifndef EFL_CONFIG_H__
  29 #define EFL_CONFIG_H__
  30 ])
  31 AH_BOTTOM([
  32 #endif /* EFL_CONFIG_H__ */
  33 ])
  34
  35 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_GNU_SOURCE
  39 AC_SYS_LARGEFILE
  40
  41 #lt_cv_deplibs_check_method='pass_all'
  42 AC_LIBTOOL_WIN32_DLL
  43 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  44 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  45 AC_PROG_LIBTOOL
  46
  47 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  48 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  49 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  50 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  51 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  52 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  53 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  54 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  55 version_info="lt_cur:lt_rev:lt_age"
  56 release_info="v_rel"
  57 AC_SUBST(version_info)
  58 AC_SUBST(release_info)
  59 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  60 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  61 VMAJ=v_maj
  62 AC_SUBST(VMAJ)
  63
  64
  65 ### Needed information
  66
  67 AC_CANONICAL_BUILD
  68 AC_CANONICAL_HOST
  69
  70 requirements_pc_eina=""
  71
  72 have_wince="no"
  73 have_win32="no"
  74 case "$host_os" in
  75    mingw32ce*)
  76       have_win32="yes"
  77       have_wince="yes"
  78       MODULE_ARCH="$host_os-$host_cpu"
  79       MODULE_EXT=".dll"
  80       ;;
  81    mingw*)
  82       have_win32="yes"
  83       MODULE_ARCH="$host_os-$host_cpu-v_maj.v_min.v_mic"
  84       MODULE_EXT=".dll"
  85       ;;
  86    *)
  87       MODULE_ARCH="$host_os-$host_cpu-v_maj.v_min.v_mic"
  88       MODULE_EXT=".so"
  89       ;;
  90 esac
  91 AM_CONDITIONAL([EINA_HAVE_WINCE], [test "x$have_wince" = "xyes"])
  92 AM_CONDITIONAL([EINA_HAVE_WIN32], [test "x$have_win32" = "xyes"])
  93 AC_SUBST([MODULE_ARCH])
  94 AC_DEFINE_UNQUOTED([MODULE_ARCH], ["${MODULE_ARCH}"], ["Module architecture"])
  95 AC_DEFINE_UNQUOTED([SHARED_LIB_SUFFIX], ["${MODULE_EXT}"], [Suffix for shared objects])
  96
  97 EFL_CHECK_CPU_MMX([have_mmx="yes"], [have_mmx="no"])
  98 EFL_CHECK_CPU_SSE([have_sse="yes"], [have_sse="no"])
  99 EFL_CHECK_CPU_SSE2([have_sse2="yes"], [have_sse2="no"])
 100 EFL_CHECK_CPU_ALTIVEC([have_altivec="yes"], [have_altivec="no"])
 101
 102 EFL_CHECK_THREADS
 103
 104 if ! test "x${efl_have_threads}" = "xno" ; then
 105    EINA_CONFIGURE_HAVE_THREADS="#define EINA_HAVE_THREADS"
 106 fi
 107 AC_SUBST(EINA_CONFIGURE_HAVE_THREADS)
 108 AM_CONDITIONAL([EINA_HAVE_THREADS], [! test "x${efl_have_threads}" = "xno"])
 109
 110 if test "x${efl_have_debug_threads}" = "xyes"; then
 111    EINA_CONFIGURE_HAVE_DEBUG_THREADS="#define EINA_HAVE_DEBUG_THREADS"
 112 fi
 113 AC_SUBST(EINA_CONFIGURE_HAVE_DEBUG_THREADS)
 114 AM_CONDITIONAL([EINA_DEBUG_THREADS], [test "x${efl_have_debug_threads}" = "xyes"])
 115
 116 if ! test "x${efl_have_on_off_threads}" = "xno"; then
 117    EINA_CONFIGURE_HAVE_ON_OFF_THREADS="#define EINA_HAVE_ON_OFF_THREADS"
 118 fi
 119 AC_SUBST(EINA_CONFIGURE_HAVE_ON_OFF_THREADS)
 120 AM_CONDITIONAL([EINA_ON_OFF_THREADS], [! test "x${efl_have_on_off_threads}" = "xno"])
 121
 122 ### Additional options to configure
 123
 124 # Magic debug
 125 AC_ARG_ENABLE([magic-debug],
 126    [AC_HELP_STRING([--disable-magic-debug], [disable magic debug of eina structure @<:@default=enabled@:>@])],
 127    [
 128     if test "x${enableval}" = "xyes" ; then
 129        have_magic_debug="yes"
 130     else
 131        have_magic_debug="no"
 132     fi
 133    ],
 134    [have_magic_debug="yes"])
 135
 136 AC_MSG_CHECKING([whether magic debug is enable])
 137 AC_MSG_RESULT([${have_magic_debug}])
 138
 139 if test "x${have_magic_debug}" = "xyes" ; then
 140    EINA_CONFIGURE_MAGIC_DEBUG="#define EINA_MAGIC_DEBUG"
 141 fi
 142 AC_SUBST(EINA_CONFIGURE_MAGIC_DEBUG)
 143
 144 # Safety checks (avoid crashes on wrong api usage)
 145 AC_ARG_ENABLE(safety-checks,
 146    [AC_HELP_STRING([--disable-safety-checks], [disable safety checks for NULL pointers and like. @<:@default=enabled@:>@])],
 147    [
 148     if test "x${enableval}" = "xyes" ; then
 149        have_safety_checks="yes"
 150     else
 151        have_safety_checks="no"
 152     fi
 153    ],
 154    [have_safety_checks="yes"])
 155
 156 AC_MSG_CHECKING(whether to do safety checking on api parameters)
 157 AC_MSG_RESULT($have_safety_checks)
 158
 159 AM_CONDITIONAL(SAFETY_CHECKS, test "x$have_safety_checks" = "xyes")
 160 if test "x$have_safety_checks" = "xyes"; then
 161   AC_DEFINE(EINA_SAFETY_CHECKS, 1, [disable safety checks for NULL pointers and like.])
 162   EINA_CONFIGURE_SAFETY_CHECKS="#define EINA_SAFETY_CHECKS"
 163 fi
 164 AC_SUBST(EINA_CONFIGURE_SAFETY_CHECKS)
 165
 166 with_max_log_level="<unset>"
 167 AC_ARG_WITH(internal-maximum-log-level,
 168    [AC_HELP_STRING([--with-internal-maximum-log-level=NUMBER],
 169                    [limit eina internal log level to the given number, any call to EINA_LOG() with values greater than this will be compiled out, ignoring runtime settings, but saving function calls.])],
 170    [
 171     if test "x${withval}" != "xno"; then
 172        if echo "${withval}" | grep -E '^[[0-9]]+$' >/dev/null 2>/dev/null; then
 173           AC_MSG_NOTICE([ignoring any EINA_LOG() with level greater than ${withval}])
 174           AC_DEFINE_UNQUOTED(EINA_LOG_LEVEL_MAXIMUM, ${withval}, [if set, logging is limited to this amount.])
 175           with_max_log_level="${withval}"
 176        else
 177           AC_MSG_ERROR([--with-internal-maximum-log-level takes a decimal number, got "${withval}" instead.])
 178        fi
 179     fi
 180     ], [:])
 181
 182 AC_ARG_ENABLE([amalgamation],
 183    [AC_HELP_STRING([--enable-amalgamation], [enable generation of one single file with all source code in it, helps compiler optimizations.])],
 184    [if test "x${enableval}" = "xyes"; then
 185        do_amalgamation="yes"
 186     else
 187        do_amalgamation="no"
 188     fi
 189    ],
 190    [do_amalgamation="no"]
 191 )
 192 AM_CONDITIONAL(EINA_AMALGAMATION, test "x${do_amalgamation}" = "xyes")
 193
 194 # Choose best memory pool
 195 AC_ARG_ENABLE([default-mempool],
 196    [AC_HELP_STRING([--enable-default-mempool], [Default memory allocator could be faster for some computer. @<:@default=disabled@:>@])],
 197    [
 198     if test "x${enableval}" = "xyes"; then
 199        have_default_mempool="yes"
 200     else
 201        have_default_mempool="no"
 202     fi
 203    ],
 204    [have_default_mempool="no"]
 205 )
 206 AC_MSG_CHECKING([whether to use default mempool allocator])
 207 AC_MSG_RESULT([${have_default_mempool}])
 208
 209 if test "x${have_default_mempool}" = "xyes" ; then
 210    EINA_CONFIGURE_DEFAULT_MEMPOOL="#define EINA_DEFAULT_MEMPOOL"
 211 fi
 212 AC_SUBST(EINA_CONFIGURE_DEFAULT_MEMPOOL)
 213
 214 # Report stringshare usage
 215 AC_ARG_ENABLE([stringshare-usage],
 216    [AC_HELP_STRING([--enable-stringshare-usage], [Report stringshare usage on stringshare shutdown. @<:@default=disabled@:>@])],
 217    [
 218     if test "x${enableval}" = "xyes"; then
 219        have_stringshare_usage="yes"
 220     else
 221        have_stringshare_usage="no"
 222     fi
 223    ],
 224    [have_stringshare_usage="no"]
 225 )
 226 AC_MSG_CHECKING([whether to report stringshare usage])
 227 AC_MSG_RESULT([${have_stringshare_usage}])
 228
 229 if test "x${have_stringshare_usage}" = "xyes"; then
 230    AC_DEFINE(EINA_STRINGSHARE_USAGE, 1, [Report Eina stringshare usage pattern])
 231 fi
 232
 233 # Assert or fail.
 234
 235 AC_ARG_ENABLE([assert],
 236    [AC_HELP_STRING([--enable-assert], [enable assert, @<:@default=no@:>@])],
 237    [
 238     if test "x${enableval}" = "xyes" ; then
 239        prefer_assert="yes"
 240     else
 241        prefer_assert="no"
 242     fi
 243    ],
 244    [prefer_assert="no"])
 245
 246 # Check if we want to benchmark on real data
 247 enable_benchmark_e17="no"
 248 AC_ARG_ENABLE([e17],
 249    [AC_HELP_STRING([--enable-e17], [enable heavy benchmark @<:@default=no@:>@])],
 250    [
 251     if test "x${enableval}" = "xyes" ; then
 252        enable_benchmark_e17="yes"
 253     else
 254        enable_benchmark_e17="no"
 255     fi
 256    ],
 257    [enable_benchmark_e17="no"])
 258
 259 AC_MSG_CHECKING([whether e17 real data benchmark are built])
 260 AC_MSG_RESULT([${enable_benchmark_e17}])
 261
 262 AM_CONDITIONAL(EINA_ENABLE_BENCHMARK_E17, test "x${enable_benchmark_e17}" = "xyes")
 263
 264
 265 ### Checks for programs
 266 AC_PROG_CC
 267 #for src/tests...
 268 AC_PROG_CXX
 269
 270 # pkg-config
 271 PKG_PROG_PKG_CONFIG
 272
 273 # Check whether pkg-config supports Requires.private
 274 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 275    pkgconfig_requires_private="Requires.private"
 276 else
 277    pkgconfig_requires_private="Requires"
 278 fi
 279 AC_SUBST(pkgconfig_requires_private)
 280
 281 # doxygen program for documentation building
 282
 283 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 284
 285
 286 ### Checks for libraries
 287
 288 ## Compatibility layers
 289
 290 # Evil library for compilation on Windows
 291
 292 EFL_EINA_BUILD=""
 293 case "$host_os" in
 294    mingw*)
 295       PKG_CHECK_EXISTS([evil >= 1.6.99])
 296       AC_DEFINE([HAVE_EVIL], [1], [Set to 1 if Evil package is installed])
 297       requirements_pc_eina="${requirements_pc_eina} evil"
 298       EFL_EINA_BUILD="-DEFL_EINA_BUILD"
 299    ;;
 300 esac
 301 AC_SUBST([EFL_EINA_BUILD])
 302
 303 # Escape library for compilation on Playstation 3
 304
 305 case "$host_vendor" in
 306   ps3*)
 307       PKG_CHECK_EXISTS([escape])
 308       AC_DEFINE([HAVE_ESCAPE], [1], [Set to 1 if Escape package is installed])
 309       requirements_pc_eina="${requirements_pc_eina} escape"
 310     ;;
 311 esac
 312
 313 # Exotic library for copilation on Coyote
 314
 315 PKG_CHECK_EXISTS([exotic],
 316    [
 317     enable_exotic="yes"
 318     AC_DEFINE([HAVE_EXOTIC_H], [1], [Define to 1 if you have Exotic.])
 319     EINA_CONFIGURE_HAVE_EXOTIC="#define EINA_HAVE_EXOTIC"
 320     requirements_pc_eina="exotic ${requirements_pc_eina}"
 321    ],
 322    [enable_exotic="no"])
 323
 324 AM_CONDITIONAL([EINA_HAVE_EXOTIC], [test "x${enable_exotic}" = "xyes"])
 325 AC_SUBST([EINA_CONFIGURE_HAVE_EXOTIC])
 326
 327 if ! test "x${requirements_pc_eina}" = "x" ; then
 328    PKG_CHECK_MODULES([EINA], [${requirements_pc_eina}])
 329 fi
 330
 331 ## Options
 332
 333 # Valgrind
 334
 335 AC_ARG_ENABLE([valgrind],
 336    [AC_HELP_STRING([--enable-valgrind], [improve valgrind support by hinting it of our memory usages, having it to report proper mempool leaks.])],
 337    [
 338     if test "x${enableval}" = "xyes" ; then
 339        want_valgrind="yes"
 340     else
 341        want_valgrind="no"
 342     fi
 343    ],
 344    [want_valgrind="auto"])
 345
 346 AC_MSG_CHECKING([whether to enable build with valgrind])
 347 AC_MSG_RESULT([${want_valgrind}])
 348
 349 if test "x${want_valgrind}" = "xyes" || test "x${want_valgrind}" = "xauto"; then
 350    PKG_CHECK_MODULES([VALGRIND], [valgrind >= 2.4.0],
 351       [
 352        have_valgrind="yes"
 353        requirements_pc_eina="valgrind ${requirements_pc_eina}"
 354       ],
 355       [
 356        have_valgrind="no"
 357        AC_DEFINE([NVALGRIND], [1], [Valgrind support disabled])
 358        if test "x${want_valgrind}" = "xyes"; then
 359           AC_MSG_ERROR([Valgrind >= 2.4.0 is required])
 360        fi
 361       ])
 362 else
 363     AC_DEFINE([NVALGRIND], [1], [Valgrind support disabled])
 364 fi
 365
 366 ## Modules
 367
 368 # Check ememoa memory pool library
 369
 370 AC_ARG_ENABLE([ememoa],
 371    [AC_HELP_STRING([--enable-ememoa], [build ememoa memory pool module @<:@default=yes@:>@])],
 372    [
 373     if test "x${enableval}" = "xyes" ; then
 374        enable_ememoa="yes"
 375     else
 376        enable_ememoa="no"
 377     fi
 378    ],
 379    [enable_ememoa="yes"])
 380
 381 AC_MSG_CHECKING([whether to use ememoa for memory pool])
 382 AC_MSG_RESULT([${enable_ememoa}])
 383
 384 if test "x${enable_ememoa}" = "xyes" ; then
 385    PKG_CHECK_MODULES([EMEMOA],
 386       [ememoa >= 0.0.26 ],
 387       [enable_ememoa="yes"],
 388       [enable_ememoa="no"])
 389 fi
 390
 391 ## Examples
 392
 393 PKG_CHECK_MODULES([ECORE_EVAS],
 394    [ecore-evas ecore evas],
 395    [build_tiler_example="yes"],
 396    [build_tiler_example="no"])
 397
 398 AM_CONDITIONAL([BUILD_TILER_EXAMPLE], [test "x${build_tiler_example}" = "xyes"])
 399
 400 ### Checks for header files
 401 AC_HEADER_ASSERT
 402 AC_HEADER_TIME
 403 AC_HEADER_DIRENT
 404
 405 AC_CHECK_HEADERS([unistd.h libgen.h inttypes.h stdint.h sys/types.h siginfo.h strings.h execinfo.h mcheck.h])
 406
 407 # sys/mman.h could be provided by evil/escape/exotic so we need to set CFLAGS accordingly
 408 CFLAGS_save="${CFLAGS}"
 409 CFLAGS="${CFLAGS} ${EINA_CFLAGS}"
 410 AC_CHECK_HEADERS([sys/mman.h])
 411 CFLAGS="${CFLAGS_save}"
 412
 413 if test "x${ac_cv_header_inttypes_h}" = "xyes" ; then
 414    EINA_CONFIGURE_HAVE_INTTYPES_H="#define EINA_HAVE_INTTYPES_H"
 415    AC_DEFINE([HAVE_INTTYPES_H], [1], [Define to 1 if you have the <inttypes.h> header file.])
 416 fi
 417 AC_SUBST([EINA_CONFIGURE_HAVE_INTTYPES_H])
 418
 419 if test "x${ac_cv_header_inttypes_h}" = "xyes" ; then
 420     EINA_CONFIGURE_HAVE_STDINT_H="#define EINA_HAVE_STDINT_H"
 421     AC_DEFINE([HAVE_STDINT_H], [1], [Define to 1 if you have the <stdint.h> header file.])
 422 fi
 423 AC_SUBST([EINA_CONFIGURE_HAVE_STDINT_H])
 424
 425 ### Checks for types
 426
 427 # wchar_t
 428
 429 AC_CHECK_SIZEOF([wchar_t])
 430 EINA_SIZEOF_WCHAR_T=$ac_cv_sizeof_wchar_t
 431 AC_SUBST([EINA_SIZEOF_WCHAR_T])
 432 AC_CHECK_TYPES([siginfo_t], [], [],
 433    [[
 434 #include <signal.h>
 435 #if HAVE_SIGINFO_H
 436 # include <siginfo.h>
 437 #endif
 438    ]])
 439
 440 # struct dirent
 441
 442 AC_CHECK_TYPES([struct dirent], [have_dirent="yes"], [have_dirent="no"],
 443    [[
 444 #include <dirent.h>
 445    ]])
 446
 447 if test "x${have_dirent}" = "xyes" ; then
 448     EINA_CONFIGURE_HAVE_DIRENT_H="#define EINA_HAVE_DIRENT_H"
 449     AC_DEFINE([HAVE_DIRENT_H], [1], [Define to 1 if you have a valid <dirent.h> header file.])
 450 fi
 451 AC_SUBST([EINA_CONFIGURE_HAVE_DIRENT_H])
 452
 453 ### Checks for structures
 454
 455 ### Checks for compiler characteristics
 456 AC_C_BIGENDIAN
 457 AC_C_INLINE
 458 AC_PROG_CC_STDC
 459 EFL_ATTRIBUTE_UNUSED
 460
 461 m4_ifdef([v_mic],
 462    [
 463     EFL_COMPILER_FLAG([-Wall])
 464     EFL_COMPILER_FLAG([-W])
 465    ])
 466
 467 EFL_COMPILER_FLAG([-Wshadow])
 468
 469 EFL_CHECK_PATH_MAX
 470
 471 ### Checks for linker characteristics
 472 lt_enable_auto_import=""
 473 case "${host_os}" in
 474    mingw*)
 475       lt_enable_auto_import="-Wl,--enable-auto-import"
 476    ;;
 477 esac
 478 AC_SUBST([lt_enable_auto_import])
 479
 480 EFL_LINKER_FLAG([-fno-strict-aliasing])
 481
 482 ### Checks for library functions
 483 AC_FUNC_ALLOCA
 484
 485 AC_CHECK_FUNCS([strlcpy openat fstatat fpathconf execvp backtrace backtrace_symbols malloc_usable_size mtrace])
 486
 487 EFL_CHECK_FUNCS([eina], [dirfd dlopen dladdr fnmatch iconv shm_open setxattr])
 488
 489 want_debug_malloc="no"
 490 AC_ARG_ENABLE([debug-malloc],
 491    [AC_HELP_STRING([--enable-debug-malloc], [enable debugging of malloc usage overhead in our allocator @<:@default=enabled@:>@])],
 492    [
 493      if test "x${enableval}" = "xyes" ; then
 494         want_debug_malloc="yes"
 495      else
 496         want_debug_malloc="no"
 497      fi
 498    ], [want_debug_malloc="no"])
 499
 500 if test "x${ac_cv_func_malloc_usable_size}" = "xyes" && test "x${want_debug_malloc}" = "xyes"; then
 501    AC_DEFINE([EINA_DEBUG_MALLOC], [1], [Turn on debugging overhead in mempool])
 502 fi
 503
 504 AC_ARG_ENABLE([log],
 505    [AC_HELP_STRING([--disable-log], [disable Eina_Log infrastructure completly @<:@default=enabled@:>@])],
 506    [
 507     if test "x${enableval}" = "xyes" ; then
 508        want_log="yes"
 509     else
 510        want_log="no"
 511     fi
 512    ],
 513    [want_log="yes"])
 514
 515 enable_log="no"
 516 if test "x${efl_func_fnmatch}" = "xyes" && test "x${want_log}" = "xyes" ; then
 517    enable_log="yes"
 518 fi
 519
 520 AC_MSG_CHECKING([wether to build Eina_Log infrastructure])
 521 AC_MSG_RESULT([${enable_log}])
 522
 523 if test "x${enable_log}" = "xyes"; then
 524     EINA_CONFIGURE_ENABLE_LOG="#define EINA_ENABLE_LOG"
 525     AC_DEFINE([HAVE_LOG], [1], [Define to 1 if we log support is on])
 526 fi
 527 AC_SUBST([EINA_CONFIGURE_ENABLE_LOG])
 528
 529
 530 ### Modules
 531
 532 if test "x${have_default_mempool}" = "xyes" ; then
 533    enable_chained_pool="no"
 534    enable_pass_through="static"
 535 else
 536    enable_chained_pool="static"
 537    enable_pass_through="no"
 538 fi
 539
 540 enable_one_big="static"
 541
 542 EINA_CHECK_MODULE([chained-pool],   [${enable_chained_pool}], [chained pool])
 543 EINA_CHECK_MODULE([ememoa-fixed],   [${enable_ememoa}],       [ememoa fixed])
 544 EINA_CHECK_MODULE([ememoa-unknown], [${enable_ememoa}],       [ememoa unknown])
 545 EINA_CHECK_MODULE([fixed-bitmap],   [no],                     [fixed bitmap])
 546 EINA_CHECK_MODULE([pass-through],   [${enable_pass_through}], [pass through])
 547 EINA_CHECK_MODULE([buddy],          [no],                     [buddy])
 548 EINA_CHECK_MODULE([one-big],        [${enable_one_big}],      [one big])
 549
 550 ### Make the debug preprocessor configurable
 551
 552 ### Unit tests, coverage and benchmarking
 553
 554 EFL_CHECK_TESTS([eina], [enable_tests="yes"], [enable_tests="no"])
 555
 556 EFL_CHECK_BENCHMARK([enable_benchmark="yes"], [enable_benchmark="no"])
 557 EINA_BENCH_MODULE([glib], [${enable_benchmark}], [glib-2.0], [enable_benchmark_glib="yes"], [enable_benchmark_glib="no"])
 558 if test -n "$CXX" && test "x$enable_benchmark" = "xyes" ; then
 559    AC_DEFINE_UNQUOTED([CITYHASH_BENCH], [1], [enable bench tests for google hash method])
 560 fi
 561 AM_CONDITIONAL([CITYHASH_BENCH], [test -n "$CXX" && test "x$enable_benchmark" = "xyes"])
 562
 563 AC_SUBST([requirements_pc_eina])
 564 AC_SUBST([requirements_libs_eina])
 565
 566 ### Build and install examples
 567 EFL_CHECK_BUILD_EXAMPLES([enable_build_examples="yes"], [enable_build_examples="no"])
 568 EFL_CHECK_INSTALL_EXAMPLES([enable_install_examples="yes"], [enable_install_examples="no"])
 569
 570 AC_CONFIG_FILES([
 571 Makefile
 572 eina.pc
 573 eina.spec
 574 doc/Makefile
 575 doc/Doxyfile
 576 src/Makefile
 577 src/include/Makefile
 578 src/include/eina_config.h
 579 src/lib/Makefile
 580 src/modules/Makefile
 581 src/modules/mp/Makefile
 582 src/modules/mp/chained_pool/Makefile
 583 src/modules/mp/ememoa_fixed/Makefile
 584 src/modules/mp/ememoa_unknown/Makefile
 585 src/modules/mp/pass_through/Makefile
 586 src/modules/mp/fixed_bitmap/Makefile
 587 src/modules/mp/buddy/Makefile
 588 src/modules/mp/one_big/Makefile
 589 src/tests/Makefile
 590 src/examples/Makefile
 591 ])
 592
 593 AC_OUTPUT
 594
 595 #####################################################################
 596 ## Info
 597
 598 echo
 599 echo
 600 echo
 601 echo "------------------------------------------------------------------------"
 602 echo "$PACKAGE $VERSION"
 603 echo "------------------------------------------------------------------------"
 604 echo
 605 echo
 606 echo "Configuration Options Summary:"
 607 echo
 608 echo "  Magic debug..........: ${have_magic_debug}"
 609 echo "  Safety checks........: ${have_safety_checks}"
 610 echo "  Maximum log level....: ${with_max_log_level}"
 611 echo "  Report string usage..: ${have_stringshare_usage}"
 612 echo "  Valgrind support.....: ${have_valgrind}"
 613 echo "  Default mempool......: ${have_default_mempool}"
 614 echo "  Log support..........: ${enable_log}"
 615 echo "  Thread Support.......: ${efl_have_threads}"
 616 if test "${efl_have_threads}" = "POSIX" ; then
 617 echo "    spinlock...........: ${efl_have_posix_threads_spinlock}"
 618 echo "    debug usage........: ${efl_have_debug_threads}"
 619 echo "    on/off support.....: ${efl_have_on_off_threads}"
 620 fi
 621 echo "  Amalgamation.........: ${do_amalgamation}"
 622 echo "  Iconv support........: ${efl_func_iconv}"
 623 echo "  File dirfd...........: ${efl_func_dirfd}"
 624 echo "  File xattr...........: ${efl_func_setxattr}"
 625 echo "  shm_open.............: ${efl_func_shm_open}"
 626 echo
 627 echo "  Documentation........: ${build_doc}"
 628 echo "  Tests................: ${enable_tests} (Coverage: ${efl_enable_coverage})"
 629 echo "  Examples.............: ${enable_build_examples}"
 630 echo "  Tiler Example........: ${build_tiler_example}"
 631 echo "  Examples installed...: ${enable_install_examples}"
 632 echo "  Benchmark............: ${enable_benchmark}"
 633 if test "x${enable_benchmark}" = "xyes" ; then
 634 echo "    Glib...............: ${enable_benchmark_glib}"
 635 echo "    E17 real data......: ${enable_benchmark_e17}"
 636 fi
 637 echo
 638 echo "  CPU Specific Extensions:"
 639 echo "    MMX................: ${have_mmx}"
 640 echo "    SSE................: ${have_sse}"
 641 echo "    SSE2...............: ${have_sse2}"
 642 echo "    ALTIVEC............: ${have_altivec}"
 643 echo
 644 echo "  Memory pools:"
 645 echo "    Buddy..............: ${enable_buddy}"
 646 echo "    Chained pool.......: ${enable_chained_pool}"
 647 echo "    Ememoa fixed.......: ${enable_ememoa_fixed}"
 648 echo "    Ememoa unknown.....: ${enable_ememoa_unknown}"
 649 echo "    Fixed bitmap.......: ${enable_fixed_bitmap}"
 650 echo "    One big............: ${enable_one_big}"
 651 echo "    Pass through.......: ${enable_pass_through}"
 652 echo
 653 echo "Compilation............: make (or gmake)"
 654 echo "  CPPFLAGS.............: $CPPFLAGS"
 655 echo "  CFLAGS...............: $CFLAGS"
 656 echo "  LDFLAGS..............: $LDFLAGS"
 657 echo
 658 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 659 echo "  prefix...............: $prefix"
 660 echo
 661 EFL_FORM_VOLTRON