configure.ac

   1 # clutter package version number, (as distinct from shared library version)
   2 # An odd micro number indicates in-progress development from Git
   3 # An even micro number indicates a released version
   4 #
   5 # Making a point release:
   6 # - increase clutter_micro_version to the next even number
   7 # - increase clutter_interface_age to the next even number
   8 # After the release:
   9 # - increase clutter_micro_version to the next odd number
  10 # - increase clutter_interface_version to the next odd number
  11 m4_define([clutter_major_version], [1])
  12 m4_define([clutter_minor_version], [9])
  13 m4_define([clutter_micro_version], [1])
  14
  15 # • for stable releases: increase the interface age by 1 for each release;
  16 #   if the API changes, set to 0. interface_age and binary_age are used to
  17 #   create the soname of the shared object:
  18 #
  19 #  (<minor> * 100 + <micro>) - <interface_age>
  20 #
  21 # this allows using the same soname for different micro-releases in case
  22 # no API was added or deprecated. for instance:
  23 #
  24 #   clutter 1.2.0  -> 100 * 2 + 0  = 200, interface age = 0 -> 200
  25 #   clutter 1.2.2  -> 100 * 2 + 2  = 202, interface age = 2 -> 200
  26 #   clutter 1.2.4  -> 100 * 2 + 4  = 204, interface age = 4 -> 200
  27 #   [ API addition, deprecation ]
  28 #   clutter 1.2.6  -> 100 * 2 + 6  = 206, interface age = 0 -> 206
  29 #   clutter 1.2.8  -> 100 * 2 + 8  = 208, interface age = 2 -> 206
  30 #   clutter 1.2.10 -> 100 * 2 + 10 = 210, interface age = 4 -> 206
  31 #   ...
  32 #
  33 # • for development releases: keep clutter_interface_age to 0
  34 m4_define([clutter_interface_age], [0])
  35
  36 m4_define([clutter_binary_age], [m4_eval(100 * clutter_minor_version + clutter_micro_version)])
  37
  38 m4_define([clutter_release_status],
  39           [m4_if(m4_eval(clutter_micro_version % 2), [1], [git],
  40                  [m4_if(m4_eval(clutter_minor_version % 2), [1], [snapshot],
  41                                                                  [release])])])
  42
  43 m4_define([clutter_version], [clutter_major_version.clutter_minor_version.clutter_micro_version])
  44
  45 # change this only when breaking the API
  46 m4_define([clutter_api_version], [1.0])
  47
  48 AC_PREREQ([2.63])
  49
  50 AC_INIT([clutter],
  51         [clutter_version],
  52         [http://bugzilla.gnome.org/enter_bug.cgi?product=clutter],
  53         [clutter],
  54         [http://www.clutter-project.org])
  55
  56 AC_CONFIG_SRCDIR([clutter/clutter.h])
  57 AC_CONFIG_HEADERS([config.h])
  58 AC_CONFIG_AUX_DIR([build])
  59 AC_CONFIG_MACRO_DIR([build/autotools])
  60
  61 AM_INIT_AUTOMAKE([1.11 foreign -Wno-portability no-define no-dist-gzip dist-xz tar-ustar])
  62 AM_SILENT_RULES([yes])
  63
  64 AC_SUBST([CLUTTER_MAJOR_VERSION],  [clutter_major_version])
  65 AC_SUBST([CLUTTER_MINOR_VERSION],  [clutter_minor_version])
  66 AC_SUBST([CLUTTER_MICRO_VERSION],  [clutter_micro_version])
  67 AC_SUBST([CLUTTER_VERSION],        [clutter_version])
  68 AC_SUBST([CLUTTER_API_VERSION],    [clutter_api_version])
  69 AC_SUBST([CLUTTER_API_VERSION_AM], [$CLUTTER_MAJOR_VERSION\_0])
  70 AC_SUBST([CLUTTER_RELEASE_STATUS], [clutter_release_status])
  71
  72 m4_define([lt_current],  [m4_eval(100 * clutter_minor_version + clutter_micro_version - clutter_interface_age)])
  73 m4_define([lt_revision], [clutter_interface_age])
  74 m4_define([lt_age],      [m4_eval(clutter_binary_age - clutter_interface_age)])
  75 CLUTTER_LT_CURRENT=lt_current
  76 CLUTTER_LT_REV=lt_revision
  77 CLUTTER_LT_AGE=lt_age
  78 CLUTTER_LT_VERSION="$CLUTTER_LT_CURRENT:$CLUTTER_LT_REV:$CLUTTER_LT_AGE"
  79 CLUTTER_LT_LDFLAGS="-version-info $CLUTTER_LT_VERSION"
  80
  81 AC_PROG_SED
  82
  83 AC_CANONICAL_HOST
  84 AC_MSG_CHECKING([if building for some Win32 platform])
  85 AS_CASE([$host],
  86         [*-*-mingw*|*-*-cygwin*],
  87         [
  88           CLUTTER_LT_LDFLAGS="$CLUTTER_LT_LDFLAGS -no-undefined"
  89           platform_win32=yes
  90         ],
  91
  92         [platform_win32=no]
  93 )
  94 AC_MSG_RESULT([$platform_win32])
  95 AM_CONDITIONAL(OS_WIN32, [test "$platform_win32" = "yes"])
  96
  97 AC_CHECK_HEADER([OpenGL/gl.h], [platform_quartz=yes], [platform_quartz=no])
  98 AM_CONDITIONAL(OS_QUARTZ, [test "$platform_quartz" = "yes"])
  99
 100 AC_SUBST(CLUTTER_LT_VERSION)
 101 AC_SUBST(CLUTTER_LT_LDFLAGS)
 102
 103 dnl ========================================================================
 104
 105 # Checks for programs.
 106 AM_PROG_CC_C_O
 107
 108 # require libtool >= 2.2
 109 LT_PREREQ([2.2.6])
 110 LT_INIT([disable-static])
 111
 112 # Checks for header files.
 113 AC_HEADER_STDC
 114
 115 # required versions for dependencies
 116 m4_define([glib_req_version],           [2.31.0])
 117 m4_define([cogl_req_version],           [1.9.1])
 118 m4_define([json_glib_req_version],      [0.12.0])
 119 m4_define([atk_req_version],            [2.1.5])
 120 m4_define([cairo_req_version],          [1.10])
 121 m4_define([pango_req_version],          [1.20])
 122 m4_define([gi_req_version],             [0.9.5])
 123 m4_define([uprof_req_version],          [0.3])
 124 m4_define([gtk_doc_req_version],        [1.15])
 125 m4_define([xfixes_req_version],         [3])
 126 m4_define([xcomposite_req_version],     [0.4])
 127
 128 AC_SUBST([GLIB_REQ_VERSION],       [glib_req_version])
 129 AC_SUBST([COGL_REQ_VERSION],       [cogl_req_version])
 130 AC_SUBST([JSON_GLIB_REQ_VERSION],  [json_glib_req_version])
 131 AC_SUBST([ATK_REQ_VERSION],        [atk_req_version])
 132 AC_SUBST([CAIRO_REQ_VERSION],      [cairo_req_version])
 133 AC_SUBST([PANGO_REQ_VERSION],      [pango_req_version])
 134 AC_SUBST([GI_REQ_VERSION],         [gi_req_version])
 135 AC_SUBST([UPROF_REQ_VERSION],      [uprof_req_version])
 136 AC_SUBST([GTK_DOC_REQ_VERSION],    [gtk_doc_req_version])
 137 AC_SUBST([XFIXES_REQ_VERSION],     [xfixes_req_version])
 138 AC_SUBST([XCOMPOSITE_REQ_VERSION], [xcomposite_req_version])
 139
 140 # Checks for typedefs, structures, and compiler characteristics.
 141 AM_PATH_GLIB_2_0([glib_req_version],
 142                  [],
 143                  [AC_MSG_ERROR([glib-2.0 is required])],
 144                  [gobject gthread gmodule-no-export])
 145
 146 # Check for -Bsymbolic-functions to avoid intra-library PLT jumps
 147 AC_ARG_ENABLE([Bsymbolic],
 148               [AS_HELP_STRING([--disable-Bsymbolic],
 149                               [Avoid linking with -Bsymbolic])],
 150               [],
 151               [
 152                 saved_LDFLAGS="${LDFLAGS}"
 153                 AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 154                 LDFLAGS=-Wl,-Bsymbolic-functions
 155                 AC_TRY_LINK([], [int main (void) { return 0; }],
 156                             [
 157                               AC_MSG_RESULT([yes])
 158                               enable_Bsymbolic=yes
 159                             ],
 160                             [
 161                               AC_MSG_RESULT([no])
 162                               enable_Bsymbolic=no
 163                             ])
 164                 LDFLAGS="${saved_LDFLAGS}"
 165               ])
 166
 167 AS_IF([test "x$enable_Bsymbolic" = "xyes"], [CLUTTER_LINK_FLAGS=-Wl[,]-Bsymbolic-functions])
 168 AC_SUBST(CLUTTER_LINK_FLAGS)
 169
 170 dnl ========================================================================
 171
 172 # defaults
 173 AS_IF([test "x$platform_win32" = "xyes"],  [CLUTTER_FLAVOUR=win32],
 174       [test "x$platform_quartz" = "xyes"], [CLUTTER_FLAVOUR=osx],
 175       [CLUTTER_FLAVOUR=glx])
 176
 177 FLAVOUR_LIBS=""
 178 FLAVOUR_CFLAGS=""
 179 CLUTTER_WINSYS_BASE=
 180 CLUTTER_WINSYS_BASE_LIB=
 181 CLUTTER_WINSYS=
 182
 183 experimental_backend=no
 184
 185 AC_ARG_WITH([flavour],
 186             [AS_HELP_STRING([--with-flavour=@<:@glx/opengl-egl-xlib/wayland/eglx/eglnative/osx/win32/cex100@:>@],
 187                             [Select the Clutter window system backend])],
 188             [CLUTTER_FLAVOUR=$with_flavour])
 189
 190 # base dependencies for core
 191 CLUTTER_BASE_PC_FILES="cogl-1.0 >= $COGL_REQ_VERSION cairo-gobject >= $CAIRO_REQ_VERSION atk >= $ATK_REQ_VERSION pangocairo >= $PANGO_REQ_VERSION cogl-pango-1.0 json-glib-1.0 >= $JSON_GLIB_REQ_VERSION"
 192
 193 # backend specific pkg-config files
 194 BACKEND_PC_FILES=""
 195
 196 dnl === Clutter windowing system backend ======================================
 197
 198 AS_CASE([$CLUTTER_FLAVOUR],
 199
 200         [glx],
 201         [
 202           CLUTTER_STAGE_TYPE="CLUTTER_TYPE_STAGE_X11"
 203
 204           SUPPORT_X11=1
 205           SUPPORT_XLIB=1
 206           SUPPORT_GLX=1
 207
 208           CLUTTER_WINSYS=x11
 209           CLUTTER_WINSYS_BASE=cogl
 210           CLUTTER_SONAME_INFIX=glx
 211
 212           # Mesa 7.3 added a GL pkg-config file, finally
 213           PKG_CHECK_EXISTS([gl],
 214                            [BACKEND_PC_FILES="$BACKEND_PC_FILES gl"],
 215                            # if a pkg-config file isn't found just add -lGL
 216                            # and hope for the best.
 217                            [FLAVOUR_LIBS="$FLAVOUR_LIBS -lGL"])
 218
 219           # We might fall back to DRM for sync-to-vblank on GLX
 220           PKG_CHECK_EXISTS([libdrm],
 221                            [
 222                              AC_DEFINE([HAVE_DRM], [1], [Have libdrm support])
 223                              BACKEND_PC_FILES="$BACKEND_PC_FILES libdrm"
 224                            ],
 225                            [])
 226         ],
 227
 228         [gdk],
 229         [
 230           CLUTTER_STAGE_TYPE="CLUTTER_TYPE_STAGE_GDK"
 231
 232           # We don't claim to support X11 (even though that's the preferred
 233           # GDK backend), to avoid building all the ClutterX11 stuff
 234           SUPPORT_GDK=1
 235
 236           CLUTTER_WINSYS=gdk
 237           CLUTTER_WINSYS_BASE=cogl
 238           CLUTTER_SONAME_INFIX=gdk
 239
 240           BACKEND_PC_FILES="$BACKEND_PC_FILES gdk-3.0"
 241           PKG_CHECK_EXISTS([gl], [BACKEND_PC_FILES="$BACKEND_PC_FILES gl"], [])
 242         ],
 243
 244         [opengl-egl-xlib],
 245         [
 246           CLUTTER_STAGE_TYPE="CLUTTER_TYPE_STAGE_X11"
 247           CLUTTER_EGL_BACKEND="generic"
 248
 249           SUPPORT_X11=1
 250           SUPPORT_XLIB=1
 251           SUPPORT_EGL=1
 252           SUPPORT_EGL_PLATFORM_POWERVR_X11=1
 253
 254           CLUTTER_WINSYS=x11
 255           CLUTTER_WINSYS_BASE=cogl
 256           # I think this winsys can be API and ABI compatible with the
 257           # glx flavour so we can also be cheeky and use the same soname
 258           CLUTTER_SONAME_INFIX=glx
 259
 260           PKG_CHECK_EXISTS([gl], [BACKEND_PC_FILES="$BACKEND_PC_FILES gl"], [])
 261           PKG_CHECK_EXISTS([egl], [BACKEND_PC_FILES="$BACKEND_PC_FILES egl"], [])
 262         ],
 263
 264         [wayland],
 265         [
 266           experimental_backend="yes"
 267           CLUTTER_STAGE_TYPE="CLUTTER_TYPE_STAGE_WAYLAND"
 268
 269           SUPPORT_WAYLAND=1
 270
 271           CLUTTER_WINSYS=wayland
 272           CLUTTER_SONAME_INFIX=wayland
 273
 274           PKG_CHECK_EXISTS([gl], [BACKEND_PC_FILES="$BACKEND_PC_FILES gl"], [])
 275           PKG_CHECK_EXISTS([egl], [BACKEND_PC_FILES="$BACKEND_PC_FILES egl"], [])
 276           PKG_CHECK_EXISTS([wayland-client xkbcommon],
 277                            [BACKEND_PC_FILES="$BACKEND_PC_FILES wayland-client xkbcommon"], [])
 278         ],
 279
 280         [eglx],
 281         [
 282           CLUTTER_STAGE_TYPE="CLUTTER_TYPE_STAGE_X11"
 283           CLUTTER_EGL_BACKEND="generic"
 284
 285           SUPPORT_X11=1
 286           SUPPORT_XLIB=1
 287           SUPPORT_EGL=1
 288           SUPPORT_EGL_PLATFORM_POWERVR_X11=1
 289
 290           CLUTTER_WINSYS=x11
 291           CLUTTER_WINSYS_BASE=cogl
 292           CLUTTER_SONAME_INFIX=eglx
 293         ],
 294
 295         [eglnative],
 296         [
 297           CLUTTER_STAGE_TYPE="CLUTTER_TYPE_STAGE_EGL"
 298           CLUTTER_EGL_BACKEND="generic"
 299
 300           SUPPORT_EGL=1
 301           SUPPORT_EGL_PLATFORM_POWERVR_NULL=1
 302
 303           PKG_CHECK_MODULES(TSLIB, [tslib-1.0], [have_tslib=yes], [have_tslib=no])
 304           AS_IF([test "x$have_tslib" = "xyes"],
 305                 [AC_DEFINE([HAVE_TSLIB], [1], [Have tslib for touchscreen handling])]
 306           )
 307
 308           # evdev
 309           PKG_CHECK_MODULES(EVDEV, [gudev-1.0 xkbcommon],
 310                             [have_evdev=yes], [have_evdev=no])
 311           AS_IF([test "x$have_evdev" = "xyes"],
 312                 [AC_DEFINE([HAVE_EVDEV], 1,
 313                            [Have evdev support for input handling])]
 314           )
 315
 316           # Make sure we don't enable tslib and evdev at the same time, we
 317           # don't support multiple event backends yet.
 318           AS_IF([test "x$have_tslib" = "xyes" -a "x$have_evdev" = "xyes"],
 319                 [AC_MSG_ERROR([Cannot enable both tslib and evdev events])])
 320
 321           FLAVOUR_LIBS="$FLAVOUR_LIBS $TSLIB_LIBS $EVDEV_LIBS"
 322           FLAVOUR_CFLAGS="$FLAVOUR_CFLAGS $TSLIB_CFLAGS $EVDEV_CFLAGS"
 323
 324           CLUTTER_WINSYS=cogl
 325           CLUTTER_SONAME_INFIX=eglnative
 326         ],
 327
 328         [cex100],
 329         [
 330           CLUTTER_STAGE_TYPE="CLUTTER_TYPE_STAGE_EGL"
 331           CLUTTER_EGL_BACKEND="cex100"
 332
 333           SUPPORT_EGL=1
 334           SUPPORT_EGL_PLATFORM_GDL=1
 335
 336           # The cex100 is a small specialization of the EGL backend
 337           CLUTTER_WINSYS=cogl
 338           CLUTTER_SONAME_INFIX=cex100
 339
 340           found_gdl=no
 341           AC_CHECK_HEADERS([libgdl.h], [found_gdl=yes])
 342           AS_IF([test "x$found_gdl" = "xno"],
 343                 [AC_CHECK_HEADERS([CE4100/libgdl.h],
 344                                   [
 345                                     FLAVOUR_CFLAGS="-I/usr/include/CE4100"
 346                                     found_gdl=yes
 347                                     CLUTTER_CEX100_LIBGDL_PREFIX=CE4100/
 348                                   ])
 349                 ])
 350           AC_SUBST(CLUTTER_CEX100_LIBGDL_PREFIX)
 351
 352           AS_IF([test x"$found_gdl" = "xno"], [AC_MSG_ERROR([libgdl.h not found])])
 353
 354           # evdev
 355           PKG_CHECK_MODULES(EVDEV, [gudev-1.0 xkbcommon],
 356                             [have_evdev=yes], [have_evdev=no])
 357           AS_IF([test "x$have_evdev" = "xyes"],
 358                 [AC_DEFINE([HAVE_EVDEV], 1,
 359                            [Have evdev support for input handling])]
 360           )
 361
 362           FLAVOUR_CFLAGS="$FLAVOUR_CFLAGS $EVDEV_CFLAGS"
 363           FLAVOUR_LIBS="$FLAVOUR_LIBS -lgdl $EVDEV_LIBS"
 364         ],
 365
 366         [osx],
 367         [
 368           CLUTTER_STAGE_TYPE="CLUTTER_TYPE_STAGE_OSX"
 369
 370           AC_DEFINE([HAVE_CLUTTER_OSX], [1], [Have the OSX backend])
 371
 372           FLAVOUR_LIBS="$FLAVOUR_LIBS -framework Cocoa -framework OpenGL"
 373
 374           CLUTTER_WINSYS=osx
 375           CLUTTER_SONAME_INFIX=osx
 376         ],
 377
 378         [win32],
 379         [
 380           CLUTTER_STAGE_TYPE="CLUTTER_TYPE_STAGE_WIN32"
 381           AC_DEFINE([HAVE_CLUTTER_WIN32], [1], [Have the Win32 backend])
 382
 383           FLAVOUR_LIBS="$FLAVOUR_LIBS -lopengl32 -lgdi32 -lwinmm"
 384           FLAVOUR_CFLAGS="$FLAVOUR_CFLAGS -D_WIN32_WINNT=0x0500"
 385
 386           AC_CHECK_TOOL(WINDRES, windres, no)
 387           if test "$WINDRES" = no; then
 388              AC_MSG_ERROR([*** windres is required])
 389           fi
 390
 391           CLUTTER_WINSYS=win32
 392           CLUTTER_SONAME_INFIX=win32
 393         ],
 394
 395         [AC_MSG_ERROR([Invalid backend for Clutter])]
 396 )
 397
 398 AS_IF([test "x$SUPPORT_X11" = "x1"],
 399       [
 400         # we use fontconfig API and pango-fc when the fontconfig
 401         # configuration changes
 402         PKG_CHECK_EXISTS([pangoft2],
 403                          [
 404                            AC_DEFINE([HAVE_PANGO_FT2], [1], [Supports PangoFt2])
 405                            BACKEND_PC_FILES="$BACKEND_PC_FILES pangoft2"
 406                          ],
 407                          [])
 408       ])
 409
 410 AS_IF([test "x$SUPPORT_GLX" = "x1"],
 411       [
 412         AC_DEFINE([HAVE_CLUTTER_GLX], [1], [Have the GLX backend])
 413       ])
 414
 415 AS_IF([test "x$SUPPORT_WAYLAND" = "x1"],
 416       [
 417         AC_DEFINE([HAVE_CLUTTER_WAYLAND], [1], [Have the Wayland backend])
 418       ])
 419
 420 AS_IF([test "x$SUPPORT_EGL" = "x1"],
 421       [
 422         AC_DEFINE([HAVE_CLUTTER_EGL], [1], [Have the EGL backend])
 423       ])
 424
 425 AS_IF([test "x$CLUTTER_EGL_BACKEND" = "xgeneric"],
 426       AC_DEFINE([CLUTTER_EGL_BACKEND_GENERIC], [1], [Use Generic EGL backend]))
 427
 428 AS_IF([test "x$CLUTTER_EGL_BACKEND" = "xcex100"],
 429       AC_DEFINE([CLUTTER_EGL_BACKEND_CEX100], [1], [Use CEX100 EGL backend]))
 430
 431 # winsys conditionals for use in automake files...
 432 AM_CONDITIONAL(SUPPORT_GLX, [test "x$SUPPORT_GLX" = "x1"])
 433 AM_CONDITIONAL(SUPPORT_X11, [test "x$SUPPORT_X11" = "x1"])
 434 AM_CONDITIONAL(SUPPORT_XLIB, [test "x$SUPPORT_XLIB" = "x1"])
 435 AM_CONDITIONAL(SUPPORT_GDK, [test "x$SUPPORT_GDK" = "x1"])
 436 AM_CONDITIONAL(SUPPORT_EGL, [test "x$SUPPORT_EGL" = "x1"])
 437 AM_CONDITIONAL(SUPPORT_OSX, [test "x$CLUTTER_WINSYS" = "xosx"])
 438 AM_CONDITIONAL(SUPPORT_WIN32, [test "x$CLUTTER_WINSYS" = "xwin32"])
 439 AM_CONDITIONAL(SUPPORT_CEX100, [test "x$SUPPORT_EGL_PLATFORM_GDL" = "x1"])
 440 AM_CONDITIONAL(SUPPORT_WAYLAND, [test "x$CLUTTER_WINSYS" = "xwayland"])
 441 AM_CONDITIONAL(SUPPORT_STUB, [test "x$CLUTTER_WINSYS" = "xwin32" -o \
 442                                    "x$CLUTTER_WINSYS" = "xosx" -o \
 443                                    "x$CLUTTER_WINSYS" = "xwayland"])
 444
 445 AM_CONDITIONAL(USE_TSLIB, [test "x$have_tslib" = "xyes"])
 446 AM_CONDITIONAL(SUPPORT_EVDEV, [test "x$have_evdev" = "xyes"])
 447
 448 dnl Instead of using AM_CFLAGS to ensure
 449 dnl COGL_ENABLE_EXPERIMENTAL_2_0_API is defined while compiling clutter
 450 dnl and cogl code we use a define in config.h instead. This helps ensure
 451 dnl other tools such as glib-mkenums and gir-scanner don't end up
 452 dnl using the define also.
 453 AC_DEFINE([COGL_ENABLE_EXPERIMENTAL_2_0_API], [1], [Can use Cogl 2.0 API internally])
 454
 455 dnl === Clutter configuration =================================================
 456
 457 CLUTTER_CONFIG_DEFINES=
 458
 459 # windowing systems
 460 AS_IF([test "x$SUPPORT_XLIB" = "x1"],
 461       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 462 #define CLUTTER_WINDOWING_X11 1"])
 463 AS_IF([test "x$SUPPORT_GDK" = "x1"],
 464       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 465 #define CLUTTER_WINDOWING_GDK 1"])
 466 AS_IF([test "x$SUPPORT_GLX" = "x1"],
 467       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 468 #define CLUTTER_WINDOWING_GLX 1"])
 469 AS_IF([test "x$SUPPORT_EGL" = "x1"],
 470       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 471 #define CLUTTER_WINDOWING_EGL 1"])
 472 AS_IF([test "x$CLUTTER_WINSYS" = "xwayland"],
 473       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 474 #define CLUTTER_WINDOWING_WAYLAND 1"])
 475 AS_IF([test "x$CLUTTER_WINSYS" = "xosx"],
 476       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 477 #define CLUTTER_WINDOWING_OSX 1"])
 478 AS_IF([test "x$CLUTTER_WINSYS" = "xwin32"],
 479       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 480 #define CLUTTER_WINDOWING_WIN32 1"])
 481 AS_IF([test "x$SUPPORT_EGL_PLATFORM_GDL" = "x1"],
 482       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 483 #define CLUTTER_WINDOWING_CEX100 1"])
 484
 485 AC_SUBST([CLUTTER_CONFIG_DEFINES])
 486
 487 dnl === Clutter substitutions =================================================
 488 # Eventually the idea of a winsys should be hidden from Clutter and moved
 489 # into Cogl, but for now we have CLUTTER_WINSYS...
 490 AC_SUBST([CLUTTER_WINSYS])
 491 # The same goes for the winsys-base...
 492 AC_SUBST([CLUTTER_WINSYS_BASE])
 493 AC_SUBST(CLUTTER_STAGE_TYPE)
 494 AC_SUBST(CLUTTER_SONAME_INFIX)
 495
 496 CLUTTER_WINSYS_LIB=libclutter-$CLUTTER_SONAME_INFIX-$CLUTTER_API_VERSION.la
 497 AC_SUBST([CLUTTER_WINSYS_LIB])
 498
 499 dnl === Clutter substitutions kept for backwards compatibility ================
 500 AC_SUBST([CLUTTER_FLAVOUR])
 501 CLUTTER_COGL=undefined
 502 AC_SUBST([CLUTTER_COGL])
 503
 504 dnl === Image loading backend =================================================
 505 IMAGE_PC_FILES=""
 506
 507 dnl === X11 checks, only for X11-based backends ===============================
 508 X11_PC_FILES=""
 509 x11_tests=no
 510
 511 AS_IF([test "x$SUPPORT_XLIB" = "x1"],
 512       [
 513         # base X11 includes and libraries
 514         AC_MSG_CHECKING([for X11])
 515
 516         # start with pkg-config
 517         PKG_CHECK_EXISTS([x11], [have_x11=yes], [have_x11=no])
 518         AS_IF([test "x$have_x11" = "xyes"],
 519               [
 520                 X11_PC_FILES="x11"
 521
 522                 # we actually need to ask for CFLAGS and LIBS
 523                 X11_CFLAGS=`$PKG_CONFIG --cflags $X11_PC_FILES`
 524                 X11_LIBS=`$PKG_CONFIG --libs $X11_PC_FILES`
 525
 526                 AC_MSG_RESULT([found])
 527               ],
 528               [
 529                 # no pkg-config, let's go old school
 530                 AC_PATH_X
 531
 532                 AS_IF([test "x$no_x" = "xyes"],
 533                       [AC_MSG_ERROR([No X11 Libraries found])],
 534                       [
 535                         AS_IF([test "x$x_includes" != "xNONE" && test -n "$x_includes"],
 536                               [X11_CFLAGS=-I`echo $x_includes | sed -e "s/:/ -I/g"`])
 537
 538                         AS_IF([test "x$x_libraries" != "xNONE" && test -n "$x_libraries"],
 539                               [X11_LIBS=-L`echo $x_libraries | sed -e "s/:/ -L/g"`])
 540
 541                         AC_MSG_RESULT([found])
 542                       ]
 543                 )
 544               ]
 545         )
 546
 547         # XEXT (required)
 548         AC_MSG_CHECKING([for XEXT extension])
 549         PKG_CHECK_EXISTS([xext], [have_xext=yes], [have_xext=no])
 550         AS_IF([test "x$have_xext" = "xyes"],
 551               [
 552                 AC_DEFINE(HAVE_XEXT, [1], [Define to 1 if we have the XEXT X extension])
 553
 554                 X11_LIBS="$X11_LIBS -lXext"
 555                 X11_PC_FILES="$X11_PC_FILES xext"
 556
 557                 AC_MSG_RESULT([found])
 558               ],
 559               [AC_MSG_ERROR([Not found])]
 560         )
 561
 562         # XFIXES (required)
 563         AC_MSG_CHECKING([for XFIXES extension >= $XFIXES_REQ_VERSION])
 564         PKG_CHECK_EXISTS([xfixes >= $XFIXES_REQ_VERSION], [have_xfixes=yes], [have_xfixes=no])
 565         AS_IF([test "x$have_xfixes" = "xyes"],
 566               [
 567                 AC_DEFINE(HAVE_XFIXES, [1], [Define to 1 if we have the XFIXES X extension])
 568
 569                 X11_LIBS="$X11_LIBS -lXfixes"
 570                 X11_PC_FILES="$X11_PC_FILES xfixes >= $XFIXES_REQ_VERSION"
 571
 572                 AC_MSG_RESULT([found])
 573               ],
 574               [AC_MSG_ERROR([Not found])]
 575         )
 576
 577         # XDAMAGE (required)
 578         AC_MSG_CHECKING([for XDAMAGE extension])
 579         PKG_CHECK_EXISTS([xdamage], [have_xdamage=yes], [have_xdamage=no])
 580         AS_IF([test "x$have_xdamage" = "xyes"],
 581               [
 582                 AC_DEFINE(HAVE_XDAMAGE, [1], [Define to 1 if we have the XDAMAGE X extension])
 583
 584                 X11_LIBS="$X11_LIBS -lXdamage"
 585                 X11_PC_FILES="$X11_PC_FILES xdamage"
 586
 587                 AC_MSG_RESULT([found])
 588               ],
 589               [AC_MSG_ERROR([not found])]
 590         )
 591
 592         # XCOMPOSITE (optional)
 593         AC_MSG_CHECKING([for XCOMPOSITE extension >= $XCOMPOSITE_REQ_VERSION])
 594         PKG_CHECK_EXISTS([xcomposite >= $XCOMPOSITE_REQ_VERSION], [have_xcomposite=yes], [have_xcomposite=no])
 595         AS_IF([test "x$have_xcomposite" = "xyes"],
 596               [
 597                 AC_DEFINE(HAVE_XCOMPOSITE, [1], [Define to 1 if we have the XCOMPOSITE X extension])
 598
 599                 X11_LIBS="$X11_LIBS -lXcomposite"
 600                 X11_PC_FILES="$X11_PC_FILES xcomposite >= $XCOMPOSITE_REQ_VERSION"
 601
 602                 AC_MSG_RESULT([found])
 603               ],
 604               [AC_MSG_ERROR([not found])]
 605         )
 606
 607         # X Generic Extensions (optional)
 608         clutter_save_CPPFLAGS="$CPPFLAGS"
 609         CPPFLAGS="$CPPFLAGS $X11_CFLAGS"
 610
 611         clutter_save_LIBS="$LIBS"
 612         LIBS="$LIBS $X11_LIBS"
 613
 614         have_xge=no
 615         AC_CHECK_FUNC([XGetEventData],
 616                       [
 617                         AC_DEFINE([HAVE_XGE], [1], [Define to 1 if X Generic Extensions is available])
 618                         have_xge=yes
 619                       ])
 620
 621         CPPFLAGS="$clutter_save_CPPFLAGS"
 622         LIBS="$clutter_save_LIBS"
 623
 624         # XI (optional)
 625         AC_ARG_ENABLE([xinput],
 626                       [AS_HELP_STRING([--enable-xinput], [Use the XI X extension])],
 627                       [],
 628                       [enable_xinput=yes])
 629
 630         AS_IF([test "x$enable_xinput" = "xyes"],
 631               [
 632                 PKG_CHECK_EXISTS([xi], [have_xinput=yes], [have_xinput=no])
 633               ],
 634               [
 635                 have_xinput=no
 636               ])
 637
 638         AS_CASE([$have_xinput],
 639
 640                 [yes],
 641                 [
 642                   AC_CHECK_HEADERS([X11/extensions/XInput2.h],
 643                                    [
 644                                      have_xinput2=yes
 645                                      AC_DEFINE([HAVE_XINPUT_2],
 646                                                [1],
 647                                                [Define to 1 if XI2 is available])
 648                                    ],
 649                                    [
 650                                      have_xinput2=no
 651                                      AC_DEFINE([HAVE_XINPUT],
 652                                                [1],
 653                                                [Define to 1 if XInput is available])
 654                                    ])
 655
 656                   X11_LIBS="$X11_LIBS $XINPUT_LIBS"
 657                   X11_PC_FILES="$X11_PC_FILES xi"
 658                 ],
 659
 660                 [no],
 661                 [have_xinput2=no],
 662
 663                 [*],
 664                 [AC_MSG_ERROR([Invalid argument for --enable-xinput])]
 665         )
 666
 667         # XKB
 668         clutter_save_CPPFLAGS="$CPPFLAGS"
 669         CPPFLAGS="$CPPFLAGS $X11_CFLAGS"
 670
 671         clutter_save_LIBS="$LIBS"
 672         LIBS="$LIBS $X11_LIBS"
 673
 674         have_xkb=no
 675         AC_CHECK_FUNC([XkbQueryExtension],
 676                       [
 677                         AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension])
 678                         have_xkb=yes
 679                       ])
 680
 681         CPPFLAGS="$clutter_save_CPPFLAGS"
 682         LIBS="$clutter_save_LIBS"
 683
 684         x11_tests=yes
 685         BACKEND_PC_FILES="$BACKEND_PC_FILES $X11_PC_FILES"
 686         FLAVOUR_LIBS="$FLAVOUR_LIBS $X11_LIBS"
 687         FLAVOUR_CFLAGS="$FLAVOUR_CFLAGS $X11_CFLAGS"
 688       ]
 689 )
 690
 691 AM_CONDITIONAL([BUILD_XI2], [test "x$have_xinput2" = "xyes"])
 692 AM_CONDITIONAL(X11_TESTS, [test "x$x11_tests" = "xyes"])
 693
 694 dnl === Enable debug level ====================================================
 695
 696 m4_define([debug_default], [m4_if(m4_eval(clutter_minor_version % 2), [1], [yes], [minimum])])
 697 AC_ARG_ENABLE([debug],
 698               [AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 699                               [Control Clutter debugging level @<:@default=]debug_default[@:>@])],
 700               [],
 701               [enable_debug=debug_default])
 702
 703 AS_CASE([$enable_debug],
 704
 705         [yes],
 706         [
 707           test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 708           CLUTTER_DEBUG_CFLAGS="-DCLUTTER_ENABLE_DEBUG"
 709         ],
 710
 711         [minimum],
 712         [CLUTTER_DEBUG_CFLAGS="-DCLUTTER_ENABLE_DEBUG -DG_DISABLE_CAST_CHECKS"],
 713
 714         [no],
 715         [CLUTTER_DEBUG_CFLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"],
 716
 717         [AC_MSG_ERROR([Unknown argument for --enable-debug])]
 718 )
 719
 720 AC_SUBST(CLUTTER_DEBUG_CFLAGS)
 721
 722 dnl === Enable deprecation guards ==================================================
 723
 724 m4_define([deprecated_default],
 725           [m4_if(m4_eval(clutter_minor_version % 2),
 726                  [1],
 727                  [no],
 728                  [yes])])
 729
 730 AC_ARG_ENABLE([deprecated],
 731               [AS_HELP_STRING([--enable-deprecated=@<:@no/yes@:>@],
 732                               [Whether deprecated symbols should be disabled when compiling Clutter @<:@default=]deprecated_default[@:>@])],
 733               [],
 734               [enable_deprecated=deprecated_default])
 735
 736 AS_CASE([$enable_deprecated],
 737
 738         [no],
 739         [
 740           CLUTTER_DEPRECATED_CFLAGS="-DG_DISABLE_SINGLE_INCLUDES -DCOGL_DISABLE_DEPRECATED -DCLUTTER_DISABLE_DEPRECATED"
 741         ],
 742
 743         [yes],
 744         [
 745           CLUTTER_DEPRECATED_CFLAGS="-DGLIB_DISABLE_DEPRECATION_WARNINGS -DCLUTTER_DISABLE_DEPRECATION_WARNINGS"
 746         ],
 747
 748         [AC_MSG_ERROR([Unknown argument for --enable-deprecated])]
 749 )
 750
 751 AC_SUBST([CLUTTER_DEPRECATED_CFLAGS])
 752
 753
 754 dnl === Conformance test suite ================================================
 755
 756 AC_ARG_ENABLE([conformance],
 757               [AS_HELP_STRING([--enable-conformance=@<:@no/yes@:>@],
 758                               [Build conformance test suite @<:@default=yes@:>@])],
 759               [],
 760               [enable_conformance=yes])
 761
 762 AM_CONDITIONAL([BUILD_TESTS], [test "x$enable_conformance" = "xyes"])
 763
 764 dnl === Profiling =============================================================
 765
 766 m4_define([profile_default], [no])
 767 AC_ARG_ENABLE(profile,
 768               AS_HELP_STRING([--enable-profile=@<:@no/yes@:>@],
 769                              [Turn on profiling support. yes; All profiling probe points are compiled in and may be runtime enabled. no; No profiling support will built into clutter.  @<:@default=no@:>@]),
 770               [],
 771               [enable_profile=profile_default])
 772
 773 AS_CASE([$enable_profile],
 774
 775         [yes],
 776         [
 777           AS_IF([test "x$GCC" = "xyes"],
 778                 [
 779                   PKG_CHECK_MODULES([PROFILE_DEP], [uprof-0.3])
 780                   CLUTTER_PROFILE_CFLAGS="-DCLUTTER_ENABLE_PROFILE $PROFILE_DEP_CFLAGS"
 781                   CLUTTER_PROFILE_LDFLAGS="$PROFILE_DEP_LIBS"
 782
 783                   AS_IF([test "x$enable_debug" = "xyes"], [CLUTTER_PROFILE_CFLAGS+=" -DUPROF_DEBUG"])
 784                 ],
 785                 [
 786                   AC_MSG_ERROR([--enable-profile is currently only supported if using GCC])
 787                 ])
 788         ],
 789
 790         [no],
 791         [
 792           CLUTTER_PROFILE_CFLAGS=""
 793           CLUTTER_PROFILE_LDFLAGS=""
 794         ],
 795
 796         [*], [AC_MSG_ERROR([Invalid value for --enable-profile])]
 797 )
 798 AM_CONDITIONAL(PROFILE, test "x$enable_profile" != "xno")
 799 AC_SUBST(CLUTTER_PROFILE_CFLAGS)
 800 AC_SUBST(CLUTTER_PROFILE_LDFLAGS)
 801
 802 dnl === Coverage report =======================================================
 803
 804 AC_PATH_PROG([GCOV], [gcov], [enable_gcov=no])
 805
 806 AC_MSG_CHECKING([whether to build with gcov testing])
 807
 808 AC_ARG_ENABLE([gcov],
 809               [AS_HELP_STRING([--enable-gcov],
 810                               [Whether to enable coverage testing (requires gcc
 811 and gcov)])],
 812               [],
 813               [enable_gcov=no])
 814
 815 AS_IF([test "x$enable_gcov" = "xyes" && test "x$GCC" = "xyes"],
 816       [
 817         AS_IF([test "x$enable_conformance" = "xno"],
 818               [AC_MSG_WARN([Conformance test suite is disabled, the coverage report will be incomplete])],
 819               [AC_MSG_RESULT([yes])]
 820         )
 821
 822         GCOV_CFLAGS="-g -O0 -fprofile-arcs -ftest-coverage"
 823         GCOV_LDFLAGS="-lgcov"
 824       ],
 825       [AC_MSG_RESULT([no])]
 826 )
 827
 828 AM_CONDITIONAL([GCOV_ENABLED], [test "x$enable_gcov" = "xyes"])
 829 AC_SUBST([GCOV_CFLAGS])
 830 AC_SUBST([GCOV_LDFLAGS])
 831
 832 dnl === Enable strict compiler flags ==========================================
 833
 834 # use strict compiler flags only when building from git; the rules for
 835 # distcheck will take care of turning this on when making a release
 836 m4_define([maintainer_flags_default], [m4_if(m4_eval(clutter_micro_version % 2), [1], [yes], [no])])
 837 AC_ARG_ENABLE([maintainer-flags],
 838               [AS_HELP_STRING([--enable-maintainer-flags=@<:@no/yes/error@:>@],
 839                               [Use strict compiler flags @<:@default=]maintainer_flags_default[@:>@])],
 840               [],
 841               [enable_maintainer_flags=maintainer_flags_default])
 842
 843 MAINTAINER_COMPILER_FLAGS="-Wall -Wshadow -Wcast-align -Wuninitialized
 844                            -Wno-strict-aliasing -Wempty-body -Wformat
 845                            -Wformat-security -Winit-self
 846                            -Wdeclaration-after-statement -Wvla
 847                            -Wpointer-arith"
 848
 849 AS_CASE([$enable_maintainer_flags],
 850         [yes],
 851         [
 852           AS_COMPILER_FLAGS([MAINTAINER_CFLAGS], [$MAINTAINER_COMPILER_FLAGS])
 853         ],
 854
 855         [no],
 856         [
 857         ],
 858
 859         [error],
 860         [
 861           MAINTAINER_COMPILER_FLAGS="$MAINTAINER_COMPILER_FLAGS -Werror"
 862           AS_COMPILER_FLAGS([MAINTAINER_CFLAGS], [$MAINTAINER_COMPILER_FLAGS])
 863         ],
 864
 865         [*],
 866         [AC_MSG_ERROR([Invalid option for --enable-maintainer-flags])]
 867 )
 868
 869 # strip leading spaces
 870 MAINTAINER_CFLAGS=${MAINTAINER_CFLAGS#*  }
 871 AC_SUBST(MAINTAINER_CFLAGS)
 872
 873 dnl === Dependencies, compiler flags and linker libraries =====================
 874 # strip leading space
 875 BACKEND_PC_FILES=${BACKEND_PC_FILES#* }
 876
 877 CLUTTER_REQUIRES="$CLUTTER_BASE_PC_FILES $IMAGE_PC_FILES $BACKEND_PC_FILES"
 878 PKG_CHECK_MODULES(CLUTTER_DEPS, [$CLUTTER_REQUIRES])
 879 AC_SUBST(CLUTTER_REQUIRES)
 880
 881 CLUTTER_CFLAGS="$FLAVOUR_CFLAGS $CLUTTER_DEPS_CFLAGS $CLUTTER_PROFILE_CFLAGS $GLIB_CFLAGS"
 882 CLUTTER_LIBS="$FLAVOUR_LIBS $CLUTTER_DEPS_LIBS $CLUTTER_PROFILE_LDFLAGS $GLIB_LIBS"
 883 AC_SUBST(CLUTTER_CFLAGS)
 884 AC_SUBST(CLUTTER_LIBS)
 885
 886
 887 dnl === GObject-Introspection check ===========================================
 888
 889 GOBJECT_INTROSPECTION_CHECK([gi_req_version])
 890
 891 dnl === GTK Doc check =========================================================
 892
 893 GTK_DOC_CHECK([gtk_doc_req_version], [--flavour no-tmpl])
 894
 895 # we don't want to build the documentation from a Git clone unless we
 896 # explicitly tell configure to do so; this allows avoiding to recurse into
 897 # the documentation directory when building Clutter inside Poky for a
 898 # target device that doesn't have gtk-doc installed. for reference
 899 # see: http://bugzilla.openedhand.com/show_bug.cgi?id=1047
 900 #
 901 # we use autogen.sh as it exists only inside the Git clones, and it
 902 # is not packaged into tarballs.
 903 AM_CONDITIONAL([BUILD_GTK_DOC], [test "x$enable_gtk_doc" = "xyes" || test ! -f "autogen.sh"])
 904
 905 # prefixes for fixing gtk-doc references
 906 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
 907 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 908 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
 909 COGL_PREFIX="`$PKG_CONFIG --variable=prefix cogl-1.0`"
 910 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
 911 AC_SUBST(CAIRO_PREFIX)
 912 AC_SUBST(GLIB_PREFIX)
 913 AC_SUBST(PANGO_PREFIX)
 914 AC_SUBST(COGL_PREFIX)
 915 AC_SUBST(ATK_PREFIX)
 916
 917 dnl === Manual ================================================================
 918
 919 AC_ARG_ENABLE([docs],
 920               [AS_HELP_STRING([--enable-docs=@<:@no/yes@:>@],
 921                               [Build optional documentation; requires xsltproc and jw.])],
 922               [enable_docs=$enableval],
 923               [enable_docs=no])
 924
 925 enable_pdfs=no
 926 AS_IF([test "x$enable_docs" = "xyes"],
 927       [
 928         AC_PATH_PROG(JW, [jw], [no])
 929         AS_IF([test "x$JW" = "xno"],
 930               [
 931                 AC_MSG_WARN([jw not found; pdf generation has been disabled])
 932               ],
 933               [enable_pdfs=yes])
 934
 935         AC_PATH_PROG(XSLTPROC, [xsltproc], [no])
 936         AS_IF([test "x$XSLTPROC" = "xno"],
 937               [
 938                 AC_MSG_ERROR([xsltproc not found])
 939               ])
 940       ]
 941 )
 942
 943 AM_CONDITIONAL(ENABLE_DOCS, [test "x$enable_docs" = "xyes"])
 944 AM_CONDITIONAL(ENABLE_PDFS, [test "x$enable_pdfs" = "xyes"])
 945
 946 dnl === I18N ==================================================================
 947
 948 AM_GNU_GETTEXT_VERSION([0.17])
 949 AM_GNU_GETTEXT([external])
 950
 951 GETTEXT_PACKAGE="clutter-1.0"
 952 AC_SUBST(GETTEXT_PACKAGE)
 953 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],
 954                    ["$GETTEXT_PACKAGE"],
 955                    [The prefix for our gettext translation domains.])
 956 AS_ALL_LINGUAS
 957
 958 dnl ===========================================================================
 959
 960 AC_CONFIG_FILES([
 961         Makefile
 962
 963         README
 964
 965         build/Makefile
 966         build/autotools/Makefile
 967         build/mingw/Makefile
 968
 969         clutter/Makefile
 970         clutter/clutter-config.h
 971         clutter/clutter-version.h
 972         clutter/clutter-$CLUTTER_API_VERSION.pc:clutter/clutter.pc.in
 973
 974         clutter/cally/cally-$CLUTTER_API_VERSION.pc:clutter/cally/cally.pc.in
 975
 976         clutter/cogl/clutter-cex100.h
 977
 978         tests/Makefile
 979         tests/accessibility/Makefile
 980         tests/conform/Makefile
 981         tests/conform/test-launcher.sh
 982         tests/data/Makefile
 983         tests/interactive/Makefile
 984         tests/interactive/wrapper.sh
 985         tests/micro-bench/Makefile
 986         tests/performance/Makefile
 987
 988         doc/Makefile
 989         doc/reference/Makefile
 990         doc/reference/clutter/Makefile
 991         doc/reference/clutter/clutter-docs.xml
 992         doc/reference/cally/Makefile
 993         doc/reference/cally/cally-docs.xml
 994         doc/common/Makefile
 995         doc/cookbook/Makefile
 996         doc/cookbook/clutter-cookbook.xml
 997         doc/cookbook/examples/Makefile
 998
 999         po/Makefile.in
1000 ])
1001
1002 AC_OUTPUT
1003
1004 dnl === Summary ===============================================================
1005
1006 echo ""
1007 echo "Clutter - $VERSION (${CLUTTER_RELEASE_STATUS})"
1008
1009 # Global flags
1010 echo ""
1011 echo " • Global:"
1012 echo "        Prefix: ${prefix}"
1013 echo "        Libdir: ${libdir}"
1014 echo "        Sysconfdir: ${sysconfdir}"
1015 echo "        Flavour: ${CLUTTER_WINSYS}"
1016 echo "        Target library: ${CLUTTER_WINSYS_LIB}"
1017
1018 # Compiler/Debug related flags
1019 echo ""
1020 echo " • Compiler options:"
1021 echo "        Clutter debug level: ${enable_debug}"
1022 echo "        Compiler flags: ${CFLAGS} ${MAINTAINER_CFLAGS}"
1023 echo "        Profiling enabled: ${enable_profile}"
1024 echo "        Enable coverage tests: ${enable_gcov}"
1025 echo "        Enable deprecated symbols: ${enable_deprecated}"
1026
1027 # Documentation
1028 echo ""
1029 echo " • Documentation:"
1030 echo "        Build API Reference: ${enable_gtk_doc}"
1031 echo "        Build Additional Documentation: ${enable_docs} (Generate PDF: ${enable_pdfs})"
1032
1033 # Miscellaneous
1034 echo ""
1035 echo " • Extra:"
1036 echo "        Build introspection data: ${enable_introspection}"
1037 echo "        Build conformance test suite: ${enable_conformance}"
1038
1039 # Clutter backend related flags
1040 echo ""
1041 echo " • Clutter Backend:"
1042
1043 if test "x$experimental_backend" = "xno"; then
1044 echo "        Windowing system: ${CLUTTER_WINSYS}"
1045 else
1046 echo "        Windowing system: ${CLUTTER_WINSYS} (WARNING: Experimental)"
1047 fi
1048
1049 if test "x$SUPPORT_XLIB" = "x1"; then
1050 echo "        Enable XComposite: ${have_xcomposite}"
1051 echo "        Enable XInput: ${have_xinput}"
1052 echo "        Enable Xge: ${have_xge}"
1053 echo "        Enable XI2: ${have_xinput2}"
1054 echo "        Enable XKB: ${have_xkb}"
1055 echo "        Enable X11 tests: ${x11_tests}"
1056 fi
1057
1058 echo ""
1059
1060 # General warning about experimental features
1061 if test "x$experimental_backend" = "xyes"; then
1062 echo ""
1063 echo "☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠"
1064 echo " *WARNING*"
1065 echo ""
1066 echo "  The stability of your build might be affected by one or more"
1067 echo "  experimental backends or experimental and unsupported features"
1068 echo "☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠"
1069 echo ""
1070 fi