configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n' | tr -d '\r'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19
  20 dnl Versions for external dependencies
  21 LIBDRM_REQUIRED=2.4.15
  22 LIBDRM_RADEON_REQUIRED=2.4.17
  23 DRI2PROTO_REQUIRED=2.1
  24 GLPROTO_REQUIRED=1.4.11
  25 LIBDRM_XORG_REQUIRED=2.4.17
  26 LIBKMS_XORG_REQUIRED=1.0.0
  27
  28 dnl Check for progs
  29 AC_PROG_CPP
  30 AC_PROG_CC
  31 AC_PROG_CXX
  32 AC_CHECK_PROGS([MAKE], [gmake make])
  33 AC_CHECK_PROGS([PYTHON2], [python2 python])
  34 AC_PATH_PROG([MKDEP], [makedepend])
  35 AC_PATH_PROG([SED], [sed])
  36
  37 if test "x$MKDEP" = "x"; then
  38     AC_MSG_ERROR([makedepend is required to build Mesa])
  39 fi
  40
  41 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  42 dnl configuration in that case.
  43 AC_PROG_INSTALL
  44 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  45
  46 dnl We need a POSIX shell for parts of the build. Assume we have one
  47 dnl in most cases.
  48 case "$host_os" in
  49 solaris*)
  50     # Solaris /bin/sh is too old/non-POSIX compliant
  51     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  52     SHELL="$POSIX_SHELL"
  53     ;;
  54 esac
  55
  56 dnl clang is mostly GCC-compatible, but its version is much lower,
  57 dnl so we have to check for it.
  58 AC_MSG_CHECKING([if compiling with clang])
  59
  60 AC_COMPILE_IFELSE(
  61 [AC_LANG_PROGRAM([], [[
  62 #ifndef __clang__
  63        not clang
  64 #endif
  65 ]])],
  66 [CLANG=yes], [CLANG=no])
  67
  68 AC_MSG_RESULT([$CLANG])
  69
  70 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
  71 dnl versions are explictly not supported.
  72 if test "x$GCC" = xyes -a "x$CLANG" = xno; then
  73     AC_MSG_CHECKING([whether gcc version is sufficient])
  74     major=0
  75     minor=0
  76
  77     GCC_VERSION=`$CC -dumpversion`
  78     if test $? -eq 0; then
  79         major=`echo $GCC_VERSION | cut -d. -f1`
  80         minor=`echo $GCC_VERSION | cut -d. -f1`
  81     fi
  82
  83     if test $major -lt 3 -o $major -eq 3 -a $minor -lt 3 ; then
  84         AC_MSG_RESULT([no])
  85         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
  86     else
  87         AC_MSG_RESULT([yes])
  88     fi
  89 fi
  90
  91
  92 MKDEP_OPTIONS=-fdepend
  93 dnl Ask gcc where it's keeping its secret headers
  94 if test "x$GCC" = xyes; then
  95     for dir in include include-fixed; do
  96         GCC_INCLUDES=`$CC -print-file-name=$dir`
  97         if test "x$GCC_INCLUDES" != x && \
  98            test "$GCC_INCLUDES" != "$dir" && \
  99            test -d "$GCC_INCLUDES"; then
 100             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 101         fi
 102     done
 103 fi
 104 AC_SUBST([MKDEP_OPTIONS])
 105
 106 dnl Make sure the pkg-config macros are defined
 107 m4_ifndef([PKG_PROG_PKG_CONFIG],
 108     [m4_fatal([Could not locate the pkg-config autoconf macros.
 109   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 110   are in a different location, try setting the environment variable
 111   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 112 PKG_PROG_PKG_CONFIG()
 113
 114 dnl LIB_DIR - library basename
 115 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 116 AC_SUBST([LIB_DIR])
 117
 118 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 119 _SAVE_LDFLAGS="$LDFLAGS"
 120 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 121 AC_SUBST([EXTRA_LIB_PATH])
 122
 123 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 124 _SAVE_CPPFLAGS="$CPPFLAGS"
 125 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 126 AC_SUBST([X11_INCLUDES])
 127
 128 dnl Compiler macros
 129 DEFINES=""
 130 AC_SUBST([DEFINES])
 131 case "$host_os" in
 132 linux*|*-gnu*|gnu*)
 133     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 134     ;;
 135 solaris*)
 136     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 137     ;;
 138 cygwin*)
 139     DEFINES="$DEFINES -DPTHREADS"
 140     ;;
 141 esac
 142
 143 dnl Add flags for gcc and g++
 144 if test "x$GCC" = xyes; then
 145     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99"
 146     if test "x$CLANG" = "xno"; then
 147        CFLAGS="$CFLAGS -ffast-math"
 148     fi
 149
 150     # Enable -fvisibility=hidden if using a gcc that supports it
 151     save_CFLAGS="$CFLAGS"
 152     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 153     CFLAGS="$CFLAGS -fvisibility=hidden"
 154     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 155                    [CFLAGS="$save_CFLAGS" ; AC_MSG_RESULT([no])]);
 156
 157     # Work around aliasing bugs - developers should comment this out
 158     CFLAGS="$CFLAGS -fno-strict-aliasing"
 159 fi
 160 if test "x$GXX" = xyes; then
 161     CXXFLAGS="$CXXFLAGS -Wall"
 162
 163     # Enable -fvisibility=hidden if using a gcc that supports it
 164     save_CXXFLAGS="$CXXFLAGS"
 165     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 166     CXXFLAGS="$CXXFLAGS -fvisibility=hidden"
 167     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 168                    [CXXFLAGS="$save_CXXFLAGS" ; AC_MSG_RESULT([no])]);
 169
 170     # Work around aliasing bugs - developers should comment this out
 171     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 172 fi
 173
 174 dnl These should be unnecessary, but let the user set them if they want
 175 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 176     Default is to use CFLAGS.])
 177 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 178     compiler. Default is to use CFLAGS.])
 179 AC_SUBST([OPT_FLAGS])
 180 AC_SUBST([ARCH_FLAGS])
 181
 182 dnl
 183 dnl Hacks to enable 32 or 64 bit build
 184 dnl
 185 AC_ARG_ENABLE([32-bit],
 186     [AS_HELP_STRING([--enable-32-bit],
 187         [build 32-bit libraries @<:@default=auto@:>@])],
 188     [enable_32bit="$enableval"],
 189     [enable_32bit=auto]
 190 )
 191 if test "x$enable_32bit" = xyes; then
 192     if test "x$GCC" = xyes; then
 193         CFLAGS="$CFLAGS -m32"
 194         ARCH_FLAGS="$ARCH_FLAGS -m32"
 195     fi
 196     if test "x$GXX" = xyes; then
 197         CXXFLAGS="$CXXFLAGS -m32"
 198     fi
 199 fi
 200 AC_ARG_ENABLE([64-bit],
 201     [AS_HELP_STRING([--enable-64-bit],
 202         [build 64-bit libraries @<:@default=auto@:>@])],
 203     [enable_64bit="$enableval"],
 204     [enable_64bit=auto]
 205 )
 206 if test "x$enable_64bit" = xyes; then
 207     if test "x$GCC" = xyes; then
 208         CFLAGS="$CFLAGS -m64"
 209     fi
 210     if test "x$GXX" = xyes; then
 211         CXXFLAGS="$CXXFLAGS -m64"
 212     fi
 213 fi
 214
 215 dnl
 216 dnl shared/static libraries, mimic libtool options
 217 dnl
 218 AC_ARG_ENABLE([static],
 219     [AS_HELP_STRING([--enable-static],
 220         [build static libraries @<:@default=disabled@:>@])],
 221     [enable_static="$enableval"],
 222     [enable_static=no]
 223 )
 224 case "x$enable_static" in
 225 xyes|xno ) ;;
 226 x ) enable_static=no ;;
 227 * )
 228     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 229     ;;
 230 esac
 231 AC_ARG_ENABLE([shared],
 232     [AS_HELP_STRING([--disable-shared],
 233         [build shared libraries @<:@default=enabled@:>@])],
 234     [enable_shared="$enableval"],
 235     [enable_shared=yes]
 236 )
 237 case "x$enable_shared" in
 238 xyes|xno ) ;;
 239 x ) enable_shared=yes ;;
 240 * )
 241     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 242     ;;
 243 esac
 244
 245 dnl Can't have static and shared libraries, default to static if user
 246 dnl explicitly requested. If both disabled, set to static since shared
 247 dnl was explicitly requirested.
 248 case "x$enable_static$enable_shared" in
 249 xyesyes )
 250     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 251     enable_shared=no
 252     ;;
 253 xnono )
 254     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 255     enable_static=yes
 256     ;;
 257 esac
 258
 259 dnl
 260 dnl mklib options
 261 dnl
 262 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 263 if test "$enable_static" = yes; then
 264     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 265 fi
 266 AC_SUBST([MKLIB_OPTIONS])
 267
 268 dnl
 269 dnl other compiler options
 270 dnl
 271 AC_ARG_ENABLE([debug],
 272     [AS_HELP_STRING([--enable-debug],
 273         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 274     [enable_debug="$enableval"],
 275     [enable_debug=no]
 276 )
 277 if test "x$enable_debug" = xyes; then
 278     DEFINES="$DEFINES -DDEBUG"
 279     if test "x$GCC" = xyes; then
 280         CFLAGS="$CFLAGS -g"
 281     fi
 282     if test "x$GXX" = xyes; then
 283         CXXFLAGS="$CXXFLAGS -g"
 284     fi
 285 fi
 286
 287 dnl
 288 dnl library names
 289 dnl
 290 LIB_PREFIX_GLOB='lib'
 291 LIB_VERSION_SEPARATOR='.'
 292 if test "$enable_static" = yes; then
 293     LIB_EXTENSION='a'
 294 else
 295     case "$host_os" in
 296     darwin* )
 297         LIB_EXTENSION='dylib' ;;
 298     cygwin* )
 299         dnl prefix can be 'cyg' or 'lib'
 300         LIB_PREFIX_GLOB='???'
 301         LIB_VERSION_SEPARATOR='-'
 302         LIB_EXTENSION='dll' ;;
 303     aix* )
 304         LIB_EXTENSION='a' ;;
 305     * )
 306         LIB_EXTENSION='so' ;;
 307     esac
 308 fi
 309
 310 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 311 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 312 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 313 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 314 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 315 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 316 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 317 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 318 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 319
 320 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 321 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 322 GLUT_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLUT_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 323 GLW_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLW_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 324 OSMESA_LIB_GLOB=${LIB_PREFIX_GLOB}'$(OSMESA_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 325 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 326 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 327 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 328 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 329 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 330
 331 AC_SUBST([GL_LIB_NAME])
 332 AC_SUBST([GLU_LIB_NAME])
 333 AC_SUBST([GLUT_LIB_NAME])
 334 AC_SUBST([GLW_LIB_NAME])
 335 AC_SUBST([OSMESA_LIB_NAME])
 336 AC_SUBST([EGL_LIB_NAME])
 337 AC_SUBST([GLESv1_CM_LIB_NAME])
 338 AC_SUBST([GLESv2_LIB_NAME])
 339 AC_SUBST([VG_LIB_NAME])
 340
 341 AC_SUBST([GL_LIB_GLOB])
 342 AC_SUBST([GLU_LIB_GLOB])
 343 AC_SUBST([GLUT_LIB_GLOB])
 344 AC_SUBST([GLW_LIB_GLOB])
 345 AC_SUBST([OSMESA_LIB_GLOB])
 346 AC_SUBST([EGL_LIB_GLOB])
 347 AC_SUBST([GLESv1_CM_LIB_GLOB])
 348 AC_SUBST([GLESv2_LIB_GLOB])
 349 AC_SUBST([VG_LIB_GLOB])
 350
 351 dnl
 352 dnl Arch/platform-specific settings
 353 dnl
 354 AC_ARG_ENABLE([asm],
 355     [AS_HELP_STRING([--disable-asm],
 356         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 357     [enable_asm="$enableval"],
 358     [enable_asm=yes]
 359 )
 360 asm_arch=""
 361 ASM_FLAGS=""
 362 MESA_ASM_SOURCES=""
 363 GLAPI_ASM_SOURCES=""
 364 AC_MSG_CHECKING([whether to enable assembly])
 365 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 366 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 367 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 368     case "$host_cpu" in
 369     i?86 | x86_64)
 370         enable_asm=no
 371         AC_MSG_RESULT([no, cross compiling])
 372         ;;
 373     esac
 374 fi
 375 # check for supported arches
 376 if test "x$enable_asm" = xyes; then
 377     case "$host_cpu" in
 378     i?86)
 379         case "$host_os" in
 380         linux* | *freebsd* | dragonfly*)
 381             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 382             ;;
 383         esac
 384         ;;
 385     x86_64)
 386         case "$host_os" in
 387         linux* | *freebsd* | dragonfly*)
 388             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 389             ;;
 390         esac
 391         ;;
 392     powerpc)
 393         case "$host_os" in
 394         linux*)
 395             asm_arch=ppc
 396             ;;
 397         esac
 398         ;;
 399     sparc*)
 400         case "$host_os" in
 401         linux*)
 402             asm_arch=sparc
 403             ;;
 404         esac
 405         ;;
 406     esac
 407
 408     case "$asm_arch" in
 409     x86)
 410         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 411         MESA_ASM_SOURCES='$(X86_SOURCES)'
 412         GLAPI_ASM_SOURCES='$(X86_API)'
 413         AC_MSG_RESULT([yes, x86])
 414         ;;
 415     x86_64)
 416         ASM_FLAGS="-DUSE_X86_64_ASM"
 417         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 418         GLAPI_ASM_SOURCES='$(X86-64_API)'
 419         AC_MSG_RESULT([yes, x86_64])
 420         ;;
 421     ppc)
 422         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 423         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 424         AC_MSG_RESULT([yes, ppc])
 425         ;;
 426     sparc)
 427         ASM_FLAGS="-DUSE_SPARC_ASM"
 428         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 429         GLAPI_ASM_SOURCES='$(SPARC_API)'
 430         AC_MSG_RESULT([yes, sparc])
 431         ;;
 432     *)
 433         AC_MSG_RESULT([no, platform not supported])
 434         ;;
 435     esac
 436 fi
 437 AC_SUBST([ASM_FLAGS])
 438 AC_SUBST([MESA_ASM_SOURCES])
 439 AC_SUBST([GLAPI_ASM_SOURCES])
 440
 441 dnl PIC code macro
 442 MESA_PIC_FLAGS
 443
 444 dnl Check to see if dlopen is in default libraries (like Solaris, which
 445 dnl has it in libc), or if libdl is needed to get it.
 446 AC_CHECK_FUNC([dlopen], [],
 447     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 448 AC_SUBST([DLOPEN_LIBS])
 449
 450 dnl See if posix_memalign is available
 451 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 452
 453 dnl SELinux awareness.
 454 AC_ARG_ENABLE([selinux],
 455     [AS_HELP_STRING([--enable-selinux],
 456         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 457     [MESA_SELINUX="$enableval"],
 458     [MESA_SELINUX=no])
 459 if test "x$enable_selinux" = "xyes"; then
 460     AC_CHECK_HEADER([selinux/selinux.h],[],
 461                     [AC_MSG_ERROR([SELinux headers not found])])
 462     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 463                  [AC_MSG_ERROR([SELinux library not found])])
 464     SELINUX_LIBS="-lselinux"
 465     DEFINES="$DEFINES -DMESA_SELINUX"
 466 fi
 467
 468 dnl Determine which APIs to support
 469 AC_ARG_ENABLE([opengl],
 470     [AS_HELP_STRING([--disable-opengl],
 471         [disable support for standard OpenGL API @<:@default=no@:>@])],
 472     [enable_opengl="$enableval"],
 473     [enable_opengl=yes])
 474 AC_ARG_ENABLE([gles1],
 475     [AS_HELP_STRING([--enable-gles1],
 476         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 477     [enable_gles1="$enableval"],
 478     [enable_gles1=no])
 479 AC_ARG_ENABLE([gles2],
 480     [AS_HELP_STRING([--enable-gles2],
 481         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 482     [enable_gles2="$enableval"],
 483     [enable_gles2=no])
 484 AC_ARG_ENABLE([gles-overlay],
 485     [AS_HELP_STRING([--enable-gles-overlay],
 486         [build separate OpenGL ES only libraries @<:@default=no@:>@])],
 487     [enable_gles_overlay="$enableval"],
 488     [enable_gles_overlay=no])
 489
 490 AC_ARG_ENABLE([openvg],
 491     [AS_HELP_STRING([--enable-openvg],
 492         [enable support for OpenVG API @<:@default=no@:>@])],
 493     [enable_openvg="$enableval"],
 494     [enable_openvg=no])
 495
 496 if test "x$enable_opengl" = xno -a \
 497         "x$enable_gles1" = xno -a \
 498         "x$enable_gles2" = xno -a \
 499         "x$enable_gles_overlay" = xno -a \
 500         "x$enable_openvg" = xno; then
 501     AC_MSG_ERROR([at least one API should be enabled])
 502 fi
 503
 504 API_DEFINES=""
 505 GLES_OVERLAY=0
 506 if test "x$enable_opengl" = xno; then
 507     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 508 else
 509     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 510 fi
 511 if test "x$enable_gles1" = xyes; then
 512     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 513 fi
 514 if test "x$enable_gles2" = xyes; then
 515     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 516 fi
 517 if test "x$enable_gles_overlay" = xyes; then
 518     GLES_OVERLAY=1
 519 fi
 520 AC_SUBST([API_DEFINES])
 521 AC_SUBST([GLES_OVERLAY])
 522
 523 dnl
 524 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 525 dnl More later: fbdev, ...
 526 dnl
 527 default_driver="xlib"
 528
 529 case "$host_os" in
 530 linux*)
 531     case "$host_cpu" in
 532     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 533     esac
 534     ;;
 535 *freebsd* | dragonfly*)
 536     case "$host_cpu" in
 537     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 538     esac
 539     ;;
 540 esac
 541
 542 if test "x$enable_opengl" = xno; then
 543     default_driver="no"
 544 fi
 545
 546 AC_ARG_WITH([driver],
 547     [AS_HELP_STRING([--with-driver=DRIVER],
 548         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 549     [mesa_driver="$withval"],
 550     [mesa_driver="$default_driver"])
 551 dnl Check for valid option
 552 case "x$mesa_driver" in
 553 xxlib|xdri|xosmesa)
 554     if test "x$enable_opengl" = xno; then
 555         AC_MSG_ERROR([Driver '$mesa_driver' requires OpenGL enabled])
 556     fi
 557     ;;
 558 xno)
 559     ;;
 560 *)
 561     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 562     ;;
 563 esac
 564
 565 PKG_CHECK_MODULES([TALLOC], [talloc])
 566 AC_SUBST([TALLOC_LIBS])
 567 AC_SUBST([TALLOC_CFLAGS])
 568
 569 dnl
 570 dnl Driver specific build directories
 571 dnl
 572
 573 dnl this variable will be prepended to SRC_DIRS and is not exported
 574 CORE_DIRS=""
 575
 576 SRC_DIRS=""
 577 GLU_DIRS="sgi"
 578 GALLIUM_DIRS="auxiliary drivers state_trackers"
 579 GALLIUM_TARGET_DIRS=""
 580 GALLIUM_WINSYS_DIRS="sw"
 581 GALLIUM_DRIVERS_DIRS="softpipe failover galahad trace rbug identity"
 582 GALLIUM_STATE_TRACKERS_DIRS=""
 583
 584 # build glapi if OpenGL is enabled
 585 if test "x$enable_opengl" = xyes; then
 586     CORE_DIRS="$CORE_DIRS mapi/glapi"
 587 fi
 588
 589 # build es1api and es2api if OpenGL ES is enabled
 590 case "x$enable_gles1$enable_gles2$enable_gles_overlay" in
 591 x*yes*)
 592     CORE_DIRS="$CORE_DIRS mapi/es1api mapi/es2api"
 593     ;;
 594 esac
 595
 596 # build vgapi if OpenVG is enabled
 597 if test "x$enable_openvg" = xyes; then
 598     CORE_DIRS="$CORE_DIRS mapi/vgapi"
 599 fi
 600
 601 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 602 case "x$enable_opengl$enable_gles1$enable_gles2$enable_gles_overlay" in
 603 x*yes*)
 604     CORE_DIRS="$CORE_DIRS glsl mesa"
 605     ;;
 606 esac
 607
 608 case "$mesa_driver" in
 609 xlib)
 610     DRIVER_DIRS="x11"
 611     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 612     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 613     ;;
 614 dri)
 615     SRC_DIRS="$SRC_DIRS glx"
 616     DRIVER_DIRS="dri"
 617     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib sw/dri"
 618     ;;
 619 osmesa)
 620     DRIVER_DIRS="osmesa"
 621     ;;
 622 no)
 623     DRIVER_DRIS=""
 624     ;;
 625 esac
 626 AC_SUBST([SRC_DIRS])
 627 AC_SUBST([GLU_DIRS])
 628 AC_SUBST([DRIVER_DIRS])
 629 AC_SUBST([GALLIUM_DIRS])
 630 AC_SUBST([GALLIUM_TARGET_DIRS])
 631 AC_SUBST([GALLIUM_WINSYS_DIRS])
 632 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 633 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 634 AC_SUBST([MESA_LLVM])
 635
 636 dnl
 637 dnl Find out if X is available. The variable have_x is set if libX11 is
 638 dnl found to mimic AC_PATH_XTRA.
 639 dnl
 640 if test -n "$PKG_CONFIG"; then
 641     AC_MSG_CHECKING([pkg-config files for X11 are available])
 642     PKG_CHECK_EXISTS([x11],[
 643         x11_pkgconfig=yes
 644         have_x=yes
 645         ],[
 646         x11_pkgconfig=no
 647     ])
 648     AC_MSG_RESULT([$x11_pkgconfig])
 649 else
 650     x11_pkgconfig=no
 651 fi
 652 dnl Use the autoconf macro if no pkg-config files
 653 if test "$x11_pkgconfig" = yes; then
 654     PKG_CHECK_MODULES([X11], [x11])
 655 else
 656     AC_PATH_XTRA
 657     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 658     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 659     AC_SUBST([X11_CFLAGS])
 660     AC_SUBST([X11_LIBS])
 661 fi
 662
 663 dnl Try to tell the user that the --x-* options are only used when
 664 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 665 m4_divert_once([HELP_BEGIN],
 666 [These options are only used when the X libraries cannot be found by the
 667 pkg-config utility.])
 668
 669 dnl We need X for xlib and dri, so bomb now if it's not found
 670 case "$mesa_driver" in
 671 xlib|dri)
 672     if test "$no_x" = yes; then
 673         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 674     fi
 675     ;;
 676 esac
 677
 678 dnl XCB - this is only used for GLX right now
 679 AC_ARG_ENABLE([xcb],
 680     [AS_HELP_STRING([--enable-xcb],
 681         [use XCB for GLX @<:@default=disabled@:>@])],
 682     [enable_xcb="$enableval"],
 683     [enable_xcb=no])
 684 if test "x$enable_xcb" = xyes; then
 685     DEFINES="$DEFINES -DUSE_XCB"
 686 else
 687     enable_xcb=no
 688 fi
 689
 690 dnl
 691 dnl libGL configuration per driver
 692 dnl
 693 case "$mesa_driver" in
 694 xlib)
 695     if test "$x11_pkgconfig" = yes; then
 696         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 697         GL_PC_REQ_PRIV="x11 xext"
 698         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 699         GL_LIB_DEPS="$XLIBGL_LIBS"
 700     else
 701         # should check these...
 702         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 703         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 704         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 705         GL_PC_CFLAGS="$X11_INCLUDES"
 706     fi
 707     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $TALLOC_LIBS"
 708     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread $TALLOC_LIBS"
 709
 710     # if static, move the external libraries to the programs
 711     # and empty the libraries for libGL
 712     if test "$enable_static" = yes; then
 713         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 714         GL_LIB_DEPS=""
 715     fi
 716     ;;
 717 dri|no) # these checks are still desired when there is no mesa_driver
 718     # DRI must be shared, I think
 719     if test "$enable_static" = yes; then
 720         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 721     fi
 722
 723     # Check for libdrm
 724     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 725     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 726     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 727     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED glproto >= $GLPROTO_REQUIRED"
 728     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 729
 730     # find the DRI deps for libGL
 731     if test "$x11_pkgconfig" = yes; then
 732         dri_modules="x11 xext xdamage xfixes"
 733
 734         # add xf86vidmode if available
 735         PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 736         if test "$HAVE_XF86VIDMODE" = yes ; then
 737             dri_modules="$dri_modules xxf86vm"
 738         fi
 739
 740         # add xcb modules if necessary
 741         if test "$enable_xcb" = yes; then
 742             dri_modules="$dri_modules x11-xcb xcb-glx"
 743         fi
 744
 745         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 746         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 747         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 748         GL_LIB_DEPS="$DRIGL_LIBS"
 749     else
 750         # should check these...
 751         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 752         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 753         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 754         GL_PC_CFLAGS="$X11_INCLUDES"
 755
 756         # XCB can only be used from pkg-config
 757         if test "$enable_xcb" = yes; then
 758             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 759             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 760             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 761             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 762         fi
 763     fi
 764
 765     # need DRM libs, -lpthread, etc.
 766     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 767     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 768     GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 769     GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 770     GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 771     GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 772     ;;
 773 osmesa)
 774     # No libGL for osmesa
 775     GL_LIB_DEPS=""
 776     ;;
 777 esac
 778 AC_SUBST([GL_LIB_DEPS])
 779 AC_SUBST([GL_PC_REQ_PRIV])
 780 AC_SUBST([GL_PC_LIB_PRIV])
 781 AC_SUBST([GL_PC_CFLAGS])
 782 AC_SUBST([DRI_PC_REQ_PRIV])
 783 AC_SUBST([GLESv1_CM_LIB_DEPS])
 784 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 785 AC_SUBST([GLESv2_LIB_DEPS])
 786 AC_SUBST([GLESv2_PC_LIB_PRIV])
 787
 788
 789 AC_SUBST([HAVE_XF86VIDMODE])
 790
 791 PKG_CHECK_MODULES([LIBDRM_RADEON],
 792                   [libdrm_radeon libdrm >= $LIBDRM_RADEON_REQUIRED],
 793                   HAVE_LIBDRM_RADEON=yes,
 794                   HAVE_LIBDRM_RADEON=no)
 795
 796 dnl
 797 dnl More X11 setup
 798 dnl
 799 if test "$mesa_driver" = xlib; then
 800     DEFINES="$DEFINES -DUSE_XSHM"
 801 fi
 802
 803 dnl
 804 dnl More DRI setup
 805 dnl
 806 AC_ARG_ENABLE([glx-tls],
 807     [AS_HELP_STRING([--enable-glx-tls],
 808         [enable TLS support in GLX @<:@default=disabled@:>@])],
 809     [GLX_USE_TLS="$enableval"],
 810     [GLX_USE_TLS=no])
 811 dnl Directory for DRI drivers
 812 AC_ARG_WITH([dri-driverdir],
 813     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 814         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 815     [DRI_DRIVER_INSTALL_DIR="$withval"],
 816     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 817 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 818 dnl Extra search path for DRI drivers
 819 AC_ARG_WITH([dri-searchpath],
 820     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 821         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 822     [DRI_DRIVER_SEARCH_DIR="$withval"],
 823     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 824 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 825 dnl Direct rendering or just indirect rendering
 826 AC_ARG_ENABLE([driglx-direct],
 827     [AS_HELP_STRING([--disable-driglx-direct],
 828         [enable direct rendering in GLX and EGL for DRI @<:@default=enabled@:>@])],
 829     [driglx_direct="$enableval"],
 830     [driglx_direct="yes"])
 831 dnl Which drivers to build - default is chosen by platform
 832 AC_ARG_WITH([dri-drivers],
 833     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 834         [comma delimited DRI drivers list, e.g.
 835         "swrast,i965,radeon" @<:@default=auto@:>@])],
 836     [with_dri_drivers="$withval"],
 837     [with_dri_drivers=yes])
 838 if test "x$with_dri_drivers" = x; then
 839     with_dri_drivers=no
 840 fi
 841
 842 dnl If $with_dri_drivers is yes, directories will be added through
 843 dnl platform checks
 844 DRI_DIRS=""
 845 case "$with_dri_drivers" in
 846 no) ;;
 847 yes)
 848     DRI_DIRS="yes"
 849     ;;
 850 *)
 851     # verify the requested driver directories exist
 852     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 853     for driver in $dri_drivers; do
 854         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 855             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 856     done
 857     DRI_DIRS="$dri_drivers"
 858     ;;
 859 esac
 860
 861 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 862 if test "$mesa_driver" = dri -o "$mesa_driver" = no; then
 863     # Use TLS in GLX?
 864     if test "x$GLX_USE_TLS" = xyes; then
 865         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 866     fi
 867
 868     # Platform specific settings and drivers to build
 869     case "$host_os" in
 870     linux*)
 871         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 872         if test "x$driglx_direct" = xyes; then
 873             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 874         fi
 875         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 876
 877         case "$host_cpu" in
 878         x86_64)
 879             # sis is missing because they have not be converted to use
 880             # the new interface.  i810 are missing because there is no
 881             # x86-64 system where they could *ever* be used.
 882             if test "x$DRI_DIRS" = "xyes"; then
 883                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 884                     savage tdfx unichrome swrast"
 885             fi
 886             ;;
 887         powerpc*)
 888             # Build only the drivers for cards that exist on PowerPC.
 889             # At some point MGA will be added, but not yet.
 890             if test "x$DRI_DIRS" = "xyes"; then
 891                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon tdfx swrast"
 892             fi
 893             ;;
 894         sparc*)
 895             # Build only the drivers for cards that exist on sparc`
 896             if test "x$DRI_DIRS" = "xyes"; then
 897                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon swrast"
 898             fi
 899             ;;
 900         esac
 901         ;;
 902     freebsd* | dragonfly*)
 903         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 904         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 905         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 906         if test "x$driglx_direct" = xyes; then
 907             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 908         fi
 909         if test "x$GXX" = xyes; then
 910             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 911         fi
 912
 913         if test "x$DRI_DIRS" = "xyes"; then
 914             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon tdfx \
 915                 unichrome savage sis swrast"
 916         fi
 917         ;;
 918     gnu*)
 919         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 920         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 921         ;;
 922     solaris*)
 923         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 924         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 925         if test "x$driglx_direct" = xyes; then
 926             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 927         fi
 928         ;;
 929     esac
 930
 931     # default drivers
 932     if test "x$DRI_DIRS" = "xyes"; then
 933         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 934             savage sis tdfx unichrome swrast"
 935     fi
 936
 937     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 938
 939     # Check for expat
 940     if test "$mesa_driver" = dri; then
 941         EXPAT_INCLUDES=""
 942         EXPAT_LIB=-lexpat
 943         AC_ARG_WITH([expat],
 944             [AS_HELP_STRING([--with-expat=DIR],
 945                 [expat install directory])],[
 946             EXPAT_INCLUDES="-I$withval/include"
 947             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 948             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 949             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 950             ])
 951         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 952         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 953             [AC_MSG_ERROR([Expat required for DRI.])])
 954     fi
 955
 956     # put all the necessary libs together
 957     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS $TALLOC_LIBS"
 958 fi
 959 AC_SUBST([DRI_DIRS])
 960 AC_SUBST([EXPAT_INCLUDES])
 961 AC_SUBST([DRI_LIB_DEPS])
 962
 963 case $DRI_DIRS in
 964 *i915*|*i965*)
 965     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= 2.4.21])
 966     ;;
 967 esac
 968
 969 case $DRI_DIRS in
 970 *radeon*|*r200*|*r300*|*r600*)
 971     if test "x$HAVE_LIBDRM_RADEON" = xyes; then
 972         RADEON_CFLAGS="-DHAVE_LIBDRM_RADEON=1 $LIBDRM_RADEON_CFLAGS"
 973         RADEON_LDFLAGS=$LIBDRM_RADEON_LIBS
 974     fi
 975     ;;
 976 esac
 977 AC_SUBST([RADEON_CFLAGS])
 978 AC_SUBST([RADEON_LDFLAGS])
 979
 980
 981 dnl
 982 dnl OSMesa configuration
 983 dnl
 984 if test "$mesa_driver" = xlib; then
 985     default_gl_osmesa=yes
 986 else
 987     default_gl_osmesa=no
 988 fi
 989 AC_ARG_ENABLE([gl-osmesa],
 990     [AS_HELP_STRING([--enable-gl-osmesa],
 991         [enable OSMesa with libGL @<:@default=enabled for xlib driver@:>@])],
 992     [gl_osmesa="$enableval"],
 993     [gl_osmesa="$default_gl_osmesa"])
 994 if test "x$gl_osmesa" = xyes; then
 995     if test "x$enable_opengl" = xno; then
 996         AC_MSG_ERROR([OpenGL is not available for OSMesa driver])
 997     fi
 998     if test "$mesa_driver" = osmesa; then
 999         AC_MSG_ERROR([libGL is not available for OSMesa driver])
1000     else
1001         DRIVER_DIRS="$DRIVER_DIRS osmesa"
1002     fi
1003 fi
1004
1005 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1006 AC_ARG_WITH([osmesa-bits],
1007     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1008         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1009     [osmesa_bits="$withval"],
1010     [osmesa_bits=8])
1011 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
1012     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
1013     osmesa_bits=8
1014 fi
1015 case "x$osmesa_bits" in
1016 x8)
1017     OSMESA_LIB=OSMesa
1018     ;;
1019 x16|x32)
1020     OSMESA_LIB="OSMesa$osmesa_bits"
1021     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1022     ;;
1023 *)
1024     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1025     ;;
1026 esac
1027 AC_SUBST([OSMESA_LIB])
1028
1029 case "$DRIVER_DIRS" in
1030 *osmesa*)
1031     # only link libraries with osmesa if shared
1032     if test "$enable_static" = no; then
1033         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS $TALLOC_LIBS"
1034     else
1035         OSMESA_LIB_DEPS=""
1036     fi
1037     OSMESA_MESA_DEPS=""
1038     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS $TALLOC_LIBS"
1039     ;;
1040 esac
1041 AC_SUBST([OSMESA_LIB_DEPS])
1042 AC_SUBST([OSMESA_MESA_DEPS])
1043 AC_SUBST([OSMESA_PC_REQ])
1044 AC_SUBST([OSMESA_PC_LIB_PRIV])
1045
1046 dnl
1047 dnl EGL configuration
1048 dnl
1049 AC_ARG_ENABLE([egl],
1050     [AS_HELP_STRING([--disable-egl],
1051         [disable EGL library @<:@default=enabled@:>@])],
1052     [enable_egl="$enableval"],
1053     [enable_egl=yes])
1054 if test "x$enable_egl" = xno; then
1055     if test "x$mesa_driver" = xno; then
1056         AC_MSG_ERROR([cannot disable EGL when there is no mesa driver])
1057     fi
1058     if test "x$enable_openvg" = xyes; then
1059         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1060     fi
1061 fi
1062 if test "x$enable_egl" = xyes; then
1063     SRC_DIRS="$SRC_DIRS egl"
1064     EGL_LIB_DEPS="$DLOPEN_LIBS -lpthread"
1065     EGL_DRIVERS_DIRS=""
1066     if test "$enable_static" != yes; then
1067         # build egl_glx when libGL is built
1068         if test "$mesa_driver" = xlib -o "$mesa_driver" = dri; then
1069             EGL_DRIVERS_DIRS="glx"
1070         fi
1071
1072         if test "$mesa_driver" = dri; then
1073             # build egl_dri2 when xcb-dri2 is available
1074             PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes],
1075                           [have_xcb_dri2=yes],[have_xcb_dri2=no])
1076             PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1077                           [have_libudev=yes],[have_libudev=no])
1078
1079             if test "$have_xcb_dri2" = yes; then
1080                 EGL_DRIVER_DRI2=dri2
1081                 DEFINES="$DEFINES -DHAVE_XCB_DRI2"
1082                 if test "$have_libudev" = yes; then
1083                     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1084                 fi
1085             fi
1086         fi
1087
1088         EGL_DRIVERS_DIRS="$EGL_DRIVERS_DIRS $EGL_DRIVER_DRI2"
1089     fi
1090 fi
1091 AC_SUBST([EGL_LIB_DEPS])
1092 AC_SUBST([EGL_DRIVERS_DIRS])
1093
1094 dnl
1095 dnl GLU configuration
1096 dnl
1097 AC_ARG_ENABLE([glu],
1098     [AS_HELP_STRING([--disable-glu],
1099         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1100     [enable_glu="$enableval"],
1101     [enable_glu=yes])
1102
1103 if test "x$enable_glu" = xyes -a "x$mesa_driver" = xno; then
1104     AC_MSG_NOTICE([Disabling GLU since there is no OpenGL driver])
1105     enable_glu=no
1106 fi
1107
1108 if test "x$enable_glu" = xyes; then
1109     SRC_DIRS="$SRC_DIRS glu"
1110
1111     case "$mesa_driver" in
1112     osmesa)
1113         # Link libGLU to libOSMesa instead of libGL
1114         GLU_LIB_DEPS=""
1115         GLU_PC_REQ="osmesa"
1116         if test "$enable_static" = no; then
1117             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1118         else
1119             GLU_MESA_DEPS=""
1120         fi
1121         ;;
1122     *)
1123         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1124         GLU_PC_REQ="gl"
1125         GLU_PC_LIB_PRIV="-lm"
1126         if test "$enable_static" = no; then
1127             GLU_LIB_DEPS="-lm"
1128             GLU_MESA_DEPS='-l$(GL_LIB)'
1129         else
1130             GLU_LIB_DEPS=""
1131             GLU_MESA_DEPS=""
1132             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
1133         fi
1134         ;;
1135     esac
1136 fi
1137 if test "$enable_static" = no; then
1138     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1139 fi
1140 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1141 AC_SUBST([GLU_LIB_DEPS])
1142 AC_SUBST([GLU_MESA_DEPS])
1143 AC_SUBST([GLU_PC_REQ])
1144 AC_SUBST([GLU_PC_REQ_PRIV])
1145 AC_SUBST([GLU_PC_LIB_PRIV])
1146 AC_SUBST([GLU_PC_CFLAGS])
1147
1148 dnl
1149 dnl GLw configuration
1150 dnl
1151 AC_ARG_ENABLE([glw],
1152     [AS_HELP_STRING([--disable-glw],
1153         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
1154     [enable_glw="$enableval"],
1155     [enable_glw=yes])
1156 dnl Don't build GLw on osmesa
1157 if test "x$enable_glw" = xyes; then
1158     case "$mesa_driver" in
1159     osmesa|no)
1160         AC_MSG_NOTICE([Disabling GLw since there is no OpenGL driver])
1161         enable_glw=no
1162         ;;
1163     esac
1164 fi
1165 AC_ARG_ENABLE([motif],
1166     [AS_HELP_STRING([--enable-motif],
1167         [use Motif widgets in GLw @<:@default=disabled@:>@])],
1168     [enable_motif="$enableval"],
1169     [enable_motif=no])
1170
1171 if test "x$enable_glw" = xyes; then
1172     SRC_DIRS="$SRC_DIRS glw"
1173     if test "$x11_pkgconfig" = yes; then
1174         PKG_CHECK_MODULES([GLW],[x11 xt])
1175         GLW_PC_REQ_PRIV="x11 xt"
1176         GLW_LIB_DEPS="$GLW_LIBS"
1177     else
1178         # should check these...
1179         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
1180         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
1181         GLW_PC_CFLAGS="$X11_INCLUDES"
1182     fi
1183
1184     GLW_SOURCES="GLwDrawA.c"
1185     MOTIF_CFLAGS=
1186     if test "x$enable_motif" = xyes; then
1187         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
1188         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
1189         if test "x$MOTIF_CONFIG" != xno; then
1190             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
1191             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
1192         else
1193             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
1194                 [AC_MSG_ERROR([Can't locate Motif headers])])
1195             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
1196                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
1197         fi
1198         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
1199         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
1200         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
1201         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
1202     fi
1203
1204     # If static, empty GLW_LIB_DEPS and add libs for programs to link
1205     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV"
1206     if test "$enable_static" = no; then
1207         GLW_MESA_DEPS='-l$(GL_LIB)'
1208         GLW_LIB_DEPS="$GLW_LIB_DEPS"
1209     else
1210         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
1211         GLW_LIB_DEPS=""
1212         GLW_MESA_DEPS=""
1213     fi
1214 fi
1215 AC_SUBST([GLW_LIB_DEPS])
1216 AC_SUBST([GLW_MESA_DEPS])
1217 AC_SUBST([GLW_SOURCES])
1218 AC_SUBST([MOTIF_CFLAGS])
1219 AC_SUBST([GLW_PC_REQ_PRIV])
1220 AC_SUBST([GLW_PC_LIB_PRIV])
1221 AC_SUBST([GLW_PC_CFLAGS])
1222
1223 dnl
1224 dnl GLUT configuration
1225 dnl
1226 if test -f "$srcdir/include/GL/glut.h"; then
1227     default_glut=yes
1228 else
1229     default_glut=no
1230 fi
1231 AC_ARG_ENABLE([glut],
1232     [AS_HELP_STRING([--disable-glut],
1233         [enable GLUT library @<:@default=enabled if source available@:>@])],
1234     [enable_glut="$enableval"],
1235     [enable_glut="$default_glut"])
1236
1237 dnl Don't build glut on osmesa
1238 if test "x$enable_glut" = xyes; then
1239     case "$mesa_driver" in
1240     osmesa|no)
1241         AC_MSG_NOTICE([Disabling glut since there is no OpenGL driver])
1242         enable_glut=no
1243         ;;
1244     esac
1245 fi
1246 dnl Can't build glut if GLU not available
1247 if test "x$enable_glu$enable_glut" = xnoyes; then
1248     AC_MSG_WARN([Disabling glut since GLU is disabled])
1249     enable_glut=no
1250 fi
1251
1252 if test "x$enable_glut" = xyes; then
1253     SRC_DIRS="$SRC_DIRS glut/glx"
1254     if test "$x11_pkgconfig" = yes; then
1255         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1256         GLUT_PC_REQ_PRIV="x11 xmu xi"
1257         GLUT_LIB_DEPS="$GLUT_LIBS"
1258     else
1259         # should check these...
1260         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1261         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1262         GLUT_PC_CFLAGS="$X11_INCLUDES"
1263     fi
1264     if test "x$GCC" = xyes; then
1265         GLUT_CFLAGS="$GLUT_CFLAGS -fexceptions"
1266     fi
1267     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
1268     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm"
1269
1270     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1271     if test "$enable_static" = no; then
1272         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1273     else
1274         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1275         GLUT_LIB_DEPS=""
1276         GLUT_MESA_DEPS=""
1277     fi
1278 fi
1279 AC_SUBST([GLUT_LIB_DEPS])
1280 AC_SUBST([GLUT_MESA_DEPS])
1281 AC_SUBST([GLUT_CFLAGS])
1282 AC_SUBST([GLUT_PC_REQ_PRIV])
1283 AC_SUBST([GLUT_PC_LIB_PRIV])
1284 AC_SUBST([GLUT_PC_CFLAGS])
1285
1286 dnl
1287 dnl Program library dependencies
1288 dnl    Only libm is added here if necessary as the libraries should
1289 dnl    be pulled in by the linker
1290 dnl
1291 if test "x$APP_LIB_DEPS" = x; then
1292     case "$host_os" in
1293     solaris*)
1294         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1295         ;;
1296     cygwin*)
1297         APP_LIB_DEPS="-lX11"
1298         ;;
1299     *)
1300         APP_LIB_DEPS="-lm"
1301         ;;
1302     esac
1303 fi
1304 AC_SUBST([APP_LIB_DEPS])
1305 AC_SUBST([PROGRAM_DIRS])
1306
1307 dnl
1308 dnl Gallium configuration
1309 dnl
1310 AC_ARG_ENABLE([gallium],
1311     [AS_HELP_STRING([--disable-gallium],
1312         [build gallium @<:@default=enabled@:>@])],
1313     [enable_gallium="$enableval"],
1314     [enable_gallium=yes])
1315 if test "x$enable_gallium" = xno -a "x$enable_openvg" = xyes; then
1316     AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1317 fi
1318 if test "x$enable_gallium" = xyes; then
1319     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1320     AC_CHECK_HEADER([udis86.h], [HAS_UDIS86="yes"],
1321                 [HAS_UDIS86="no"])
1322     AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1323 fi
1324
1325 AC_SUBST([LLVM_CFLAGS])
1326 AC_SUBST([LLVM_LIBS])
1327 AC_SUBST([LLVM_LDFLAGS])
1328 AC_SUBST([LLVM_VERSION])
1329
1330 dnl
1331 dnl Gallium state trackers configuration
1332 dnl
1333 AC_ARG_WITH([state-trackers],
1334     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1335         [comma delimited state_trackers list, e.g.
1336         "egl,glx" @<:@default=auto@:>@])],
1337     [with_state_trackers="$withval"],
1338     [with_state_trackers=yes])
1339
1340 case "$with_state_trackers" in
1341 no)
1342     GALLIUM_STATE_TRACKERS_DIRS=""
1343     ;;
1344 yes)
1345     st_egl="no"
1346
1347     # look at what else is built
1348     case "$mesa_driver" in
1349     xlib)
1350         GALLIUM_STATE_TRACKERS_DIRS=glx
1351         ;;
1352     dri)
1353         GALLIUM_STATE_TRACKERS_DIRS="dri"
1354         HAVE_ST_DRI="yes"
1355         st_egl="yes"
1356         # Have only tested st/xorg on 1.6.0 servers
1357         PKG_CHECK_MODULES(XORG, [xorg-server >= 1.6.0 libdrm >= $LIBDRM_XORG_REQUIRED libkms >= $LIBKMS_XORG_REQUIRED],
1358             HAVE_ST_XORG="yes"; GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xorg",
1359             HAVE_ST_XORG="no")
1360         ;;
1361     no)
1362         st_egl="yes"
1363     esac
1364
1365     if test "x$enable_egl" = xyes; then
1366         if test "$enable_openvg" = yes; then
1367             GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vega"
1368             st_egl="yes"
1369         fi
1370
1371         if test "$st_egl" = yes; then
1372             GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS egl"
1373             HAVE_ST_EGL="yes"
1374         fi
1375     fi
1376     ;;
1377 *)
1378     # verify the requested state tracker exist
1379     state_trackers=""
1380     _state_trackers=`IFS=', '; echo $with_state_trackers`
1381     for tracker in $_state_trackers; do
1382         case "$tracker" in
1383         dri)
1384             if test "x$mesa_driver" != xdri; then
1385                 AC_MSG_ERROR([cannot build dri state tracker without mesa driver set to dri])
1386             fi
1387             HAVE_ST_DRI="yes"
1388             ;;
1389         egl)
1390             if test "x$enable_egl" != xyes; then
1391                 AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1392             fi
1393             HAVE_ST_EGL="yes"
1394             ;;
1395         xorg)
1396             PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1397             PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1398             PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1399             HAVE_ST_XORG="yes"
1400             ;;
1401         esac
1402
1403         if test -n "$tracker"; then
1404             test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1405                 AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1406             if test -n "$state_trackers"; then
1407                 state_trackers="$state_trackers $tracker"
1408             else
1409                 state_trackers="$tracker"
1410             fi
1411         fi
1412     done
1413     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1414     ;;
1415 esac
1416
1417
1418 EGL_CLIENT_APIS=""
1419 VG_LIB_DEPS=""
1420
1421 case "x$enable_opengl$enable_gles1$enable_gles2" in
1422 x*yes*)
1423     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1424     ;;
1425 esac
1426 if test "x$enable_gles_overlay" = xyes; then
1427     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GLESv1_CM_LIB) $(GLESv2_LIB)'
1428 fi
1429 if test "x$enable_openvg" = xyes; then
1430     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1431     VG_LIB_DEPS="$VG_LIB_DEPS -lpthread"
1432 fi
1433
1434 AC_SUBST([VG_LIB_DEPS])
1435 AC_SUBST([EGL_CLIENT_APIS])
1436
1437 if test "x$HAVE_ST_EGL" = xyes; then
1438         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl"
1439         # define GLX_DIRECT_RENDERING even when the driver is not dri
1440         if test "x$mesa_driver" != xdri -a "x$driglx_direct" = xyes; then
1441             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1442         fi
1443 fi
1444
1445 if test "x$HAVE_ST_XORG" = xyes; then
1446     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1447         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1448         HAVE_XEXTPROTO_71="no")
1449 fi
1450
1451 AC_ARG_WITH([egl-platforms],
1452     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1453         [comma delimited native platforms libEGL supports, e.g.
1454         "x11,drm" @<:@default=auto@:>@])],
1455     [with_egl_platforms="$withval"],
1456     [with_egl_platforms=yes])
1457 AC_ARG_WITH([egl-displays],
1458     [AS_HELP_STRING([--with-egl-displays@<:@=DIRS...@:>@],
1459         [DEPRECATED.  Use --with-egl-platforms instead])],
1460     [with_egl_platforms="$withval"])
1461
1462 EGL_PLATFORMS=""
1463 case "$with_egl_platforms" in
1464 yes)
1465     if test "x$enable_egl" = xyes && test "x$mesa_driver" != xosmesa; then
1466         EGL_PLATFORMS="x11"
1467         if test "$mesa_driver" = dri; then
1468             EGL_PLATFORMS="$EGL_PLATFORMS drm"
1469         fi
1470     fi
1471     ;;
1472 *)
1473     if test "x$enable_egl" != xyes; then
1474         AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1475     fi
1476     # verify the requested driver directories exist
1477     egl_platforms=`IFS=', '; echo $with_egl_platforms`
1478     for plat in $egl_platforms; do
1479         test -d "$srcdir/src/gallium/state_trackers/egl/$plat" || \
1480             AC_MSG_ERROR([EGL platform '$plat' does't exist])
1481         if test "$plat" = "fbdev"; then
1482                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/fbdev"
1483         fi
1484     done
1485     EGL_PLATFORMS="$egl_platforms"
1486     ;;
1487 esac
1488 AC_SUBST([EGL_PLATFORMS])
1489
1490 AC_ARG_WITH([egl-driver-dir],
1491     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1492                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1493     [EGL_DRIVER_INSTALL_DIR="$withval"],
1494     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1495 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1496
1497 AC_ARG_WITH([xorg-driver-dir],
1498     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1499                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1500     [XORG_DRIVER_INSTALL_DIR="$withval"],
1501     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1502 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1503
1504 AC_ARG_WITH([max-width],
1505     [AS_HELP_STRING([--with-max-width=N],
1506                     [Maximum framebuffer width (4096)])],
1507     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1508      AS_IF([test "${withval}" -gt "4096"],
1509            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1510 )
1511 AC_ARG_WITH([max-height],
1512     [AS_HELP_STRING([--with-max-height=N],
1513                     [Maximum framebuffer height (4096)])],
1514     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1515      AS_IF([test "${withval}" -gt "4096"],
1516            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1517 )
1518
1519 dnl
1520 dnl Gallium LLVM
1521 dnl
1522 AC_ARG_ENABLE([gallium-llvm],
1523     [AS_HELP_STRING([--enable-gallium-llvm],
1524         [build gallium LLVM support @<:@default=disabled@:>@])],
1525     [enable_gallium_llvm="$enableval"],
1526     [enable_gallium_llvm=auto])
1527 if test "x$enable_gallium_llvm" = xyes; then
1528     if test "x$LLVM_CONFIG" != xno; then
1529         LLVM_VERSION=`$LLVM_CONFIG --version`
1530         LLVM_CFLAGS=`$LLVM_CONFIG --cflags`
1531         LLVM_LIBS="`$LLVM_CONFIG --libs jit interpreter nativecodegen bitwriter` -lstdc++"
1532
1533         if test "x$HAS_UDIS86" != xno; then
1534             LLVM_LIBS="$LLVM_LIBS -ludis86"
1535             DEFINES="$DEFINES -DHAVE_UDIS86"
1536         fi
1537         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1538         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1539         DEFINES="$DEFINES -DGALLIUM_LLVMPIPE -D__STDC_CONSTANT_MACROS"
1540         MESA_LLVM=1
1541     else
1542         MESA_LLVM=0
1543     fi
1544 else
1545     MESA_LLVM=0
1546 fi
1547
1548 dnl
1549 dnl Gallium helper functions
1550 dnl
1551 gallium_check_st() {
1552     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes; then
1553          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1554     fi
1555     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1556          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1557     fi
1558     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1559          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1560     fi
1561 }
1562
1563
1564 dnl
1565 dnl Gallium SVGA configuration
1566 dnl
1567 AC_ARG_ENABLE([gallium-svga],
1568     [AS_HELP_STRING([--enable-gallium-svga],
1569         [build gallium SVGA @<:@default=disabled@:>@])],
1570     [enable_gallium_svga="$enableval"],
1571     [enable_gallium_svga=auto])
1572 if test "x$enable_gallium_svga" = xyes; then
1573     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1574     gallium_check_st "svga/drm" "dri-vmwgfx" "xorg-vmwgfx"
1575 elif test "x$enable_gallium_svga" = xauto; then
1576     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1577 fi
1578
1579 dnl
1580 dnl Gallium i915 configuration
1581 dnl
1582 AC_ARG_ENABLE([gallium-i915],
1583     [AS_HELP_STRING([--enable-gallium-i915],
1584         [build gallium i915 @<:@default=disabled@:>@])],
1585     [enable_gallium_i915="$enableval"],
1586     [enable_gallium_i915=auto])
1587 if test "x$enable_gallium_i915" = xyes; then
1588     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1589     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1590     gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1591 elif test "x$enable_gallium_i915" = xauto; then
1592     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1593     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1594 fi
1595
1596 dnl
1597 dnl Gallium i965 configuration
1598 dnl
1599 AC_ARG_ENABLE([gallium-i965],
1600     [AS_HELP_STRING([--enable-gallium-i965],
1601         [build gallium i965 @<:@default=disabled@:>@])],
1602     [enable_gallium_i965="$enableval"],
1603     [enable_gallium_i965=auto])
1604 if test "x$enable_gallium_i965" = xyes; then
1605     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i965"
1606     gallium_check_st "i965/drm" "dri-i965" "xorg-i965"
1607 elif test "x$enable_gallium_i965" = xauto; then
1608     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i965"
1609 fi
1610
1611 dnl
1612 dnl Gallium Radeon r300g configuration
1613 dnl
1614 AC_ARG_ENABLE([gallium-radeon],
1615     [AS_HELP_STRING([--enable-gallium-radeon],
1616         [build gallium radeon @<:@default=disabled@:>@])],
1617     [enable_gallium_radeon="$enableval"],
1618     [enable_gallium_radeon=auto])
1619 if test "x$enable_gallium_radeon" = xauto; then
1620     if test "x$HAVE_LIBDRM_RADEON" = xyes; then
1621         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1622         gallium_check_st "radeon/drm" "dri-r300"
1623     else
1624         AC_MSG_WARN([libdrm_radeon is missing, not building gallium-radeon (r300)])
1625     fi
1626 fi
1627 if test "x$enable_gallium_radeon" = xyes; then
1628     if test "x$HAVE_LIBDRM_RADEON" = xyes; then
1629         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1630         gallium_check_st "radeon/drm" "dri-r300" "xorg-radeon"
1631     else
1632         AC_MSG_ERROR([libdrm_radeon is missing, cannot build gallium-radeon (r300)])
1633     fi
1634 fi
1635
1636 dnl
1637 dnl Gallium Radeon r600g configuration
1638 dnl
1639 AC_ARG_ENABLE([gallium-r600],
1640     [AS_HELP_STRING([--enable-gallium-r600],
1641         [build gallium radeon @<:@default=disabled@:>@])],
1642     [enable_gallium_r600="$enableval"],
1643     [enable_gallium_r600=auto])
1644 if test "x$enable_gallium_r600" = xyes; then
1645     if test "x$HAVE_LIBDRM_RADEON" = xyes; then
1646         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1647         gallium_check_st "r600/drm" "dri-r600"
1648     else
1649         AC_MSG_ERROR([libdrm_radeon is missing, cannot build gallium-r600])
1650     fi
1651 fi
1652
1653 dnl
1654 dnl Gallium Nouveau configuration
1655 dnl
1656 AC_ARG_ENABLE([gallium-nouveau],
1657     [AS_HELP_STRING([--enable-gallium-nouveau],
1658         [build gallium nouveau @<:@default=disabled@:>@])],
1659     [enable_gallium_nouveau="$enableval"],
1660     [enable_gallium_nouveau=no])
1661 if test "x$enable_gallium_nouveau" = xyes; then
1662     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nvfx nv50"
1663     gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau"
1664 fi
1665
1666 dnl
1667 dnl Gallium swrast configuration
1668 dnl
1669 AC_ARG_ENABLE([gallium-swrast],
1670     [AS_HELP_STRING([--enable-gallium-swrast],
1671         [build gallium swrast @<:@default=auto@:>@])],
1672     [enable_gallium_swrast="$enableval"],
1673     [enable_gallium_swrast=auto])
1674 if test "x$enable_gallium_swrast" = xyes || test "x$enable_gallium_swrast" = xauto; then
1675     if test "x$HAVE_ST_DRI" = xyes; then
1676         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1677     fi
1678 fi
1679
1680 dnl prepend CORE_DIRS to SRC_DIRS
1681 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1682
1683 dnl Restore LDFLAGS and CPPFLAGS
1684 LDFLAGS="$_SAVE_LDFLAGS"
1685 CPPFLAGS="$_SAVE_CPPFLAGS"
1686
1687 dnl Substitute the config
1688 AC_CONFIG_FILES([configs/autoconf])
1689
1690 dnl Replace the configs/current symlink
1691 AC_CONFIG_COMMANDS([configs],[
1692 if test -f configs/current || test -L configs/current; then
1693     rm -f configs/current
1694 fi
1695 ln -s autoconf configs/current
1696 ])
1697
1698 AC_OUTPUT
1699
1700 dnl
1701 dnl Output some configuration info for the user
1702 dnl
1703 echo ""
1704 echo "        prefix:          $prefix"
1705 echo "        exec_prefix:     $exec_prefix"
1706 echo "        libdir:          $libdir"
1707 echo "        includedir:      $includedir"
1708
1709 dnl API info
1710 echo ""
1711 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
1712 echo "        GLES overlay:    $enable_gles_overlay"
1713 echo "        OpenVG:          $enable_openvg"
1714
1715 dnl Driver info
1716 echo ""
1717 echo "        Driver:          $mesa_driver"
1718 if test "$mesa_driver" != no; then
1719     if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1720         echo "        OSMesa:          lib$OSMESA_LIB"
1721     else
1722         echo "        OSMesa:          no"
1723     fi
1724     if test "$mesa_driver" = dri; then
1725         # cleanup the drivers var
1726         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1727         if test "x$DRI_DIRS" = x; then
1728             echo "        DRI drivers:     no"
1729         else
1730             echo "        DRI drivers:     $dri_dirs"
1731         fi
1732         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1733         echo "        Use XCB:         $enable_xcb"
1734     fi
1735 fi
1736 echo ""
1737 echo "        GLU:             $enable_glu"
1738 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1739 echo "        glut:            $enable_glut"
1740
1741 dnl EGL
1742 echo ""
1743 echo "        EGL:             $enable_egl"
1744 if test "$enable_egl" = yes; then
1745     echo "        EGL platforms:   $EGL_PLATFORMS"
1746     echo "        EGL drivers:     $EGL_DRIVERS_DIRS"
1747     if test "$enable_gallium" = yes -a "$HAVE_ST_EGL" = yes; then
1748         echo "        EGL tracker:     yes"
1749         echo "        EGL client APIs:$EGL_CLIENT_APIS"
1750     else
1751         echo "        EGL tracker:     no"
1752     fi
1753 fi
1754
1755 echo ""
1756 if test "x$MESA_LLVM" = x1; then
1757     echo "        llvm:            yes"
1758     echo "        llvm-config:     $LLVM_CONFIG"
1759     echo "        llvm-version:    $LLVM_VERSION"
1760 else
1761     echo "        llvm:            no"
1762 fi
1763
1764 echo ""
1765 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1766     echo "        Gallium:         yes"
1767     echo "        Gallium dirs:    $GALLIUM_DIRS"
1768     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
1769     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1770     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1771     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1772     if test "x$HAVE_ST_EGL" = xyes; then
1773         echo "        EGL client APIs: $EGL_CLIENT_APIS"
1774     fi
1775 else
1776     echo "        Gallium:         no"
1777 fi
1778
1779 dnl Libraries
1780 echo ""
1781 echo "        Shared libs:     $enable_shared"
1782 echo "        Static libs:     $enable_static"
1783
1784 dnl Compiler options
1785 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1786 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1787     $SED 's/^ *//;s/  */ /;s/ *$//'`
1788 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1789     $SED 's/^ *//;s/  */ /;s/ *$//'`
1790 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1791 echo ""
1792 echo "        CFLAGS:          $cflags"
1793 echo "        CXXFLAGS:        $cxxflags"
1794 echo "        Macros:          $defines"
1795 echo ""
1796 echo "        PYTHON2:         $PYTHON2"
1797
1798 echo ""
1799 echo "        Run '${MAKE-make}' to build Mesa"
1800 echo ""