configure.ac

   1 #  Copyright 2005 Adam Jackson.
   2 #
   3 #  Permission is hereby granted, free of charge, to any person obtaining a
   4 #  copy of this software and associated documentation files (the "Software"),
   5 #  to deal in the Software without restriction, including without limitation
   6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
   7 #  license, and/or sell copies of the Software, and to permit persons to whom
   8 #  the Software is furnished to do so, subject to the following conditions:
   9 #
  10 #  The above copyright notice and this permission notice (including the next
  11 #  paragraph) shall be included in all copies or substantial portions of the
  12 #  Software.
  13 #
  14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  20
  21 AC_PREREQ([2.63])
  22 AC_INIT([libdrm],
  23         [2.4.42],
  24         [https://bugs.freedesktop.org/enter_bug.cgi?product=DRI],
  25         [libdrm])
  26
  27 AC_CONFIG_HEADERS([config.h])
  28 AC_CONFIG_SRCDIR([Makefile.am])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31
  32 AM_INIT_AUTOMAKE([1.10 foreign dist-bzip2])
  33 AM_MAINTAINER_MODE([enable])
  34
  35 # Enable quiet compiles on automake 1.11.
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 # Check for programs
  39 AC_PROG_CC
  40
  41 AC_USE_SYSTEM_EXTENSIONS
  42 AC_SYS_LARGEFILE
  43 AC_FUNC_ALLOCA
  44
  45 # Initialize libtool
  46 LT_PREREQ([2.2])
  47 LT_INIT([disable-static])
  48
  49
  50 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
  51 AC_SUBST(PTHREADSTUBS_CFLAGS)
  52 AC_SUBST(PTHREADSTUBS_LIBS)
  53
  54 pkgconfigdir=${libdir}/pkgconfig
  55 AC_SUBST(pkgconfigdir)
  56 AC_ARG_ENABLE([udev],
  57               [AS_HELP_STRING([--enable-udev],
  58                               [Enable support for using udev instead of mknod (default: disabled)])],
  59               [UDEV=$enableval], [UDEV=no])
  60
  61 AC_ARG_ENABLE(libkms,
  62               AS_HELP_STRING([--disable-libkms],
  63               [Disable KMS mm abstraction library (default: auto)]),
  64               [LIBKMS=$enableval], [LIBKMS=auto])
  65
  66 AC_ARG_ENABLE(intel,
  67               AS_HELP_STRING([--disable-intel],
  68               [Enable support for intel's KMS API (default: auto)]),
  69               [INTEL=$enableval], [INTEL=auto])
  70
  71 AC_ARG_ENABLE(radeon,
  72               AS_HELP_STRING([--disable-radeon],
  73               [Enable support for radeon's KMS API (default: auto)]),
  74               [RADEON=$enableval], [RADEON=auto])
  75
  76 AC_ARG_ENABLE(nouveau,
  77               AS_HELP_STRING([--disable-nouveau],
  78               [Enable support for nouveau's KMS API (default: auto)]),
  79               [NOUVEAU=$enableval], [NOUVEAU=auto])
  80
  81 AC_ARG_ENABLE(vmwgfx,
  82               AS_HELP_STRING([--disable-vmwgfx],
  83               [Enable support for vmwgfx's KMS API (default: yes)]),
  84               [VMWGFX=$enableval], [VMWGFX=yes])
  85
  86 AC_ARG_ENABLE(omap-experimental-api,
  87               AS_HELP_STRING([--enable-omap-experimental-api],
  88               [Enable support for OMAP's experimental API (default: disabled)]),
  89               [OMAP=$enableval], [OMAP=no])
  90
  91 AC_ARG_ENABLE(exynos-experimental-api,
  92               AS_HELP_STRING([--enable-exynos-experimental-api],
  93               [Enable support for EXYNOS's experimental API (default: disabled)]),
  94               [EXYNOS=$enableval], [EXYNOS=no])
  95
  96 AC_ARG_ENABLE(slp,
  97               AS_HELP_STRING([--disable-slp],
  98               [Enable support for slp's API (default: auto)]),
  99               [SLP=$enableval], [SLP=auto])
 100
 101 AC_ARG_VAR([bufmgr_dir], [Directory of slp-bufmgr])
 102
 103 if test "x$bufmgr_dir" = xyes; then
 104   AC_DEFINE_UNQUOTED(BUFMGR_DIR, "$bufmgr_dir", [Directory for the modules of slp_bufmgr])
 105 else
 106   AC_DEFINE(BUFMGR_DIR, "/usr/lib/bufmgr", [Directory for the modules of slp_bufmgr])
 107 fi
 108
 109 dnl ===========================================================================
 110 dnl check compiler flags
 111 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
 112   AC_MSG_CHECKING([whether $CC supports $1])
 113
 114   libdrm_save_CFLAGS="$CFLAGS"
 115   CFLAGS="$CFLAGS $1"
 116
 117   AC_COMPILE_IFELSE([ ], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
 118   CFLAGS="$libdrm_save_CFLAGS"
 119
 120   if test "x$libdrm_cc_flag" = "xyes"; then
 121     ifelse([$2], , :, [$2])
 122   else
 123     ifelse([$3], , :, [$3])
 124   fi
 125   AC_MSG_RESULT([$libdrm_cc_flag])
 126 ])
 127
 128 dnl We use clock_gettime to check for timeouts in drmWaitVBlank
 129
 130 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 131                [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 132                              [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 133 AC_SUBST([CLOCK_LIB])
 134
 135 AC_CHECK_FUNCS([open_memstream], [HAVE_OPEN_MEMSTREAM=yes])
 136
 137 dnl Use lots of warning flags with with gcc and compatible compilers
 138
 139 dnl Note: if you change the following variable, the cache is automatically
 140 dnl skipped and all flags rechecked.  So there's no need to do anything
 141 dnl else.  If for any reason you need to force a recheck, just change
 142 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
 143
 144 MAYBE_WARN="-Wall -Wextra \
 145 -Wsign-compare -Werror-implicit-function-declaration \
 146 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
 147 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
 148 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
 149 -Wstrict-aliasing=2 -Winit-self \
 150 -Wdeclaration-after-statement -Wold-style-definition \
 151 -Wno-missing-field-initializers -Wno-unused-parameter \
 152 -Wno-attributes -Wno-long-long -Winline"
 153
 154 # invalidate cached value if MAYBE_WARN has changed
 155 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
 156         unset libdrm_cv_warn_cflags
 157 fi
 158 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
 159         echo
 160         WARN_CFLAGS=""
 161
 162         # Some warning options are not supported by all versions of
 163         # gcc, so test all desired options against the current
 164         # compiler.
 165         #
 166         # Note that there are some order dependencies
 167         # here. Specifically, an option that disables a warning will
 168         # have no net effect if a later option then enables that
 169         # warnings, (perhaps implicitly). So we put some grouped
 170         # options (-Wall and -Wextra) up front and the -Wno options
 171         # last.
 172
 173         for W in $MAYBE_WARN; do
 174                 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
 175         done
 176
 177         libdrm_cv_warn_cflags=$WARN_CFLAGS
 178         libdrm_cv_warn_maybe=$MAYBE_WARN
 179
 180         AC_MSG_CHECKING([which warning flags were supported])])
 181 WARN_CFLAGS="$libdrm_cv_warn_cflags"
 182
 183 if test "x$UDEV" = xyes; then
 184         AC_DEFINE(UDEV, 1, [Have UDEV support])
 185 fi
 186
 187 AC_CANONICAL_HOST
 188 if test "x$LIBKMS" = xauto ; then
 189         case $host_os in
 190                 linux*)         LIBKMS="yes" ;;
 191                 *)              LIBKMS="no" ;;
 192         esac
 193 fi
 194
 195 AM_CONDITIONAL(HAVE_LIBKMS, [test "x$LIBKMS" = xyes])
 196
 197 AM_CONDITIONAL(HAVE_VMWGFX, [test "x$VMWGFX" = xyes])
 198 if test "x$VMWGFX" = xyes; then
 199         AC_DEFINE(HAVE_VMWGFX, 1, [Have vmwgfx kernel headers])
 200 fi
 201
 202 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
 203 if test "x$NOUVEAU" = xyes; then
 204         AC_DEFINE(HAVE_NOUVEAU, 1, [Have nouveau (nvidia) support])
 205 fi
 206
 207 AM_CONDITIONAL(HAVE_OMAP, [test "x$OMAP" = xyes])
 208 if test "x$OMAP" = xyes; then
 209         AC_DEFINE(HAVE_OMAP, 1, [Have OMAP support])
 210 fi
 211
 212 AM_CONDITIONAL(HAVE_EXYNOS, [test "x$EXYNOS" = xyes])
 213 if test "x$EXYNOS" = xyes; then
 214         AC_DEFINE(HAVE_EXYNOS, 1, [Have EXYNOS support])
 215 fi
 216
 217 AC_ARG_ENABLE([cairo-tests],
 218               [AS_HELP_STRING([--enable-cairo-tests],
 219                               [Enable support for Cairo rendering in tests (default: auto)])],
 220               [CAIRO=$enableval], [CAIRO=auto])
 221 PKG_CHECK_MODULES(CAIRO, cairo, [HAVE_CAIRO=yes], [HAVE_CAIRO=no])
 222 AC_MSG_CHECKING([whether to enable Cairo tests])
 223 if test "x$CAIRO" = xauto; then
 224         CAIRO="$HAVE_CAIRO"
 225 fi
 226 if test "x$CAIRO" = xyes; then
 227         if ! test "x$HAVE_CAIRO" = xyes; then
 228                 AC_MSG_ERROR([Cairo support required but not present])
 229         fi
 230         AC_DEFINE(HAVE_CAIRO, 1, [Have Cairo support])
 231 fi
 232 AC_MSG_RESULT([$CAIRO])
 233 AM_CONDITIONAL(HAVE_CAIRO, [test "x$CAIRO" = xyes])
 234
 235 # For enumerating devices in test case
 236 PKG_CHECK_MODULES(LIBUDEV, libudev, [HAVE_LIBUDEV=yes], [HAVE_LIBUDEV=no])
 237 if test "x$HAVE_LIBUDEV" = xyes; then
 238         AC_DEFINE(HAVE_LIBUDEV, 1, [Have libudev support])
 239 fi
 240 AM_CONDITIONAL(HAVE_LIBUDEV, [test "x$HAVE_LIBUDEV" = xyes])
 241
 242 # xsltproc for docbook manpages
 243 AC_ARG_ENABLE([manpages],
 244               AS_HELP_STRING([--disable-manpages], [disable manpages @<:@default=enabled@:>@]),
 245               [MANS=$enableval], [MANS=auto])
 246 AC_PATH_PROG(XSLTPROC, xsltproc)
 247 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$XSLTPROC" != "x" -a "x$MANS" != "xno"])
 248
 249 # check for offline man-pages stylesheet
 250 AC_MSG_CHECKING([for docbook manpages stylesheet])
 251 MANPAGES_STYLESHEET="http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl"
 252 AC_PATH_PROGS_FEATURE_CHECK([XSLTPROC_TMP], [xsltproc],
 253                             AS_IF([`"$ac_path_XSLTPROC_TMP" --nonet "$MANPAGES_STYLESHEET" > /dev/null 2>&1`],
 254                                   [HAVE_MANPAGES_STYLESHEET=yes]))
 255 if test "x$HAVE_MANPAGES_STYLESHEET" = "xyes"; then
 256         AC_SUBST(MANPAGES_STYLESHEET)
 257         AC_MSG_RESULT([yes])
 258 else
 259         AC_MSG_RESULT([no])
 260 fi
 261 AM_CONDITIONAL([HAVE_MANPAGES_STYLESHEET], [test "x$HAVE_MANPAGES_STYLESHEET" = "xyes"])
 262
 263 if test "x$INTEL" != "xno" -o "x$RADEON" != "xno" -o "x$NOUVEAU" != "xno" -o "x$OMAP" != "xno" -o "x$SLP" != "xno"; then
 264     # Check for atomic intrinsics
 265     AC_CACHE_CHECK([for native atomic primitives], drm_cv_atomic_primitives,
 266     [
 267             drm_cv_atomic_primitives="none"
 268
 269             AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 270     int atomic_add(int i) { return __sync_fetch_and_add (&i, 1); }
 271     int atomic_cmpxchg(int i, int j, int k) { return __sync_val_compare_and_swap (&i, j, k); }
 272                                             ]],[[]])],
 273                            [drm_cv_atomic_primitives="Intel"],[])
 274
 275             if test "x$drm_cv_atomic_primitives" = "xnone"; then
 276                     AC_CHECK_HEADER([atomic_ops.h], drm_cv_atomic_primitives="libatomic-ops")
 277             fi
 278
 279             # atomic functions defined in <atomic.h> & libc on Solaris
 280             if test "x$drm_cv_atomic_primitives" = "xnone"; then
 281                     AC_CHECK_FUNC([atomic_cas_uint],
 282                                   drm_cv_atomic_primitives="Solaris")
 283             fi
 284
 285     ])
 286     if test "x$drm_cv_atomic_primitives" = xIntel; then
 287             AC_DEFINE(HAVE_LIBDRM_ATOMIC_PRIMITIVES, 1,
 288                       [Enable if your compiler supports the Intel __sync_* atomic primitives])
 289     fi
 290     if test "x$drm_cv_atomic_primitives" = "xlibatomic-ops"; then
 291             AC_DEFINE(HAVE_LIB_ATOMIC_OPS, 1, [Enable if you have libatomic-ops-dev installed])
 292     fi
 293
 294     if test "x$drm_cv_atomic_primitives" = "xnone"; then
 295            if test "x$INTEL" != "xauto"; then
 296                    if test "x$INTEL" != "xno"; then
 297                         AC_MSG_ERROR([libdrm_intel depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Intel GPUs by passing --disable-intel to ./configure])
 298                    fi
 299            else
 300                    AC_MSG_WARN([Disabling libdrm_intel. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
 301                    INTEL=no
 302            fi
 303            if test "x$RADEON" != "xauto"; then
 304                    if test "x$RADEON" != "xno"; then
 305                         AC_MSG_ERROR([libdrm_radeon depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Radeon support by passing --disable-radeon to ./configure])
 306                    fi
 307            else
 308                    AC_MSG_WARN([Disabling libdrm_radeon. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
 309                    RADEON=no
 310            fi
 311            if test "x$NOUVEAU" != "xauto"; then
 312                    if test "x$NOUVEAU" != "xno"; then
 313                         AC_MSG_ERROR([libdrm_nouveau depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for NVIDIA GPUs by passing --disable-nouveau to ./configure])
 314                    fi
 315            else
 316                    AC_MSG_WARN([Disabling libdrm_nouveau. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
 317                    NOUVEAU=no
 318            fi
 319     else
 320            if test "x$INTEL" != "xno"; then
 321                    case $host_cpu in
 322                            i?86|x86_64) INTEL=yes ;;
 323                            *) INTEL=no ;;
 324                    esac
 325            fi
 326            if test "x$RADEON" != "xno"; then
 327                    RADEON=yes
 328            fi
 329            if test "x$NOUVEAU" != "xno"; then
 330                    NOUVEAU=yes
 331            fi
 332     fi
 333 fi
 334
 335 if test "x$SLP" != "xno"; then
 336         AC_DEFINE(HAVE_SLP, 1, [Have slp])
 337 fi
 338
 339 if test "x$INTEL" != "xno"; then
 340         PKG_CHECK_MODULES(PCIACCESS, [pciaccess >= 0.10])
 341 fi
 342 AC_SUBST(PCIACCESS_CFLAGS)
 343 AC_SUBST(PCIACCESS_LIBS)
 344
 345 PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
 346 if test "x$have_valgrind" = "xyes"; then
 347         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
 348 fi
 349
 350 AM_CONDITIONAL(HAVE_SLP, [test "x$SLP" != "xno"])
 351 AM_CONDITIONAL(HAVE_INTEL, [test "x$INTEL" != "xno"])
 352 AM_CONDITIONAL(HAVE_RADEON, [test "x$RADEON" != "xno"])
 353 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" != "xno"])
 354 if test "x$RADEON" = xyes; then
 355         AC_DEFINE(HAVE_RADEON, 1, [Have radeon support])
 356 fi
 357
 358 AC_ARG_WITH([kernel-source],
 359             [AS_HELP_STRING([--with-kernel-source],
 360               [specify path to linux kernel source])],
 361             [kernel_source="$with_kernel_source"])
 362 AC_SUBST(kernel_source)
 363
 364 AC_SUBST(WARN_CFLAGS)
 365 AC_CONFIG_FILES([
 366         Makefile
 367         libkms/Makefile
 368         libkms/libkms.pc
 369         slp/Makefile
 370         slp/libdrm_slp.pc
 371         intel/Makefile
 372         intel/libdrm_intel.pc
 373         radeon/Makefile
 374         radeon/libdrm_radeon.pc
 375         nouveau/Makefile
 376         nouveau/libdrm_nouveau.pc
 377         omap/Makefile
 378         omap/libdrm_omap.pc
 379         exynos/Makefile
 380         exynos/libdrm_exynos.pc
 381         tests/Makefile
 382         tests/modeprint/Makefile
 383         tests/modetest/Makefile
 384         tests/kmstest/Makefile
 385         tests/radeon/Makefile
 386         tests/vbltest/Makefile
 387         include/Makefile
 388         include/drm/Makefile
 389         man/Makefile
 390         libdrm.pc])
 391 AC_OUTPUT
 392
 393 echo ""
 394 echo "$PACKAGE_STRING will be compiled with:"
 395 echo ""
 396 echo "  libkms         $LIBKMS"
 397 echo "  Intel API      $INTEL"
 398 echo "  vmwgfx API     $VMWGFX"
 399 echo "  Radeon API     $RADEON"
 400 echo "  Nouveau API    $NOUVEAU"
 401 echo "  OMAP API       $OMAP"
 402 echo "  EXYNOS API     $EXYNOS"
 403 echo "  SLP API        $SLP"
 404 echo "  SLP bufmgr_dir $bufmgr_dir"
 405 echo ""