configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of PulseAudio.
   7 #
   8 # Copyright 2004-2006 Lennart Poettering
   9 # Copyright 2006-2007 Pierre Ossman <ossman@cendio.se> for Cendio AB
  10 #
  11 # PulseAudio is free software; you can redistribute it and/or modify it
  12 # under the terms of the GNU Lesser General Public License as published by
  13 # the Free Software Foundation; either version 2 of the License, or
  14 # (at your option) any later version.
  15 #
  16 # PulseAudio is distributed in the hope that it will be useful, but
  17 # WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  19 # General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU Lesser General Public License
  22 # along with PulseAudio; if not, write to the Free Software Foundation,
  23 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  24
  25 AC_PREREQ(2.57)
  26
  27 m4_define(PA_MAJOR, [0])
  28 m4_define(PA_MINOR, [9])
  29 m4_define(PA_MICRO, [7])
  30
  31 AC_INIT([pulseaudio], PA_MAJOR.PA_MINOR.PA_MICRO,[mzcbylcnhqvb (at) 0pointer (dot) de])
  32 AC_CONFIG_SRCDIR([src/daemon/main.c])
  33 AC_CONFIG_HEADERS([config.h])
  34 AM_INIT_AUTOMAKE([foreign -Wall])
  35
  36 AC_SUBST(PA_MAJORMINOR, "PA_MAJOR.PA_MINOR")
  37 AC_SUBST(PACKAGE_URL, [http://0pointer.de/lennart/projects/pulseaudio/])
  38
  39 AC_SUBST(PA_API_VERSION, 10)
  40 AC_SUBST(PA_PROTOCOL_VERSION, 11)
  41
  42 AC_SUBST(LIBPULSE_VERSION_INFO, [3:0:3])
  43 AC_SUBST(LIBPULSECORE_VERSION_INFO, [4:0:0])
  44 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [0:0:0])
  45 AC_SUBST(LIBPULSE_BROWSE_VERSION_INFO, [1:0:1])
  46 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:2:0])
  47
  48 AC_CANONICAL_HOST
  49
  50 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  51    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  52    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  53 fi
  54
  55 #### Platform hacks ####
  56
  57 case $host in
  58    *-*-solaris* )
  59       AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  60       AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
  61       AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  62       ;;
  63 esac
  64
  65 #### Checks for programs. ####
  66
  67 # CC
  68
  69 AC_PROG_CC
  70 AM_PROG_CC_C_O
  71 AC_PROG_GCC_TRADITIONAL
  72 AC_GNU_SOURCE
  73
  74 # M4
  75
  76 AC_PATH_PROG([M4], [m4 gm4], [no])
  77 if test "x$M4" = xno ; then
  78    AC_MSG_ERROR([m4 missing])
  79 fi
  80
  81 # GCC flags
  82
  83 test_gcc_flag() {
  84     AC_LANG_CONFTEST([int main(int argc, char*argv[]) {}])
  85     $CC -c conftest.c $CFLAGS -o conftest.o > /dev/null 2> /dev/null
  86     ret=$?
  87     rm -f conftest.o
  88     return $ret
  89 }
  90
  91 # If using GCC specify some additional parameters
  92 if test "x$GCC" = "xyes" ; then
  93
  94     # We use gnu99 instead of c99 because many have interpreted the standard
  95     # in a way that int64_t isn't defined on non-64 bit platforms.
  96     DESIRED_FLAGS="-std=gnu99 -Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter -ffast-math"
  97
  98     for flag in $DESIRED_FLAGS ; do
  99         AC_MSG_CHECKING([whether $CC accepts $flag])
 100         if test_gcc_flag $flag ; then
 101            CFLAGS="$CFLAGS $flag"
 102            AC_MSG_RESULT([yes])
 103         else
 104            AC_MSG_RESULT([no])
 105         fi
 106     done
 107 fi
 108
 109 AC_MSG_CHECKING([whether $CC knows __sync_bool_compare_and_swap()])
 110 AC_LANG_CONFTEST([int main() { int a = 4; __sync_bool_compare_and_swap(&a, 4, 5); }])
 111 $CC conftest.c $CFLAGS -o conftest > /dev/null 2> /dev/null
 112 ret=$?
 113 rm -f conftest.o conftest
 114 if test $ret -eq 0 ; then
 115     AC_DEFINE([HAVE_ATOMIC_BUILTINS], 1, [Have __sync_bool_compare_and_swap() and friends.])
 116     AC_MSG_RESULT([yes])
 117 else
 118     AC_MSG_RESULT([no])
 119 fi
 120
 121 AC_MSG_CHECKING([whether $CC knows __thread])
 122 AC_LANG_CONFTEST([static __thread int a = 6; int main() { a = 5; }])
 123 $CC conftest.c $CFLAGS -o conftest > /dev/null 2> /dev/null
 124 ret=$?
 125 rm -f conftest.o conftest
 126 if test $ret -eq 0 ; then
 127     AC_DEFINE([HAVE_TLS_BUILTIN], 1, [Have __thread().])
 128     AC_MSG_RESULT([yes])
 129 else
 130     AC_MSG_RESULT([no])
 131 fi
 132
 133 AC_MSG_CHECKING([whether $CC knows _Bool])
 134 AC_LANG_CONFTEST([int main() { _Bool b; }])
 135 $CC conftest.c $CFLAGS -o conftest > /dev/null 2> /dev/null
 136 ret=$?
 137 rm -f conftest.o conftest
 138 if test $ret -eq 0 ; then
 139     AC_DEFINE([HAVE_STD_BOOL], 1, [Have _Bool.])
 140     AC_MSG_RESULT([yes])
 141 else
 142     AC_MSG_RESULT([no])
 143 fi
 144
 145 #### libtool stuff ####
 146
 147 AC_LTDL_ENABLE_INSTALL
 148 AC_LIBLTDL_INSTALLABLE
 149 AC_LIBTOOL_DLOPEN
 150 AC_LIBTOOL_WIN32_DLL
 151 AC_PROG_LIBTOOL
 152 AC_SUBST(LTDLINCL)
 153 AC_SUBST(LIBLTDL)
 154 AC_CONFIG_SUBDIRS(libltdl)
 155
 156 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 157     AC_MSG_ERROR([[
 158
 159         *** Cannot find the libltdl development files.
 160         *** Maybe you need to install the libltdl-dev package.
 161         ]])
 162 fi
 163
 164 #### Determine build environment ####
 165
 166 os_is_win32=0
 167
 168 case "$host_os" in
 169         mingw*)
 170         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 171         os_is_win32=1
 172                 ;;
 173         esac
 174
 175 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 176
 177 ###################################
 178 #   Basic environment checks      #
 179 ###################################
 180
 181 #### Checks for header files. ####
 182
 183 # ISO
 184 AC_HEADER_STDC
 185
 186 # POSIX
 187 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 188     netinet/in_systm.h netinet/tcp.h pwd.h sched.h \
 189     sys/mman.h sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 190     syslog.h sys/dl.h dlfcn.h])
 191 AC_CHECK_HEADERS([netinet/ip.h], [], [],
 192                  [#include <sys/types.h>
 193                   #if HAVE_NETINET_IN_H
 194                   # include <netinet/in.h>
 195                   #endif
 196                   #if HAVE_NETINET_IN_SYSTM_H
 197                   # include <netinet/in_systm.h>
 198                   #endif
 199                  ])
 200 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 201 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 202
 203 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 204 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 205
 206 # XPG4-UNIX
 207 AC_CHECK_HEADERS([sys/poll.h])
 208
 209 # Linux
 210 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 211
 212 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 213
 214 AC_CHECK_HEADERS([sys/prctl.h])
 215
 216 # Solaris
 217 AC_CHECK_HEADERS([sys/filio.h])
 218
 219 # Windows
 220 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 221
 222 # Other
 223 AC_CHECK_HEADERS([sys/ioctl.h])
 224 AC_CHECK_HEADERS([byteswap.h])
 225
 226 #### Typdefs, structures, etc. ####
 227
 228 AC_C_CONST
 229 AC_C_BIGENDIAN
 230 AC_TYPE_PID_T
 231 AC_TYPE_SIZE_T
 232 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 233     [Define ssize_t if it is not done by the standard libs.])])
 234 AC_TYPE_OFF_T
 235 AC_TYPE_SIGNAL
 236 AC_TYPE_UID_T
 237
 238 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [
 239 HAVE_SIGXCPU=1
 240 AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?])
 241 ], [HAVE_SIGXCPU=0])
 242 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 243
 244 # Solaris lacks this
 245 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 246     [AC_CHECK_DEFINE([INADDR_NONE], [winsock2.h], [],
 247         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 248
 249 #### Check for libs ####
 250
 251 # ISO
 252 AC_SEARCH_LIBS([pow], [m])
 253
 254 # POSIX
 255 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 256 AC_SEARCH_LIBS([dlopen], [dl])
 257 AC_SEARCH_LIBS([shm_open], [rt])
 258
 259 # BSD
 260 AC_SEARCH_LIBS([connect], [socket])
 261
 262 # Non-standard
 263
 264 # This magic is needed so we do not needlessly add static libs to the win32
 265 # build, disabling its ability to make dlls.
 266 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 267
 268 #### Check for functions ####
 269
 270 # ISO
 271 AC_CHECK_FUNCS([lrintf strtof])
 272
 273 # POSIX
 274 AC_FUNC_FORK
 275 AC_FUNC_GETGROUPS
 276 AC_FUNC_SELECT_ARGTYPES
 277 AC_CHECK_FUNCS([chmod chown getaddrinfo getgrgid_r getpwuid_r gettimeofday \
 278     getuid inet_ntop inet_pton nanosleep pipe posix_fadvise posix_madvise \
 279     posix_memalign setpgid setsid shm_open sigaction sleep sysconf])
 280 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 281
 282 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 283
 284 # X/OPEN
 285 AC_CHECK_FUNCS([readlink])
 286
 287 # SUSv2
 288 AC_CHECK_FUNCS([ctime_r usleep])
 289
 290 # SUSv3
 291 AC_CHECK_FUNCS([strerror_r])
 292
 293 # BSD
 294 AC_CHECK_FUNCS([lstat])
 295
 296 # Non-standard
 297
 298 AC_CHECK_FUNCS([setresuid setresgid setreuid setregid seteuid setegid ppoll strsignal sig2str strtof_l])
 299
 300 #### POSIX threads ####
 301
 302 ACX_PTHREAD
 303
 304 AC_MSG_CHECKING([for PTHREAD_PRIO_INHERIT])
 305 AC_LANG_CONFTEST([AC_LANG_SOURCE([[
 306 #include <pthread.h>
 307 int main() { int i = PTHREAD_PRIO_INHERIT; }]])])
 308 $PTHREAD_CC conftest.c $PTHREAD_CFLAGS $CFLAGS $PTHREAD_LIBS -o conftest > /dev/null 2> /dev/null
 309 ret=$?
 310 rm -f conftest.o conftest
 311
 312 if test $ret -eq 0 ; then
 313     AC_DEFINE([HAVE_PTHREAD_PRIO_INHERIT], 1, [Have PTHREAD_PRIO_INHERIT.])
 314     AC_MSG_RESULT([yes])
 315 else
 316     AC_MSG_RESULT([no])
 317 fi
 318
 319
 320 #### Large File-Support (LFS) ####
 321
 322 AC_SYS_LARGEFILE
 323
 324 # Check for open64 to know if the current system does have open64() and similar functions
 325 AC_CHECK_FUNCS([open64])
 326
 327 #### [lib]iconv ####
 328
 329 AM_ICONV
 330
 331 ###################################
 332 #      External libraries         #
 333 ###################################
 334
 335 #### X11 (optional) ####
 336
 337 HAVE_X11=0
 338
 339 # The macro tests the host, not the build target
 340 if test "x$os_is_win32" != "x1" ; then
 341     AC_PATH_XTRA
 342     test "x$no_x" != "xyes" && HAVE_X11=1
 343 fi
 344
 345 AC_SUBST(HAVE_X11)
 346 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 347 if test "x$HAVE_X11" = "x1" ; then
 348     AC_DEFINE([HAVE_X11], 1, [Have X11])
 349 fi
 350
 351 #### Capabilities (optional) ####
 352
 353 CAP_LIBS=''
 354
 355 AC_ARG_WITH(
 356         [caps],
 357         AC_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 358
 359 if test "x${with_caps}" != "xno"; then
 360     AC_SEARCH_LIBS([cap_init], [cap], [], [
 361                     if test "x${with_caps}" = "xyes" ; then
 362                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 363                     fi])
 364     AC_CHECK_HEADERS([sys/capability.h], [], [
 365                     if test "x${with_caps}" = "xyes" ; then
 366                         AC_MSG_ERROR([*** POSIX caps headers not found])
 367                     fi])
 368 fi
 369
 370 #### pkg-config ####
 371
 372 # Check for pkg-config manually first, as if its not installed the
 373 # PKG_PROG_PKG_CONFIG macro won't be defined.
 374 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 375
 376 if test x"$have_pkg_config" = "xno"; then
 377     AC_MSG_ERROR(pkg-config is required to install this program)
 378 fi
 379
 380 PKG_PROG_PKG_CONFIG
 381
 382 #### Sound file ####
 383
 384 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 385 AC_SUBST(LIBSNDFILE_CFLAGS)
 386 AC_SUBST(LIBSNDFILE_LIBS)
 387
 388 #### atomic-ops ###
 389
 390 AC_CHECK_HEADERS([atomic_ops.h], [], [
 391 AC_MSG_ERROR([*** libatomic-ops headers not found])
 392 ])
 393
 394 # Win32 does not need the lib and breaks horribly if we try to include it
 395 if test "x$os_is_win32" != "x1" ; then
 396     LIBS="$LIBS -latomic_ops"
 397 fi
 398
 399 #### Libsamplerate support (optional) ####
 400
 401 AC_ARG_ENABLE([samplerate],
 402     AC_HELP_STRING([--disable-samplerate], [Disable optional libsamplerate support]),
 403         [
 404             case "${enableval}" in
 405                 yes) samplerate=yes ;;
 406                 no) samplerate=no ;;
 407                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-samplerate) ;;
 408             esac
 409         ],
 410         [samplerate=auto])
 411
 412 if test "x${samplerate}" != xno ; then
 413     PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ],
 414         HAVE_LIBSAMPLERATE=1,
 415         [
 416             HAVE_LIBSAMPLERATE=0
 417             if test "x$samplerate" = xyes ; then
 418                 AC_MSG_ERROR([*** Libsamplerate not found])
 419             fi
 420         ])
 421 else
 422     HAVE_LIBSAMPLERATE=0
 423 fi
 424
 425 if test "x${HAVE_LIBSAMPLERATE}" = x1 ; then
 426    AC_DEFINE([HAVE_LIBSAMPLERATE], 1, [Have libsamplerate?])
 427 fi
 428
 429 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 430 AC_SUBST(LIBSAMPLERATE_LIBS)
 431 AC_SUBST(HAVE_LIBSAMPLERATE)
 432 AM_CONDITIONAL([HAVE_LIBSAMPLERATE], [test "x$HAVE_LIBSAMPLERATE" = x1])
 433
 434 #### OSS support (optional) ####
 435
 436 AC_ARG_ENABLE([oss],
 437     AC_HELP_STRING([--disable-oss], [Disable optional OSS support]),
 438         [
 439             case "${enableval}" in
 440                 yes) oss=yes ;;
 441                 no) oss=no ;;
 442                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-oss) ;;
 443             esac
 444         ],
 445         [oss=auto])
 446
 447 if test "x${oss}" != xno ; then
 448     AC_CHECK_HEADERS([sys/soundcard.h],
 449         [
 450             HAVE_OSS=1
 451             AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 452         ],
 453         [
 454             HAVE_OSS=0
 455             if test "x$oss" = xyes ; then
 456                 AC_MSG_ERROR([*** OSS support not found])
 457             fi
 458         ])
 459 else
 460     HAVE_OSS=0
 461 fi
 462
 463 AC_SUBST(HAVE_OSS)
 464 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 465
 466
 467 #### ALSA support (optional) ####
 468
 469 AC_ARG_ENABLE([alsa],
 470     AC_HELP_STRING([--disable-alsa], [Disable optional ALSA support]),
 471         [
 472             case "${enableval}" in
 473                 yes) alsa=yes ;;
 474                 no) alsa=no ;;
 475                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-alsa) ;;
 476             esac
 477         ],
 478         [alsa=auto])
 479
 480 if test "x${alsa}" != xno ; then
 481     PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.0 ],
 482         [
 483             HAVE_ALSA=1
 484             AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 485         ],
 486         [
 487             HAVE_ALSA=0
 488             if test "x$alsa" = xyes ; then
 489                 AC_MSG_ERROR([*** ALSA support not found])
 490             fi
 491         ])
 492 else
 493     HAVE_ALSA=0
 494 fi
 495
 496 AC_SUBST(ASOUNDLIB_CFLAGS)
 497 AC_SUBST(ASOUNDLIB_LIBS)
 498 AC_SUBST(HAVE_ALSA)
 499 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 500
 501 #### Solaris audio support (optional) ####
 502
 503 AC_ARG_ENABLE([solaris],
 504     AC_HELP_STRING([--disable-solaris], [Disable optional Solaris audio support]),
 505         [
 506             case "${enableval}" in
 507                 yes) solaris=yes ;;
 508                 no) solaris=no ;;
 509                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-solaris) ;;
 510             esac
 511         ],
 512         [solaris=auto])
 513
 514 if test "x${solaris}" != xno ; then
 515     AC_CHECK_HEADERS([sys/audio.h],
 516         [
 517             HAVE_SOLARIS=1
 518             AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 519         ],
 520         [
 521             HAVE_SOLARIS=0
 522             if test "x$solaris" = xyes ; then
 523                 AC_MSG_ERROR([*** Solaris audio support not found])
 524             fi
 525         ])
 526 else
 527     HAVE_SOLARIS=0
 528 fi
 529
 530 AC_SUBST(HAVE_SOLARIS)
 531 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 532
 533 #### GLib 2 support (optional) ####
 534
 535 AC_ARG_ENABLE([glib2],
 536     AC_HELP_STRING([--disable-glib2], [Disable optional GLib 2 support]),
 537         [
 538             case "${enableval}" in
 539                 yes) glib2=yes ;;
 540                 no) glib2=no ;;
 541                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib2) ;;
 542             esac
 543         ],
 544         [glib2=auto])
 545
 546 if test "x${glib2}" != xno ; then
 547     PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ],
 548         HAVE_GLIB20=1,
 549         [
 550             HAVE_GLIB20=0
 551             if test "x$glib2" = xyes ; then
 552                 AC_MSG_ERROR([*** GLib 2 support not found])
 553             fi
 554         ])
 555 else
 556     HAVE_GLIB20=0
 557 fi
 558
 559 AC_SUBST(GLIB20_CFLAGS)
 560 AC_SUBST(GLIB20_LIBS)
 561 AC_SUBST(HAVE_GLIB20)
 562 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 563
 564 #### GConf support (optional) ####
 565
 566 AC_ARG_ENABLE([gconf],
 567     AC_HELP_STRING([--disable-gconf], [Disable optional GConf support]),
 568         [
 569             case "${enableval}" in
 570                 yes) gconf=yes ;;
 571                 no) gconf=no ;;
 572                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-gconf) ;;
 573             esac
 574         ],
 575         [glib=auto])
 576
 577 if test "x${gconf}" != xno ; then
 578     PKG_CHECK_MODULES(GCONF, [ gconf-2.0 >= 2.4.0 ],
 579         HAVE_GCONF=1,
 580         [
 581             HAVE_GCONF=0
 582             if test "x$gconf" = xyes ; then
 583                 AC_MSG_ERROR([*** GConf support not found])
 584             fi
 585         ])
 586 else
 587     HAVE_GCONF=0
 588 fi
 589
 590 AC_SUBST(GCONF_CFLAGS)
 591 AC_SUBST(GCONF_LIBS)
 592 AC_SUBST(HAVE_GCONF)
 593 AM_CONDITIONAL([HAVE_GCONF], [test "x$HAVE_GCONF" = x1])
 594
 595 #### Avahi support (optional) ####
 596
 597 AC_ARG_ENABLE([avahi],
 598     AC_HELP_STRING([--disable-avahi], [Disable optional Avahi support]),
 599         [
 600             case "${enableval}" in
 601                 yes) avahi=yes ;;
 602                 no) avahi=no ;;
 603                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-avahi) ;;
 604             esac
 605         ],
 606         [avahi=auto])
 607
 608 if test "x${avahi}" != xno ; then
 609     PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ],
 610         HAVE_AVAHI=1,
 611         [
 612                 HAVE_AVAHI=0
 613                 if test "x$avahi" = xyes ; then
 614                         AC_MSG_ERROR([*** Avahi support not found])
 615                 fi
 616         ])
 617 else
 618     HAVE_AVAHI=0
 619 fi
 620
 621 AC_SUBST(AVAHI_CFLAGS)
 622 AC_SUBST(AVAHI_LIBS)
 623 AC_SUBST(HAVE_AVAHI)
 624 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
 625
 626 ### LIBOIL ####
 627
 628 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 629 AC_SUBST(LIBOIL_CFLAGS)
 630 AC_SUBST(LIBOIL_LIBS)
 631
 632 ### JACK (optional) ####
 633
 634 AC_ARG_ENABLE([jack],
 635     AC_HELP_STRING([--disable-jack], [Disable optional JACK support]),
 636         [
 637             case "${enableval}" in
 638                 yes) jack=yes ;;
 639                 no) jack=no ;;
 640                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-jack) ;;
 641             esac
 642         ],
 643         [jack=auto])
 644
 645 if test "x${jack}" != xno ; then
 646     PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ],
 647         HAVE_JACK=1,
 648         [
 649             HAVE_JACK=0
 650             if test "x$jack" = xyes ; then
 651                 AC_MSG_ERROR([*** JACK support not found])
 652             fi
 653         ])
 654 else
 655     HAVE_JACK=0
 656 fi
 657
 658 AC_SUBST(JACK_CFLAGS)
 659 AC_SUBST(JACK_LIBS)
 660 AC_SUBST(HAVE_JACK)
 661 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 662
 663 #### Async DNS support (optional) ####
 664
 665 AC_ARG_ENABLE([asyncns],
 666     AC_HELP_STRING([--disable-asyncns], [Disable optional Async DNS support]),
 667         [
 668             case "${enableval}" in
 669                 yes) asyncns=yes ;;
 670                 no) asyncns=no ;;
 671                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-asyncns) ;;
 672             esac
 673         ],
 674         [asyncns=auto])
 675
 676 if test "x${asyncns}" != xno ; then
 677     PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ],
 678         HAVE_LIBASYNCNS=1,
 679         [
 680             HAVE_LIBASYNCNS=0
 681             if test "x$asyncns" = xyes ; then
 682                 AC_MSG_ERROR([*** Async DNS support not found])
 683             fi
 684         ])
 685 else
 686     HAVE_LIBASYNCNS=0
 687 fi
 688
 689 AC_SUBST(LIBASYNCNS_CFLAGS)
 690 AC_SUBST(LIBASYNCNS_LIBS)
 691 AC_SUBST(HAVE_LIBASYNCNS)
 692 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 693
 694 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 695    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 696 fi
 697
 698 #### TCP wrappers (optional) ####
 699
 700 AC_ARG_ENABLE([tcpwrap],
 701     AC_HELP_STRING([--disable-tcpwrap], [Disable optional TCP wrappers support]),
 702         [
 703             case "${enableval}" in
 704                 yes) tcpwrap=yes ;;
 705                 no) tcpwrap=no ;;
 706                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 707             esac
 708         ],
 709         [tcpwrap=auto])
 710
 711 if test "x${tcpwrap}" != xno ; then
 712     ACX_LIBWRAP
 713     if test "x${LIBWRAP_LIBS}" = x && test "x$tcpwrap" = xyes ; then
 714         AC_MSG_ERROR([*** TCP wrappers support not found])
 715     fi
 716 else
 717     LIBWRAP_LIBS=
 718 fi
 719
 720 AC_SUBST(LIBWRAP_LIBS)
 721
 722 #### LIRC support (optional) ####
 723
 724 AC_ARG_ENABLE([lirc],
 725     AC_HELP_STRING([--disable-lirc], [Disable optional LIRC support]),
 726         [
 727             case "${enableval}" in
 728                 yes) lirc=yes ;;
 729                 no) lirc=no ;;
 730                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-lirc) ;;
 731             esac
 732         ],
 733         [lirc=auto])
 734
 735 if test "x${lirc}" != xno ; then
 736     ACX_LIRC
 737     if test "x${HAVE_LIRC}" = x0 && test "x$lirc" = xyes ; then
 738         AC_MSG_ERROR([*** LIRC support not found])
 739     fi
 740 else
 741     HAVE_LIRC=0
 742 fi
 743
 744 AC_SUBST(LIRC_CFLAGS)
 745 AC_SUBST(LIRC_LIBS)
 746 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 747
 748 #### HAL support (optional) ####
 749
 750 AC_ARG_ENABLE([hal],
 751     AC_HELP_STRING([--disable-hal], [Disable optional HAL support]),
 752         [
 753             case "${enableval}" in
 754                 yes) hal=yes ;;
 755                 no) hal=no ;;
 756                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-hal) ;;
 757             esac
 758         ],
 759         [hal=auto])
 760 if test "x${hal}" != xno -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \) ; then
 761     PKG_CHECK_MODULES(HAL, [ hal >= 0.5.7 ],
 762         HAVE_HAL=1,
 763         [
 764             HAVE_HAL=0
 765             if test "x$hal" = xyes ; then
 766                 AC_MSG_ERROR([*** HAL support not found])
 767             fi
 768         ])
 769 else
 770     HAVE_HAL=0
 771 fi
 772
 773 AC_SUBST(HAL_CFLAGS)
 774 AC_SUBST(HAL_LIBS)
 775 AC_SUBST(HAVE_HAL)
 776 AM_CONDITIONAL([HAVE_HAL], [test "x$HAVE_HAL" = x1])
 777
 778 #### D-Bus support (optional) ####
 779
 780 AC_ARG_ENABLE([dbus],
 781     AC_HELP_STRING([--disable-dbus], [Disable optional D-Bus support]),
 782         [
 783             case "${enableval}" in
 784                 yes) dbus=yes ;;
 785                 no) dbus=no ;;
 786                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-dbus) ;;
 787             esac
 788         ],
 789         [dbus=auto])
 790
 791 if test "x$HAVE_HAL" = x1 ; then
 792    dbus=yes
 793 fi
 794
 795 if test "x${dbus}" != xno ; then
 796
 797     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.0.0 ],
 798         [
 799             HAVE_DBUS=1
 800             saved_LIBS="$LIBS"
 801             LIBS="$LIBS $DBUS_LIBS"
 802             AC_CHECK_FUNCS(dbus_watch_get_unix_fd)
 803             LIBS="$saved_LIBS"
 804             AC_DEFINE([HAVE_DBUS], 1, [Have D-Bus.])
 805         ],
 806         [
 807             HAVE_DBUS=0
 808             if test "x$dbus" = xyes ; then
 809                 AC_MSG_ERROR([*** D-Bus support not found])
 810             fi
 811         ])
 812 else
 813     HAVE_DBUS=0
 814 fi
 815
 816 AC_SUBST(DBUS_CFLAGS)
 817 AC_SUBST(DBUS_LIBS)
 818 AC_SUBST(HAVE_DBUS)
 819 AM_CONDITIONAL([HAVE_DBUS], [test "x$HAVE_DBUS" = x1])
 820
 821 #### PulseAudio system group & user  #####
 822
 823 AC_ARG_WITH(system_user, AS_HELP_STRING([--with-system-user=<user>],[User for running the PulseAudio daemon as a system-wide instance (pulse)]))
 824 if test -z "$with_system_user" ; then
 825     PA_SYSTEM_USER=pulse
 826 else
 827     PA_SYSTEM_USER=$with_system_user
 828 fi
 829 AC_SUBST(PA_SYSTEM_USER)
 830 AC_DEFINE_UNQUOTED(PA_SYSTEM_USER,"$PA_SYSTEM_USER", [User for running the PulseAudio system daemon])
 831
 832 AC_ARG_WITH(system_group,AS_HELP_STRING([--with-system-group=<group>],[Group for running the PulseAudio daemon as a system-wide instance (pulse)]))
 833 if test -z "$with_system_group" ; then
 834     PA_SYSTEM_GROUP=pulse
 835 else
 836     PA_SYSTEM_GROUP=$with_system_group
 837 fi
 838 AC_SUBST(PA_SYSTEM_GROUP)
 839 AC_DEFINE_UNQUOTED(PA_SYSTEM_GROUP,"$PA_SYSTEM_GROUP", [Group for the PulseAudio system daemon])
 840
 841 AC_ARG_WITH(realtime_group,AS_HELP_STRING([--with-realtime-group=<group>],[Group for users that are allowed to start the PulseAudio daemon with realtime scheduling (realtime)]))
 842 if test -z "$with_realtime_group" ; then
 843     PA_REALTIME_GROUP=pulse-rt
 844 else
 845     PA_REALTIME_GROUP=$with_realtime_group
 846 fi
 847 AC_SUBST(PA_REALTIME_GROUP)
 848 AC_DEFINE_UNQUOTED(PA_REALTIME_GROUP,"$PA_REALTIME_GROUP", [Realtime group])
 849
 850 AC_ARG_WITH(access_group,AS_HELP_STRING([--with-access-group=<group>],[Group which is allowed access to a system-wide PulseAudio daemon (pulse-access)]))
 851 if test -z "$with_access_group" ; then
 852     PA_ACCESS_GROUP=pulse-access
 853 else
 854     PA_ACCESS_GROUP=$with_access_group
 855 fi
 856 AC_SUBST(PA_ACCESS_GROUP)
 857 AC_DEFINE_UNQUOTED(PA_ACCESS_GROUP,"$PA_ACCESS_GROUP", [Access group])
 858
 859 #### PulseAudio system runtime dir ####
 860 PA_SYSTEM_RUNTIME_PATH="${localstatedir}/run/pulse"
 861 AC_SUBST(PA_SYSTEM_RUNTIME_PATH)
 862
 863 ###################################
 864 #            Output               #
 865 ###################################
 866
 867 AC_ARG_ENABLE(
 868         [static-bins],
 869         AC_HELP_STRING([--enable-static-bins],[Statically link executables.]),
 870         [STATIC_BINS=1], [STATIC_BINS=0])
 871 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
 872
 873 AC_ARG_WITH(
 874         [preopen-mods],
 875         AC_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
 876         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
 877 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
 878 if test "x$PREOPEN_MODS" != "xall" ; then
 879     tmpLIBS=""
 880     for mod in $PREOPEN_MODS; do
 881         tmpLIBS="$tmpLIBS module-$mod.la"
 882     done
 883     PREOPEN_MODS="$tmpLIBS"
 884     AC_SUBST(PREOPEN_MODS)
 885 fi
 886
 887 AC_ARG_WITH(
 888         [module-dir],
 889         AC_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINOR}/modules/]),
 890         [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINOR}/modules/"])
 891
 892 AC_SUBST(modlibexecdir)
 893
 894 AC_ARG_ENABLE(
 895         [force-preopen],
 896         AC_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]),
 897         [FORCE_PREOPEN=1], [FORCE_PREOPEN=0])
 898 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "x1"])
 899
 900 AC_CONFIG_FILES([
 901 Makefile
 902 src/Makefile
 903 libpulse.pc
 904 libpulse-simple.pc
 905 libpulse-browse.pc
 906 libpulse-mainloop-glib.pc
 907 doxygen/Makefile
 908 doxygen/doxygen.conf
 909 src/pulse/version.h
 910 ])
 911 AC_OUTPUT
 912
 913 # ==========================================================================
 914 ENABLE_X11=no
 915 if test "x$HAVE_X11" = "x1" ; then
 916    ENABLE_X11=yes
 917 fi
 918
 919 ENABLE_OSS=no
 920 if test "x$HAVE_OSS" = "x1" ; then
 921    ENABLE_OSS=yes
 922 fi
 923
 924 ENABLE_ALSA=no
 925 if test "x$HAVE_ALSA" = "x1" ; then
 926    ENABLE_ALSA=yes
 927 fi
 928
 929 ENABLE_SOLARIS=no
 930 if test "x$HAVE_SOLARIS" = "x1" ; then
 931    ENABLE_SOLARIS=yes
 932 fi
 933
 934 ENABLE_GLIB20=no
 935 if test "x$HAVE_GLIB20" = "x1" ; then
 936    ENABLE_GLIB20=yes
 937 fi
 938
 939 ENABLE_GCONF=no
 940 if test "x$HAVE_GCONF" = "x1" ; then
 941    ENABLE_GCONF=yes
 942 fi
 943
 944 ENABLE_AVAHI=no
 945 if test "x$HAVE_AVAHI" = "x1" ; then
 946    ENABLE_AVAHI=yes
 947 fi
 948
 949 ENABLE_JACK=no
 950 if test "x$HAVE_JACK" = "x1" ; then
 951    ENABLE_JACK=yes
 952 fi
 953
 954 ENABLE_LIBASYNCNS=no
 955 if test "x$HAVE_LIBASYNCNS" = "x1" ; then
 956    ENABLE_LIBASYNCNS=yes
 957 fi
 958
 959 ENABLE_LIRC=no
 960 if test "x$HAVE_LIRC" = "x1" ; then
 961    ENABLE_LIRC=yes
 962 fi
 963
 964 ENABLE_HAL=no
 965 if test "x$HAVE_HAL" = "x1" ; then
 966    ENABLE_HAL=yes
 967 fi
 968
 969 ENABLE_TCPWRAP=no
 970 if test "x${LIBWRAP_LIBS}" != x ; then
 971    ENABLE_TCPWRAP=yes
 972 fi
 973
 974 ENABLE_LIBSAMPLERATE=no
 975 if test "x${HAVE_LIBSAMPLERATE}" = "x1" ; then
 976    ENABLE_LIBSAMPLERATE=yes
 977 fi
 978
 979 echo "
 980  ---{ $PACKAGE_NAME $VERSION }---
 981
 982     prefix:                 ${prefix}
 983     sysconfdir:             ${sysconfdir}
 984     localstatedir:          ${localstatedir}
 985     System Runtime Path:    ${PA_SYSTEM_RUNTIME_PATH}
 986     Compiler:               ${CC}
 987     CFLAGS:                 ${CFLAGS}
 988     Have X11:               ${ENABLE_X11}
 989     Enable OSS:             ${ENABLE_OSS}
 990     Enable Alsa:            ${ENABLE_ALSA}
 991     Enable Solaris:         ${ENABLE_SOLARIS}
 992     Enable GLib 2.0:        ${ENABLE_GLIB20}
 993     Enable GConf:           ${ENABLE_GCONF}
 994     Enable Avahi:           ${ENABLE_AVAHI}
 995     Enable Jack:            ${ENABLE_JACK}
 996     Enable Async DNS:       ${ENABLE_LIBASYNCNS}
 997     Enable LIRC:            ${ENABLE_LIRC}
 998     Enable HAL:             ${ENABLE_HAL}
 999     Enable TCP Wrappers:    ${ENABLE_TCPWRAP}
1000     Enable libsamplerate:   ${ENABLE_LIBSAMPLERATE}
1001     System User:            ${PA_SYSTEM_USER}
1002     System Group:           ${PA_SYSTEM_GROUP}
1003     Realtime Group:         ${PA_REALTIME_GROUP}
1004     Access Group:           ${PA_ACCESS_GROUP}
1005 "