configure.ac

   1 dnl -*- mode: m4 -*-
   2 AC_PREREQ(2.52)
   3
   4 m4_define([dbus_major_version], [1])
   5 m4_define([dbus_minor_version], [4])
   6 m4_define([dbus_micro_version], [7])
   7 m4_define([dbus_version],
   8           [dbus_major_version.dbus_minor_version.dbus_micro_version])
   9 AC_INIT(dbus, [dbus_version])
  10
  11 AC_CANONICAL_HOST
  12 AC_LIBTOOL_WIN32_DLL
  13 AC_LIBTOOL_RC
  14
  15 AC_CONFIG_MACRO_DIR([m4])
  16
  17 AM_INIT_AUTOMAKE([1.9 tar-ustar -Wno-portability])
  18 AM_CONFIG_HEADER(config.h)
  19
  20 # Honor aclocal flags
  21 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
  22
  23 GETTEXT_PACKAGE=dbus-1
  24 AC_SUBST(GETTEXT_PACKAGE)
  25 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])
  26
  27  ## must come before we use the $USE_MAINTAINER_MODE variable later
  28 AM_MAINTAINER_MODE
  29
  30 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  31
  32 AC_DEFINE_UNQUOTED(DBUS_DAEMON_NAME,"dbus-daemon",[Name of executable])
  33
  34 # libtool versioning - this applies to libdbus
  35 #
  36 # See http://sources.redhat.com/autobook/autobook/autobook_91.html#SEC91 for details
  37 #
  38
  39 ## increment if the interface has additions, changes, removals.
  40 LT_CURRENT=8
  41
  42 ## increment any time the source changes; set to
  43 ##  0 if you increment CURRENT
  44 LT_REVISION=4
  45
  46 ## increment if any interfaces have been added; set to 0
  47 ## if any interfaces have been changed or removed. removal has
  48 ## precedence over adding, so set to 0 if both happened.
  49 LT_AGE=5
  50
  51 AC_SUBST(LT_CURRENT)
  52 AC_SUBST(LT_REVISION)
  53 AC_SUBST(LT_AGE)
  54
  55 DBUS_MAJOR_VERSION=dbus_major_version
  56 DBUS_MINOR_VERSION=dbus_minor_version
  57 DBUS_MICRO_VERSION=dbus_micro_version
  58 DBUS_VERSION=dbus_major_version.dbus_minor_version.dbus_micro_version
  59
  60 AC_SUBST(DBUS_MAJOR_VERSION)
  61 AC_SUBST(DBUS_MINOR_VERSION)
  62 AC_SUBST(DBUS_MICRO_VERSION)
  63 AC_SUBST(DBUS_VERSION)
  64
  65 AC_PROG_CC
  66 AM_PROG_CC_C_O
  67 AC_PROG_CXX
  68 AC_USE_SYSTEM_EXTENSIONS
  69 AC_ISC_POSIX
  70 AC_HEADER_STDC
  71 AC_C_INLINE
  72 AM_PROG_LIBTOOL
  73 AC_PROG_MKDIR_P
  74 COMPILER_COVERAGE
  75 COMPILER_OPTIMISATIONS
  76
  77 # Set some internal variables depending on the platform for later use.
  78 dbus_win=no
  79 dbus_cygwin=no
  80 dbus_unix=no
  81 case "${host}" in
  82     *-mingw32ce*)
  83         dbus_win=yes
  84         dbus_wince=yes
  85         ;;
  86     *-mingw32*)
  87         dbus_win=yes
  88         ;;
  89     *-cygwin*)
  90         dbus_cygwin=yes
  91         dbus_unix=yes
  92         ;;
  93     *)
  94         dbus_unix=yes
  95        ;;
  96 esac
  97
  98 # Special defines for certain platforms
  99 if test "$dbus_win" = yes; then
 100     AC_DEFINE(DBUS_WIN,1,[Defined if we run on a W32 API based system])
 101     BUILD_TIMESTAMP=`date --iso-8601=minutes`
 102     AC_SUBST(BUILD_TIMESTAMP)
 103     # Assume DBUS_VERSION is always three numbers
 104     BUILD_FILEVERSION=`echo "$DBUS_VERSION" | sed -e 's/\./,/g'`,0
 105     AC_SUBST(BUILD_FILEVERSION)
 106     AC_CHECK_TOOL(WINDRES, windres, no)
 107     if test "$WINDRES" = no; then
 108       AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 109     fi
 110     if test "$dbus_wince" = yes; then
 111       AC_DEFINE(DBUS_WINCE,1,[Defined if we run on a W32 CE API based system])
 112       AC_DEFINE(_WIN32_WCE, 0x0502, [Defined to get newer W32 CE APIs])
 113     fi
 114 else
 115     AC_DEFINE(DBUS_UNIX,1,[Defined if we run on a Unix-based system])
 116 fi
 117 if test "$dbus_cygwin" = yes; then
 118     AC_DEFINE(DBUS_CYGWIN,1,[Defined if we run on a cygwin API based system])
 119 fi
 120
 121 AM_CONDITIONAL(DBUS_WIN, test "$dbus_win" = yes)
 122 AM_CONDITIONAL(DBUS_WINCE, test "$dbus_wince" = yes)
 123 AM_CONDITIONAL(DBUS_UNIX, test "$dbus_unix" = yes)
 124 AM_CONDITIONAL(DBUS_CYGWIN, test "$dbus_cygwin" = yes)
 125
 126 AC_ARG_ENABLE(tests, AS_HELP_STRING([--enable-tests],[enable unit test code in the library and binaries]),enable_tests=$enableval,enable_tests=$USE_MAINTAINER_MODE)
 127 AC_ARG_ENABLE(ansi, AS_HELP_STRING([--enable-ansi],[enable -ansi -pedantic gcc flags]),enable_ansi=$enableval,enable_ansi=no)
 128 AC_ARG_ENABLE(verbose-mode, AS_HELP_STRING([--enable-verbose-mode],[support verbose debug mode]),enable_verbose_mode=$enableval,enable_verbose_mode=$USE_MAINTAINER_MODE)
 129 AC_ARG_ENABLE(asserts, AS_HELP_STRING([--enable-asserts],[include assertion checks]),enable_asserts=$enableval,enable_asserts=$USE_MAINTAINER_MODE)
 130 AC_ARG_ENABLE(checks, AS_HELP_STRING([--enable-checks],[include sanity checks on public API]),enable_checks=$enableval,enable_checks=yes)
 131 AC_ARG_ENABLE(xml-docs, AS_HELP_STRING([--enable-xml-docs],[build XML documentation (requires xmlto)]),enable_xml_docs=$enableval,enable_xml_docs=auto)
 132 AC_ARG_ENABLE(doxygen-docs, AS_HELP_STRING([--enable-doxygen-docs],[build DOXYGEN documentation (requires Doxygen)]),enable_doxygen_docs=$enableval,enable_doxygen_docs=auto)
 133 AC_ARG_ENABLE(abstract-sockets, AS_HELP_STRING([--enable-abstract-sockets],[use abstract socket namespace (linux only)]),enable_abstract_sockets=$enableval,enable_abstract_sockets=auto)
 134 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--enable-selinux],[build with SELinux support]),enable_selinux=$enableval,enable_selinux=auto)
 135 AC_ARG_ENABLE(libaudit,AS_HELP_STRING([--enable-libaudit],[build audit daemon support for SELinux]),enable_libaudit=$enableval,enable_libaudit=auto)
 136 AC_ARG_ENABLE(dnotify, AS_HELP_STRING([--enable-dnotify],[build with dnotify support (linux only)]),enable_dnotify=$enableval,enable_dnotify=auto)
 137 AC_ARG_ENABLE(inotify, AS_HELP_STRING([--enable-inotify],[build with inotify support (linux only)]),enable_inotify=$enableval,enable_inotify=auto)
 138 AC_ARG_ENABLE(kqueue, AS_HELP_STRING([--enable-kqueue],[build with kqueue support]),enable_kqueue=$enableval,enable_kqueue=auto)
 139 AC_ARG_ENABLE(console-owner-file, AS_HELP_STRING([--enable-console-owner-file],[enable console owner file]),enable_console_owner_file=$enableval,enable_console_owner_file=auto)
 140 AC_ARG_ENABLE(userdb-cache, AS_HELP_STRING([--enable-userdb-cache],[build with userdb-cache support]),enable_userdb_cache=$enableval,enable_userdb_cache=yes)
 141 AC_ARG_ENABLE(launchd, AS_HELP_STRING([--enable-launchd],[build with launchd auto-launch support]),enable_launchd=$enableval,enable_launchd=auto)
 142
 143 AC_ARG_WITH(xml, AS_HELP_STRING([--with-xml=[libxml/expat]],[XML library to use (libxml may be named libxml2 on some systems)]))
 144 AC_ARG_WITH(init-scripts, AS_HELP_STRING([--with-init-scripts=[redhat]],[Style of init scripts to install]))
 145 AC_ARG_WITH(session-socket-dir, AS_HELP_STRING([--with-session-socket-dir=[dirname]],[Where to put sockets for the per-login-session message bus]))
 146 AC_ARG_WITH(test-socket-dir, AS_HELP_STRING([--with-test-socket-dir=[dirname]],[Where to put sockets for make check]))
 147 AC_ARG_WITH(system-pid-file, AS_HELP_STRING([--with-system-pid-file=[pidfile]],[PID file for systemwide daemon]))
 148 AC_ARG_WITH(system-socket, AS_HELP_STRING([--with-system-socket=[filename]],[UNIX domain socket for systemwide daemon]))
 149 AC_ARG_WITH(console-auth-dir, AS_HELP_STRING([--with-console-auth-dir=[dirname]],[directory to check for console ownerhip]))
 150 AC_ARG_WITH(console-owner-file, AS_HELP_STRING([--with-console-owner-file=[filename]],[file whose owner determines current console owner]))
 151 AC_ARG_WITH(launchd-agent-dir, AS_HELP_STRING([--with-launchd-agent-dir=[dirname]],[directory to put the launchd agent (default: /Library/LaunchAgents)]))
 152 AC_ARG_WITH(dbus_user, AS_HELP_STRING([--with-dbus-user=<user>],[User for running the DBUS daemon (messagebus)]))
 153 AC_ARG_WITH(dbus_daemondir, AS_HELP_STRING([--with-dbus-daemondir=[dirname]],[Directory for installing the DBUS daemon]))
 154
 155 dnl DBUS_BUILD_TESTS controls unit tests built in to .c files
 156 dnl and also some stuff in the test/ subdir
 157 AM_CONDITIONAL(DBUS_BUILD_TESTS, test x$enable_tests = xyes)
 158 if test x$enable_tests = xyes; then
 159     AC_DEFINE(DBUS_BUILD_TESTS,1,[Build test code])
 160 fi
 161
 162 if test x$enable_verbose_mode = xyes; then
 163     AC_DEFINE(DBUS_ENABLE_VERBOSE_MODE,1,[Support a verbose mode])
 164 fi
 165
 166 if test x$enable_asserts = xno; then
 167     AC_DEFINE(DBUS_DISABLE_ASSERT,1,[Disable assertion checking])
 168     AC_DEFINE(G_DISABLE_ASSERT,1,[Disable GLib assertion macros])
 169     R_DYNAMIC_LDFLAG=""
 170 else
 171     # -rdynamic is needed for glibc's backtrace_symbols to work.
 172     # No clue how much overhead this adds, but it's useful
 173     # to do this on any assertion failure,
 174     # so for now it's enabled anytime asserts are (currently not
 175     # in production builds).
 176
 177     # To get -rdynamic you pass -export-dynamic to libtool.
 178     AC_DEFINE(DBUS_BUILT_R_DYNAMIC,1,[whether -export-dynamic was passed to libtool])
 179     R_DYNAMIC_LDFLAG=-export-dynamic
 180 fi
 181 AC_SUBST(R_DYNAMIC_LDFLAG)
 182
 183 if test x$enable_checks = xno; then
 184     AC_DEFINE(DBUS_DISABLE_CHECKS,1,[Disable public API sanity checking])
 185     AC_DEFINE(G_DISABLE_CHECKS,1,[Disable GLib public API sanity checking])
 186 fi
 187
 188 if test x$enable_userdb_cache = xyes; then
 189     AC_DEFINE(DBUS_ENABLE_USERDB_CACHE,1,[Build with caching of user data])
 190 fi
 191
 192 if test x$enable_compiler_coverage = xyes; then
 193      ## so that config.h changes when you toggle gcov support
 194      AC_DEFINE_UNQUOTED(DBUS_GCOV_ENABLED, 1, [Defined if gcov is enabled to force a rebuild due to config.h changing])
 195 fi
 196
 197 # glibc21.m4 serial 3
 198 dnl Copyright (C) 2000-2002, 2004 Free Software Foundation, Inc.
 199 dnl This file is free software; the Free Software Foundation
 200 dnl gives unlimited permission to copy and/or distribute it,
 201 dnl with or without modifications, as long as this notice is preserved.
 202
 203 # Test for the GNU C Library, version 2.1 or newer.
 204 # From Bruno Haible.
 205
 206 AC_CACHE_CHECK(whether we are using the GNU C Library 2.1 or newer,
 207   ac_cv_gnu_library_2_1,
 208   [AC_EGREP_CPP([Lucky GNU user],
 209     [
 210 #include <features.h>
 211 #ifdef __GNU_LIBRARY__
 212  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || (__GLIBC__ > 2)
 213   Lucky GNU user
 214  #endif
 215 #endif
 216     ],
 217     ac_cv_gnu_library_2_1=yes,
 218     ac_cv_gnu_library_2_1=no)
 219   ]
 220 )
 221
 222 #### Integer sizes
 223
 224 AC_CHECK_SIZEOF(char)
 225 AC_CHECK_SIZEOF(short)
 226 AC_CHECK_SIZEOF(long)
 227 AC_CHECK_SIZEOF(int)
 228 AC_CHECK_SIZEOF(void *)
 229 AC_CHECK_SIZEOF(long long)
 230 AC_CHECK_SIZEOF(__int64)
 231
 232 ### See what our 64 bit type is called
 233 AC_MSG_CHECKING([64-bit integer type])
 234
 235 case 8 in
 236 $ac_cv_sizeof_int)
 237   dbusint64=int
 238   dbusint64_constant='(val)'
 239   dbusuint64_constant='(val)'
 240   dbusint64_printf_modifier='""'
 241   ;;
 242 $ac_cv_sizeof_long)
 243   dbusint64=long
 244   dbusint64_constant='(val##L)'
 245   dbusuint64_constant='(val##UL)'
 246   dbusint64_printf_modifier='"l"'
 247   ;;
 248 $ac_cv_sizeof_long_long)
 249   dbusint64='long long'
 250   dbusint64_constant='(val##LL)'
 251   dbusuint64_constant='(val##ULL)'
 252   # Ideally we discover what the format is, but this is
 253   # only used in verbose mode, so eh...
 254   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 255     dbusint64_printf_modifier='"ll"'
 256   fi
 257   ;;
 258 $ac_cv_sizeof___int64)
 259   dbusint64=__int64
 260   dbusint64_constant='(val##i64)'
 261   dbusuint64_constant='(val##ui64)'
 262   # See above case
 263   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 264     dbusint64_printf_modifier='"ll"'
 265   fi
 266   ;;
 267 esac
 268
 269 if test -z "$dbusint64" ; then
 270         DBUS_INT64_TYPE="no_int64_type_detected"
 271         DBUS_HAVE_INT64=0
 272         DBUS_INT64_CONSTANT=
 273         DBUS_UINT64_CONSTANT=
 274         AC_MSG_RESULT([none found])
 275 else
 276         DBUS_INT64_TYPE="$dbusint64"
 277         DBUS_HAVE_INT64=1
 278         DBUS_INT64_CONSTANT="$dbusint64_constant"
 279         DBUS_UINT64_CONSTANT="$dbusuint64_constant"
 280         if test x"$dbusint64_printf_modifier" != x; then
 281                 AC_DEFINE_UNQUOTED(DBUS_INT64_PRINTF_MODIFIER, [$dbusint64_printf_modifier], [Define to printf modifier for 64 bit integer type])
 282         fi
 283         AC_MSG_RESULT($DBUS_INT64_TYPE)
 284 fi
 285
 286 AC_SUBST(DBUS_INT64_TYPE)
 287 AC_SUBST(DBUS_INT64_CONSTANT)
 288 AC_SUBST(DBUS_UINT64_CONSTANT)
 289 AC_SUBST(DBUS_HAVE_INT64)
 290
 291 ### see what 32-bit int is called
 292 AC_MSG_CHECKING([32-bit integer type])
 293
 294 case 4 in
 295 $ac_cv_sizeof_short)
 296   dbusint32=short
 297   ;;
 298 $ac_cv_sizeof_int)
 299   dbusint32=int
 300   ;;
 301 $ac_cv_sizeof_long)
 302   dbusint32=long
 303   ;;
 304 esac
 305
 306 if test -z "$dbusint32" ; then
 307         DBUS_INT32_TYPE="no_int32_type_detected"
 308         AC_MSG_ERROR([No 32-bit integer type found])
 309 else
 310         DBUS_INT32_TYPE="$dbusint32"
 311         AC_MSG_RESULT($DBUS_INT32_TYPE)
 312 fi
 313
 314 AC_SUBST(DBUS_INT32_TYPE)
 315
 316 ### see what 16-bit int is called
 317 AC_MSG_CHECKING([16-bit integer type])
 318
 319 case 2 in
 320 $ac_cv_sizeof_short)
 321   dbusint16=short
 322   ;;
 323 $ac_cv_sizeof_int)
 324   dbusint16=int
 325   ;;
 326 esac
 327
 328 if test -z "$dbusint16" ; then
 329         DBUS_INT16_TYPE="no_int16_type_detected"
 330         AC_MSG_ERROR([No 16-bit integer type found])
 331 else
 332         DBUS_INT16_TYPE="$dbusint16"
 333         AC_MSG_RESULT($DBUS_INT16_TYPE)
 334 fi
 335
 336 AC_SUBST(DBUS_INT16_TYPE)
 337
 338 ## byte order
 339 case $host_os in
 340         darwin*)
 341                 # check at compile-time, so that it is possible to build universal
 342                 # (with multiple architectures at once on the compile line)
 343                 AH_VERBATIM([WORDS_BIGENDIAN_DARWIN], [
 344                         /* Use the compiler-provided endianness defines to allow universal compiling. */
 345                         #if defined(__BIG_ENDIAN__)
 346                         #define WORDS_BIGENDIAN 1
 347                         #endif
 348                 ])
 349                 ;;
 350         *)
 351                 AC_C_BIGENDIAN
 352                 ;;
 353 esac
 354
 355 dnl **********************************
 356 dnl *** va_copy checks (from GLib) ***
 357 dnl **********************************
 358 dnl we currently check for all three va_copy possibilities, so we get
 359 dnl all results in config.log for bug reports.
 360 AC_CACHE_CHECK([for an implementation of va_copy()],dbus_cv_va_copy,[
 361         AC_LINK_IFELSE([#include <stdarg.h>
 362 #include <stdlib.h>
 363         static void f (int i, ...) {
 364         va_list args1, args2;
 365         va_start (args1, i);
 366         va_copy (args2, args1);
 367         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 368           exit (1);
 369         va_end (args1); va_end (args2);
 370         }
 371         int main() {
 372           f (0, 42);
 373           return 0;
 374         }],
 375         [dbus_cv_va_copy=yes],
 376         [dbus_cv_va_copy=no])
 377 ])
 378 AC_CACHE_CHECK([for an implementation of __va_copy()],dbus_cv___va_copy,[
 379         AC_LINK_IFELSE([#include <stdarg.h>
 380 #include <stdlib.h>
 381         static void f (int i, ...) {
 382         va_list args1, args2;
 383         va_start (args1, i);
 384         __va_copy (args2, args1);
 385         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 386           exit (1);
 387         va_end (args1); va_end (args2);
 388         }
 389         int main() {
 390           f (0, 42);
 391           return 0;
 392         }],
 393         [dbus_cv___va_copy=yes],
 394         [dbus_cv___va_copy=no])
 395 ])
 396
 397 if test "x$dbus_cv_va_copy" = "xyes"; then
 398   dbus_va_copy_func=va_copy
 399 else if test "x$dbus_cv___va_copy" = "xyes"; then
 400   dbus_va_copy_func=__va_copy
 401 fi
 402 fi
 403
 404 if test -n "$dbus_va_copy_func"; then
 405   AC_DEFINE_UNQUOTED(DBUS_VA_COPY,$dbus_va_copy_func,[A 'va_copy' style function])
 406 fi
 407
 408 AC_LANG_PUSH(C)
 409 AC_CACHE_CHECK([whether va_lists can be copied by value],
 410         dbus_cv_va_val_copy,
 411         [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 412 [[
 413         #include <stdarg.h>
 414         #include <stdlib.h>
 415 ]],
 416 [[
 417         static void f (int i, ...) {
 418         va_list args1, args2;
 419         va_start (args1, i);
 420         args2 = args1;
 421         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 422           exit (1);
 423         va_end (args1); va_end (args2);
 424         }
 425         int main() {
 426           f (0, 42);
 427           return 0;
 428         }
 429 ]])],
 430         [dbus_cv_va_val_copy=yes],
 431         [dbus_cv_va_val_copy=no],
 432         [dbus_cv_va_val_copy=yes])
 433 ])
 434 AC_LANG_POP(C)
 435
 436 if test "x$dbus_cv_va_val_copy" = "xno"; then
 437   AC_DEFINE(DBUS_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 438 fi
 439
 440
 441 #### Atomic integers
 442
 443 AC_CACHE_CHECK([whether $CC knows __sync_sub_and_fetch()],
 444   dbus_cv_sync_sub_and_fetch,
 445   [AC_LINK_IFELSE(
 446      AC_LANG_PROGRAM([], [[int a = 4; int b = __sync_sub_and_fetch(&a, 4); exit(b); ]]),
 447      [dbus_cv_sync_sub_and_fetch=yes],
 448      [dbus_cv_sync_sub_and_fetch=no])
 449   ])
 450
 451 if test "x$dbus_cv_sync_sub_and_fetch" = "xyes" ; then
 452    have_sync=1
 453 else
 454    have_sync=0
 455 fi
 456
 457 AC_DEFINE_UNQUOTED([DBUS_USE_SYNC], [$have_sync], [Use the gcc __sync extension])
 458
 459 #### Various functions
 460 AC_SEARCH_LIBS(socket,[socket network])
 461 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 462
 463 AC_CHECK_FUNCS(vsnprintf vasprintf nanosleep usleep setenv clearenv unsetenv socketpair getgrouplist fpathconf setrlimit poll setlocale localeconv strtoll strtoull)
 464
 465 #### Check for broken poll; taken from Glib's configure
 466
 467 AC_MSG_CHECKING([for broken poll])
 468 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 469     #include <stdlib.h>
 470     #include <fcntl.h>
 471     #include <poll.h>
 472     #ifdef HAVE_SYS_POLL_H
 473     #include <sys/poll.h>
 474     #endif
 475     int main(void) {
 476       struct pollfd fds[1];
 477       int fd;
 478       fd = open("/dev/null", 1);
 479       fds[0].fd = fd;
 480       fds[0].events = POLLIN;
 481       fds[0].revents = 0;
 482       if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 483             exit(1);  /* Does not work for devices -- fail */
 484       }
 485       exit(0);
 486     }]])],
 487   [broken_poll=no],
 488   [broken_poll=yes
 489    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 490   [broken_poll="no (cross compiling)"])
 491 AC_MSG_RESULT($broken_poll)
 492
 493 AC_MSG_CHECKING(for dirfd)
 494 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 495 #include <sys/types.h>
 496 #include <dirent.h>
 497 ]], [[
 498 DIR *dirp;
 499 dirp = opendir(".");
 500 dirfd(dirp);
 501 closedir(dirp);
 502 ]])],
 503 [dbus_have_dirfd=yes],
 504 [dbus_have_dirfd=no])
 505 AC_MSG_RESULT($dbus_have_dirfd)
 506 if test "$dbus_have_dirfd" = yes; then
 507         AC_DEFINE(HAVE_DIRFD,1,[Have dirfd function])
 508 else
 509         AC_MSG_CHECKING(for DIR *dirp->dd_fd)
 510         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 511 #include <sys/types.h>
 512 #include <dirent.h>
 513         ]], [[
 514 DIR *dirp;
 515 int fd;
 516 dirp = opendir(".");
 517 fd = dirp->dd_fd;
 518 closedir(dirp);
 519         ]])],
 520         [dbus_have_ddfd=yes],
 521         [dbus_have_ddfd=no])
 522         AC_MSG_RESULT($dbus_have_ddfd)
 523         if test "$dbus_have_ddfd" = yes; then
 524                 AC_DEFINE(HAVE_DDFD,1,[Have the ddfd member of DIR])
 525         fi
 526 fi
 527
 528 AC_CHECK_HEADERS(sys/resource.h)
 529
 530 AC_CHECK_HEADERS(dirent.h)
 531
 532 AC_CHECK_HEADERS(execinfo.h, [AC_CHECK_FUNCS(backtrace)])
 533
 534 AC_CHECK_HEADERS(errno.h)
 535
 536 AC_CHECK_HEADERS(signal.h)
 537
 538 AC_CHECK_HEADERS(locale.h)
 539
 540 AC_CHECK_HEADERS(byteswap.h)
 541
 542 AC_CHECK_HEADERS(unistd.h)
 543
 544 AC_CHECK_HEADERS(ws2tcpip.h)
 545
 546 AC_CHECK_HEADERS(wspiapi.h)
 547
 548 # Add -D_POSIX_PTHREAD_SEMANTICS if on Solaris
 549 #
 550 case $host_os in
 551     solaris*)
 552        CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS" ;;
 553 esac
 554
 555 # checking for a posix version of getpwnam_r
 556 # if we are cross compiling and can not run the test
 557 # assume getpwnam_r is the posix version
 558 # it is up to the person cross compiling to change
 559 # this behavior if desired
 560 AC_LANG_PUSH(C)
 561 AC_CACHE_CHECK([for posix getpwnam_r],
 562                 ac_cv_func_posix_getpwnam_r,
 563                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 564 [[
 565 #include <errno.h>
 566 #include <pwd.h>
 567 ]],
 568 [[
 569     char buffer[10000];
 570     struct passwd pwd, *pwptr = &pwd;
 571     int error;
 572     errno = 0;
 573     error = getpwnam_r ("", &pwd, buffer,
 574                         sizeof (buffer), &pwptr);
 575    return (error < 0 && errno == ENOSYS)
 576            || error == ENOSYS;
 577 ]])],
 578         [ac_cv_func_posix_getpwnam_r=yes],
 579         [ac_cv_func_posix_getpwnam_r=no],
 580         [ac_cv_func_posix_getpwnam_r=yes]
 581 )])
 582 AC_LANG_POP(C)
 583
 584 if test "$ac_cv_func_posix_getpwnam_r" = yes; then
 585         AC_DEFINE(HAVE_POSIX_GETPWNAM_R,1,
 586                 [Have POSIX function getpwnam_r])
 587 else
 588         AC_CACHE_CHECK([for nonposix getpwnam_r],
 589                 ac_cv_func_nonposix_getpwnam_r,
 590                 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pwd.h>]], [[char buffer[10000];
 591                         struct passwd pwd;
 592                         getpwnam_r ("", &pwd, buffer,
 593                                         sizeof (buffer));]])],
 594                         [ac_cv_func_nonposix_getpwnam_r=yes],
 595                         [ac_cv_func_nonposix_getpwnam_r=no])])
 596                 if test "$ac_cv_func_nonposix_getpwnam_r" = yes; then
 597                 AC_DEFINE(HAVE_NONPOSIX_GETPWNAM_R,1,
 598                         [Have non-POSIX function getpwnam_r])
 599         fi
 600 fi
 601
 602 dnl check for socklen_t
 603 AC_MSG_CHECKING(whether socklen_t is defined)
 604 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 605 #include <sys/types.h>
 606 #include <sys/socket.h>
 607 #include <netdb.h>
 608 ]], [[
 609 socklen_t foo;
 610 foo = 1;
 611 ]])],
 612 [dbus_have_socklen_t=yes],
 613 [dbus_have_socklen_t=no])
 614 AC_MSG_RESULT($dbus_have_socklen_t)
 615
 616 if test "x$dbus_have_socklen_t" = "xyes"; then
 617     AC_DEFINE(HAVE_SOCKLEN_T,1,[Have socklen_t type])
 618 fi
 619
 620 dnl check for writev header and writev function so we're
 621 dnl good to go if HAVE_WRITEV gets defined.
 622 AC_CHECK_HEADERS(sys/uio.h, [AC_CHECK_FUNCS(writev)])
 623
 624 dnl needed on darwin for NAME_MAX
 625 AC_CHECK_HEADERS(sys/syslimits.h)
 626
 627 dnl Make it easy to check if we have MSG_NOSIGNAL without actually having to include sys/socket.h
 628 AC_CHECK_DECLS([MSG_NOSIGNAL], [], [], [[ #include <sys/socket.h> ]])
 629
 630 dnl check for flavours of varargs macros (test from GLib)
 631 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 632 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 633 int a(int p1, int p2, int p3);
 634 #define call_a(...) a(1,__VA_ARGS__)
 635 call_a(2,3);
 636 ]])],
 637 [dbus_have_iso_c_varargs=yes],
 638 [dbus_have_iso_c_varargs=no])
 639 AC_MSG_RESULT($dbus_have_iso_c_varargs)
 640
 641 AC_MSG_CHECKING(for GNUC varargs macros)
 642 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 643 int a(int p1, int p2, int p3);
 644 #define call_a(params...) a(1,params)
 645 call_a(2,3);
 646 ]])],
 647 [dbus_have_gnuc_varargs=yes],
 648 [dbus_have_gnuc_varargs=no])
 649 AC_MSG_RESULT($dbus_have_gnuc_varargs)
 650
 651 dnl Output varargs tests
 652 if test x$dbus_have_iso_c_varargs = xyes; then
 653     AC_DEFINE(HAVE_ISO_VARARGS,1,[Have ISO C99 varargs macros])
 654 fi
 655 if test x$dbus_have_gnuc_varargs = xyes; then
 656     AC_DEFINE(HAVE_GNUC_VARARGS,1,[Have GNU-style varargs macros])
 657 fi
 658
 659 dnl Check for various credentials.
 660 AC_MSG_CHECKING(for struct cmsgcred)
 661 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 662 #include <sys/types.h>
 663 #include <sys/socket.h>
 664 ]], [[
 665 struct cmsgcred cred;
 666
 667 cred.cmcred_pid = 0;
 668 ]])],
 669 [dbus_have_struct_cmsgcred=yes],
 670 [dbus_have_struct_cmsgcred=no])
 671 AC_MSG_RESULT($dbus_have_struct_cmsgcred)
 672
 673 if test x$dbus_have_struct_cmsgcred = xyes; then
 674     AC_DEFINE(HAVE_CMSGCRED,1,[Have cmsgcred structure])
 675 fi
 676
 677 AC_CHECK_FUNCS(getpeerucred getpeereid)
 678
 679 AC_CHECK_FUNCS(pipe2 accept4)
 680
 681 #### Abstract sockets
 682
 683 if test x$enable_abstract_sockets = xauto; then
 684 AC_LANG_PUSH(C)
 685 warn_on_xcompile=no
 686 AC_CACHE_CHECK([abstract socket namespace],
 687                 ac_cv_have_abstract_sockets,
 688                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 689 [[
 690 #include <sys/types.h>
 691 #include <stdlib.h>
 692 #include <string.h>
 693 #include <stdio.h>
 694 #include <sys/socket.h>
 695 #include <sys/un.h>
 696 #include <errno.h>
 697 ]],
 698 [[
 699   size_t slen;
 700   int listen_fd;
 701   struct sockaddr_un addr;
 702
 703   listen_fd = socket (PF_UNIX, SOCK_STREAM, 0);
 704
 705   if (listen_fd < 0)
 706     {
 707       fprintf (stderr, "socket() failed: %s\n", strerror (errno));
 708       exit (1);
 709     }
 710
 711   memset (&addr, '\0', sizeof (addr));
 712   addr.sun_family = AF_UNIX;
 713   strcpy (addr.sun_path, "X/tmp/dbus-fake-socket-path-used-in-configure-test");
 714   /* SUN_LEN uses strlen() so need to calculate it before adding \0 at the
 715    * beginning.
 716    */
 717   slen = SUN_LEN(&addr);
 718   addr.sun_path[0] = '\0'; /* this is what makes it abstract */
 719
 720   if (bind (listen_fd, (struct sockaddr*) &addr, slen) < 0)
 721     {
 722        fprintf (stderr, "Abstract socket namespace bind() failed: %s\n",
 723                 strerror (errno));
 724        exit (1);
 725     }
 726   else
 727     exit (0);
 728 ]])],
 729               [ac_cv_have_abstract_sockets=yes],
 730               [ac_cv_have_abstract_sockets=no],
 731               [
 732                 ac_cv_have_abstract_sockets=no
 733                 warn_on_xcompile=yes
 734               ]
 735 )])
 736 if test x$warn_on_xcompile = xyes ; then
 737   AC_MSG_WARN([Cannot check for abstract sockets when cross-compiling, please use --enable-abstract-sockets])
 738 fi
 739 AC_LANG_POP(C)
 740 fi
 741
 742 if test x$enable_abstract_sockets = xyes; then
 743     if test x$ac_cv_have_abstract_sockets = xno; then
 744         AC_MSG_ERROR([Abstract sockets explicitly required, and support not detected.])
 745     fi
 746 fi
 747
 748 if test x$enable_abstract_sockets = xno; then
 749    ac_cv_have_abstract_sockets=no;
 750 fi
 751
 752 if test x$ac_cv_have_abstract_sockets = xyes ; then
 753    DBUS_PATH_OR_ABSTRACT=abstract
 754    AC_DEFINE(HAVE_ABSTRACT_SOCKETS,1,[Have abstract socket namespace])
 755 else
 756    DBUS_PATH_OR_ABSTRACT=path
 757 fi
 758
 759 # this is used in addresses to prefer abstract, e.g.
 760 # unix:path=/foo or unix:abstract=/foo
 761 AC_SUBST(DBUS_PATH_OR_ABSTRACT)
 762
 763 PKG_PROG_PKG_CONFIG
 764
 765 #### Sort out XML library
 766
 767 # see what we have
 768 AC_CHECK_LIB(expat, XML_ParserCreate_MM,
 769              [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ],
 770              have_expat=false)
 771
 772 # see what we want to use
 773 dbus_use_libxml=false
 774 dbus_use_expat=false
 775 if test x$with_xml = xexpat; then
 776         if ! $have_expat ; then
 777            AC_MSG_ERROR([Explicitly requested expat but expat not found])
 778         fi
 779         dbus_use_expat=true
 780 elif test x$with_xml = xlibxml; then
 781         PKG_CHECK_MODULES(LIBXML, libxml-2.0 >= 2.6.0, have_libxml=true, have_libxml=false)
 782         if ! $have_libxml ; then
 783            AC_MSG_ERROR([Explicitly requested libxml but libxml not found])
 784         fi
 785         dbus_use_libxml=true
 786 else
 787         ### expat is the default because libxml can't currently survive
 788         ### our brutal OOM-handling unit test setup.
 789         ### http://bugzilla.gnome.org/show_bug.cgi?id=109368
 790         if test x$have_expat = xfalse; then
 791                 AC_MSG_ERROR([Could not find expat.h, check config.log for failed attempts])
 792         fi
 793         ### By default, only use Expat since it's tested and known to work.  If you're a
 794         ### general-purpose OS vendor, please don't enable libxml.  For embedded use
 795         ### if your OS is built around libxml, that's another case.
 796         dbus_use_expat=true
 797 fi
 798
 799 AM_CONDITIONAL(DBUS_USE_EXPAT, $dbus_use_expat)
 800 AM_CONDITIONAL(DBUS_USE_LIBXML, $dbus_use_libxml)
 801
 802 if $dbus_use_expat; then
 803    XML_LIBS=-lexpat
 804    XML_CFLAGS=
 805 fi
 806 if $dbus_use_libxml; then
 807    XML_LIBS=$LIBXML_LIBS
 808    XML_CFLAGS=$LIBXML_CFLAGS
 809 fi
 810
 811 # Thread lib detection
 812 AC_CHECK_FUNC(pthread_cond_timedwait,[AC_CHECK_LIB(pthread,pthread_cond_timedwait,
 813                                                     [THREAD_LIBS="-lpthread"])])
 814 save_libs="$LIBS"
 815 LIBS="$LIBS $THREAD_LIBS"
 816 AC_CHECK_FUNC(pthread_condattr_setclock,have_pthread_condattr_setclock=true,have_pthread_condattr_setclock=false)
 817 if test x$have_pthread_condattr_setclock = xtrue; then
 818     AC_SEARCH_LIBS([clock_getres],[rt],[THREAD_LIBS="$THREAD_LIBS -lrt"])
 819     AC_MSG_CHECKING([for CLOCK_MONOTONIC])
 820     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>
 821 #include <pthread.h>
 822 ]], [[
 823 struct timespec monotonic_timer;
 824 pthread_condattr_t attr;
 825 pthread_condattr_init (&attr);
 826 pthread_condattr_setclock (&attr, CLOCK_MONOTONIC);
 827 clock_getres (CLOCK_MONOTONIC,&monotonic_timer);
 828 ]])],
 829 [have_clock_monotonic=true],
 830 [have_clock_monotonic=false])
 831 if test x$have_clock_monotonic = xtrue; then
 832     AC_MSG_RESULT([found])
 833     AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1, [Define if we have CLOCK_MONOTONIC])
 834 else
 835     AC_MSG_RESULT([not found])
 836 fi
 837 fi
 838 LIBS="$save_libs"
 839
 840 # SELinux detection
 841 if test x$enable_selinux = xno ; then
 842     have_selinux=no;
 843 else
 844     # See if we have SELinux library
 845     AC_CHECK_LIB(selinux, is_selinux_enabled,
 846                  have_selinux=yes, have_selinux=no)
 847
 848     # see if we have the SELinux header with the new D-Bus stuff in it
 849     if test x$have_selinux = xyes ; then
 850         AC_MSG_CHECKING([for DBUS Flask permissions in selinux/av_permissions.h])
 851         AC_TRY_COMPILE([#include <selinux/av_permissions.h>],
 852                         [#ifdef DBUS__ACQUIRE_SVC return 0;
 853                          #else
 854                          #error DBUS__ACQUIRE_SVC not defined
 855                          #endif],
 856                         have_selinux=yes, have_selinux=no)
 857         AC_MSG_RESULT($have_selinux)
 858     fi
 859
 860     if test x$enable_selinux = xauto ; then
 861         if test x$have_selinux = xno ; then
 862                 AC_MSG_WARN([Sufficiently new SELinux library not found])
 863         fi
 864     else
 865         if test x$have_selinux = xno ; then
 866                 AC_MSG_ERROR([SElinux explicitly required, and SELinux library not found])
 867         fi
 868     fi
 869 fi
 870
 871 AM_CONDITIONAL(HAVE_SELINUX, test x$have_selinux = xyes)
 872
 873 if test x$have_selinux = xyes ; then
 874     # the selinux code creates threads
 875     # which requires libpthread even on linux
 876     AC_CHECK_FUNC(pthread_create,,[AC_CHECK_LIB(pthread,pthread_create,
 877                                                 [SELINUX_THREAD_LIBS="-lpthread"])])
 878
 879     SELINUX_LIBS="-lselinux $SELINUX_THREAD_LIBS"
 880     AC_DEFINE(HAVE_SELINUX,1,[SELinux support])
 881 else
 882     SELINUX_LIBS=
 883 fi
 884
 885 # inotify checks
 886 if test x$enable_inotify = xno ; then
 887     have_inotify=no;
 888 else
 889     AC_CHECK_HEADERS(sys/inotify.h, have_inotify=yes, have_inotify=no)
 890 fi
 891
 892 dnl check if inotify backend is enabled
 893 if test x$have_inotify = xyes; then
 894    AC_DEFINE(DBUS_BUS_ENABLE_INOTIFY,1,[Use inotify])
 895    AC_CHECK_FUNCS(inotify_init1)
 896 fi
 897
 898 AM_CONDITIONAL(DBUS_BUS_ENABLE_INOTIFY, test x$have_inotify = xyes)
 899
 900 # dnotify checks
 901 if test x$enable_dnotify = xno ; then
 902     have_dnotify=no;
 903 else
 904     if test x$have_inotify = xno -a x$host_os = xlinux-gnu -o x$host_os = xlinux; then
 905         have_dnotify=yes;
 906     else
 907         have_dnotify=no;
 908     fi
 909 fi
 910
 911 dnl check if dnotify backend is enabled
 912 if test x$have_dnotify = xyes; then
 913    AC_DEFINE(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX,1,[Use dnotify on Linux])
 914 fi
 915
 916 AM_CONDITIONAL(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX, test x$have_dnotify = xyes)
 917
 918 # kqueue checks
 919 if test x$enable_kqueue = xno ; then
 920     have_kqueue=no
 921 else
 922     have_kqueue=yes
 923     AC_CHECK_HEADER(sys/event.h, , have_kqueue=no)
 924     AC_CHECK_FUNC(kqueue, , have_kqueue=no)
 925
 926     if test x$enable_kqueue = xyes -a x$have_kqueue = xno; then
 927         AC_MSG_ERROR(kqueue support explicitly enabled but not available)
 928     fi
 929 fi
 930
 931 dnl check if kqueue backend is enabled
 932 if test x$have_kqueue = xyes; then
 933    AC_DEFINE(DBUS_BUS_ENABLE_KQUEUE,1,[Use kqueue])
 934 fi
 935
 936 AM_CONDITIONAL(DBUS_BUS_ENABLE_KQUEUE, test x$have_kqueue = xyes)
 937
 938 # launchd checks
 939 if test x$enable_launchd = xno ; then
 940     have_launchd=no
 941 else
 942     have_launchd=yes
 943     AC_CHECK_HEADER([launch.h], , have_launchd=no)
 944     AC_PATH_PROG([LAUNCHCTL], [launchctl])
 945     if test "x$LAUNCHCTL" = "x"; then
 946         have_launchd=no
 947     fi
 948
 949     if test x$enable_launchd = xyes && test x$have_launchd = xno ; then
 950         AC_MSG_ERROR([launchd support explicitly enabled but not available])
 951     fi
 952 fi
 953
 954 dnl check if launchd is enabled
 955 if test x$have_launchd = xyes; then
 956     AC_DEFINE(DBUS_ENABLE_LAUNCHD,1,[Use launchd autolaunch])
 957 fi
 958
 959 AM_CONDITIONAL(DBUS_ENABLE_LAUNCHD, test x$have_launchd = xyes)
 960
 961 #### Directory to place launchd agent file
 962 if test "x$with_launchd_agent_dir" = "x"; then
 963    LAUNCHD_AGENT_DIR="/Library/LaunchAgents"
 964 else
 965    LAUNCHD_AGENT_DIR="$with_launchd_agent_dir"
 966 fi
 967
 968 AC_SUBST(LAUNCHD_AGENT_DIR)
 969
 970 dnl console owner file
 971 if test x$enable_console_owner_file = xno ; then
 972     have_console_owner_file=no;
 973 else
 974     case $host_os in
 975     solaris*)
 976         have_console_owner_file=yes;
 977         AC_DEFINE(HAVE_CONSOLE_OWNER_FILE,1,[Have console owner file])
 978         ;;
 979     *)
 980         have_console_owner_file=no;;
 981     esac
 982 fi
 983
 984 AM_CONDITIONAL(HAVE_CONSOLE_OWNER_FILE, test x$have_console_owner_file = xyes)
 985
 986 # libaudit detection
 987 if test x$enable_libaudit = xno ; then
 988     have_libaudit=no;
 989 else
 990     # See if we have audit daemon & capabilities library
 991     AC_CHECK_LIB(audit, audit_log_user_avc_message,
 992                  have_libaudit=yes, have_libaudit=no)
 993     if test x$have_libaudit = xyes ; then
 994         AC_CHECK_LIB(cap-ng, capng_clear,
 995                  have_libaudit=yes, have_libaudit=no)
 996     fi
 997 fi
 998
 999 AM_CONDITIONAL(HAVE_LIBAUDIT, test x$have_libaudit = xyes)
1000
1001 if test x$have_libaudit = xyes ; then
1002     SELINUX_LIBS="$SELINUX_LIBS -laudit -lcap-ng"
1003     AC_DEFINE(HAVE_LIBAUDIT,1,[audit daemon SELinux support])
1004 fi
1005
1006 # Check for ADT API
1007 AC_MSG_CHECKING(for ADT API)
1008 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1009 #include <bsm/adt.h>
1010 adt_user_context = ADT_USER;
1011 ]], [[]])], [ check_adt_audit=yes ], [ check_adt_audit=no ])
1012
1013 if test ${check_adt_audit} = yes
1014 then
1015    AC_DEFINE([HAVE_ADT], [], [Adt audit API])
1016    ADT_LIBS="-lbsm"
1017    LIBS="-lbsm $LIBS"
1018    AC_MSG_RESULT(yes)
1019 else
1020    AC_MSG_RESULT(no)
1021 fi
1022
1023 # Check for SCM_RIGHTS
1024 AC_MSG_CHECKING([for SCM_RIGHTS])
1025 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1026 #include <sys/socket.h>
1027 #include <sys/un.h>
1028 static int x = SCM_RIGHTS;
1029 ]], [[]])],
1030 [ AC_MSG_RESULT([supported])
1031   AC_DEFINE([HAVE_UNIX_FD_PASSING], [1], [Supports sending UNIX file descriptors]) ],
1032 [ AC_MSG_RESULT([not supported]) ])
1033
1034 NETWORK_libs=
1035 if test x$dbus_win = xyes ; then
1036   if test x$dbus_wince = xyes ; then
1037     NETWORK_libs="-lws2"
1038   else
1039     NETWORK_libs="-lws2_32"
1040   fi
1041 fi
1042
1043 #### Set up final flags
1044 DBUS_CLIENT_CFLAGS=
1045 DBUS_CLIENT_LIBS="$THREAD_LIBS $NETWORK_libs"
1046 AC_SUBST(DBUS_CLIENT_CFLAGS)
1047 AC_SUBST(DBUS_CLIENT_LIBS)
1048
1049 DBUS_BUS_CFLAGS="$XML_CFLAGS"
1050 DBUS_BUS_LIBS="$XML_LIBS $SELINUX_LIBS $THREAD_LIBS $ADT_LIBS $NETWORK_libs"
1051 AC_SUBST(DBUS_BUS_CFLAGS)
1052 AC_SUBST(DBUS_BUS_LIBS)
1053
1054 DBUS_LAUNCHER_CFLAGS="$XML_CFLAGS"
1055 DBUS_LAUNCHER_LIBS="$XML_LIBS $THREAD_LIBS $NETWORK_libs"
1056 AC_SUBST(DBUS_LAUNCHER_CFLAGS)
1057 AC_SUBST(DBUS_LAUNCHER_LIBS)
1058
1059 DBUS_TEST_CFLAGS=
1060 DBUS_TEST_LIBS="$THREAD_LIBS $NETWORK_libs"
1061 AC_SUBST(DBUS_TEST_CFLAGS)
1062 AC_SUBST(DBUS_TEST_LIBS)
1063
1064 ### X11 detection
1065 if test x$dbus_win = xyes ; then
1066    enable_x11=no
1067 else
1068 AC_PATH_XTRA
1069
1070 ## for now enable_x11 just tracks have_x11,
1071 ## there's no --enable-x11
1072 if test x$no_x = xyes ; then
1073    have_x11=no
1074    enable_x11=no
1075 else
1076    have_x11=yes
1077    enable_x11=yes
1078 fi
1079
1080 if test x$enable_x11 = xyes ; then
1081    AC_DEFINE(DBUS_BUILD_X11,1,[Build X11-dependent code])
1082    DBUS_X_LIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
1083    DBUS_X_CFLAGS="$X_CFLAGS"
1084 else
1085    DBUS_X_LIBS=
1086    DBUS_X_CFLAGS=
1087 fi
1088
1089 AC_SUBST(DBUS_X_CFLAGS)
1090 AC_SUBST(DBUS_X_LIBS)
1091 fi
1092
1093
1094 #### gcc warning flags
1095
1096 cc_supports_flag() {
1097   AC_MSG_CHECKING(whether $CC supports "$*")
1098   save_CFLAGS="$CFLAGS"
1099   CFLAGS="$*"
1100   AC_TRY_COMPILE([], [], [rc=yes], [rc=no])
1101   CFLAGS="$save_CFLAGS"
1102   AC_MSG_RESULT([$rc])
1103   test "x$rc" = xyes
1104 }
1105
1106 ld_supports_flag() {
1107   AC_MSG_CHECKING([whether $LD supports "$@"])
1108   AC_TRY_LINK([
1109     int one(void) { return 1; }
1110     int two(void) { return 2; }
1111   ], [ two(); ] , [_ac_ld_flag_supported=yes], [_ac_ld_flag_supported=no])
1112
1113   if test "$_ac_ld_flag_supported" = "yes"; then
1114     rm -f conftest.c
1115     touch conftest.c
1116     if $CC -c conftest.c; then
1117       ld_out=`$LD $@ -o conftest conftest.o 2>&1`
1118       ld_ret=$?
1119       if test $ld_ret -ne 0 ; then
1120         _ac_ld_flag_supported=no
1121       elif echo "$ld_out" | egrep 'option ignored|^usage:|unrecognized option|illegal option' >/dev/null ; then
1122         _ac_ld_flag_supported=no
1123       fi
1124     fi
1125     rm -f conftest.c conftest.o conftest
1126   fi
1127
1128   AC_MSG_RESULT($_ac_ld_flag_supported)
1129   if test "$_ac_ld_flag_supported" = "yes" ; then
1130     return 0
1131   else
1132     return 1
1133   fi
1134 }
1135
1136 # Don't bother with -Werror on Windows for now, too many warnings
1137 if test x$dbus_win != xyes -a x$dbus_cygwin != xyes -a x$USE_MAINTAINER_MODE = xyes; then
1138   if cc_supports_flag "-Werror"; then
1139     CFLAGS="$CFLAGS -Werror"
1140   fi
1141 fi
1142
1143 if test "x$GCC" = "xyes"; then
1144   changequote(,)dnl
1145   case " $CFLAGS " in
1146   *[\ \ ]-Wall[\ \      ]*) ;;
1147   *) CFLAGS="$CFLAGS -Wall" ;;
1148   esac
1149
1150   case " $CFLAGS " in
1151   *[\ \ ]-Wchar-subscripts[\ \  ]*) ;;
1152   *) CFLAGS="$CFLAGS -Wchar-subscripts" ;;
1153   esac
1154
1155   case " $CFLAGS " in
1156   *[\ \ ]-Wmissing-declarations[\ \     ]*) ;;
1157   *) CFLAGS="$CFLAGS -Wmissing-declarations" ;;
1158   esac
1159
1160   case " $CFLAGS " in
1161   *[\ \ ]-Wmissing-prototypes[\ \       ]*) ;;
1162   *) CFLAGS="$CFLAGS -Wmissing-prototypes" ;;
1163   esac
1164
1165   case " $CFLAGS " in
1166   *[\ \ ]-Wnested-externs[\ \   ]*) ;;
1167   *) CFLAGS="$CFLAGS -Wnested-externs" ;;
1168   esac
1169
1170   case " $CFLAGS " in
1171   *[\ \ ]-Wpointer-arith[\ \    ]*) ;;
1172   *) CFLAGS="$CFLAGS -Wpointer-arith" ;;
1173   esac
1174
1175   case " $CFLAGS " in
1176   *[\ \ ]-Wcast-align[\ \       ]*) ;;
1177   *) CFLAGS="$CFLAGS -Wcast-align" ;;
1178   esac
1179
1180   case " $CFLAGS " in
1181   *[\ \ ]-Wno-address[\ \       ]*) ;;
1182   *) CFLAGS="$CFLAGS -Wno-address" ;;
1183   esac
1184
1185   case " $CFLAGS " in
1186   *[\ \ ]-Wfloat-equal[\ \      ]*) ;;
1187   *) if cc_supports_flag -Wfloat-equal; then
1188         CFLAGS="$CFLAGS -Wfloat-equal"
1189      fi
1190      ;;
1191   esac
1192
1193   case " $CFLAGS " in
1194   *[\ \ ]-Wdeclaration-after-statement[\ \      ]*) ;;
1195   *) if cc_supports_flag -Wdeclaration-after-statement; then
1196         CFLAGS="$CFLAGS -Wdeclaration-after-statement"
1197      fi
1198      ;;
1199   esac
1200
1201   case " $CFLAGS " in
1202   *[\ \ ]-fno-common[\ \        ]*) ;;
1203   *) if cc_supports_flag -fno-common; then
1204         CFLAGS="$CFLAGS -fno-common"
1205      fi
1206      ;;
1207   esac
1208
1209   case " $CFLAGS " in
1210   *[\ \ ]-fPIC[\ \      ]*) ;;
1211   *) if test x$dbus_win = xno && cc_supports_flag -fPIC; then
1212         PIC_CFLAGS="-fPIC"
1213         if ld_supports_flag -z,relro; then
1214            PIC_LDFLAGS="-Wl,-z,relro"
1215         fi
1216      fi
1217      ;;
1218   esac
1219
1220   case " $CFLAGS " in
1221   *[\ \ ]-fPIE[\ \      ]*) ;;
1222   *) if test x$dbus_win = xno && cc_supports_flag -fPIE; then
1223         PIE_CFLAGS="-fPIE"
1224         if ld_supports_flag -z,relro; then
1225            PIE_LDFLAGS="-pie -Wl,-z,relro"
1226         else
1227            PIE_LDFLAGS="-pie"
1228         fi
1229      fi
1230      ;;
1231   esac
1232
1233   ### Disabled warnings, and compiler flag overrides
1234
1235   # Let's just ignore unused for now
1236   case " $CFLAGS " in
1237   *[\ \ ]-Wno-unused[\ \        ]*) ;;
1238   *) CFLAGS="$CFLAGS -Wno-unused" ;;
1239   esac
1240
1241   # This group is for warnings we currently don't pass.
1242   # We would like to, however.  Please fix.
1243
1244   # http://bugs.freedesktop.org/show_bug.cgi?id=17433
1245   case " $CFLAGS " in
1246   *[\ \ ]-Wno-sign-compare[\ \  ]*) ;;
1247   *) CFLAGS="$CFLAGS -Wno-sign-compare" ;;
1248   esac
1249   case " $CFLAGS " in
1250   *[\ \ ]-Wno-pointer-sign[\ \  ]*) ;;
1251   *) if cc_supports_flag -Wno-pointer-sign; then
1252         CFLAGS="$CFLAGS -Wno-pointer-sign"
1253      fi
1254      ;;
1255   esac
1256
1257   # This one is special - it's not a warning override.
1258   # http://bugs.freedesktop.org/show_bug.cgi?id=10599
1259   case " $CFLAGS " in
1260   *[\ \ ]-fno-strict-aliasing[\ \       ]*) ;;
1261   *) CFLAGS="$CFLAGS -fno-strict-aliasing" ;;
1262   esac
1263   ### End disabled warnings
1264
1265   if test "x$enable_ansi" = "xyes"; then
1266     case " $CFLAGS " in
1267     *[\ \       ]-ansi[\ \      ]*) ;;
1268     *) CFLAGS="$CFLAGS -ansi" ;;
1269     esac
1270
1271     case " $CFLAGS " in
1272     *[\ \       ]-D_POSIX_C_SOURCE*) ;;
1273     *) CFLAGS="$CFLAGS -D_POSIX_C_SOURCE=199309L" ;;
1274     esac
1275
1276     case " $CFLAGS " in
1277     *[\ \       ]-D_BSD_SOURCE[\ \      ]*) ;;
1278     *) CFLAGS="$CFLAGS -D_BSD_SOURCE" ;;
1279     esac
1280
1281     case " $CFLAGS " in
1282     *[\ \       ]-pedantic[\ \  ]*) ;;
1283     *) CFLAGS="$CFLAGS -pedantic" ;;
1284     esac
1285   fi
1286   changequote([,])dnl
1287 fi
1288
1289 AC_SUBST(PIC_CFLAGS)
1290 AC_SUBST(PIC_LDFLAGS)
1291 AC_SUBST(PIE_CFLAGS)
1292 AC_SUBST(PIE_LDFLAGS)
1293
1294 if ld_supports_flag --gc-sections; then
1295   SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
1296   CFLAGS="-ffunction-sections -fdata-sections $CFLAGS"
1297 fi
1298 AC_SUBST(SECTION_FLAGS)
1299 AC_SUBST(SECTION_LDFLAGS)
1300 AC_MSG_RESULT($ac_gcsections)
1301
1302 case $host_os in
1303     solaris*)
1304         # Solaris' C library apparently needs these runes to be threadsafe...
1305         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS -D_REENTRANT"
1306 esac
1307
1308 changequote(,)dnl
1309 # compress spaces in flags
1310 CFLAGS=`echo "$CFLAGS" | sed -e 's/ +/ /g'`
1311 CXXFLAGS=`echo "$CXXFLAGS" | sed -e 's/ +/ /g'`
1312 CPPFLAGS=`echo "$CPPFLAGS" | sed -e 's/ +/ /g'`
1313 changequote([,])dnl
1314
1315 ### Doxygen Documentation
1316
1317 AC_PATH_PROG(DOXYGEN, doxygen, no)
1318
1319 AC_MSG_CHECKING([whether to build Doxygen documentation])
1320
1321 if test x$DOXYGEN = xno ; then
1322     have_doxygen=no
1323 else
1324     have_doxygen=yes
1325 fi
1326
1327 if test x$enable_doxygen_docs = xauto ; then
1328     if test x$have_doxygen = xno ; then
1329         enable_doxygen_docs=no
1330     else
1331         enable_doxygen_docs=yes
1332     fi
1333 fi
1334
1335 if test x$enable_doxygen_docs = xyes; then
1336     if test x$have_doxygen = xno; then
1337         AC_MSG_ERROR([Building Doxygen docs explicitly required, but Doxygen not found])
1338     fi
1339 fi
1340
1341 AM_CONDITIONAL(DBUS_DOXYGEN_DOCS_ENABLED, test x$enable_doxygen_docs = xyes)
1342 AC_MSG_RESULT($enable_doxygen_docs)
1343
1344 ### XML Documentation
1345
1346 AC_PATH_PROG(XMLTO, xmlto, no)
1347
1348 AC_MSG_CHECKING([whether to build XML documentation])
1349
1350 if test x$XMLTO = xno ; then
1351     have_xmlto=no
1352 else
1353     have_xmlto=yes
1354 fi
1355
1356 if test x$enable_xml_docs = xauto ; then
1357     if test x$have_xmlto = xno ; then
1358         enable_xml_docs=no
1359     else
1360         enable_xml_docs=yes
1361     fi
1362 fi
1363
1364 if test x$enable_xml_docs = xyes; then
1365     if test x$have_xmlto = xno; then
1366         AC_MSG_ERROR([Building XML docs explicitly required, but xmlto not found])
1367     fi
1368 fi
1369
1370 AM_CONDITIONAL(DBUS_XML_DOCS_ENABLED, test x$enable_xml_docs = xyes)
1371 AC_MSG_RESULT($enable_xml_docs)
1372
1373 AC_PATH_PROG([MAN2HTML], [man2html])
1374 AC_ARG_VAR([MAN2HTML], [Path to man2html (optional)])
1375 AM_CONDITIONAL(DBUS_HAVE_MAN2HTML, test x$MAN2HTML != x)
1376
1377 AM_CONDITIONAL(DBUS_CAN_UPLOAD_DOCS,
1378     test x$enable_doxygen_docs = xyes -a x$enable_xml_docs = xyes -a \
1379          x$MAN2HTML != x)
1380
1381 #### Have to go $localstatedir->$prefix/var->/usr/local/var
1382
1383 #### find the actual value for $prefix that we'll end up with
1384 ##   (I know this is broken and should be done in the Makefile, but
1385 ##    that's a major pain and almost nobody actually seems to care)
1386 AS_AC_EXPAND(EXPANDED_PREFIX, "$prefix")
1387 AS_AC_EXPAND(EXPANDED_LOCALSTATEDIR, "$localstatedir")
1388 AS_AC_EXPAND(EXPANDED_SYSCONFDIR, "$sysconfdir")
1389 AS_AC_EXPAND(EXPANDED_BINDIR, "$bindir")
1390 AS_AC_EXPAND(EXPANDED_LIBDIR, "$libdir")
1391 AS_AC_EXPAND(EXPANDED_LIBEXECDIR, "$libexecdir")
1392 AS_AC_EXPAND(EXPANDED_DATADIR, "$datadir")
1393
1394 #### Check our operating system
1395 operating_system=unknown
1396 if test -f /etc/redhat-release || test -f $EXPANDED_SYSCONFDIR/redhat-release ; then
1397    operating_system=redhat
1398 fi
1399
1400 if test -f /etc/slackware-version || test -f $EXPANDED_SYSCONFDIR/slackware-version ; then
1401    operating_system=slackware
1402 fi
1403
1404 if test -f /usr/bin/cygwin1.dll || test -f $EXPANDED_BINDIR/cygwin1.dll ; then
1405    operating_system=cygwin
1406 fi
1407
1408 #### Sort out init scripts
1409
1410 if test x$with_init_scripts = x; then
1411     case x$operating_system in
1412         xredhat)        with_init_scripts=redhat ;;
1413         xslackware)     with_init_scripts=slackware ;;
1414         xcygwin)        with_init_scripts=cygwin ;;
1415         *)                      with_init_scripts=none ;;
1416     esac
1417 fi
1418
1419 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_RED_HAT, test x$with_init_scripts = xredhat)
1420 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_SLACKWARE, test x$with_init_scripts = xslackware)
1421 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_CYGWIN, test x$with_init_scripts = xcygwin)
1422
1423 ##### systemd unit files
1424 AC_ARG_WITH([systemdsystemunitdir],
1425 AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
1426         [], [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
1427 if test "x$with_systemdsystemunitdir" != xno; then
1428    AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
1429 fi
1430 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
1431
1432 ##### Set up location for system bus socket
1433 if ! test -z "$with_system_socket"; then
1434    DBUS_SYSTEM_SOCKET=$with_system_socket
1435 else
1436    DBUS_SYSTEM_SOCKET=${EXPANDED_LOCALSTATEDIR}/run/dbus/system_bus_socket
1437 fi
1438
1439 AC_SUBST(DBUS_SYSTEM_SOCKET)
1440 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_SOCKET,"$DBUS_SYSTEM_SOCKET",[The name of the socket the system bus listens on by default])
1441
1442 ## system bus only listens on local domain sockets, and never
1443 ## on an abstract socket (so only root can create the socket)
1444 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$DBUS_SYSTEM_SOCKET"
1445 AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
1446 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS, "$DBUS_SYSTEM_BUS_DEFAULT_ADDRESS",[The default D-Bus address of the system bus])
1447
1448 #### Set up the pid file
1449 if ! test -z "$with_system_pid_file"; then
1450    DBUS_SYSTEM_PID_FILE=$with_system_pid_file
1451 elif test x$with_init_scripts = xredhat ; then
1452    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/messagebus.pid
1453 else
1454    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/dbus/pid
1455 fi
1456
1457 AC_SUBST(DBUS_SYSTEM_PID_FILE)
1458
1459 #### Directory to check for console ownership
1460 if ! test -z "$with_console_auth_dir"; then
1461    DBUS_CONSOLE_AUTH_DIR=$with_console_auth_dir
1462 else
1463    DBUS_CONSOLE_AUTH_DIR=/var/run/console/
1464 fi
1465
1466 AC_SUBST(DBUS_CONSOLE_AUTH_DIR)
1467 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_AUTH_DIR, "$DBUS_CONSOLE_AUTH_DIR", [Directory to check for console ownerhip])
1468
1469 #### File to check for console ownership
1470 if test x$have_console_owner_file = xyes; then
1471    if ! test -z "$with_console_owner_file"; then
1472       DBUS_CONSOLE_OWNER_FILE=$with_console_owner_file
1473    else
1474       DBUS_CONSOLE_OWNER_FILE=/dev/console
1475    fi
1476 else
1477   DBUS_CONSOLE_OWNER_FILE=
1478 fi
1479
1480 AC_SUBST(DBUS_CONSOLE_OWNER_FILE)
1481 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_OWNER_FILE, "$DBUS_CONSOLE_OWNER_FILE", [File to check for console ownerhip])
1482
1483 #### User to start the system bus as
1484 if test -z "$with_dbus_user" ; then
1485     DBUS_USER=messagebus
1486 else
1487     DBUS_USER=$with_dbus_user
1488 fi
1489 AC_SUBST(DBUS_USER)
1490 AC_DEFINE_UNQUOTED(DBUS_USER,"$DBUS_USER", [User for running the system BUS daemon])
1491
1492 #### Prefix to install into
1493 DBUS_PREFIX=$EXPANDED_PREFIX
1494 AC_SUBST(DBUS_PREFIX)
1495 AC_DEFINE_UNQUOTED(DBUS_PREFIX,"$DBUS_PREFIX", [Prefix for installing DBUS])
1496
1497 #### Direcotry to install data files into
1498 DBUS_DATADIR=$EXPANDED_DATADIR
1499 AC_SUBST(DBUS_DATADIR)
1500 AC_DEFINE_UNQUOTED(DBUS_DATADIR,"$DBUS_DATADIR", [Directory for installing DBUS data files])
1501
1502 #### Directory to install dbus-daemon
1503 if test -z "$with_dbus_daemondir" ; then
1504     DBUS_DAEMONDIR=$EXPANDED_BINDIR
1505 else
1506     DBUS_DAEMONDIR=$with_dbus_daemondir
1507 fi
1508 AC_SUBST(DBUS_DAEMONDIR)
1509 AC_DEFINE_UNQUOTED(DBUS_DAEMONDIR,"$DBUS_DAEMONDIR", [Directory for installing the DBUS daemon])
1510
1511 #### Directory to install the other binaries
1512 DBUS_BINDIR="$EXPANDED_BINDIR"
1513 AC_SUBST(DBUS_BINDIR)
1514 AC_DEFINE_UNQUOTED(DBUS_BINDIR,"$DBUS_BINDIR", [Directory for installing the binaries])
1515
1516 #### Directory to install the libexec binaries
1517 DBUS_LIBEXECDIR="$EXPANDED_LIBEXECDIR"
1518 AC_SUBST(DBUS_LIBEXECDIR)
1519 AC_DEFINE_UNQUOTED(DBUS_LIBEXECDIR,"$DBUS_LIBEXECDIR", [Directory for installing the libexec binaries])
1520
1521 #### Tell tests where to find certain stuff in builddir
1522
1523 DBUS_PWD=`pwd`
1524 # Useful in a cross-compilation environment, where the tests are run on the host system.
1525 AC_ARG_WITH(dbus-test-dir, AS_HELP_STRING([--with-dbus-test-dir=[dirname]],[path where the tests tools are available]),
1526                            DBUS_PWD=$withval)
1527 AC_DEFUN([TEST_PATH], [
1528 TEST_$1=${DBUS_PWD}/test/$2
1529 AC_DEFINE_UNQUOTED(TEST_$1, "$TEST_$1",
1530                    [Full path to test file test/$2 in builddir])
1531 AC_SUBST(TEST_$1)
1532 ])
1533 AC_DEFUN([TEST_PROG], [
1534 TEST_$1=${DBUS_PWD}/test/$2
1535 AC_DEFINE_UNQUOTED(TEST_$1, "$TEST_$1$EXEEXT",
1536                    [Full path to test file test/$2 in builddir])
1537 AC_SUBST(TEST_$1)
1538 ])
1539
1540 TEST_PATH(VALID_SERVICE_DIR, data/valid-service-files)
1541 TEST_PATH(INVALID_SERVICE_DIR, data/invalid-service-files)
1542 TEST_PATH(VALID_SERVICE_SYSTEM_DIR, data/valid-service-files-system)
1543 TEST_PATH(INVALID_SERVICE_SYSTEM_DIR, data/invalid-service-files-system)
1544 TEST_PROG(SERVICE_BINARY, test-service)
1545 TEST_PROG(SHELL_SERVICE_BINARY, test-shell-service)
1546 TEST_PROG(EXIT_BINARY, test-exit)
1547 TEST_PROG(SEGFAULT_BINARY, test-segfault)
1548 TEST_PROG(SLEEP_FOREVER_BINARY, test-sleep-forever)
1549 TEST_PROG(PRIVSERVER_BINARY, name-test/test-privserver)
1550
1551 AC_DEFINE_UNQUOTED(TEST_BUS_BINARY, "$DBUS_PWD/bus/dbus-daemon$EXEEXT",
1552                    [Full path to the daemon in the builddir])
1553 AC_SUBST(TEST_BUS_BINARY)
1554
1555 ## Export the non-setuid external helper
1556 TEST_LAUNCH_HELPER_BINARY="$DBUS_PWD/bus/dbus-daemon-launch-helper-test$EXEEXT"
1557 AC_SUBST(TEST_LAUNCH_HELPER_BINARY)
1558 AC_DEFINE_UNQUOTED(DBUS_TEST_LAUNCH_HELPER_BINARY, "$TEST_LAUNCH_HELPER_BINARY",
1559                    [Full path to the launch helper test program in the builddir])
1560
1561 #### Find socket directories
1562 if ! test -z "$TMPDIR" ; then
1563    DEFAULT_SOCKET_DIR=$TMPDIR
1564 elif ! test -z "$TEMP" ; then
1565    DEFAULT_SOCKET_DIR=$TEMP
1566 elif ! test -z "$TMP" ; then
1567    DEFAULT_SOCKET_DIR=$TMP
1568 else
1569    DEFAULT_SOCKET_DIR=/tmp
1570 fi
1571
1572 DEFAULT_SOCKET_DIR=`echo $DEFAULT_SOCKET_DIR | sed 's/+/%2B/g'`
1573
1574 if ! test -z "$with_test_socket_dir" ; then
1575    TEST_SOCKET_DIR="$with_test_socket_dir"
1576 else
1577    TEST_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1578 fi
1579 AC_SUBST(TEST_SOCKET_DIR)
1580 AC_DEFINE_UNQUOTED(DBUS_TEST_SOCKET_DIR, "$TEST_SOCKET_DIR", [Where to put test sockets])
1581
1582 if ! test -z "$with_session_socket_dir" ; then
1583    DBUS_SESSION_SOCKET_DIR="$with_session_socket_dir"
1584 else
1585    DBUS_SESSION_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1586 fi
1587 AC_DEFINE_UNQUOTED(DBUS_SESSION_SOCKET_DIR, "$DBUS_SESSION_SOCKET_DIR", [Where per-session bus puts its sockets])
1588 AC_SUBST(DBUS_SESSION_SOCKET_DIR)
1589
1590 if test x$dbus_win = xyes; then
1591         DBUS_SESSION_BUS_DEFAULT_ADDRESS="nonce-tcp:"
1592 elif test x$have_launchd = xyes; then
1593         DBUS_SESSION_BUS_DEFAULT_ADDRESS="launchd:env=DBUS_LAUNCHD_SESSION_BUS_SOCKET"
1594 else
1595         DBUS_SESSION_BUS_DEFAULT_ADDRESS="unix:tmpdir=$DBUS_SESSION_SOCKET_DIR"
1596 fi
1597 AC_SUBST(DBUS_SESSION_BUS_DEFAULT_ADDRESS)
1598
1599 # darwin needs this to initialize the environment
1600 AC_CHECK_HEADERS(crt_externs.h)
1601 AC_CHECK_FUNC(_NSGetEnviron, [AC_DEFINE(HAVE_NSGETENVIRON, 1, [Define if your system needs _NSGetEnviron to set up the environment])])
1602 AH_VERBATIM(_DARWIN_ENVIRON,
1603 [
1604 #if defined(HAVE_NSGETENVIRON) && defined(HAVE_CRT_EXTERNS_H)
1605 # include <sys/time.h>
1606 # include <crt_externs.h>
1607 # define environ (*_NSGetEnviron())
1608 #endif
1609 ])
1610
1611 AC_OUTPUT([
1612 Doxyfile
1613 dbus/versioninfo.rc
1614 dbus/dbus-arch-deps.h
1615 bus/system.conf
1616 bus/session.conf
1617 bus/messagebus
1618 bus/messagebus-config
1619 bus/org.freedesktop.dbus-session.plist
1620 bus/rc.messagebus
1621 bus/dbus.service
1622 bus/dbus.socket
1623 Makefile
1624 dbus/Makefile
1625 bus/Makefile
1626 tools/Makefile
1627 test/Makefile
1628 test/name-test/Makefile
1629 doc/Makefile
1630 doc/dbus-daemon.1
1631 dbus-1.pc
1632 test/data/valid-config-files/debug-allow-all.conf
1633 test/data/valid-config-files/debug-allow-all-sha1.conf
1634 test/data/valid-config-files-system/debug-allow-all-pass.conf
1635 test/data/valid-config-files-system/debug-allow-all-fail.conf
1636 test/data/valid-service-files/org.freedesktop.DBus.TestSuite.PrivServer.service
1637 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteEchoService.service
1638 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteForkingEchoService.service
1639 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteSegfaultService.service
1640 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1641 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1642 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteEchoService.service
1643 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteSegfaultService.service
1644 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1645 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1646 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoExec.service
1647 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoUser.service
1648 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoService.service
1649 ])
1650
1651 dnl ==========================================================================
1652 echo "
1653                     D-Bus $VERSION
1654                   ==============
1655
1656         prefix:                   ${EXPANDED_PREFIX}
1657         exec_prefix:              ${exec_prefix}
1658         libdir:                   ${EXPANDED_LIBDIR}
1659         libexecdir:               ${EXPANDED_LIBEXECDIR}
1660         bindir:                   ${EXPANDED_BINDIR}
1661         sysconfdir:               ${EXPANDED_SYSCONFDIR}
1662         localstatedir:            ${EXPANDED_LOCALSTATEDIR}
1663         datadir:                  ${EXPANDED_DATADIR}
1664         source code location:     ${srcdir}
1665         compiler:                 ${CC}
1666         cflags:                   ${CFLAGS}
1667         cppflags:                 ${CPPFLAGS}
1668         cxxflags:                 ${CXXFLAGS}
1669         64-bit int:               ${DBUS_INT64_TYPE}
1670         32-bit int:               ${DBUS_INT32_TYPE}
1671         16-bit int:               ${DBUS_INT16_TYPE}
1672         Doxygen:                  ${DOXYGEN:-not found}
1673         xmlto:                    ${XMLTO:-not found}
1674         man2html:                 ${MAN2HTML:-not found}"
1675
1676 echo "
1677         Maintainer mode:          ${USE_MAINTAINER_MODE}
1678         gcc coverage profiling:   ${enable_compiler_coverage}
1679         Building unit tests:      ${enable_tests}
1680         Building verbose mode:    ${enable_verbose_mode}
1681         Building assertions:      ${enable_asserts}
1682         Building checks:          ${enable_checks}
1683         Building SELinux support: ${have_selinux}
1684         Building inotify support: ${have_inotify}
1685         Building dnotify support: ${have_dnotify}
1686         Building kqueue support:  ${have_kqueue}
1687         Building X11 code:        ${enable_x11}
1688         Building Doxygen docs:    ${enable_doxygen_docs}
1689         Building XML docs:        ${enable_xml_docs}
1690         Building cache support:   ${enable_userdb_cache}
1691         Building launchd support: ${have_launchd}
1692         Using XML parser:         ${with_xml}
1693         Init scripts style:       ${with_init_scripts}
1694         Abstract socket names:    ${ac_cv_have_abstract_sockets}
1695         System bus socket:        ${DBUS_SYSTEM_SOCKET}
1696         System bus address:       ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1697         System bus PID file:      ${DBUS_SYSTEM_PID_FILE}
1698         Session bus address:      ${DBUS_SESSION_BUS_DEFAULT_ADDRESS}
1699         Console auth dir:         ${DBUS_CONSOLE_AUTH_DIR}
1700         Console owner file:       ${have_console_owner_file}
1701         Console owner file path:  ${DBUS_CONSOLE_OWNER_FILE}
1702         System bus user:          ${DBUS_USER}
1703         Session bus services dir: ${EXPANDED_DATADIR}/dbus-1/services
1704         'make check' socket dir:  ${TEST_SOCKET_DIR}
1705 "
1706 if test x$have_launchd = xyes; then
1707         echo "        launchd agent dir:        ${LAUNCHD_AGENT_DIR}"
1708 fi
1709 echo
1710
1711 if test x$enable_tests = xyes; then
1712         echo "NOTE: building with unit tests increases the size of the installed library and renders it insecure."
1713 fi
1714 if test x$enable_tests = xyes -a x$enable_asserts = xno; then
1715         echo "NOTE: building with unit tests but without assertions means tests may not properly report failures (this configuration is only useful when doing something like profiling the tests)"
1716 fi
1717 if test x$enable_compiler_coverage = xyes; then
1718         echo "NOTE: building with coverage profiling is definitely for developers only."
1719 fi
1720 if test x$enable_verbose_mode = xyes; then
1721         echo "NOTE: building with verbose mode increases library size, may slightly increase security risk, and decreases performance."
1722 fi
1723 if test x$enable_asserts = xyes; then
1724         echo "NOTE: building with assertions increases library size and decreases performance."
1725 fi
1726 if test x$enable_checks = xno; then
1727         echo "NOTE: building without checks for arguments passed to public API makes it harder to debug apps using D-Bus, but will slightly decrease D-Bus library size and _very_ slightly improve performance."
1728 fi
1729 if test x$dbus_use_libxml = xtrue; then
1730         echo
1731         echo "WARNING: You have chosen to use libxml as your xml parser however this code path is not maintained by the D-Bus developers and if it breaks you get to keep the pieces.  If you have selected this option in err please reconfigure with expat (e.g. --with-xml=expat)."
1732 fi