configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [32])
  34 m4_define([glib_micro_version], [2])
  35 m4_define([glib_interface_age], [2])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  58
  59 AC_CONFIG_HEADER([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS+set}
  65
  66 AM_INIT_AUTOMAKE([1.11 no-define no-dist-gzip dist-xz tar-ustar])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114
 115 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 116
 117 AC_CANONICAL_HOST
 118
 119 AC_MSG_CHECKING([for the BeOS])
 120 case $host in
 121   *-*-beos*)
 122     glib_native_beos="yes"
 123     ;;
 124   *)
 125     glib_native_beos="no"
 126     ;;
 127 esac
 128 AC_MSG_RESULT([$glib_native_beos])
 129
 130 dnl
 131
 132 AC_MSG_CHECKING([for Win32])
 133 LIB_EXE_MACHINE_FLAG=X86
 134 case "$host" in
 135   *-*-mingw*)
 136     glib_native_win32=yes
 137     glib_pid_type='void *'
 138     glib_cv_stack_grows=no
 139     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 140     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 141     # (Sorry, I don't know exactly what is the problem, but it is related to
 142     # floating point formatting and decimal point vs. comma.)
 143     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 144     # rigorous enough to notice, though.
 145     # So preset the autoconf cache variables.
 146     ac_cv_func_vsnprintf_c99=no
 147     ac_cv_func_snprintf_c99=no
 148     case "$host" in
 149     x86_64-*-*)
 150       LIB_EXE_MACHINE_FLAG=X64
 151       ;;
 152     esac
 153     ;;
 154   *)
 155     glib_native_win32=no
 156     glib_pid_type=int
 157     ;;
 158 esac
 159 case $host in
 160   *-*-linux*)
 161     glib_os_linux=yes
 162     ;;
 163 esac
 164
 165 AC_MSG_RESULT([$glib_native_win32])
 166
 167 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 168
 169 glib_have_carbon=no
 170 AC_MSG_CHECKING([for Mac OS X Carbon support])
 171 AC_TRY_CPP([
 172 #include <Carbon/Carbon.h>
 173 #include <CoreServices/CoreServices.h>
 174 ], glib_have_carbon=yes)
 175
 176 AC_MSG_RESULT([$glib_have_carbon])
 177
 178 glib_have_cocoa=no
 179 AC_MSG_CHECKING([for Mac OS X Cocoa support])
 180 AC_TRY_CPP([
 181 #include <Cocoa/Cocoa.h>
 182 ], glib_have_cocoa=yes)
 183
 184 AC_MSG_RESULT([$glib_have_cocoa])
 185
 186 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 187 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 188 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 189 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 190 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 191 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
 192
 193 if test "$glib_native_win32" = "yes"; then
 194   AC_CHECK_TOOL(WINDRES, windres, no)
 195   if test "$WINDRES" = no; then
 196     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 197   fi
 198   AC_CHECK_TOOL(NM, nm, no)
 199   if test "$NM" = no; then
 200     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 201   fi
 202   AC_CHECK_TOOL(RANLIB, ranlib, :)
 203   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 204 fi
 205 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 206
 207 if test "$glib_native_win32" != yes; then
 208     # libtool option to control which symbols are exported
 209     # right now, symbols starting with _ are not exported
 210     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 211 else
 212     # We currently use .def files on Windows
 213     LIBTOOL_EXPORT_OPTIONS=
 214 fi
 215 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 216
 217 if test "x$glib_have_carbon" = "xyes"; then
 218   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 219   LDFLAGS="$LDFLAGS -framework Carbon"
 220 fi
 221
 222 if test "x$glib_have_cocoa" = "xyes"; then
 223   AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
 224   LDFLAGS="$LDFLAGS -framework Foundation"
 225 fi
 226
 227 gl_GLIBC21
 228 if test "x$GLIBC21" = "xyes"; then
 229   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 230 fi
 231
 232 dnl declare --enable-* args and collect ac_help strings
 233 AC_ARG_ENABLE(debug,
 234               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 235                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 236               enable_debug=glib_debug_default)
 237
 238 AC_ARG_ENABLE(gc_friendly,
 239               [AC_HELP_STRING([--enable-gc-friendly],
 240                               [turn on garbage collector friendliness [default=no]])],,
 241               [enable_gc_friendly=no])
 242 AC_ARG_ENABLE(mem_pools,
 243               [AC_HELP_STRING([--disable-mem-pools],
 244                               [disable all glib memory pools])],,
 245               [disable_mem_pools=no])
 246 AC_ARG_ENABLE(rebuilds,
 247               [AC_HELP_STRING([--disable-rebuilds],
 248                               [disable all source autogeneration rules])],,
 249               [enable_rebuilds=yes])
 250 AC_ARG_ENABLE(modular_tests,
 251               AC_HELP_STRING([--disable-modular-tests],
 252                              [Disable build of test programs (default: no)]),,
 253               [enable_modular_tests=yes])
 254 AM_CONDITIONAL(BUILD_MODULAR_TESTS, test x$enable_modular_tests = xyes)
 255
 256 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 257 if test "x$enable_gc_friendly" = "xyes"; then
 258   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 259   AC_MSG_RESULT([yes])
 260 else
 261   AC_MSG_RESULT([no])
 262 fi
 263
 264 AC_MSG_CHECKING([whether to disable memory pools])
 265 if test "x$disable_mem_pools" = "xno"; then
 266   AC_MSG_RESULT([no])
 267 else
 268   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 269   AC_MSG_RESULT([yes])
 270 fi
 271
 272 dnl location to install runtime libraries, e.g. ../../lib to install
 273 dnl to /lib if libdir is /usr/lib
 274 AC_ARG_WITH(runtime-libdir,
 275            [AC_HELP_STRING([--with-runtime-libdir=RELPATH],
 276                            [install runtime libraries relative to libdir])],
 277            [],
 278            [with_runtime_libdir=""])
 279 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 280 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 281 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 282 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 283 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 284
 285 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 286 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 287 AC_LANG_SAVE
 288 AC_LANG_CPLUSPLUS
 289 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 290 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 291 AC_LANG_RESTORE
 292
 293 AM_PROG_CC_STDC
 294 AM_PROG_CC_C_O
 295 AC_PROG_INSTALL
 296
 297 AC_SYS_LARGEFILE
 298
 299 PKG_PROG_PKG_CONFIG(0.16)
 300
 301 if test "x$enable_debug" = "xyes"; then
 302   if test x$cflags_set != xset ; then
 303       case " $CFLAGS " in
 304       *[[\ \    ]]-g[[\ \       ]]*) ;;
 305       *) CFLAGS="$CFLAGS -g" ;;
 306       esac
 307   fi
 308   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 309 else
 310   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 311
 312   if test "x$enable_debug" = "xno"; then
 313     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 314   fi
 315 fi
 316
 317 # Ensure MSVC-compatible struct packing convention is used when
 318 # compiling for Win32 with gcc.
 319 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 320 # gcc2 uses "-fnative-struct".
 321 if test x"$glib_native_win32" = xyes; then
 322   if test x"$GCC" = xyes; then
 323     msnative_struct=''
 324     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 325     if test -z "$ac_cv_prog_CC"; then
 326       our_gcc="$CC"
 327     else
 328       our_gcc="$ac_cv_prog_CC"
 329     fi
 330     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 331       2.)
 332         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 333           msnative_struct='-fnative-struct'
 334         fi
 335         ;;
 336       *)
 337         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 338           msnative_struct='-mms-bitfields'
 339         fi
 340         ;;
 341     esac
 342     if test x"$msnative_struct" = x ; then
 343       AC_MSG_RESULT([no way])
 344       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 345     else
 346       CFLAGS="$CFLAGS $msnative_struct"
 347       AC_MSG_RESULT([${msnative_struct}])
 348     fi
 349   fi
 350 fi
 351 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 352 AC_SUBST(GLIB_EXTRA_CFLAGS)
 353
 354 AC_EXEEXT
 355
 356 # define a MAINT-like variable REBUILD which is set if Perl
 357 # and awk are found, so autogenerated sources can be rebuilt
 358 AC_PROG_AWK
 359 AC_CHECK_PROGS(PERL, [perl5 perl])
 360 # We would like indent, but don't require it.
 361 AC_CHECK_PROG(INDENT, indent, indent)
 362 REBUILD=\#
 363 if test "x$enable_rebuilds" = "xyes" && \
 364      test -n "$PERL" && \
 365      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 366      test -n "$AWK" ; then
 367   REBUILD=
 368 fi
 369 AC_SUBST(REBUILD)
 370
 371 # Need full path to Perl for glib-mkenums
 372 #
 373 if test "x$PERL" != x ; then
 374   AC_PATH_PROG(PERL_PATH, [$PERL])
 375 fi
 376 if test "x$PERL_PATH" = x ; then
 377   PERL_PATH="/usr/bin/env perl"
 378 fi
 379 AC_SUBST(PERL_PATH)
 380
 381 # Need suitable python path for greport
 382 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 383
 384
 385 dnl ***********************
 386 dnl *** Tests for iconv ***
 387 dnl ***********************
 388 dnl
 389 dnl We do this before the gettext checks, to avoid distortion
 390
 391 dnl On Windows we use a native implementation
 392
 393 if test x"$glib_native_win32" = xyes; then
 394   with_libiconv=native
 395 else
 396   AC_ARG_WITH(libiconv,
 397               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 398                               [use the libiconv library])],,
 399               [with_libiconv=maybe])
 400
 401   found_iconv=no
 402   case $with_libiconv in
 403     maybe)
 404       # Check in the C library first
 405       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 406       # Check if we have GNU libiconv
 407       if test $found_iconv = "no"; then
 408         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 409       fi
 410       # Check if we have a iconv in -liconv, possibly from vendor
 411       if test $found_iconv = "no"; then
 412         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 413       fi
 414       ;;
 415     no)
 416       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 417       ;;
 418     gnu|yes)
 419       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 420       ;;
 421     native)
 422       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 423       ;;
 424   esac
 425
 426   if test "x$found_iconv" = "xno" ; then
 427      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 428   fi
 429 fi
 430
 431 AC_ARG_ENABLE(iconv-cache,
 432               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 433                               [cache iconv descriptors [default=auto]])],,
 434               [enable_iconv_cache=auto])
 435
 436 AC_MSG_CHECKING([whether to cache iconv descriptors])
 437 case $enable_iconv_cache in
 438   auto)
 439     if test $ac_cv_gnu_library_2_1 = yes; then
 440       enable_iconv_cache=no
 441     else
 442       enable_iconv_cache=yes
 443     fi
 444   ;;
 445   yes|no)
 446   ;;
 447   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 448   ;;
 449 esac
 450
 451 if test $enable_iconv_cache = yes; then
 452    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 453 fi
 454
 455 AC_MSG_RESULT($enable_iconv_cache)
 456
 457
 458 dnl
 459 dnl zlib support
 460 dnl
 461 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 462 if test "x$found_zlib" = "xno" ; then
 463   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 464   if test "x$found_zlib" = "xno" ; then
 465     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 466   fi
 467   ZLIB_LIBS='-lz'
 468   AC_SUBST(ZLIB_LIBS)
 469 fi
 470
 471 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 472 AC_SUBST(LIBFFI_CFLAGS)
 473 AC_SUBST(LIBFFI_LIBS)
 474
 475 dnl
 476 dnl gettext support
 477 dnl
 478
 479 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 480 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 481 GLIB_GNU_GETTEXT
 482
 483 if test "$gt_cv_have_gettext" != "yes" ; then
 484   AC_MSG_ERROR([
 485 *** You must have either have gettext support in your C library, or use the
 486 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 487 ])
 488 fi
 489
 490 LIBS="$INTLLIBS $LIBS"
 491
 492 GETTEXT_PACKAGE=glib20
 493 AC_SUBST(GETTEXT_PACKAGE)
 494 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 495   [Define the gettext package to be used])
 496
 497 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 498
 499 dnl
 500 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 501 dnl
 502
 503 if test x"$glib_native_win32" != xyes; then
 504   if test x$with_libiconv != xno ; then
 505     case " $INTLLIBS " in
 506     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 507     *) ICONV_LIBS="-liconv" ;;
 508     esac
 509   fi
 510 fi
 511 AC_SUBST(ICONV_LIBS)
 512
 513 case $with_libiconv in
 514   gnu)
 515     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 516     ;;
 517   native)
 518     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 519     ;;
 520 esac
 521
 522 dnl Initialize libtool
 523 LT_PREREQ([2.2])
 524 LT_INIT([disable-static win32-dll])
 525 dnl when using libtool 2.x create libtool early, because it's used in configure
 526 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 527
 528
 529 if test "x$GCC" = "xyes"; then
 530   case " $CFLAGS " in
 531   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 532   *) CFLAGS="$CFLAGS -Wall" ;;
 533   esac
 534 fi
 535
 536 if test "$glib_native_win32" = "yes"; then
 537   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 538     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 539   fi
 540   if test x$enable_static = xyes; then
 541     glib_win32_static_compilation=yes
 542     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 543 #define GOBJECT_STATIC_COMPILATION 1"
 544     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 545   fi
 546 fi
 547 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 548
 549 dnl
 550 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 551 dnl
 552 if test $cross_compiling != yes ; then
 553     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 554     glib_save_LIBS=$LIBS
 555     LIBS="$LIBS -lm"
 556     AC_TRY_RUN([#include <math.h>
 557                  int main (void) { return (log(1) != log(1.)); }],
 558          AC_MSG_RESULT(none needed),
 559          glib_save_CFLAGS=$CFLAGS
 560          CFLAGS="$CFLAGS -std1"
 561          AC_TRY_RUN([#include <math.h>
 562                      int main (void) { return (log(1) != log(1.)); }],
 563              AC_MSG_RESULT(-std1),
 564              AC_MSG_RESULT()
 565              CFLAGS=$glib_save_CFLAGS
 566              AC_MSG_WARN(
 567                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 568          )
 569     )
 570     LIBS=$glib_save_LIBS
 571 fi
 572
 573 dnl NeXTStep cc seems to need this
 574 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 575 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 576   AC_MSG_RESULT(none needed),
 577   glib_save_CFLAGS=$CFLAGS
 578   CFLAGS="$CFLAGS -posix"
 579   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 580     AC_MSG_RESULT(-posix),
 581     AC_MSG_RESULT()
 582     CFLAGS=$glib_save_CFLAGS
 583     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 584
 585 # Checks for library functions.
 586 AC_FUNC_VPRINTF
 587 AC_FUNC_ALLOCA
 588 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2)
 589 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 590
 591 AC_CHECK_SIZEOF(char)
 592 AC_CHECK_SIZEOF(short)
 593 AC_CHECK_SIZEOF(long)
 594 AC_CHECK_SIZEOF(int)
 595 AC_CHECK_SIZEOF(void *)
 596 AC_CHECK_SIZEOF(long long)
 597 AC_CHECK_SIZEOF(__int64)
 598
 599 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
 600   [AC_TRY_LINK([#include <signal.h>
 601      #include <sys/types.h>
 602      sig_atomic_t val = 42;],
 603     [return val == 42 ? 0 : 1],
 604    ac_cv_type_sig_atomic_t=yes,
 605    ac_cv_type_sig_atomic_t=no)])
 606 if test x$ac_cv_type_sig_atomic_t = xyes; then
 607    AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
 608      [Define if you have the 'sig_atomic_t' type.])
 609 fi
 610
 611 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 612   :
 613 else
 614   AC_MSG_ERROR([
 615 *** GLib requires a 64 bit type. You might want to consider
 616 *** using the GNU C compiler.
 617 ])
 618 fi
 619
 620 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 621         # long long is a 64 bit integer.
 622         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 623         AC_CACHE_VAL(glib_cv_long_long_format,[
 624                 for format in ll q I64; do
 625                   AC_TRY_RUN([#include <stdio.h>
 626                         int main()
 627                         {
 628                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 629                           char buffer[1000];
 630                           sprintf (buffer, "%${format}u", a);
 631                           sscanf (buffer, "%${format}u", &b);
 632                           exit (b!=a);
 633                         }
 634                         ],
 635                         [glib_cv_long_long_format=${format}
 636                         break],
 637                         [],[:])
 638                 done])
 639         if test -n "$glib_cv_long_long_format"; then
 640           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 641           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 642           if test x"$glib_cv_long_long_format" = xI64; then
 643             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 644           fi
 645         else
 646           AC_MSG_RESULT(none)
 647         fi
 648 elif test x$ac_cv_sizeof___int64 = x8; then
 649         # __int64 is a 64 bit integer.
 650         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 651         # We know this is MSVCRT.DLL, and what the formats are
 652         glib_cv_long_long_format=I64
 653         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 654         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 655         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 656 fi
 657
 658 AC_C_CONST
 659
 660 dnl ok, here we try to check whether the systems prototypes for
 661 dnl malloc and friends actually match the prototypes provided
 662 dnl by gmem.h (keep in sync). i currently only know how to check
 663 dnl this reliably with gcc (-Werror), improvements for other
 664 dnl compilers are apprechiated.
 665 SANE_MALLOC_PROTOS=no
 666 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 667 glib_save_CFLAGS=$CFLAGS
 668 if test "x$GCC" = "xyes"; then
 669   CFLAGS="$CFLAGS -Werror"
 670   AC_TRY_COMPILE([#include <stdlib.h>], [
 671     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 672     void* (*my_malloc_p)  (size_t)         = malloc;
 673     void  (*my_free_p)    (void*)          = free;
 674     void* (*my_realloc_p) (void*, size_t)  = realloc;
 675     my_calloc_p = 0;
 676     my_malloc_p = 0;
 677     my_free_p = 0;
 678     my_realloc_p = 0;
 679   ],
 680     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 681       [Define if you have correct malloc prototypes])
 682     SANE_MALLOC_PROTOS=yes)
 683 fi
 684 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 685 CFLAGS=$glib_save_CFLAGS
 686
 687 dnl
 688 dnl check in which direction the stack grows
 689 dnl
 690 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 691         AC_TRY_RUN([
 692         volatile int *a = 0, *b = 0;
 693         void foo (void);
 694         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 695         void foo (void) { volatile int x = 5; b = &x; }
 696         ],
 697         glib_cv_stack_grows=no
 698         ,
 699         glib_cv_stack_grows=yes
 700         ,)
 701 ])
 702
 703 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 704 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 705 dnl actually supported.
 706 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 707         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 708         __inline int foo () { return 0; }
 709         int main () { return foo (); }
 710         ]])],
 711         glib_cv_has__inline=yes
 712         ,
 713         glib_cv_has__inline=no
 714         ,)
 715 ])
 716 case x$glib_cv_has__inline in
 717 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 718 esac
 719 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 720         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 721         __inline__ int foo () { return 0; }
 722         int main () { return foo (); }
 723         ]])],
 724         glib_cv_has__inline__=yes
 725         ,
 726         glib_cv_has__inline__=no
 727         ,)
 728 ])
 729 case x$glib_cv_has__inline__ in
 730 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 731 esac
 732 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 733         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 734         #undef inline
 735         inline int foo () { return 0; }
 736         int main () { return foo (); }
 737         ]])],
 738         glib_cv_hasinline=yes
 739         ,
 740         glib_cv_hasinline=no
 741         ,)
 742 ])
 743 case x$glib_cv_hasinline in
 744 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 745 esac
 746
 747 # if we can use inline functions in headers
 748 AC_MSG_CHECKING(if inline functions in headers work)
 749 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 750 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 751 #  undef inline
 752 #  define inline __inline__
 753 #elif !defined (G_HAVE_INLINE)
 754 #  undef inline
 755 #  if defined (G_HAVE___INLINE__)
 756 #    define inline __inline__
 757 #  elif defined (G_HAVE___INLINE)
 758 #    define inline __inline
 759 #  endif
 760 #endif
 761
 762 int glib_test_func2 (int);
 763
 764 static inline int
 765 glib_test_func1 (void) {
 766   return glib_test_func2 (1);
 767 }
 768
 769 int
 770 main (void) {
 771   int i = 1;
 772 }]])],[g_can_inline=yes],[g_can_inline=no])
 773 AC_MSG_RESULT($g_can_inline)
 774
 775 dnl *** check for working do while(0) macros ***
 776 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 777         AC_TRY_COMPILE([],[
 778         #define STMT_START do
 779         #define STMT_END while(0)
 780         #define STMT_TEST STMT_START { i = 0; } STMT_END
 781         int main(void) { int i = 1; STMT_TEST; return i; }],
 782         [g_cv_support_dowhile_macros=yes],
 783         [g_cv_support_dowhile_macros=no],
 784         [g_cv_support_dowhile_macros=yes])
 785 ])
 786 if test x$g_cv_support_dowhile_macros = xyes; then
 787   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 788 fi
 789
 790 # check for flavours of varargs macros
 791 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 792 AC_TRY_COMPILE([],[
 793 int a(int p1, int p2, int p3);
 794 #define call_a(...) a(1,__VA_ARGS__)
 795 call_a(2,3);
 796 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 797 AC_MSG_RESULT($g_have_iso_c_varargs)
 798
 799 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 800 if test "$CXX" = ""; then
 801 dnl No C++ compiler
 802   g_have_iso_cxx_varargs=no
 803 else
 804   AC_LANG_CPLUSPLUS
 805   AC_TRY_COMPILE([],[
 806 int a(int p1, int p2, int p3);
 807 #define call_a(...) a(1,__VA_ARGS__)
 808 call_a(2,3);
 809 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 810   AC_LANG_C
 811 fi
 812 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 813
 814 AC_MSG_CHECKING(for GNUC varargs macros)
 815 AC_TRY_COMPILE([],[
 816 int a(int p1, int p2, int p3);
 817 #define call_a(params...) a(1,params)
 818 call_a(2,3);
 819 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 820 AC_MSG_RESULT($g_have_gnuc_varargs)
 821
 822 # check for GNUC visibility support
 823 AC_MSG_CHECKING(for GNUC visibility attribute)
 824 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 825 void
 826 __attribute__ ((visibility ("hidden")))
 827      f_hidden (void)
 828 {
 829 }
 830 void
 831 __attribute__ ((visibility ("internal")))
 832      f_internal (void)
 833 {
 834 }
 835 void
 836 __attribute__ ((visibility ("protected")))
 837      f_protected (void)
 838 {
 839 }
 840 void
 841 __attribute__ ((visibility ("default")))
 842      f_default (void)
 843 {
 844 }
 845 int main (int argc, char **argv)
 846 {
 847         f_hidden();
 848         f_internal();
 849         f_protected();
 850         f_default();
 851         return 0;
 852 }
 853 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 854 AC_MSG_RESULT($g_have_gnuc_visibility)
 855 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 856
 857 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 858 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 859 #else
 860 # include "error: this is not Sun Studio."
 861 #endif
 862 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 863 AC_MSG_RESULT($g_have_sunstudio_visibility)
 864 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 865
 866 # check for bytesex stuff
 867 AC_C_BIGENDIAN
 868 if test x$ac_cv_c_bigendian = xuniversal ; then
 869 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 870 #else
 871 #error Not a big endian.
 872 #endif],
 873     ac_cv_c_bigendian=yes
 874     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 875 #else
 876 #error Not a little endian.
 877 #endif],
 878     ac_cv_c_bigendian=no
 879     ,AC_MSG_WARN([Could not determine endianness.])))
 880 fi
 881
 882
 883 # check for header files
 884 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 885 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 886 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 887 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 888 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 889 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 890 AC_CHECK_HEADERS([linux/magic.h])
 891 AC_CHECK_HEADERS([sys/prctl.h])
 892
 893 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 894 [#if HAVE_SYS_PARAM_H
 895  #include <sys/param.h>
 896  #endif
 897 ])
 898
 899 AC_CHECK_HEADERS([xlocale.h])
 900
 901 # check for structure fields
 902 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 903 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 904 #include <sys/stat.h>
 905 #include <unistd.h>
 906 #ifdef HAVE_SYS_STATFS_H
 907 #include <sys/statfs.h>
 908 #endif
 909 #ifdef HAVE_SYS_PARAM_H
 910 #include <sys/param.h>
 911 #endif
 912 #ifdef HAVE_SYS_MOUNT_H
 913 #include <sys/mount.h>
 914 #endif])
 915 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 916 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 917 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 918 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 919
 920 AC_STRUCT_DIRENT_D_TYPE
 921
 922 # Checks for libcharset
 923 AM_LANGINFO_CODESET
 924 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 925 AC_CHECK_FUNCS(setlocale)
 926
 927 # check additional type sizes
 928 AC_CHECK_SIZEOF(size_t)
 929
 930 dnl Try to figure out whether gsize, gssize should be long or int
 931 AC_MSG_CHECKING([for the appropriate definition for size_t])
 932
 933 case $ac_cv_sizeof_size_t in
 934   $ac_cv_sizeof_short)
 935       glib_size_type=short
 936       ;;
 937   $ac_cv_sizeof_int)
 938       glib_size_type=int
 939       ;;
 940   $ac_cv_sizeof_long)
 941       glib_size_type=long
 942       ;;
 943   $ac_cv_sizeof_long_long)
 944       glib_size_type='long long'
 945       ;;
 946   $ac_cv_sizeof__int64)
 947       glib_size_type='__int64'
 948       ;;
 949   *)  AC_MSG_ERROR([No type matching size_t in size])
 950       ;;
 951 esac
 952
 953 dnl If int/long are the same size, we see which one produces
 954 dnl warnings when used in the location as size_t. (This matters
 955 dnl on AIX with xlc)
 956 dnl
 957 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 958    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 959   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 960 #if defined(_AIX) && !defined(__GNUC__)
 961 #pragma options langlvl=stdc89
 962 #endif
 963 #include <stddef.h>
 964 int main ()
 965 {
 966   size_t s = 1;
 967   unsigned int *size_int = &s;
 968   return (int)*size_int;
 969 }
 970     ]])],glib_size_type=int,
 971       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 972 #if defined(_AIX) && !defined(__GNUC__)
 973 #pragma options langlvl=stdc89
 974 #endif
 975 #include <stddef.h>
 976 int main ()
 977 {
 978    size_t s = 1;
 979    unsigned long *size_long = &s;
 980    return (int)*size_long;
 981 }
 982         ]])],glib_size_type=long)])
 983 fi
 984
 985 AC_MSG_RESULT(unsigned $glib_size_type)
 986
 987 # Check for some functions
 988 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 989 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid)
 990 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
 991 # Check for high-resolution sleep functions
 992 AC_CHECK_FUNCS(splice)
 993 AC_CHECK_FUNCS(prlimit)
 994
 995 # To avoid finding a compatibility unusable statfs, which typically
 996 # successfully compiles, but warns to use the newer statvfs interface:
 997 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
 998 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
 999
1000 AC_MSG_CHECKING([whether to use statfs or statvfs])
1001 # Some systems have both statfs and statvfs, pick the most "native" for these
1002 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1003    [
1004    # on solaris and irix, statfs doesn't even have the f_bavail field
1005    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1006       [ac_cv_func_statfs=no],
1007    # else, at least on linux, statfs is the actual syscall
1008       [ac_cv_func_statvfs=no])
1009    ])
1010
1011 AS_IF([test x$ac_cv_func_statfs = xyes],
1012       [
1013          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1014          AC_MSG_RESULT([statfs])
1015       ],
1016       [test x$ac_cv_func_statvfs = xyes],
1017       [
1018          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1019          AC_MSG_RESULT([statvfs])
1020       ],
1021       [  AC_MSG_RESULT([neither])])
1022
1023 AC_CHECK_HEADERS(crt_externs.h)
1024 AC_CHECK_FUNCS(_NSGetEnviron)
1025
1026 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1027
1028 AC_FUNC_VSNPRINTF_C99
1029 AC_FUNC_PRINTF_UNIX98
1030
1031 # Internet address families
1032 if test $glib_native_win32 = yes; then
1033   glib_inet_includes=["
1034 #include <winsock2.h>
1035   "]
1036 else
1037   glib_inet_includes=["
1038 #include <sys/types.h>
1039 #include <sys/socket.h>
1040   "]
1041 fi
1042
1043 glib_failed=false
1044 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1045 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1046 # winsock defines this even though it doesn't support it
1047 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1048 if $glib_failed ; then
1049   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1050 fi
1051
1052 glib_failed=false
1053 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1054 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1055 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1056 if $glib_failed ; then
1057   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1058 fi
1059
1060 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex)
1061 AC_CHECK_HEADERS([netdb.h wspiapi.h arpa/nameser_compat.h])
1062
1063 if test $glib_native_win32 = no; then
1064   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1065   NETWORK_LIBS=""
1066   AC_MSG_CHECKING([for res_query])
1067   AC_TRY_LINK([#include <sys/types.h>
1068                #include <netinet/in.h>
1069                #include <arpa/nameser.h>
1070                #include <resolv.h>
1071               ],[
1072                res_query("test", 0, 0, (void *)0, 0);
1073               ],[AC_MSG_RESULT([yes])],
1074               [save_libs="$LIBS"
1075                LIBS="-lresolv $LIBS"
1076                AC_TRY_LINK([#include <sys/types.h>
1077                             #include <netinet/in.h>
1078                             #include <arpa/nameser.h>
1079                             #include <resolv.h>
1080                            ],[
1081                             res_query("test", 0, 0, (void *)0, 0);
1082                            ],[AC_MSG_RESULT([in -lresolv])
1083                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1084                            [LIBS="-lbind $save_libs"
1085                             AC_TRY_LINK([#include <resolv.h>],
1086                                         [res_query("test", 0, 0, (void *)0, 0);],
1087                                         [AC_MSG_RESULT([in -lbind])
1088                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1089                                         [AC_MSG_ERROR(not found)])])
1090                LIBS="$save_libs"])
1091   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1092                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1093                                         [AC_MSG_ERROR(Could not find socket())]))
1094 fi
1095 AC_SUBST(NETWORK_LIBS)
1096
1097 AC_CHECK_HEADER([linux/netlink.h],
1098                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1099                 [#include <sys/socket.h>])
1100 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1101
1102 AC_CHECK_TYPE([struct ip_mreqn], [
1103               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1104               [#include <netinet/in.h>])
1105
1106 case $host in
1107   *-*-solaris* )
1108      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1109      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1110      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1111      ;;
1112 esac
1113
1114 dnl
1115 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1116 dnl
1117 if test "$ac_cv_func_statfs" = yes ; then
1118   AC_MSG_CHECKING([number of arguments to statfs()])
1119   AC_TRY_COMPILE([#include <unistd.h>
1120   #ifdef HAVE_SYS_PARAM_H
1121   #include <sys/param.h>
1122   #endif
1123   #ifdef HAVE_SYS_VFS_H
1124   #include <sys/vfs.h>
1125   #endif
1126   #ifdef HAVE_SYS_MOUNT_H
1127   #include <sys/mount.h>
1128   #endif
1129   #ifdef HAVE_SYS_STATFS_H
1130   #include <sys/statfs.h>
1131   #endif], [struct statfs st;
1132   statfs(NULL, &st);],[
1133     AC_MSG_RESULT([2])
1134     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1135     AC_TRY_COMPILE([#include <unistd.h>
1136   #ifdef HAVE_SYS_PARAM_H
1137   #include <sys/param.h>
1138   #endif
1139   #ifdef HAVE_SYS_VFS_H
1140   #include <sys/vfs.h>
1141   #endif
1142   #ifdef HAVE_SYS_MOUNT_H
1143   #include <sys/mount.h>
1144   #endif
1145   #ifdef HAVE_SYS_STATFS_H
1146   #include <sys/statfs.h>
1147   #endif], [struct statfs st;
1148   statfs(NULL, &st, sizeof (st), 0);],[
1149       AC_MSG_RESULT([4])
1150       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1151       AC_MSG_RESULT(unknown)
1152       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1153 fi
1154
1155 #
1156 # Check whether to use an included printf
1157 #
1158
1159 AC_ARG_ENABLE(included-printf,
1160               [AC_HELP_STRING([--enable-included-printf],
1161                               [use included printf [default=auto]])],
1162               enable_included_printf="$enableval")
1163
1164 need_included_printf=no
1165 if test "x$enable_included_printf" = "xyes" ; then
1166   need_included_printf=yes
1167 fi
1168 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1169   need_included_printf=yes
1170 fi
1171 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1172   need_included_printf=yes
1173 fi
1174 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1175    test -z "$glib_cv_long_long_format" ; then
1176   need_included_printf=yes
1177 fi
1178
1179 if test "x$enable_included_printf" = "xno" &&
1180    test "x$need_included_printf" = "xyes" ; then
1181   AC_MSG_ERROR([
1182 *** Your C library's printf doesn't appear to have the features that
1183 *** GLib needs, but you specified --enable-included-printf=no.])
1184 fi
1185
1186 enable_included_printf=$need_included_printf
1187
1188 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1189 if test "$enable_included_printf" != "yes" ; then
1190   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1191 else
1192   if test -z "$glib_cv_long_long_format" ; then
1193     glib_cv_long_long_format="ll"
1194   fi
1195   AC_DEFINE(HAVE_VASPRINTF,1)
1196 fi
1197
1198 # Checks needed for gnulib vasnprintf
1199 bh_C_SIGNED
1200 jm_AC_TYPE_LONG_LONG
1201 gt_TYPE_LONGDOUBLE
1202 gt_TYPE_WCHAR_T
1203 gt_TYPE_WINT_T
1204 AC_TYPE_SIZE_T
1205 AC_CHECK_TYPES(ptrdiff_t)
1206 jm_AC_TYPE_INTMAX_T
1207 AC_CHECK_FUNCS([snprintf wcslen])
1208 AC_FUNC_SNPRINTF_C99
1209
1210 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1211 # The check is borrowed from the PERL Configure script.
1212 if test "$ac_cv_func_memmove" != "yes"; then
1213   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1214     glib_cv_working_bcopy,[AC_TRY_RUN([
1215       int main() {
1216         char buf[128], abc[128], *b;
1217         int len, off, align;
1218         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1219         for (align = 7; align >= 0; align--) {
1220           for (len = 36; len; len--) {
1221             b = buf+align; bcopy(abc, b, len);
1222             for (off = 1; off <= len; off++) {
1223               bcopy(b, b+off, len); bcopy(b+off, b, len);
1224                 if (bcmp(b, abc, len)) return(1);
1225             }
1226           }
1227         }
1228         return(0);
1229       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1230
1231   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1232   if test "$glib_cv_working_bcopy" = "yes"; then
1233     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1234   fi
1235 fi
1236
1237 # Check if <sys/select.h> needs to be included for fd_set
1238 AC_MSG_CHECKING([for fd_set])
1239 AC_TRY_COMPILE([#include <sys/types.h>],
1240         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1241 if test "$gtk_ok" = "yes"; then
1242     AC_MSG_RESULT([yes, found in sys/types.h])
1243 else
1244     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1245     if test "$gtk_ok" = "yes"; then
1246         # *** FIXME: give it a different name
1247         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1248         AC_MSG_RESULT([yes, found in sys/select.h])
1249     else
1250         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1251         AC_MSG_RESULT(no)
1252     fi
1253 fi
1254
1255 dnl *** check for sane realloc() ***
1256 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1257         AC_TRY_RUN([#include <stdlib.h>
1258         int main() {
1259           return realloc (0, sizeof (int)) == 0;
1260         }],
1261         [glib_cv_sane_realloc=yes],
1262         [glib_cv_sane_realloc=no],
1263         [glib_cv_sane_realloc=yes])
1264 ])
1265 if test x$glib_cv_sane_realloc = xyes; then
1266   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1267 fi
1268
1269 dnl Check for nl_langinfo and CODESET
1270 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1271         AC_TRY_COMPILE([#include <langinfo.h>],
1272                 [char *codeset = nl_langinfo (CODESET);],
1273                 [glib_cv_langinfo_codeset=yes],
1274                 [glib_cv_langinfo_codeset=no])])
1275 if test x$glib_cv_langinfo_codeset = xyes; then
1276   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1277 fi
1278
1279 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1280 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1281         AC_TRY_COMPILE([#include <langinfo.h>],
1282                 [char *str;
1283                  str = nl_langinfo (PM_STR);
1284                  str = nl_langinfo (D_T_FMT);
1285                  str = nl_langinfo (D_FMT);
1286                  str = nl_langinfo (T_FMT);
1287                  str = nl_langinfo (T_FMT_AMPM);
1288                  str = nl_langinfo (MON_1);
1289                  str = nl_langinfo (ABMON_12);
1290                  str = nl_langinfo (DAY_1);
1291                  str = nl_langinfo (ABDAY_7);],
1292                 [glib_cv_langinfo_time=yes],
1293                 [glib_cv_langinfo_time=no])])
1294 if test x$glib_cv_langinfo_time = xyes; then
1295   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1296 fi
1297
1298 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1299 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1300         AC_TRY_COMPILE([#include <langinfo.h>],
1301                 [char *str;
1302                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1303                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1304                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1305                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1306                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1307                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1308                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1309                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1310                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1311                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);],
1312                 [glib_cv_langinfo_outdigit=yes],
1313                 [glib_cv_langinfo_outdigit=no])])
1314 if test x$glib_cv_langinfo_outdigit = xyes; then
1315   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1316 fi
1317
1318 dnl ****************************************
1319 dnl *** posix_memalign                   ***
1320 dnl ****************************************
1321 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1322 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1323     glib_cv_compliant_posix_memalign=0
1324     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1325         AC_TRY_RUN([
1326                 #define _XOPEN_SOURCE 600
1327                 #include <stdlib.h> /* posix_memalign() should be defined here */
1328                 /* some systems break if #include <malloc.h> used */
1329                 static void test_memalign (size_t boundary, size_t size) {
1330                     void *mem = 0;
1331                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1332                         exit (1);
1333                     else
1334                       free (mem);
1335                 }
1336                 int main() {
1337                     test_memalign (  128,   128 - 2 * sizeof (void*));
1338                     test_memalign (  256,   256 - 2 * sizeof (void*));
1339                     test_memalign (  512,   512 - 2 * sizeof (void*));
1340                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1341                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1342                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1343                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1344                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1345                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1346                     exit (0); /* success */
1347                 }
1348                 ],
1349             [glib_cv_compliant_posix_memalign=1], [], [:])
1350       :
1351     fi
1352     ])
1353 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1354     AC_MSG_RESULT(yes)
1355     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1356 else
1357     AC_MSG_RESULT(no)
1358 fi
1359
1360
1361 dnl ****************************************
1362 dnl *** strlcpy/strlcat                  ***
1363 dnl ****************************************
1364 # Check for strlcpy
1365 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1366 AC_TRY_RUN([#include <stdlib.h>
1367 #include <string.h>
1368 int main() {
1369   char p[10];
1370   (void) strlcpy (p, "hi", 10);
1371   if (strlcat (p, "bye", 0) != 3)
1372     return 1;
1373   return 0;
1374 }], glib_cv_have_strlcpy=yes,
1375     glib_cv_have_strlcpy=no,
1376     glib_cv_have_strlcpy=no)])
1377 if test "$glib_cv_have_strlcpy" = "yes"; then
1378     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1379 fi
1380
1381
1382 dnl **********************
1383 dnl *** va_copy checks ***
1384 dnl **********************
1385 dnl we currently check for all three va_copy possibilities, so we get
1386 dnl all results in config.log for bug reports.
1387 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1388         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1389 #include <stdlib.h>
1390         void f (int i, ...) {
1391         va_list args1, args2;
1392         va_start (args1, i);
1393         va_copy (args2, args1);
1394         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1395           exit (1);
1396         va_end (args1); va_end (args2);
1397         }
1398         int main() {
1399           f (0, 42);
1400           return 0;
1401         }]])],
1402         [glib_cv_va_copy=yes],
1403         [glib_cv_va_copy=no])
1404 ])
1405 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1406         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1407 #include <stdlib.h>
1408         void f (int i, ...) {
1409         va_list args1, args2;
1410         va_start (args1, i);
1411         __va_copy (args2, args1);
1412         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1413           exit (1);
1414         va_end (args1); va_end (args2);
1415         }
1416         int main() {
1417           f (0, 42);
1418           return 0;
1419         }]])],
1420         [glib_cv___va_copy=yes],
1421         [glib_cv___va_copy=no])
1422 ])
1423
1424 if test "x$glib_cv_va_copy" = "xyes"; then
1425   g_va_copy_func=va_copy
1426 else if test "x$glib_cv___va_copy" = "xyes"; then
1427   g_va_copy_func=__va_copy
1428 fi
1429 fi
1430
1431 if test -n "$g_va_copy_func"; then
1432   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1433 fi
1434
1435 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1436         AC_TRY_RUN([#include <stdarg.h>
1437 #include <stdlib.h>
1438         void f (int i, ...) {
1439         va_list args1, args2;
1440         va_start (args1, i);
1441         args2 = args1;
1442         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1443           exit (1);
1444         va_end (args1); va_end (args2);
1445         }
1446         int main() {
1447           f (0, 42);
1448           return 0;
1449         }],
1450         [glib_cv_va_val_copy=yes],
1451         [glib_cv_va_val_copy=no],
1452         [glib_cv_va_val_copy=yes])
1453 ])
1454
1455 if test "x$glib_cv_va_val_copy" = "xno"; then
1456   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1457 fi
1458
1459 dnl ***********************
1460 dnl *** g_module checks ***
1461 dnl ***********************
1462 G_MODULE_LIBS=
1463 G_MODULE_LIBS_EXTRA=
1464 G_MODULE_PLUGIN_LIBS=
1465 if test x"$glib_native_win32" = xyes; then
1466   dnl No use for this on Win32
1467   G_MODULE_LDFLAGS=
1468 else
1469   export SED
1470   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1471 fi
1472 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1473 G_MODULE_NEED_USCORE=0
1474 G_MODULE_BROKEN_RTLD_GLOBAL=0
1475 G_MODULE_HAVE_DLERROR=0
1476 dnl *** force native WIN32 shared lib loader
1477 if test -z "$G_MODULE_IMPL"; then
1478   case "$host" in
1479   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1480   esac
1481 fi
1482 dnl *** force native AIX library loader
1483 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1484 if test -z "$G_MODULE_IMPL"; then
1485   case "$host" in
1486   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1487   esac
1488 fi
1489 dnl *** dlopen() and dlsym() in system libraries
1490 if test -z "$G_MODULE_IMPL"; then
1491         AC_CHECK_FUNC(dlopen,
1492                       [AC_CHECK_FUNC(dlsym,
1493                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1494                       [])
1495 fi
1496 dnl *** load_image (BeOS)
1497 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1498   AC_CHECK_LIB(root, load_image,
1499       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1500       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1501       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1502       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1503       [])
1504 fi
1505 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1506 if test -z "$G_MODULE_IMPL"; then
1507         AC_CHECK_FUNC(NSLinkModule,
1508                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1509                        G_MODULE_NEED_USCORE=1],
1510                       [])
1511 fi
1512 dnl *** dlopen() and dlsym() in libdl
1513 if test -z "$G_MODULE_IMPL"; then
1514         AC_CHECK_LIB(dl, dlopen,
1515                      [AC_CHECK_LIB(dl, dlsym,
1516                                    [G_MODULE_LIBS=-ldl
1517                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1518                      [])
1519 fi
1520 dnl *** shl_load() in libdld (HP-UX)
1521 if test -z "$G_MODULE_IMPL"; then
1522         AC_CHECK_LIB(dld, shl_load,
1523                 [G_MODULE_LIBS=-ldld
1524                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1525                 [])
1526 fi
1527 dnl *** additional checks for G_MODULE_IMPL_DL
1528 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1529         LIBS_orig="$LIBS"
1530         LDFLAGS_orig="$LDFLAGS"
1531         LIBS="$G_MODULE_LIBS $LIBS"
1532         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1533 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1534         echo "void glib_plugin_test(void) { }" > plugin.c
1535         ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1536                 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1537         ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1538                 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1539                 -shrext ".o" -avoid-version plugin.lo \
1540                 -rpath /dont/care >/dev/null 2>&1
1541         eval `./libtool --config | grep ^objdir`
1542         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1543                 glib_cv_rtldglobal_broken,[
1544                 AC_TRY_RUN([
1545 #include <dlfcn.h>
1546 #ifndef RTLD_GLOBAL
1547 #  define RTLD_GLOBAL 0
1548 #endif
1549 #ifndef RTLD_LAZY
1550 #  define RTLD_LAZY 0
1551 #endif
1552 int glib_plugin_test;
1553 int main () {
1554     void *handle, *global, *local;
1555     global = &glib_plugin_test;
1556     handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1557     if (!handle) return 0;
1558     local = dlsym (handle, "glib_plugin_test");
1559     return global == local;
1560 }                       ],
1561                         [glib_cv_rtldglobal_broken=no],
1562                         [glib_cv_rtldglobal_broken=yes],
1563                         [glib_cv_rtldglobal_broken=no])
1564                 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1565                 rmdir ${objdir} 2>/dev/null
1566         ])
1567         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1568                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1569         else
1570                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1571         fi
1572 dnl *** check whether we need preceeding underscores
1573         AC_CACHE_CHECK([for preceeding underscore in symbols],
1574                 glib_cv_uscore,[
1575                 AC_TRY_RUN([#include <dlfcn.h>
1576                 int glib_underscore_test (void) { return 42; }
1577                 int main() {
1578                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1579                   handle = dlopen ((void*)0, 0);
1580                   if (handle) {
1581                     f1 = dlsym (handle, "glib_underscore_test");
1582                     f2 = dlsym (handle, "_glib_underscore_test");
1583                   } return (!f2 || f1);
1584                 }],
1585                         [glib_cv_uscore=yes],
1586                         [glib_cv_uscore=no],
1587                         [])
1588                 rm -f plugin.c plugin.$ac_objext plugin.lo
1589         ])
1590         GLIB_ASSERT_SET(glib_cv_uscore)
1591         if test "x$glib_cv_uscore" = "xyes"; then
1592                 G_MODULE_NEED_USCORE=1
1593         else
1594                 G_MODULE_NEED_USCORE=0
1595         fi
1596
1597         LDFLAGS="$LDFLAGS_orig"
1598 dnl *** check for having dlerror()
1599         AC_CHECK_FUNC(dlerror,
1600                 [G_MODULE_HAVE_DLERROR=1],
1601                 [G_MODULE_HAVE_DLERROR=0])
1602         LIBS="$LIBS_orig"
1603 fi
1604 dnl *** done, have we got an implementation?
1605 if test -z "$G_MODULE_IMPL"; then
1606         G_MODULE_IMPL=0
1607         G_MODULE_SUPPORTED=false
1608 else
1609         G_MODULE_SUPPORTED=true
1610 fi
1611
1612 AC_MSG_CHECKING(for the suffix of module shared libraries)
1613 export SED
1614 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1615 eval $shrext_cmds
1616 module=yes eval std_shrext=$shrext_cmds
1617 # chop the initial dot
1618 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1619 AC_MSG_RESULT(.$glib_gmodule_suffix)
1620 # any reason it may fail?
1621 if test "x$glib_gmodule_suffix" = x; then
1622         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1623 fi
1624
1625 AC_SUBST(G_MODULE_SUPPORTED)
1626 AC_SUBST(G_MODULE_IMPL)
1627 AC_SUBST(G_MODULE_LIBS)
1628 AC_SUBST(G_MODULE_LIBS_EXTRA)
1629 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1630 AC_SUBST(G_MODULE_LDFLAGS)
1631 AC_SUBST(G_MODULE_HAVE_DLERROR)
1632 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1633 AC_SUBST(G_MODULE_NEED_USCORE)
1634 AC_SUBST(GLIB_DEBUG_FLAGS)
1635
1636 dnl **********************
1637 dnl *** g_spawn checks ***
1638 dnl **********************
1639
1640 AC_MSG_CHECKING(for gspawn implementation)
1641 case "$host" in
1642   *-*-mingw*)
1643     GSPAWN=gspawn-win32.lo
1644     ;;
1645   *)
1646     GSPAWN=gspawn.lo
1647     ;;
1648 esac
1649 AC_MSG_RESULT($GSPAWN)
1650 AC_SUBST(GSPAWN)
1651
1652 dnl *************************
1653 dnl *** GIOChannel checks ***
1654 dnl *************************
1655
1656 AC_MSG_CHECKING(for GIOChannel implementation)
1657 case "$host" in
1658   *-*-mingw*)
1659     GIO=giowin32.lo
1660     ;;
1661   *)
1662     GIO=giounix.lo
1663     ;;
1664 esac
1665 AC_MSG_RESULT($GIO)
1666 AC_SUBST(GIO)
1667
1668 dnl *********************************
1669 dnl *** Directory for GIO modules ***
1670 dnl *********************************
1671
1672 AC_ARG_WITH(gio-module-dir,
1673            [AC_HELP_STRING([--with-gio-module-dir=DIR],
1674                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1675            [],
1676            [with_gio_module_dir='${libdir}/gio/modules'])
1677 GIO_MODULE_DIR=$with_gio_module_dir
1678 AC_SUBST(GIO_MODULE_DIR)
1679
1680 dnl **********************************
1681 dnl *** Check for libselinux (GIO) ***
1682 dnl **********************************
1683 AC_ARG_ENABLE(selinux,
1684               AC_HELP_STRING([--disable-selinux],
1685                              [build without selinux support]))
1686 msg_selinux=no
1687 SELINUX_LIBS=
1688 if test "x$enable_selinux" != "xno"; then
1689
1690  AC_CHECK_LIB(selinux, is_selinux_enabled,
1691    [AC_CHECK_HEADERS(selinux/selinux.h,
1692      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1693        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1694         SELINUX_LIBS="-lselinux"
1695         msg_selinux=yes])
1696      ])
1697    ])
1698 fi
1699 AC_SUBST(SELINUX_LIBS)
1700
1701 dnl *****************************
1702 dnl ** Check for inotify (GIO) **
1703 dnl *****************************
1704 inotify_support=no
1705 AC_CHECK_HEADERS([sys/inotify.h],
1706 [
1707         inotify_support=yes
1708         AC_CHECK_FUNCS(inotify_init1)
1709 ])
1710
1711 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1712
1713 dnl *********************************
1714 dnl ** Check for Solaris FEN (GIO) **
1715 dnl *********************************
1716 fen_support=no
1717 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1718 #include <port.h>
1719 #ifndef PORT_SOURCE_FILE
1720 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1721 #endif
1722 int main() { return 0; } ]])],
1723 [
1724         fen_support=yes
1725 ],)
1726
1727 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1728
1729 dnl ****************************
1730 dnl *** Checks for FAM (GIO) ***
1731 dnl ****************************
1732
1733 should_disable_fam=no
1734
1735 AC_ARG_ENABLE(fam,
1736               AC_HELP_STRING([--disable-fam],
1737                              [don't use fam for file system monitoring]),
1738                          [
1739                                 if test "x$enable_fam" = "xno"; then
1740                                         should_disable_fam=yes
1741                                 fi
1742                          ]
1743                          )
1744 fam_support=no
1745 FAM_LIBS=
1746 if test "x$should_disable_fam" = "xno"; then
1747 AC_CHECK_LIB(fam, FAMOpen,
1748   [AC_CHECK_HEADERS(fam.h,
1749     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1750      AC_CHECK_LIB(fam, FAMNoExists,
1751                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1752      FAM_LIBS="-lfam"]
1753      fam_support=yes,
1754     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1755   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1756 AC_SUBST(FAM_LIBS)
1757 fi
1758 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1759
1760
1761 dnl *****************************
1762 dnl *** Check for xattr (GIO) ***
1763 dnl *****************************
1764 AC_ARG_ENABLE(xattr,
1765               AC_HELP_STRING([--disable-xattr], [build without xattr support]))
1766 msg_xattr=no
1767 XATTR_LIBS=
1768 if test "x$enable_xattr" != "xno"; then
1769
1770 dnl either glibc or libattr can provide xattr support
1771
1772 dnl for both of them, we check for getxattr being in
1773 dnl the library and a valid xattr header.
1774
1775 dnl try glibc
1776  AC_CHECK_LIB(c, getxattr,
1777    [AC_CHECK_HEADERS(sys/xattr.h,
1778      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1779       msg_xattr=yes])
1780    ])
1781
1782   if test "x$msg_xattr" != "xyes"; then
1783 dnl   failure. try libattr
1784    AC_CHECK_LIB(attr, getxattr,
1785       [AC_CHECK_HEADERS(attr/xattr.h,
1786        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1787         XATTR_LIBS="-lattr"
1788         msg_xattr=yes])
1789       ])
1790   fi
1791
1792   if test "x$msg_xattr" = "xyes"; then
1793     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1794     AC_TRY_COMPILE([
1795       #include <stdio.h>
1796       #ifdef HAVE_SYS_TYPES_H
1797       #include <sys/types.h>
1798       #endif
1799       #ifdef HAVE_SYS_XATTR_H
1800       #include <sys/xattr.h>
1801       #elif HAVE_ATTR_XATTR_H
1802       #include <attr/xattr.h>
1803       #endif
1804     ],
1805     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1806     [
1807       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1808       AC_MSG_RESULT([yes])
1809     ],
1810     [AC_MSG_RESULT([no])]
1811     )
1812   fi
1813
1814 fi
1815 AC_SUBST(XATTR_LIBS)
1816
1817 dnl ************************
1818 dnl *** check for libelf ***
1819 dnl ************************
1820
1821 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=maybe])
1822
1823 if test $have_libelf = maybe; then
1824   AC_CHECK_LIB([elf], [elf_begin], , [have_libelf=no])
1825   AC_CHECK_LIB([elf], [elf_getshdrstrndx], , [have_libelf=no])
1826   AC_CHECK_LIB([elf], [elf_getshdrnum], , [have_libelf=no])
1827   AC_CHECK_HEADER([libelf.h], , [have_libelf=no])
1828
1829   if test $have_libelf != no; then
1830     LIBELF_LIBS=-lelf
1831     have_libelf=yes
1832   fi
1833 fi
1834
1835 if test $have_libelf = yes; then
1836   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1837 fi
1838
1839 dnl ****************************************
1840 dnl *** platform dependent source checks ***
1841 dnl ****************************************
1842
1843 AC_MSG_CHECKING(for platform-dependent source)
1844 case "$host" in
1845   *-*-cygwin*|*-*-mingw*)
1846     PLATFORMDEP=gwin32.lo
1847     ;;
1848   *)
1849     PLATFORMDEP=
1850     ;;
1851 esac
1852 AC_MSG_RESULT($PLATFORMDEP)
1853 AC_SUBST(PLATFORMDEP)
1854
1855 AC_MSG_CHECKING([whether to compile timeloop])
1856 case "$host" in
1857   *-*-cygwin*|*-*-mingw*|*-*-minix)
1858     enable_timeloop=no
1859     ;;
1860   *)
1861     enable_timeloop=yes
1862     ;;
1863 esac
1864 AC_MSG_RESULT($enable_timeloop)
1865 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1866
1867 AC_MSG_CHECKING([if building for some Win32 platform])
1868 case "$host" in
1869   *-*-mingw*|*-*-cygwin*)
1870     platform_win32=yes
1871     ;;
1872   *)
1873     platform_win32=no
1874     ;;
1875 esac
1876 AC_MSG_RESULT($platform_win32)
1877 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1878
1879 dnl ***********************
1880 dnl *** g_thread checks ***
1881 dnl ***********************
1882
1883 AC_ARG_WITH(threads,
1884            [AC_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1885                            [specify a thread implementation to use])],
1886            [],
1887            [with_threads=yes])
1888
1889 dnl error and warning message
1890 dnl *************************
1891
1892 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1893
1894 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1895                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1896                 compilation now, but then your programs might not work.
1897                 Please provide information on how it is done on your system."
1898
1899 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1900                  "
1901
1902 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1903                   provide information on your thread implementation."
1904
1905 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1906                 functions will not be MT-safe during their first call because
1907                 there is no working 'getpwuid_r' on your system."
1908
1909 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1910                 because there is no 'localtime_r' on your system."
1911
1912 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1913                 linking threaded applications. As GLib cannot do that
1914                 automatically, you will get an linkg error everytime you are
1915                 not using the right compiler. In that case you have to relink
1916                 with the right compiler. Ususally just '_r' is appended
1917                 to the compiler name."
1918
1919 dnl determination of thread implementation
1920 dnl ***************************************
1921
1922 AC_MSG_CHECKING(for thread implementation)
1923
1924 have_threads=no
1925 if test "x$with_threads" = xyes || test "x$with_threads" = xposix; then
1926         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1927         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1928         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1929         glib_save_CPPFLAGS="$CPPFLAGS"
1930         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1931         if test "x$have_threads" = xno; then
1932                 AC_TRY_COMPILE([#include <pthread.h>],
1933                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1934                         have_threads=posix)
1935         fi
1936         # Tru64Unix requires -pthread to find pthread.h. See #103020
1937         CPPFLAGS="$CPPFLAGS -pthread"
1938         if test "x$have_threads" = xno; then
1939         AC_TRY_COMPILE([#include <pthread.h>],
1940                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1941                        have_threads=posix)
1942         fi
1943         CPPFLAGS="$glib_save_CPPFLAGS"
1944 fi
1945 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1946         case $host in
1947                 *-*-mingw*)
1948                 have_threads=win32
1949                 ;;
1950         esac
1951 fi
1952
1953 if test "x$have_threads" = xno; then
1954         AC_MSG_RESULT(none available)
1955         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1956 else
1957         AC_MSG_RESULT($have_threads)
1958 fi
1959
1960
1961 dnl determination of G_THREAD_CFLAGS
1962 dnl ********************************
1963
1964 G_THREAD_LIBS=
1965 G_THREAD_LIBS_EXTRA=
1966 G_THREAD_CFLAGS=
1967
1968 dnl
1969 dnl Test program for basic POSIX threads functionality
1970 dnl
1971 m4_define([glib_thread_test],[
1972 #include <pthread.h>
1973 int check_me = 0;
1974 void* func(void* data) {check_me = 42; return &check_me;}
1975 int main()
1976  { pthread_t t;
1977    void *ret;
1978    pthread_create (&t, $1, func, 0);
1979    pthread_join (t, &ret);
1980    return (check_me != 42 || ret != &check_me);
1981 }])
1982
1983 if test x"$have_threads" = xposix; then
1984   # First we test for posix, whether -pthread or -pthreads do the trick as
1985   # both CPPFLAG and LIBS.
1986   # One of them does for most gcc versions and some other platforms/compilers
1987   # too and could be considered as the canonical way to go.
1988   case $host in
1989     *-*-cygwin*|*-*-darwin*)
1990        # skip cygwin and darwin -pthread or -pthreads test
1991        ;;
1992     *-solaris*)
1993       # These compiler/linker flags work with both Sun Studio and gcc
1994       # Sun Studio expands -mt to -D_REENTRANT and -lthread
1995       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1996       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1997       G_THREAD_LIBS="-lpthread -lthread"
1998       ;;
1999     *)
2000       for flag in pthread pthreads mt; do
2001         glib_save_CFLAGS="$CFLAGS"
2002         CFLAGS="$CFLAGS -$flag"
2003         AC_TRY_RUN(glib_thread_test(0),
2004                    glib_flag_works=yes,
2005                    glib_flag_works=no,
2006                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2007                                    glib_flag_works=yes,
2008                                    glib_flag_works=no)])
2009         CFLAGS="$glib_save_CFLAGS"
2010         if test $glib_flag_works = yes ; then
2011            G_THREAD_CFLAGS=-$flag
2012         G_THREAD_LIBS=-$flag
2013         break;
2014         fi
2015       done
2016        ;;
2017   esac
2018 fi
2019
2020 if test x"$G_THREAD_CFLAGS" = x; then
2021
2022   # The canonical -pthread[s] does not work. Try something different.
2023
2024   case $host in
2025         *-aix*)
2026                 if test x"$GCC" = xyes; then
2027                         # GCC 3.0 and above needs -pthread.
2028                         # Should be coverd by the case above.
2029                         # GCC 2.x and below needs -mthreads
2030                         G_THREAD_CFLAGS="-mthreads"
2031                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2032                 else
2033                         # We are probably using the aix compiler. Normaly a
2034                         # program would have to be compiled with the _r variant
2035                         # of the corresponding compiler, but we as GLib cannot
2036                         # do that: but the good news is that for compiling the
2037                         # only difference is the added -D_THREAD_SAFE compile
2038                         # option. This is according to the "C for AIX User's
2039                         # Guide".
2040                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2041                 fi
2042                 ;;
2043         *-dg-dgux*)  # DG/UX
2044                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2045                 ;;
2046         *-sysv5uw7*) # UnixWare 7
2047                 # We are not using gcc with -pthread. Catched above.
2048                 G_THREAD_CFLAGS="-Kthread"
2049                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2050                 ;;
2051         *-mingw*)
2052                 # No flag needed when using MSVCRT.DLL
2053                 G_THREAD_CFLAGS=""
2054                 ;;
2055         *)
2056                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2057                 ;;
2058   esac
2059
2060 fi
2061
2062 # if we are not finding the localtime_r function, then we probably are
2063 # not using the proper multithread flag
2064
2065 glib_save_CPPFLAGS="$CPPFLAGS"
2066 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2067
2068 # First we test, whether localtime_r is declared in time.h
2069 # directly. Then we test whether a macro localtime_r exists, in
2070 # which case localtime_r in the test program is replaced and thus
2071 # if we still find localtime_r in the output, it is not defined as
2072 # a macro.
2073
2074 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2075   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2076                                                            localtime_r(a,b)],
2077                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2078
2079 CPPFLAGS="$glib_save_CPPFLAGS"
2080
2081 AC_MSG_CHECKING(thread related cflags)
2082 AC_MSG_RESULT($G_THREAD_CFLAGS)
2083 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2084
2085 dnl determination of G_THREAD_LIBS
2086 dnl ******************************
2087
2088 case $have_threads in
2089         posix)
2090           glib_save_CPPFLAGS="$CPPFLAGS"
2091           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2092           if test x"$G_THREAD_LIBS" = x; then
2093             case $host in
2094               *-aix*)
2095                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2096                 # probably using the aix compiler.
2097                 AC_MSG_WARN($AIX_COMPILE_INFO)
2098                 ;;
2099               *)
2100                 G_THREAD_LIBS=error
2101                 glib_save_LIBS="$LIBS"
2102                 for thread_lib in "" pthread pthread32 pthreads thread; do
2103                         if test x"$thread_lib" = x; then
2104                                 add_thread_lib=""
2105                                 IN=""
2106                         else
2107                                 add_thread_lib="-l$thread_lib"
2108                                 IN=" in -l$thread_lib"
2109                         fi
2110                         if test x"$have_threads" = xposix; then
2111                                 defattr=0
2112                         else
2113                                 defattr=pthread_attr_default
2114                         fi
2115
2116                         LIBS="$add_thread_lib $glib_save_LIBS"
2117
2118                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2119                         AC_TRY_RUN(glib_thread_test($defattr),
2120                                    glib_result=yes,
2121                                    glib_result=no,
2122                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2123                                                    glib_result=yes,
2124                                                    glib_result=no)])
2125                         AC_MSG_RESULT($glib_result)
2126
2127                         if test "$glib_result" = "yes" ; then
2128                           G_THREAD_LIBS="$add_thread_lib"
2129                           break
2130                         fi
2131                 done
2132                 if test "x$G_THREAD_LIBS" = xerror; then
2133                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2134                 fi
2135                 LIBS="$glib_save_LIBS"
2136                 ;;
2137             esac
2138           fi
2139
2140           g_threads_impl="POSIX"
2141           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2142           CPPFLAGS="$glib_save_CPPFLAGS"
2143           ;;
2144         win32)
2145            g_threads_impl="WIN32"
2146            ;;
2147         *)
2148            g_threads_impl="NONE"
2149            G_THREAD_LIBS=error
2150            ;;
2151 esac
2152
2153 if test "x$G_THREAD_LIBS" = xerror; then
2154         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2155 fi
2156
2157 case $host in
2158   *-*-beos*)
2159     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2160     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2161     ;;
2162   *)
2163     ;;
2164 esac
2165
2166 AC_MSG_CHECKING(thread related libraries)
2167 AC_MSG_RESULT($G_THREAD_LIBS)
2168
2169 dnl check for mt safe function variants and some posix functions
2170 dnl ************************************************************
2171
2172 glib_save_LIBS="$LIBS"
2173 # we are not doing the following for now, as this might require glib
2174 # to always be linked with the thread libs on some platforms.
2175 # LIBS="$LIBS $G_THREAD_LIBS"
2176 AC_CHECK_FUNCS(localtime_r gmtime_r)
2177 if test "$ac_cv_header_pwd_h" = "yes"; then
2178         AC_CACHE_CHECK([for posix getpwuid_r],
2179                 ac_cv_func_posix_getpwuid_r,
2180                 [AC_TRY_RUN([
2181 #include <errno.h>
2182 #include <pwd.h>
2183 int main () {
2184     char buffer[10000];
2185     struct passwd pwd, *pwptr = &pwd;
2186     int error;
2187     errno = 0;
2188     error = getpwuid_r (0, &pwd, buffer,
2189                         sizeof (buffer), &pwptr);
2190    return (error < 0 && errno == ENOSYS)
2191            || error == ENOSYS;
2192 }                               ],
2193                         [ac_cv_func_posix_getpwuid_r=yes],
2194                         [ac_cv_func_posix_getpwuid_r=no])])
2195         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2196         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2197                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2198                         [Have POSIX function getpwuid_r])
2199         else
2200                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2201                         ac_cv_func_nonposix_getpwuid_r,
2202                         [AC_TRY_LINK([#include <pwd.h>],
2203                                 [char buffer[10000];
2204                                 struct passwd pwd;
2205                                 getpwuid_r (0, &pwd, buffer,
2206                                                 sizeof (buffer));],
2207                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2208                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2209                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2210                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2211                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2212                                 [Have non-POSIX function getpwuid_r])
2213                 fi
2214         fi
2215 fi
2216 if test "$ac_cv_header_grp_h" = "yes"; then
2217         AC_CACHE_CHECK([for posix getgrgid_r],
2218                 ac_cv_func_posix_getgrgid_r,
2219                 [AC_TRY_RUN([
2220 #include <errno.h>
2221 #include <grp.h>
2222 int main () {
2223     char buffer[10000];
2224     struct group grp, *grpptr = &grp;
2225     int error;
2226     errno = 0;
2227     error = getgrgid_r (0, &grp, buffer,
2228                         sizeof (buffer), &grpptr);
2229    return (error < 0 && errno == ENOSYS)
2230            || error == ENOSYS;
2231 }                              ],
2232                        [ac_cv_func_posix_getgrgid_r=yes],
2233                        [ac_cv_func_posix_getgrgid_r=no])])
2234         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2235         if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2236                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2237                         [Have POSIX function getgrgid_r])
2238         else
2239                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2240                         ac_cv_func_nonposix_getgrgid_r,
2241                         [AC_TRY_LINK([#include <grp.h>],
2242                                 [char buffer[10000];
2243                                 struct group grp;
2244                                 getgrgid_r (0, &grp, buffer,
2245                                 sizeof (buffer));],
2246                         [ac_cv_func_nonposix_getgrgid_r=yes],
2247                         [ac_cv_func_nonposix_getgrgid_r=no])])
2248                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2249                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2250                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2251                                 [Have non-POSIX function getgrgid_r])
2252                 fi
2253         fi
2254 fi
2255 LIBS="$G_THREAD_LIBS $LIBS"
2256 if test x"$have_threads" = xposix; then
2257         glib_save_CPPFLAGS="$CPPFLAGS"
2258         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2259         # This is not AC_CHECK_FUNC to also work with function
2260         # name mangling in header files.
2261         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2262         AC_LINK_IFELSE(
2263             [AC_LANG_PROGRAM(
2264                 [#include <pthread.h>],
2265                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2266             [AC_MSG_RESULT(yes)
2267              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2268                 [Have function pthread_attr_setstacksize])],
2269             [AC_MSG_RESULT(no)])
2270         AC_MSG_CHECKING(for pthread_condattr_setclock)
2271         AC_LINK_IFELSE(
2272             [AC_LANG_PROGRAM(
2273                 [#include <pthread.h>],
2274                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2275             [AC_MSG_RESULT(yes)
2276              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2277                 [Have function pthread_condattr_setclock])],
2278             [AC_MSG_RESULT(no)])
2279         CPPFLAGS="$glib_save_CPPFLAGS"
2280 fi
2281
2282 LIBS="$glib_save_LIBS"
2283
2284 # now spit out all the warnings.
2285 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2286    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2287         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2288 fi
2289 if test "$ac_cv_func_localtime_r" != "yes"; then
2290         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2291 fi
2292
2293 #
2294 # Hack to deal with:
2295 #
2296 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2297 #     building shared libraries with linux.
2298 #  b) FreeBSD doesn't do this either.
2299 #
2300 case $host in
2301   *-*-freebsd*|*-*-linux*)
2302     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2303     ;;
2304   *-*-openbsd*)
2305     LDFLAGS="$LDFLAGS -pthread"
2306     ;;
2307   *)
2308     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2309     ;;
2310 esac
2311
2312 AC_SUBST(G_THREAD_CFLAGS)
2313 AC_SUBST(G_THREAD_LIBS)
2314 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2315 AC_SUBST(G_THREAD_LIBS_EXTRA)
2316
2317 AC_CHECK_FUNCS(clock_gettime, [], [
2318   AC_CHECK_LIB(rt, clock_gettime, [
2319     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2320     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2321     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2322   ])
2323 ])
2324
2325
2326 dnl ************************
2327 dnl *** g_atomic_* tests ***
2328 dnl ************************
2329
2330 dnl We need to decide at configure time if GLib will use real atomic
2331 dnl operations ("lock free") or emulated ones with a mutex.  This is
2332 dnl because we must put this information in glibconfig.h so we know if
2333 dnl it is safe or not to inline using compiler intrinsics directly from
2334 dnl the header.
2335 dnl
2336 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2337 dnl user is interested in knowing if they can use the atomic ops across
2338 dnl processes.
2339 dnl
2340 dnl We can currently support the atomic ops natively when building GLib
2341 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2342 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2343 dnl we are using GCC.
2344 dnl
2345 dnl Note that the atomic ops are only available with GCC on x86 when
2346 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2347 dnl not available but would be available given the right flags, we want
2348 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2349 dnl that then to silently fall back on emulated atomic ops just because
2350 dnl the user had the wrong build environment.
2351
2352 dnl We may add other compilers here in the future...
2353
2354 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2355   AC_TRY_COMPILE([],
2356                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2357                  [glib_cv_g_atomic_lock_free=yes],
2358                  [glib_cv_g_atomic_lock_free=no])])
2359
2360 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2361   SAVE_CFLAGS="${CFLAGS}"
2362   CFLAGS="-march=i486"
2363   AC_TRY_COMPILE([],
2364                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2365                  [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2366                  [])
2367   CFLAGS="${SAVE_CFLAGS}"
2368 fi
2369
2370 dnl We need a more robust approach here...
2371 case $host_cpu in
2372   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2373     glib_memory_barrier_needed=no
2374     ;;
2375   sparc*|alpha*|powerpc*|ia64)
2376     glib_memory_barrier_needed=yes
2377     ;;
2378   *)
2379     glib_memory_barrier_needed=yes
2380     ;;
2381 esac
2382
2383 dnl ************************
2384 dnl ** Check for futex(2) **
2385 dnl ************************
2386 AC_CACHE_CHECK(for futex(2) system call,
2387     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2388 #include <linux/futex.h>
2389 #include <sys/syscall.h>
2390 #include <unistd.h>
2391 ],[
2392 int
2393 main (void)
2394 {
2395   /* it is not like this actually runs or anything... */
2396   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2397   return 0;
2398 }
2399 ])],glib_cv_futex=yes,glib_cv_futex=no))
2400 if test x"$glib_cv_futex" = xyes; then
2401   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2402 fi
2403
2404 AC_CACHE_CHECK(for eventfd(2) system call,
2405     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2406 #include <sys/eventfd.h>
2407 #include <unistd.h>
2408 ],[
2409 int
2410 main (void)
2411 {
2412   eventfd (0, EFD_CLOEXEC);
2413   return 0;
2414 }
2415 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2416 if test x"$glib_cv_eventfd" = x"yes"; then
2417   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2418 fi
2419 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2420
2421 dnl ****************************************
2422 dnl *** GLib POLL* compatibility defines ***
2423 dnl ****************************************
2424
2425 glib_poll_includes=["
2426 #include <sys/types.h>
2427 #include <sys/poll.h>
2428 "]
2429
2430 if test $ac_cv_header_sys_types_h = yes &&
2431    test $ac_cv_header_sys_poll_h = yes ; then
2432   glib_failed=false
2433   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2434   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2435   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2436   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2437   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2438   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2439   if $glib_failed ; then
2440     AC_MSG_ERROR([Could not determine values for POLL* constants])
2441   fi
2442 else
2443   glib_cv_value_POLLIN=1
2444   glib_cv_value_POLLOUT=4
2445   glib_cv_value_POLLPRI=2
2446   glib_cv_value_POLLERR=8
2447   glib_cv_value_POLLHUP=16
2448   glib_cv_value_POLLNVAL=32
2449 fi
2450
2451 AC_MSG_CHECKING([for broken poll])
2452 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2453         #include <stdlib.h>
2454         #include <fcntl.h>
2455         #include <poll.h>
2456         #ifdef HAVE_SYS_POLL_H
2457         #include <sys/poll.h>
2458         #endif
2459         int main(void) {
2460           struct pollfd fds[1];
2461           int fd;
2462           fd = open("/dev/null", 1);
2463           fds[0].fd = fd;
2464           fds[0].events = POLLIN;
2465           fds[0].revents = 0;
2466           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2467                 exit(1);  /* Does not work for devices -- fail */
2468           }
2469           exit(0);
2470         }]])],
2471   [broken_poll=no],
2472   [broken_poll=yes
2473    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2474   [broken_poll="no (cross compiling)"])
2475 AC_MSG_RESULT($broken_poll)
2476
2477 dnl *********************
2478 dnl *** GRegex checks ***
2479 dnl *********************
2480
2481 PCRE_REQUIRED_VERSION=8.11
2482
2483 # Check if we should use the internal or the system-supplied pcre
2484 AC_ARG_WITH(pcre,
2485             [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2486                             [whether to use system PCRE [default=internal]])])
2487
2488 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2489
2490 if test "x$with_pcre" = xsystem; then
2491   PKG_CHECK_MODULES(PCRE,
2492                     libpcre >= $PCRE_REQUIRED_VERSION)
2493   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2494                   glib_save_CFLAGS="$CFLAGS"
2495                   glib_save_LIBS="$LIBS"
2496                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2497                   AC_TRY_RUN([#include <pcre.h>
2498                               int main () {
2499                                 int support;
2500                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2501                                 if (!support)
2502                                   return 1;
2503                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2504                                 if (!support)
2505                                   return 1;
2506                                 return 0;
2507                               }],
2508                   glib_cv_pcre_has_unicode=yes,
2509                   glib_cv_pcre_has_unicode=no,
2510                   glib_cv_pcre_has_unicode=yes)
2511                   CFLAGS="$glib_save_CFLAGS"
2512                   LIBS="$glib_save_LIBS"
2513       ])
2514   if test "$glib_cv_pcre_has_unicode" = "no"; then
2515     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2516   fi
2517   AC_SUBST(PCRE_CFLAGS)
2518   AC_SUBST(PCRE_LIBS)
2519   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2520   PCRE_REQUIRES=libpcre
2521   AC_SUBST(PCRE_REQUIRES)
2522 else
2523   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2524   if test x"$GCC" = xyes; then
2525     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2526     save_CFLAGS="$CFLAGS"
2527     CFLAGS="$CFLAGS -Wno-pointer-sign"
2528     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2529                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2530     CFLAGS="$save_CFLAGS"
2531   fi
2532 fi
2533 AC_SUBST(PCRE_WARN_CFLAGS)
2534
2535 dnl **********************
2536 dnl *** Win32 API libs ***
2537 dnl **********************
2538
2539 case $host in
2540   *-*-cygwin*)
2541         G_LIBS_EXTRA="-luser32 -lkernel32"
2542     ;;
2543   *-*-mingw*)
2544         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2545     ;;
2546   *)
2547         G_LIBS_EXTRA=""
2548     ;;
2549 esac
2550 AC_SUBST(G_LIBS_EXTRA)
2551
2552 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2553 dnl since we need it for g_iconv()
2554
2555 AC_MSG_CHECKING([for EILSEQ])
2556 AC_TRY_COMPILE([
2557 #include <errno.h>
2558 ],
2559 [
2560 int error = EILSEQ;
2561 ], have_eilseq=yes, have_eilseq=no);
2562 AC_MSG_RESULT($have_eilseq)
2563
2564 dnl ******************************************************************
2565 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2566 dnl *** glib-compile-schemas in PATH                               ***
2567 dnl ******************************************************************
2568
2569 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2570
2571 if test $cross_compiling = yes && test x$enable_modular_tests = xyes; then
2572   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2573   if test x$GLIB_GENMARSHAL = xno; then
2574     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2575   fi
2576
2577   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2578   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2579     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2580   fi
2581
2582   AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources, no)
2583   if test x$GLIB_COMPILE_RESOURCES = xno; then
2584     AC_MSG_ERROR(Could not find a glib-compile-resources in your PATH)
2585   fi
2586 fi
2587
2588 dnl **************************
2589 dnl *** Checks for gtk-doc ***
2590 dnl **************************
2591
2592 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2593
2594 AC_ARG_ENABLE(man,
2595               [AC_HELP_STRING([--enable-man],
2596                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2597               enable_man=no)
2598
2599 if test "${enable_man}" != no; then
2600 dnl
2601 dnl Check for xsltproc
2602 dnl
2603 AC_PATH_PROG([XSLTPROC], [xsltproc])
2604   if test -z "$XSLTPROC"; then
2605     enable_man=no
2606   fi
2607
2608   dnl check for DocBook DTD and stylesheets in the local catalog.
2609   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2610      [DocBook XML DTD V4.1.2],,enable_man=no)
2611   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2612      [DocBook XSL Stylesheets],,enable_man=no)
2613 fi
2614
2615 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2616
2617 dnl
2618 dnl Tracing
2619 dnl
2620
2621 AC_ARG_ENABLE([dtrace],
2622              [AS_HELP_STRING([--enable-dtrace],
2623                               [include tracing support for dtrace])])
2624 have_dtrace=no
2625 AC_MSG_CHECKING([whether to include dtrace tracing support])
2626 if test "x$enable_dtrace" != xno; then
2627   if test x$glib_have_carbon = xyes; then
2628     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2629   else
2630     AC_MSG_RESULT([yes])
2631     AC_CHECK_PROGS(DTRACE, dtrace)
2632     if test -z "$DTRACE"; then
2633       if test "x$enable_dtrace" = xyes; then
2634         AC_MSG_ERROR([dtrace not found])
2635       fi
2636     else
2637       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2638                       [if test "x$enable_dtrace" = xyes; then
2639                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2640                        fi])
2641     fi
2642   fi
2643 else
2644   AC_MSG_RESULT([no])
2645 fi
2646 if test "x$have_dtrace" = xyes; then
2647   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2648 fi
2649 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2650
2651 AC_MSG_CHECKING([whether to include systemtap tracing support])
2652 AC_ARG_ENABLE([systemtap],
2653              [AS_HELP_STRING([--enable-systemtap],
2654                               [include tracing support for systemtap])])
2655 have_systemtap=no
2656 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2657   have_systemtap=yes
2658 fi
2659 AC_MSG_RESULT(${have_systemtap})
2660
2661 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2662
2663 AC_ARG_WITH([tapset-install-dir],
2664             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2665                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2666             [if test "x${withval}" = x; then
2667                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2668              else
2669                ABS_TAPSET_DIR="${withval}"
2670               fi],
2671             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2672 AC_SUBST(ABS_TAPSET_DIR)
2673
2674 dnl ************************************
2675 dnl *** Enable lcov coverage reports ***
2676 dnl ************************************
2677
2678 AC_ARG_ENABLE(gcov,
2679   AS_HELP_STRING([--enable-gcov],
2680                  [enable coverage testing with gcov]),
2681   [use_gcov=$enableval], [use_gcov=no])
2682
2683 if test "x$use_gcov" = "xyes"; then
2684   dnl we need gcc:
2685   if test "$GCC" != "yes"; then
2686     AC_MSG_ERROR([GCC is required for --enable-gcov])
2687   fi
2688
2689   dnl Check if ccache is being used
2690   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2691   case `$SHTOOL path $CC` in
2692     *ccache*[)] gcc_ccache=yes;;
2693     *[)] gcc_ccache=no;;
2694   esac
2695
2696   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2697     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2698   fi
2699
2700   ltp_version_list="1.6 1.7 1.8 1.9"
2701   AC_CHECK_PROG(LTP, lcov, lcov)
2702   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2703
2704   if test "$LTP"; then
2705     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2706       glib_cv_ltp_version=invalid
2707       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2708       for ltp_check_version in $ltp_version_list; do
2709         if test "$ltp_version" = "$ltp_check_version"; then
2710           glib_cv_ltp_version="$ltp_check_version (ok)"
2711         fi
2712       done
2713     ])
2714   else
2715     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2716     AC_MSG_ERROR([$ltp_msg])
2717   fi
2718
2719   case $glib_cv_ltp_version in
2720     ""|invalid[)]
2721       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2722       AC_MSG_ERROR([$ltp_msg])
2723       LTP="exit 0;"
2724       ;;
2725   esac
2726
2727   if test -z "$LTP_GENHTML"; then
2728     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2729   fi
2730
2731   dnl Remove all optimization flags from CFLAGS
2732   changequote({,})
2733   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2734   changequote([,])
2735
2736   dnl Add the special gcc flags
2737   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2738   LDFLAGS="$LDFLAGS -lgcov"
2739 fi
2740
2741 dnl ******************************
2742 dnl *** output the whole stuff ***
2743 dnl ******************************
2744
2745 dnl this section will only be run if config.status is invoked with no
2746 dnl arguments, or with "glib/glibconfig.h" as an argument.
2747 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2748 [
2749         outfile=glib/glibconfig.h-tmp
2750         cat > $outfile <<\_______EOF
2751 /* glibconfig.h
2752  *
2753  * This is a generated file.  Please modify 'configure.ac'
2754  */
2755
2756 #ifndef __GLIBCONFIG_H__
2757 #define __GLIBCONFIG_H__
2758
2759 #include <glib/gmacros.h>
2760
2761 _______EOF
2762
2763         if test x$glib_limits_h = xyes; then
2764           echo '#include <limits.h>' >> $outfile
2765         fi
2766         if test x$glib_float_h = xyes; then
2767           echo '#include <float.h>' >> $outfile
2768         fi
2769         if test x$glib_values_h = xyes; then
2770           echo '#include <values.h>' >> $outfile
2771         fi
2772         if test "$glib_header_alloca_h" = "yes"; then
2773           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2774         fi
2775         if test x$glib_sys_poll_h = xyes; then
2776           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2777         fi
2778         if test x$glib_included_printf != xyes; then
2779           echo "
2780 /* Specifies that GLib's g_print*() functions wrap the
2781  * system printf functions.  This is useful to know, for example,
2782  * when using glibc's register_printf_function().
2783  */" >> $outfile
2784           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2785         fi
2786
2787         cat >> $outfile <<_______EOF
2788
2789 G_BEGIN_DECLS
2790
2791 #define G_MINFLOAT      $glib_mf
2792 #define G_MAXFLOAT      $glib_Mf
2793 #define G_MINDOUBLE     $glib_md
2794 #define G_MAXDOUBLE     $glib_Md
2795 #define G_MINSHORT      $glib_ms
2796 #define G_MAXSHORT      $glib_Ms
2797 #define G_MAXUSHORT     $glib_Mus
2798 #define G_MININT        $glib_mi
2799 #define G_MAXINT        $glib_Mi
2800 #define G_MAXUINT       $glib_Mui
2801 #define G_MINLONG       $glib_ml
2802 #define G_MAXLONG       $glib_Ml
2803 #define G_MAXULONG      $glib_Mul
2804
2805 _______EOF
2806
2807
2808         ### this should always be true in a modern C/C++ compiler
2809         cat >>$outfile <<_______EOF
2810 typedef signed char gint8;
2811 typedef unsigned char guint8;
2812 _______EOF
2813
2814
2815         if test -n "$gint16"; then
2816           cat >>$outfile <<_______EOF
2817 typedef signed $gint16 gint16;
2818 typedef unsigned $gint16 guint16;
2819 #define G_GINT16_MODIFIER $gint16_modifier
2820 #define G_GINT16_FORMAT $gint16_format
2821 #define G_GUINT16_FORMAT $guint16_format
2822 _______EOF
2823         fi
2824
2825
2826         if test -n "$gint32"; then
2827           cat >>$outfile <<_______EOF
2828 typedef signed $gint32 gint32;
2829 typedef unsigned $gint32 guint32;
2830 #define G_GINT32_MODIFIER $gint32_modifier
2831 #define G_GINT32_FORMAT $gint32_format
2832 #define G_GUINT32_FORMAT $guint32_format
2833 _______EOF
2834         fi
2835
2836         cat >>$outfile <<_______EOF
2837 #define G_HAVE_GINT64 1          /* deprecated, always true */
2838
2839 ${glib_extension}typedef signed $gint64 gint64;
2840 ${glib_extension}typedef unsigned $gint64 guint64;
2841
2842 #define G_GINT64_CONSTANT(val)  $gint64_constant
2843 #define G_GUINT64_CONSTANT(val) $guint64_constant
2844 _______EOF
2845
2846         if test x$gint64_format != x ; then
2847           cat >>$outfile <<_______EOF
2848 #define G_GINT64_MODIFIER $gint64_modifier
2849 #define G_GINT64_FORMAT $gint64_format
2850 #define G_GUINT64_FORMAT $guint64_format
2851 _______EOF
2852         else
2853           cat >>$outfile <<_______EOF
2854 #undef G_GINT64_MODIFIER
2855 #undef G_GINT64_FORMAT
2856 #undef G_GUINT64_FORMAT
2857 _______EOF
2858         fi
2859
2860         cat >>$outfile <<_______EOF
2861
2862 #define GLIB_SIZEOF_VOID_P $glib_void_p
2863 #define GLIB_SIZEOF_LONG   $glib_long
2864 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2865
2866 _______EOF
2867
2868         cat >>$outfile <<_______EOF
2869 typedef signed $glib_size_type_define gssize;
2870 typedef unsigned $glib_size_type_define gsize;
2871 #define G_GSIZE_MODIFIER $gsize_modifier
2872 #define G_GSSIZE_FORMAT $gssize_format
2873 #define G_GSIZE_FORMAT $gsize_format
2874
2875 #define G_MAXSIZE       G_MAXU$glib_msize_type
2876 #define G_MINSSIZE      G_MIN$glib_msize_type
2877 #define G_MAXSSIZE      G_MAX$glib_msize_type
2878
2879 typedef gint64 goffset;
2880 #define G_MINOFFSET     G_MININT64
2881 #define G_MAXOFFSET     G_MAXINT64
2882
2883 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2884 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2885 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2886
2887 _______EOF
2888
2889         if test -z "$glib_unknown_void_p"; then
2890           cat >>$outfile <<_______EOF
2891
2892 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2893 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2894
2895 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2896 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2897
2898 typedef signed $glib_intptr_type_define gintptr;
2899 typedef unsigned $glib_intptr_type_define guintptr;
2900
2901 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2902 #define G_GINTPTR_FORMAT        $gintptr_format
2903 #define G_GUINTPTR_FORMAT       $guintptr_format
2904 _______EOF
2905         else
2906           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2907         fi
2908
2909
2910
2911         cat >>$outfile <<_______EOF
2912 $glib_atexit
2913 $glib_memmove
2914 $glib_defines
2915 $glib_os
2916 $glib_static_compilation
2917
2918 $glib_vacopy
2919
2920 #ifdef  __cplusplus
2921 #define G_HAVE_INLINE   1
2922 #else   /* !__cplusplus */
2923 $glib_inline
2924 #endif  /* !__cplusplus */
2925
2926 #ifdef  __cplusplus
2927 #define G_CAN_INLINE    1
2928 _______EOF
2929
2930         if test x$g_can_inline = xyes ; then
2931                 cat >>$outfile <<_______EOF
2932 #else   /* !__cplusplus */
2933 #define G_CAN_INLINE    1
2934 _______EOF
2935         fi
2936
2937         cat >>$outfile <<_______EOF
2938 #endif
2939
2940 _______EOF
2941
2942         if test x$g_have_iso_c_varargs = xyes ; then
2943                 cat >>$outfile <<_______EOF
2944 #ifndef __cplusplus
2945 # define G_HAVE_ISO_VARARGS 1
2946 #endif
2947 _______EOF
2948         fi
2949         if test x$g_have_iso_cxx_varargs = xyes ; then
2950                 cat >>$outfile <<_______EOF
2951 #ifdef __cplusplus
2952 # define G_HAVE_ISO_VARARGS 1
2953 #endif
2954 _______EOF
2955         fi
2956         if test x$g_have_gnuc_varargs = xyes ; then
2957                 cat >>$outfile <<_______EOF
2958
2959 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2960  * is passed ISO vararg support is turned off, and there is no work
2961  * around to turn it on, so we unconditionally turn it off.
2962  */
2963 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2964 #  undef G_HAVE_ISO_VARARGS
2965 #endif
2966
2967 #define G_HAVE_GNUC_VARARGS 1
2968 _______EOF
2969         fi
2970
2971         case x$g_stack_grows in
2972         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2973         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2974         esac
2975
2976
2977         echo >>$outfile
2978         if test x$g_have_eilseq = xno; then
2979                 cat >>$outfile <<_______EOF
2980 #ifndef EILSEQ
2981 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
2982  * The correspondence between this and the corresponding definition
2983  * in libiconv is essential.
2984  */
2985 #  define EILSEQ ENOENT
2986 #endif
2987 _______EOF
2988
2989         fi
2990
2991         if test x$g_have_gnuc_visibility = xyes; then
2992                 cat >>$outfile <<_______EOF
2993 #define G_HAVE_GNUC_VISIBILITY 1
2994 _______EOF
2995         fi
2996                 cat >>$outfile <<_______EOF
2997 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
2998 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2999 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3000 #define G_GNUC_INTERNAL __hidden
3001 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3002 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3003 #else
3004 #define G_GNUC_INTERNAL
3005 #endif
3006 _______EOF
3007
3008         echo >>$outfile
3009         cat >>$outfile <<_______EOF
3010 #define G_THREADS_ENABLED
3011 #define G_THREADS_IMPL_$g_threads_impl_def
3012 _______EOF
3013
3014         if test x"$g_memory_barrier_needed" != xno; then
3015           echo >>$outfile
3016           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3017         fi
3018         if test x"$g_atomic_lock_free" = xyes; then
3019           echo >>$outfile
3020           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3021         fi
3022         echo >>$outfile
3023         g_bit_sizes="16 32 64"
3024         for bits in $g_bit_sizes; do
3025           cat >>$outfile <<_______EOF
3026 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3027 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3028 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3029 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3030 _______EOF
3031         done
3032
3033         cat >>$outfile <<_______EOF
3034 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3035 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3036 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3037 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3038 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3039 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3040 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3041 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3042 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3043 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3044 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3045 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3046 #define G_BYTE_ORDER $g_byte_order
3047
3048 #define GLIB_SYSDEF_POLLIN =$g_pollin
3049 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3050 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3051 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3052 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3053 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3054
3055 #define G_MODULE_SUFFIX "$g_module_suffix"
3056
3057 typedef $g_pid_type GPid;
3058
3059 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3060 #define GLIB_SYSDEF_AF_INET $g_af_inet
3061 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3062
3063 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3064 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3065 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3066
3067 G_END_DECLS
3068
3069 #endif /* __GLIBCONFIG_H__ */
3070 _______EOF
3071
3072
3073         if cmp -s $outfile glib/glibconfig.h; then
3074           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3075           rm -f $outfile
3076         else
3077           mv $outfile glib/glibconfig.h
3078         fi
3079 ],[
3080
3081 # Note that if two cases are the same, case goes with the first one.
3082 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3083 # on variable expansion in case labels.  Look at the generated config.status
3084 # for a hint.
3085
3086 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3087   glib_header_alloca_h="$ac_cv_working_alloca_h"
3088 else
3089   glib_header_alloca_h="$ac_cv_header_alloca_h"
3090 fi
3091
3092 case xyes in
3093 x$ac_cv_header_float_h)
3094   glib_float_h=yes
3095   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3096   glib_md=DBL_MIN glib_Md=DBL_MAX
3097   ;;
3098 x$ac_cv_header_values_h)
3099   glib_values_h=yes
3100   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3101   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3102   ;;
3103 esac
3104
3105 case xyes in
3106 x$ac_cv_header_limits_h)
3107   glib_limits_h=yes
3108   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3109   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3110   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3111   ;;
3112 x$ac_cv_header_values_h)
3113   glib_values_h=yes
3114   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3115   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3116   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3117   ;;
3118 esac
3119
3120 if test x$ac_cv_header_sys_poll_h = xyes ; then
3121   glib_sys_poll_h=yes
3122 fi
3123
3124 if test x$enable_included_printf = xyes ; then
3125   glib_included_printf=yes
3126 fi
3127
3128 case 2 in
3129 $ac_cv_sizeof_short)
3130   gint16=short
3131   gint16_modifier='"h"'
3132   gint16_format='"hi"'
3133   guint16_format='"hu"'
3134   ;;
3135 $ac_cv_sizeof_int)
3136   gint16=int
3137   gint16_modifier='""'
3138   gint16_format='"i"'
3139   guint16_format='"u"'
3140   ;;
3141 esac
3142 case 4 in
3143 $ac_cv_sizeof_short)
3144   gint32=short
3145   gint32_modifier='"h"'
3146   gint32_format='"hi"'
3147   guint32_format='"hu"'
3148   ;;
3149 $ac_cv_sizeof_int)
3150   gint32=int
3151   gint32_modifier='""'
3152   gint32_format='"i"'
3153   guint32_format='"u"'
3154   ;;
3155 $ac_cv_sizeof_long)
3156   gint32=long
3157   gint32_modifier='"l"'
3158   gint32_format='"li"'
3159   guint32_format='"lu"'
3160   ;;
3161 esac
3162 case 8 in
3163 $ac_cv_sizeof_int)
3164   gint64=int
3165   gint64_modifier='""'
3166   gint64_format='"i"'
3167   guint64_format='"u"'
3168   glib_extension=
3169   gint64_constant='(val)'
3170   guint64_constant='(val)'
3171   ;;
3172 $ac_cv_sizeof_long)
3173   gint64=long
3174   gint64_modifier='"l"'
3175   gint64_format='"li"'
3176   guint64_format='"lu"'
3177   glib_extension=
3178   gint64_constant='(val##L)'
3179   guint64_constant='(val##UL)'
3180   ;;
3181 $ac_cv_sizeof_long_long)
3182   gint64='long long'
3183   if test -n "$glib_cv_long_long_format"; then
3184     gint64_modifier='"'$glib_cv_long_long_format'"'
3185     gint64_format='"'$glib_cv_long_long_format'i"'
3186     guint64_format='"'$glib_cv_long_long_format'u"'
3187   fi
3188   glib_extension='G_GNUC_EXTENSION '
3189   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3190   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3191   ;;
3192 $ac_cv_sizeof___int64)
3193   gint64='__int64'
3194   if test -n "$glib_cv_long_long_format"; then
3195     gint64_modifier='"'$glib_cv_long_long_format'"'
3196     gint64_format='"'$glib_cv_long_long_format'i"'
3197     guint64_format='"'$glib_cv_long_long_format'u"'
3198   fi
3199   glib_extension=
3200   gint64_constant='(val##i64)'
3201   guint64_constant='(val##ui64)'
3202   ;;
3203 esac
3204 glib_size_t=$ac_cv_sizeof_size_t
3205 glib_size_type_define="$glib_size_type"
3206 glib_void_p=$ac_cv_sizeof_void_p
3207 glib_long=$ac_cv_sizeof_long
3208
3209 case "$glib_size_type" in
3210 short)
3211   gsize_modifier='"h"'
3212   gsize_format='"hu"'
3213   gssize_format='"hi"'
3214   glib_msize_type='SHRT'
3215   ;;
3216 int)
3217   gsize_modifier='""'
3218   gsize_format='"u"'
3219   gssize_format='"i"'
3220   glib_msize_type='INT'
3221   ;;
3222 long)
3223   gsize_modifier='"l"'
3224   gsize_format='"lu"'
3225   gssize_format='"li"'
3226   glib_msize_type='LONG'
3227   ;;
3228 "long long"|__int64)
3229   gsize_modifier='"I64"'
3230   gsize_format='"I64u"'
3231   gssize_format='"I64i"'
3232   glib_msize_type='INT64'
3233   ;;
3234 esac
3235
3236 gintbits=`expr $ac_cv_sizeof_int \* 8`
3237 glongbits=`expr $ac_cv_sizeof_long \* 8`
3238 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3239
3240 case $ac_cv_sizeof_void_p in
3241 $ac_cv_sizeof_int)
3242   glib_intptr_type_define=int
3243   gintptr_modifier='""'
3244   gintptr_format='"i"'
3245   guintptr_format='"u"'
3246   glib_gpi_cast='(gint)'
3247   glib_gpui_cast='(guint)'
3248   ;;
3249 $ac_cv_sizeof_long)
3250   glib_intptr_type_define=long
3251   gintptr_modifier='"l"'
3252   gintptr_format='"li"'
3253   guintptr_format='"lu"'
3254   glib_gpi_cast='(glong)'
3255   glib_gpui_cast='(gulong)'
3256   ;;
3257 $ac_cv_sizeof_long_long)
3258   glib_intptr_type_define='long long'
3259   gintptr_modifier='"I64"'
3260   gintptr_format='"I64i"'
3261   guintptr_format='"I64u"'
3262   glib_gpi_cast='(gint64)'
3263   glib_gpui_cast='(guint64)'
3264   ;;
3265 $ac_cv_sizeof___int64)
3266   glib_intptr_type_define=__int64
3267   gintptr_modifier='"I64"'
3268   gintptr_format='"I64i"'
3269   guintptr_format='"I64u"'
3270   glib_gpi_cast='(gint64)'
3271   glib_gpui_cast='(guint64)'
3272   ;;
3273 *)
3274   glib_unknown_void_p=yes
3275   ;;
3276 esac
3277
3278
3279 case xyes in
3280 x$ac_cv_func_atexit)
3281   glib_atexit="
3282 #ifdef NeXT /* @#%@! NeXTStep */
3283 # define g_ATEXIT(proc) (!atexit (proc))
3284 #else
3285 # define g_ATEXIT(proc) (atexit (proc))
3286 #endif"
3287   ;;
3288 x$ac_cv_func_on_exit)
3289   glib_atexit="
3290 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3291   ;;
3292 esac
3293
3294 case xyes in
3295 x$ac_cv_func_memmove)
3296   glib_memmove='
3297 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3298   ;;
3299 x$glib_cv_working_bcopy)
3300   glib_memmove="
3301 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3302 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3303   ;;
3304 *)
3305   glib_memmove="
3306 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3307  * so we have to roll our own copy routine. */
3308 void g_memmove (void* dest, const void * src, unsigned long len);"
3309   ;;
3310 esac
3311
3312 glib_defines="
3313 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3314 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3315 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3316 "
3317
3318 case xyes in
3319 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3320 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3321 *)                      glib_vacopy=''
3322 esac
3323
3324 if test x$glib_cv_va_val_copy = xno; then
3325   glib_vacopy="\$glib_vacopy
3326 #define G_VA_COPY_AS_ARRAY 1"
3327 fi
3328
3329 if test x$glib_cv_hasinline = xyes; then
3330     glib_inline='#define G_HAVE_INLINE 1'
3331 fi
3332 if test x$glib_cv_has__inline = xyes; then
3333     glib_inline="\$glib_inline
3334 #define G_HAVE___INLINE 1"
3335 fi
3336 if test x$glib_cv_has__inline__ = xyes; then
3337     glib_inline="\$glib_inline
3338 #define G_HAVE___INLINE__ 1"
3339 fi
3340
3341 g_have_gnuc_varargs=$g_have_gnuc_varargs
3342 g_have_iso_c_varargs=$g_have_iso_c_varargs
3343 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3344
3345 g_can_inline=$g_can_inline
3346 g_have_gnuc_visibility=$g_have_gnuc_visibility
3347 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3348
3349 if test x$ac_cv_c_bigendian = xyes; then
3350   g_byte_order=G_BIG_ENDIAN
3351   g_bs_native=BE
3352   g_bs_alien=LE
3353 else
3354   g_byte_order=G_LITTLE_ENDIAN
3355   g_bs_native=LE
3356   g_bs_alien=BE
3357 fi
3358
3359 g_pollin=$glib_cv_value_POLLIN
3360 g_pollout=$glib_cv_value_POLLOUT
3361 g_pollpri=$glib_cv_value_POLLPRI
3362 g_pollhup=$glib_cv_value_POLLHUP
3363 g_pollerr=$glib_cv_value_POLLERR
3364 g_pollnval=$glib_cv_value_POLLNVAL
3365
3366 # If a family is not found on the system, define that family to
3367 # a negative value, picking a different one for each undefined
3368 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3369 # This is needed because glib-mkenums doesn't handle optional
3370 # values in enums, and thus we have to have all existing values
3371 # defined in the enum.
3372 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3373   g_af_unix=$glib_cv_value_AF_UNIX
3374 else
3375   g_af_unix=-1
3376 fi
3377 g_af_inet=$glib_cv_value_AF_INET
3378 g_af_inet6=$glib_cv_value_AF_INET6
3379
3380 g_msg_peek=$glib_cv_value_MSG_PEEK
3381 g_msg_oob=$glib_cv_value_MSG_OOB
3382 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3383
3384 g_stack_grows=$glib_cv_stack_grows
3385
3386 g_have_eilseq=$have_eilseq
3387
3388 g_threads_impl_def=$g_threads_impl
3389
3390 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3391 g_memory_barrier_needed="$glib_memory_barrier_needed"
3392 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3393
3394 g_module_suffix="$glib_gmodule_suffix"
3395
3396 g_pid_type="$glib_pid_type"
3397 case $host in
3398   *-*-beos*)
3399     glib_os="#define G_OS_BEOS"
3400     ;;
3401   *-*-cygwin*)
3402     glib_os="#define G_OS_UNIX
3403 #define G_PLATFORM_WIN32
3404 #define G_WITH_CYGWIN"
3405     ;;
3406   *-*-mingw*)
3407     glib_os="#define G_OS_WIN32
3408 #define G_PLATFORM_WIN32"
3409     ;;
3410   *)
3411     glib_os="#define G_OS_UNIX"
3412     ;;
3413 esac
3414 glib_static_compilation=""
3415 if test x$glib_win32_static_compilation = xyes; then
3416   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3417 #define GOBJECT_STATIC_COMPILATION 1"
3418 fi
3419 ])
3420
3421 # Redo enough to get guint32 and guint64 for the alignment checks below
3422 case 4 in
3423 $ac_cv_sizeof_short)
3424   gint32=short
3425   ;;
3426 $ac_cv_sizeof_int)
3427   gint32=int
3428   ;;
3429 $ac_cv_sizeof_long)
3430   gint32=long
3431   ;;
3432 esac
3433 case 8 in
3434 $ac_cv_sizeof_int)
3435   gint64=int
3436   ;;
3437 $ac_cv_sizeof_long)
3438   gint64=long
3439   ;;
3440 $ac_cv_sizeof_long_long)
3441   gint64='long long'
3442   ;;
3443 $ac_cv_sizeof___int64)
3444   gint64='__int64'
3445   ;;
3446 esac
3447
3448 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3449 typedef unsigned $gint32 guint32;])
3450 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3451 typedef unsigned $gint64 guint64;])
3452 AC_CHECK_ALIGNOF([unsigned long])
3453
3454 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3455 #
3456 # 1.2.14 required for dbus_message_set_serial
3457 if test x$enable_modular_tests = xyes; then
3458    PKG_CHECK_MODULES(DBUS1,
3459                      dbus-1 >= 1.2.14,
3460                      [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3461                      have_dbus1=no)
3462    AC_SUBST(DBUS1_CFLAGS)
3463    AC_SUBST(DBUS1_LIBS)
3464 fi
3465 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3466
3467 dnl
3468 dnl Check for -Bsymbolic-functions linker flag used to avoid
3469 dnl intra-library PLT jumps, if available.
3470 dnl
3471
3472 AC_ARG_ENABLE(Bsymbolic,
3473               [AC_HELP_STRING([--disable-Bsymbolic],
3474                               [avoid linking with -Bsymbolic])],,
3475               [SAVED_LDFLAGS="${LDFLAGS}"
3476                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3477                LDFLAGS=-Wl,-Bsymbolic-functions
3478                AC_TRY_LINK([], [int main (void) { return 0; }],
3479                            AC_MSG_RESULT(yes)
3480                            enable_Bsymbolic=yes,
3481                            AC_MSG_RESULT(no)
3482                            enable_Bsymbolic=no)
3483                LDFLAGS="${SAVED_LDFLAGS}"])
3484
3485 if test "x${enable_Bsymbolic}" = "xyes"; then
3486   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3487 fi
3488
3489 AC_SUBST(GLIB_LINK_FLAGS)
3490
3491 #
3492 # Define variables corresponding to the correct include paths to use for
3493 # in-tree building.
3494 #
3495
3496 # for config.h:
3497 config_h_INCLUDES='-I$(top_builddir)'
3498 AC_SUBST(config_h_INCLUDES)
3499
3500 # glib:
3501 #   config.h
3502 #   $(top_builddir)/glib: for glibconfig.h
3503 #   $(top_srcdir)/glib:   for glib.h
3504 #   $(top_srcdir):        for everything
3505 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3506 AC_SUBST(glib_INCLUDES)
3507
3508 # gthread:
3509 #   same as glib
3510 gthread_INCLUDES='$(glib_INCLUDES)'
3511 AC_SUBST(gthread_INCLUDES)
3512
3513 # gobject:
3514 #   same as gthread
3515 gobject_INCLUDES='$(gthread_INCLUDES)'
3516 AC_SUBST(gobject_INCLUDES)
3517
3518 # gmodule:
3519 #   glib includes
3520 #   $(top_srcdir)/gmodule: for gmodule.h
3521 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3522 AC_SUBST(gmodule_INCLUDES)
3523
3524 # gio:
3525 #   same as gmodule
3526 gio_INCLUDES='$(gmodule_INCLUDES)'
3527 AC_SUBST(gio_INCLUDES)
3528
3529
3530 AC_CONFIG_FILES([
3531 glib-2.0.pc
3532 gmodule-2.0.pc
3533 gmodule-export-2.0.pc
3534 gmodule-no-export-2.0.pc
3535 gthread-2.0.pc
3536 gobject-2.0.pc
3537 gio-2.0.pc
3538 gio-unix-2.0.pc
3539 gio-windows-2.0.pc
3540 glib-zip
3541 glib-gettextize
3542 Makefile
3543 build/Makefile
3544 build/win32/Makefile
3545 build/win32/dirent/Makefile
3546 build/win32/vs9/Makefile
3547 build/win32/vs10/Makefile
3548 glib/Makefile
3549 glib/glib.stp
3550 glib/libcharset/Makefile
3551 glib/gnulib/Makefile
3552 glib/pcre/Makefile
3553 glib/update-pcre/Makefile
3554 glib/tests/Makefile
3555 gmodule/Makefile
3556 gmodule/gmoduleconf.h
3557 gobject/Makefile
3558 gobject/gobject.stp
3559 gobject/glib-mkenums
3560 gobject/tests/Makefile
3561 gthread/Makefile
3562 gio/Makefile
3563 gio/gdbus-2.0/codegen/Makefile
3564 gio/gdbus-2.0/codegen/config.py
3565 gio/xdgmime/Makefile
3566 gio/inotify/Makefile
3567 gio/fen/Makefile
3568 gio/fam/Makefile
3569 gio/win32/Makefile
3570 gio/tests/Makefile
3571 gio/tests/gdbus-object-manager-example/Makefile
3572 po/Makefile.in
3573 docs/Makefile
3574 docs/reference/Makefile
3575 docs/reference/glib/Makefile
3576 docs/reference/glib/version.xml
3577 docs/reference/gobject/Makefile
3578 docs/reference/gobject/version.xml
3579 docs/reference/gio/Makefile
3580 docs/reference/gio/gdbus-object-manager-example/Makefile
3581 docs/reference/gio/version.xml
3582 tests/Makefile
3583 tests/gobject/Makefile
3584 tests/refcount/Makefile
3585 m4macros/Makefile
3586 ])
3587
3588 AC_CONFIG_COMMANDS([chmod-scripts],
3589 [chmod 0755 glib-zip
3590 chmod 0755 glib-gettextize
3591 chmod 0755 gobject/glib-mkenums])
3592
3593 # we want to invoke this macro solely so that the config.status script
3594 # and automake generated makefiles know about these generated files.
3595 # They are only needed to distcheck the package
3596 if false; then
3597   AC_CONFIG_FILES([
3598     INSTALL
3599     README
3600     config.h.win32
3601     glib/glibconfig.h.win32
3602     glib/makefile.msc
3603     glib/glib.rc
3604     gmodule/makefile.msc
3605     gmodule/gmodule.rc
3606     gobject/makefile.msc
3607     gobject/gobject.rc
3608     gthread/makefile.msc
3609     gthread/gthread.rc
3610     gio/gio.rc
3611     tests/makefile.msc
3612   ])
3613 fi
3614
3615 AC_OUTPUT