configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 dnl the gi version number
   5 m4_define(gi_major_version, 0)
   6 m4_define(gi_minor_version, 9)
   7 m4_define(gi_micro_version, 10)
   8 m4_define(gi_version, gi_major_version.gi_minor_version.gi_micro_version)
   9
  10 AC_PREREQ(2.59)
  11 AC_INIT(gobject-introspection, gi_version,
  12         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib&component=introspection])
  13 AM_INIT_AUTOMAKE([1.7 dist-bzip2 no-dist-gzip foreign -Wno-portability])
  14 AM_MAINTAINER_MODE
  15
  16 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],)
  17
  18 AC_CONFIG_HEADER([config.h])
  19
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 # Check for Win32
  23 AC_CANONICAL_HOST
  24 AC_MSG_CHECKING([for Win32])
  25 case "$host" in
  26 *-*-mingw*)
  27         os_win32=yes
  28         ;;
  29 *)
  30         os_win32=no
  31         ;;
  32 esac
  33 AC_MSG_RESULT([$os_win32])
  34 AM_CONDITIONAL(OS_WIN32, [test "$os_win32" = "yes"])
  35
  36 # Checks for programs.
  37 AC_PROG_CC
  38 AM_PROG_CC_C_O
  39 AC_PROG_LIBTOOL
  40 PKG_PROG_PKG_CONFIG
  41
  42 AC_PROG_LEX
  43 if test "$LEX" = :; then
  44         AC_MSG_ERROR([flex not found but required])
  45 fi
  46
  47 AC_CHECK_PROGS(YACC, 'bison -y', :)
  48 if test "$YACC" = :; then
  49         AC_MSG_ERROR([bison not found but required])
  50 fi
  51
  52
  53 changequote(,)dnl
  54 ensureflag() {
  55   flag="$1"; shift
  56   result="$@"
  57
  58   case " ${result} " in
  59   *[\ \ ]${flag}[\ \    ]*) ;;
  60   *) result="${flag} ${result}" ;;
  61   esac
  62
  63   echo ${result}
  64 }
  65 changequote([,])dnl
  66
  67 if test "$GCC" = "yes"; then
  68     for flag in -Wall -Wchar-subscripts -Wmissing-declarations \
  69         -Wmissing-prototypes -Wnested-externs -Wpointer-arith -Wcast-align \
  70         -Wsign-compare -fno-strict-aliasing;
  71     do
  72         CFLAGS="$(ensureflag $flag $CFLAGS)"
  73     done
  74 fi
  75
  76 # Checks for libraries.
  77 AC_CHECK_LIB([dl], [dlopen])
  78
  79 AC_MSG_CHECKING(for the suffix of shared libraries)
  80 # libtool variables are immediately available since 2.0, prior to that we need
  81 # to call libtool --config explicitly
  82 if test "x$shrext_cmds" = x; then
  83     shrext_cmds=`SED=$SED ./libtool --config | grep '^shrext_cmds='`
  84     eval $shrext_cmds
  85 fi
  86 eval std_shrext=$shrext_cmds
  87 # chop the initial dot
  88 SHLIB_SUFFIX=${std_shrext#.}
  89 AC_MSG_RESULT(.$SHLIB_SUFFIX)
  90 # any reason it may fail?
  91 if test "x$SHLIB_SUFFIX" = x; then
  92         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
  93 fi
  94 AC_DEFINE_UNQUOTED([SHLIB_SUFFIX], "$SHLIB_SUFFIX", [Define to the platform's shared library suffix])
  95
  96 # Copied from dbus configure.in
  97 #### find the actual value for $prefix that we'll end up with
  98 ##   (I know this is broken and should be done in the Makefile, but
  99 ##    that's a major pain and almost nobody actually seems to care)
 100 AS_AC_EXPAND(EXPANDED_LOCALSTATEDIR, "$localstatedir")
 101 AS_AC_EXPAND(EXPANDED_SYSCONFDIR, "$sysconfdir")
 102 AS_AC_EXPAND(EXPANDED_BINDIR, "$bindir")
 103 AS_AC_EXPAND(EXPANDED_LIBDIR, "$libdir")
 104 AS_AC_EXPAND(EXPANDED_LIBEXECDIR, "$libexecdir")
 105 AS_AC_EXPAND(EXPANDED_DATADIR, "$datadir")
 106
 107 #### Directory to install the libexec binaries
 108 GOBJECT_INTROSPECTION_LIBDIR="$EXPANDED_LIBDIR"
 109 AC_SUBST(GOBJECT_INTROSPECTION_LIBDIR)
 110 AC_DEFINE_UNQUOTED(GOBJECT_INTROSPECTION_LIBDIR,"$GOBJECT_INTROSPECTION_LIBDIR", [Directory prefix for typelib installation])
 111
 112 #### Directory to install the gir files
 113 GIR_SUFFIX="gir-1.0"
 114 AC_SUBST(GIR_SUFFIX)
 115 AC_DEFINE_UNQUOTED(GIR_SUFFIX, "$GIR_SUFFIX", [Name of the gir directory])
 116
 117 GIR_DIR="$EXPANDED_DATADIR/$GIR_SUFFIX"
 118 AC_SUBST(GIR_DIR)
 119 AC_DEFINE_UNQUOTED(GIR_DIR, "$GIR_DIR", [Director prefix for gir installation])
 120
 121 PKG_CHECK_MODULES(GOBJECT, [gobject-2.0 gio-2.0])
 122 PKG_CHECK_MODULES(GTHREAD, [gthread-2.0])
 123 PKG_CHECK_MODULES(GIO_UNIX, [gio-unix-2.0], have_gio_unix=true, have_gio_unix=false)
 124 AM_CONDITIONAL(HAVE_GIO_UNIX, test x$have_gio_unix = xtrue)
 125
 126 AC_ARG_ENABLE(tests,[  --disable-tests           disable test libraries ], enable_tests=$enableval,enable_tests=yes)
 127 have_cairo=no
 128 if test x$enable_tests != xno; then
 129   PKG_CHECK_MODULES(CAIRO, [cairo], have_cairo=yes, have_cairo=no)
 130   if test x$have_cairo != xyes; then
 131     AC_MSG_ERROR([Tests enabled but cairo not found; pass --disable-tests or install cairo])
 132   fi
 133 fi
 134 AM_CONDITIONAL(BUILD_TESTS, test x$enable_tests != xno)
 135 AM_CONDITIONAL(HAVE_CAIRO, test x$have_cairo != xno)
 136
 137 PKG_CHECK_MODULES(SCANNER, [gobject-2.0 gthread-2.0 gio-2.0])
 138
 139 dnl libffi
 140 PKG_CHECK_MODULES(FFI, libffi, have_ffi_pkgconfig=yes, have_ffi_pkgconfig=no)
 141 FFI_PC_CFLAGS=""
 142 FFI_PC_LIBS=""
 143 FFI_PC_PACKAGES=""
 144 if test x"$have_ffi_pkgconfig" = xyes ; then
 145     FFI_PC_PACKAGES="libffi"
 146 else
 147   AC_MSG_CHECKING(for ffi.h)
 148
 149   AC_TRY_CPP([#include <ffi.h>], have_ffi_h=yes, have_ffi_h=no)
 150   if test x"$have_ffi_h" = x"yes"; then
 151
 152     save_LIBS=$LIBS
 153     if test x"$with_ffi" = x"yes" || test x"$with_ffi" = x"auto"; then
 154       other_LIBS=
 155     else
 156       other_LIBS=$with_ffi
 157     fi
 158
 159     AC_SEARCH_LIBS(ffi_call,ffi,,AC_MSG_ERROR([libffi not found]),$other_LIBS)
 160     if test x"$ac_cv_search_ffi_call" = x"none required" ; then
 161       FFI_LIBS=$other_LIBS
 162     else
 163       FFI_LIBS="$ac_cv_search_ffi_call $other_LIBS"
 164     fi
 165
 166     LIBS=$save_LIBS
 167   fi
 168   if test x"$have_ffi_h" != x"yes" ; then
 169     AC_MSG_ERROR([ffi.h not found])
 170   fi
 171
 172   FFI_PC_LIBS=$FFI_LIBS
 173   FFI_PC_CFLAGS=$FFI_CFLAGS
 174   FFI_CFLAGS=
 175   AC_MSG_RESULT([$have_ffi_h])
 176   AC_SUBST(FFI_LIBS)
 177   AC_SUBST(FFI_CFLAGS)
 178 fi
 179 AC_SUBST(FFI_PC_CFLAGS)
 180 AC_SUBST(FFI_PC_LIBS)
 181 AC_SUBST(FFI_PC_PACKAGES)
 182
 183 AC_CHECK_SIZEOF(char)
 184 AC_CHECK_SIZEOF(short)
 185 AC_CHECK_SIZEOF(int)
 186 AC_CHECK_SIZEOF(long)
 187
 188 PKG_CHECK_MODULES(GIREPO, [glib-2.0 >= 2.24.0 gobject-2.0 gmodule-2.0 gio-2.0])
 189
 190 # if we ever remove manual check for ffi and require .pc file, then
 191 # just put libffi in the PKG_CHECK_MODULES(GIREPO) deps
 192 GIREPO_LIBS="$GIREPO_LIBS $GCOV_LIBS $FFI_LIBS"
 193 GIREPO_CFLAGS="$GIREPO_CFLAGS $FFI_CFLAGS"
 194
 195 GIREPO_CFLAGS="$GIREPO_CFLAGS $GCOV_CFLAGS"
 196
 197 # gtk-doc
 198 GTK_DOC_CHECK([1.12])
 199
 200 # Checks for header files.
 201 AC_HEADER_STDC
 202 AC_CHECK_HEADERS([fcntl.h stdlib.h string.h])
 203
 204 # Checks for typedefs, structures, and compiler characteristics.
 205 AC_C_CONST
 206
 207 # Checks for library functions.
 208 AC_FUNC_STRTOD
 209 AC_CHECK_FUNCS([memchr strchr strspn strstr strtol strtoull])
 210 AC_CHECK_FUNCS([backtrace backtrace_symbols])
 211
 212 # Python
 213
 214 AC_MSG_CHECKING([whether Python support is requested])
 215
 216 AM_PATH_PYTHON([2.5])
 217 case "$host" in
 218 *-*-mingw*)
 219         # Change backslashes to forward slashes in pyexecdir to avoid
 220         # quoting issues
 221         pyexecdir=`echo $pyexecdir | tr '\\\\' '/'`
 222         ;;
 223 esac
 224 AM_CHECK_PYTHON_HEADERS(,AC_MSG_ERROR([Python headers not found]))
 225
 226 # Glib documentation
 227
 228 GLIBSRC=
 229 AC_MSG_CHECKING([for glib source directory to use for documentation])
 230
 231 AC_ARG_WITH(glib-src,
 232         [  --with-glib-src=PATH    Source directory for glib - needed to add docs to gir],
 233         GLIBSRC=$withval
 234 )
 235 AM_CONDITIONAL(WITH_GLIBSRC, test x"$GLIBSRC" != x)
 236 AC_SUBST(GLIBSRC)
 237 AC_MSG_RESULT([$GLIBSRC])
 238
 239
 240
 241 AC_CONFIG_FILES([
 242 Makefile
 243 gir/Makefile
 244 girepository/Makefile
 245 giscanner/Makefile
 246 giscanner/config.py
 247 m4/Makefile
 248 tools/Makefile
 249 tests/Makefile
 250 tests/offsets/Makefile
 251 tests/scanner/Makefile
 252 tests/repository/Makefile
 253 tests/warn/Makefile
 254 examples/Makefile
 255 docs/Makefile
 256 docs/reference/Makefile
 257 gobject-introspection-1.0.pc
 258 gobject-introspection-no-export-1.0.pc])
 259 AC_OUTPUT