configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT([GStreamer Good Plug-ins],[1.13.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-good])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 AG_GST_LIBTOOL_PREPARE
  46 AS_LIBTOOL(GST, 1300, 0, 1300)
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=1.13.0.1
  50 GSTPB_REQ=1.13.0.1
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.17])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  69 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  70
  71 AG_GST_ARG_DEBUG
  72 AG_GST_ARG_PROFILING
  73 AG_GST_ARG_VALGRIND
  74 AG_GST_ARG_GCOV
  75
  76 AG_GST_ARG_EXAMPLES
  77
  78 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  79 AG_GST_ARG_WITH_PACKAGE_NAME
  80 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  81
  82 AG_GST_ARG_WITH_PLUGINS
  83
  84 AG_GST_ARG_ENABLE_EXTERNAL
  85
  86 AG_GST_ARG_ENABLE_EXPERIMENTAL
  87
  88 AG_GST_PKG_CONFIG_PATH
  89
  90 dnl *** checks for platform ***
  91
  92 dnl * hardware/architecture *
  93
  94 dnl common/m4/gst-arch.m4
  95 dnl check CPU type
  96 AG_GST_ARCH
  97
  98 dnl Determine endianness
  99 AC_C_BIGENDIAN
 100
 101 dnl *** checks for programs ***
 102
 103 dnl find a compiler
 104 AC_PROG_CC
 105 AC_PROG_CC_STDC
 106
 107 dnl determine c++ compiler
 108 AC_PROG_CXX
 109 dnl determine if c++ is available on this system
 110 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 111
 112 dnl determine c++ preprocessor
 113 dnl FIXME: do we need this ?
 114 AC_PROG_CXXCPP
 115
 116 AC_PROG_OBJC
 117
 118 dnl check if the compiler supports '-c' and '-o' options
 119 AM_PROG_CC_C_O
 120
 121 dnl find an assembler
 122 AM_PROG_AS
 123
 124 dnl check if the compiler supports do while(0) macros
 125 AG_GST_CHECK_DOWHILE_MACROS
 126
 127 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 128 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 129
 130 dnl check for documentation tools
 131 GTK_DOC_CHECK([1.12])
 132 AG_GST_PLUGIN_DOCS([1.12])
 133
 134 dnl *** checks for libraries ***
 135
 136 dnl check for libm, for sin()
 137 LT_LIB_M
 138 AC_SUBST(LIBM)
 139
 140 AC_CHECK_FUNCS(clock_gettime, [], [
 141   AC_CHECK_LIB(rt, clock_gettime, [
 142     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 143     LIBRT="-lrt"
 144     AC_SUBST([LIBRT])
 145   ])
 146 ])
 147
 148 dnl check for pthreads
 149 AX_PTHREAD
 150
 151 dnl *** checks for header files ***
 152
 153 dnl check if we have ANSI C header files
 154 AC_HEADER_STDC
 155
 156 dnl used by ext/wavpack
 157 AX_CREATE_STDINT_H
 158
 159 dnl used in gst/udp
 160 AC_CHECK_HEADERS([sys/time.h])
 161
 162 dnl used in gst/udp
 163 AC_CHECK_HEADERS([sys/socket.h])
 164
 165 dnl *** checks for types/defines ***
 166
 167 dnl Check for FIONREAD ioctl declaration.  This check is needed
 168 dnl for the UDP plugin to build on Solaris
 169 GST_CHECK_FIONREAD
 170
 171 dnl *** checks for structures ***
 172
 173 dnl *** checks for compiler characteristics ***
 174
 175 dnl check if we have GCC inline-asm
 176 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 177 if test x$HAVE_GCC_ASM = xyes ; then
 178   AC_DEFINE(HAVE_GCC_ASM, 1,
 179     [Define if compiler supports gcc inline assembly])
 180 fi
 181 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 182
 183 dnl *** checks for library functions ***
 184
 185 LIBS_SAVE=$LIBS
 186 LIBS="$LIBS $LIBM"
 187 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 188 LIBS=$LIBS_SAVE
 189
 190 dnl Check whether isinf() is defined by math.h
 191 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 192     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 193 if test "$ac_cv_have_isinf" = "yes"
 194 then
 195     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 196 fi
 197
 198 dnl Check for mmap (needed by electricfence plugin)
 199 AC_FUNC_MMAP
 200 AC_CHECK_SIZEOF([off_t])
 201 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 202
 203 dnl Check for mmap (needed by electricfence plugin)
 204
 205 AC_CHECK_TYPE([struct ip_mreqn], [
 206               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 207               [#include <netinet/in.h>])
 208
 209 dnl *** checks for dependency libraries ***
 210
 211
 212 dnl GLib
 213 GLIB_REQ=2.40.0
 214 AG_GST_GLIB_CHECK([$GLIB_REQ])
 215
 216 dnl Orc
 217 ORC_CHECK([0.4.17])
 218
 219 dnl checks for gstreamer
 220 dnl uninstalled is selected preferentially -- see pkg-config(1)
 221 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 222 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 223 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 224 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 225 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 226 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 227
 228 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 229 if test -z $GST_TOOLS_DIR; then
 230   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 231 fi
 232 AC_SUBST(GST_TOOLS_DIR)
 233
 234 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 235 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 236
 237 AG_GST_PKG_CHECK_MODULES(GST_GL, gstreamer-gl-[$GST_API_VERSION], [$GST_REQ], no)
 238
 239 dnl FIXME: if uninstalled setup we might not want to pick up an installed gst-gl?
 240 if test "x$HAVE_GST_GL" = "xyes"; then
 241
 242   AC_MSG_CHECKING([GStreamer OpenGL window systems ...])
 243   GST_GL_WINSYS=`$PKG_CONFIG --variable=gl_winsys gstreamer-gl-1.0`
 244   AC_MSG_RESULT([$GST_GL_WINSYS])
 245   GST_GL_HAVE_WINDOW_X11=""
 246   GST_GL_HAVE_WINDOW_WAYLAND=""
 247   GST_GL_HAVE_WINDOW_ANDROID=""
 248   GST_GL_HAVE_WINDOW_COCOA=""
 249   GST_GL_HAVE_WINDOW_EAGL=""
 250   case "$GST_GL_WINSYS" in  *x11*) GST_GL_HAVE_WINDOW_X11="1" ;; esac
 251   case "$GST_GL_WINSYS" in  *wayland*) GST_GL_HAVE_WINDOW_WAYLAND="1" ;; esac
 252   case "$GST_GL_WINSYS" in  *android*) GST_GL_HAVE_WINDOW_ANDROID="1" ;; esac
 253   case "$GST_GL_WINSYS" in  *cocoa*) GST_GL_HAVE_WINDOW_COCOA="1" ;; esac
 254   case "$GST_GL_WINSYS" in  *eagl*) GST_GL_HAVE_WINDOW_EAGL="1" ;; esac
 255
 256   AC_MSG_CHECKING([GStreamer OpenGL platforms ...])
 257   GST_GL_PLATFORMS=`$PKG_CONFIG --variable=gl_platforms gstreamer-gl-1.0`
 258   AC_MSG_RESULT([$GST_GL_PLATFORMS])
 259   GST_GL_HAVE_PLATFORM_GLX=""
 260   GST_GL_HAVE_PLATFORM_EGL=""
 261   GST_GL_HAVE_PLATFORM_CGL=""
 262   GST_GL_HAVE_PLATFORM_EAGL=""
 263   case "$GST_GL_PLATFORMS" in  *glx*) GST_GL_HAVE_PLATFORM_GLX="1" ;; esac
 264   case "$GST_GL_PLATFORMS" in  *egl*) GST_GL_HAVE_PLATFORM_EGL="1" ;; esac
 265   case "$GST_GL_PLATFORMS" in  *cgl*) GST_GL_HAVE_PLATFORM_CGL="1" ;; esac
 266   case "$GST_GL_PLATFORMS" in  *eagl*) GST_GL_HAVE_PLATFORM_EAGL="1" ;; esac
 267
 268   AC_MSG_CHECKING([GStreamer OpenGL apis ...])
 269   GST_GL_APIS=`$PKG_CONFIG --variable=gl_apis gstreamer-gl-1.0`
 270   AC_MSG_RESULT([$GST_GL_APIS])
 271   GST_GL_HAVE_API_GLES2=""
 272   GST_GL_HAVE_API_GL=""
 273   case "$GST_GL_APIS" in  *gles2*) GST_GL_HAVE_API_GLES2="1" ;; esac
 274   case "$GST_GL_APIS" in "gl"|"gl "*|*" gl"|*" gl "*) GST_GL_HAVE_API_GL="1" ;; esac
 275 fi
 276
 277 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 278
 279 dnl Check for documentation xrefs
 280 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 281 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 282 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 283 AC_SUBST(GLIB_PREFIX)
 284 AC_SUBST(GST_PREFIX)
 285 AC_SUBST(GSTPB_PREFIX)
 286
 287 dnl GTK is optional and used in examples
 288 HAVE_GTK=no
 289 GTK_REQ=3.0.0
 290 if test "x$BUILD_EXAMPLES" = "xyes"; then
 291   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 292   dnl some examples need gtk+-x11
 293   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 294   AC_SUBST(GTK_LIBS)
 295   AC_SUBST(GTK_CFLAGS)
 296 fi
 297 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 298 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 299
 300 dnl Check for -Bsymbolic-functions linker flag used to avoid
 301 dnl intra-library PLT jumps, if available.
 302 AC_ARG_ENABLE(Bsymbolic,
 303               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 304               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 305                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 306                LDFLAGS=-Wl,-Bsymbolic-functions
 307                LIBS=
 308                AC_TRY_LINK([], [return 0],
 309                            AC_MSG_RESULT(yes)
 310                            enable_Bsymbolic=yes,
 311                            AC_MSG_RESULT(no)
 312                            enable_Bsymbolic=no)
 313                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 314
 315 dnl *** set variables based on configure arguments ***
 316
 317 dnl set license and copyright notice
 318 GST_LICENSE="LGPL"
 319 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 320 AC_SUBST(GST_LICENSE)
 321
 322 dnl set location of plugin directory
 323 AG_GST_SET_PLUGINDIR
 324
 325 dnl set release date/time
 326 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 327   ["${srcdir}/gst-plugins-good.doap"],
 328   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 329
 330 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 331 dnl make sure it doesn't complain about unused variables if debugging is disabled
 332 NO_WARNINGS=""
 333 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 334
 335 dnl define an ERROR_CFLAGS Makefile variable
 336 dnl -Wundef: too many broken headers
 337 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 338       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 339       -Wwrite-strings -Wold-style-definition -Waggregate-return
 340       -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 341       -Wnested-externs $NO_WARNINGS])
 342
 343 dnl define an ERROR_CXXFLAGS Makefile variable
 344 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 345         -Wmissing-declarations -Wredundant-decls
 346         -Wwrite-strings
 347         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 348         $NO_WARNINGS])
 349
 350 dnl define an ERROR_OBJCFLAGS Makefile variable
 351 AG_GST_SET_ERROR_OBJCFLAGS($FATAL_WARNINGS, [
 352       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 353       -Wwrite-strings -Wold-style-definition
 354       -Winit-self -Wmissing-include-dirs -Wno-multichar
 355       -Wnested-externs $NO_WARNINGS])
 356
 357 dnl define correct level for debugging messages
 358 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 359
 360 dnl used in examples
 361 AG_GST_DEFAULT_ELEMENTS
 362
 363 dnl *** plug-ins to include ***
 364
 365 dnl these are all the gst plug-ins, compilable without additional libs
 366 dnl videofilter is at the top because others depend on it
 367 AG_GST_CHECK_PLUGIN(alpha)
 368 AG_GST_CHECK_PLUGIN(apetag)
 369 AG_GST_CHECK_PLUGIN(audiofx)
 370 AG_GST_CHECK_PLUGIN(audioparsers)
 371 AG_GST_CHECK_PLUGIN(auparse)
 372 AG_GST_CHECK_PLUGIN(autodetect)
 373 AG_GST_CHECK_PLUGIN(avi)
 374 AG_GST_CHECK_PLUGIN(cutter)
 375 AG_GST_CHECK_PLUGIN(debugutils)
 376 AG_GST_CHECK_PLUGIN(deinterlace)
 377 AG_GST_CHECK_PLUGIN(dtmf)
 378 AG_GST_CHECK_PLUGIN(effectv)
 379 AG_GST_CHECK_PLUGIN(equalizer)
 380 AG_GST_CHECK_PLUGIN(flv)
 381 AG_GST_CHECK_PLUGIN(flx)
 382 AG_GST_CHECK_PLUGIN(goom)
 383 AG_GST_CHECK_PLUGIN(goom2k1)
 384 AG_GST_CHECK_PLUGIN(icydemux)
 385 AG_GST_CHECK_PLUGIN(id3demux)
 386 AG_GST_CHECK_PLUGIN(imagefreeze)
 387 AG_GST_CHECK_PLUGIN(interleave)
 388 AG_GST_CHECK_PLUGIN(isomp4)
 389 AG_GST_CHECK_PLUGIN(law)
 390 AG_GST_CHECK_PLUGIN(level)
 391 AG_GST_CHECK_PLUGIN(matroska)
 392 AG_GST_CHECK_PLUGIN(monoscope)
 393 AG_GST_CHECK_PLUGIN(multifile)
 394 AG_GST_CHECK_PLUGIN(multipart)
 395 AG_GST_CHECK_PLUGIN(replaygain)
 396 AG_GST_CHECK_PLUGIN(rtp)
 397 AG_GST_CHECK_PLUGIN(rtpmanager)
 398 AG_GST_CHECK_PLUGIN(rtsp)
 399 AG_GST_CHECK_PLUGIN(shapewipe)
 400 AG_GST_CHECK_PLUGIN(smpte)
 401 AG_GST_CHECK_PLUGIN(spectrum)
 402 AG_GST_CHECK_PLUGIN(udp)
 403 AG_GST_CHECK_PLUGIN(videobox)
 404 AG_GST_CHECK_PLUGIN(videocrop)
 405 AG_GST_CHECK_PLUGIN(videofilter)
 406 AG_GST_CHECK_PLUGIN(videomixer)
 407 AG_GST_CHECK_PLUGIN(wavenc)
 408 AG_GST_CHECK_PLUGIN(wavparse)
 409 AG_GST_CHECK_PLUGIN(y4m)
 410
 411 dnl disable experimental plug-ins
 412 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 413   AG_GST_DISABLE_PLUGIN(monoscope)
 414 fi
 415
 416 dnl *** sys plug-ins ***
 417
 418 echo
 419 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 420 echo
 421
 422 dnl DirectSound
 423 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 424 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 425   HAVE_DIRECTSOUND="no"
 426   save_CFLAGS="$CFLAGS"
 427   save_LDFLAGS="$LDFLAGS"
 428   save_LIBS="$LIBS"
 429   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 430   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 431   LIBS="$LIBS -ldsound -ldxerr9 -luser32 -lole32"
 432   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 433   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 434 #include <windows.h>
 435 #include <dxerr9.h>
 436 #include <dsound.h>
 437 ]], [[
 438   DXGetErrorString9 (0);
 439   DirectSoundCreate(NULL, NULL, NULL);
 440   CLSIDFromString(NULL, NULL);
 441 ]])
 442 ],
 443     [HAVE_DIRECTSOUND="yes"],
 444     [HAVE_DIRECTSOUND="no"])
 445   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 446   CFLAGS=$save_CFLAGS
 447   LDFLAGS=$save_LDFLAGS
 448   LIBS=$save_LIBS
 449
 450   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 451     dnl this is much more than we want
 452     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32 -lole32"
 453     AC_SUBST(DIRECTSOUND_CFLAGS)
 454     AC_SUBST(DIRECTSOUND_LDFLAGS)
 455     AC_SUBST(DIRECTSOUND_LIBS)
 456   fi
 457   AC_SUBST(HAVE_DIRECTSOUND)
 458 ])
 459
 460 dnl *** Win32 WaveOut ***
 461 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 462 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 463   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 464 ])
 465
 466 dnl *** OSS audio *** (Linux, *BSD)
 467 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 468 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 469  HAVE_OSS="yes"
 470 dnl Linux and newer BSD versions :
 471  AC_CHECK_HEADER(sys/soundcard.h, [
 472    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 473    ] , [
 474 dnl Some old BSD versions and also newer OpenBSD versions :
 475    AC_CHECK_HEADER(soundcard.h, [
 476      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 477      ], [
 478   dnl Some old BSD versions :
 479      AC_CHECK_HEADER(machine/soundcard.h, [
 480        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 481          [Define if OSS includes are in /machine/])
 482        ], [
 483        HAVE_OSS="no"
 484      ])
 485    ])
 486  ])
 487 ])
 488
 489 dnl *** oss4 ***
 490 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 491 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 492   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 493   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 494       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 495       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 496 ])
 497
 498 dnl *** OSX Audio ***
 499 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 500 HAVE_IOS="no"
 501 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 502   AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 503     [HAVE_OSX_AUDIO="yes"],
 504     [AC_CHECK_HEADER(CoreAudio/CoreAudioTypes.h,
 505     [
 506       HAVE_OSX_AUDIO="yes"
 507       HAVE_IOS="yes"
 508     ], [
 509       HAVE_OSX_AUDIO="no"
 510       HAVE_IOS="no"
 511     ])]
 512   )
 513 ])
 514 if test "x$HAVE_IOS" = "xyes"; then
 515   AC_DEFINE(HAVE_IOS, 1, [building for iOS platofrm])
 516 fi
 517 AM_CONDITIONAL(HAVE_IOS, test "x$HAVE_IOS" = "xyes")
 518
 519 dnl *** OS X video ***
 520 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 521 HAVE_OSX_VIDEO="no"
 522 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 523   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 524
 525   dnl in case header OpenGL/gl.h is found on other platforms (or older, unsupported OS X)
 526   dnl also require Snow Leopard or newer
 527
 528   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 529         #include <AvailabilityMacros.h>
 530         #if MAC_OS_X_VERSION_MIN_REQUIRED < 1060
 531         #error Too old OSX version
 532         #endif
 533       ]], [[return 0;]])],[HAVE_OSX_VIDEO="yes"],[HAVE_OSX_VIDEO="no"])
 534 ])
 535
 536 dnl *** Video 4 Linux 2 ***
 537 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 538 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 539 HAVE_GST_V4L2=no
 540 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], video4linux2, [
 541   AC_MSG_CHECKING([Checking for video4linux2 header ...])
 542   AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_GST_V4L2=yes ],
 543   [
 544     AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_GST_V4L2=yes ],
 545     [
 546       AC_CHECK_HEADER(sys/videoio.h, [ HAVE_GST_V4L2=yes ])
 547     ])
 548   ])
 549   if test "x$HAVE_VIDEODEV" = "xno"; then
 550      AC_MSG_WARN([video4linux2 was not found])
 551   fi
 552 ])
 553
 554 # Optional gudev for device probing
 555 AC_ARG_WITH([gudev],
 556   AS_HELP_STRING([--with-gudev],[device detection with gudev]),
 557   [],
 558   [with_gudev=check])
 559 if test x$HAVE_GST_V4L2 = xyes; then
 560   if test x$with_gudev != xno; then
 561     PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 147 ],
 562       [ AC_DEFINE(HAVE_GUDEV, 1,
 563           [Whether gudev is available for device detection])
 564       ],
 565       [true])
 566   fi
 567 fi
 568
 569 AC_SUBST(GUDEV_CFLAGS)
 570 AC_SUBST(GUDEV_LIBS)
 571
 572 # Make libv4l2 non-automagic
 573 AC_ARG_WITH([libv4l2],
 574   AS_HELP_STRING([--with-libv4l2],[support video buffer conversion using libv4l2]),
 575   [],
 576   [with_libv4l2=check])
 577 if test x$HAVE_GST_V4L2 = xyes; then
 578   if test x$with_libv4l2 != xno; then
 579       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 580           [ have_libv4l2=yes
 581             AC_DEFINE(HAVE_LIBV4L2, 1,
 582                 [Whether libv4l2 is available for video buffer conversion])
 583           ], [
 584           have_libv4l2=no
 585           ])
 586   else
 587     have_libv4l2=no
 588   fi
 589 fi
 590
 591 dnl Allow enabling v4l2 device probing
 592 AS_CASE([$host],
 593     [*-*linux*],
 594       [AS_CASE([$host_cpu],
 595         [arm*], [
 596           enable_v4l2_probe="yes"],
 597         [aarch64*], [
 598           enable_v4l2_probe="yes"])])
 599 AC_ARG_ENABLE(
 600   v4l2-probe,
 601   AC_HELP_STRING(
 602     [--enable-v4l2-probe],
 603     [enable V4L2 plugin to probe devices @<:@default=no@:>@]))
 604 if test "x$enable_v4l2_probe" = "xyes"; then
 605   AC_DEFINE(GST_V4L2_ENABLE_PROBE, 1,
 606     [Define if Video4Linux probe shall be run at plugin load])
 607 fi
 608
 609 dnl Check for X11
 610 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 611 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 612                   [ximagesrc], [
 613   PKG_CHECK_MODULES([X], [x11], [
 614     HAVE_X="yes"
 615     dnl check for Xfixes
 616     PKG_CHECK_MODULES([XFIXES], [ xfixes ], [
 617       AC_DEFINE(HAVE_XFIXES, 1, [Defined if Xfixes is available])
 618     ], [ HAVE_XFIXES="no" ])
 619
 620     dnl check for Xdamage
 621     PKG_CHECK_MODULES([XDAMAGE], [ xdamage ], [
 622       AC_DEFINE(HAVE_XDAMAGE, 1, [Defined if Xdamage is available])
 623     ], [ HAVE_XDAMAGE="no" ])
 624
 625     dnl check for X Shm
 626     PKG_CHECK_MODULES([XEXT], [ xext ], [
 627       AC_CHECK_LIB([Xext], [ XShmAttach ], [
 628         AC_DEFINE(HAVE_XSHM, 1, [Defined if XShm is available])
 629         XSHM_LIBS="$XEXT_LIBS"
 630         XSHM_CFLAGS="$XEXT_CFLAGS"
 631       ], [ HAVE_XEXT="no" ] , [ $X_LIBS ])
 632     ])
 633     AC_SUBST(XSHM_LIBS)
 634     AC_SUBST(XSHM_CFLAGS)
 635   ], [ HAVE_X="no" ])
 636 ])
 637
 638 dnl *** ext plug-ins ***
 639 dnl keep this list sorted alphabetically !
 640
 641 if test "x$BUILD_EXTERNAL" = "xyes"; then
 642
 643 echo
 644 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 645 echo
 646
 647 dnl *** aalib ***
 648 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 649 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 650   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 651 ])
 652
 653 dnl *** cairo ***
 654 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 655 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering and gobject bindings], cairo, [
 656   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.10.0 cairo-gobject >= 1.10.0)
 657 ])
 658
 659 dnl *** FLAC ***
 660 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 661 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 662   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 663 ])
 664
 665 dnl *** GDK pixbuf ***
 666 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 667 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 668   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 669 ])
 670
 671 dnl *** gtk+ ***
 672 HAVE_GTK3_GL="no"
 673 translit(dnm, m, l) AM_CONDITIONAL(USE_GTK3, true)
 674 AG_GST_CHECK_FEATURE(GTK3, [Gtk+ elements], gtk, [
 675   PKG_CHECK_MODULES(GTK3, gtk+-3.0, [
 676     AC_DEFINE([HAVE_GTK3], 1, [Define if Gtk+ 3.0 is installed])
 677     HAVE_GTK3="yes"
 678   ], [
 679     HAVE_GTK3="no"
 680   ])
 681   PKG_CHECK_MODULES(GTK3_GL, gtk+-3.0 >= 3.15.0, [
 682     GDK_WINDOWING="no"
 683     if test "x$GST_GL_HAVE_WINDOW_X11" = "x1" -a "x$GST_GL_HAVE_PLATFORM_GLX" = "x1"; then
 684       PKG_CHECK_MODULES(GTK3_X11, gtk+-x11-3.0, [
 685         GTK3_CFLAGS="$GTK3_CFLAGS $GTK3_X11_CFLAGS"
 686         GTK3_LIBS="$GTK3_LIBS $GTK3_X11_LIBS"
 687         GDK_WINDOWING="yes"
 688       ], [AC_MSG_NOTICE([Could not find Gtk X11 integration])])
 689     fi
 690     if test "x$GST_GL_HAVE_WINDOW_WAYLAND" = "x1" -a "x$GST_GL_HAVE_PLATFORM_EGL" = "x1"; then
 691       PKG_CHECK_MODULES(GTK3_WAYLAND, gtk+-wayland-3.0, [
 692         GTK3_CFLAGS="$GTK3_CFLAGS $GTK3_WAYLAND_CFLAGS"
 693         GTK3_LIBS="$GTK3_LIBS $GTK3_WAYLAND_LIBS"
 694         GDK_WINDOWING="yes"
 695       ], [AC_MSG_NOTICE([Could not find Gtk Wayland integration])])
 696     fi
 697     if test "x$GDK_WINDOWING" = "xyes" -a "x$HAVE_GST_GL" = "xyes"; then
 698       AC_DEFINE([HAVE_GTK3_GL], 1, [Define if Gtk+ 3.0 GL is installed])
 699       HAVE_GTK3_GL="yes"
 700     fi
 701   ], [
 702       HAVE_GTK3_GL="no"
 703   ])
 704 ])
 705 AM_CONDITIONAL(USE_GTK3_GL, test "x$HAVE_GTK3_GL" = "xyes")
 706
 707 dnl *** Jack ***
 708 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 709 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 710   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 711   AC_SUBST(JACK_CFLAGS)
 712   AC_SUBST(JACK_LIBS)
 713
 714   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 715   if test x$HAVE_JACK_0_120_1 = xyes; then
 716     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 717   fi
 718   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 719   if test x$HAVE_JACK_1_9_7 = xyes; then
 720     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 721   fi
 722
 723 ])
 724
 725 dnl *** jpeg ***
 726 dnl FIXME: we could use header checks here as well IMO
 727 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 728 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 729   AC_ARG_WITH(jpeg-mmx,
 730     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 731   OLD_LIBS="$LIBS"
 732   if test x$with_jpeg_mmx != x; then
 733     LIBS="$LIBS -L$with_jpeg_mmx"
 734   fi
 735   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 736   JPEG_LIBS="$LIBS -ljpeg-mmx"
 737   LIBS="$OLD_LIBS"
 738   if test x$HAVE_JPEG != xyes; then
 739     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 740     JPEG_LIBS="-ljpeg"
 741   fi
 742   AC_SUBST(JPEG_LIBS)
 743 ])
 744
 745 dnl *** lame ***
 746 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
 747 AG_GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
 748   AG_GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, $LIBM, lame/lame.h,
 749   [
 750     HAVE_LAME="yes"
 751     LAME_LIBS="-lmp3lame $LIBM"
 752     dnl is lame presets available
 753     LAME_CFLAGS=""
 754     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <lame/lame.h>]], [[ int preset = MEDIUM ]])],[LAME_CFLAGS="-DGSTLAME_PRESET"],[LAME_CFLAGS=""
 755     ])
 756     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <lame/lame.h>]], [[
 757         void *ptr = &lame_set_VBR_quality
 758       ]])],[LAME_CFLAGS="$LAME_CFLAGS -DHAVE_LAME_SET_VBR_QUALITY"],[LAME_CFLAGS="$LAME_CFLAGS"
 759     ])
 760   AC_SUBST(LAME_CFLAGS)
 761   AC_SUBST(LAME_LIBS)
 762   ])
 763 ])
 764
 765 dnl *** libcaca ***
 766 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 767 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 768   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 769 ])
 770
 771 dnl *** libdv ***
 772 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 773 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 774   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 775 ])
 776
 777 dnl *** libpng ***
 778 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 779 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 780   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 781   if test $HAVE_LIBPNG = "yes"; then
 782     PKG_CHECK_MODULES(LIBPNG_1_5, libpng >= 1.5.1, [
 783         AC_DEFINE(HAVE_LIBPNG_1_5, 1, [Defined if libpng version is 1.5.1 or newer])
 784       ], [true])
 785   fi
 786 ])
 787
 788 dnl *** mpg123 ***
 789 translit(dnm, m, l) AM_CONDITIONAL(USE_MPG123, true)
 790 AG_GST_CHECK_FEATURE(MPG123, [mpg123 audio decoder], mpg123, [
 791   PKG_CHECK_MODULES(MPG123, libmpg123 >= 1.13, HAVE_MPG123="yes", HAVE_MPG123="no")
 792   AC_SUBST(MPG123_CFLAGS)
 793   AC_SUBST(MPG123_LIBS)
 794 ])
 795
 796 dnl *** pulseaudio ***
 797 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 798 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 799
 800   dnl used in ext/pulse/pulseutil.c
 801   AC_CHECK_HEADERS([process.h])
 802
 803   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 2.0)
 804 ])
 805
 806 dnl *** dv1394 ***
 807 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 808 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 809   dnl first test for libraw1394 >= 2.0.0
 810   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 811   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 812   dnl now see how far we got
 813   if test x$HAVE_RAW1394 = xyes && \
 814      test x$HAVE_LIBIEC61883 = xyes; then
 815        AG_GST_CHECK_LIBHEADER(AVC1394,
 816         avc1394, avc1394_send_command, $RAW1394_LIBS,
 817         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 818        AG_GST_CHECK_LIBHEADER(ROM1394,
 819         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 820         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 821        if test x$HAVE_AVC1394 = xyes && \
 822           test x$HAVE_AVC1394 = xyes && \
 823           test x$HAVE_ROM1394 = xyes; then
 824           HAVE_DV1394=yes
 825           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 826           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 827           AC_SUBST(DV1394_CFLAGS)
 828           AC_SUBST(DV1394_LIBS)
 829         fi
 830   else
 831        if test x$HAVE_RAW1394 = xno; then
 832           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 833           AG_GST_CHECK_LIBHEADER(AVC1394,
 834            avc1394, avc1394_send_command, $RAW1394_LIBS,
 835            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 836           AG_GST_CHECK_LIBHEADER(ROM1394,
 837            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 838            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 839           if test x$HAVE_RAW1394 = xyes && \
 840              test x$HAVE_AVC1394 = xyes && \
 841              test x$HAVE_ROM1394 = xyes; then
 842              HAVE_DV1394=yes
 843              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 844              DV1394_CFLAGS="$RAW1394_CFLAGS"
 845              if test x$HAVE_LIBIEC61883 = xyes; then
 846                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 847                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 848              fi
 849              AC_SUBST(DV1394_CFLAGS)
 850              AC_SUBST(DV1394_LIBS)
 851            fi
 852          fi
 853   fi
 854 ])
 855 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 856
 857 dnl *** shout2 ***
 858 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 859 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 860   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 861 ])
 862
 863 dnl *** soup ***
 864 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 865 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 866   PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.48, [HAVE_SOUP="yes"], [HAVE_SOUP="no"])
 867   AC_SUBST(SOUP_CFLAGS)
 868   AC_SUBST(SOUP_LIBS)
 869 ])
 870
 871 dnl *** speex ***
 872 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 873 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 874   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 875 ])
 876
 877 dnl *** taglib ***
 878 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 879 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 880   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 881   if test "x$HAVE_CXX" != "xyes"; then
 882     USE_TAGLIB=false
 883     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 884   else
 885     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 886     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 887         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 888       ], [
 889         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 890     ])
 891     AC_SUBST(TAGLIB_CXXFLAGS)
 892   fi
 893 ])
 894
 895 dnl *** twolame ***
 896 translit(dnm, m, l) AM_CONDITIONAL(USE_TWOLAME, true)
 897 AG_GST_CHECK_FEATURE(TWOLAME, [twolame], twolame, [
 898   PKG_CHECK_MODULES(TWOLAME, twolame >= 0.3.10, [
 899       HAVE_TWOLAME="yes"], [
 900       HAVE_TWOLAME="no"
 901   ])
 902   AC_SUBST(TWOLAME_CFLAGS)
 903   AC_SUBST(TWOLAME_LIBS)
 904 ])
 905
 906
 907 dnl *** vpx ***
 908 translit(dnm, m, l) AM_CONDITIONAL(USE_VPX, vpx)
 909 AG_GST_CHECK_FEATURE(VPX, [VPX decoder], vpx, [
 910   PKG_CHECK_MODULES(VPX, vpx >= 1.1.0, [HAVE_VPX="yes"], [HAVE_VPX="no"])
 911   HAVE_VP8=no
 912   HAVE_VP9=no
 913
 914   if test $HAVE_VPX = "yes"; then
 915     OLD_LIBS="$LIBS"
 916     OLD_CFLAGS="$CFLAGS"
 917     CFLAGS="$CFLAGS $VPX_CFLAGS"
 918     LIBS="$LIBS $VPX_LIBS"
 919     AC_CHECK_LIB(vpx, vpx_codec_vp8_cx_algo, [
 920       HAVE_VP8=yes
 921       AC_DEFINE(HAVE_VP8_ENCODER, 1, [Defined if the VP8 encoder is available])
 922     ])
 923     AC_CHECK_LIB(vpx, vpx_codec_vp8_dx_algo, [
 924       HAVE_VP8=yes
 925       AC_DEFINE(HAVE_VP8_DECODER, 1, [Defined if the VP8 decoder is available])
 926     ])
 927
 928     PKG_CHECK_MODULES(VPX_130, vpx >= 1.3.0, [
 929       AC_CHECK_LIB(vpx, vpx_codec_vp9_cx_algo, [
 930         HAVE_VP9=yes
 931         AC_DEFINE(HAVE_VP9_ENCODER, 1, [Defined if the VP9 encoder is available])
 932       ])
 933       AC_CHECK_LIB(vpx, vpx_codec_vp9_dx_algo, [
 934         HAVE_VP9=yes
 935         AC_DEFINE(HAVE_VP9_DECODER, 1, [Defined if the VP9 decoder is available])
 936       ])
 937     ], [true])
 938
 939     PKG_CHECK_MODULES(VPX_140, vpx >= 1.4.0, [
 940       AC_DEFINE(HAVE_VPX_1_4, 1, [Defined if the VPX library version is 1.4 or bigger])
 941     ], [true])
 942
 943     LIBS="$OLD_LIBS"
 944     CFLAGS="$OLD_CFLAGS"
 945   fi
 946   AC_SUBST(VPX_LIBS)
 947   AC_SUBST(VPX_CFLAGS)
 948 ])
 949
 950 dnl *** wavpack ***
 951 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 952 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 953   AG_GST_PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.60.0)
 954 ])
 955
 956 dnl *** qtdemux & matroska prefer to have zlib ***
 957 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 958 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 959   AG_GST_CHECK_LIBHEADER(ZLIB,
 960     z, uncompress,, zlib.h, [
 961     HAVE_ZLIB="yes"
 962     ZLIB_LIBS="-lz"
 963     AC_SUBST(ZLIB_LIBS)
 964   ])
 965 ])
 966
 967 dnl *** matroska prefers to have bz2 ***
 968 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 969 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 970   save_LIBS=$LIBS
 971   LIBS="$LIBS -lbz2"
 972   AC_MSG_CHECKING([for BZ2_bzlibVersion in -lbz2])
 973   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <bzlib.h>]], [[const char *version = BZ2_bzlibVersion ();]])],[HAVE_BZ2=yes],[HAVE_BZ2=no])
 974   AC_MSG_RESULT($HAVE_BZ2)
 975   LIBS=$save_LIBS
 976   if test "x$HAVE_BZ2" = "xyes"; then
 977     BZ2_LIBS="-lbz2"
 978   fi
 979   AC_SUBST(BZ2_LIBS)
 980 ])
 981
 982 else
 983
 984 dnl not building plugins with external dependencies,
 985 dnl but we still need to set the conditionals
 986 AM_CONDITIONAL(USE_AALIB, false)
 987 AM_CONDITIONAL(USE_BZ2, false)
 988 AM_CONDITIONAL(USE_CAIRO, false)
 989 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 990 AM_CONDITIONAL(USE_DV1394, false)
 991 AM_CONDITIONAL(USE_FLAC, false)
 992 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 993 AM_CONDITIONAL(USE_JACK, false)
 994 AM_CONDITIONAL(USE_JPEG, false)
 995 AM_CONDITIONAL(USE_LAME, false)
 996 AM_CONDITIONAL(USE_LIBCACA, false)
 997 AM_CONDITIONAL(USE_LIBDV, false)
 998 AM_CONDITIONAL(USE_LIBIEC61883, false)
 999 AM_CONDITIONAL(USE_LIBPNG, false)
1000 AM_CONDITIONAL(USE_MPG123, false)
1001 AM_CONDITIONAL(USE_OSS, false)
1002 AM_CONDITIONAL(USE_OSS4, false)
1003 AM_CONDITIONAL(USE_OSX_AUDIO, false)
1004 AM_CONDITIONAL(USE_OSX_VIDEO, false)
1005 AM_CONDITIONAL(USE_PULSE, false)
1006 AM_CONDITIONAL(USE_SHOUT2, false)
1007 AM_CONDITIONAL(USE_SOUP, false)
1008 AM_CONDITIONAL(USE_SPEEX, false)
1009 AM_CONDITIONAL(USE_TAGLIB, false)
1010 AM_CONDITIONAL(USE_TWOLAME, false)
1011 AM_CONDITIONAL(USE_VPX, false)
1012 AM_CONDITIONAL(USE_WAVEFORM, false)
1013 AM_CONDITIONAL(USE_WAVPACK, false)
1014 AM_CONDITIONAL(USE_X, false)
1015 AM_CONDITIONAL(USE_ZLIB, false)
1016
1017 fi dnl of EXT plugins
1018
1019 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1020
1021 dnl Overview:
1022 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1023 dnl GST_*:              flags shared by all built objects
1024 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1025 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1026 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1027 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1028
1029 dnl GST_OPTION_CFLAGS
1030 if test "x$USE_DEBUG" = xyes; then
1031    PROFILE_CFLAGS="-g"
1032 fi
1033 AC_SUBST(PROFILE_CFLAGS)
1034
1035 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1036   dnl Define _only_ for git (not pre-releases or releases)
1037   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1038 else
1039   DEPRECATED_CFLAGS=""
1040 fi
1041 AC_SUBST(DEPRECATED_CFLAGS)
1042
1043 VISIBILITY_CFLAGS=""
1044 AS_COMPILER_FLAG([-fvisibility=hidden], [VISIBILITY_CFLAGS="-fvisibility=hidden"])
1045 AC_SUBST(VISIBILITY_CFLAGS)
1046
1047 VISIBILITY_CXXFLAGS=""
1048 if test "x$HAVE_CXX" = "xyes"; then
1049   AS_CXX_COMPILER_FLAG([-fvisibility=hidden], [VISIBILITY_CXXFLAGS="-fvisibility=hidden"])
1050 fi
1051 AC_SUBST(VISIBILITY_CXXFLAGS)
1052
1053 dnl disable strict aliasing
1054 AS_COMPILER_FLAG([-fno-strict-aliasing], [EXTRA_CFLAGS="-fno-strict-aliasing"])
1055 AC_SUBST(EXTRA_CFLAGS)
1056
1057 dnl every flag in GST_OPTION_CFLAGS, GST_OPTION_CXXFLAGS and GST_OPTION_OBJCFLAGS can be overridden
1058 dnl at make time with e.g. make ERROR_CFLAGS=""
1059 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1060 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1061 GST_OPTION_OBJCFLAGS="\$(WARNING_OBJCFLAGS) \$(ERROR_OBJCFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1062 AC_SUBST(GST_OPTION_CFLAGS)
1063 AC_SUBST(GST_OPTION_CXXFLAGS)
1064 AC_SUBST(GST_OPTION_OBJCFLAGS)
1065
1066 dnl our libraries need to be versioned correctly
1067 AC_SUBST(GST_LT_LDFLAGS)
1068
1069 dnl FIXME: do we want to rename to GST_ALL_* ?
1070 dnl prefer internal headers to already installed ones
1071 dnl also add builddir include for enumtypes and marshal
1072 dnl add ERROR_CFLAGS, but overridable
1073 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
1074 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $EXTRA_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(VISIBILITY_CXXFLAGS)"
1075 GST_OBJCFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $EXTRA_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_OBJCFLAGS)"
1076 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $EXTRA_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS) \$(VISIBILITY_CFLAGS)"
1077 AC_SUBST(GST_CFLAGS)
1078 AC_SUBST(GST_CXXFLAGS)
1079 AC_SUBST(GST_OBJCFLAGS)
1080 AC_SUBST(GST_LIBS)
1081
1082 dnl LDFLAGS really should only contain flags, not libs - they get added before
1083 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1084 GST_ALL_LDFLAGS="-no-undefined"
1085 if test "x${enable_Bsymbolic}" = "xyes"; then
1086   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
1087 fi
1088 AC_SUBST(GST_ALL_LDFLAGS)
1089
1090 dnl this really should only contain flags, not libs - they get added before
1091 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1092 GST_PLUGIN_LDFLAGS="-module -avoid-version $GST_ALL_LDFLAGS"
1093 AC_SUBST(GST_PLUGIN_LDFLAGS)
1094
1095 dnl *** output files ***
1096
1097 $MKDIR_P tests/check/orc
1098
1099 dnl keep this alphabetic per directory, please
1100 AC_CONFIG_FILES(
1101 Makefile
1102 gst/Makefile
1103 gst/alpha/Makefile
1104 gst/apetag/Makefile
1105 gst/audiofx/Makefile
1106 gst/audioparsers/Makefile
1107 gst/auparse/Makefile
1108 gst/autodetect/Makefile
1109 gst/avi/Makefile
1110 gst/cutter/Makefile
1111 gst/deinterlace/Makefile
1112 gst/dtmf/Makefile
1113 gst/debugutils/Makefile
1114 gst/effectv/Makefile
1115 gst/equalizer/Makefile
1116 gst/flv/Makefile
1117 gst/goom/Makefile
1118 gst/goom2k1/Makefile
1119 gst/id3demux/Makefile
1120 gst/icydemux/Makefile
1121 gst/imagefreeze/Makefile
1122 gst/interleave/Makefile
1123 gst/isomp4/Makefile
1124 gst/law/Makefile
1125 gst/level/Makefile
1126 gst/matroska/Makefile
1127 gst/monoscope/Makefile
1128 gst/multifile/Makefile
1129 gst/multipart/Makefile
1130 gst/replaygain/Makefile
1131 gst/rtp/Makefile
1132 gst/rtpmanager/Makefile
1133 gst/rtsp/Makefile
1134 gst/shapewipe/Makefile
1135 gst/smpte/Makefile
1136 gst/spectrum/Makefile
1137 gst/udp/Makefile
1138 gst/videobox/Makefile
1139 gst/videocrop/Makefile
1140 gst/videofilter/Makefile
1141 gst/videomixer/Makefile
1142 gst/wavenc/Makefile
1143 gst/wavparse/Makefile
1144 gst/flx/Makefile
1145 gst/y4m/Makefile
1146 ext/Makefile
1147 ext/aalib/Makefile
1148 ext/cairo/Makefile
1149 ext/dv/Makefile
1150 ext/flac/Makefile
1151 ext/gdk_pixbuf/Makefile
1152 ext/gtk/Makefile
1153 ext/jack/Makefile
1154 ext/jpeg/Makefile
1155 ext/lame/Makefile
1156 ext/libcaca/Makefile
1157 ext/libpng/Makefile
1158 ext/mpg123/Makefile
1159 ext/pulse/Makefile
1160 ext/raw1394/Makefile
1161 ext/shout2/Makefile
1162 ext/soup/Makefile
1163 ext/speex/Makefile
1164 ext/taglib/Makefile
1165 ext/twolame/Makefile
1166 ext/vpx/Makefile
1167 ext/wavpack/Makefile
1168 sys/Makefile
1169 sys/directsound/Makefile
1170 sys/oss/Makefile
1171 sys/oss4/Makefile
1172 sys/osxaudio/Makefile
1173 sys/osxvideo/Makefile
1174 sys/v4l2/Makefile
1175 sys/waveform/Makefile
1176 sys/ximage/Makefile
1177 po/Makefile.in
1178 tests/Makefile
1179 tests/check/Makefile
1180 tests/examples/Makefile
1181 tests/examples/audiofx/Makefile
1182 tests/examples/cairo/Makefile
1183 tests/examples/equalizer/Makefile
1184 tests/examples/gtk/Makefile
1185 tests/examples/jack/Makefile
1186 tests/examples/level/Makefile
1187 tests/examples/rtp/Makefile
1188 tests/examples/shapewipe/Makefile
1189 tests/examples/spectrum/Makefile
1190 tests/examples/v4l2/Makefile
1191 tests/files/Makefile
1192 tests/icles/Makefile
1193 common/Makefile
1194 common/m4/Makefile
1195 m4/Makefile
1196 docs/Makefile
1197 docs/plugins/Makefile
1198 docs/version.entities
1199 pkgconfig/Makefile
1200 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1201 )
1202 AC_OUTPUT
1203
1204 AG_GST_OUTPUT_PLUGINS
1205 ORC_OUTPUT
1206