configure.ac

   1 dnl  Copyright © 2008 Dan Nicholson
   2 dnl
   3 dnl  Permission to use, copy, modify, distribute, and sell this software and its
   4 dnl  documentation for any purpose is hereby granted without fee, provided that
   5 dnl  the above copyright notice appear in all copies and that both that
   6 dnl  copyright notice and this permission notice appear in supporting
   7 dnl  documentation, and that the name of Keith Packard not be used in
   8 dnl  advertising or publicity pertaining to distribution of the software without
   9 dnl  specific, written prior permission.  Keith Packard makes no
  10 dnl  representations about the suitability of this software for any purpose.  It
  11 dnl  is provided "as is" without express or implied warranty.
  12 dnl
  13 dnl  DAN NICHOLSON DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  14 dnl  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  15 dnl  EVENT SHALL KEITH PACKARD BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  16 dnl  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  17 dnl  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  18 dnl  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  19 dnl  PERFORMANCE OF THIS SOFTWARE.
  20 dnl
  21 dnl Process this file with autoconf to create configure.
  22
  23 # Initialize Autoconf
  24 AC_PREREQ([2.60])
  25 AC_INIT([libxkbcommon], [0.1.0],
  26     [https://bugs.freedesktop.org/enter_bug.cgi?product=xorg])
  27 AC_CONFIG_SRCDIR([Makefile.am])
  28 AC_CONFIG_HEADERS([src/config.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 # Initialize Automake
  32 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  33 AM_MAINTAINER_MODE
  34
  35 # Initialize libtool
  36 AC_PROG_LIBTOOL
  37
  38 AC_PROG_CC
  39 AC_PROG_YACC
  40 AC_PROG_LEX
  41
  42 m4_ifndef([PKG_PROG_PKG_CONFIG],
  43     [m4_fatal([Could not locate the pkg-config autoconf macros.
  44     These are usually located in /usr/share/aclocal/pkg.m4. If your
  45     macros are in a different location, try setting the environment
  46     variable ACLOCAL="aclocal -I/other/macro/dir" before running
  47     autoreconf/autogen.sh.])])
  48 PKG_PROG_PKG_CONFIG
  49
  50 # Require xorg-macros minimum of 1.8 for AM_SILENT_RULES
  51 m4_ifndef([XORG_MACROS_VERSION],
  52           [m4_fatal([must install xorg-macros 1.8 or later before running autoconf/autogen])])
  53 XORG_MACROS_VERSION(1.8)
  54 XORG_DEFAULT_OPTIONS
  55 XORG_CHECK_MALLOC_ZERO
  56
  57 dnl Build native compiler needed for makekeys
  58 AC_ARG_VAR([CC_FOR_BUILD], [Build native C compiler program])
  59 if test "x$CC_FOR_BUILD" = x; then
  60     if test "$cross_compiling" != no; then
  61         AC_PATH_PROGS([CC_FOR_BUILD], [gcc cc], [cc])
  62     else
  63         CC_FOR_BUILD="$CC"
  64     fi
  65 fi
  66
  67 AC_CHECK_FUNCS([strcasecmp])
  68
  69 if  test "x$GCC" = xyes ; then
  70   CFLAGS="$CFLAGS -fvisibility=hidden"
  71 fi
  72
  73 PKG_CHECK_MODULES([X11], [xproto kbproto >= 1.0.5])
  74
  75 dnl Ensure we have keysym headers
  76 AC_MSG_CHECKING([for X11 includedir])
  77 x11includedir="`$PKG_CONFIG --variable=includedir xproto`/X11"
  78 AC_MSG_RESULT([$x11includedir])
  79
  80 AC_MSG_CHECKING([for keysymdef.h])
  81 KEYSYMDEF_H="$x11includedir/keysymdef.h"
  82 test -f "$KEYSYMDEF_H" || AC_MSG_ERROR([can't locate keysymdef.h in $x11includedir])
  83 AC_MSG_RESULT([$KEYSYMDEF_H])
  84 AC_SUBST([KEYSYMDEF_H])
  85
  86 AC_MSG_CHECKING([for XF86keysym.h])
  87 XF86KEYSYM_H="$x11includedir/XF86keysym.h"
  88 test -f "$XF86KEYSYM_H" || AC_MSG_ERROR([can't locate XF86keysym.h in $x11includedir])
  89 AC_MSG_RESULT([$XF86KEYSYM_H])
  90 AC_SUBST([XF86KEYSYM_H])
  91
  92 AC_SUBST([KS_HEADERS], ['$(KEYSYMDEF_H) $(XF86KEYSYM_H)'])
  93
  94 AC_ARG_WITH([xkb_config_root],
  95     [AS_HELP_STRING([--with-xkb-config-root=<paths>],
  96         [Set default XKB config root (default: ${datadir}/X11/xkb)])],
  97     [XKBCONFIGROOT="$withval"],
  98     [XKBCONFIGROOT='${datadir}/X11/xkb'])
  99 AC_SUBST([XKBCONFIGROOT])
 100
 101 AC_CONFIG_FILES([
 102 Makefile
 103 xkbcommon.pc
 104 include/Makefile
 105 src/Makefile
 106 src/makekeys/Makefile
 107 src/xkbcomp/Makefile
 108 test/Makefile
 109 ])
 110 AC_OUTPUT