configure.ac

   1 dnl  Copyright © 2008 Dan Nicholson
   2 dnl
   3 dnl  Permission to use, copy, modify, distribute, and sell this software and its
   4 dnl  documentation for any purpose is hereby granted without fee, provided that
   5 dnl  the above copyright notice appear in all copies and that both that
   6 dnl  copyright notice and this permission notice appear in supporting
   7 dnl  documentation, and that the name of Keith Packard not be used in
   8 dnl  advertising or publicity pertaining to distribution of the software without
   9 dnl  specific, written prior permission.  Keith Packard makes no
  10 dnl  representations about the suitability of this software for any purpose.  It
  11 dnl  is provided "as is" without express or implied warranty.
  12 dnl
  13 dnl  DAN NICHOLSON DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  14 dnl  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  15 dnl  EVENT SHALL KEITH PACKARD BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  16 dnl  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  17 dnl  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  18 dnl  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  19 dnl  PERFORMANCE OF THIS SOFTWARE.
  20 dnl
  21 dnl Process this file with autoconf to create configure.
  22
  23 # Initialize Autoconf
  24 AC_PREREQ([2.62])
  25 AC_INIT([libxkbcommon], [0.3.1],
  26         [https://bugs.freedesktop.org/enter_bug.cgi?product=libxkbcommon],
  27         [libxkbcommon], [http://xkbcommon.org])
  28 AC_CONFIG_SRCDIR([Makefile.am])
  29 AC_CONFIG_HEADERS([src/config.h])
  30 AC_CONFIG_MACRO_DIR([m4])
  31
  32 # Initialize Automake
  33 AM_INIT_AUTOMAKE([foreign dist-xz no-dist-gzip subdir-objects color-tests parallel-tests])
  34 AM_MAINTAINER_MODE([enable])
  35
  36 # Get _GNU_SOURCE and friends
  37 AC_USE_SYSTEM_EXTENSIONS
  38
  39 # Initialize libtool
  40 LT_INIT
  41
  42 # Add xorg-macros stuff
  43 m4_ifndef([XORG_MACROS_VERSION],
  44           [m4_fatal([must install xorg-macros 1.16 or later before running autoconf/autogen])])
  45 XORG_MACROS_VERSION(1.16)
  46 XORG_DEFAULT_OPTIONS
  47 XORG_MEMORY_CHECK_FLAGS
  48 XORG_ENABLE_DOCS
  49 XORG_WITH_DOXYGEN
  50
  51 # Check for compiler features
  52 AC_C_INLINE
  53
  54 # Check for programs
  55 AC_PROG_MKDIR_P
  56 PKG_PROG_PKG_CONFIG
  57
  58 AC_PROG_YACC
  59 AC_PATH_PROG([YACC_INST], $YACC)
  60 if test ! -f "src/xkbcomp/parser.c"; then
  61    if test -z "$YACC_INST"; then
  62       AC_MSG_ERROR([yacc not found - unable to compile src/xkbcomp/parser.y])
  63    fi
  64 fi
  65
  66 # Checks for library functions.
  67 AC_CHECK_FUNCS([strcasecmp strncasecmp])
  68 if test "x$ac_cv_func_strcasecmp" = xno || \
  69    test "x$ac_cv_func_strncasecmp" = xno; then
  70     AC_MSG_ERROR([C library does not support strcasecmp/strncasecmp])
  71 fi
  72
  73 AC_CHECK_FUNCS([eaccess euidaccess mmap])
  74
  75 # Some tests use Linux-specific headers
  76 AC_CHECK_HEADER([linux/input.h])
  77 AM_CONDITIONAL(BUILD_LINUX_TESTS, [test "x$ac_cv_header_linux_input_h" = xyes])
  78
  79 XORG_TESTSET_CFLAG([BASE_CFLAGS], [-fvisibility=hidden])
  80
  81 # Define a configuration option for the XKB config root
  82 xkb_base=`$PKG_CONFIG --variable=xkb_base xkeyboard-config`
  83 if test "x$xkb_base" = x; then
  84     xkb_base=$datadir/X11/xkb
  85 fi
  86 AC_ARG_WITH([xkb_config_root],
  87     [AS_HELP_STRING([--with-xkb-config-root=<path>],
  88         [Set default XKB config root (default: xkeyboard-config install path)])],
  89     [XKBCONFIGROOT="$withval"],
  90     [XKBCONFIGROOT="$xkb_base"])
  91 AC_SUBST([XKBCONFIGROOT])
  92
  93 AC_ARG_WITH([default_rules],
  94     [AS_HELP_STRING([--with-default-rules=<path>],
  95         [Default XKB ruleset (default: evdev)])],
  96     [DEFAULT_XKB_RULES="$withval"],
  97     [DEFAULT_XKB_RULES="evdev"])
  98 AC_DEFINE_UNQUOTED([DEFAULT_XKB_RULES], ["$DEFAULT_XKB_RULES"],
  99                    [Default XKB ruleset])
 100
 101 AC_ARG_WITH([default_model],
 102     [AS_HELP_STRING([--with-default-model=<path>],
 103         [Default XKB model (default: pc105)])],
 104     [DEFAULT_XKB_MODEL="$withval"],
 105     [DEFAULT_XKB_MODEL="pc105"])
 106 AC_DEFINE_UNQUOTED([DEFAULT_XKB_MODEL], ["$DEFAULT_XKB_MODEL"],
 107                    [Default XKB model])
 108
 109 AC_ARG_WITH([default_layout],
 110     [AS_HELP_STRING([--with-default-layout=<path>],
 111         [Default XKB layout (default: us)])],
 112     [DEFAULT_XKB_LAYOUT="$withval"],
 113     [DEFAULT_XKB_LAYOUT="us"])
 114 AC_DEFINE_UNQUOTED([DEFAULT_XKB_LAYOUT], ["$DEFAULT_XKB_LAYOUT"],
 115                    [Default XKB layout])
 116
 117 AC_ARG_WITH([default_variant],
 118     [AS_HELP_STRING([--with-default-variant=<path>],
 119         [Default XKB variant (default: (none))])],
 120     [DEFAULT_XKB_VARIANT="$withval"],
 121     [DEFAULT_XKB_VARAINT=])
 122 if ! test "x$DEFAULT_XKB_VARIANT" = x; then
 123     AC_DEFINE_UNQUOTED([DEFAULT_XKB_VARIANT], ["$DEFAULT_XKB_VARIANT"],
 124                        [Default XKB variant])
 125 fi
 126
 127 AC_ARG_WITH([default_options],
 128     [AS_HELP_STRING([--with-default-options=<path>],
 129         [Default XKB options (default: (none))])],
 130     [DEFAULT_XKB_OPTIONS="$withval"],
 131     [DEFAULT_XKB_OPTIONS=])
 132 if ! test "x$DEFAULT_XKB_OPTIONS" = x; then
 133     AC_DEFINE_UNQUOTED([DEFAULT_XKB_OPTIONS], ["$DEFAULT_XKB_OPTIONS"],
 134                        [Default XKB options])
 135 fi
 136
 137 AC_CONFIG_FILES([
 138     Makefile
 139     xkbcommon-uninstalled.pc
 140     xkbcommon.pc
 141     doc/Doxyfile
 142 ])
 143 AC_OUTPUT