configure.ac

   1 AC_PREREQ(2.57)
   2
   3 dnl Version not hardcoded here. Fetched later from ares_version.h
   4 AC_INIT([c-ares], [-],
   5   [c-ares mailing list => http://cool.haxx.se/mailman/listinfo/c-ares])
   6
   7 AC_CONFIG_SRCDIR([ares_ipv6.h])
   8 AM_CONFIG_HEADER([config.h])
   9 AM_MAINTAINER_MODE
  10
  11 dnl SED is mandatory for configure process and libtool.
  12 dnl Set it now, allowing it to be changed later.
  13 AC_PATH_PROG([SED], [sed], [not_found],
  14   [$PATH:/usr/bin:/usr/local/bin])
  15 if test -z "$SED" || test "$SED" = "not_found"; then
  16   AC_MSG_ERROR([sed not found in PATH. Cannot continue without sed.])
  17 fi
  18 AC_SUBST([SED])
  19
  20 dnl GREP is mandatory for configure process and libtool.
  21 dnl Set it now, allowing it to be changed later.
  22 AC_PATH_PROG([GREP], [grep], [not_found],
  23   [$PATH:/usr/bin:/usr/local/bin])
  24 if test -z "$GREP" || test "$GREP" = "not_found"; then
  25   AC_MSG_ERROR([grep not found in PATH. Cannot continue without grep.])
  26 fi
  27 AC_SUBST([GREP])
  28
  29 dnl EGREP is mandatory for configure process and libtool.
  30 dnl Set it now, allowing it to be changed later.
  31 if echo a | ($GREP -E '(a|b)') >/dev/null 2>&1; then
  32   AC_MSG_CHECKING([for egrep])
  33   EGREP="$GREP -E"
  34   AC_MSG_RESULT([$EGREP])
  35 else
  36   AC_PATH_PROG([EGREP], [egrep], [not_found],
  37     [$PATH:/usr/bin:/usr/local/bin])
  38 fi
  39 if test -z "$EGREP" || test "$EGREP" = "not_found"; then
  40   AC_MSG_ERROR([egrep not found in PATH. Cannot continue without egrep.])
  41 fi
  42 AC_SUBST([EGREP])
  43
  44 dnl AR is mandatory for configure process and libtool.
  45 dnl This is target dependant, so check it as a tool.
  46 AC_PATH_TOOL([AR], [ar], [not_found],
  47   [$PATH:/usr/bin:/usr/local/bin])
  48 if test -z "$AR" || test "$AR" = "not_found"; then
  49   AC_MSG_ERROR([ar not found in PATH. Cannot continue without ar.])
  50 fi
  51 AC_SUBST([AR])
  52
  53 dnl Fetch c-ares version from ares_version.h
  54 VERSION=`$SED -ne 's/^#define ARES_VERSION_STR "\(.*\)"/\1/p' ${srcdir}/ares_version.h`
  55 AM_INIT_AUTOMAKE([c-ares], [$VERSION])
  56 AC_MSG_CHECKING([c-ares version])
  57 AC_MSG_RESULT([$VERSION])
  58
  59 dnl
  60 dnl Detect the canonical host and target build environment
  61 dnl
  62
  63 AC_CANONICAL_HOST
  64 dnl Get system canonical name
  65 AC_DEFINE_UNQUOTED(OS, "${host}", [cpu-machine-OS])
  66
  67 AC_PROG_CC
  68 AM_PROG_CC_C_O
  69 AC_PROG_INSTALL
  70
  71 dnl This defines _ALL_SOURCE for AIX
  72 CARES_CHECK_AIX_ALL_SOURCE
  73
  74 dnl Our configure and build reentrant settings
  75 CARES_CONFIGURE_REENTRANT
  76
  77 dnl check for how to do large files
  78 AC_SYS_LARGEFILE
  79
  80 case $host_os in
  81   solaris*)
  82     AC_DEFINE(ETC_INET, 1, [if a /etc/inet dir is being used])
  83     ;;
  84 esac
  85
  86 dnl support building of Windows DLLs
  87 AC_LIBTOOL_WIN32_DLL
  88
  89 dnl ************************************************************
  90 dnl Option to switch on debug options. This makes an assumption that
  91 dnl this is built as an 'ares' subdir in the curl source tree. Subject for
  92 dnl improval in the future!
  93 dnl
  94 AC_MSG_CHECKING([whether to enable debug options])
  95 AC_ARG_ENABLE(debug,
  96 AC_HELP_STRING([--enable-debug],[Enable pedantic debug options])
  97 AC_HELP_STRING([--disable-debug],[Disable debug options]),
  98 [ case "$enableval" in
  99   no)
 100        AC_MSG_RESULT(no)
 101        ;;
 102   *)   AC_MSG_RESULT(yes)
 103
 104     dnl when doing the debug stuff, use static library only
 105     AC_DISABLE_SHARED
 106
 107     debugbuild="yes"
 108
 109     dnl the entire --enable-debug is a hack that lives and runs on top of
 110     dnl libcurl stuff so this BUILDING_LIBCURL is not THAT much uglier
 111     AC_DEFINE(BUILDING_LIBCURL, 1, [when building as static part of libcurl])
 112
 113     CPPFLAGS="$CPPFLAGS -DCURLDEBUG -I$srcdir/../include"
 114     CFLAGS="$CFLAGS -g"
 115
 116     dnl set compiler "debug" options to become more picky, and remove
 117     dnl optimize options from CFLAGS
 118     CURL_CC_DEBUG_OPTS
 119
 120        ;;
 121   esac ],
 122        AC_MSG_RESULT(no)
 123 )
 124 AM_CONDITIONAL(DEBUGBUILD, test x$debugbuild = xyes)
 125 AM_CONDITIONAL(CURLDEBUG, test x$debugbuild = xyes)
 126
 127 dnl skip libtool C++ and Fortran compiler checks
 128 m4_ifdef([AC_PROG_CXX], [m4_undefine([AC_PROG_CXX])])
 129 m4_defun([AC_PROG_CXX],[])
 130 m4_ifdef([AC_PROG_CXXCPP], [m4_undefine([AC_PROG_CXXCPP])])
 131 m4_defun([AC_PROG_CXXCPP],[true])
 132 m4_ifdef([AC_PROG_F77], [m4_undefine([AC_PROG_F77])])
 133 m4_defun([AC_PROG_F77],[])
 134
 135 dnl skip libtool C++ and Fortran linker checks
 136 m4_ifdef([AC_LIBTOOL_CXX], [m4_undefine([AC_LIBTOOL_CXX])])
 137 m4_defun([AC_LIBTOOL_CXX],[])
 138 m4_ifdef([AC_LIBTOOL_CXXCPP], [m4_undefine([AC_LIBTOOL_CXXCPP])])
 139 m4_defun([AC_LIBTOOL_CXXCPP],[true])
 140 m4_ifdef([AC_LIBTOOL_F77], [m4_undefine([AC_LIBTOOL_F77])])
 141 m4_defun([AC_LIBTOOL_F77],[])
 142
 143 dnl force libtool to build static libraries with PIC on AMD64-linux
 144 AC_MSG_CHECKING([if arch-OS host is AMD64-linux (to build static libraries with PIC)])
 145 case $host in
 146   x86_64*linux*)
 147     AC_MSG_RESULT([yes])
 148     with_pic=yes
 149     ;;
 150   *)
 151     AC_MSG_RESULT([no])
 152     ;;
 153 esac
 154
 155 dnl libtool setup
 156 AC_PROG_LIBTOOL
 157
 158 AC_MSG_CHECKING([if we need -no-undefined])
 159 case $host in
 160   *-*-cygwin* | *-*-mingw* | *-*-pw32* | *-*-cegcc*)
 161     need_no_undefined=yes
 162     ;;
 163   *)
 164     need_no_undefined=no
 165     ;;
 166 esac
 167 AC_MSG_RESULT($need_no_undefined)
 168 AM_CONDITIONAL(NO_UNDEFINED, test x$need_no_undefined = xyes)
 169
 170 dnl **********************************************************************
 171 dnl platform/compiler/architecture specific checks/flags
 172 dnl **********************************************************************
 173
 174 case $host in
 175   #
 176   x86_64*linux*)
 177     #
 178     dnl find out if icc is being used
 179     if test "z$ICC" = "z"; then
 180       CURL_DETECT_ICC
 181     fi
 182     #
 183     if test "$ICC" = "yes"; then
 184       dnl figure out icc version
 185       AC_MSG_CHECKING([icc version])
 186       iccver=`$CC -dumpversion`
 187       iccnhi=`echo $iccver | cut -d . -f1`
 188       iccnlo=`echo $iccver | cut -d . -f2`
 189       iccnum=`(expr $iccnhi "*" 100 + $iccnlo) 2>/dev/null`
 190       AC_MSG_RESULT($iccver)
 191       #
 192       if test "$iccnum" -ge "900" && test "$iccnum" -lt "1000"; then
 193         dnl icc 9.X specific
 194         CFLAGS="$CFLAGS -i-dynamic"
 195       fi
 196       #
 197       if test "$iccnum" -ge "1000"; then
 198         dnl icc 10.X or later
 199         CFLAGS="$CFLAGS -shared-intel"
 200       fi
 201       #
 202     fi
 203     ;;
 204   #
 205 esac
 206
 207 AC_MSG_CHECKING([whether we are using the IBM C compiler])
 208 CURL_CHECK_DEF([__IBMC__], [], [silent])
 209 if test "$curl_cv_have_def___IBMC__" = "yes"; then
 210   AC_MSG_RESULT([yes])
 211   dnl Ensure that compiler optimizations are always thread-safe.
 212   CFLAGS="$CFLAGS -qthreaded"
 213   dnl Disable type based strict aliasing optimizations, using worst
 214   dnl case aliasing assumptions when compiling. Type based aliasing
 215   dnl would restrict the lvalues that could be safely used to access
 216   dnl a data object.
 217   CFLAGS="$CFLAGS -qnoansialias"
 218   dnl Force compiler to stop after the compilation phase, without
 219   dnl generating an object code file when compilation has errors.
 220   CFLAGS="$CFLAGS -qhalt=e"
 221 else
 222   AC_MSG_RESULT([no])
 223 fi
 224
 225 AC_MSG_CHECKING([whether we are using the Intel C compiler])
 226 CURL_CHECK_DEF([__INTEL_COMPILER], [], [silent])
 227 if test "$curl_cv_have_def___INTEL_COMPILER" = "yes"; then
 228   AC_MSG_RESULT([yes])
 229   dnl Select strict ANSI C conformance
 230   CPPFLAGS="$CPPFLAGS -strict-ansi"
 231   dnl Select ANSI C dialect
 232   CPPFLAGS="$CPPFLAGS -std=c89 -D__STRICT_ANSI__"
 233   dnl Change some warnings into errors
 234   dnl #140: too many arguments in function call
 235   dnl #147: declaration is incompatible with 'previous one'
 236   dnl #165: too few arguments in function call
 237   dnl #266: function declared implicitly
 238   CPPFLAGS="$CPPFLAGS -we 140,147,165,266"
 239   dnl Disable use of ANSI C aliasing rules in optimizations
 240   CFLAGS="$CFLAGS -no-ansi-alias"
 241 else
 242   AC_MSG_RESULT([no])
 243 fi
 244
 245 AC_MSG_CHECKING([whether we are using the DEC/Compaq C compiler])
 246 CURL_CHECK_DEF([__DECC], [], [silent])
 247 CURL_CHECK_DEF([__DECC_VER], [], [silent])
 248 if test "$curl_cv_have_def___DECC" = "yes" &&
 249   test "$curl_cv_have_def___DECC_VER" = "yes"; then
 250   AC_MSG_RESULT([yes])
 251   dnl Select strict ANSI C compiler mode
 252   CFLAGS="$CFLAGS -std1"
 253   dnl Turn off optimizer ANSI C aliasing rules
 254   CFLAGS="$CFLAGS -noansi_alias"
 255   dnl Select a higher warning level than default level2
 256   CFLAGS="$CFLAGS -msg_enable level3"
 257   dnl Generate warnings for missing function prototypes
 258   CFLAGS="$CFLAGS -warnprotos"
 259   dnl Change some warnings into fatal errors
 260   CFLAGS="$CFLAGS -msg_fatal toofewargs,toomanyargs"
 261 else
 262   AC_MSG_RESULT([no])
 263 fi
 264
 265 CURL_CHECK_COMPILER_HALT_ON_ERROR
 266 CURL_CHECK_COMPILER_ARRAY_SIZE_NEGATIVE
 267
 268 dnl **********************************************************************
 269 dnl Compilation based checks should not be done before this point.
 270 dnl **********************************************************************
 271
 272 dnl **********************************************************************
 273 dnl Make sure that our checks for headers windows.h winsock.h winsock2.h
 274 dnl and ws2tcpip.h take precedence over any other further checks which
 275 dnl could be done later using AC_CHECK_HEADER or AC_CHECK_HEADERS for
 276 dnl this specific header files. And do them before its results are used.
 277 dnl **********************************************************************
 278
 279 CURL_CHECK_HEADER_WINDOWS
 280 CURL_CHECK_NATIVE_WINDOWS
 281 case X-"$ac_cv_native_windows" in
 282   X-yes)
 283     CURL_CHECK_HEADER_WINSOCK
 284     CURL_CHECK_HEADER_WINSOCK2
 285     CURL_CHECK_HEADER_WS2TCPIP
 286     ;;
 287   *)
 288     ac_cv_header_winsock_h="no"
 289     ac_cv_header_winsock2_h="no"
 290     ac_cv_header_ws2tcpip_h="no"
 291     ;;
 292 esac
 293
 294 dnl **********************************************************************
 295 dnl Checks for libraries.
 296 dnl **********************************************************************
 297
 298 dnl gethostbyname without lib or in the nsl lib?
 299 AC_CHECK_FUNC(gethostbyname,
 300               [HAVE_GETHOSTBYNAME="1"
 301               ],
 302               [ AC_CHECK_LIB(nsl, gethostbyname,
 303                              [HAVE_GETHOSTBYNAME="1"
 304                              LIBS="$LIBS -lnsl"
 305                              ])
 306               ])
 307
 308 if test "$HAVE_GETHOSTBYNAME" != "1"
 309 then
 310   dnl gethostbyname in the socket lib?
 311   AC_CHECK_LIB(socket, gethostbyname,
 312                [HAVE_GETHOSTBYNAME="1"
 313                LIBS="$LIBS -lsocket"
 314                ])
 315 fi
 316
 317 dnl At least one system has been identified to require BOTH nsl and socket
 318 dnl libs at the same time to link properly.
 319 if test "$HAVE_GETHOSTBYNAME" != "1"
 320 then
 321   AC_MSG_CHECKING([for gethostbyname with both nsl and socket libs])
 322   my_ac_save_LIBS=$LIBS
 323   LIBS="-lnsl -lsocket $LIBS"
 324   AC_LINK_IFELSE([
 325     AC_LANG_PROGRAM([[
 326     ]],[[
 327       gethostbyname();
 328     ]])
 329   ],[
 330     AC_MSG_RESULT([yes])
 331     HAVE_GETHOSTBYNAME="1"
 332   ],[
 333     AC_MSG_RESULT([no])
 334     LIBS=$my_ac_save_LIBS
 335   ])
 336 fi
 337
 338 if test "$HAVE_GETHOSTBYNAME" != "1"
 339 then
 340   dnl This is for winsock systems
 341   if test "$ac_cv_header_windows_h" = "yes"; then
 342     if test "$ac_cv_header_winsock_h" = "yes"; then
 343       case $host in
 344         *-*-mingw32ce*)
 345           winsock_LIB="-lwinsock"
 346           ;;
 347         *)
 348           winsock_LIB="-lwsock32"
 349           ;;
 350       esac
 351     fi
 352     if test "$ac_cv_header_winsock2_h" = "yes"; then
 353       winsock_LIB="-lws2_32"
 354     fi
 355     if test ! -z "$winsock_LIB"; then
 356       my_ac_save_LIBS=$LIBS
 357       LIBS="$winsock_LIB $LIBS"
 358       AC_MSG_CHECKING([for gethostbyname in $winsock_LIB])
 359       AC_LINK_IFELSE([
 360         AC_LANG_PROGRAM([[
 361 #ifdef HAVE_WINDOWS_H
 362 #ifndef WIN32_LEAN_AND_MEAN
 363 #define WIN32_LEAN_AND_MEAN
 364 #endif
 365 #include <windows.h>
 366 #ifdef HAVE_WINSOCK2_H
 367 #include <winsock2.h>
 368 #else
 369 #ifdef HAVE_WINSOCK_H
 370 #include <winsock.h>
 371 #endif
 372 #endif
 373 #endif
 374         ]],[[
 375           gethostbyname("www.dummysite.com");
 376         ]])
 377       ],[
 378         AC_MSG_RESULT([yes])
 379         HAVE_GETHOSTBYNAME="1"
 380       ],[
 381         AC_MSG_RESULT([no])
 382         winsock_LIB=""
 383         LIBS=$my_ac_save_LIBS
 384       ])
 385     fi
 386   fi
 387 fi
 388
 389 if test "$HAVE_GETHOSTBYNAME" != "1"
 390 then
 391   dnl This is for Minix 3.1
 392   AC_MSG_CHECKING([for gethostbyname for Minix 3])
 393   AC_LINK_IFELSE([
 394     AC_LANG_PROGRAM([[
 395 /* Older Minix versions may need <net/gen/netdb.h> here instead */
 396 #include <netdb.h>
 397     ]],[[
 398       gethostbyname("www.dummysite.com");
 399     ]])
 400   ],[
 401     AC_MSG_RESULT([yes])
 402     HAVE_GETHOSTBYNAME="1"
 403   ],[
 404     AC_MSG_RESULT([no])
 405   ])
 406 fi
 407
 408 if test "$HAVE_GETHOSTBYNAME" != "1"
 409 then
 410   dnl This is for eCos with a stubbed DNS implementation
 411   AC_MSG_CHECKING([for gethostbyname for eCos])
 412   AC_LINK_IFELSE([
 413     AC_LANG_PROGRAM([[
 414 #include <stdio.h>
 415 #include <netdb.h>
 416     ]],[[
 417       gethostbyname("www.dummysite.com");
 418     ]])
 419   ],[
 420     AC_MSG_RESULT([yes])
 421     HAVE_GETHOSTBYNAME="1"
 422   ],[
 423     AC_MSG_RESULT([no])
 424   ])
 425 fi
 426
 427 if test "$HAVE_GETHOSTBYNAME" != "1"
 428 then
 429   dnl gethostbyname in the net lib - for BeOS
 430   AC_CHECK_LIB(net, gethostbyname,
 431                [HAVE_GETHOSTBYNAME="1"
 432                LIBS="$LIBS -lnet"
 433                ])
 434 fi
 435
 436
 437 if test "$HAVE_GETHOSTBYNAME" = "1"; then
 438   AC_DEFINE(HAVE_GETHOSTBYNAME, 1, [If you have gethostbyname])
 439 else
 440   AC_MSG_ERROR([couldn't find libraries for gethostbyname()])
 441 fi
 442
 443 dnl resolve lib?
 444 AC_CHECK_FUNC(strcasecmp, , [ AC_CHECK_LIB(resolve, strcasecmp) ])
 445
 446 if test "$ac_cv_lib_resolve_strcasecmp" = "$ac_cv_func_strcasecmp"; then
 447   AC_CHECK_LIB(resolve, strcasecmp,
 448               [LIBS="-lresolve $LIBS"],
 449                ,
 450                -lnsl)
 451 fi
 452
 453 dnl socket lib?
 454 AC_CHECK_FUNC(connect, , [ AC_CHECK_LIB(socket, connect) ])
 455
 456 dnl **********************************************************************
 457 dnl In case that function clock_gettime with monotonic timer is available,
 458 dnl check for additional required libraries.
 459 dnl **********************************************************************
 460 CURL_CHECK_LIBS_CLOCK_GETTIME_MONOTONIC
 461
 462 AC_MSG_CHECKING([whether to use libgcc])
 463 AC_ARG_ENABLE(libgcc,
 464 AC_HELP_STRING([--enable-libgcc],[use libgcc when linking]),
 465 [ case "$enableval" in
 466   yes)
 467         LIBS="$LIBS -lgcc"
 468        AC_MSG_RESULT(yes)
 469        ;;
 470   *)   AC_MSG_RESULT(no)
 471        ;;
 472   esac ],
 473        AC_MSG_RESULT(no)
 474 )
 475
 476
 477 dnl Default is to try the thread-safe versions of a few functions
 478 OPT_THREAD=on
 479
 480 dnl detect AIX 4.3 or later
 481 AC_MSG_CHECKING([AIX 4.3 or later])
 482 AC_PREPROC_IFELSE([
 483 #if defined(_AIX) && defined(_AIX43)
 484 printf("just fine");
 485 #else
 486 #error "this is not AIX 4.3 or later"
 487 #endif
 488 ],
 489  [ AC_MSG_RESULT([yes])
 490    RECENTAIX=yes
 491    OPT_THREAD=off ],
 492  [ AC_MSG_RESULT([no]) ]
 493 )
 494
 495 AC_ARG_ENABLE(thread,dnl
 496 AC_HELP_STRING([--disable-thread],[don't look for thread-safe functions])
 497 AC_HELP_STRING([--enable-thread],[look for thread-safe functions]),
 498 [ case "$enableval" in
 499   no)
 500     OPT_THREAD=off
 501     AC_MSG_WARN(c-ares will not get built using thread-safe functions)
 502     ;;
 503   *)
 504     ;;
 505   esac
 506 ]
 507 )
 508
 509 if test X"$OPT_THREAD" = Xoff
 510 then
 511   AC_DEFINE(DISABLED_THREADSAFE, 1,
 512     [Set to explicitly specify we don't want to use thread-safe functions])
 513 fi
 514
 515 dnl for recent AIX versions, we skip all the thread-safe checks above since
 516 dnl they claim a thread-safe libc using the standard API. But there are
 517 dnl some functions still not thread-safe. Check for these!
 518
 519 dnl Let's hope this split URL remains working:
 520 dnl http://publibn.boulder.ibm.com/doc_link/en_US/a_doc_lib/aixprggd/ \
 521 dnl genprogc/thread_quick_ref.htm
 522
 523 if test "x$RECENTAIX" = "xyes"; then
 524
 525   AC_DEFINE(_THREAD_SAFE, 1, [define this if you need it to compile thread-safe code])
 526
 527 fi
 528
 529
 530 dnl **********************************************************************
 531 dnl Back to "normal" configuring
 532 dnl **********************************************************************
 533
 534 dnl Checks for header files.
 535 AC_HEADER_STDC
 536
 537 CURL_CHECK_HEADER_MALLOC
 538
 539 dnl check for a few basic system headers we need
 540 AC_CHECK_HEADERS(
 541        sys/types.h \
 542        sys/time.h \
 543        sys/select.h \
 544        sys/socket.h \
 545        sys/ioctl.h \
 546        sys/param.h \
 547        netdb.h \
 548        netinet/in.h \
 549        netinet/tcp.h \
 550        net/if.h \
 551        errno.h \
 552        strings.h \
 553        stdbool.h \
 554        time.h \
 555        arpa/nameser.h \
 556        arpa/nameser_compat.h \
 557        arpa/inet.h,
 558 dnl to do if not found
 559 [],
 560 dnl to do if found
 561 [],
 562 dnl default includes
 563 [
 564 #ifdef HAVE_SYS_TYPES_H
 565 #include <sys/types.h>
 566 #endif
 567 #ifdef HAVE_SYS_TIME_H
 568 #include <sys/time.h>
 569 #endif
 570 dnl We do this default-include simply to make sure that the nameser_compat.h
 571 dnl header *REALLY* can be include after the new nameser.h. It seems AIX 5.1
 572 dnl (and others?) is not designed to allow this.
 573 #ifdef HAVE_ARPA_NAMESER_H
 574 #include <arpa/nameser.h>
 575 #endif
 576
 577 dnl *Sigh* these are needed in order for net/if.h to get properly detected.
 578 #ifdef HAVE_SYS_SOCKET_H
 579 #include <sys/socket.h>
 580 #endif
 581 #ifdef HAVE_NETINET_IN_H
 582 #include <netinet/in.h>
 583 #endif
 584 ]
 585 )
 586
 587 dnl Checks for typedefs, structures, and compiler characteristics.
 588 AC_C_CONST
 589 AC_TYPE_SIZE_T
 590 AC_HEADER_TIME
 591 CURL_CHECK_STRUCT_TIMEVAL
 592
 593 AC_CHECK_SIZEOF(size_t)
 594 AC_CHECK_SIZEOF(long)
 595 AC_CHECK_SIZEOF(time_t)
 596
 597 AC_CHECK_TYPE(long long,
 598    [AC_DEFINE(HAVE_LONGLONG, 1,
 599      [Define to 1 if the compiler supports the 'long long' data type.])]
 600    longlong="yes"
 601 )
 602
 603 if test "xyes" = "x$longlong"; then
 604   AC_MSG_CHECKING([if numberLL works])
 605   AC_COMPILE_IFELSE([long long val = 1000LL;],
 606    [AC_DEFINE(HAVE_LL, 1, [if your compiler supports LL])]
 607    AC_MSG_RESULT(yes),
 608    AC_MSG_RESULT(no)
 609   )
 610 fi
 611
 612
 613 # check for ssize_t
 614 AC_CHECK_TYPE(ssize_t, ,
 615    AC_DEFINE(ssize_t, int, [the signed version of size_t]))
 616
 617 # check for bool type
 618 AC_CHECK_TYPE([bool],[
 619   AC_DEFINE(HAVE_BOOL_T, 1,
 620     [Define to 1 if bool is an available type.])
 621 ], ,[
 622 #ifdef HAVE_SYS_TYPES_H
 623 #include <sys/types.h>
 624 #endif
 625 #ifdef HAVE_STDBOOL_H
 626 #include <stdbool.h>
 627 #endif
 628 ])
 629
 630 # Check for socklen_t or equivalent
 631 CURL_CHECK_TYPE_SOCKLEN_T
 632
 633 TYPE_IN_ADDR_T
 634
 635 TYPE_SOCKADDR_STORAGE
 636
 637 TYPE_SIG_ATOMIC_T
 638
 639 AC_TYPE_SIGNAL
 640
 641 CURL_CHECK_FUNC_RECV
 642 CURL_CHECK_FUNC_RECVFROM
 643 CURL_CHECK_FUNC_SEND
 644 CURL_CHECK_MSG_NOSIGNAL
 645
 646 dnl check for AF_INET6
 647 CARES_CHECK_CONSTANT(
 648   [
 649 #undef inline
 650 #ifdef HAVE_WINDOWS_H
 651 #ifndef WIN32_LEAN_AND_MEAN
 652 #define WIN32_LEAN_AND_MEAN
 653 #endif
 654 #include <windows.h>
 655 #ifdef HAVE_WINSOCK2_H
 656 #include <winsock2.h>
 657 #endif
 658 #else
 659 #ifdef HAVE_SYS_TYPES_H
 660 #include <sys/types.h>
 661 #endif
 662 #ifdef HAVE_SYS_SOCKET_H
 663 #include <sys/socket.h>
 664 #endif
 665 #endif
 666   ], [PF_INET6],
 667      AC_DEFINE_UNQUOTED(HAVE_PF_INET6,1,[Define to 1 if you have PF_INET6.])
 668 )
 669
 670 dnl check for PF_INET6
 671 CARES_CHECK_CONSTANT(
 672   [
 673 #undef inline
 674 #ifdef HAVE_WINDOWS_H
 675 #ifndef WIN32_LEAN_AND_MEAN
 676 #define WIN32_LEAN_AND_MEAN
 677 #endif
 678 #include <windows.h>
 679 #ifdef HAVE_WINSOCK2_H
 680 #include <winsock2.h>
 681 #endif
 682 #else
 683 #ifdef HAVE_SYS_TYPES_H
 684 #include <sys/types.h>
 685 #endif
 686 #ifdef HAVE_SYS_SOCKET_H
 687 #include <sys/socket.h>
 688 #endif
 689 #endif
 690   ], [AF_INET6],
 691      AC_DEFINE_UNQUOTED(HAVE_AF_INET6,1,[Define to 1 if you have AF_INET6.])
 692 )
 693
 694
 695 dnl check for the in6_addr structure
 696 CARES_CHECK_STRUCT(
 697   [
 698 #undef inline
 699 #ifdef HAVE_WINDOWS_H
 700 #ifndef WIN32_LEAN_AND_MEAN
 701 #define WIN32_LEAN_AND_MEAN
 702 #endif
 703 #include <windows.h>
 704 #ifdef HAVE_WINSOCK2_H
 705 #include <winsock2.h>
 706 #ifdef HAVE_WS2TCPIP_H
 707 #include <ws2tcpip.h>
 708 #endif
 709 #endif
 710 #else
 711 #ifdef HAVE_SYS_TYPES_H
 712 #include <sys/types.h>
 713 #endif
 714 #ifdef HAVE_NETINET_IN_H
 715 #include <netinet/in.h>
 716 #endif
 717 #endif
 718   ], [in6_addr],
 719      AC_DEFINE_UNQUOTED(HAVE_STRUCT_IN6_ADDR,1,[Define to 1 if you have struct in6_addr.])
 720 )
 721
 722 dnl check for the sockaddr_in6 structure
 723 CARES_CHECK_STRUCT(
 724   [
 725 #undef inline
 726 #ifdef HAVE_WINDOWS_H
 727 #ifndef WIN32_LEAN_AND_MEAN
 728 #define WIN32_LEAN_AND_MEAN
 729 #endif
 730 #include <windows.h>
 731 #ifdef HAVE_WINSOCK2_H
 732 #include <winsock2.h>
 733 #ifdef HAVE_WS2TCPIP_H
 734 #include <ws2tcpip.h>
 735 #endif
 736 #endif
 737 #else
 738 #ifdef HAVE_SYS_TYPES_H
 739 #include <sys/types.h>
 740 #endif
 741 #ifdef HAVE_NETINET_IN_H
 742 #include <netinet/in.h>
 743 #endif
 744 #endif
 745   ], [sockaddr_in6],
 746      AC_DEFINE_UNQUOTED(HAVE_STRUCT_SOCKADDR_IN6,1,
 747        [Define to 1 if you have struct sockaddr_in6.]) ac_have_sockaddr_in6=yes
 748 )
 749
 750 AC_CHECK_MEMBER(struct sockaddr_in6.sin6_scope_id,
 751     AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_IN6_SIN6_SCOPE_ID,1,
 752       [Define to 1 if your struct sockaddr_in6 has sin6_scope_id.])
 753    , ,
 754   [
 755 #undef inline
 756 #ifdef HAVE_WINDOWS_H
 757 #ifndef WIN32_LEAN_AND_MEAN
 758 #define WIN32_LEAN_AND_MEAN
 759 #endif
 760 #include <windows.h>
 761 #ifdef HAVE_WINSOCK2_H
 762 #include <winsock2.h>
 763 #ifdef HAVE_WS2TCPIP_H
 764 #include <ws2tcpip.h>
 765 #endif
 766 #endif
 767 #else
 768 #ifdef HAVE_SYS_TYPES_H
 769 #include <sys/types.h>
 770 #endif
 771 #ifdef HAVE_NETINET_IN_H
 772 #include <netinet/in.h>
 773 #endif
 774 #endif
 775   ])
 776
 777 dnl check for the addrinfo structure
 778 AC_CHECK_MEMBER(struct addrinfo.ai_flags,
 779      AC_DEFINE_UNQUOTED(HAVE_STRUCT_ADDRINFO,1,
 780        [Define to 1 if you have struct addrinfo.]),,
 781   [
 782 #undef inline
 783 #ifdef HAVE_WINDOWS_H
 784 #ifndef WIN32_LEAN_AND_MEAN
 785 #define WIN32_LEAN_AND_MEAN
 786 #endif
 787 #include <windows.h>
 788 #ifdef HAVE_WINSOCK2_H
 789 #include <winsock2.h>
 790 #ifdef HAVE_WS2TCPIP_H
 791 #include <ws2tcpip.h>
 792 #endif
 793 #endif
 794 #else
 795 #ifdef HAVE_SYS_TYPES_H
 796 #include <sys/types.h>
 797 #endif
 798 #ifdef HAVE_NETINET_IN_H
 799 #include <netinet/in.h>
 800 #endif
 801 #ifdef HAVE_SYS_SOCKET_H
 802 #include <sys/socket.h>
 803 #endif
 804 #ifdef HAVE_NETDB_H
 805 #include <netdb.h>
 806 #endif
 807 #endif
 808   ]
 809 )
 810
 811
 812 AC_CHECK_FUNCS([bitncmp \
 813   gettimeofday \
 814   if_indextoname
 815 ],[
 816 ],[
 817   func="$ac_func"
 818   AC_MSG_CHECKING([deeper for $func])
 819   AC_LINK_IFELSE([
 820     AC_LANG_PROGRAM([[
 821     ]],[[
 822       $func ();
 823     ]])
 824   ],[
 825     AC_MSG_RESULT([yes])
 826     eval "ac_cv_func_$func=yes"
 827     AC_DEFINE_UNQUOTED([AS_TR_CPP([HAVE_$func])], [1],
 828       [Define to 1 if you have the $func function.])
 829   ],[
 830     AC_MSG_RESULT([but still no])
 831   ])
 832 ])
 833
 834
 835 dnl check for inet_pton
 836 AC_CHECK_FUNCS(inet_pton)
 837 dnl Some systems have it, but not IPv6
 838 if test "$ac_cv_func_inet_pton" = "yes" ; then
 839 AC_MSG_CHECKING(if inet_pton supports IPv6)
 840 AC_TRY_RUN(
 841   [
 842 #ifdef HAVE_SYS_TYPES_H
 843 #include <sys/types.h>
 844 #endif
 845 #ifdef HAVE_SYS_SOCKET_H
 846 #include <sys/socket.h>
 847 #endif
 848 #ifdef HAVE_NETINET_IN_H
 849 #include <netinet/in.h>
 850 #endif
 851 int main()
 852   {
 853     struct in6_addr addr6;
 854     if (inet_pton(AF_INET6, "::1", &addr6) < 1)
 855       exit(1);
 856     else
 857       exit(0);
 858   }
 859   ], [
 860        AC_MSG_RESULT(yes)
 861        AC_DEFINE_UNQUOTED(HAVE_INET_PTON_IPV6,1,[Define to 1 if inet_pton supports IPv6.])
 862      ], AC_MSG_RESULT(no),AC_MSG_RESULT(no))
 863 fi
 864 dnl Check for inet_net_pton
 865 AC_CHECK_FUNCS(inet_net_pton)
 866 dnl Again, some systems have it, but not IPv6
 867 if test "$ac_cv_func_inet_net_pton" = "yes" ; then
 868 AC_MSG_CHECKING(if inet_net_pton supports IPv6)
 869 AC_TRY_RUN(
 870   [
 871 #ifdef HAVE_SYS_TYPES_H
 872 #include <sys/types.h>
 873 #endif
 874 #ifdef HAVE_SYS_SOCKET_H
 875 #include <sys/socket.h>
 876 #endif
 877 #ifdef HAVE_NETINET_IN_H
 878 #include <netinet/in.h>
 879 #endif
 880 int main()
 881   {
 882     struct in6_addr addr6;
 883     if (inet_net_pton(AF_INET6, "::1", &addr6, sizeof(addr6)) < 1)
 884       exit(1);
 885     else
 886       exit(0);
 887   }
 888   ], [
 889        AC_MSG_RESULT(yes)
 890        AC_DEFINE_UNQUOTED(HAVE_INET_NET_PTON_IPV6,1,[Define to 1 if inet_net_pton supports IPv6.])
 891      ], AC_MSG_RESULT(no),AC_MSG_RESULT(no))
 892 fi
 893
 894
 895 dnl Check for inet_ntop
 896 AC_CHECK_FUNCS(inet_ntop)
 897 dnl Again, some systems have it, but not IPv6
 898 if test "$ac_cv_func_inet_ntop" = "yes" ; then
 899 AC_MSG_CHECKING(if inet_ntop supports IPv6)
 900 AC_TRY_RUN(
 901   [
 902 #ifdef HAVE_SYS_TYPES_H
 903 #include <sys/types.h>
 904 #endif
 905 #ifdef HAVE_SYS_SOCKET_H
 906 #include <sys/socket.h>
 907 #endif
 908 #ifdef HAVE_NETINET_IN_H
 909 #include <netinet/in.h>
 910 #endif
 911 #include <errno.h>
 912 int main()
 913   {
 914     struct in6_addr addr6;
 915     char buf[128];
 916     if (inet_ntop(AF_INET6, &addr6, buf, 128) == 0 && errno == EAFNOSUPPORT)
 917       exit(1);
 918     else
 919       exit(0);
 920   }
 921   ], [
 922        AC_MSG_RESULT(yes)
 923        AC_DEFINE_UNQUOTED(HAVE_INET_NTOP_IPV6,1,
 924           [Define to 1 if inet_ntop supports IPv6.])
 925      ], AC_MSG_RESULT(no),AC_MSG_RESULT(no))
 926 fi
 927
 928 AC_CHECK_SIZEOF(struct in6_addr, ,
 929 [
 930 #undef inline
 931 #ifdef HAVE_WINDOWS_H
 932 #ifndef WIN32_LEAN_AND_MEAN
 933 #define WIN32_LEAN_AND_MEAN
 934 #endif
 935 #include <windows.h>
 936 #ifdef HAVE_WINSOCK2_H
 937 #include <winsock2.h>
 938 #ifdef HAVE_WS2TCPIP_H
 939 #include <ws2tcpip.h>
 940 #endif
 941 #endif
 942 #else
 943 #ifdef HAVE_SYS_TYPES_H
 944 #include <sys/types.h>
 945 #endif
 946 #ifdef HAVE_SYS_SOCKET_H
 947 #include <sys/socket.h>
 948 #endif
 949 #ifdef HAVE_NETINET_IN_H
 950 #include <netinet/in.h>
 951 #endif
 952 #endif
 953 ]
 954 )
 955
 956 AC_CHECK_SIZEOF(struct in_addr, ,
 957 [
 958 #undef inline
 959 #ifdef HAVE_WINDOWS_H
 960 #ifndef WIN32_LEAN_AND_MEAN
 961 #define WIN32_LEAN_AND_MEAN
 962 #endif
 963 #include <windows.h>
 964 #ifdef HAVE_WINSOCK2_H
 965 #include <winsock2.h>
 966 #ifdef HAVE_WS2TCPIP_H
 967 #include <ws2tcpip.h>
 968 #endif
 969 #endif
 970 #else
 971 #ifdef HAVE_SYS_TYPES_H
 972 #include <sys/types.h>
 973 #endif
 974 #ifdef HAVE_SYS_SOCKET_H
 975 #include <sys/socket.h>
 976 #endif
 977 #ifdef HAVE_NETINET_IN_H
 978 #include <netinet/in.h>
 979 #endif
 980 #endif
 981 ]
 982 )
 983
 984
 985 dnl Check if the getnameinfo function is available
 986 dnl and get the types of five of its arguments.
 987 CURL_CHECK_FUNC_GETNAMEINFO
 988
 989
 990 dnl God bless non-standardized functions! We need to see which getservbyport_r
 991 dnl variant is available
 992 CARES_CHECK_GETSERVBYPORT_R
 993
 994 CURL_CHECK_NONBLOCKING_SOCKET
 995
 996 AC_C_BIGENDIAN(
 997     [AC_DEFINE(ARES_BIG_ENDIAN, 1,
 998       [define this if ares is built for a big endian system])],
 999     ,
1000     [AC_MSG_WARN([couldn't figure out endianess, assuming little endian!])]
1001 )
1002
1003 dnl Check for user-specified random device
1004 AC_ARG_WITH(random,
1005 AC_HELP_STRING([--with-random=FILE],
1006                [read randomness from FILE (default=/dev/urandom)]),
1007     [ RANDOM_FILE="$withval" ],
1008     [
1009         dnl Check for random device.  If we're cross compiling, we can't
1010         dnl check, and it's better to assume it doesn't exist than it is
1011         dnl to fail on AC_CHECK_FILE or later.
1012         if test "$cross_compiling" = "no"; then
1013           AC_CHECK_FILE("/dev/urandom", [ RANDOM_FILE="/dev/urandom"] )
1014         else
1015           AC_MSG_WARN([cannot check for /dev/urandom while cross compiling; assuming none])
1016         fi
1017
1018     ]
1019 )
1020 if test -n "$RANDOM_FILE" && test X"$RANDOM_FILE" != Xno ; then
1021         AC_SUBST(RANDOM_FILE)
1022         AC_DEFINE_UNQUOTED(RANDOM_FILE, "$RANDOM_FILE",
1023         [a suitable file/device to read random data from])
1024 fi
1025
1026 CARES_PRIVATE_LIBS="$LIBS"
1027 AC_SUBST(CARES_PRIVATE_LIBS)
1028
1029 AC_CONFIG_FILES([Makefile libcares.pc])
1030 AC_OUTPUT