configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Configure input file for elfutils.                     -*-autoconf-*-
   3 dnl
   4 dnl Copyright (C) 1996-2016 Red Hat, Inc.
   5 dnl
   6 dnl This file is part of elfutils.
   7 dnl
   8 dnl  This file is free software; you can redistribute it and/or modify
   9 dnl  it under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 3 of the License, or
  11 dnl  (at your option) any later version.
  12 dnl
  13 dnl  elfutils is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl  GNU General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 AC_INIT([elfutils],[0.166],[https://bugzilla.redhat.com/],[elfutils])
  21
  22 # We want eu- as default program prefix if none was given by the user.
  23 # But if the user explicitly provided --program-prefix="" then pretend
  24 # it wasn't set at all (NONE). We want to test this really early before
  25 # configure has a chance to use the value.
  26
  27 if test "x$program_prefix" = "xNONE"; then
  28   AC_MSG_NOTICE([No --program-prefix given, using "eu-"])
  29   program_prefix="eu-"
  30 elif test "x$program_prefix" = "x"; then
  31   AC_MSG_NOTICE([Using no program-prefix])
  32   program_prefix=NONE
  33 fi
  34
  35 AC_CONFIG_AUX_DIR([config])
  36 AC_CONFIG_FILES([config/Makefile])
  37
  38 AC_COPYRIGHT([Copyright (C) 1996-2016 Red Hat, Inc.])
  39 AC_PREREQ(2.63)                 dnl Minimum Autoconf version required.
  40
  41 dnl We use GNU make extensions; automake 1.10 defaults to -Wportability.
  42 AM_INIT_AUTOMAKE([gnits 1.11 -Wno-portability dist-bzip2 no-dist-gzip parallel-tests])
  43 AM_MAINTAINER_MODE
  44
  45 AM_SILENT_RULES([yes])
  46
  47 AC_CONFIG_SRCDIR([libelf/libelf.h])
  48 AC_CONFIG_FILES([Makefile])
  49 AC_CONFIG_HEADERS([config.h])
  50
  51 AC_CONFIG_MACRO_DIR([m4])
  52 AC_CONFIG_FILES([m4/Makefile])
  53
  54 dnl The RPM spec file.  We substitute a few values in the file.
  55 AC_CONFIG_FILES([elfutils.spec:config/elfutils.spec.in])
  56
  57
  58 AC_CANONICAL_HOST
  59
  60 AC_ARG_ENABLE(deterministic-archives,
  61 [AS_HELP_STRING([--enable-deterministic-archives],
  62                 [ar and ranlib default to -D behavior])], [
  63 if test "${enableval}" = no; then
  64   default_ar_deterministic=false
  65 else
  66   default_ar_deterministic=true
  67 fi], [default_ar_deterministic=false])
  68 AC_DEFINE_UNQUOTED(DEFAULT_AR_DETERMINISTIC, $default_ar_deterministic,
  69                    [Should ar and ranlib use -D behavior by default?])
  70
  71 AC_ARG_ENABLE([thread-safety],
  72 AS_HELP_STRING([--enable-thread-safety],
  73                [enable thread safety of libraries EXPERIMENTAL]),
  74                use_locks=$enableval, use_locks=no)
  75 AM_CONDITIONAL(USE_LOCKS, test "$use_locks" = yes)
  76 AS_IF([test "$use_locks" = yes], [AC_DEFINE(USE_LOCKS)])
  77 AS_IF([test "$use_locks" = yes],
  78       [AC_MSG_WARN([thread-safety is EXPERIMENTAL tests might fail.])])
  79
  80 AH_TEMPLATE([USE_LOCKS], [Defined if libraries should be thread-safe.])
  81
  82 AC_PROG_CC
  83 AC_PROG_RANLIB
  84 AC_PROG_YACC
  85 AM_PROG_LEX
  86 # Only available since automake 1.12
  87 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  88 AC_CHECK_TOOL([READELF], [readelf])
  89 AC_CHECK_TOOL([NM], [nm])
  90
  91 # We use -std=gnu99 but have explicit checks for some language constructs
  92 # and GNU extensions since some compilers claim GNU99 support, but don't
  93 # really support all language extensions. In particular we need
  94 # Mixed Declarations and Code
  95 # https://gcc.gnu.org/onlinedocs/gcc/Mixed-Declarations.html
  96 # Nested Functions
  97 # https://gcc.gnu.org/onlinedocs/gcc/Nested-Functions.html
  98 # Arrays of Variable Length
  99 # https://gcc.gnu.org/onlinedocs/gcc/Variable-Length.html
 100 AC_CACHE_CHECK([for gcc with GNU99 support], ac_cv_c99, [dnl
 101 old_CFLAGS="$CFLAGS"
 102 CFLAGS="$CFLAGS -std=gnu99"
 103 AC_COMPILE_IFELSE([AC_LANG_SOURCE([dnl
 104 int foo (int a)
 105 {
 106   for (int i = 0; i < a; ++i) if (i % 4) break; int s = a; return s;
 107 }
 108
 109 double bar (double a, double b)
 110 {
 111   double square (double z) { return z * z; }
 112   return square (a) + square (b);
 113 }
 114
 115 void baz (int n)
 116 {
 117   struct S { int x[[n]]; };
 118 }])],
 119                   ac_cv_c99=yes, ac_cv_c99=no)
 120 CFLAGS="$old_CFLAGS"])
 121 AS_IF([test "x$ac_cv_c99" != xyes],
 122       AC_MSG_ERROR([gcc with GNU99 support required]))
 123
 124 AC_CACHE_CHECK([for __thread support], ac_cv_tls, [dnl
 125 # Use the same flags that we use for our DSOs, so the test is representative.
 126 # Some old compiler/linker/libc combinations fail some ways and not others.
 127 save_CFLAGS="$CFLAGS"
 128 save_LDFLAGS="$LDFLAGS"
 129 CFLAGS="-fPIC $CFLAGS"
 130 LDFLAGS="-shared -Wl,-z,defs,-z,relro $LDFLAGS"
 131 AC_LINK_IFELSE([dnl
 132 AC_LANG_PROGRAM([[#include <stdlib.h>
 133 #undef __thread
 134 static __thread int a; int foo (int b) { return a + b; }]],
 135                 [[exit (foo (0));]])],
 136                ac_cv_tls=yes, ac_cv_tls=no)
 137 CFLAGS="$save_CFLAGS"
 138 LDFLAGS="$save_LDFLAGS"])
 139 AS_IF([test "x$ac_cv_tls" != xyes],
 140       AC_MSG_ERROR([__thread support required]))
 141
 142 dnl This test must come as early as possible after the compiler configuration
 143 dnl tests, because the choice of the file model can (in principle) affect
 144 dnl whether functions and headers are available, whether they work, etc.
 145 AC_SYS_LARGEFILE
 146
 147 dnl Enable the linker to be build as a native-only linker.  By default it
 148 dnl can handle all architectures but this comes at a cost.  A native
 149 dnl will be slightly faster, small, and has fewer dependencies.
 150 native_ld=no
 151 AC_ARG_ENABLE([generic],
 152 AS_HELP_STRING([--disable-generic], [do not build generic linker]), [dnl
 153 if test "$enable_generic" = no; then
 154   case "$host_cpu" in
 155    i?86)
 156     AC_DEFINE(NATIVE_ELF, 32)
 157     native_ld=yes
 158     base_cpu=i386
 159     ;;
 160    *)
 161     AC_MSG_ERROR([no machine-specific linker for this configuration available])
 162     ;;
 163   esac
 164 fi])
 165 AH_TEMPLATE([NATIVE_ELF],
 166 [Define to 32 or 64 if a specific implementation is wanted.])
 167 AM_CONDITIONAL(NATIVE_LD, test "$native_ld" = yes)
 168 dnl The automake generated Makefile cannot deal with macros in the name
 169 dnl of files if at any time there is no such file, even if the filename
 170 dnl would not be used.
 171 AS_IF([test -z "$base_cpu"], [base_cpu=none])
 172 AC_SUBST(base_cpu)
 173 dnl Support to work around automake's inflexible dependency generation.
 174 dnl See src/Makefile.am for more information.
 175 AM_CONDITIONAL(NEVER, false)
 176
 177 dnl enable debugging of branch prediction.
 178 AC_ARG_ENABLE([debugpred],
 179 AS_HELP_STRING([--enable-debugpred],[build binaries with support to debug branch prediction]),
 180 [use_debugpred=$enableval], [use_debugpred=no])
 181 case $use_debugpred in
 182  yes) use_debugpred_val=1 ;;
 183  *)   use_debugpred_val=0 ;;
 184 esac
 185 AC_SUBST([DEBUGPRED], $use_debugpred_val)
 186
 187 dnl Enable gprof suport.
 188 AC_ARG_ENABLE([gprof],
 189 AS_HELP_STRING([--enable-gprof],[build binaries with gprof support]), [use_gprof=$enableval], [use_gprof=no])
 190 if test "$use_gprof" = yes; then
 191   CFLAGS="$CFLAGS -pg"
 192   LDFLAGS="$LDFLAGS -pg"
 193 fi
 194 AM_CONDITIONAL(GPROF, test "$use_gprof" = yes)
 195
 196 # Enable gcov suport.
 197 AC_ARG_ENABLE([gcov],
 198 AS_HELP_STRING([--enable-gcov],[build binaries with gcov support]), [use_gcov=$enableval], [use_gcov=no])
 199 if test "$use_gcov" = yes; then
 200   CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 201   LDFLAGS="$LDFLAGS -fprofile-arcs"
 202 fi
 203 AM_CONDITIONAL(GCOV, test "$use_gcov" = yes)
 204
 205 AC_ARG_ENABLE([sanitize-undefined],
 206               AS_HELP_STRING([--enable-sanitize-undefined],
 207                              [Use gcc undefined behaviour sanitizer]),
 208                              [use_undefined=$enableval], [use_undefined=no])
 209 if test "$use_undefined" = yes; then
 210   old_CFLAGS="$CFLAGS"
 211   old_CXXFLAGS="$CXXFLAGS"
 212   # We explicitly use unaligned access when possible (see ALLOW_UNALIGNED)
 213   # We want to fail immediately on first error, don't try to recover.
 214   CFLAGS="$CFLAGS -fsanitize=undefined -fno-sanitize-recover"
 215   CXXFLAGS="$CXXFLAGS -fsanitize=undefined -fno-sanitize-recover"
 216   AC_LINK_IFELSE([AC_LANG_SOURCE([int main (int argc, char **argv) { return 0; }])], use_undefined=yes, use_undefined=no)
 217   AS_IF([test "x$use_undefined" != xyes],
 218         AC_MSG_WARN([gcc undefined behaviour sanitizer not available])
 219         CFLAGS="$old_CFLAGS" CXXFLAGS="$old_CXXFLAGS")
 220 fi
 221 case $use_undefined in
 222  yes) check_undefined_val=1 ;;
 223  *)   check_undefined_val=0 ;;
 224 esac
 225 AC_DEFINE_UNQUOTED(CHECK_UNDEFINED, $check_undefined_val,
 226                    [Building with -fsanitize=undefined or not])
 227
 228 AC_ARG_ENABLE([valgrind],
 229 AS_HELP_STRING([--enable-valgrind],[run all tests under valgrind]),
 230 [use_valgrind=$enableval], [use_valgrind=no])
 231 if test "$use_valgrind" = yes; then
 232   AC_CHECK_PROG(HAVE_VALGRIND, valgrind, yes, no)
 233   if test "$HAVE_VALGRIND" = "no"; then
 234     AC_MSG_ERROR([valgrind not found])
 235   fi
 236 fi
 237 AM_CONDITIONAL(USE_VALGRIND, test "$use_valgrind" = yes)
 238
 239 AM_CONDITIONAL(BUILD_STATIC, [dnl
 240 test "$use_gprof" = yes -o "$use_gcov" = yes])
 241
 242 AC_ARG_ENABLE([tests-rpath],
 243 AS_HELP_STRING([--enable-tests-rpath],[build $ORIGIN-using rpath into tests]),
 244                [tests_use_rpath=$enableval], [tests_use_rpath=no])
 245 AM_CONDITIONAL(TESTS_RPATH, test "$tests_use_rpath" = yes)
 246
 247 LIBEBL_SUBDIR="$PACKAGE"
 248 AC_ARG_ENABLE([libebl-subdir],
 249 AS_HELP_STRING([--enable-libebl-subdir=DIR],
 250 [install libebl_CPU modules in $(libdir)/DIR]), [dnl
 251 LIBEBL_SUBDIR="$enable_libebl_subdir"])
 252 AC_SUBST([LIBEBL_SUBDIR])
 253 AC_DEFINE_UNQUOTED(LIBEBL_SUBDIR, "$LIBEBL_SUBDIR")
 254 AH_TEMPLATE([LIBEBL_SUBDIR], [$libdir subdirectory containing libebl modules.])
 255
 256 dnl zlib is mandatory.
 257 save_LIBS="$LIBS"
 258 LIBS=
 259 eu_ZIPLIB(zlib,ZLIB,z,gzdirect,gzip)
 260 AS_IF([test "x$with_zlib" = xno], [AC_MSG_ERROR([zlib not found but is required])])
 261 LIBS="$save_LIBS"
 262
 263 dnl Test for bzlib and xz/lzma, gives BZLIB/LZMALIB .am
 264 dnl conditional and config.h USE_BZLIB/USE_LZMALIB #define.
 265 save_LIBS="$LIBS"
 266 LIBS=
 267 eu_ZIPLIB(bzlib,BZLIB,bz2,BZ2_bzdopen,bzip2)
 268 # We need this since bzip2 doesn't have a pkgconfig file.
 269 BZ2_LIB="$LIBS"
 270 AC_SUBST([BZ2_LIB])
 271 eu_ZIPLIB(lzma,LZMA,lzma,lzma_auto_decoder,[LZMA (xz)])
 272 AS_IF([test "x$with_lzma" = xyes], [LIBLZMA="liblzma"], [LIBLZMA=""])
 273 AC_SUBST([LIBLZMA])
 274 zip_LIBS="$LIBS"
 275 LIBS="$save_LIBS"
 276 AC_SUBST([zip_LIBS])
 277
 278 AC_CHECK_LIB([stdc++], [__cxa_demangle], [dnl
 279 AC_DEFINE([USE_DEMANGLE], [1], [Defined if demangling is enabled])])
 280 AM_CONDITIONAL(DEMANGLE, test "x$ac_cv_lib_stdcpp___cxa_demangle" = "xyes")
 281 AS_IF([test "x$ac_cv_lib_stdcpp___cxa_demangle" = "xyes"],
 282       [enable_demangler=yes],[enable_demangler=no])
 283
 284 AC_ARG_ENABLE([textrelcheck],
 285 AS_HELP_STRING([--disable-textrelcheck],
 286                [Disable textrelcheck being a fatal error]))
 287 AM_CONDITIONAL(FATAL_TEXTREL, [test "x$enable_textrelcheck" != "xno"])
 288 AS_IF([test "x$enable_textrelcheck" != "xno"],
 289       [enable_textrelcheck=yes],[enable_textrelcheck=no])
 290
 291 AC_ARG_ENABLE([symbol-versioning],
 292 AS_HELP_STRING([--disable-symbol-versioning],
 293                [Disable symbol versioning in shared objects]))
 294 AM_CONDITIONAL(SYMBOL_VERSIONING, [test "x$enable_symbol_versioning" != "xno"])
 295 AS_IF([test "x$enable_symbol_versioning" = "xno"],
 296       [AC_MSG_WARN([Disabling symbol versioning breaks ABI compatibility.])
 297        enable_symbol_versioning=no],[enable_symbol_versioning=yes])
 298
 299 AC_CACHE_CHECK([whether gcc accepts -Wstack-usage], ac_cv_stack_usage, [dnl
 300 old_CFLAGS="$CFLAGS"
 301 CFLAGS="$CFLAGS -Wstack-usage=262144 -Werror"
 302 AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 303                   ac_cv_stack_usage=yes, ac_cv_stack_usage=no)
 304 CFLAGS="$old_CFLAGS"])
 305 AM_CONDITIONAL(ADD_STACK_USAGE_WARNING, [test "x$ac_cv_stack_usage" != "xno"])
 306
 307 # -Wlogical-op was too fragile in the past, make sure we get a sane one.
 308 AC_CACHE_CHECK([whether gcc has a sane -Wlogical-op], ac_cv_logical_op, [dnl
 309 old_CFLAGS="$CFLAGS"
 310 CFLAGS="$CFLAGS -Wlogical-op -Werror"
 311 AC_COMPILE_IFELSE([AC_LANG_SOURCE(
 312         [#define FLAG 1
 313         int f (int r, int f) { return (r && (FLAG || (FLAG & f))); }])],
 314                   ac_cv_logical_op=yes, ac_cv_logical_op=no)
 315 CFLAGS="$old_CFLAGS"])
 316 AM_CONDITIONAL(SANE_LOGICAL_OP_WARNING,
 317                [test "x$ac_cv_logical_op" != "xno"])
 318
 319 # -Wduplicated-cond was added by GCC6
 320 AC_CACHE_CHECK([whether gcc accepts -Wduplicated-cond], ac_cv_duplicated_cond, [dnl
 321 old_CFLAGS="$CFLAGS"
 322 CFLAGS="$CFLAGS -Wduplicated-cond -Werror"
 323 AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 324                   ac_cv_duplicated_cond=yes, ac_cv_duplicated_cond=no)
 325 CFLAGS="$old_CFLAGS"])
 326 AM_CONDITIONAL(HAVE_DUPLICATED_COND_WARNING,
 327                [test "x$ac_cv_duplicated_cond" != "xno"])
 328
 329 # -Wnull-dereference was added by GCC6
 330 AC_CACHE_CHECK([whether gcc accepts -Wnull-dereference], ac_cv_null_dereference, [dnl
 331 old_CFLAGS="$CFLAGS"
 332 CFLAGS="$CFLAGS -Wnull-dereference -Werror"
 333 AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 334                   ac_cv_null_dereference=yes, ac_cv_null_dereference=no)
 335 CFLAGS="$old_CFLAGS"])
 336 AM_CONDITIONAL(HAVE_NULL_DEREFERENCE_WARNING,
 337                [test "x$ac_cv_null_dereference" != "xno"])
 338
 339 dnl Check if we have argp available from our libc
 340 AC_LINK_IFELSE(
 341         [AC_LANG_PROGRAM(
 342                 [#include <argp.h>],
 343                 [int argc=1; char *argv[]={"test"}; argp_parse(0,argc,&argv,0,0,0); return 0;]
 344                 )],
 345         [libc_has_argp="true"],
 346         [libc_has_argp="false"]
 347 )
 348
 349 dnl If our libc doesn't provide argp, then test for libargp
 350 if test "$libc_has_argp" = "false" ; then
 351         AC_MSG_WARN("libc does not have argp")
 352         AC_CHECK_LIB([argp], [argp_parse], [have_argp="true"], [have_argp="false"])
 353
 354         if test "$have_argp" = "false"; then
 355                 AC_MSG_ERROR("no libargp found")
 356         else
 357                 argp_LDADD="-largp"
 358         fi
 359 else
 360         argp_LDADD=""
 361 fi
 362 AC_SUBST([argp_LDADD])
 363
 364 dnl Check if we have <linux/bpf.h> for EM_BPF disassembly.
 365 AC_CHECK_HEADERS(linux/bpf.h)
 366 AM_CONDITIONAL(HAVE_LINUX_BPF_H, [test "x$ac_cv_header_linux_bpf_h" = "xyes"])
 367
 368 dnl The directories with content.
 369
 370 dnl Documentation.
 371 dnl Commented out for now.
 372 dnl AC_CONFIG_FILES([doc/Makefile])
 373
 374 dnl Support library.
 375 AC_CONFIG_FILES([lib/Makefile])
 376
 377 dnl ELF library.
 378 AC_CONFIG_FILES([libelf/Makefile])
 379
 380 dnl Higher-level ELF support library.
 381 AC_CONFIG_FILES([libebl/Makefile])
 382
 383 dnl DWARF-ELF Lower-level Functions support library.
 384 AC_CONFIG_FILES([libdwelf/Makefile])
 385
 386 dnl DWARF library.
 387 AC_CONFIG_FILES([libdw/Makefile])
 388
 389 dnl Higher-level DWARF support library.
 390 AC_CONFIG_FILES([libdwfl/Makefile])
 391
 392 dnl CPU handling library.
 393 AC_CONFIG_FILES([libcpu/Makefile])
 394
 395 dnl Assembler library.
 396 AM_CONDITIONAL(HAVE_LIBASM, true)dnl Used in tests/Makefile.am, which see.
 397 AC_CONFIG_FILES([libasm/Makefile])
 398
 399 dnl CPU-specific backend libraries.
 400 AC_CONFIG_FILES([backends/Makefile])
 401
 402 dnl Tools.
 403 AC_CONFIG_FILES([src/Makefile po/Makefile.in])
 404
 405 dnl Test suite.
 406 AM_CONDITIONAL(STANDALONE, false)dnl Used in tests/Makefile.am, which see.
 407 AC_CONFIG_FILES([tests/Makefile])
 408
 409 dnl pkgconfig files
 410 AC_CONFIG_FILES([config/libelf.pc config/libdw.pc])
 411
 412 # Get the definitions necessary to create the Makefiles in the po
 413 # subdirectories.  This is a small subset of the gettext rules.
 414 AC_SUBST(USE_NLS, yes)
 415 AM_PO_SUBDIRS
 416
 417 dnl Appended to the config.h file.
 418 dnl We hide all kinds of configuration magic in lib/eu-config.h.
 419 AH_BOTTOM([#include <eu-config.h>])
 420
 421 dnl Version compatibility header.
 422 AC_CONFIG_FILES([version.h:config/version.h.in])
 423 AC_SUBST([eu_version])
 424
 425 # 1.234<whatever> -> 1234<whatever>
 426 case "$PACKAGE_VERSION" in
 427 [[0-9]].*) eu_version=`echo "$PACKAGE_VERSION" | sed 's@\.@@'` ;;
 428 *)         AC_MSG_ERROR([confused by version number '$PACKAGE_VERSION']) ;;
 429 esac
 430 case "$eu_version" in
 431 *.*)
 432   # 1234.567 -> "1234", "567"
 433   eu_extra_version="${eu_version#*.}"
 434   eu_version="${eu_version%%.*}"
 435   case "$eu_extra_version" in
 436   [[0-9]][[0-9]][[0-9]]) ;;
 437   [[0-9]][[0-9]])       eu_extra_version="${eu_extra_version}0" ;;
 438   [[0-9]])              eu_extra_version="${eu_extra_version}00" ;;
 439   *) AC_MSG_ERROR([confused by version number '$PACKAGE_VERSION']) ;;
 440   esac
 441   ;;
 442 *)
 443   eu_extra_version=000
 444   ;;
 445 esac
 446
 447 case "$eu_version" in
 448       0[[0-9]][[0-9]][[0-9]]) eu_version="${eu_version#0}$eu_extra_version" ;;
 449 [[0-9]][[0-9]][[0-9]][[0-9]]) eu_version="${eu_version}$eu_extra_version" ;;
 450 [[0-9]][[0-9]][[0-9]])        eu_version="${eu_version}0$eu_extra_version" ;;
 451 [[0-9]][[0-9]])               eu_version="${eu_version}00$eu_extra_version";;
 452 *) AC_MSG_ERROR([confused by version number '$PACKAGE_VERSION']) ;;
 453 esac
 454
 455 # Round up to the next release API (x.y) version.
 456 eu_version=$(( (eu_version + 999) / 1000 ))
 457
 458 dnl Unique ID for this build.
 459 MODVERSION="Build for ${LIBEBL_SUBDIR} ${eu_version} ${ac_cv_build}"
 460 AC_SUBST([MODVERSION])
 461 AC_DEFINE_UNQUOTED(MODVERSION, "$MODVERSION")
 462 AH_TEMPLATE([MODVERSION], [Identifier for modules in the build.])
 463
 464 AC_CHECK_SIZEOF(long)
 465
 466 # On aarch64 before glibc 2.20 we would get the kernel user_pt_regs instead
 467 # of the user_regs_struct from sys/user.h. They are structurally the same
 468 # but we get either one or the other.
 469 AC_CHECK_TYPE([struct user_regs_struct],
 470               [sys_user_has_user_regs=yes], [sys_user_has_user_regs=no],
 471               [[#include <sys/ptrace.h>]
 472                [#include <sys/time.h>]
 473                [#include <sys/user.h>]])
 474 if test "$sys_user_has_user_regs" = "yes"; then
 475   AC_DEFINE(HAVE_SYS_USER_REGS, 1,
 476             [Define to 1 if <sys/user.h> defines struct user_regs_struct])
 477 fi
 478
 479 # On a 64-bit host where can can use $CC -m32, we'll run two sets of tests.
 480 # Likewise in a 32-bit build on a host where $CC -m64 works.
 481 utrace_BIARCH
 482 # `$utrace_biarch' will be `-m64' even on an uniarch i386 machine.
 483 CC_BIARCH="$CC $utrace_biarch"
 484 AC_SUBST([CC_BIARCH])
 485
 486 # In maintainer mode we really need flex and bison.
 487 # Otherwise we really need a release dir with maintainer files generated.
 488 if test "x$enable_maintainer_mode" = xyes; then
 489   AC_CHECK_PROG(HAVE_FLEX, flex, yes, no)
 490   if test "$HAVE_FLEX" = "no"; then
 491     AC_MSG_ERROR([flex needed in maintainer mode])
 492   fi
 493   AC_CHECK_PROG(HAVE_BISON, bison, yes, no)
 494   if test "$HAVE_BISON" = "no"; then
 495     AC_MSG_ERROR([bison needed in maintainer mode])
 496   fi
 497 else
 498   if test ! -f ${srcdir}/libdw/known-dwarf.h; then
 499     AC_MSG_ERROR([No libdw/known-dwarf.h. configure --enable-maintainer-mode])
 500   fi
 501 fi
 502
 503 # The testfiles are all compressed, we need bunzip2 when running make check
 504 AC_CHECK_PROG(HAVE_BUNZIP2, bunzip2, yes, no)
 505 if test "$HAVE_BUNZIP2" = "no"; then
 506   AC_MSG_WARN([No bunzip2, needed to run make check])
 507 fi
 508
 509 AC_OUTPUT
 510
 511 AC_MSG_NOTICE([
 512 =====================================================================
 513         elfutils: ${PACKAGE_VERSION} (eu_version: ${eu_version})
 514 =====================================================================
 515
 516     Prefix                             : ${prefix}
 517     Program prefix ("eu-" recommended) : ${program_prefix}
 518     Source code location               : ${srcdir}
 519     Maintainer mode                    : ${enable_maintainer_mode}
 520     libebl modules subdirectory        : ${LIBEBL_SUBDIR}
 521     build arch                         : ${ac_cv_build}
 522
 523   RECOMMENDED FEATURES (should all be yes)
 524     gzip support                       : ${with_zlib}
 525     bzip2 support                      : ${with_bzlib}
 526     lzma/xz support                    : ${with_lzma}
 527     libstdc++ demangle support         : ${enable_demangler}
 528     File textrel check                 : ${enable_textrelcheck}
 529     Symbol versioning                  : ${enable_symbol_versioning}
 530
 531   NOT RECOMMENDED FEATURES (should all be no)
 532     Experimental thread safety         : ${use_locks}
 533
 534   OTHER FEATURES
 535     Deterministic archives by default  : ${default_ar_deterministic}
 536     Native language support            : ${USE_NLS}
 537
 538   EXTRA TEST FEATURES (used with make check)
 539     have bunzip2 installed (required)  : ${HAVE_BUNZIP2}
 540     debug branch prediction            : ${use_debugpred}
 541     gprof support                      : ${use_gprof}
 542     gcov support                       : ${use_gcov}
 543     run all tests under valgrind       : ${use_valgrind}
 544     gcc undefined behaviour sanitizer  : ${use_undefined}
 545     use rpath in tests                 : ${tests_use_rpath}
 546     test biarch                        : ${utrace_cv_cc_biarch}
 547 ])