configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of PulseAudio.
   7 #
   8 # Copyright 2004-2006 Lennart Poettering
   9 # Copyright 2006-2007 Pierre Ossman <ossman@cendio.se> for Cendio AB
  10 #
  11 # PulseAudio is free software; you can redistribute it and/or modify it
  12 # under the terms of the GNU Lesser General Public License as published by
  13 # the Free Software Foundation; either version 2 of the License, or
  14 # (at your option) any later version.
  15 #
  16 # PulseAudio is distributed in the hope that it will be useful, but
  17 # WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  19 # General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU Lesser General Public License
  22 # along with PulseAudio; if not, write to the Free Software Foundation,
  23 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  24
  25 AC_PREREQ(2.57)
  26
  27 m4_define(PA_MAJOR, [0])
  28 m4_define(PA_MINOR, [9])
  29 m4_define(PA_MICRO, [8])
  30
  31 AC_INIT([pulseaudio], PA_MAJOR.PA_MINOR.PA_MICRO,[mzchyfrnhqvb (at) 0pointer (dot) net])
  32 AC_CONFIG_SRCDIR([src/daemon/main.c])
  33 AC_CONFIG_HEADERS([config.h])
  34 AM_INIT_AUTOMAKE([foreign -Wall])
  35
  36 AC_SUBST(PA_MAJORMINOR, "PA_MAJOR.PA_MINOR")
  37 AC_SUBST(PACKAGE_URL, [http://pulseaudio.org/])
  38
  39 AC_SUBST(PA_API_VERSION, 11)
  40 AC_SUBST(PA_PROTOCOL_VERSION, 12)
  41
  42 # The stable ABI for client applications, for the version info x:y:z
  43 # always will hold y=z
  44 AC_SUBST(LIBPULSE_VERSION_INFO, [4:0:4])
  45
  46 # A simplified, synchronous, ABI-stable interface for client
  47 # applications, for the version info x:y:z always will hold y=z
  48 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [0:1:0])
  49
  50 # The ABI-stable network browsing interface for client applications,
  51 # for the version info x:y:z always will hold y=z
  52 AC_SUBST(LIBPULSE_BROWSE_VERSION_INFO, [1:1:1])
  53
  54 # The ABI-stable GLib adapter for client applications, for the version
  55 # info x:y:z always will hold y=z
  56 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:3:0])
  57
  58 # An internally used, ABI-unstable library that contains the
  59 # PulseAudio core, SONAMEs are bumped on every release, version info
  60 # suffix will always be 0:0
  61 AC_SUBST(LIBPULSECORE_VERSION_INFO, [5:0:0])
  62
  63 AC_CANONICAL_HOST
  64
  65 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  66    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  67    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  68 fi
  69
  70 #### Platform hacks ####
  71
  72 case $host in
  73    *-*-solaris* )
  74       AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  75       AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
  76       AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  77       ;;
  78 esac
  79
  80 #### Checks for programs. ####
  81
  82 # mkdir -p
  83
  84 AC_PROG_MKDIR_P
  85
  86 # CC
  87
  88 AC_PROG_CC
  89 AM_PROG_CC_C_O
  90 AC_PROG_GCC_TRADITIONAL
  91 AC_GNU_SOURCE
  92
  93 # M4
  94
  95 AC_PATH_PROG([M4], [m4 gm4], [no])
  96 if test "x$M4" = xno ; then
  97    AC_MSG_ERROR([m4 missing])
  98 fi
  99
 100 # GCC flags
 101
 102 test_gcc_flag() {
 103     AC_LANG_CONFTEST([int main(int argc, char*argv[]) {}])
 104     $CC -c conftest.c $CFLAGS -o conftest.o > /dev/null 2> /dev/null
 105     ret=$?
 106     rm -f conftest.o
 107     return $ret
 108 }
 109
 110 # If using GCC specify some additional parameters
 111 if test "x$GCC" = "xyes" ; then
 112
 113     # We use gnu99 instead of c99 because many have interpreted the standard
 114     # in a way that int64_t isn't defined on non-64 bit platforms.
 115     DESIRED_FLAGS="-std=gnu99 -Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter -ffast-math"
 116
 117     for flag in $DESIRED_FLAGS ; do
 118         AC_MSG_CHECKING([whether $CC accepts $flag])
 119         if test_gcc_flag $flag ; then
 120            CFLAGS="$CFLAGS $flag"
 121            AC_MSG_RESULT([yes])
 122         else
 123            AC_MSG_RESULT([no])
 124         fi
 125     done
 126 fi
 127
 128 AC_MSG_CHECKING([whether $CC knows __sync_bool_compare_and_swap()])
 129 AC_LANG_CONFTEST([int main() { int a = 4; __sync_bool_compare_and_swap(&a, 4, 5); }])
 130 $CC conftest.c $CFLAGS -o conftest > /dev/null 2> /dev/null
 131 ret=$?
 132 rm -f conftest.o conftest
 133 if test $ret -eq 0 ; then
 134     AC_DEFINE([HAVE_ATOMIC_BUILTINS], 1, [Have __sync_bool_compare_and_swap() and friends.])
 135     AC_MSG_RESULT([yes])
 136 else
 137     AC_MSG_RESULT([no])
 138 fi
 139
 140 AC_MSG_CHECKING([whether $CC knows __thread])
 141 AC_LANG_CONFTEST([static __thread int a = 6; int main() { a = 5; }])
 142 $CC conftest.c $CFLAGS -o conftest > /dev/null 2> /dev/null
 143 ret=$?
 144 rm -f conftest.o conftest
 145 if test $ret -eq 0 ; then
 146     AC_DEFINE([HAVE_TLS_BUILTIN], 1, [Have __thread().])
 147     AC_MSG_RESULT([yes])
 148 else
 149     AC_MSG_RESULT([no])
 150 fi
 151
 152 AC_MSG_CHECKING([whether $CC knows _Bool])
 153 AC_LANG_CONFTEST([int main() { _Bool b; }])
 154 $CC conftest.c $CFLAGS -o conftest > /dev/null 2> /dev/null
 155 ret=$?
 156 rm -f conftest.o conftest
 157 if test $ret -eq 0 ; then
 158     AC_DEFINE([HAVE_STD_BOOL], 1, [Have _Bool.])
 159     AC_MSG_RESULT([yes])
 160 else
 161     AC_MSG_RESULT([no])
 162 fi
 163
 164 #### libtool stuff ####
 165
 166 AC_LTDL_ENABLE_INSTALL
 167 AC_LIBLTDL_INSTALLABLE
 168 AC_LIBTOOL_DLOPEN
 169 AC_LIBTOOL_WIN32_DLL
 170 AC_PROG_LIBTOOL
 171 AC_SUBST(LTDLINCL)
 172 AC_SUBST(LIBLTDL)
 173 AC_CONFIG_SUBDIRS(libltdl)
 174
 175 old_LIBS=$LIBS
 176 LIBS="$LIBS $LIBLTDL"
 177 AC_CHECK_FUNCS([lt_dlmutex_register])
 178 LIBS=$old_LIBS
 179 AC_CHECK_TYPES([lt_user_dlloader, lt_dladvise], , , [#include <ltdl.h>])
 180
 181 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 182     AC_MSG_ERROR([[
 183
 184         *** Cannot find the libltdl development files.
 185         *** Maybe you need to install the libltdl-dev package.
 186         ]])
 187 fi
 188
 189 #### Determine build environment ####
 190
 191 os_is_win32=0
 192
 193 case "$host_os" in
 194         mingw*)
 195         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 196         os_is_win32=1
 197                 ;;
 198         esac
 199
 200 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 201
 202 ###################################
 203 #   Basic environment checks      #
 204 ###################################
 205
 206 #### Checks for header files. ####
 207
 208 # ISO
 209 AC_HEADER_STDC
 210
 211 # POSIX
 212 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 213     netinet/in_systm.h netinet/tcp.h poll.h pwd.h sched.h \
 214     sys/mman.h sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 215     syslog.h sys/dl.h dlfcn.h linux/sockios.h])
 216 AC_CHECK_HEADERS([netinet/ip.h], [], [],
 217                  [#include <sys/types.h>
 218                   #if HAVE_NETINET_IN_H
 219                   # include <netinet/in.h>
 220                   #endif
 221                   #if HAVE_NETINET_IN_SYSTM_H
 222                   # include <netinet/in_systm.h>
 223                   #endif
 224                  ])
 225 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 226 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 227
 228 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 229 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 230
 231 # Linux
 232 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 233
 234 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 235
 236 AC_CHECK_HEADERS([sys/prctl.h])
 237
 238 # Solaris
 239 AC_CHECK_HEADERS([sys/filio.h])
 240
 241 # Windows
 242 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 243
 244 # Other
 245 AC_CHECK_HEADERS([sys/ioctl.h])
 246 AC_CHECK_HEADERS([byteswap.h])
 247 AC_CHECK_HEADERS([sys/syscall.h])
 248
 249 #### Typdefs, structures, etc. ####
 250
 251 AC_C_CONST
 252 AC_C_BIGENDIAN
 253 AC_TYPE_PID_T
 254 AC_TYPE_SIZE_T
 255 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 256     [Define ssize_t if it is not done by the standard libs.])])
 257 AC_TYPE_OFF_T
 258 AC_TYPE_SIGNAL
 259 AC_TYPE_UID_T
 260
 261 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [
 262 HAVE_SIGXCPU=1
 263 AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?])
 264 ], [HAVE_SIGXCPU=0])
 265 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 266
 267 # Solaris lacks this
 268 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 269     [AC_CHECK_DEFINE([INADDR_NONE], [winsock2.h], [],
 270         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 271
 272 #### POSIX threads ####
 273
 274 ACX_PTHREAD
 275
 276 #### Check for libs ####
 277
 278 # ISO
 279 AC_SEARCH_LIBS([pow], [m])
 280
 281 # POSIX
 282 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 283 AC_SEARCH_LIBS([dlopen], [dl])
 284 AC_SEARCH_LIBS([shm_open], [rt])
 285 AC_SEARCH_LIBS([inet_ntop], [nsl])
 286 AC_SEARCH_LIBS([timer_create], [rt])
 287
 288 # BSD
 289 AC_SEARCH_LIBS([connect], [socket])
 290
 291 # Non-standard
 292
 293 # This magic is needed so we do not needlessly add static libs to the win32
 294 # build, disabling its ability to make dlls.
 295 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 296
 297 #### Check for functions ####
 298
 299 # ISO
 300 AC_CHECK_FUNCS([lrintf strtof])
 301
 302 # POSIX
 303 AC_FUNC_FORK
 304 AC_FUNC_GETGROUPS
 305 AC_FUNC_SELECT_ARGTYPES
 306 AC_CHECK_FUNCS([chmod chown clock_gettime getaddrinfo getgrgid_r \
 307     getpwuid_r gettimeofday getuid inet_ntop inet_pton mlock nanosleep \
 308     pipe posix_fadvise posix_madvise posix_memalign setpgid setsid shm_open \
 309     sigaction sleep sysconf])
 310 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 311
 312 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 313
 314 # X/OPEN
 315 AC_CHECK_FUNCS([readlink])
 316
 317 # SUSv2
 318 AC_CHECK_FUNCS([ctime_r usleep])
 319
 320 # SUSv3
 321 AC_CHECK_FUNCS([strerror_r])
 322
 323 # BSD
 324 AC_CHECK_FUNCS([lstat])
 325
 326 # Non-standard
 327
 328 AC_CHECK_FUNCS([setresuid setresgid setreuid setregid seteuid setegid ppoll strsignal sig2str strtof_l])
 329
 330 AC_MSG_CHECKING([for PTHREAD_PRIO_INHERIT])
 331 AC_LANG_CONFTEST([AC_LANG_SOURCE([[
 332 #include <pthread.h>
 333 int main() { int i = PTHREAD_PRIO_INHERIT; }]])])
 334 $PTHREAD_CC conftest.c $PTHREAD_CFLAGS $CFLAGS $PTHREAD_LIBS -o conftest > /dev/null 2> /dev/null
 335 ret=$?
 336 rm -f conftest.o conftest
 337
 338 if test $ret -eq 0 ; then
 339     AC_DEFINE([HAVE_PTHREAD_PRIO_INHERIT], 1, [Have PTHREAD_PRIO_INHERIT.])
 340     AC_MSG_RESULT([yes])
 341 else
 342     AC_MSG_RESULT([no])
 343 fi
 344
 345 #### Large File-Support (LFS) ####
 346
 347 AC_SYS_LARGEFILE
 348
 349 # Check for open64 to know if the current system does have open64() and similar functions
 350 AC_CHECK_FUNCS([open64])
 351
 352 #### [lib]iconv ####
 353
 354 AM_ICONV
 355
 356 ###################################
 357 #      External libraries         #
 358 ###################################
 359
 360 #### X11 (optional) ####
 361
 362 HAVE_X11=0
 363
 364 # The macro tests the host, not the build target
 365 if test "x$os_is_win32" != "x1" ; then
 366     AC_PATH_XTRA
 367     test "x$no_x" != "xyes" && HAVE_X11=1
 368 fi
 369
 370 AC_SUBST(HAVE_X11)
 371 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 372 if test "x$HAVE_X11" = "x1" ; then
 373     AC_DEFINE([HAVE_X11], 1, [Have X11])
 374 fi
 375
 376 #### Capabilities (optional) ####
 377
 378 CAP_LIBS=''
 379
 380 AC_ARG_WITH(
 381         [caps],
 382         AC_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 383
 384 if test "x${with_caps}" != "xno"; then
 385     AC_SEARCH_LIBS([cap_init], [cap], [], [
 386                     if test "x${with_caps}" = "xyes" ; then
 387                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 388                     fi])
 389     AC_CHECK_HEADERS([sys/capability.h], [], [
 390                     if test "x${with_caps}" = "xyes" ; then
 391                         AC_MSG_ERROR([*** POSIX caps headers not found])
 392                     fi])
 393 fi
 394
 395 #### pkg-config ####
 396
 397 # Check for pkg-config manually first, as if its not installed the
 398 # PKG_PROG_PKG_CONFIG macro won't be defined.
 399 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 400
 401 if test x"$have_pkg_config" = "xno"; then
 402     AC_MSG_ERROR(pkg-config is required to install this program)
 403 fi
 404
 405 PKG_PROG_PKG_CONFIG
 406
 407 #### Sound file ####
 408
 409 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 410 AC_SUBST(LIBSNDFILE_CFLAGS)
 411 AC_SUBST(LIBSNDFILE_LIBS)
 412
 413 #### atomic-ops ###
 414
 415 AC_CHECK_HEADERS([atomic_ops.h], [], [
 416 AC_MSG_ERROR([*** libatomic-ops headers not found])
 417 ])
 418
 419 # Win32 does not need the lib and breaks horribly if we try to include it
 420 if test "x$os_is_win32" != "x1" ; then
 421     LIBS="$LIBS -latomic_ops"
 422 fi
 423
 424 #### Libsamplerate support (optional) ####
 425
 426 AC_ARG_ENABLE([samplerate],
 427     AC_HELP_STRING([--disable-samplerate], [Disable optional libsamplerate support]),
 428         [
 429             case "${enableval}" in
 430                 yes) samplerate=yes ;;
 431                 no) samplerate=no ;;
 432                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-samplerate) ;;
 433             esac
 434         ],
 435         [samplerate=auto])
 436
 437 if test "x${samplerate}" != xno ; then
 438     PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ],
 439         HAVE_LIBSAMPLERATE=1,
 440         [
 441             HAVE_LIBSAMPLERATE=0
 442             if test "x$samplerate" = xyes ; then
 443                 AC_MSG_ERROR([*** Libsamplerate not found])
 444             fi
 445         ])
 446 else
 447     HAVE_LIBSAMPLERATE=0
 448 fi
 449
 450 if test "x${HAVE_LIBSAMPLERATE}" = x1 ; then
 451    AC_DEFINE([HAVE_LIBSAMPLERATE], 1, [Have libsamplerate?])
 452 fi
 453
 454 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 455 AC_SUBST(LIBSAMPLERATE_LIBS)
 456 AC_SUBST(HAVE_LIBSAMPLERATE)
 457 AM_CONDITIONAL([HAVE_LIBSAMPLERATE], [test "x$HAVE_LIBSAMPLERATE" = x1])
 458
 459 #### OSS support (optional) ####
 460
 461 AC_ARG_ENABLE([oss],
 462     AC_HELP_STRING([--disable-oss], [Disable optional OSS support]),
 463         [
 464             case "${enableval}" in
 465                 yes) oss=yes ;;
 466                 no) oss=no ;;
 467                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-oss) ;;
 468             esac
 469         ],
 470         [oss=auto])
 471
 472 if test "x${oss}" != xno ; then
 473     AC_CHECK_HEADERS([sys/soundcard.h],
 474         [
 475             HAVE_OSS=1
 476             AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 477         ],
 478         [
 479             HAVE_OSS=0
 480             if test "x$oss" = xyes ; then
 481                 AC_MSG_ERROR([*** OSS support not found])
 482             fi
 483         ])
 484 else
 485     HAVE_OSS=0
 486 fi
 487
 488 AC_SUBST(HAVE_OSS)
 489 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 490
 491
 492 #### ALSA support (optional) ####
 493
 494 AC_ARG_ENABLE([alsa],
 495     AC_HELP_STRING([--disable-alsa], [Disable optional ALSA support]),
 496         [
 497             case "${enableval}" in
 498                 yes) alsa=yes ;;
 499                 no) alsa=no ;;
 500                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-alsa) ;;
 501             esac
 502         ],
 503         [alsa=auto])
 504
 505 if test "x${alsa}" != xno ; then
 506     PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.0 ],
 507         [
 508             HAVE_ALSA=1
 509             AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 510         ],
 511         [
 512             HAVE_ALSA=0
 513             if test "x$alsa" = xyes ; then
 514                 AC_MSG_ERROR([*** ALSA support not found])
 515             fi
 516         ])
 517 else
 518     HAVE_ALSA=0
 519 fi
 520
 521 AC_SUBST(ASOUNDLIB_CFLAGS)
 522 AC_SUBST(ASOUNDLIB_LIBS)
 523 AC_SUBST(HAVE_ALSA)
 524 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 525
 526 #### Solaris audio support (optional) ####
 527
 528 AC_ARG_ENABLE([solaris],
 529     AC_HELP_STRING([--disable-solaris], [Disable optional Solaris audio support]),
 530         [
 531             case "${enableval}" in
 532                 yes) solaris=yes ;;
 533                 no) solaris=no ;;
 534                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-solaris) ;;
 535             esac
 536         ],
 537         [solaris=auto])
 538
 539 if test "x${solaris}" != xno ; then
 540     AC_CHECK_HEADERS([sys/audio.h],
 541         [
 542             HAVE_SOLARIS=1
 543             AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 544         ],
 545         [
 546             HAVE_SOLARIS=0
 547             if test "x$solaris" = xyes ; then
 548                 AC_MSG_ERROR([*** Solaris audio support not found])
 549             fi
 550         ])
 551 else
 552     HAVE_SOLARIS=0
 553 fi
 554
 555 AC_SUBST(HAVE_SOLARIS)
 556 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 557
 558 #### GLib 2 support (optional) ####
 559
 560 AC_ARG_ENABLE([glib2],
 561     AC_HELP_STRING([--disable-glib2], [Disable optional GLib 2 support]),
 562         [
 563             case "${enableval}" in
 564                 yes) glib2=yes ;;
 565                 no) glib2=no ;;
 566                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib2) ;;
 567             esac
 568         ],
 569         [glib2=auto])
 570
 571 if test "x${glib2}" != xno ; then
 572     PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ],
 573         HAVE_GLIB20=1,
 574         [
 575             HAVE_GLIB20=0
 576             if test "x$glib2" = xyes ; then
 577                 AC_MSG_ERROR([*** GLib 2 support not found])
 578             fi
 579         ])
 580 else
 581     HAVE_GLIB20=0
 582 fi
 583
 584 AC_SUBST(GLIB20_CFLAGS)
 585 AC_SUBST(GLIB20_LIBS)
 586 AC_SUBST(HAVE_GLIB20)
 587 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 588
 589 #### GConf support (optional) ####
 590
 591 AC_ARG_ENABLE([gconf],
 592     AC_HELP_STRING([--disable-gconf], [Disable optional GConf support]),
 593         [
 594             case "${enableval}" in
 595                 yes) gconf=yes ;;
 596                 no) gconf=no ;;
 597                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-gconf) ;;
 598             esac
 599         ],
 600         [glib=auto])
 601
 602 if test "x${gconf}" != xno ; then
 603     PKG_CHECK_MODULES(GCONF, [ gconf-2.0 >= 2.4.0 ],
 604         HAVE_GCONF=1,
 605         [
 606             HAVE_GCONF=0
 607             if test "x$gconf" = xyes ; then
 608                 AC_MSG_ERROR([*** GConf support not found])
 609             fi
 610         ])
 611 else
 612     HAVE_GCONF=0
 613 fi
 614
 615 AC_SUBST(GCONF_CFLAGS)
 616 AC_SUBST(GCONF_LIBS)
 617 AC_SUBST(HAVE_GCONF)
 618 AM_CONDITIONAL([HAVE_GCONF], [test "x$HAVE_GCONF" = x1])
 619
 620 #### Avahi support (optional) ####
 621
 622 AC_ARG_ENABLE([avahi],
 623     AC_HELP_STRING([--disable-avahi], [Disable optional Avahi support]),
 624         [
 625             case "${enableval}" in
 626                 yes) avahi=yes ;;
 627                 no) avahi=no ;;
 628                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-avahi) ;;
 629             esac
 630         ],
 631         [avahi=auto])
 632
 633 if test "x${avahi}" != xno ; then
 634     PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ],
 635         HAVE_AVAHI=1,
 636         [
 637                 HAVE_AVAHI=0
 638                 if test "x$avahi" = xyes ; then
 639                         AC_MSG_ERROR([*** Avahi support not found])
 640                 fi
 641         ])
 642 else
 643     HAVE_AVAHI=0
 644 fi
 645
 646 AC_SUBST(AVAHI_CFLAGS)
 647 AC_SUBST(AVAHI_LIBS)
 648 AC_SUBST(HAVE_AVAHI)
 649 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
 650
 651 ### LIBOIL ####
 652
 653 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 654 AC_SUBST(LIBOIL_CFLAGS)
 655 AC_SUBST(LIBOIL_LIBS)
 656
 657 ### JACK (optional) ####
 658
 659 AC_ARG_ENABLE([jack],
 660     AC_HELP_STRING([--disable-jack], [Disable optional JACK support]),
 661         [
 662             case "${enableval}" in
 663                 yes) jack=yes ;;
 664                 no) jack=no ;;
 665                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-jack) ;;
 666             esac
 667         ],
 668         [jack=auto])
 669
 670 if test "x${jack}" != xno ; then
 671     PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ],
 672         HAVE_JACK=1,
 673         [
 674             HAVE_JACK=0
 675             if test "x$jack" = xyes ; then
 676                 AC_MSG_ERROR([*** JACK support not found])
 677             fi
 678         ])
 679 else
 680     HAVE_JACK=0
 681 fi
 682
 683 AC_SUBST(JACK_CFLAGS)
 684 AC_SUBST(JACK_LIBS)
 685 AC_SUBST(HAVE_JACK)
 686 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 687
 688 #### Async DNS support (optional) ####
 689
 690 AC_ARG_ENABLE([asyncns],
 691     AC_HELP_STRING([--disable-asyncns], [Disable optional Async DNS support]),
 692         [
 693             case "${enableval}" in
 694                 yes) asyncns=yes ;;
 695                 no) asyncns=no ;;
 696                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-asyncns) ;;
 697             esac
 698         ],
 699         [asyncns=auto])
 700
 701 if test "x${asyncns}" != xno ; then
 702     PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ],
 703         HAVE_LIBASYNCNS=1,
 704         [
 705             HAVE_LIBASYNCNS=0
 706             if test "x$asyncns" = xyes ; then
 707                 AC_MSG_ERROR([*** Async DNS support not found])
 708             fi
 709         ])
 710 else
 711     HAVE_LIBASYNCNS=0
 712 fi
 713
 714 AC_SUBST(LIBASYNCNS_CFLAGS)
 715 AC_SUBST(LIBASYNCNS_LIBS)
 716 AC_SUBST(HAVE_LIBASYNCNS)
 717 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 718
 719 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 720    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 721 fi
 722
 723 #### TCP wrappers (optional) ####
 724
 725 AC_ARG_ENABLE([tcpwrap],
 726     AC_HELP_STRING([--disable-tcpwrap], [Disable optional TCP wrappers support]),
 727         [
 728             case "${enableval}" in
 729                 yes) tcpwrap=yes ;;
 730                 no) tcpwrap=no ;;
 731                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 732             esac
 733         ],
 734         [tcpwrap=auto])
 735
 736 if test "x${tcpwrap}" != xno ; then
 737     ACX_LIBWRAP
 738     if test "x${LIBWRAP_LIBS}" = x && test "x$tcpwrap" = xyes ; then
 739         AC_MSG_ERROR([*** TCP wrappers support not found])
 740     fi
 741 else
 742     LIBWRAP_LIBS=
 743 fi
 744
 745 AC_SUBST(LIBWRAP_LIBS)
 746
 747 #### LIRC support (optional) ####
 748
 749 AC_ARG_ENABLE([lirc],
 750     AC_HELP_STRING([--disable-lirc], [Disable optional LIRC support]),
 751         [
 752             case "${enableval}" in
 753                 yes) lirc=yes ;;
 754                 no) lirc=no ;;
 755                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-lirc) ;;
 756             esac
 757         ],
 758         [lirc=auto])
 759
 760 if test "x${lirc}" != xno ; then
 761     ACX_LIRC
 762     if test "x${HAVE_LIRC}" = x0 && test "x$lirc" = xyes ; then
 763         AC_MSG_ERROR([*** LIRC support not found])
 764     fi
 765 else
 766     HAVE_LIRC=0
 767 fi
 768
 769 AC_SUBST(LIRC_CFLAGS)
 770 AC_SUBST(LIRC_LIBS)
 771 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 772
 773 #### HAL support (optional) ####
 774
 775 AC_ARG_ENABLE([hal],
 776     AC_HELP_STRING([--disable-hal], [Disable optional HAL support]),
 777         [
 778             case "${enableval}" in
 779                 yes) hal=yes ;;
 780                 no) hal=no ;;
 781                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-hal) ;;
 782             esac
 783         ],
 784         [hal=auto])
 785 if test "x${hal}" != xno -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \) ; then
 786     PKG_CHECK_MODULES(HAL, [ hal >= 0.5.7 ],
 787         HAVE_HAL=1,
 788         [
 789             HAVE_HAL=0
 790             if test "x$hal" = xyes ; then
 791                 AC_MSG_ERROR([*** HAL support not found])
 792             fi
 793         ])
 794 else
 795     HAVE_HAL=0
 796 fi
 797
 798 AC_SUBST(HAL_CFLAGS)
 799 AC_SUBST(HAL_LIBS)
 800 AC_SUBST(HAVE_HAL)
 801 AM_CONDITIONAL([HAVE_HAL], [test "x$HAVE_HAL" = x1])
 802
 803 #### BlueZ support (optional) ####
 804
 805 AC_ARG_ENABLE([bluez],
 806     AC_HELP_STRING([--disable-bluez], [Disable optional BlueZ support]),
 807         [
 808             case "${enableval}" in
 809                 yes) bluez=yes ;;
 810                 no) bluez=no ;;
 811                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-bluez) ;;
 812             esac
 813         ],
 814         [bluez=auto])
 815 if test "x${bluez}" != xno ; then
 816     PKG_CHECK_MODULES(BLUEZ, [ bluez >= 3.0 ],
 817         HAVE_BLUEZ=1,
 818         [
 819             HAVE_BLUEZ=0
 820             if test "x$bluez" = xyes ; then
 821                 AC_MSG_ERROR([*** BLUEZ support not found])
 822             fi
 823         ])
 824 else
 825     HAVE_BLUEZ=0
 826 fi
 827
 828 AC_SUBST(BLUEZ_CFLAGS)
 829 AC_SUBST(BLUEZ_LIBS)
 830 AC_SUBST(HAVE_BLUEZ)
 831 AM_CONDITIONAL([HAVE_BLUEZ], [test "x$HAVE_BLUEZ" = x1])
 832
 833 #### D-Bus support (optional) ####
 834
 835 AC_ARG_ENABLE([dbus],
 836     AC_HELP_STRING([--disable-dbus], [Disable optional D-Bus support]),
 837         [
 838             case "${enableval}" in
 839                 yes) dbus=yes ;;
 840                 no) dbus=no ;;
 841                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-dbus) ;;
 842             esac
 843         ],
 844         [dbus=auto])
 845
 846 if test "x$HAVE_HAL" = x1 ; then
 847    dbus=yes
 848 fi
 849
 850 if test "x${dbus}" != xno || test "x${bluez}" != xno || "x${hal}" != xno ; then
 851
 852     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.0.0 ],
 853         [
 854             HAVE_DBUS=1
 855             saved_LIBS="$LIBS"
 856             LIBS="$LIBS $DBUS_LIBS"
 857             AC_CHECK_FUNCS(dbus_watch_get_unix_fd)
 858             LIBS="$saved_LIBS"
 859             AC_DEFINE([HAVE_DBUS], 1, [Have D-Bus.])
 860         ],
 861         [
 862             HAVE_DBUS=0
 863             if test "x$dbus" = xyes ; then
 864                 AC_MSG_ERROR([*** D-Bus support not found])
 865             fi
 866         ])
 867 else
 868     HAVE_DBUS=0
 869 fi
 870
 871 AC_SUBST(DBUS_CFLAGS)
 872 AC_SUBST(DBUS_LIBS)
 873 AC_SUBST(HAVE_DBUS)
 874 AM_CONDITIONAL([HAVE_DBUS], [test "x$HAVE_DBUS" = x1])
 875
 876 #### PolicyKit support (optional) ####
 877
 878 AC_ARG_ENABLE([polkit],
 879     AC_HELP_STRING([--disable-polkit], [Disable optional PolicyKit support]),
 880         [
 881             case "${enableval}" in
 882                 yes) polkit=yes ;;
 883                 no) polkit=no ;;
 884                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-polkit) ;;
 885             esac
 886         ],
 887         [polkit=auto])
 888
 889 if test "x${polkit}" != xno ; then
 890
 891     PKG_CHECK_MODULES(POLKIT, [ polkit-dbus ],
 892         [
 893             HAVE_POLKIT=1
 894             saved_LIBS="$LIBS"
 895             LIBS="$LIBS $POLKIT_LIBS"
 896             AC_CHECK_FUNCS(polkit_context_is_caller_authorized)
 897             LIBS="$saved_LIBS"
 898             AC_DEFINE([HAVE_POLKIT], 1, [Have PolicyKit])
 899             policydir=`pkg-config polkit-dbus --variable prefix`/share/PolicyKit/policy/
 900             AC_SUBST(policydir)
 901         ],
 902         [
 903             HAVE_POLKIT=0
 904             if test "x$polkit" = xyes ; then
 905                 AC_MSG_ERROR([*** PolicyKit support not found])
 906             fi
 907         ])
 908 else
 909     HAVE_POLKIT=0
 910 fi
 911
 912 AC_SUBST(POLKIT_CFLAGS)
 913 AC_SUBST(POLKIT_LIBS)
 914 AC_SUBST(HAVE_POLKIT)
 915 AM_CONDITIONAL([HAVE_POLKIT], [test "x$HAVE_POLKIT" = x1])
 916
 917 ### Build and Install man pages ###
 918 AC_ARG_ENABLE(manpages,
 919         AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]),
 920 [case "${enableval}" in
 921   yes) manpages=yes ;;
 922   no)  manpages=no ;;
 923   *) AC_MSG_ERROR([bad value ${enableval} for --disable-manpages]) ;;
 924 esac],[manpages=yes])
 925
 926 if test x$manpages = xyes ; then
 927     #
 928     # XMLTOMAN manpage generation
 929     #
 930     AC_ARG_ENABLE(xmltoman,
 931     AS_HELP_STRING([--disable-xmltoman],[Enable rebuilding of man pages with xmltoman]),
 932     [case "${enableval}" in
 933       yes) xmltoman=yes ;;
 934       no)  xmltoman=no ;;
 935       *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
 936     esac],[xmltoman=yes])
 937
 938     if test x$xmltoman = xyes ; then
 939         AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
 940     fi
 941
 942     if test x$have_xmltoman = xno -o x$xmltoman = xno; then
 943         if ! test -e man/pulseaudio.1 ; then
 944             AC_MSG_ERROR([*** xmltoman was not found or was disabled, it is required to build the manpages as they have not been pre-built, install xmltoman, pass --disable-manpages or dont pass --disable-xmltoman])
 945             exit 1
 946         fi
 947         AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
 948         xmltoman=no
 949     fi
 950 fi
 951 AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
 952 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$manpages" = xyes])
 953
 954 #### PulseAudio system group & user  #####
 955
 956 AC_ARG_WITH(system_user, AS_HELP_STRING([--with-system-user=<user>],[User for running the PulseAudio daemon as a system-wide instance (pulse)]))
 957 if test -z "$with_system_user" ; then
 958     PA_SYSTEM_USER=pulse
 959 else
 960     PA_SYSTEM_USER=$with_system_user
 961 fi
 962 AC_SUBST(PA_SYSTEM_USER)
 963 AC_DEFINE_UNQUOTED(PA_SYSTEM_USER,"$PA_SYSTEM_USER", [User for running the PulseAudio system daemon])
 964
 965 AC_ARG_WITH(system_group,AS_HELP_STRING([--with-system-group=<group>],[Group for running the PulseAudio daemon as a system-wide instance (pulse)]))
 966 if test -z "$with_system_group" ; then
 967     PA_SYSTEM_GROUP=pulse
 968 else
 969     PA_SYSTEM_GROUP=$with_system_group
 970 fi
 971 AC_SUBST(PA_SYSTEM_GROUP)
 972 AC_DEFINE_UNQUOTED(PA_SYSTEM_GROUP,"$PA_SYSTEM_GROUP", [Group for the PulseAudio system daemon])
 973
 974 AC_ARG_WITH(realtime_group,AS_HELP_STRING([--with-realtime-group=<group>],[Group for users that are allowed to start the PulseAudio daemon with realtime scheduling (realtime)]))
 975 if test -z "$with_realtime_group" ; then
 976     PA_REALTIME_GROUP=pulse-rt
 977 else
 978     PA_REALTIME_GROUP=$with_realtime_group
 979 fi
 980 AC_SUBST(PA_REALTIME_GROUP)
 981 AC_DEFINE_UNQUOTED(PA_REALTIME_GROUP,"$PA_REALTIME_GROUP", [Realtime group])
 982
 983 AC_ARG_WITH(access_group,AS_HELP_STRING([--with-access-group=<group>],[Group which is allowed access to a system-wide PulseAudio daemon (pulse-access)]))
 984 if test -z "$with_access_group" ; then
 985     PA_ACCESS_GROUP=pulse-access
 986 else
 987     PA_ACCESS_GROUP=$with_access_group
 988 fi
 989 AC_SUBST(PA_ACCESS_GROUP)
 990 AC_DEFINE_UNQUOTED(PA_ACCESS_GROUP,"$PA_ACCESS_GROUP", [Access group])
 991
 992 AC_ARG_WITH(peruser_esound, AS_HELP_STRING([--with-peruser-esound-socket], [Use per-user esound socket directory, like /tmp/.esd-UID/socket.]))
 993
 994 if test "x$with_peruser_esound" = "xyes"; then
 995    AC_DEFINE([USE_PERUSER_ESOUND_SOCKET], [1], [Define this if you want per-user esound socket directories])
 996 fi
 997
 998 #### PulseAudio system runtime dir ####
 999 PA_SYSTEM_RUNTIME_PATH="${localstatedir}/run/pulse"
1000 AC_SUBST(PA_SYSTEM_RUNTIME_PATH)
1001
1002 ###################################
1003 #            Output               #
1004 ###################################
1005
1006 AC_ARG_ENABLE(
1007         [static-bins],
1008         AC_HELP_STRING([--enable-static-bins],[Statically link executables.]),
1009         [STATIC_BINS=1], [STATIC_BINS=0])
1010 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
1011
1012 AC_ARG_WITH(
1013         [preopen-mods],
1014         AC_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
1015         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
1016 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
1017 if test "x$PREOPEN_MODS" != "xall" ; then
1018     tmpLIBS=""
1019     for mod in $PREOPEN_MODS; do
1020         tmpLIBS="$tmpLIBS module-$mod.la"
1021     done
1022     PREOPEN_MODS="$tmpLIBS"
1023     AC_SUBST(PREOPEN_MODS)
1024 fi
1025
1026 AC_ARG_WITH(
1027         [module-dir],
1028         AC_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINOR}/modules/]),
1029         [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINOR}/modules/"])
1030
1031 AC_SUBST(modlibexecdir)
1032
1033 AC_ARG_ENABLE(
1034         [force-preopen],
1035         AC_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]),
1036         [FORCE_PREOPEN=1], [FORCE_PREOPEN=0])
1037 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "x1"])
1038
1039 AC_CONFIG_FILES([
1040 Makefile
1041 src/Makefile
1042 man/Makefile
1043 libpulse.pc
1044 libpulse-simple.pc
1045 libpulse-browse.pc
1046 libpulse-mainloop-glib.pc
1047 doxygen/Makefile
1048 doxygen/doxygen.conf
1049 src/pulse/version.h
1050 ])
1051 AC_OUTPUT
1052
1053 # ==========================================================================
1054 ENABLE_X11=no
1055 if test "x$HAVE_X11" = "x1" ; then
1056    ENABLE_X11=yes
1057 fi
1058
1059 ENABLE_OSS=no
1060 if test "x$HAVE_OSS" = "x1" ; then
1061    ENABLE_OSS=yes
1062 fi
1063
1064 ENABLE_ALSA=no
1065 if test "x$HAVE_ALSA" = "x1" ; then
1066    ENABLE_ALSA=yes
1067 fi
1068
1069 ENABLE_SOLARIS=no
1070 if test "x$HAVE_SOLARIS" = "x1" ; then
1071    ENABLE_SOLARIS=yes
1072 fi
1073
1074 ENABLE_GLIB20=no
1075 if test "x$HAVE_GLIB20" = "x1" ; then
1076    ENABLE_GLIB20=yes
1077 fi
1078
1079 ENABLE_GCONF=no
1080 if test "x$HAVE_GCONF" = "x1" ; then
1081    ENABLE_GCONF=yes
1082 fi
1083
1084 ENABLE_AVAHI=no
1085 if test "x$HAVE_AVAHI" = "x1" ; then
1086    ENABLE_AVAHI=yes
1087 fi
1088
1089 ENABLE_JACK=no
1090 if test "x$HAVE_JACK" = "x1" ; then
1091    ENABLE_JACK=yes
1092 fi
1093
1094 ENABLE_LIBASYNCNS=no
1095 if test "x$HAVE_LIBASYNCNS" = "x1" ; then
1096    ENABLE_LIBASYNCNS=yes
1097 fi
1098
1099 ENABLE_LIRC=no
1100 if test "x$HAVE_LIRC" = "x1" ; then
1101    ENABLE_LIRC=yes
1102 fi
1103
1104 ENABLE_HAL=no
1105 if test "x$HAVE_HAL" = "x1" ; then
1106    ENABLE_HAL=yes
1107 fi
1108
1109 ENABLE_TCPWRAP=no
1110 if test "x${LIBWRAP_LIBS}" != x ; then
1111    ENABLE_TCPWRAP=yes
1112 fi
1113
1114 ENABLE_LIBSAMPLERATE=no
1115 if test "x${HAVE_LIBSAMPLERATE}" = "x1" ; then
1116    ENABLE_LIBSAMPLERATE=yes
1117 fi
1118
1119 ENABLE_BLUEZ=no
1120 if test "x${HAVE_BLUEZ}" = "x1" ; then
1121    ENABLE_BLUEZ=yes
1122 fi
1123
1124 ENABLE_POLKIT=no
1125 if test "x${HAVE_POLKIT}" = "x1" ; then
1126    ENABLE_POLKIT=yes
1127 fi
1128
1129 echo "
1130  ---{ $PACKAGE_NAME $VERSION }---
1131
1132     prefix:                 ${prefix}
1133     sysconfdir:             ${sysconfdir}
1134     localstatedir:          ${localstatedir}
1135     System Runtime Path:    ${PA_SYSTEM_RUNTIME_PATH}
1136     Compiler:               ${CC}
1137     CFLAGS:                 ${CFLAGS}
1138     Have X11:               ${ENABLE_X11}
1139     Enable OSS:             ${ENABLE_OSS}
1140     Enable Alsa:            ${ENABLE_ALSA}
1141     Enable Solaris:         ${ENABLE_SOLARIS}
1142     Enable GLib 2.0:        ${ENABLE_GLIB20}
1143     Enable GConf:           ${ENABLE_GCONF}
1144     Enable Avahi:           ${ENABLE_AVAHI}
1145     Enable Jack:            ${ENABLE_JACK}
1146     Enable Async DNS:       ${ENABLE_LIBASYNCNS}
1147     Enable LIRC:            ${ENABLE_LIRC}
1148     Enable HAL:             ${ENABLE_HAL}
1149     Enable BlueZ:           ${ENABLE_BLUEZ}
1150     Enable TCP Wrappers:    ${ENABLE_TCPWRAP}
1151     Enable libsamplerate:   ${ENABLE_LIBSAMPLERATE}
1152     Enable PolicyKit:       ${ENABLE_POLKIT}
1153     System User:            ${PA_SYSTEM_USER}
1154     System Group:           ${PA_SYSTEM_GROUP}
1155     Realtime Group:         ${PA_REALTIME_GROUP}
1156     Access Group:           ${PA_ACCESS_GROUP}
1157 "