configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # in easier to understand terms:
  24 #
  25 # <mclasen> on the stable branch, interface age == micro
  26 # <mclasen> on the unstable (ie master), interface age = 0
  27
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [29])
  30 m4_define([glib_micro_version], [90])
  31 m4_define([glib_interface_age], [0])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_HEADER([config.h])
  56 AC_CONFIG_SRCDIR([glib/glib.h])
  57 AC_CONFIG_MACRO_DIR([m4macros])
  58
  59 # Save this value here, since automake will set cflags later
  60 cflags_set=${CFLAGS+set}
  61
  62 AM_INIT_AUTOMAKE([1.11 no-define no-dist-gzip dist-xz tar-ustar])
  63 AM_MAINTAINER_MODE([enable])
  64
  65 # Support silent build rules. Disable
  66 # by either passing --disable-silent-rules to configure or passing V=1
  67 # to make
  68 AM_SILENT_RULES([yes])
  69
  70 GLIB_MAJOR_VERSION=glib_major_version
  71 GLIB_MINOR_VERSION=glib_minor_version
  72 GLIB_MICRO_VERSION=glib_micro_version
  73 GLIB_INTERFACE_AGE=glib_interface_age
  74 GLIB_BINARY_AGE=glib_binary_age
  75 GLIB_VERSION=glib_version
  76
  77 AC_SUBST(GLIB_MAJOR_VERSION)
  78 AC_SUBST(GLIB_MINOR_VERSION)
  79 AC_SUBST(GLIB_MICRO_VERSION)
  80 AC_SUBST(GLIB_VERSION)
  81 AC_SUBST(GLIB_INTERFACE_AGE)
  82 AC_SUBST(GLIB_BINARY_AGE)
  83
  84 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  85           [Define to the GLIB major version])
  86 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  87           [Define to the GLIB minor version])
  88 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  89           [Define to the GLIB micro version])
  90 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  91           [Define to the GLIB interface age])
  92 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  93           [Define to the GLIB binary age])
  94
  95 # libtool versioning
  96 LT_RELEASE=glib_lt_release
  97 LT_CURRENT=glib_lt_current
  98 LT_REVISION=glib_lt_revision
  99 LT_AGE=glib_lt_age
 100 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 101 AC_SUBST(LT_RELEASE)
 102 AC_SUBST(LT_CURRENT)
 103 AC_SUBST(LT_REVISION)
 104 AC_SUBST(LT_AGE)
 105 AC_SUBST(LT_CURRENT_MINUS_AGE)
 106
 107 dnl Checks for programs.
 108 AC_PROG_CC
 109 AC_PROG_CPP
 110
 111 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 112
 113 AC_CANONICAL_HOST
 114
 115 AC_MSG_CHECKING([for the BeOS])
 116 case $host in
 117   *-*-beos*)
 118     glib_native_beos="yes"
 119     ;;
 120   *)
 121     glib_native_beos="no"
 122     ;;
 123 esac
 124 AC_MSG_RESULT([$glib_native_beos])
 125
 126 dnl
 127
 128 AC_MSG_CHECKING([for Win32])
 129 LIB_EXE_MACHINE_FLAG=X86
 130 case "$host" in
 131   *-*-mingw*)
 132     glib_native_win32=yes
 133     glib_pid_type='void *'
 134     glib_cv_stack_grows=no
 135     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 136     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 137     # (Sorry, I don't know exactly what is the problem, but it is related to
 138     # floating point formatting and decimal point vs. comma.)
 139     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 140     # rigorous enough to notice, though.
 141     # So preset the autoconf cache variables.
 142     ac_cv_func_vsnprintf_c99=no
 143     ac_cv_func_snprintf_c99=no
 144     case "$host" in
 145     x86_64-*-*)
 146       LIB_EXE_MACHINE_FLAG=X64
 147       ;;
 148     esac
 149     ;;
 150   *)
 151     glib_native_win32=no
 152     glib_pid_type=int
 153     ;;
 154 esac
 155 case $host in
 156   *-*-linux*)
 157     glib_os_linux=yes
 158     ;;
 159 esac
 160
 161 AC_MSG_RESULT([$glib_native_win32])
 162
 163 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 164
 165 glib_have_carbon=no
 166 AC_MSG_CHECKING([for Mac OS X Carbon support])
 167 AC_TRY_CPP([
 168 #include <Carbon/Carbon.h>
 169 #include <CoreServices/CoreServices.h>
 170 ], glib_have_carbon=yes)
 171
 172 AC_MSG_RESULT([$glib_have_carbon])
 173
 174 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 175 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 176 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 177 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 178 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 179
 180 if test "$glib_native_win32" = "yes"; then
 181   AC_CHECK_TOOL(WINDRES, windres, no)
 182   if test "$WINDRES" = no; then
 183     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 184   fi
 185   AC_CHECK_TOOL(NM, nm, no)
 186   if test "$NM" = no; then
 187     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 188   fi
 189   AC_CHECK_TOOL(RANLIB, ranlib, :)
 190   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 191 fi
 192 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 193
 194 if test "$glib_native_win32" != yes; then
 195     # libtool option to control which symbols are exported
 196     # right now, symbols starting with _ are not exported
 197     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 198 else
 199     # We currently use .def files on Windows
 200     LIBTOOL_EXPORT_OPTIONS=
 201 fi
 202 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 203
 204 if test "x$glib_have_carbon" = "xyes"; then
 205   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 206   LDFLAGS="$LDFLAGS -framework Carbon"
 207 fi
 208
 209 gl_GLIBC21
 210 if test "x$GLIBC21" = "xyes"; then
 211   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 212 fi
 213
 214 dnl declare --enable-* args and collect ac_help strings
 215 AC_ARG_ENABLE(debug,
 216               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 217                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 218               enable_debug=glib_debug_default)
 219
 220 AC_ARG_ENABLE(gc_friendly,
 221               [AC_HELP_STRING([--enable-gc-friendly],
 222                               [turn on garbage collector friendliness [default=no]])],,
 223               [enable_gc_friendly=no])
 224 AC_ARG_ENABLE(mem_pools,
 225               [AC_HELP_STRING([--disable-mem-pools],
 226                               [disable all glib memory pools])],,
 227               [disable_mem_pools=no])
 228 AC_ARG_ENABLE(threads,
 229               [AC_HELP_STRING([--enable-threads],
 230                               [turn on basic thread support [default=yes]
 231 ([=no] will override --with-threads)])],,
 232               [enable_threads=yes])
 233 AC_ARG_ENABLE(rebuilds,
 234               [AC_HELP_STRING([--disable-rebuilds],
 235                               [disable all source autogeneration rules])],,
 236               [enable_rebuilds=yes])
 237
 238 if test "x$enable_threads" != "xyes"; then
 239   enable_threads=no
 240 fi
 241
 242 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 243 if test "x$enable_gc_friendly" = "xyes"; then
 244   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 245   AC_MSG_RESULT([yes])
 246 else
 247   AC_MSG_RESULT([no])
 248 fi
 249
 250 AC_MSG_CHECKING([whether to disable memory pools])
 251 if test "x$disable_mem_pools" = "xno"; then
 252   AC_MSG_RESULT([no])
 253 else
 254   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 255   AC_SUBST(DISABLE_MEM_POOLS)
 256   AC_MSG_RESULT([yes])
 257 fi
 258
 259 dnl location to install runtime libraries, e.g. ../../lib to install
 260 dnl to /lib if libdir is /usr/lib
 261 AC_ARG_WITH(runtime-libdir,
 262            [AC_HELP_STRING([--with-runtime-libdir=RELPATH],
 263                            [Install runtime libraries relative to libdir])],
 264            [],
 265            [with_runtime_libdir=""])
 266 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 267 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 268 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 269 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 270 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 271
 272 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 273 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 274 AC_LANG_SAVE
 275 AC_LANG_CPLUSPLUS
 276 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 277 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 278 AC_LANG_RESTORE
 279
 280 AM_PROG_CC_STDC
 281 AM_PROG_CC_C_O
 282 AC_PROG_INSTALL
 283
 284 AC_SYS_LARGEFILE
 285
 286 PKG_PROG_PKG_CONFIG(0.16)
 287
 288 if test "x$enable_debug" = "xyes"; then
 289   if test x$cflags_set != xset ; then
 290       case " $CFLAGS " in
 291       *[[\ \    ]]-g[[\ \       ]]*) ;;
 292       *) CFLAGS="$CFLAGS -g" ;;
 293       esac
 294   fi
 295
 296   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 297 else
 298   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 299
 300   if test "x$enable_debug" = "xno"; then
 301     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 302   fi
 303 fi
 304
 305 # Ensure MSVC-compatible struct packing convention is used when
 306 # compiling for Win32 with gcc.
 307 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 308 # gcc2 uses "-fnative-struct".
 309 if test x"$glib_native_win32" = xyes; then
 310   if test x"$GCC" = xyes; then
 311     msnative_struct=''
 312     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 313     if test -z "$ac_cv_prog_CC"; then
 314       our_gcc="$CC"
 315     else
 316       our_gcc="$ac_cv_prog_CC"
 317     fi
 318     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 319       2.)
 320         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 321           msnative_struct='-fnative-struct'
 322         fi
 323         ;;
 324       *)
 325         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 326           msnative_struct='-mms-bitfields'
 327         fi
 328         ;;
 329     esac
 330     if test x"$msnative_struct" = x ; then
 331       AC_MSG_RESULT([no way])
 332       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 333     else
 334       CFLAGS="$CFLAGS $msnative_struct"
 335       AC_MSG_RESULT([${msnative_struct}])
 336     fi
 337   fi
 338 fi
 339 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 340 AC_SUBST(GLIB_EXTRA_CFLAGS)
 341
 342 AC_EXEEXT
 343
 344 # define a MAINT-like variable REBUILD which is set if Perl
 345 # and awk are found, so autogenerated sources can be rebuilt
 346 AC_PROG_AWK
 347 AC_CHECK_PROGS(PERL, [perl5 perl])
 348 # We would like indent, but don't require it.
 349 AC_CHECK_PROG(INDENT, indent, indent)
 350 REBUILD=\#
 351 if test "x$enable_rebuilds" = "xyes" && \
 352      test -n "$PERL" && \
 353      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 354      test -n "$AWK" ; then
 355   REBUILD=
 356 fi
 357 AC_SUBST(REBUILD)
 358
 359 # Need full path to Perl for glib-mkenums
 360 #
 361 if test "x$PERL" != x ; then
 362   AC_PATH_PROG(PERL_PATH, [$PERL])
 363 fi
 364 if test "x$PERL_PATH" = x ; then
 365   PERL_PATH="/usr/bin/env perl"
 366 fi
 367 AC_SUBST(PERL_PATH)
 368
 369 # Need suitable python path for greport
 370 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 371
 372
 373 dnl ***********************
 374 dnl *** Tests for iconv ***
 375 dnl ***********************
 376 dnl
 377 dnl We do this before the gettext checks, to avoid distortion
 378
 379 dnl On Windows we use a native implementation
 380
 381 if test x"$glib_native_win32" = xyes; then
 382   with_libiconv=native
 383 else
 384   AC_ARG_WITH(libiconv,
 385               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 386                               [use the libiconv library])],,
 387               [with_libiconv=maybe])
 388
 389   found_iconv=no
 390   case $with_libiconv in
 391     maybe)
 392       # Check in the C library first
 393       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 394       # Check if we have GNU libiconv
 395       if test $found_iconv = "no"; then
 396         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 397       fi
 398       # Check if we have a iconv in -liconv, possibly from vendor
 399       if test $found_iconv = "no"; then
 400         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 401       fi
 402       ;;
 403     no)
 404       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 405       ;;
 406     gnu|yes)
 407       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 408       ;;
 409     native)
 410       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 411       ;;
 412   esac
 413
 414   if test "x$found_iconv" = "xno" ; then
 415      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 416   fi
 417 fi
 418
 419 AC_ARG_ENABLE(iconv-cache,
 420               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 421                               [cache iconv descriptors [default=auto]])],,
 422               [enable_iconv_cache=auto])
 423
 424 AC_MSG_CHECKING([whether to cache iconv descriptors])
 425 case $enable_iconv_cache in
 426   auto)
 427     if test $ac_cv_gnu_library_2_1 = yes; then
 428       enable_iconv_cache=no
 429     else
 430       enable_iconv_cache=yes
 431     fi
 432   ;;
 433   yes|no)
 434   ;;
 435   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 436   ;;
 437 esac
 438
 439 if test $enable_iconv_cache = yes; then
 440    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 441 fi
 442
 443 AC_MSG_RESULT($enable_iconv_cache)
 444
 445
 446 dnl
 447 dnl zlib support
 448 dnl
 449 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 450 if test "x$found_zlib" = "xno" ; then
 451   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 452   if test "x$found_zlib" = "xno" ; then
 453     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 454   fi
 455   ZLIB_LIBS='-lz'
 456   AC_SUBST(ZLIB_LIBS)
 457 fi
 458
 459 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 460 AC_SUBST(LIBFFI_CFLAGS)
 461 AC_SUBST(LIBFFI_LIBS)
 462
 463 dnl
 464 dnl gettext support
 465 dnl
 466
 467 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 468 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 469 GLIB_GNU_GETTEXT
 470
 471 if test "$gt_cv_have_gettext" != "yes" ; then
 472   AC_MSG_ERROR([
 473 *** You must have either have gettext support in your C library, or use the
 474 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 475 ])
 476 fi
 477
 478 LIBS="$INTLLIBS $LIBS"
 479
 480 GETTEXT_PACKAGE=glib20
 481 AC_SUBST(GETTEXT_PACKAGE)
 482 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 483   [Define the gettext package to be used])
 484
 485 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 486
 487 dnl
 488 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 489 dnl
 490
 491 if test x"$glib_native_win32" != xyes; then
 492   if test x$with_libiconv != xno ; then
 493     case " $INTLLIBS " in
 494     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 495     *) ICONV_LIBS="-liconv" ;;
 496     esac
 497   fi
 498 fi
 499 AC_SUBST(ICONV_LIBS)
 500
 501 case $with_libiconv in
 502   gnu)
 503     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 504     ;;
 505   native)
 506     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 507     ;;
 508 esac
 509
 510 dnl Initialize libtool
 511 LT_PREREQ([2.2])
 512 LT_INIT([disable-static win32-dll])
 513 dnl when using libtool 2.x create libtool early, because it's used in configure
 514 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 515
 516
 517 if test "x$GCC" = "xyes"; then
 518   case " $CFLAGS " in
 519   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 520   *) CFLAGS="$CFLAGS -Wall" ;;
 521   esac
 522 fi
 523
 524 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES"
 525
 526 if test "$glib_native_win32" = "yes"; then
 527   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 528     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 529   fi
 530   if test x$enable_static = xyes; then
 531     glib_win32_static_compilation=yes
 532     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 533 #define GOBJECT_STATIC_COMPILATION 1"
 534     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 535   fi
 536 fi
 537 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 538
 539 dnl
 540 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 541 dnl
 542 if test $cross_compiling != yes ; then
 543     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 544     glib_save_LIBS=$LIBS
 545     LIBS="$LIBS -lm"
 546     AC_TRY_RUN([#include <math.h>
 547                  int main (void) { return (log(1) != log(1.)); }],
 548          AC_MSG_RESULT(none needed),
 549          glib_save_CFLAGS=$CFLAGS
 550          CFLAGS="$CFLAGS -std1"
 551          AC_TRY_RUN([#include <math.h>
 552                      int main (void) { return (log(1) != log(1.)); }],
 553              AC_MSG_RESULT(-std1),
 554              AC_MSG_RESULT()
 555              CFLAGS=$glib_save_CFLAGS
 556              AC_MSG_WARN(
 557                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 558          )
 559     )
 560     LIBS=$glib_save_LIBS
 561 fi
 562
 563 dnl NeXTStep cc seems to need this
 564 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 565 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 566   AC_MSG_RESULT(none needed),
 567   glib_save_CFLAGS=$CFLAGS
 568   CFLAGS="$CFLAGS -posix"
 569   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 570     AC_MSG_RESULT(-posix),
 571     AC_MSG_RESULT()
 572     CFLAGS=$glib_save_CFLAGS
 573     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 574
 575 # Checks for header files.
 576 AC_HEADER_STDC
 577
 578 # Checks for library functions.
 579 AC_FUNC_VPRINTF
 580 AC_FUNC_ALLOCA
 581 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2)
 582 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 583
 584 dnl don't use AC_CHECK_FUNCS here, otherwise HAVE_QSORT_R will
 585 dnl be automatically defined, which we don't want to do
 586 dnl until we have checked this function is actually usable
 587 AC_CHECK_FUNC([qsort_r])
 588
 589 # BSD has a qsort_r with wrong argument order
 590 if test x$ac_cv_func_qsort_r = xyes ; then
 591   AC_CACHE_CHECK([if qsort_r uses glibc compatible argument order], glib_cv_have_qsort_r, [
 592   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 593   #define _GNU_SOURCE
 594   #include <stdlib.h>
 595
 596   static int
 597   cmp (const void *a, const void *b, void *c)
 598   {
 599     const int *ia = a;
 600     const int *ib = b;
 601
 602     if (*ia < *ib)
 603       return -1;
 604     else if (*ia > *ib)
 605       return 1;
 606     else
 607       return 0;
 608   }
 609
 610   int
 611   main (int argc, char **argv)
 612   {
 613     int arr[3] = { 1, 2, 0 };
 614     int d = 3;
 615
 616     qsort_r (arr, 3, sizeof (int), cmp, &d);
 617
 618     if (arr[0] == 0 && arr[1] == 1 && arr[2] == 2)
 619       return 0;
 620     else
 621       return 1;
 622   }]])],[glib_cv_have_qsort_r=yes],[glib_cv_have_qsort_r=no])])
 623 fi
 624
 625 if test x$glib_cv_have_qsort_r = xyes ; then
 626   AC_DEFINE(HAVE_QSORT_R, 1, [Define to 1 if you have the 'qsort_r' function])
 627 fi
 628
 629 AC_CHECK_SIZEOF(char)
 630 AC_CHECK_SIZEOF(short)
 631 AC_CHECK_SIZEOF(long)
 632 AC_CHECK_SIZEOF(int)
 633 AC_CHECK_SIZEOF(void *)
 634 AC_CHECK_SIZEOF(long long)
 635 AC_CHECK_SIZEOF(__int64)
 636
 637 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 638   :
 639 else
 640   AC_MSG_ERROR([
 641 *** GLib requires a 64 bit type. You might want to consider
 642 *** using the GNU C compiler.
 643 ])
 644 fi
 645
 646 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 647         # long long is a 64 bit integer.
 648         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 649         AC_CACHE_VAL(glib_cv_long_long_format,[
 650                 for format in ll q I64; do
 651                   AC_TRY_RUN([#include <stdio.h>
 652                         int main()
 653                         {
 654                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 655                           char buffer[1000];
 656                           sprintf (buffer, "%${format}u", a);
 657                           sscanf (buffer, "%${format}u", &b);
 658                           exit (b!=a);
 659                         }
 660                         ],
 661                         [glib_cv_long_long_format=${format}
 662                         break],
 663                         [],[:])
 664                 done])
 665         if test -n "$glib_cv_long_long_format"; then
 666           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 667           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 668           if test x"$glib_cv_long_long_format" = xI64; then
 669             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 670           fi
 671         else
 672           AC_MSG_RESULT(none)
 673         fi
 674 elif test x$ac_cv_sizeof___int64 = x8; then
 675         # __int64 is a 64 bit integer.
 676         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 677         # We know this is MSVCRT.DLL, and what the formats are
 678         glib_cv_long_long_format=I64
 679         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 680         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 681         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 682 fi
 683
 684 dnl long doubles were not used, and a portability problem
 685 dnl AC_C_LONG_DOUBLE
 686 AC_C_CONST
 687
 688 dnl ok, here we try to check whether the systems prototypes for
 689 dnl malloc and friends actually match the prototypes provided
 690 dnl by gmem.h (keep in sync). i currently only know how to check
 691 dnl this reliably with gcc (-Werror), improvements for other
 692 dnl compilers are apprechiated.
 693 SANE_MALLOC_PROTOS=no
 694 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 695 glib_save_CFLAGS=$CFLAGS
 696 if test "x$GCC" = "xyes"; then
 697   CFLAGS="$CFLAGS -Werror"
 698   AC_TRY_COMPILE([#include <stdlib.h>], [
 699     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 700     void* (*my_malloc_p)  (size_t)         = malloc;
 701     void  (*my_free_p)    (void*)          = free;
 702     void* (*my_realloc_p) (void*, size_t)  = realloc;
 703     my_calloc_p = 0;
 704     my_malloc_p = 0;
 705     my_free_p = 0;
 706     my_realloc_p = 0;
 707   ],
 708     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 709       [Define if you have correct malloc prototypes])
 710     SANE_MALLOC_PROTOS=yes)
 711 fi
 712 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 713 CFLAGS=$glib_save_CFLAGS
 714
 715 dnl
 716 dnl check in which direction the stack grows
 717 dnl
 718 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 719         AC_TRY_RUN([
 720         volatile int *a = 0, *b = 0;
 721         void foo (void);
 722         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 723         void foo (void) { volatile int x = 5; b = &x; }
 724         ],
 725         glib_cv_stack_grows=no
 726         ,
 727         glib_cv_stack_grows=yes
 728         ,)
 729 ])
 730
 731 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 732 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 733 dnl actually supported.
 734 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 735         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 736         __inline int foo () { return 0; }
 737         int main () { return foo (); }
 738         ]])],
 739         glib_cv_has__inline=yes
 740         ,
 741         glib_cv_has__inline=no
 742         ,)
 743 ])
 744 case x$glib_cv_has__inline in
 745 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 746 esac
 747 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 748         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 749         __inline__ int foo () { return 0; }
 750         int main () { return foo (); }
 751         ]])],
 752         glib_cv_has__inline__=yes
 753         ,
 754         glib_cv_has__inline__=no
 755         ,)
 756 ])
 757 case x$glib_cv_has__inline__ in
 758 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 759 esac
 760 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 761         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 762         #undef inline
 763         inline int foo () { return 0; }
 764         int main () { return foo (); }
 765         ]])],
 766         glib_cv_hasinline=yes
 767         ,
 768         glib_cv_hasinline=no
 769         ,)
 770 ])
 771 case x$glib_cv_hasinline in
 772 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 773 esac
 774
 775 # if we can use inline functions in headers
 776 AC_MSG_CHECKING(if inline functions in headers work)
 777 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 778 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 779 #  undef inline
 780 #  define inline __inline__
 781 #elif !defined (G_HAVE_INLINE)
 782 #  undef inline
 783 #  if defined (G_HAVE___INLINE__)
 784 #    define inline __inline__
 785 #  elif defined (G_HAVE___INLINE)
 786 #    define inline __inline
 787 #  endif
 788 #endif
 789
 790 int glib_test_func2 (int);
 791
 792 static inline int
 793 glib_test_func1 (void) {
 794   return glib_test_func2 (1);
 795 }
 796
 797 int
 798 main (void) {
 799   int i = 1;
 800 }]])],[g_can_inline=yes],[g_can_inline=no])
 801 AC_MSG_RESULT($g_can_inline)
 802
 803 dnl *** check for working do while(0) macros ***
 804 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 805         AC_TRY_COMPILE([],[
 806         #define STMT_START do
 807         #define STMT_END while(0)
 808         #define STMT_TEST STMT_START { i = 0; } STMT_END
 809         int main(void) { int i = 1; STMT_TEST; return i; }],
 810         [g_cv_support_dowhile_macros=yes],
 811         [g_cv_support_dowhile_macros=no],
 812         [g_cv_support_dowhile_macros=yes])
 813 ])
 814 if test x$g_cv_support_dowhile_macros = xyes; then
 815   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 816 fi
 817
 818 # check for flavours of varargs macros
 819 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 820 AC_TRY_COMPILE([],[
 821 int a(int p1, int p2, int p3);
 822 #define call_a(...) a(1,__VA_ARGS__)
 823 call_a(2,3);
 824 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 825 AC_MSG_RESULT($g_have_iso_c_varargs)
 826
 827 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 828 if test "$CXX" = ""; then
 829 dnl No C++ compiler
 830   g_have_iso_cxx_varargs=no
 831 else
 832   AC_LANG_CPLUSPLUS
 833   AC_TRY_COMPILE([],[
 834 int a(int p1, int p2, int p3);
 835 #define call_a(...) a(1,__VA_ARGS__)
 836 call_a(2,3);
 837 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 838   AC_LANG_C
 839 fi
 840 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 841
 842 AC_MSG_CHECKING(for GNUC varargs macros)
 843 AC_TRY_COMPILE([],[
 844 int a(int p1, int p2, int p3);
 845 #define call_a(params...) a(1,params)
 846 call_a(2,3);
 847 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 848 AC_MSG_RESULT($g_have_gnuc_varargs)
 849
 850 # check for GNUC visibility support
 851 AC_MSG_CHECKING(for GNUC visibility attribute)
 852 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 853 void
 854 __attribute__ ((visibility ("hidden")))
 855      f_hidden (void)
 856 {
 857 }
 858 void
 859 __attribute__ ((visibility ("internal")))
 860      f_internal (void)
 861 {
 862 }
 863 void
 864 __attribute__ ((visibility ("protected")))
 865      f_protected (void)
 866 {
 867 }
 868 void
 869 __attribute__ ((visibility ("default")))
 870      f_default (void)
 871 {
 872 }
 873 int main (int argc, char **argv)
 874 {
 875         f_hidden();
 876         f_internal();
 877         f_protected();
 878         f_default();
 879         return 0;
 880 }
 881 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 882 AC_MSG_RESULT($g_have_gnuc_visibility)
 883 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 884
 885 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 886 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 887 #else
 888 # include "error: this is not Sun Studio."
 889 #endif
 890 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 891 AC_MSG_RESULT($g_have_sunstudio_visibility)
 892 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 893
 894 # check for bytesex stuff
 895 AC_C_BIGENDIAN
 896 if test x$ac_cv_c_bigendian = xuniversal ; then
 897 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 898 #else
 899 #error Not a big endian.
 900 #endif],
 901     ac_cv_c_bigendian=yes
 902     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 903 #else
 904 #error Not a little endian.
 905 #endif],
 906     ac_cv_c_bigendian=no
 907     ,AC_MSG_WARN([Could not determine endianness.])))
 908 fi
 909
 910
 911 # check for header files
 912 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 913 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 914 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 915 AC_CHECK_HEADERS([sys/vfs.h sys/mount.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 916 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h sys/sysctl.h fstab.h])
 917 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 918 AC_CHECK_HEADERS([linux/magic.h])
 919
 920 # check for structure fields
 921 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 922 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 923 #include <sys/stat.h>
 924 #include <unistd.h>
 925 #ifdef HAVE_SYS_STATFS_H
 926 #include <sys/statfs.h>
 927 #endif
 928 #ifdef HAVE_SYS_PARAM_H
 929 #include <sys/param.h>
 930 #endif
 931 #ifdef HAVE_SYS_MOUNT_H
 932 #include <sys/mount.h>
 933 #endif])
 934 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 935 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 936 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 937 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 938
 939 # Checks for libcharset
 940 AM_LANGINFO_CODESET
 941 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 942 AC_CHECK_FUNCS(setlocale)
 943
 944 # check additional type sizes
 945 AC_CHECK_SIZEOF(size_t)
 946
 947 dnl Try to figure out whether gsize, gssize should be long or int
 948 AC_MSG_CHECKING([for the appropriate definition for size_t])
 949
 950 case $ac_cv_sizeof_size_t in
 951   $ac_cv_sizeof_short)
 952       glib_size_type=short
 953       ;;
 954   $ac_cv_sizeof_int)
 955       glib_size_type=int
 956       ;;
 957   $ac_cv_sizeof_long)
 958       glib_size_type=long
 959       ;;
 960   $ac_cv_sizeof_long_long)
 961       glib_size_type='long long'
 962       ;;
 963   $ac_cv_sizeof__int64)
 964       glib_size_type='__int64'
 965       ;;
 966   *)  AC_MSG_ERROR([No type matching size_t in size])
 967       ;;
 968 esac
 969
 970 dnl If int/long are the same size, we see which one produces
 971 dnl warnings when used in the location as size_t. (This matters
 972 dnl on AIX with xlc)
 973 dnl
 974 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 975    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 976   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 977 #if defined(_AIX) && !defined(__GNUC__)
 978 #pragma options langlvl=stdc89
 979 #endif
 980 #include <stddef.h>
 981 int main ()
 982 {
 983   size_t s = 1;
 984   unsigned int *size_int = &s;
 985   return (int)*size_int;
 986 }
 987     ]])],glib_size_type=int,
 988       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 989 #if defined(_AIX) && !defined(__GNUC__)
 990 #pragma options langlvl=stdc89
 991 #endif
 992 #include <stddef.h>
 993 int main ()
 994 {
 995    size_t s = 1;
 996    unsigned long *size_long = &s;
 997    return (int)*size_long;
 998 }
 999         ]])],glib_size_type=long)])
1000 fi
1001
1002 AC_MSG_RESULT(unsigned $glib_size_type)
1003
1004 # Check for some functions
1005 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
1006 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid)
1007 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
1008 # Check for high-resolution sleep functions
1009 AC_CHECK_FUNCS(splice)
1010
1011 # To avoid finding a compatibility unusable statfs, which typically
1012 # successfully compiles, but warns to use the newer statvfs interface:
1013 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1014 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1015
1016 AC_MSG_CHECKING([whether to use statfs or statvfs])
1017 # Some systems have both statfs and statvfs, pick the most "native" for these
1018 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1019    [
1020    # on solaris and irix, statfs doesn't even have the f_bavail field
1021    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1022       [ac_cv_func_statfs=no],
1023    # else, at least on linux, statfs is the actual syscall
1024       [ac_cv_func_statvfs=no])
1025    ])
1026
1027 AS_IF([test x$ac_cv_func_statfs = xyes],
1028       [
1029          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1030          AC_MSG_RESULT([statfs])
1031       ],
1032       [test x$ac_cv_func_statvfs = xyes],
1033       [
1034          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1035          AC_MSG_RESULT([statvfs])
1036       ],
1037       [  AC_MSG_RESULT([neither])])
1038
1039 AC_CHECK_HEADERS(crt_externs.h)
1040 AC_CHECK_FUNCS(_NSGetEnviron)
1041
1042 AC_FUNC_VSNPRINTF_C99
1043 AC_FUNC_PRINTF_UNIX98
1044
1045 # Internet address families
1046 if test $glib_native_win32 = yes; then
1047   glib_inet_includes=["
1048 #include <winsock2.h>
1049   "]
1050 else
1051   glib_inet_includes=["
1052 #include <sys/types.h>
1053 #include <sys/socket.h>
1054   "]
1055 fi
1056
1057 glib_failed=false
1058 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1059 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1060 # winsock defines this even though it doesn't support it
1061 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1062 if $glib_failed ; then
1063   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1064 fi
1065
1066 glib_failed=false
1067 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1068 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1069 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1070 if $glib_failed ; then
1071   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1072 fi
1073
1074 AC_CHECK_FUNCS(getprotobyname_r endservent)
1075 AC_CHECK_HEADERS([netdb.h wspiapi.h arpa/nameser_compat.h])
1076
1077 # For gio/libasyncns
1078 if test $glib_native_win32 = no; then
1079   AC_CHECK_FUNCS(strndup setresuid setreuid)
1080   AC_CHECK_HEADERS(sys/prctl.h)
1081
1082   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1083   NETWORK_LIBS=""
1084   AC_MSG_CHECKING([for res_query])
1085   AC_TRY_LINK([#include <sys/types.h>
1086                #include <netinet/in.h>
1087                #include <arpa/nameser.h>
1088                #include <resolv.h>
1089               ],[
1090                res_query("test", 0, 0, (void *)0, 0);
1091               ],[AC_MSG_RESULT([yes])],
1092               [save_libs="$LIBS"
1093                LIBS="-lresolv $LIBS"
1094                AC_TRY_LINK([#include <sys/types.h>
1095                             #include <netinet/in.h>
1096                             #include <arpa/nameser.h>
1097                             #include <resolv.h>
1098                            ],[
1099                             res_query("test", 0, 0, (void *)0, 0);
1100                            ],[AC_MSG_RESULT([in -lresolv])
1101                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1102                            [LIBS="-lbind $save_libs"
1103                             AC_TRY_LINK([#include <resolv.h>],
1104                                         [res_query("test", 0, 0, (void *)0, 0);],
1105                                         [AC_MSG_RESULT([in -lbind])
1106                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1107                                         [AC_MSG_ERROR(not found)])])
1108                LIBS="$save_libs"])
1109   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1110                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1111                                         [AC_MSG_ERROR(Could not find socket())]))
1112 fi
1113 AC_SUBST(NETWORK_LIBS)
1114
1115 case $host in
1116   *-*-solaris* )
1117      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1118      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1119      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1120      ;;
1121 esac
1122
1123 dnl
1124 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1125 dnl
1126 if test "$ac_cv_func_statfs" = yes ; then
1127   AC_MSG_CHECKING([number of arguments to statfs()])
1128   AC_TRY_COMPILE([#include <unistd.h>
1129   #ifdef HAVE_SYS_PARAM_H
1130   #include <sys/param.h>
1131   #endif
1132   #ifdef HAVE_SYS_VFS_H
1133   #include <sys/vfs.h>
1134   #endif
1135   #ifdef HAVE_SYS_MOUNT_H
1136   #include <sys/mount.h>
1137   #endif
1138   #ifdef HAVE_SYS_STATFS_H
1139   #include <sys/statfs.h>
1140   #endif], [struct statfs st;
1141   statfs(NULL, &st);],[
1142     AC_MSG_RESULT([2])
1143     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1144     AC_TRY_COMPILE([#include <unistd.h>
1145   #ifdef HAVE_SYS_PARAM_H
1146   #include <sys/param.h>
1147   #endif
1148   #ifdef HAVE_SYS_VFS_H
1149   #include <sys/vfs.h>
1150   #endif
1151   #ifdef HAVE_SYS_MOUNT_H
1152   #include <sys/mount.h>
1153   #endif
1154   #ifdef HAVE_SYS_STATFS_H
1155   #include <sys/statfs.h>
1156   #endif], [struct statfs st;
1157   statfs(NULL, &st, sizeof (st), 0);],[
1158       AC_MSG_RESULT([4])
1159       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1160       AC_MSG_RESULT(unknown)
1161       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1162 fi
1163
1164 #
1165 # Check whether to use an included printf
1166 #
1167
1168 AC_ARG_ENABLE(included-printf,
1169               [AC_HELP_STRING([--enable-included-printf],
1170                               [use included printf [default=auto]])],
1171               enable_included_printf="$enableval")
1172
1173 need_included_printf=no
1174 if test "x$enable_included_printf" = "xyes" ; then
1175   need_included_printf=yes
1176 fi
1177 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1178   need_included_printf=yes
1179 fi
1180 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1181   need_included_printf=yes
1182 fi
1183 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1184    test -z "$glib_cv_long_long_format" ; then
1185   need_included_printf=yes
1186 fi
1187
1188 if test "x$enable_included_printf" = "xno" &&
1189    test "x$need_included_printf" = "xyes" ; then
1190   AC_MSG_ERROR([
1191 *** Your C library's printf doesn't appear to have the features that
1192 *** GLib needs, but you specified --enable-included-printf=no.])
1193 fi
1194
1195 enable_included_printf=$need_included_printf
1196
1197 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1198 if test "$enable_included_printf" != "yes" ; then
1199   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1200 else
1201   if test -z "$glib_cv_long_long_format" ; then
1202     glib_cv_long_long_format="ll"
1203   fi
1204   AC_DEFINE(HAVE_VASPRINTF,1)
1205 fi
1206
1207 # Checks needed for gnulib vasnprintf
1208 bh_C_SIGNED
1209 jm_AC_TYPE_LONG_LONG
1210 gt_TYPE_LONGDOUBLE
1211 gt_TYPE_WCHAR_T
1212 gt_TYPE_WINT_T
1213 AC_TYPE_SIZE_T
1214 AC_CHECK_TYPES(ptrdiff_t)
1215 jm_AC_TYPE_INTMAX_T
1216 AC_CHECK_FUNCS([snprintf wcslen])
1217 AC_FUNC_SNPRINTF_C99
1218
1219 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1220 # The check is borrowed from the PERL Configure script.
1221 if test "$ac_cv_func_memmove" != "yes"; then
1222   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1223     glib_cv_working_bcopy,[AC_TRY_RUN([
1224       int main() {
1225         char buf[128], abc[128], *b;
1226         int len, off, align;
1227         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1228         for (align = 7; align >= 0; align--) {
1229           for (len = 36; len; len--) {
1230             b = buf+align; bcopy(abc, b, len);
1231             for (off = 1; off <= len; off++) {
1232               bcopy(b, b+off, len); bcopy(b+off, b, len);
1233                 if (bcmp(b, abc, len)) return(1);
1234             }
1235           }
1236         }
1237         return(0);
1238       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1239
1240   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1241   if test "$glib_cv_working_bcopy" = "yes"; then
1242     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1243   fi
1244 fi
1245
1246 # Check for sys_errlist
1247 AC_MSG_CHECKING(for sys_errlist)
1248 AC_TRY_LINK(, [
1249 extern char *sys_errlist[];
1250 extern int sys_nerr;
1251 sys_errlist[sys_nerr-1][0] = 0;
1252 ], glib_ok=yes, glib_ok=no)
1253 AC_MSG_RESULT($glib_ok)
1254 if test "$glib_ok" = "no"; then
1255     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
1256 fi
1257
1258 # Check for sys_siglist
1259 AC_MSG_CHECKING(for sys_siglist)
1260 AC_TRY_LINK(, [
1261 extern char *sys_siglist[];
1262 exit (sys_siglist[0]);
1263 ], glib_ok=yes, glib_ok=no)
1264 AC_MSG_RESULT($glib_ok)
1265 if test "$glib_ok" = "no"; then
1266     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
1267 fi
1268
1269 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
1270 AC_MSG_CHECKING(for sys_siglist declaration)
1271 AC_TRY_COMPILE([#include <signal.h>], [
1272 strlen (sys_siglist[0]);
1273 ], glib_ok=yes, glib_ok=no)
1274 AC_MSG_RESULT($glib_ok)
1275 if test "$glib_ok" = "no"; then
1276     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
1277 fi
1278
1279 # Check if <sys/select.h> needs to be included for fd_set
1280 AC_MSG_CHECKING([for fd_set])
1281 AC_TRY_COMPILE([#include <sys/types.h>],
1282         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1283 if test "$gtk_ok" = "yes"; then
1284     AC_MSG_RESULT([yes, found in sys/types.h])
1285 else
1286     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1287     if test "$gtk_ok" = "yes"; then
1288         # *** FIXME: give it a different name
1289         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1290         AC_MSG_RESULT([yes, found in sys/select.h])
1291     else
1292         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1293         AC_MSG_RESULT(no)
1294     fi
1295 fi
1296
1297 dnl *** check for sane realloc() ***
1298 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1299         AC_TRY_RUN([#include <stdlib.h>
1300         int main() {
1301           return realloc (0, sizeof (int)) == 0;
1302         }],
1303         [glib_cv_sane_realloc=yes],
1304         [glib_cv_sane_realloc=no],
1305         [glib_cv_sane_realloc=yes])
1306 ])
1307 if test x$glib_cv_sane_realloc = xyes; then
1308   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1309 fi
1310
1311 dnl Check for nl_langinfo and CODESET
1312 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1313         AC_TRY_COMPILE([#include <langinfo.h>],
1314                 [char *codeset = nl_langinfo (CODESET);],
1315                 [glib_cv_langinfo_codeset=yes],
1316                 [glib_cv_langinfo_codeset=no])])
1317 if test x$glib_cv_langinfo_codeset = xyes; then
1318   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1319 fi
1320
1321 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1322 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1323         AC_TRY_COMPILE([#include <langinfo.h>],
1324                 [char *str;
1325                  str = nl_langinfo (PM_STR);
1326                  str = nl_langinfo (D_T_FMT);
1327                  str = nl_langinfo (D_FMT);
1328                  str = nl_langinfo (T_FMT);
1329                  str = nl_langinfo (T_FMT_AMPM);
1330                  str = nl_langinfo (MON_1);
1331                  str = nl_langinfo (ABMON_12);
1332                  str = nl_langinfo (DAY_1);
1333                  str = nl_langinfo (ABDAY_7);],
1334                 [glib_cv_langinfo_time=yes],
1335                 [glib_cv_langinfo_time=no])])
1336 if test x$glib_cv_langinfo_time = xyes; then
1337   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1338 fi
1339
1340 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_WC
1341 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_WC)], glib_cv_langinfo_outdigit,[
1342         AC_TRY_COMPILE([#include <langinfo.h>],
1343                 [char *str;
1344                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_WC);
1345                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_WC);
1346                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_WC);
1347                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_WC);
1348                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_WC);
1349                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_WC);
1350                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_WC);
1351                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_WC);
1352                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_WC);
1353                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_WC);],
1354                 [glib_cv_langinfo_outdigit=yes],
1355                 [glib_cv_langinfo_outdigit=no])])
1356 if test x$glib_cv_langinfo_outdigit = xyes; then
1357   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_WC)])
1358 fi
1359
1360 dnl ****************************************
1361 dnl *** posix_memalign                   ***
1362 dnl ****************************************
1363 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1364 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1365     glib_cv_compliant_posix_memalign=0
1366     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1367         AC_TRY_RUN([
1368                 #define _XOPEN_SOURCE 600
1369                 #include <stdlib.h> /* posix_memalign() should be defined here */
1370                 /* some systems break if #include <malloc.h> used */
1371                 static void test_memalign (size_t boundary, size_t size) {
1372                     void *mem = 0;
1373                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1374                         exit (1);
1375                     else
1376                       free (mem);
1377                 }
1378                 int main() {
1379                     test_memalign (  128,   128 - 2 * sizeof (void*));
1380                     test_memalign (  256,   256 - 2 * sizeof (void*));
1381                     test_memalign (  512,   512 - 2 * sizeof (void*));
1382                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1383                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1384                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1385                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1386                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1387                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1388                     exit (0); /* success */
1389                 }
1390                 ],
1391             [glib_cv_compliant_posix_memalign=1], [], [:])
1392       :
1393     fi
1394     ])
1395 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1396     AC_MSG_RESULT(yes)
1397     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1398 else
1399     AC_MSG_RESULT(no)
1400 fi
1401
1402
1403 dnl ****************************************
1404 dnl *** strlcpy/strlcat                  ***
1405 dnl ****************************************
1406 # Check for strlcpy
1407 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1408 AC_TRY_RUN([#include <stdlib.h>
1409 #include <string.h>
1410 int main() {
1411   char p[10];
1412   (void) strlcpy (p, "hi", 10);
1413   if (strlcat (p, "bye", 0) != 3)
1414     return 1;
1415   return 0;
1416 }], glib_cv_have_strlcpy=yes,
1417     glib_cv_have_strlcpy=no,
1418     glib_cv_have_strlcpy=no)])
1419 if test "$glib_cv_have_strlcpy" = "yes"; then
1420     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1421 fi
1422
1423
1424 dnl **********************
1425 dnl *** va_copy checks ***
1426 dnl **********************
1427 dnl we currently check for all three va_copy possibilities, so we get
1428 dnl all results in config.log for bug reports.
1429 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1430         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1431 #include <stdlib.h>
1432         void f (int i, ...) {
1433         va_list args1, args2;
1434         va_start (args1, i);
1435         va_copy (args2, args1);
1436         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1437           exit (1);
1438         va_end (args1); va_end (args2);
1439         }
1440         int main() {
1441           f (0, 42);
1442           return 0;
1443         }]])],
1444         [glib_cv_va_copy=yes],
1445         [glib_cv_va_copy=no])
1446 ])
1447 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1448         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1449 #include <stdlib.h>
1450         void f (int i, ...) {
1451         va_list args1, args2;
1452         va_start (args1, i);
1453         __va_copy (args2, args1);
1454         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1455           exit (1);
1456         va_end (args1); va_end (args2);
1457         }
1458         int main() {
1459           f (0, 42);
1460           return 0;
1461         }]])],
1462         [glib_cv___va_copy=yes],
1463         [glib_cv___va_copy=no])
1464 ])
1465
1466 if test "x$glib_cv_va_copy" = "xyes"; then
1467   g_va_copy_func=va_copy
1468 else if test "x$glib_cv___va_copy" = "xyes"; then
1469   g_va_copy_func=__va_copy
1470 fi
1471 fi
1472
1473 if test -n "$g_va_copy_func"; then
1474   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1475 fi
1476
1477 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1478         AC_TRY_RUN([#include <stdarg.h>
1479 #include <stdlib.h>
1480         void f (int i, ...) {
1481         va_list args1, args2;
1482         va_start (args1, i);
1483         args2 = args1;
1484         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1485           exit (1);
1486         va_end (args1); va_end (args2);
1487         }
1488         int main() {
1489           f (0, 42);
1490           return 0;
1491         }],
1492         [glib_cv_va_val_copy=yes],
1493         [glib_cv_va_val_copy=no],
1494         [glib_cv_va_val_copy=yes])
1495 ])
1496
1497 if test "x$glib_cv_va_val_copy" = "xno"; then
1498   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1499 fi
1500
1501 dnl ***********************
1502 dnl *** g_module checks ***
1503 dnl ***********************
1504 G_MODULE_LIBS=
1505 G_MODULE_LIBS_EXTRA=
1506 G_MODULE_PLUGIN_LIBS=
1507 if test x"$glib_native_win32" = xyes; then
1508   dnl No use for this on Win32
1509   G_MODULE_LDFLAGS=
1510 else
1511   export SED
1512   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1513 fi
1514 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1515 G_MODULE_NEED_USCORE=0
1516 G_MODULE_BROKEN_RTLD_GLOBAL=0
1517 G_MODULE_HAVE_DLERROR=0
1518 dnl *** force native WIN32 shared lib loader
1519 if test -z "$G_MODULE_IMPL"; then
1520   case "$host" in
1521   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1522   esac
1523 fi
1524 dnl *** force native AIX library loader
1525 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1526 if test -z "$G_MODULE_IMPL"; then
1527   case "$host" in
1528   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1529   esac
1530 fi
1531 dnl *** dlopen() and dlsym() in system libraries
1532 if test -z "$G_MODULE_IMPL"; then
1533         AC_CHECK_FUNC(dlopen,
1534                       [AC_CHECK_FUNC(dlsym,
1535                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1536                       [])
1537 fi
1538 dnl *** load_image (BeOS)
1539 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1540   AC_CHECK_LIB(root, load_image,
1541       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1542       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1543       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1544       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1545       [])
1546 fi
1547 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1548 if test -z "$G_MODULE_IMPL"; then
1549         AC_CHECK_FUNC(NSLinkModule,
1550                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1551                        G_MODULE_NEED_USCORE=1],
1552                       [])
1553 fi
1554 dnl *** dlopen() and dlsym() in libdl
1555 if test -z "$G_MODULE_IMPL"; then
1556         AC_CHECK_LIB(dl, dlopen,
1557                      [AC_CHECK_LIB(dl, dlsym,
1558                                    [G_MODULE_LIBS=-ldl
1559                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1560                      [])
1561 fi
1562 dnl *** shl_load() in libdld (HP-UX)
1563 if test -z "$G_MODULE_IMPL"; then
1564         AC_CHECK_LIB(dld, shl_load,
1565                 [G_MODULE_LIBS=-ldld
1566                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1567                 [])
1568 fi
1569 dnl *** additional checks for G_MODULE_IMPL_DL
1570 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1571         LIBS_orig="$LIBS"
1572         LDFLAGS_orig="$LDFLAGS"
1573         LIBS="$G_MODULE_LIBS $LIBS"
1574         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1575 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1576         echo "void glib_plugin_test(void) { }" > plugin.c
1577         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1578                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1579         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1580                 glib_cv_rtldglobal_broken,[
1581                 AC_TRY_RUN([
1582 #include <dlfcn.h>
1583 #ifndef RTLD_GLOBAL
1584 #  define RTLD_GLOBAL 0
1585 #endif
1586 #ifndef RTLD_LAZY
1587 #  define RTLD_LAZY 0
1588 #endif
1589 int glib_plugin_test;
1590 int main () {
1591     void *handle, *global, *local;
1592     global = &glib_plugin_test;
1593     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1594     if (!handle) return 0;
1595     local = dlsym (handle, "glib_plugin_test");
1596     return global == local;
1597 }                       ],
1598                         [glib_cv_rtldglobal_broken=no],
1599                         [glib_cv_rtldglobal_broken=yes],
1600                         [glib_cv_rtldglobal_broken=no])
1601                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1602                 rmdir .libs 2>/dev/null
1603         ])
1604         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1605                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1606         else
1607                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1608         fi
1609 dnl *** check whether we need preceeding underscores
1610         AC_CACHE_CHECK([for preceeding underscore in symbols],
1611                 glib_cv_uscore,[
1612                 AC_TRY_RUN([#include <dlfcn.h>
1613                 int glib_underscore_test (void) { return 42; }
1614                 int main() {
1615                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1616                   handle = dlopen ((void*)0, 0);
1617                   if (handle) {
1618                     f1 = dlsym (handle, "glib_underscore_test");
1619                     f2 = dlsym (handle, "_glib_underscore_test");
1620                   } return (!f2 || f1);
1621                 }],
1622                         [glib_cv_uscore=yes],
1623                         [glib_cv_uscore=no],
1624                         [])
1625                 rm -f plugin.c plugin.$ac_objext plugin.lo
1626         ])
1627         GLIB_ASSERT_SET(glib_cv_uscore)
1628         if test "x$glib_cv_uscore" = "xyes"; then
1629                 G_MODULE_NEED_USCORE=1
1630         else
1631                 G_MODULE_NEED_USCORE=0
1632         fi
1633
1634         LDFLAGS="$LDFLAGS_orig"
1635 dnl *** check for having dlerror()
1636         AC_CHECK_FUNC(dlerror,
1637                 [G_MODULE_HAVE_DLERROR=1],
1638                 [G_MODULE_HAVE_DLERROR=0])
1639         LIBS="$LIBS_orig"
1640 fi
1641 dnl *** done, have we got an implementation?
1642 if test -z "$G_MODULE_IMPL"; then
1643         G_MODULE_IMPL=0
1644         G_MODULE_SUPPORTED=false
1645 else
1646         G_MODULE_SUPPORTED=true
1647 fi
1648
1649 AC_MSG_CHECKING(for the suffix of module shared libraries)
1650 export SED
1651 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1652 eval $shrext_cmds
1653 module=yes eval std_shrext=$shrext_cmds
1654 # chop the initial dot
1655 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1656 AC_MSG_RESULT(.$glib_gmodule_suffix)
1657 # any reason it may fail?
1658 if test "x$glib_gmodule_suffix" = x; then
1659         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1660 fi
1661
1662 AC_SUBST(G_MODULE_SUPPORTED)
1663 AC_SUBST(G_MODULE_IMPL)
1664 AC_SUBST(G_MODULE_LIBS)
1665 AC_SUBST(G_MODULE_LIBS_EXTRA)
1666 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1667 AC_SUBST(G_MODULE_LDFLAGS)
1668 AC_SUBST(G_MODULE_HAVE_DLERROR)
1669 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1670 AC_SUBST(G_MODULE_NEED_USCORE)
1671 AC_SUBST(GLIB_DEBUG_FLAGS)
1672
1673 dnl **********************
1674 dnl *** g_spawn checks ***
1675 dnl **********************
1676
1677 AC_MSG_CHECKING(for gspawn implementation)
1678 case "$host" in
1679   *-*-mingw*)
1680     GSPAWN=gspawn-win32.lo
1681     ;;
1682   *)
1683     GSPAWN=gspawn.lo
1684     ;;
1685 esac
1686 AC_MSG_RESULT($GSPAWN)
1687 AC_SUBST(GSPAWN)
1688
1689 dnl *************************
1690 dnl *** GIOChannel checks ***
1691 dnl *************************
1692
1693 AC_MSG_CHECKING(for GIOChannel implementation)
1694 case "$host" in
1695   *-*-mingw*)
1696     GIO=giowin32.lo
1697     ;;
1698   *)
1699     GIO=giounix.lo
1700     ;;
1701 esac
1702 AC_MSG_RESULT($GIO)
1703 AC_SUBST(GIO)
1704
1705 dnl *********************************
1706 dnl *** Directory for GIO modules ***
1707 dnl *********************************
1708
1709 AC_ARG_WITH(gio-module-dir,
1710            [AC_HELP_STRING([--with-gio-module-dir=PATH],
1711                            [Load gio modules from this directory [LIBDIR/gio/modules]])],
1712            [],
1713            [with_gio_module_dir='${libdir}/gio/modules'])
1714 GIO_MODULE_DIR=$with_gio_module_dir
1715 AC_SUBST(GIO_MODULE_DIR)
1716
1717 dnl **********************************
1718 dnl *** Check for libselinux (GIO) ***
1719 dnl **********************************
1720 AC_ARG_ENABLE(selinux, [  --disable-selinux       build without selinux support])
1721 msg_selinux=no
1722 SELINUX_LIBS=
1723 if test "x$enable_selinux" != "xno"; then
1724
1725  AC_CHECK_LIB(selinux, is_selinux_enabled,
1726    [AC_CHECK_HEADERS(selinux/selinux.h,
1727      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1728        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1729         SELINUX_LIBS="-lselinux"
1730         msg_selinux=yes])
1731      ])
1732    ])
1733 fi
1734 AC_SUBST(SELINUX_LIBS)
1735
1736 dnl *****************************
1737 dnl ** Check for inotify (GIO) **
1738 dnl *****************************
1739 inotify_support=no
1740 AC_CHECK_HEADERS([sys/inotify.h],
1741 [
1742         inotify_support=yes
1743         AC_CHECK_FUNCS(inotify_init1)
1744 ])
1745
1746 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1747
1748 dnl *********************************
1749 dnl ** Check for Solaris FEN (GIO) **
1750 dnl *********************************
1751 fen_support=no
1752 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1753 #include <port.h>
1754 #ifndef PORT_SOURCE_FILE
1755 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1756 #endif
1757 int main() { return 0; } ]])],
1758 [
1759         fen_support=yes
1760 ],)
1761
1762 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1763
1764 dnl ****************************
1765 dnl *** Checks for FAM (GIO) ***
1766 dnl ****************************
1767
1768 should_disable_fam=no
1769
1770 AC_ARG_ENABLE(fam, [  --disable-fam          build without enabling fam for file system monitoring],
1771                          [
1772                                 if test "x$enable_fam" = "xno"; then
1773                                         should_disable_fam=yes
1774                                         echo "Not building FAM support"
1775                                 fi
1776                          ]
1777                          )
1778 fam_support=no
1779 FAM_LIBS=
1780 if test "x$should_disable_fam" = "xno"; then
1781 AC_CHECK_LIB(fam, FAMOpen,
1782   [AC_CHECK_HEADERS(fam.h,
1783     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1784      AC_CHECK_LIB(fam, FAMNoExists,
1785                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1786      FAM_LIBS="-lfam"]
1787      fam_support=yes,
1788     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1789   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1790 AC_SUBST(FAM_LIBS)
1791 fi
1792 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1793
1794
1795 dnl *****************************
1796 dnl *** Check for xattr (GIO) ***
1797 dnl *****************************
1798 AC_ARG_ENABLE(xattr, [  --disable-xattr           build without xattr support])
1799 msg_xattr=no
1800 XATTR_LIBS=
1801 if test "x$enable_xattr" != "xno"; then
1802
1803 dnl either glibc or libattr can provide xattr support
1804
1805 dnl for both of them, we check for getxattr being in
1806 dnl the library and a valid xattr header.
1807
1808 dnl try glibc
1809  AC_CHECK_LIB(c, getxattr,
1810    [AC_CHECK_HEADERS(sys/xattr.h,
1811      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1812       msg_xattr=yes])
1813    ])
1814
1815   if test "x$msg_xattr" != "xyes"; then
1816 dnl   failure. try libattr
1817    AC_CHECK_LIB(attr, getxattr,
1818       [AC_CHECK_HEADERS(attr/xattr.h,
1819        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1820         XATTR_LIBS="-lattr"
1821         msg_xattr=yes])
1822       ])
1823   fi
1824
1825   if test "x$msg_xattr" = "xyes"; then
1826     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1827     AC_TRY_COMPILE([
1828       #include <stdio.h>
1829       #ifdef HAVE_SYS_TYPES_H
1830       #include <sys/types.h>
1831       #endif
1832       #ifdef HAVE_SYS_XATTR_H
1833       #include <sys/xattr.h>
1834       #elif HAVE_ATTR_XATTR_H
1835       #include <attr/xattr.h>
1836       #endif
1837     ],
1838     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1839     [
1840       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1841       AC_MSG_RESULT([yes])
1842     ],
1843     [AC_MSG_RESULT([no])]
1844     )
1845   fi
1846
1847 fi
1848 AC_SUBST(XATTR_LIBS)
1849
1850 dnl ****************************************
1851 dnl *** platform dependent source checks ***
1852 dnl ****************************************
1853
1854 AC_MSG_CHECKING(for platform-dependent source)
1855 case "$host" in
1856   *-*-cygwin*|*-*-mingw*)
1857     PLATFORMDEP=gwin32.lo
1858     ;;
1859   *)
1860     PLATFORMDEP=
1861     ;;
1862 esac
1863 AC_MSG_RESULT($PLATFORMDEP)
1864 AC_SUBST(PLATFORMDEP)
1865
1866 AC_MSG_CHECKING([whether to compile timeloop])
1867 case "$host" in
1868   *-*-cygwin*|*-*-mingw*|*-*-minix)
1869     enable_timeloop=no
1870     ;;
1871   *)
1872     enable_timeloop=yes
1873     ;;
1874 esac
1875 AC_MSG_RESULT($enable_timeloop)
1876 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1877
1878 AC_MSG_CHECKING([if building for some Win32 platform])
1879 case "$host" in
1880   *-*-mingw*|*-*-cygwin*)
1881     platform_win32=yes
1882     ;;
1883   *)
1884     platform_win32=no
1885     ;;
1886 esac
1887 AC_MSG_RESULT($platform_win32)
1888 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1889
1890 dnl ***********************
1891 dnl *** g_thread checks ***
1892 dnl ***********************
1893
1894 AC_ARG_WITH(threads,
1895            [AC_HELP_STRING([--with-threads=@<:@none/posix/dce/win32@:>@],
1896                            [specify a thread implementation to use])],
1897            [if test "x$with_threads" = x; then
1898                 want_threads=yes
1899             else
1900                 want_threads=$with_threads
1901             fi],
1902            [want_threads=yes])
1903 if test "x$enable_threads" = "xno"; then
1904         want_threads=no
1905 fi
1906
1907 dnl error and warning message
1908 dnl *************************
1909
1910 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1911                 computer. GLib will not have a default thread implementation."
1912
1913 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1914                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1915                 compilation now, but then your programs might not work.
1916                 Please provide information on how it is done on your system."
1917
1918 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1919                 "
1920
1921 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1922                 provide information on your thread implementation.
1923                 You can also run 'configure --disable-threads'
1924                 to compile without thread support."
1925
1926 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1927                 functions will not be MT-safe during their first call because
1928                 there is no working 'getpwuid_r' on your system."
1929
1930 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1931                 because there is no 'localtime_r' on your system."
1932
1933 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1934                 crude surrogate will be used. If you happen to know a
1935                 yield function for your system, please inform the GLib
1936                 developers."
1937
1938 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1939                 threads on your system. Thus threads can only have the default
1940                 priority. If you happen to know these main/max
1941                 priorities, please inform the GLib developers."
1942
1943 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1944                 linking threaded applications. As GLib cannot do that
1945                 automatically, you will get an linkg error everytime you are
1946                 not using the right compiler. In that case you have to relink
1947                 with the right compiler. Ususally just '_r' is appended
1948                 to the compiler name."
1949
1950 dnl determination of thread implementation
1951 dnl ***************************************
1952
1953 # have_threads=no   means no thread support
1954 # have_threads=none means no default thread implementation
1955
1956 have_threads=no
1957 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1958                                 || test "x$want_threads" = xdce; then
1959         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1960         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1961         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1962         glib_save_CPPFLAGS="$CPPFLAGS"
1963         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1964         if test "x$have_threads" = xno; then
1965                 AC_TRY_COMPILE([#include <pthread.h>],
1966                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1967                         have_threads=posix)
1968         fi
1969         if test "x$have_threads" = xno; then
1970                 AC_TRY_COMPILE([#include <pthread.h>],
1971                         [pthread_mutex_t m;
1972                          pthread_mutex_init (&m, pthread_mutexattr_default);],
1973                         have_threads=dce)
1974         fi
1975         # Tru64Unix requires -pthread to find pthread.h. See #103020
1976         CPPFLAGS="$CPPFLAGS -pthread"
1977         if test "x$have_threads" = xno; then
1978         AC_TRY_COMPILE([#include <pthread.h>],
1979                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1980                        have_threads=posix)
1981         fi
1982         CPPFLAGS="$glib_save_CPPFLAGS"
1983 fi
1984 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1985         case $host in
1986                 *-*-mingw*)
1987                 have_threads=win32
1988                 ;;
1989         esac
1990 fi
1991 if test "x$want_threads" = xnone; then
1992         have_threads=none
1993 fi
1994
1995 AC_MSG_CHECKING(for thread implementation)
1996
1997 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1998         AC_MSG_RESULT(none available)
1999         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
2000 else
2001         AC_MSG_RESULT($have_threads)
2002 fi
2003
2004
2005 dnl determination of G_THREAD_CFLAGS
2006 dnl ********************************
2007
2008 G_THREAD_LIBS=
2009 G_THREAD_LIBS_EXTRA=
2010 G_THREAD_CFLAGS=
2011
2012 dnl
2013 dnl Test program for basic POSIX threads functionality
2014 dnl
2015 m4_define([glib_thread_test],[
2016 #include <pthread.h>
2017 int check_me = 0;
2018 void* func(void* data) {check_me = 42; return &check_me;}
2019 int main()
2020  { pthread_t t;
2021    void *ret;
2022    pthread_create (&t, $1, func, 0);
2023    pthread_join (t, &ret);
2024    return (check_me != 42 || ret != &check_me);
2025 }])
2026
2027 dnl
2028 dnl Test program for sched_get_priority_min()
2029 dnl
2030 m4_define([glib_sched_priority_test],[
2031 #include <sched.h>
2032 #include <errno.h>
2033 int main() {
2034     errno = 0;
2035     return sched_get_priority_min(SCHED_OTHER)==-1
2036            && errno != 0;
2037 }])
2038
2039 if test x"$have_threads" != xno; then
2040
2041   if test x"$have_threads" = xposix; then
2042     # First we test for posix, whether -pthread or -pthreads do the trick as
2043     # both CPPFLAG and LIBS.
2044     # One of them does for most gcc versions and some other platforms/compilers
2045     # too and could be considered as the canonical way to go.
2046     case $host in
2047       *-*-cygwin*|*-*-darwin*)
2048          # skip cygwin and darwin -pthread or -pthreads test
2049          ;;
2050       *-solaris*)
2051         # These compiler/linker flags work with both Sun Studio and gcc
2052         # Sun Studio expands -mt to -D_REENTRANT and -lthread
2053         # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2054         G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2055         G_THREAD_LIBS="-lpthread -lthread"
2056         ;;
2057       *)
2058         for flag in pthread pthreads mt; do
2059           glib_save_CFLAGS="$CFLAGS"
2060           CFLAGS="$CFLAGS -$flag"
2061           AC_TRY_RUN(glib_thread_test(0),
2062                      glib_flag_works=yes,
2063                      glib_flag_works=no,
2064                      [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2065                                      glib_flag_works=yes,
2066                                      glib_flag_works=no)])
2067           CFLAGS="$glib_save_CFLAGS"
2068           if test $glib_flag_works = yes ; then
2069              G_THREAD_CFLAGS=-$flag
2070              G_THREAD_LIBS=-$flag
2071              break;
2072           fi
2073         done
2074          ;;
2075     esac
2076   fi
2077
2078   if test x"$G_THREAD_CFLAGS" = x; then
2079
2080     # The canonical -pthread[s] does not work. Try something different.
2081
2082     case $host in
2083         *-aix*)
2084                 if test x"$GCC" = xyes; then
2085                         # GCC 3.0 and above needs -pthread.
2086                         # Should be coverd by the case above.
2087                         # GCC 2.x and below needs -mthreads
2088                         G_THREAD_CFLAGS="-mthreads"
2089                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2090                 else
2091                         # We are probably using the aix compiler. Normaly a
2092                         # program would have to be compiled with the _r variant
2093                         # of the corresponding compiler, but we as GLib cannot
2094                         # do that: but the good news is that for compiling the
2095                         # only difference is the added -D_THREAD_SAFE compile
2096                         # option. This is according to the "C for AIX User's
2097                         # Guide".
2098                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2099                 fi
2100                 ;;
2101         *-dg-dgux*)  # DG/UX
2102                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2103                 ;;
2104         *-osf*)
2105                 # So we are using dce threads. posix threads are already
2106                 # catched above.
2107                 G_THREAD_CFLAGS="-threads"
2108                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2109                 ;;
2110         *-sysv5uw7*) # UnixWare 7
2111                 # We are not using gcc with -pthread. Catched above.
2112                 G_THREAD_CFLAGS="-Kthread"
2113                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2114                 ;;
2115         *-mingw*)
2116                 # No flag needed when using MSVCRT.DLL
2117                 G_THREAD_CFLAGS=""
2118                 ;;
2119         *)
2120                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2121                 ;;
2122     esac
2123
2124   fi
2125
2126     # if we are not finding the localtime_r function, then we probably are
2127     # not using the proper multithread flag
2128
2129     glib_save_CPPFLAGS="$CPPFLAGS"
2130     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2131
2132     # First we test, whether localtime_r is declared in time.h
2133     # directly. Then we test whether a macro localtime_r exists, in
2134     # which case localtime_r in the test program is replaced and thus
2135     # if we still find localtime_r in the output, it is not defined as
2136     # a macro.
2137
2138     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2139       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2140                                                            localtime_r(a,b)],
2141                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2142
2143     CPPFLAGS="$glib_save_CPPFLAGS"
2144
2145     AC_MSG_CHECKING(thread related cflags)
2146     AC_MSG_RESULT($G_THREAD_CFLAGS)
2147     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2148 fi
2149
2150 dnl determination of G_THREAD_LIBS
2151 dnl ******************************
2152
2153 mutex_has_default=no
2154 case $have_threads in
2155         posix|dce)
2156           glib_save_CPPFLAGS="$CPPFLAGS"
2157           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2158           if test x"$G_THREAD_LIBS" = x; then
2159             case $host in
2160               *-aix*)
2161                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2162                 # probably using the aix compiler.
2163                 AC_MSG_WARN($AIX_COMPILE_INFO)
2164                 ;;
2165               *)
2166                 G_THREAD_LIBS=error
2167                 glib_save_LIBS="$LIBS"
2168                 for thread_lib in "" pthread pthread32 pthreads thread dce; do
2169                         if test x"$thread_lib" = x; then
2170                                 add_thread_lib=""
2171                                 IN=""
2172                         else
2173                                 add_thread_lib="-l$thread_lib"
2174                                 IN=" in -l$thread_lib"
2175                         fi
2176                         if test x"$have_threads" = xposix; then
2177                                 defattr=0
2178                         else
2179                                 defattr=pthread_attr_default
2180                         fi
2181
2182                         LIBS="$add_thread_lib $glib_save_LIBS"
2183
2184                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2185                         AC_TRY_RUN(glib_thread_test($defattr),
2186                                    glib_result=yes,
2187                                    glib_result=no,
2188                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2189                                                    glib_result=yes,
2190                                                    glib_result=no)])
2191                         AC_MSG_RESULT($glib_result)
2192
2193                         if test "$glib_result" = "yes" ; then
2194                           G_THREAD_LIBS="$add_thread_lib"
2195                           break
2196                         fi
2197                 done
2198                 if test "x$G_THREAD_LIBS" = xerror; then
2199                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2200                 fi
2201                 LIBS="$glib_save_LIBS"
2202                 ;;
2203             esac
2204           fi
2205
2206           glib_save_LIBS="$LIBS"
2207           for thread_lib in "" rt rte; do
2208             if test x"$thread_lib" = x; then
2209               add_thread_lib=""
2210               IN=""
2211             else
2212               add_thread_lib="-l$thread_lib"
2213               IN=" in -l$thread_lib"
2214             fi
2215             LIBS="$add_thread_lib $glib_save_LIBS"
2216
2217             AC_MSG_CHECKING(for sched_get_priority_min$IN)
2218             AC_TRY_RUN(glib_sched_priority_test,
2219                        glib_result=yes,
2220                        glib_result=no,
2221                        [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_sched_priority_test)],
2222                                        glib_result=yes,
2223                                        glib_result=no)])
2224             AC_MSG_RESULT($glib_result)
2225
2226             if test "$glib_result" = "yes" ; then
2227                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
2228                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
2229                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
2230                break
2231             fi
2232           done
2233           LIBS="$glib_save_LIBS"
2234           mutex_has_default=yes
2235           mutex_default_type='pthread_mutex_t'
2236           mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
2237           mutex_header_file='pthread.h'
2238           if test "x$have_threads" = "xposix"; then
2239             g_threads_impl="POSIX"
2240           else
2241             g_threads_impl="DCE"
2242             have_threads="posix"
2243           fi
2244           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2245           CPPFLAGS="$glib_save_CPPFLAGS"
2246           ;;
2247         win32)
2248            g_threads_impl="WIN32"
2249            ;;
2250         none|no)
2251            g_threads_impl="NONE"
2252            ;;
2253         *)
2254            g_threads_impl="NONE"
2255            G_THREAD_LIBS=error
2256            ;;
2257 esac
2258
2259 if test "x$G_THREAD_LIBS" = xerror; then
2260         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2261 fi
2262
2263 case $host in
2264   *-*-beos*)
2265     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2266     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2267     ;;
2268   *)
2269     ;;
2270 esac
2271
2272 AC_MSG_CHECKING(thread related libraries)
2273 AC_MSG_RESULT($G_THREAD_LIBS)
2274
2275 dnl check for mt safe function variants and some posix functions
2276 dnl ************************************************************
2277
2278 if test x"$have_threads" != xno; then
2279         glib_save_LIBS="$LIBS"
2280         # we are not doing the following for now, as this might require glib
2281         # to always be linked with the thread libs on some platforms.
2282         # LIBS="$LIBS $G_THREAD_LIBS"
2283         AC_CHECK_FUNCS(localtime_r gmtime_r)
2284         if test "$ac_cv_header_pwd_h" = "yes"; then
2285                 AC_CACHE_CHECK([for posix getpwuid_r],
2286                         ac_cv_func_posix_getpwuid_r,
2287                         [AC_TRY_RUN([
2288 #include <errno.h>
2289 #include <pwd.h>
2290 int main () {
2291     char buffer[10000];
2292     struct passwd pwd, *pwptr = &pwd;
2293     int error;
2294     errno = 0;
2295     error = getpwuid_r (0, &pwd, buffer,
2296                         sizeof (buffer), &pwptr);
2297    return (error < 0 && errno == ENOSYS)
2298            || error == ENOSYS;
2299 }                               ],
2300                                 [ac_cv_func_posix_getpwuid_r=yes],
2301                                 [ac_cv_func_posix_getpwuid_r=no])])
2302                 GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2303                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2304                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2305                                 [Have POSIX function getpwuid_r])
2306                 else
2307                         AC_CACHE_CHECK([for nonposix getpwuid_r],
2308                                 ac_cv_func_nonposix_getpwuid_r,
2309                                 [AC_TRY_LINK([#include <pwd.h>],
2310                                         [char buffer[10000];
2311                                         struct passwd pwd;
2312                                         getpwuid_r (0, &pwd, buffer,
2313                                                         sizeof (buffer));],
2314                                         [ac_cv_func_nonposix_getpwuid_r=yes],
2315                                         [ac_cv_func_nonposix_getpwuid_r=no])])
2316                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2317                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2318                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2319                                         [Have non-POSIX function getpwuid_r])
2320                         fi
2321                 fi
2322         fi
2323         if test "$ac_cv_header_grp_h" = "yes"; then
2324                 AC_CACHE_CHECK([for posix getgrgid_r],
2325                         ac_cv_func_posix_getgrgid_r,
2326                         [AC_TRY_RUN([
2327 #include <errno.h>
2328 #include <grp.h>
2329 int main () {
2330     char buffer[10000];
2331     struct group grp, *grpptr = &grp;
2332     int error;
2333     errno = 0;
2334     error = getgrgid_r (0, &grp, buffer,
2335                         sizeof (buffer), &grpptr);
2336    return (error < 0 && errno == ENOSYS)
2337            || error == ENOSYS;
2338 }                              ],
2339                                [ac_cv_func_posix_getgrgid_r=yes],
2340                                [ac_cv_func_posix_getgrgid_r=no])])
2341                 GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2342                 if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2343                         AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2344                                 [Have POSIX function getgrgid_r])
2345                 else
2346                         AC_CACHE_CHECK([for nonposix getgrgid_r],
2347                                 ac_cv_func_nonposix_getgrgid_r,
2348                                 [AC_TRY_LINK([#include <grp.h>],
2349                                         [char buffer[10000];
2350                                         struct group grp;
2351                                         getgrgid_r (0, &grp, buffer,
2352                                         sizeof (buffer));],
2353                                 [ac_cv_func_nonposix_getgrgid_r=yes],
2354                                 [ac_cv_func_nonposix_getgrgid_r=no])])
2355                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2356                         if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2357                                 AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2358                                         [Have non-POSIX function getgrgid_r])
2359                         fi
2360                 fi
2361         fi
2362         LIBS="$G_THREAD_LIBS $LIBS"
2363         if test x"$have_threads" = xposix; then
2364                 glib_save_CPPFLAGS="$CPPFLAGS"
2365                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2366                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
2367                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
2368                 # This is not AC_CHECK_FUNC to also work with function
2369                 # name mangling in header files.
2370                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
2371                 AC_TRY_LINK([#include <pthread.h>],
2372                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
2373                         [AC_MSG_RESULT(yes)
2374                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2375                                   [Have function pthread_attr_setstacksize])],
2376                         [AC_MSG_RESULT(no)])
2377                 AC_MSG_CHECKING(for minimal/maximal thread priority)
2378                 if test x"$posix_priority_min" = x; then
2379                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
2380                                 PX_PRIO_MIN],,[
2381                                 posix_priority_min=PX_PRIO_MIN
2382                                 posix_priority_max=PX_PRIO_MAX])
2383                 fi
2384                 if test x"$posix_priority_min" = x; then
2385                         # AIX
2386                         AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
2387                                 PTHREAD_PRIO_MIN],,[
2388                                 posix_priority_min=PTHREAD_PRIO_MIN
2389                                 posix_priority_max=PTHREAD_PRIO_MAX])
2390                 fi
2391                 if test x"$posix_priority_min" = x; then
2392                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
2393                                 PRI_OTHER_MIN],,[
2394                                 posix_priority_min=PRI_OTHER_MIN
2395                                 posix_priority_max=PRI_OTHER_MAX])
2396                 fi
2397                 if test x"$posix_priority_min" = x; then
2398                         AC_MSG_RESULT(none found)
2399                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
2400                         posix_priority_min=-1
2401                         posix_priority_max=-1
2402                 else
2403                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
2404                         AC_MSG_CHECKING(for pthread_setschedparam)
2405                         AC_TRY_LINK([#include <pthread.h>],
2406                           [pthread_t t; pthread_setschedparam(t, 0, NULL)],
2407                           [AC_MSG_RESULT(yes)
2408                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
2409                            AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
2410                           [AC_MSG_RESULT(no)
2411                            AC_MSG_WARN($POSIX_NO_PRIORITIES)])
2412                 fi
2413                 posix_yield_func=none
2414                 AC_MSG_CHECKING(for posix yield function)
2415                 for yield_func in sched_yield pthread_yield_np pthread_yield \
2416                                                         thr_yield; do
2417                         AC_TRY_LINK([#include <pthread.h>],
2418                                 [$yield_func()],
2419                                 [posix_yield_func="$yield_func"
2420                                 break])
2421                 done
2422                 if test x"$posix_yield_func" = xnone; then
2423                         AC_MSG_RESULT(none found)
2424                         AC_MSG_WARN($POSIX_NO_YIELD)
2425                         posix_yield_func="g_usleep(1000)"
2426                 else
2427                         AC_MSG_RESULT($posix_yield_func)
2428                         posix_yield_func="$posix_yield_func()"
2429                 fi
2430                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
2431                 CPPFLAGS="$glib_save_CPPFLAGS"
2432
2433         elif test x"$have_threads" = xwin32; then
2434                 # It's a pointer to a private struct
2435                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
2436         fi
2437
2438         LIBS="$glib_save_LIBS"
2439
2440         # now spit out all the warnings.
2441         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2442            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2443                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2444         fi
2445         if test "$ac_cv_func_localtime_r" != "yes"; then
2446                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2447         fi
2448 fi
2449
2450 if test x"$glib_cv_sizeof_system_thread" = x; then
2451    # use a pointer as a fallback.
2452    GLIB_SIZEOF(,void *, system_thread)
2453 fi
2454
2455 #
2456 # Hack to deal with:
2457 #
2458 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2459 #     building shared libraries with linux.
2460 #  b) FreeBSD doesn't do this either.
2461 #
2462 case $host in
2463   *-*-freebsd*|*-*-linux*)
2464     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2465     ;;
2466   *)
2467     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2468     ;;
2469 esac
2470
2471 AM_CONDITIONAL(HAVE_THREADS, [test "$have_threads" != "none"])
2472 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
2473                    [Source file containing theread implementation])
2474 AC_SUBST(G_THREAD_CFLAGS)
2475 AC_SUBST(G_THREAD_LIBS)
2476 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2477 AC_SUBST(G_THREAD_LIBS_EXTRA)
2478
2479 dnl **********************************************
2480 dnl *** GDefaultMutex setup and initialization ***
2481 dnl **********************************************
2482 dnl
2483 dnl if mutex_has_default = yes, we also got
2484 dnl mutex_default_type, mutex_default_init and mutex_header_file
2485 if test $mutex_has_default = yes ; then
2486         glib_save_CPPFLAGS="$CPPFLAGS"
2487         glib_save_LIBS="$LIBS"
2488         LIBS="$G_THREAD_LIBS $LIBS"
2489         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2490         GLIB_SIZEOF([#include <$mutex_header_file>],
2491                     $mutex_default_type,
2492                     gmutex)
2493         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
2494                            $mutex_default_type,
2495                            gmutex,
2496                            $glib_cv_sizeof_gmutex,
2497                            $mutex_default_init)
2498         if test x"$glib_cv_byte_contents_gmutex" = xno; then
2499                 mutex_has_default=no
2500         fi
2501         CPPFLAGS="$glib_save_CPPFLAGS"
2502         LIBS="$glib_save_LIBS"
2503 fi
2504
2505 AC_CHECK_FUNCS(clock_gettime, [], [
2506   AC_CHECK_LIB(rt, clock_gettime, [
2507     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2508     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2509     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2510     GLIB_RT_LIBS="-lrt"
2511   ])
2512 ])
2513 AC_SUBST(GLIB_RT_LIBS)
2514
2515 AC_CACHE_CHECK(for monotonic clocks,
2516     glib_cv_monotonic_clock,AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
2517 #include <time.h>
2518 #include <unistd.h>
2519 int main() {
2520 #if !(defined(_POSIX_MONOTONIC_CLOCK) && _POSIX_MONOTONIC_CLOCK >= 0 && defined(CLOCK_MONOTONIC))
2521         #error No monotonic clock
2522 #endif
2523         return 0;
2524 }
2525 ]])],glib_cv_monotonic_clock=yes,glib_cv_monotonic_clock=no))
2526 if test "$glib_cv_monotonic_clock" = "yes"; then
2527   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
2528 fi
2529
2530
2531 dnl ************************
2532 dnl *** g_atomic_* tests ***
2533 dnl ************************
2534
2535 AC_MSG_CHECKING([whether to use assembler code for atomic operations])
2536     case $host_cpu in
2537       i386)
2538         AC_MSG_RESULT([none])
2539         glib_memory_barrier_needed=no
2540         ;;
2541       i?86)
2542         AC_MSG_RESULT([i486])
2543         AC_DEFINE_UNQUOTED(G_ATOMIC_I486, 1,
2544                            [i486 atomic implementation])
2545         glib_memory_barrier_needed=no
2546         ;;
2547       sparc*)
2548         SPARCV9_WARNING="Try to rerun configure with CFLAGS='-mcpu=v9',
2549                          when you are using a sparc with v9 instruction set (most
2550                          sparcs nowadays). This will make the code for atomic
2551                          operations much faster. The resulting code will not run
2552                          on very old sparcs though."
2553
2554         AC_LINK_IFELSE([AC_LANG_SOURCE([[
2555           main ()
2556           {
2557             int tmp1, tmp2, tmp3;
2558             __asm__ __volatile__("casx [%2], %0, %1"
2559                                  : "=&r" (tmp1), "=&r" (tmp2) : "r" (&tmp3));
2560           }]])],
2561           AC_MSG_RESULT([sparcv9])
2562           AC_DEFINE_UNQUOTED(G_ATOMIC_SPARCV9, 1,
2563                              [sparcv9 atomic implementation]),
2564           AC_MSG_RESULT([no])
2565           AC_MSG_WARN([[$SPARCV9_WARNING]]))
2566         glib_memory_barrier_needed=yes
2567         ;;
2568       alpha*)
2569         AC_MSG_RESULT([alpha])
2570         AC_DEFINE_UNQUOTED(G_ATOMIC_ALPHA, 1,
2571                            [alpha atomic implementation])
2572         glib_memory_barrier_needed=yes
2573         ;;
2574       x86_64)
2575         AC_MSG_RESULT([x86_64])
2576         AC_DEFINE_UNQUOTED(G_ATOMIC_X86_64, 1,
2577                            [x86_64 atomic implementation])
2578         glib_memory_barrier_needed=no
2579        ;;
2580       powerpc*)
2581         AC_MSG_RESULT([powerpc])
2582         AC_DEFINE_UNQUOTED(G_ATOMIC_POWERPC, 1,
2583                            [powerpc atomic implementation])
2584         glib_memory_barrier_needed=yes
2585         AC_MSG_CHECKING([whether asm supports numbered local labels])
2586         AC_TRY_COMPILE(
2587                        ,[
2588                        __asm__ __volatile__ ("1:       nop\n"
2589                                "         bne-    1b")
2590                        ],[
2591                        AC_DEFINE_UNQUOTED(ASM_NUMERIC_LABELS, 1, [define if asm blocks can use numeric local labels])
2592                        AC_MSG_RESULT([yes])
2593                        ],[
2594                        AC_MSG_RESULT([no])
2595                        ])
2596         ;;
2597       ia64)
2598         AC_MSG_RESULT([ia64])
2599         AC_DEFINE_UNQUOTED(G_ATOMIC_IA64, 1,
2600                            [ia64 atomic implementation])
2601         glib_memory_barrier_needed=yes
2602         ;;
2603       s390|s390x)
2604         AC_MSG_RESULT([s390])
2605         AC_DEFINE_UNQUOTED(G_ATOMIC_S390, 1,
2606                            [s390 atomic implementation])
2607         glib_memory_barrier_needed=no
2608         ;;
2609       arm*)
2610         AC_MSG_RESULT([arm])
2611         AC_DEFINE_UNQUOTED(G_ATOMIC_ARM, 1,
2612                            [arm atomic implementation])
2613         glib_memory_barrier_needed=no
2614         ;;
2615       crisv32*|etraxfs*)
2616         AC_MSG_RESULT([crisv32])
2617         AC_DEFINE_UNQUOTED(G_ATOMIC_CRISV32, 1,
2618                            [crisv32 atomic implementation])
2619         glib_memory_barrier_needed=no
2620         ;;
2621       cris*|etrax*)
2622         AC_MSG_RESULT([cris])
2623         AC_DEFINE_UNQUOTED(G_ATOMIC_CRIS, 1,
2624                            [cris atomic implementation])
2625         glib_memory_barrier_needed=no
2626         ;;
2627       *)
2628         AC_MSG_RESULT([none])
2629         glib_memory_barrier_needed=yes
2630         ;;
2631     esac
2632
2633 glib_cv_gcc_has_builtin_atomic_operations=no
2634 if test x"$GCC" = xyes; then
2635   AC_MSG_CHECKING([whether GCC supports built-in atomic intrinsics])
2636   AC_TRY_LINK([],
2637               [int i;
2638                __sync_synchronize ();
2639                __sync_bool_compare_and_swap (&i, 0, 1);
2640                __sync_fetch_and_add (&i, 1);
2641               ],
2642               [glib_cv_gcc_has_builtin_atomic_operations=yes],
2643               [glib_cv_gcc_has_builtin_atomic_operations=no])
2644
2645   AC_MSG_RESULT($glib_cv_gcc_has_builtin_atomic_operations)
2646 fi
2647 AM_CONDITIONAL(HAVE_GCC_BUILTINS_FOR_ATOMIC_OPERATIONS,
2648                [test $glib_cv_gcc_has_builtin_atomic_operations = yes])
2649
2650 AC_MSG_CHECKING([for Win32 atomic intrinsics])
2651 glib_cv_has_win32_atomic_operations=no
2652 AC_TRY_LINK([],
2653         [int i; _InterlockedExchangeAdd (&i, 0);],
2654         [glib_cv_has_win32_atomic_operations=yes],
2655         [glib_cv_has_win32_atomic_operations=no])
2656 AC_MSG_RESULT($glib_cv_has_win32_atomic_operations)
2657 if test "x$glib_cv_has_win32_atomic_operations" = xyes; then
2658         AC_DEFINE(HAVE_WIN32_BUILTINS_FOR_ATOMIC_OPERATIONS,1,[Have Win32 atomic intrinsics])
2659 fi
2660
2661 dnl ************************
2662 dnl ** Check for futex(2) **
2663 dnl ************************
2664 AC_CACHE_CHECK(for futex(2) system call,
2665     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2666 #include <linux/futex.h>
2667 #include <sys/syscall.h>
2668 #include <unistd.h>
2669 ],[
2670 int
2671 main (void)
2672 {
2673   /* it is not like this actually runs or anything... */
2674   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2675   return 0;
2676 }
2677 ])],glib_cv_futex=yes,glib_cv_futex=no))
2678 if test x"$glib_cv_futex" = xyes; then
2679   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2680 fi
2681
2682 AC_CACHE_CHECK(for eventfd(2) system call,
2683     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2684 #include <sys/eventfd.h>
2685 #include <unistd.h>
2686 ],[
2687 int
2688 main (void)
2689 {
2690   eventfd (0, EFD_CLOEXEC);
2691   return 0;
2692 }
2693 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2694 if test x"$glib_cv_eventfd" = x"yes"; then
2695   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2696 fi
2697 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2698
2699 dnl ****************************************
2700 dnl *** GLib POLL* compatibility defines ***
2701 dnl ****************************************
2702
2703 glib_poll_includes=["
2704 #include <sys/types.h>
2705 #include <sys/poll.h>
2706 "]
2707
2708 if test $ac_cv_header_sys_types_h = yes &&
2709    test $ac_cv_header_sys_poll_h = yes ; then
2710   glib_failed=false
2711   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2712   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2713   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2714   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2715   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2716   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2717   if $glib_failed ; then
2718     AC_MSG_ERROR([Could not determine values for POLL* constants])
2719   fi
2720 else
2721   glib_cv_value_POLLIN=1
2722   glib_cv_value_POLLOUT=4
2723   glib_cv_value_POLLPRI=2
2724   glib_cv_value_POLLERR=8
2725   glib_cv_value_POLLHUP=16
2726   glib_cv_value_POLLNVAL=32
2727 fi
2728
2729 AC_MSG_CHECKING([for broken poll])
2730 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2731         #include <stdlib.h>
2732         #include <fcntl.h>
2733         #include <poll.h>
2734         #ifdef HAVE_SYS_POLL_H
2735         #include <sys/poll.h>
2736         #endif
2737         int main(void) {
2738           struct pollfd fds[1];
2739           int fd;
2740           fd = open("/dev/null", 1);
2741           fds[0].fd = fd;
2742           fds[0].events = POLLIN;
2743           fds[0].revents = 0;
2744           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2745                 exit(1);  /* Does not work for devices -- fail */
2746           }
2747           exit(0);
2748         }]])],
2749   [broken_poll=no],
2750   [broken_poll=yes
2751    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2752   [broken_poll="no (cross compiling)"])
2753 AC_MSG_RESULT($broken_poll)
2754
2755 dnl *********************
2756 dnl *** GRegex checks ***
2757 dnl *********************
2758 PCRE_REQUIRED_VERSION=8.11
2759
2760 # Check if we should compile GRegex
2761 AC_ARG_ENABLE(regex, AC_HELP_STRING([--disable-regex],
2762               [disable the compilation of GRegex]),
2763 [case "${enableval}" in
2764   yes) enable_regex=true ;;
2765   no)  enable_regex=false ;;
2766   *) AC_MSG_ERROR(bad value ${enableval} for --enable-regex) ;;
2767 esac],
2768 [enable_regex=true])
2769
2770 AM_CONDITIONAL(ENABLE_REGEX, $enable_regex)
2771
2772 if test x$enable_regex = xtrue; then
2773   AC_DEFINE(ENABLE_REGEX, [], [include GRegex])
2774   # Check if we should use the internal or the system-supplied pcre
2775   AC_ARG_WITH(pcre,
2776              [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2777                              [specify whether to use the internal or the
2778                               system-supplied PCRE library])])
2779
2780   AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2781
2782   if test "x$with_pcre" = xsystem; then
2783     PKG_CHECK_MODULES(PCRE,
2784                       libpcre >= $PCRE_REQUIRED_VERSION)
2785     AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2786                    glib_save_CFLAGS="$CFLAGS"
2787                    glib_save_LIBS="$LIBS"
2788                    CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2789                    AC_TRY_RUN([#include <pcre.h>
2790                                int main () {
2791                                  int support;
2792                                  pcre_config (PCRE_CONFIG_UTF8, &support);
2793                                  if (!support)
2794                                    return 1;
2795                                  pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2796                                  if (!support)
2797                                    return 1;
2798                                  return 0;
2799                                }],
2800                    glib_cv_pcre_has_unicode=yes,
2801                    glib_cv_pcre_has_unicode=no,
2802                    glib_cv_pcre_has_unicode=yes)
2803                    CFLAGS="$glib_save_CFLAGS"
2804                    LIBS="$glib_save_LIBS"
2805         ])
2806     if test "$glib_cv_pcre_has_unicode" = "no"; then
2807       AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2808     fi
2809     AC_SUBST(PCRE_CFLAGS)
2810     AC_SUBST(PCRE_LIBS)
2811     AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2812     PCRE_REQUIRES=libpcre
2813     AC_SUBST(PCRE_REQUIRES)
2814   else
2815     # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2816     if test x"$GCC" = xyes; then
2817       AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2818       save_CFLAGS="$CFLAGS"
2819       CFLAGS="$CFLAGS -Wno-pointer-sign"
2820       AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2821                             AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2822       CFLAGS="$save_CFLAGS"
2823     fi
2824   fi
2825   AC_SUBST(PCRE_WARN_CFLAGS)
2826 else
2827   AM_CONDITIONAL(USE_SYSTEM_PCRE, false])
2828 fi
2829
2830 dnl **********************
2831 dnl *** Win32 API libs ***
2832 dnl **********************
2833
2834 case $host in
2835   *-*-cygwin*)
2836         G_LIBS_EXTRA="-luser32 -lkernel32"
2837     ;;
2838   *-*-mingw*)
2839         G_LIBS_EXTRA="-lws2_32 -lole32"
2840     ;;
2841   *)
2842         G_LIBS_EXTRA=""
2843     ;;
2844 esac
2845 AC_SUBST(G_LIBS_EXTRA)
2846
2847 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2848 dnl since we need it for g_iconv()
2849
2850 AC_MSG_CHECKING([for EILSEQ])
2851 AC_TRY_COMPILE([
2852 #include <errno.h>
2853 ],
2854 [
2855 int error = EILSEQ;
2856 ], have_eilseq=yes, have_eilseq=no);
2857 AC_MSG_RESULT($have_eilseq)
2858
2859 dnl ******************************************************************
2860 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2861 dnl *** glib-compile-schemas in PATH                               ***
2862 dnl ******************************************************************
2863
2864 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2865
2866 if test $cross_compiling = yes; then
2867   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2868   if test x$GLIB_GENMARSHAL = xno; then
2869     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2870   fi
2871
2872   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2873   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2874     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2875   fi
2876 fi
2877
2878 dnl **************************
2879 dnl *** Checks for gtk-doc ***
2880 dnl **************************
2881
2882 GTK_DOC_CHECK([1.15])
2883
2884 AC_ARG_ENABLE(man,
2885               [AC_HELP_STRING([--enable-man],
2886                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2887               enable_man=no)
2888
2889 if test "${enable_man}" != no; then
2890 dnl
2891 dnl Check for xsltproc
2892 dnl
2893 AC_PATH_PROG([XSLTPROC], [xsltproc])
2894   if test -z "$XSLTPROC"; then
2895     enable_man=no
2896   fi
2897
2898   dnl check for DocBook DTD and stylesheets in the local catalog.
2899   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2900      [DocBook XML DTD V4.1.2],,enable_man=no)
2901   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2902      [DocBook XSL Stylesheets],,enable_man=no)
2903 fi
2904
2905 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2906
2907 dnl
2908 dnl Tracing
2909 dnl
2910
2911 AC_ARG_ENABLE([dtrace],
2912              [AS_HELP_STRING([--enable-dtrace],
2913                               [Enable inclusion of dtrace trace support])])
2914 have_dtrace=no
2915 AC_MSG_CHECKING([whether to include dtrace tracing support])
2916 if test "x$enable_dtrace" != xno; then
2917   if test x$glib_have_carbon = xyes; then
2918     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2919   else
2920     AC_MSG_RESULT([yes])
2921     AC_CHECK_PROGS(DTRACE, dtrace)
2922     if test -z "$DTRACE"; then
2923       if test "x$enable_dtrace" = xyes; then
2924         AC_MSG_ERROR([dtrace not found])
2925       fi
2926     else
2927       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2928                       [if test "x$enable_dtrace" = xyes; then
2929                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2930                        fi])
2931     fi
2932   fi
2933 else
2934   AC_MSG_RESULT([no])
2935 fi
2936 if test "x$have_dtrace" = xyes; then
2937   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2938 fi
2939 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2940
2941 AC_MSG_CHECKING([whether to include systemtap tracing support])
2942 AC_ARG_ENABLE([systemtap],
2943              [AS_HELP_STRING([--enable-systemtap],
2944                               [Enable inclusion of systemtap trace support])])
2945 have_systemtap=no
2946 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2947   have_systemtap=yes
2948 fi
2949 AC_MSG_RESULT(${have_systemtap})
2950
2951 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2952
2953 AC_ARG_WITH([tapset-install-dir],
2954             [AS_HELP_STRING([--with-tapset-install-dir],
2955             [The absolute path where the systemtap tapsets will be installed])],
2956             [if test "x${withval}" = x; then
2957                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2958              else
2959                ABS_TAPSET_DIR="${withval}"
2960               fi],
2961             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2962 AC_SUBST(ABS_TAPSET_DIR)
2963
2964 dnl ************************************
2965 dnl *** Enable lcov coverage reports ***
2966 dnl ************************************
2967
2968 AC_ARG_ENABLE(gcov,
2969   AS_HELP_STRING([--enable-gcov],
2970                  [Enable gcov]),
2971   [use_gcov=$enableval], [use_gcov=no])
2972
2973 if test "x$use_gcov" = "xyes"; then
2974   dnl we need gcc:
2975   if test "$GCC" != "yes"; then
2976     AC_MSG_ERROR([GCC is required for --enable-gcov])
2977   fi
2978
2979   dnl Check if ccache is being used
2980   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2981   case `$SHTOOL path $CC` in
2982     *ccache*[)] gcc_ccache=yes;;
2983     *[)] gcc_ccache=no;;
2984   esac
2985
2986   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2987     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2988   fi
2989
2990   ltp_version_list="1.6 1.7 1.8 1.9"
2991   AC_CHECK_PROG(LTP, lcov, lcov)
2992   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2993
2994   if test "$LTP"; then
2995     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2996       glib_cv_ltp_version=invalid
2997       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2998       for ltp_check_version in $ltp_version_list; do
2999         if test "$ltp_version" = "$ltp_check_version"; then
3000           glib_cv_ltp_version="$ltp_check_version (ok)"
3001         fi
3002       done
3003     ])
3004   else
3005     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
3006     AC_MSG_ERROR([$ltp_msg])
3007   fi
3008
3009   case $glib_cv_ltp_version in
3010     ""|invalid[)]
3011       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
3012       AC_MSG_ERROR([$ltp_msg])
3013       LTP="exit 0;"
3014       ;;
3015   esac
3016
3017   if test -z "$LTP_GENHTML"; then
3018     AC_MSG_ERROR([Could not find genhtml from the LTP package])
3019   fi
3020
3021   AC_DEFINE(HAVE_GCOV, 1, [Whether you have gcov])
3022
3023   dnl Remove all optimization flags from CFLAGS
3024   changequote({,})
3025   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
3026   changequote([,])
3027
3028   dnl Add the special gcc flags
3029   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
3030   LDFLAGS="$LDFLAGS -lgcov"
3031 fi
3032
3033 dnl ******************************
3034 dnl *** output the whole stuff ***
3035 dnl ******************************
3036
3037 dnl this section will only be run if config.status is invoked with no
3038 dnl arguments, or with "glib/glibconfig.h" as an argument.
3039 AC_CONFIG_COMMANDS([glib/glibconfig.h],
3040 [
3041         outfile=glib/glibconfig.h-tmp
3042         cat > $outfile <<\_______EOF
3043 /* glibconfig.h
3044  *
3045  * This is a generated file.  Please modify 'configure.ac'
3046  */
3047
3048 #ifndef __G_LIBCONFIG_H__
3049 #define __G_LIBCONFIG_H__
3050
3051 #include <glib/gmacros.h>
3052
3053 _______EOF
3054
3055         if test x$glib_limits_h = xyes; then
3056           echo '#include <limits.h>' >> $outfile
3057         fi
3058         if test x$glib_float_h = xyes; then
3059           echo '#include <float.h>' >> $outfile
3060         fi
3061         if test x$glib_values_h = xyes; then
3062           echo '#include <values.h>' >> $outfile
3063         fi
3064         if test "$glib_header_alloca_h" = "yes"; then
3065           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
3066         fi
3067         if test x$glib_sys_poll_h = xyes; then
3068           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
3069         fi
3070         if test x$glib_included_printf != xyes; then
3071           echo "
3072 /* Specifies that GLib's g_print*() functions wrap the
3073  * system printf functions.  This is useful to know, for example,
3074  * when using glibc's register_printf_function().
3075  */" >> $outfile
3076           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
3077         fi
3078
3079         cat >> $outfile <<_______EOF
3080
3081 G_BEGIN_DECLS
3082
3083 #define G_MINFLOAT      $glib_mf
3084 #define G_MAXFLOAT      $glib_Mf
3085 #define G_MINDOUBLE     $glib_md
3086 #define G_MAXDOUBLE     $glib_Md
3087 #define G_MINSHORT      $glib_ms
3088 #define G_MAXSHORT      $glib_Ms
3089 #define G_MAXUSHORT     $glib_Mus
3090 #define G_MININT        $glib_mi
3091 #define G_MAXINT        $glib_Mi
3092 #define G_MAXUINT       $glib_Mui
3093 #define G_MINLONG       $glib_ml
3094 #define G_MAXLONG       $glib_Ml
3095 #define G_MAXULONG      $glib_Mul
3096
3097 _______EOF
3098
3099
3100         ### this should always be true in a modern C/C++ compiler
3101         cat >>$outfile <<_______EOF
3102 typedef signed char gint8;
3103 typedef unsigned char guint8;
3104 _______EOF
3105
3106
3107         if test -n "$gint16"; then
3108           cat >>$outfile <<_______EOF
3109 typedef signed $gint16 gint16;
3110 typedef unsigned $gint16 guint16;
3111 #define G_GINT16_MODIFIER $gint16_modifier
3112 #define G_GINT16_FORMAT $gint16_format
3113 #define G_GUINT16_FORMAT $guint16_format
3114 _______EOF
3115         fi
3116
3117
3118         if test -n "$gint32"; then
3119           cat >>$outfile <<_______EOF
3120 typedef signed $gint32 gint32;
3121 typedef unsigned $gint32 guint32;
3122 #define G_GINT32_MODIFIER $gint32_modifier
3123 #define G_GINT32_FORMAT $gint32_format
3124 #define G_GUINT32_FORMAT $guint32_format
3125 _______EOF
3126         fi
3127
3128         cat >>$outfile <<_______EOF
3129 #define G_HAVE_GINT64 1          /* deprecated, always true */
3130
3131 ${glib_extension}typedef signed $gint64 gint64;
3132 ${glib_extension}typedef unsigned $gint64 guint64;
3133
3134 #define G_GINT64_CONSTANT(val)  $gint64_constant
3135 #define G_GUINT64_CONSTANT(val) $guint64_constant
3136 _______EOF
3137
3138         if test x$gint64_format != x ; then
3139           cat >>$outfile <<_______EOF
3140 #define G_GINT64_MODIFIER $gint64_modifier
3141 #define G_GINT64_FORMAT $gint64_format
3142 #define G_GUINT64_FORMAT $guint64_format
3143 _______EOF
3144         else
3145           cat >>$outfile <<_______EOF
3146 #undef G_GINT64_MODIFIER
3147 #undef G_GINT64_FORMAT
3148 #undef G_GUINT64_FORMAT
3149 _______EOF
3150         fi
3151
3152         cat >>$outfile <<_______EOF
3153
3154 #define GLIB_SIZEOF_VOID_P $glib_void_p
3155 #define GLIB_SIZEOF_LONG   $glib_long
3156 #define GLIB_SIZEOF_SIZE_T $glib_size_t
3157
3158 _______EOF
3159
3160         cat >>$outfile <<_______EOF
3161 typedef signed $glib_size_type_define gssize;
3162 typedef unsigned $glib_size_type_define gsize;
3163 #define G_GSIZE_MODIFIER $gsize_modifier
3164 #define G_GSSIZE_FORMAT $gssize_format
3165 #define G_GSIZE_FORMAT $gsize_format
3166
3167 #define G_MAXSIZE       G_MAXU$glib_msize_type
3168 #define G_MINSSIZE      G_MIN$glib_msize_type
3169 #define G_MAXSSIZE      G_MAX$glib_msize_type
3170
3171 typedef gint64 goffset;
3172 #define G_MINOFFSET     G_MININT64
3173 #define G_MAXOFFSET     G_MAXINT64
3174
3175 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
3176 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
3177 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
3178
3179 _______EOF
3180
3181         if test -z "$glib_unknown_void_p"; then
3182           cat >>$outfile <<_______EOF
3183
3184 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
3185 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
3186
3187 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
3188 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
3189
3190 typedef signed $glib_intptr_type_define gintptr;
3191 typedef unsigned $glib_intptr_type_define guintptr;
3192
3193 #define G_GINTPTR_MODIFIER      $gintptr_modifier
3194 #define G_GINTPTR_FORMAT        $gintptr_format
3195 #define G_GUINTPTR_FORMAT       $guintptr_format
3196 _______EOF
3197         else
3198           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
3199         fi
3200
3201
3202
3203         cat >>$outfile <<_______EOF
3204 $glib_atexit
3205 $glib_memmove
3206 $glib_defines
3207 $glib_os
3208 $glib_static_compilation
3209
3210 $glib_vacopy
3211
3212 #ifdef  __cplusplus
3213 #define G_HAVE_INLINE   1
3214 #else   /* !__cplusplus */
3215 $glib_inline
3216 #endif  /* !__cplusplus */
3217
3218 #ifdef  __cplusplus
3219 #define G_CAN_INLINE    1
3220 _______EOF
3221
3222         if test x$g_can_inline = xyes ; then
3223                 cat >>$outfile <<_______EOF
3224 #else   /* !__cplusplus */
3225 #define G_CAN_INLINE    1
3226 _______EOF
3227         fi
3228
3229         cat >>$outfile <<_______EOF
3230 #endif
3231
3232 _______EOF
3233
3234         if test x$g_have_iso_c_varargs = xyes ; then
3235                 cat >>$outfile <<_______EOF
3236 #ifndef __cplusplus
3237 # define G_HAVE_ISO_VARARGS 1
3238 #endif
3239 _______EOF
3240         fi
3241         if test x$g_have_iso_cxx_varargs = xyes ; then
3242                 cat >>$outfile <<_______EOF
3243 #ifdef __cplusplus
3244 # define G_HAVE_ISO_VARARGS 1
3245 #endif
3246 _______EOF
3247         fi
3248         if test x$g_have_gnuc_varargs = xyes ; then
3249                 cat >>$outfile <<_______EOF
3250
3251 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3252  * is passed ISO vararg support is turned off, and there is no work
3253  * around to turn it on, so we unconditionally turn it off.
3254  */
3255 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3256 #  undef G_HAVE_ISO_VARARGS
3257 #endif
3258
3259 #define G_HAVE_GNUC_VARARGS 1
3260 _______EOF
3261         fi
3262
3263         case x$g_stack_grows in
3264         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3265         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3266         esac
3267
3268
3269         echo >>$outfile
3270         if test x$g_have_eilseq = xno; then
3271                 cat >>$outfile <<_______EOF
3272 #ifndef EILSEQ
3273 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3274  * The correspondence between this and the corresponding definition
3275  * in libiconv is essential.
3276  */
3277 #  define EILSEQ ENOENT
3278 #endif
3279 _______EOF
3280
3281         fi
3282
3283         if test x$g_have_gnuc_visibility = xyes; then
3284                 cat >>$outfile <<_______EOF
3285 #define G_HAVE_GNUC_VISIBILITY 1
3286 _______EOF
3287         fi
3288                 cat >>$outfile <<_______EOF
3289 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3290 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3291 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3292 #define G_GNUC_INTERNAL __hidden
3293 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3294 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3295 #else
3296 #define G_GNUC_INTERNAL
3297 #endif
3298 _______EOF
3299
3300
3301         echo >>$outfile
3302         if test x$g_mutex_has_default = xyes; then
3303                 cat >>$outfile <<_______EOF
3304 $g_enable_threads_def G_THREADS_ENABLED
3305 #define G_THREADS_IMPL_$g_threads_impl_def
3306 typedef struct _GStaticMutex GStaticMutex;
3307 struct _GStaticMutex
3308 {
3309   struct _GMutex *runtime_mutex;
3310   union {
3311     char   pad[[$g_mutex_sizeof]];
3312     double dummy_double;
3313     void  *dummy_pointer;
3314     long   dummy_long;
3315   } static_mutex;
3316 };
3317 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
3318 #define g_static_mutex_get_mutex(mutex) \\
3319   (g_thread_use_default_impl ? ((GMutex*)(gpointer) ((mutex)->static_mutex.pad)) : \\
3320    g_static_mutex_get_mutex_impl_shortcut (&((mutex)->runtime_mutex)))
3321 _______EOF
3322         else
3323                 cat >>$outfile <<_______EOF
3324 $g_enable_threads_def G_THREADS_ENABLED
3325 #define G_THREADS_IMPL_$g_threads_impl_def
3326 typedef struct _GMutex* GStaticMutex;
3327 #define G_STATIC_MUTEX_INIT NULL
3328 #define g_static_mutex_get_mutex(mutex) \\
3329   (g_static_mutex_get_mutex_impl_shortcut (mutex))
3330 _______EOF
3331         fi
3332
3333         cat >>$outfile <<_______EOF
3334 /* This represents a system thread as used by the implementation. An
3335  * alien implementaion, as loaded by g_thread_init can only count on
3336  * "sizeof (gpointer)" bytes to store their info. We however need more
3337  * for some of our native implementations. */
3338 typedef union _GSystemThread GSystemThread;
3339 union _GSystemThread
3340 {
3341   char   data[[$g_system_thread_sizeof]];
3342   double dummy_double;
3343   void  *dummy_pointer;
3344   long   dummy_long;
3345 };
3346 _______EOF
3347         if test x"$g_memory_barrier_needed" != xno; then
3348           echo >>$outfile
3349           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3350         fi
3351         if test x"$g_gcc_atomic_ops" != xno; then
3352           echo >>$outfile
3353           echo "#define G_ATOMIC_OP_USE_GCC_BUILTINS 1" >>$outfile
3354         fi
3355         echo >>$outfile
3356         g_bit_sizes="16 32 64"
3357         for bits in $g_bit_sizes; do
3358           cat >>$outfile <<_______EOF
3359 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3360 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3361 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3362 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3363 _______EOF
3364         done
3365
3366         cat >>$outfile <<_______EOF
3367 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3368 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3369 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3370 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3371 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3372 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3373 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3374 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3375 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3376 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3377 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3378 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3379 #define G_BYTE_ORDER $g_byte_order
3380
3381 #define GLIB_SYSDEF_POLLIN =$g_pollin
3382 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3383 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3384 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3385 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3386 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3387
3388 #define G_MODULE_SUFFIX "$g_module_suffix"
3389
3390 /* A GPid is an abstraction for a process "handle". It is *not* an
3391  * abstraction for a process identifier in general. GPid is used in
3392  * GLib only for descendant processes spawned with the g_spawn*
3393  * functions. On POSIX there is no "process handle" concept as such,
3394  * but on Windows a GPid is a handle to a process, a kind of pointer,
3395  * not a process identifier.
3396  */
3397 typedef $g_pid_type GPid;
3398
3399 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3400 #define GLIB_SYSDEF_AF_INET $g_af_inet
3401 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3402
3403 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3404 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3405 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3406
3407 G_END_DECLS
3408
3409 #endif /* GLIBCONFIG_H */
3410 _______EOF
3411
3412
3413         if cmp -s $outfile glib/glibconfig.h; then
3414           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3415           rm -f $outfile
3416         else
3417           mv $outfile glib/glibconfig.h
3418         fi
3419 ],[
3420
3421 # Note that if two cases are the same, case goes with the first one.
3422 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3423 # on variable expansion in case labels.  Look at the generated config.status
3424 # for a hint.
3425
3426 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3427   glib_header_alloca_h="$ac_cv_working_alloca_h"
3428 else
3429   glib_header_alloca_h="$ac_cv_header_alloca_h"
3430 fi
3431
3432 case xyes in
3433 x$ac_cv_header_float_h)
3434   glib_float_h=yes
3435   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3436   glib_md=DBL_MIN glib_Md=DBL_MAX
3437   ;;
3438 x$ac_cv_header_values_h)
3439   glib_values_h=yes
3440   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3441   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3442   ;;
3443 esac
3444
3445 case xyes in
3446 x$ac_cv_header_limits_h)
3447   glib_limits_h=yes
3448   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3449   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3450   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3451   ;;
3452 x$ac_cv_header_values_h)
3453   glib_values_h=yes
3454   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3455   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3456   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3457   ;;
3458 esac
3459
3460 if test x$ac_cv_header_sys_poll_h = xyes ; then
3461   glib_sys_poll_h=yes
3462 fi
3463
3464 if test x$enable_included_printf = xyes ; then
3465   glib_included_printf=yes
3466 fi
3467
3468 case 2 in
3469 $ac_cv_sizeof_short)
3470   gint16=short
3471   gint16_modifier='"h"'
3472   gint16_format='"hi"'
3473   guint16_format='"hu"'
3474   ;;
3475 $ac_cv_sizeof_int)
3476   gint16=int
3477   gint16_modifier='""'
3478   gint16_format='"i"'
3479   guint16_format='"u"'
3480   ;;
3481 esac
3482 case 4 in
3483 $ac_cv_sizeof_short)
3484   gint32=short
3485   gint32_modifier='"h"'
3486   gint32_format='"hi"'
3487   guint32_format='"hu"'
3488   ;;
3489 $ac_cv_sizeof_int)
3490   gint32=int
3491   gint32_modifier='""'
3492   gint32_format='"i"'
3493   guint32_format='"u"'
3494   ;;
3495 $ac_cv_sizeof_long)
3496   gint32=long
3497   gint32_modifier='"l"'
3498   gint32_format='"li"'
3499   guint32_format='"lu"'
3500   ;;
3501 esac
3502 case 8 in
3503 $ac_cv_sizeof_int)
3504   gint64=int
3505   gint64_modifier='""'
3506   gint64_format='"i"'
3507   guint64_format='"u"'
3508   glib_extension=
3509   gint64_constant='(val)'
3510   guint64_constant='(val)'
3511   ;;
3512 $ac_cv_sizeof_long)
3513   gint64=long
3514   gint64_modifier='"l"'
3515   gint64_format='"li"'
3516   guint64_format='"lu"'
3517   glib_extension=
3518   gint64_constant='(val##L)'
3519   guint64_constant='(val##UL)'
3520   ;;
3521 $ac_cv_sizeof_long_long)
3522   gint64='long long'
3523   if test -n "$glib_cv_long_long_format"; then
3524     gint64_modifier='"'$glib_cv_long_long_format'"'
3525     gint64_format='"'$glib_cv_long_long_format'i"'
3526     guint64_format='"'$glib_cv_long_long_format'u"'
3527   fi
3528   glib_extension='G_GNUC_EXTENSION '
3529   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3530   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3531   ;;
3532 $ac_cv_sizeof___int64)
3533   gint64='__int64'
3534   if test -n "$glib_cv_long_long_format"; then
3535     gint64_modifier='"'$glib_cv_long_long_format'"'
3536     gint64_format='"'$glib_cv_long_long_format'i"'
3537     guint64_format='"'$glib_cv_long_long_format'u"'
3538   fi
3539   glib_extension=
3540   gint64_constant='(val##i64)'
3541   guint64_constant='(val##ui64)'
3542   ;;
3543 esac
3544 glib_size_t=$ac_cv_sizeof_size_t
3545 glib_size_type_define="$glib_size_type"
3546 glib_void_p=$ac_cv_sizeof_void_p
3547 glib_long=$ac_cv_sizeof_long
3548
3549 case "$glib_size_type" in
3550 short)
3551   gsize_modifier='"h"'
3552   gsize_format='"hu"'
3553   gssize_format='"hi"'
3554   glib_msize_type='SHRT'
3555   ;;
3556 int)
3557   gsize_modifier='""'
3558   gsize_format='"u"'
3559   gssize_format='"i"'
3560   glib_msize_type='INT'
3561   ;;
3562 long)
3563   gsize_modifier='"l"'
3564   gsize_format='"lu"'
3565   gssize_format='"li"'
3566   glib_msize_type='LONG'
3567   ;;
3568 "long long"|__int64)
3569   gsize_modifier='"I64"'
3570   gsize_format='"I64u"'
3571   gssize_format='"I64i"'
3572   glib_msize_type='INT64'
3573   ;;
3574 esac
3575
3576 gintbits=`expr $ac_cv_sizeof_int \* 8`
3577 glongbits=`expr $ac_cv_sizeof_long \* 8`
3578 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3579
3580 case $ac_cv_sizeof_void_p in
3581 $ac_cv_sizeof_int)
3582   glib_intptr_type_define=int
3583   gintptr_modifier='""'
3584   gintptr_format='"i"'
3585   guintptr_format='"u"'
3586   glib_gpi_cast=''
3587   glib_gpui_cast=''
3588   ;;
3589 $ac_cv_sizeof_long)
3590   glib_intptr_type_define=long
3591   gintptr_modifier='"l"'
3592   gintptr_format='"li"'
3593   guintptr_format='"lu"'
3594   glib_gpi_cast='(glong)'
3595   glib_gpui_cast='(gulong)'
3596   ;;
3597 $ac_cv_sizeof_long_long)
3598   glib_intptr_type_define='long long'
3599   gintptr_modifier='"I64"'
3600   gintptr_format='"I64i"'
3601   guintptr_format='"I64u"'
3602   glib_gpi_cast='(gint64)'
3603   glib_gpui_cast='(guint64)'
3604   ;;
3605 $ac_cv_sizeof___int64)
3606   glib_intptr_type_define=__int64
3607   gintptr_modifier='"I64"'
3608   gintptr_format='"I64i"'
3609   guintptr_format='"I64u"'
3610   glib_gpi_cast='(gint64)'
3611   glib_gpui_cast='(guint64)'
3612   ;;
3613 *)
3614   glib_unknown_void_p=yes
3615   ;;
3616 esac
3617
3618
3619 case xyes in
3620 x$ac_cv_func_atexit)
3621   glib_atexit="
3622 #ifdef NeXT /* @#%@! NeXTStep */
3623 # define g_ATEXIT(proc) (!atexit (proc))
3624 #else
3625 # define g_ATEXIT(proc) (atexit (proc))
3626 #endif"
3627   ;;
3628 x$ac_cv_func_on_exit)
3629   glib_atexit="
3630 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3631   ;;
3632 esac
3633
3634 case xyes in
3635 x$ac_cv_func_memmove)
3636   glib_memmove='
3637 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3638   ;;
3639 x$glib_cv_working_bcopy)
3640   glib_memmove="
3641 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3642 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3643   ;;
3644 *)
3645   glib_memmove="
3646 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3647  * so we have to roll our own copy routine. */
3648 void g_memmove (void* dest, const void * src, unsigned long len);"
3649   ;;
3650 esac
3651
3652 glib_defines="
3653 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3654 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3655 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3656 "
3657
3658 case xyes in
3659 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3660 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3661 *)                      glib_vacopy=''
3662 esac
3663
3664 if test x$glib_cv_va_val_copy = xno; then
3665   glib_vacopy="\$glib_vacopy
3666 #define G_VA_COPY_AS_ARRAY 1"
3667 fi
3668
3669 if test x$glib_cv_hasinline = xyes; then
3670     glib_inline='#define G_HAVE_INLINE 1'
3671 fi
3672 if test x$glib_cv_has__inline = xyes; then
3673     glib_inline="\$glib_inline
3674 #define G_HAVE___INLINE 1"
3675 fi
3676 if test x$glib_cv_has__inline__ = xyes; then
3677     glib_inline="\$glib_inline
3678 #define G_HAVE___INLINE__ 1"
3679 fi
3680
3681 g_have_gnuc_varargs=$g_have_gnuc_varargs
3682 g_have_iso_c_varargs=$g_have_iso_c_varargs
3683 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3684
3685 g_can_inline=$g_can_inline
3686 g_have_gnuc_visibility=$g_have_gnuc_visibility
3687 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3688
3689 if test x$ac_cv_c_bigendian = xyes; then
3690   g_byte_order=G_BIG_ENDIAN
3691   g_bs_native=BE
3692   g_bs_alien=LE
3693 else
3694   g_byte_order=G_LITTLE_ENDIAN
3695   g_bs_native=LE
3696   g_bs_alien=BE
3697 fi
3698
3699 g_pollin=$glib_cv_value_POLLIN
3700 g_pollout=$glib_cv_value_POLLOUT
3701 g_pollpri=$glib_cv_value_POLLPRI
3702 g_pollhup=$glib_cv_value_POLLHUP
3703 g_pollerr=$glib_cv_value_POLLERR
3704 g_pollnval=$glib_cv_value_POLLNVAL
3705
3706 g_af_unix=$glib_cv_value_AF_UNIX
3707 g_af_inet=$glib_cv_value_AF_INET
3708 g_af_inet6=$glib_cv_value_AF_INET6
3709
3710 g_msg_peek=$glib_cv_value_MSG_PEEK
3711 g_msg_oob=$glib_cv_value_MSG_OOB
3712 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3713
3714 g_stack_grows=$glib_cv_stack_grows
3715
3716 g_have_eilseq=$have_eilseq
3717
3718 case x$have_threads in
3719 xno)    g_enable_threads_def="#undef";;
3720 *)      g_enable_threads_def="#define";;
3721 esac
3722
3723 g_threads_impl_def=$g_threads_impl
3724
3725 g_mutex_has_default="$mutex_has_default"
3726 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
3727 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
3728 g_mutex_contents="$glib_cv_byte_contents_gmutex"
3729
3730 g_memory_barrier_needed="$glib_memory_barrier_needed"
3731 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3732
3733 g_module_suffix="$glib_gmodule_suffix"
3734
3735 g_pid_type="$glib_pid_type"
3736 case $host in
3737   *-*-beos*)
3738     glib_os="#define G_OS_BEOS"
3739     ;;
3740   *-*-cygwin*)
3741     glib_os="#define G_OS_UNIX
3742 #define G_PLATFORM_WIN32
3743 #define G_WITH_CYGWIN"
3744     ;;
3745   *-*-mingw*)
3746     glib_os="#define G_OS_WIN32
3747 #define G_PLATFORM_WIN32"
3748     ;;
3749   *)
3750     glib_os="#define G_OS_UNIX"
3751     ;;
3752 esac
3753 glib_static_compilation=""
3754 if test x$glib_win32_static_compilation = xyes; then
3755   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3756 #define GOBJECT_STATIC_COMPILATION 1"
3757 fi
3758 ])
3759
3760 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3761 #
3762 # 1.2.14 required for dbus_message_set_serial
3763 PKG_CHECK_MODULES(DBUS1,
3764                   dbus-1 >= 1.2.14,
3765                   [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3766                   have_dbus1=no)
3767 AC_SUBST(DBUS1_CFLAGS)
3768 AC_SUBST(DBUS1_LIBS)
3769 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3770
3771 dnl
3772 dnl Check for -Bsymbolic-functions linker flag used to avoid
3773 dnl intra-library PLT jumps, if available.
3774 dnl
3775
3776 AC_ARG_ENABLE(Bsymbolic,
3777               [AC_HELP_STRING([--disable-Bsymbolic],
3778                               [avoid linking with -Bsymbolic])],,
3779               [SAVED_LDFLAGS="${LDFLAGS}"
3780                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3781                LDFLAGS=-Wl,-Bsymbolic-functions
3782                AC_TRY_LINK([], [int main (void) { return 0; }],
3783                            AC_MSG_RESULT(yes)
3784                            enable_Bsymbolic=yes,
3785                            AC_MSG_RESULT(no)
3786                            enable_Bsymbolic=no)
3787                LDFLAGS="${SAVED_LDFLAGS}"])
3788
3789 if test "x${enable_Bsymbolic}" == "xyes"; then
3790   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3791 fi
3792
3793 AC_SUBST(GLIB_LINK_FLAGS)
3794
3795 #
3796 # Define variables corresponding to the correct include paths to use for
3797 # in-tree building.
3798 #
3799
3800 # for config.h:
3801 config_h_INCLUDES='-I$(top_builddir)'
3802 AC_SUBST(config_h_INCLUDES)
3803
3804 # glib:
3805 #   config.h
3806 #   $(top_builddir)/glib: for glibconfig.h
3807 #   $(top_srcdir)/glib:   for glib.h
3808 #   $(top_srcdir):        for everything
3809 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3810 AC_SUBST(glib_INCLUDES)
3811
3812 # gthread:
3813 #   same as glib
3814 gthread_INCLUDES='$(glib_INCLUDES)'
3815 AC_SUBST(gthread_INCLUDES)
3816
3817 # gobject:
3818 #   same as gthread
3819 gobject_INCLUDES='$(gthread_INCLUDES)'
3820 AC_SUBST(gobject_INCLUDES)
3821
3822 # gmodule:
3823 #   glib includes
3824 #   $(top_srcdir)/gmodule: for gmodule.h
3825 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3826 AC_SUBST(gmodule_INCLUDES)
3827
3828 # gio:
3829 #   same as gmodule
3830 gio_INCLUDES='$(gmodule_INCLUDES)'
3831 AC_SUBST(gio_INCLUDES)
3832
3833
3834 AC_CONFIG_FILES([
3835 glib-2.0.pc
3836 glib-2.0-uninstalled.pc
3837 gmodule-2.0.pc
3838 gmodule-export-2.0.pc
3839 gmodule-no-export-2.0.pc
3840 gmodule-2.0-uninstalled.pc
3841 gmodule-no-export-2.0-uninstalled.pc
3842 gthread-2.0.pc
3843 gthread-2.0-uninstalled.pc
3844 gobject-2.0.pc
3845 gobject-2.0-uninstalled.pc
3846 gio-2.0.pc
3847 gio-unix-2.0.pc
3848 gio-windows-2.0.pc
3849 gio-2.0-uninstalled.pc
3850 gio-unix-2.0-uninstalled.pc
3851 glib-zip
3852 glib-gettextize
3853 Makefile
3854 build/Makefile
3855 build/win32/Makefile
3856 build/win32/dirent/Makefile
3857 build/win32/vs9/Makefile
3858 build/win32/vs10/Makefile
3859 glib/Makefile
3860 glib/glib.stp
3861 glib/libcharset/Makefile
3862 glib/gnulib/Makefile
3863 glib/pcre/Makefile
3864 glib/update-pcre/Makefile
3865 glib/tests/Makefile
3866 gmodule/Makefile
3867 gmodule/gmoduleconf.h
3868 gobject/Makefile
3869 gobject/gobject.stp
3870 gobject/glib-mkenums
3871 gobject/tests/Makefile
3872 gthread/Makefile
3873 gthread/tests/Makefile
3874 gio/Makefile
3875 gio/gdbus-2.0/codegen/Makefile
3876 gio/gdbus-2.0/codegen/config.py
3877 gio/xdgmime/Makefile
3878 gio/inotify/Makefile
3879 gio/libasyncns/Makefile
3880 gio/fen/Makefile
3881 gio/fam/Makefile
3882 gio/win32/Makefile
3883 gio/tests/Makefile
3884 gio/tests/gdbus-object-manager-example/Makefile
3885 po/Makefile.in
3886 docs/Makefile
3887 docs/reference/Makefile
3888 docs/reference/glib/Makefile
3889 docs/reference/glib/version.xml
3890 docs/reference/gobject/Makefile
3891 docs/reference/gobject/version.xml
3892 docs/reference/gio/Makefile
3893 docs/reference/gio/gdbus-object-manager-example/Makefile
3894 docs/reference/gio/version.xml
3895 tests/Makefile
3896 tests/gobject/Makefile
3897 tests/refcount/Makefile
3898 m4macros/Makefile
3899 ])
3900
3901 AC_CONFIG_COMMANDS([chmod-scripts],
3902 [chmod 0755 glib-zip
3903 chmod 0755 glib-gettextize
3904 chmod 0755 gobject/glib-mkenums])
3905
3906 # we want to invoke this macro solely so that the config.status script
3907 # and automake generated makefiles know about these generated files.
3908 # They are only needed to distcheck the package
3909 if false; then
3910   AC_CONFIG_FILES([
3911     INSTALL
3912     README
3913     config.h.win32
3914     glib/glibconfig.h.win32
3915     glib/makefile.msc
3916     glib/glib.rc
3917     gmodule/makefile.msc
3918     gmodule/gmodule.rc
3919     gobject/makefile.msc
3920     gobject/gobject.rc
3921     gthread/makefile.msc
3922     gthread/gthread.rc
3923     gio/gio.rc
3924     tests/makefile.msc
3925   ])
3926 fi
3927
3928 AC_OUTPUT