configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [6])
   5 m4_define([v_mic], [99])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v '\(export\|Unversioned directory\)' || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 dnl m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-07])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  15 m4_define([lt_cur], m4_eval(v_maj + v_min))
  16 m4_define([lt_rev], v_mic)
  17 m4_define([lt_age], v_min)
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20
  21 AC_INIT([edje], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  22 AC_PREREQ([2.52])
  23 AC_CONFIG_SRCDIR([configure.ac])
  24 AC_CONFIG_MACRO_DIR([m4])
  25
  26 AC_CONFIG_HEADERS([config.h])
  27 AH_TOP([
  28 #ifndef EFL_CONFIG_H__
  29 #define EFL_CONFIG_H__
  30 ])
  31 AH_BOTTOM([
  32 #endif /* EFL_CONFIG_H__ */
  33 ])
  34
  35 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_LIBTOOL_WIN32_DLL
  39 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  40 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  41 AC_PROG_LIBTOOL
  42
  43 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  44 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  45 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  46 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  47 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  48 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  49 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  50 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  51 version_info="lt_cur:lt_rev:lt_age"
  52 release_info="v_rel"
  53 AC_SUBST(version_info)
  54 AC_SUBST(release_info)
  55 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  56 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  57 VMAJ=v_maj
  58 AC_SUBST(VMAJ)
  59
  60 AC_DEFINE_UNQUOTED([SHARED_LIB_SUFFIX], ["$shrext_cmds"], [Suffix for shared objects])
  61
  62 ### Default options with respect to host
  63 AC_CANONICAL_BUILD
  64 AC_CANONICAL_HOST
  65
  66
  67 case "$host_os" in
  68    mingw32ce*)
  69       MODULE_ARCH="$host_os-$host_cpu"
  70       install_vim="no"
  71       have_edje_cc="no"
  72       ;;
  73    *)
  74       MODULE_ARCH="$host_os-$host_cpu-v_maj.0.0"
  75       install_vim="yes"
  76       have_edje_cc="yes"
  77       ;;
  78 esac
  79
  80 requirement_edje=""
  81
  82 AC_SUBST(MODULE_ARCH)
  83 AC_DEFINE_UNQUOTED(MODULE_ARCH, "${MODULE_ARCH}", "Module architecture")
  84
  85 ### Additional options to configure
  86
  87 AC_ARG_ENABLE([amalgamation],
  88    [AC_HELP_STRING([--enable-amalgamation], [enable generation of one single file with all source code in it, helps compiler optimizations.])],
  89    [if test "x${enableval}" = "xyes"; then
  90        do_amalgamation="yes"
  91     else
  92        do_amalgamation="no"
  93     fi
  94    ],
  95    [do_amalgamation="no"]
  96 )
  97 AM_CONDITIONAL([EDJE_AMALGAMATION], [test "x${do_amalgamation}" = "xyes"])
  98
  99 EFL_WITH_BIN([edje], [edje-cc], [edje_cc])
 100
 101 EFL_ENABLE_BIN([edje-cc])
 102 EFL_ENABLE_BIN([edje-decc])
 103 EFL_ENABLE_BIN([edje-recc])
 104 EFL_ENABLE_BIN([edje-player])
 105 EFL_ENABLE_BIN([edje-inspector])
 106 EFL_ENABLE_BIN([edje-external-inspector])
 107 EFL_ENABLE_BIN([edje-watch])
 108
 109 # Optional EDJE_PROGRAM_CACHE (use much more ram, but increase speed in some cases)
 110 want_edje_program_cache="no"
 111
 112 AC_ARG_ENABLE([edje-program-cache],
 113    [AC_HELP_STRING(
 114        [--enable-edje-program-cache],
 115        [enable EDJE_PROGRAM_CACHE support. [[default=disabled]]]
 116     )],
 117    [want_edje_program_cache=$enableval]
 118 )
 119 AM_CONDITIONAL([EDJE_PROGRAM_CACHE], [test "x${want_edje_program_cache}" = "xyes"])
 120
 121 if test "x${want_edje_program_cache}" = "xyes" ; then
 122    AC_DEFINE([EDJE_PROGRAM_CACHE], [1], [Cache result of program glob matches - this uses up extra ram with the gain of faster program matching])
 123 fi
 124
 125 # Optional EDJE_CALC_CACHE (use more ram, but increase speed by reducing the need to recalculate static stuff)
 126 want_edje_calc_cache="yes"
 127
 128 AC_ARG_ENABLE([edje-calc-cache],
 129    [AC_HELP_STRING(
 130        [--enable-edje-calc-cache],
 131        [enable EDJE_CALC_CACHE support. [[default=disabled]]]
 132     )],
 133    [want_edje_calc_cache=$enableval]
 134 )
 135 AM_CONDITIONAL([EDJE_CALC_CACHE], [test "x${want_edje_calc_cache}" = "xyes"])
 136
 137 if test "x${want_edje_calc_cache}" = "xyes" ; then
 138    AC_DEFINE([EDJE_CALC_CACHE], [1], [Cache result of edje_part_recalc - this uses up extra ram with the gain of reducing CPU usage when edje object are not resized])
 139 fi
 140
 141 # Enable Fixed Point use
 142 want_fixed_point="no"
 143
 144 AC_ARG_ENABLE([fixed-point],
 145    [AC_HELP_STRING(
 146        [--enable-fixed-point],
 147        [reduce use of FPU by using Fixed Point provided by Eina and Eet, [[default=disabled]]]
 148     )],
 149     [want_fixed_point=$enableval]
 150 )
 151 AM_CONDITIONAL([BUILD_EDJE_FP], [test "x${want_fixed_point}" = "xyes"])
 152
 153 if test "x${want_fixed_point}" = "xyes" ; then
 154    AC_DEFINE([BUILD_EDJE_FP], [1], [Use Fixed Point instead of FPU])
 155 fi
 156
 157 install_vim="yes"
 158 AC_ARG_WITH([vim],
 159     [AC_HELP_STRING([--with-vim=DIR], [Location of Vim data files [[autodetect]]])],
 160     [
 161      if test -d "${withval}"; then
 162         vimdir="${withval}"
 163      fi
 164     ]
 165 )
 166
 167 if test "x${vimdir}" = "x" ; then
 168    if test -d "${prefix}/share/vim"; then
 169       vimdir="${prefix}/share/vim"
 170    elif test -d "/usr/share/vim"; then
 171       vimdir="/usr/share/vim"
 172    elif test -d "/usr/local/share/vim"; then
 173       vimdir="/usr/local/share/vim"
 174    elif test -d "/opt/share/vim"; then
 175       vimdir="/opt/share/vim"
 176    else
 177       install_vim="no"
 178    fi
 179 fi
 180
 181 AC_MSG_CHECKING([for location of Vim data files])
 182
 183 if test "${install_vim}" = "yes"; then
 184    AC_MSG_RESULT([$vimdir])
 185 else
 186    AC_MSG_RESULT([Not found, EDC syntax file will not be installed])
 187 fi
 188
 189 AC_SUBST(vimdir)
 190
 191 ### Checks for programs
 192 AC_PROG_CC
 193
 194 # doxygen program for documentation building
 195
 196 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 197
 198 # python
 199
 200 AM_PATH_PYTHON([2.5], , [:])
 201 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != : ])
 202
 203 # pkg-config
 204
 205 PKG_PROG_PKG_CONFIG
 206
 207 # Check whether pkg-config supports Requires.private
 208
 209 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 210    pkgconfig_requires_private="Requires.private"
 211 else
 212    pkgconfig_requires_private="Requires"
 213 fi
 214 AC_SUBST(pkgconfig_requires_private)
 215
 216
 217 ### Checks for libraries
 218
 219 # Evil library for compilation on Windows
 220
 221 EFL_EDJE_BUILD=""
 222 case "$host_os" in
 223    mingw*)
 224       PKG_CHECK_MODULES([EVIL], [evil >= 1.6.99])
 225       AC_DEFINE([HAVE_EVIL], [1], [Set to 1 if Evil library is installed])
 226       requirement_edje="evil ${requirement_edje}"
 227       EFL_EDJE_BUILD="-DEFL_EDJE_BUILD"
 228    ;;
 229 esac
 230 AC_SUBST(EFL_EDJE_BUILD)
 231
 232 # Dependencies for the library
 233
 234 # Lua pkg-config hack for different naming conventions
 235 have_lua="yes"
 236 requirement_lua=""
 237 lua_libs=""
 238 PKG_CHECK_MODULES([LUA], [lua >= 5.1.0], requirement_lua="lua",
 239    [PKG_CHECK_MODULES([LUA], [lua5.1 >= 5.1.0], requirement_lua="lua5.1",
 240       [PKG_CHECK_MODULES([LUA], [lua-5.1 >= 5.1.0], requirement_lua="lua-5.1",
 241          [PKG_CHECK_MODULES([LUA], [lua51 >= 5.1.0], requirement_lua="lua51",
 242             [have_lua="no"])])])])
 243
 244 if test "x${have_lua}" = "xno" ; then
 245    AC_MSG_CHECKING([whether lua_newstate() is in liblua])
 246    AC_CHECK_LIB([lua], [lua_newstate],
 247       [
 248        have_lua="yes"
 249        lua_libs="-llua"
 250       ],
 251       [have_lua="no"])
 252    AC_MSG_RESULT([${have_lua}])
 253 fi
 254 AC_SUBST(lua_libs)
 255
 256 if test "x${have_lua}" = "xno" ; then
 257    AC_MSG_ERROR([Cannot find lua library. Be sure that you have installed it and set CFLAGS and LDFLAGS correctly])
 258 fi
 259
 260 PKG_CHECK_MODULES([MINIMAL],
 261    [
 262     eina >= 1.6.99
 263     eet >= 1.6.99
 264    ])
 265
 266 PKG_CHECK_MODULES([EDJE],
 267    [
 268     eina >= 1.6.99
 269     eet >= 1.6.99
 270     evas >= 1.6.99
 271     ecore >= 1.6.99
 272     ecore-evas >= 1.6.99
 273     ecore-file >= 1.6.99
 274     embryo >= 1.6.99
 275    ])
 276
 277 EDJE_LIBS="${EDJE_LIBS} ${LUA_LIBS} ${lua_libs}"
 278 EDJE_CFLAGS="${EDJE_CFLAGS} ${LUA_CFLAGS}"
 279
 280 requirement_edje="embryo >= 1.6.99 ecore-evas >= 1.6.99 ecore >= 1.6.99 evas >= 1.6.99 eet >= 1.6.99 eina >= 1.6.99 ${requirement_edje}"
 281 requirement_edje="${requirement_lua} ${requirement_edje}"
 282
 283 have_ecore_imf="no"
 284 PKG_CHECK_MODULES([ECORE_IMF],
 285    [
 286     ecore-imf >= 1.6.99
 287     ecore-imf-evas >= 1.6.99
 288    ],
 289    [
 290     AC_DEFINE([HAVE_ECORE_IMF], [1], [Input Method Support for Edje Entry])
 291     have_ecore_imf="yes"
 292     requirement_edje="ecore-imf-evas >= 1.6.99 ecore-imf >= 1.6.99 ${requirement_edje}"
 293    ],
 294    [have_ecore_imf="no"])
 295
 296 PKG_CHECK_MODULES([EIO],
 297    [eio >= 1.6.99],
 298    [
 299     AC_DEFINE([HAVE_EIO], [1], [Eio is available for monitoring file assynchronously])
 300     have_eio="yes"
 301     requirement_edje="eio >= 1.6.99 ${requirement_edje}"
 302    ],
 303    [have_eio="no"])
 304
 305 # Enable Multisense use
 306 want_multisense="yes"
 307 AC_ARG_ENABLE([multisense],
 308    [AC_HELP_STRING(
 309        [--disable-multisense],
 310        [multisense provides sound and tone play support, [[default=enabled]]]
 311     )],
 312     [want_multisense=$enableval]
 313 )
 314 AM_CONDITIONAL([ENABLE_MULTISENSE], [test "x${want_multisense}" = "xyes"])
 315
 316 ##sndfile library
 317 have_sndfile="no"
 318 want_sndfile="auto"
 319 AC_ARG_ENABLE([sndfile],
 320    [AC_HELP_STRING([--disable-sndfile], [disable sndfile support. @<:@default=detect@:>@])],
 321    [want_sndfile=$enableval], [])
 322
 323 if test "x${want_multisense}" = "xyes" -a  "x$want_sndfile" != "xno"; then
 324
 325            PKG_CHECK_MODULES([SNDFILE],
 326               [sndfile >= 1.0.21],
 327               [
 328                AC_DEFINE(HAVE_LIBSNDFILE, 1, [sndfile support for Edje])
 329                have_sndfile="yes"
 330                requirement_edje="sndfile >= 1.0.21 ${requirement_edje}"
 331                ],
 332               [have_sndfile="no"; want_multisense="no"]
 333            )
 334
 335         if test "x$want_sndfile" = "xyes" -a "x$have_sndfile" = "xno"; then
 336             AC_MSG_ERROR([sndfile support requested, but not found by pkg-config.])
 337         fi
 338 fi
 339 AM_CONDITIONAL([HAVE_LIBSNDFILE], [test "x${have_sndfile}" = "xyes"])
 340
 341 ##libremix library
 342 have_libremix="no"
 343 want_libremix="auto"
 344 AC_ARG_ENABLE([remix],
 345    [AC_HELP_STRING([--disable-remix], [disable remix support. @<:@default=detect@:>@])],
 346    [want_libremix=$enableval], [])
 347
 348 if test "x${want_multisense}" = "xyes" -a "x$want_libremix" != "xno"; then
 349    PKG_CHECK_MODULES([REMIX],
 350       [remix >= 0.2.4],
 351       [
 352        AC_DEFINE(HAVE_LIBREMIX, 1, [remix support for Edje])
 353        have_libremix="yes"
 354        requirement_edje="remix >= 0.2.4 ${requirement_edje}"
 355        AC_DEFINE(__REMIX_PLUGIN__, 1, "Set to REMIX Plugin type")
 356        REMIX_PLUGIN_DIR=`pkg-config --variable=libdir remix`"/remix"
 357        AC_SUBST(REMIX_PLUGIN_DIR)
 358        AC_DEFINE_UNQUOTED(REMIX_PLUGIN_DIR, "$REMIX_PLUGIN_DIR", [Set the remix plugin directory])
 359        ],
 360       [have_libremix="no"; want_multisense="no"]
 361    )
 362
 363         if test "x$want_libremix" = "xyes" -a "x$have_libremix" = "xno"; then
 364             AC_MSG_ERROR([remix support requested, but not found by pkg-config.])
 365         fi
 366 fi
 367 AM_CONDITIONAL([HAVE_LIBREMIX], [test "x${have_libremix}" = "xyes"])
 368
 369 ##vorbis/ogg library
 370 have_vorbis="no"
 371 want_vorbis="auto"
 372 AC_ARG_ENABLE([vorbisenc],
 373    [AC_HELP_STRING([--disable-vorbis], [disable ogg-vorbis support. @<:@default=detect@:>@])],
 374    [want_vorbis=$enableval], [])
 375
 376 if test "x${want_multisense}" = "xyes" -a "x$want_vorbis" != "xno"; then
 377    PKG_CHECK_MODULES([VORBISENC],
 378       [
 379        ogg >= 1.1.4
 380        vorbis >= 1.2.3
 381        vorbisenc >= 1.2.3
 382       ],
 383       [
 384        AC_DEFINE(HAVE_VORBIS, 1, [vorbis support for Edje])
 385        have_vorbis="yes"
 386        requirement_edje="ogg >= 1.1.4 vorbis >= 1.2.3 vorbisenc >= 1.2.3 ${requirement_edje}"
 387       ],
 388       [have_vorbis="no"]
 389    )
 390
 391         if test "x$want_vorbis" = "xyes" -a "x$have_vorbis" = "xno"; then
 392             AC_MSG_ERROR([vorbisenc support requested, but not found by pkg-config.])
 393         fi
 394 fi
 395
 396 ##alsa library
 397 have_alsa_lib="no"
 398 want_alsa_lib="auto"
 399 AC_ARG_ENABLE([alsa],
 400    [AC_HELP_STRING([--disable-alsa], [disable alsa support. @<:@default=detect@:>@])],
 401    [want_alsa_lib=$enableval], [])
 402
 403 if test "x${want_multisense}" = "xyes" -a "x$want_alsa_lib" != "xno"; then
 404    PKG_CHECK_MODULES([ALSA],
 405       [
 406        alsa >= 1.0.21
 407       ],
 408       [
 409        AC_DEFINE(HAVE_LIBALSA, 1, [ALSA support for Edje])
 410        have_alsa_lib="yes"
 411        requirement_edje="alsa >= 1.0.21 ${requirement_edje}"
 412       ],
 413       [have_alsa_lib="no"]
 414    )
 415
 416         if test "x$want_alsa_lib" = "xyes" -a "x$have_alsa_lib" = "xno"; then
 417             AC_MSG_ERROR([alsa support requested, but not found by pkg-config.])
 418         fi
 419 fi
 420 AM_CONDITIONAL([HAVE_LIBALSA], [test "x${have_alsa_lib}" = "xyes"])
 421
 422 ##pulse audio library
 423 have_pa_lib="no"
 424 want_pa_lib="auto"
 425 AC_ARG_ENABLE([pulseaudio],
 426    [AC_HELP_STRING([--disable-pa], [disable pulse audio support. @<:@default=detect@:>@])],
 427    [want_pa_lib=$enableval], [])
 428
 429 if test "x${want_multisense}" = "xyes" -a "x$want_pa_lib" != "xno"; then
 430    PKG_CHECK_MODULES([PA],
 431       [
 432        libpulse >= 0.9.21
 433        libpulse-simple >= 0.9.21
 434       ],
 435       [
 436        AC_DEFINE(HAVE_LIBPA, 1, [Pulse Audio support for Edje])
 437        have_pa_lib="yes"
 438        requirement_edje="libpulse >= 0.9.21 ${requirement_edje}"
 439       ],
 440       [have_pa_lib="no"]
 441    )
 442
 443         if test "x$want_pa_lib" = "xyes" -a "x$have_pa_lib" = "xno"; then
 444             AC_MSG_ERROR([pulse audio support requested, but not found by pkg-config.])
 445         fi
 446 fi
 447 AM_CONDITIONAL([HAVE_LIBPA], [test "x${have_pa_lib}" = "xyes"])
 448
 449
 450 ##flac library
 451 have_flac_lib="no"
 452 want_flac_lib="auto"
 453 AC_ARG_ENABLE([flac],
 454    [AC_HELP_STRING([--disable-flac], [disable flac support. @<:@default=detect@:>@])],
 455    [want_flac_lib=$enableval], [])
 456
 457 if test "x${want_multisense}" = "xyes" -a "x$want_flac_lib" != "xno"; then
 458    PKG_CHECK_MODULES([FLAC],
 459       [
 460        flac >= 1.2.1
 461       ],
 462       [
 463        AC_DEFINE(HAVE_LIBFLAC, 1, [flac support for Edje])
 464        have_flac_lib="yes"
 465        # disabled because this adds flac include dirs to cflags... and
 466        # FLAC has an assert.h in its include dirs that ends up
 467        # overriding the system assert.h and thus causes all sorts of
 468        # mayhem
 469        #requirement_edje="flac >= 1.2.1 ${requirement_edje}"
 470       ],
 471       [have_flac_lib="no"]
 472    )
 473         if test "x$want_flac_lib" = "xyes" -a "x$have_flac_lib" = "xno"; then
 474             AC_MSG_ERROR([flac support requested, but not found by pkg-config.])
 475         fi
 476 fi
 477
 478 if test "x${want_multisense}" = "xyes" ; then
 479    AC_DEFINE([ENABLE_MULTISENSE], [1], [Use Multisense])
 480 fi
 481 AC_SUBST([want_multisense])
 482
 483 # Dependencies for the binaries
 484
 485 if test "x${have_edje_cc}" = "xyes" ; then
 486    PKG_CHECK_MODULES([EDJE_CC],
 487       [ecore-file >= 1.6.99 ecore-evas >= 1.6.99 ecore >= 1.6.99 evas >= 1.6.99 eet >= 1.6.0 eina >= 1.6.99])
 488    EDJE_CC_LIBS="${EDJE_CC_LIBS} ${LUA_LIBS} ${lua_libs}"
 489 fi
 490
 491 AM_CONDITIONAL([BUILD_EPP], [test "x${have_edje_cc}" = "xyes"])
 492
 493 if test "x${have_edje_decc}" = "xyes" ; then
 494    PKG_CHECK_MODULES([EDJE_DECC],
 495       [ecore-file >= 1.6.99 ecore-evas >= 1.6.99 ecore >= 1.6.99 evas >= 1.6.99 eet >= 1.6.99 eina >= 1.6.99])
 496 fi
 497
 498 if test "x${have_edje_player}" = "xyes" ; then
 499    PKG_CHECK_MODULES([EDJE_PLAYER],
 500       [ecore-evas >= 1.6.99 ecore >= 1.6.99 evas >= 1.6.99 eina >= 1.6.99])
 501 fi
 502
 503 if test "x${have_edje_inspector}" = "xyes" ; then
 504    PKG_CHECK_MODULES([EDJE_INSPECTOR],
 505       [ecore-evas >= 1.6.99 ecore >= 1.6.99 evas >= 1.6.99 eina >= 1.6.99])
 506 fi
 507
 508 if test "x${have_edje_external_inspector}" = "xyes" ; then
 509    PKG_CHECK_MODULES([EDJE_EXTERNAL_INSPECTOR],
 510       [ecore >= 1.6.99 evas >= 1.6.99 eina >= 1.6.99])
 511 fi
 512
 513 if test "x${have_edje_watch}" = "xyes" ; then
 514    PKG_CHECK_MODULES([EDJE_WATCH],
 515       [ecore >= 1.6.99 eina >= 1.6.99 eio >= 1.6.99],
 516       [have_edje_watch="yes"],
 517       [have_edje_watch="no"])
 518 fi
 519
 520 AM_CONDITIONAL([BUILD_EDJE_WATCH], [test "x${have_edje_watch}" = "xyes"])
 521
 522 ### Checks for header files
 523 AC_CHECK_HEADERS([locale.h sys/resource.h])
 524
 525 EFL_CHECK_PATH_MAX
 526
 527
 528 ### Checks for types
 529
 530
 531 ### Checks for structures
 532
 533
 534 ### Checks for compiler characteristics
 535 AM_PROG_CC_C_O
 536 AC_C_CONST
 537 AC_PROG_CC_STDC
 538 AC_HEADER_STDC
 539 AC_C___ATTRIBUTE__
 540
 541 case "$host_os" in
 542    mingw32ce*)
 543       EDJE_CFLAGS="${EDJE_CFLAGS} -D_WIN32_WCE=0x0420"
 544       ;;
 545 esac
 546
 547
 548 ### Checks for linker characteristics
 549
 550 lt_enable_auto_import=""
 551 case "$host_os" in
 552    mingw*)
 553       lt_enable_auto_import="-Wl,--enable-auto-import"
 554       ;;
 555 esac
 556 AC_SUBST(lt_enable_auto_import)
 557
 558
 559 ### Checks for library functions
 560
 561 AC_ISC_POSIX
 562
 563 AC_FUNC_ALLOCA
 564
 565 case "$host_os" in
 566    mingw*)
 567       AC_DEFINE([HAVE_REALPATH], [1], [Define to 1 if you have the `realpath' function.])
 568       ;;
 569    *)
 570       AC_CHECK_FUNCS([realpath])
 571       ;;
 572 esac
 573
 574 ### Unit tests, coverage and benchmarking
 575
 576 EFL_CHECK_TESTS([enable_tests="yes"], [enable_tests="no"])
 577
 578 EFL_CHECK_COVERAGE([${enable_tests}], [enable_coverage="yes"], [enable_coverage="no"])
 579 EDJE_CFLAGS="${EDJE_CFLAGS} ${EFL_COVERAGE_CFLAGS}"
 580 EDJE_LIBS="${EDJE_LIBS} ${EFL_COVERAGE_LIBS}"
 581 if test "x$enable_coverage" = "xyes" ; then
 582    EDJE_CFLAGS="${EDJE_CFLAGS} ${EFL_DEBUG_CFLAGS}"
 583 fi
 584
 585 ## Examples
 586
 587 build_examples="no"
 588 AC_ARG_ENABLE([build-examples],
 589    AC_HELP_STRING([--enable-build-examples],
 590                   [Enable building examples. This requires extra denpendencies. If you don't have them installed yet, don't build with this option or it will fail. Build again when you have it, overriding the previous installation). @<:@default==disabled@:>@]),
 591    [
 592     if test "x${enableval}" = "xyes" ; then
 593        build_examples="yes"
 594     else
 595        build_examples="no"
 596     fi
 597    ],
 598    [build_examples="no"])
 599 AM_CONDITIONAL([BUILD_EXAMPLES], [test "x${build_examples}" = "xyes"])
 600
 601 AC_SUBST(requirement_edje)
 602
 603 AC_OUTPUT([
 604 edje.pc
 605 edje.spec
 606 Makefile
 607 data/Makefile
 608 data/include/Makefile
 609 doc/Makefile
 610 doc/Doxyfile
 611 src/Makefile
 612 src/lib/Makefile
 613 src/bin/Makefile
 614 src/bin/epp/Makefile
 615 src/modules/Makefile
 616 src/modules/alsa_snd_player/Makefile
 617 src/modules/pa_snd_player/Makefile
 618 src/modules/eet_snd_reader/Makefile
 619 src/modules/multisense_factory/Makefile
 620 src/tests/Makefile
 621 utils/Makefile
 622 src/examples/Makefile
 623 ])
 624
 625
 626 #####################################################################
 627 ## Info
 628
 629 echo
 630 echo
 631 echo
 632 echo "------------------------------------------------------------------------"
 633 echo "$PACKAGE $VERSION"
 634 echo "------------------------------------------------------------------------"
 635 echo
 636 echo "Configuration Options Summary:"
 637 echo
 638 echo "  Amalgamation.........: ${do_amalgamation}"
 639 echo "  Ecore IMF............: $have_ecore_imf"
 640 dnl echo "  Multisense...........: $want_multisense"
 641
 642 if test "x${want_multisense}" = "xyes" ; then
 643 echo "  LibRemix.............: $have_libremix"
 644 echo "  Libsndfile...........: $have_sndfile"
 645 echo "  Ogg/Vorbis...........: $have_vorbis"
 646 echo "  LibFLAC..............: $have_flac_lib"
 647 echo "  LibALSA..............: $have_alsa_lib"
 648 echo "  LibPA................: $have_pa_lib"
 649 fi
 650
 651 echo "  EDJE_PROGRAM_CACHE...: $want_edje_program_cache"
 652 echo "  EDJE_CALC_CACHE......: $want_edje_calc_cache"
 653 echo "  Fixed point..........: $want_fixed_point"
 654 echo "  Documentation........: ${build_doc}"
 655 echo "  Tests................: ${enable_tests}"
 656 echo "  Coverage.............: ${enable_coverage}"
 657 echo "  Examples.............: install:${install_examples} build:${build_examples}"
 658 echo
 659 echo "Programs:"
 660 echo
 661 echo "  Build edje_cc................: $have_edje_cc"
 662 echo "  Build edje_decc..............: $have_edje_decc"
 663 echo "  Build edje_recc..............: $have_edje_recc"
 664 echo "  Build edje_player............: $have_edje_player"
 665 echo "  Build edje_inspector.........: $have_edje_inspector"
 666 echo "  Build edje_external_inspector: $have_edje_external_inspector"
 667 echo "  Build edje_watch.............: $have_edje_watch"
 668 echo
 669 echo "Compilation............: make (or gmake)"
 670 echo "  CPPFLAGS.............: $CPPFLAGS"
 671 echo "  CFLAGS...............: $CFLAGS"
 672 echo "  LDFLAGS..............: $LDFLAGS"
 673 echo
 674 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 675 echo "  prefix...............: $prefix"
 676 echo