configure.ac

   1 m4_define(LIBUSB_MAJOR, [1])
   2 m4_define(LIBUSB_MINOR, [0])
   3 m4_define(LIBUSB_MICRO, [8])
   4
   5 AC_INIT([libusb], LIBUSB_MAJOR.LIBUSB_MINOR.LIBUSB_MICRO, [libusb-devel@lists.sourceforge.net], [libusb], [http://www.libusb.org/])
   6
   7 AC_SUBST([LIBUSB_VERSION_MAJOR], [LIBUSB_MAJOR])
   8 AC_SUBST([LIBUSB_VERSION_MINOR], [LIBUSB_MINOR])
   9 AC_SUBST([LIBUSB_VERSION_MICRO], [LIBUSB_MICRO])
  10
  11 # Library versioning
  12 # These numbers should be tweaked on every release. Read carefully:
  13 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  14 # http://sourceware.org/autobook/autobook/autobook_91.html
  15 lt_current="1"
  16 lt_revision="0"
  17 lt_age="1"
  18 AC_SUBST(lt_current)
  19 AC_SUBST(lt_revision)
  20 AC_SUBST(lt_age)
  21
  22 AM_INIT_AUTOMAKE
  23 AC_CONFIG_SRCDIR([libusb/core.c])
  24 AC_CONFIG_MACRO_DIR([m4])
  25 AM_CONFIG_HEADER([config.h])
  26 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  27
  28 AC_PREREQ([2.50])
  29 AC_PROG_CC
  30 AC_PROG_LIBTOOL
  31 AC_C_INLINE
  32 AM_PROG_CC_C_O
  33 AC_DEFINE([_GNU_SOURCE], [], [Use GNU extensions])
  34
  35 AM_MAINTAINER_MODE
  36
  37 AC_MSG_CHECKING([operating system])
  38 PC_LIBS_PRIVATE=
  39 case $host in
  40 *-linux*)
  41         AC_DEFINE(OS_LINUX, [], [Linux backend])
  42         AC_SUBST(OS_LINUX)
  43         AC_DEFINE([THREADS_POSIX], [], [Use Posix Threads])
  44         AC_MSG_RESULT([Linux])
  45         backend="linux"
  46         AC_CHECK_LIB(rt, clock_gettime, PC_LIBS_PRIVATE="-lrt")
  47         LIBS="${LIBS} ${PC_LIBS_PRIVATE}"
  48         threads="posix"
  49         THREAD_CFLAGS="-pthread"
  50         PC_LIBS_PRIVATE="${PC_LIBS_PRIVATE} -pthread"
  51         AM_LDFLAGS=""
  52         AC_CHECK_HEADERS([poll.h])
  53         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
  54         ;;
  55 *-darwin*)
  56         AC_DEFINE(OS_DARWIN, [], [Darwin backend])
  57         AC_SUBST(OS_DARWIN)
  58         AC_DEFINE([THREADS_POSIX], [], [Use Posix Threads])
  59         AC_MSG_RESULT([Darwin/MacOS X])
  60         backend="darwin"
  61         threads="posix"
  62         THREAD_CFLAGS="-pthread"
  63         PC_LIBS_PRIVATE="-Wl,-framework,IOKit -Wl,-framework,CoreFoundation -Wl,-prebind -no-undefined -pthread"
  64         AM_LDFLAGS=${PC_LIBS_PRIVATE}
  65         AC_CHECK_HEADERS([poll.h])
  66         AC_CHECK_TYPE([nfds_t],
  67                 [AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])],
  68                 [AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])],
  69                 [#include <poll.h>])
  70 ;;
  71 *-mingw*)
  72         AC_DEFINE(OS_WINDOWS, [], [Windows backend])
  73         AC_SUBST(OS_WINDOWS)
  74         AC_MSG_RESULT([Windows])
  75         backend="windows"
  76         threads="windows"
  77         PC_LIBS_PRIVATE="-lsetupapi -lole32 -ladvapi32"
  78         LIBS="${LIBS} ${PC_LIBS_PRIVATE}"
  79         # -avoid-version to avoid a naming scheme such as libusb-0.dll
  80         AM_LDFLAGS="-no-undefined -avoid-version --add-stdcall-alias"
  81         AC_CHECK_TOOL(RC, windres, no)
  82         AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])
  83         ;;
  84 *-cygwin*)
  85         AC_DEFINE(OS_WINDOWS, [], [Windows backend])
  86         AC_SUBST(OS_WINDOWS)
  87         AC_DEFINE([THREADS_POSIX], [], [Use Posix Threads])
  88         AC_MSG_RESULT([Windows])
  89         backend="windows"
  90         threads="posix"
  91         PC_LIBS_PRIVATE="-lsetupapi -lole32 -ladvapi32"
  92         LIBS="${LIBS} ${PC_LIBS_PRIVATE}"
  93         AM_LDFLAGS="-no-undefined -avoid-version"
  94         AC_CHECK_TOOL(RC, windres, no)
  95         AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])
  96         ;;
  97 *)
  98         AC_MSG_ERROR([unsupported operating system])
  99 esac
 100 AC_SUBST(PC_LIBS_PRIVATE)
 101
 102 AM_CONDITIONAL([OS_LINUX], [test "x$backend" = "xlinux"])
 103 AM_CONDITIONAL([OS_DARWIN], [test "x$backend" = "xdarwin"])
 104 AM_CONDITIONAL([OS_WINDOWS], [test "x$backend" = "xwindows"])
 105 AM_CONDITIONAL([THREADS_POSIX], [test "x$threads" = "xposix"])
 106
 107 # timerfd
 108 AC_CHECK_HEADER([sys/timerfd.h], [timerfd_h=1], [timerfd_h=0])
 109 AC_ARG_ENABLE([timerfd],
 110         [AS_HELP_STRING([--enable-timerfd],
 111                 [use timerfd for timing (default auto)])],
 112         [use_timerfd=$enableval], [use_timerfd='auto'])
 113
 114 if test "x$use_timerfd" = "xyes" -a "x$timerfd_h" = "x0"; then
 115         AC_MSG_ERROR([timerfd header not available; glibc 2.9+ required])
 116 fi
 117
 118 AC_CHECK_DECL([TFD_NONBLOCK], [tfd_hdr_ok=yes], [tfd_hdr_ok=no], [#include <sys/timerfd.h>])
 119 if test "x$use_timerfd" = "xyes" -a "x$tfd_hdr_ok" = "xno"; then
 120         AC_MSG_ERROR([timerfd header not usable; glibc 2.9+ required])
 121 fi
 122
 123 AC_MSG_CHECKING([whether to use timerfd for timing])
 124 if test "x$use_timerfd" = "xno"; then
 125         AC_MSG_RESULT([no (disabled by user)])
 126 else
 127         if test "x$timerfd_h" = "x1" -a "x$tfd_hdr_ok" = "xyes"; then
 128                 AC_MSG_RESULT([yes])
 129                 AC_DEFINE(USBI_TIMERFD_AVAILABLE, [], [timerfd headers available])
 130         else
 131                 AC_MSG_RESULT([no (header not available)])
 132         fi
 133 fi
 134
 135 AC_CHECK_TYPES(struct timespec)
 136
 137 # Message logging
 138 AC_ARG_ENABLE([log], [AS_HELP_STRING([--disable-log], [disable all logging])],
 139         [log_enabled=$enableval],
 140         [log_enabled='yes'])
 141 if test "x$log_enabled" != "xno"; then
 142         AC_DEFINE([ENABLE_LOGGING], 1, [Message logging])
 143 fi
 144
 145 AC_ARG_ENABLE([debug-log], [AS_HELP_STRING([--enable-debug-log],
 146         [enable debug logging (default n)])],
 147         [debug_log_enabled=$enableval],
 148         [debug_log_enabled='no'])
 149 if test "x$debug_log_enabled" != "xno"; then
 150         AC_DEFINE([ENABLE_DEBUG_LOGGING], 1, [Debug message logging])
 151 fi
 152
 153 # Examples build
 154 AC_ARG_ENABLE([examples-build], [AS_HELP_STRING([--enable-examples-build],
 155         [build example applications (default n)])],
 156         [build_examples=$enableval],
 157         [build_examples='no'])
 158 AM_CONDITIONAL([BUILD_EXAMPLES], [test "x$build_examples" != "xno"])
 159
 160 # Restore gnu89 inline semantics on gcc 4.3 and newer
 161 saved_cflags="$CFLAGS"
 162 CFLAGS="$CFLAGS -fgnu89-inline"
 163 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]), inline_cflags="-fgnu89-inline", inline_cflags="")
 164 CFLAGS="$saved_cflags"
 165
 166 # check for -fvisibility=hidden compiler support (GCC >= 3.4)
 167 saved_cflags="$CFLAGS"
 168 # -Werror required for cygwin
 169 CFLAGS="$CFLAGS -Werror -fvisibility=hidden"
 170 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
 171         [VISIBILITY_CFLAGS="-fvisibility=hidden"
 172          AC_DEFINE([DEFAULT_VISIBILITY], [__attribute__((visibility("default")))], [Default visibility]) ],
 173         [ VISIBILITY_CFLAGS=""
 174          AC_DEFINE([DEFAULT_VISIBILITY], [], [Default visibility]) ],
 175         ])
 176 CFLAGS="$saved_cflags"
 177
 178 # check for -Wno-pointer-sign compiler support (GCC >= 4)
 179 saved_cflags="$CFLAGS"
 180 CFLAGS="$CFLAGS -Wno-pointer-sign"
 181 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
 182         nopointersign_cflags="-Wno-pointer-sign", nopointersign_cflags="")
 183 CFLAGS="$saved_cflags"
 184
 185 # sigaction not available on MinGW
 186 AC_CHECK_FUNC([sigaction], [have_sigaction=yes], [have_sigaction=no])
 187 AM_CONDITIONAL([HAVE_SIGACTION], [test "x$have_sigaction" = "xyes"])
 188
 189 # headers not available on all platforms but required on others
 190 AC_CHECK_HEADERS([sys/time.h])
 191
 192 AC_SUBST([THREAD_CFLAGS])
 193
 194 AM_CFLAGS="-std=gnu99 $inline_cflags -Wall -Wundef -Wunused -Wstrict-prototypes -Werror-implicit-function-declaration $nopointersign_cflags -Wshadow"
 195
 196 AC_SUBST(VISIBILITY_CFLAGS)
 197 AC_SUBST(AM_CFLAGS)
 198 AC_SUBST(AM_LDFLAGS)
 199
 200 AC_CONFIG_FILES([libusb-1.0.pc] [Makefile] [libusb/Makefile] [libusb/libusb-1.0.rc] [examples/Makefile] [doc/Makefile] [doc/doxygen.cfg])
 201 AC_OUTPUT
 202