configure.ac

   1 AC_INIT([btrfs-progs],
   2         m4_esyscmd([./version.sh --configure]),
   3         [linux-btrfs@vger.kernel.org],,
   4         [http://btrfs.wiki.kernel.org])
   5
   6 dnl library version
   7 LIBBTRFS_MAJOR=0
   8 LIBBTRFS_MINOR=1
   9 LIBBTRFS_PATCHLEVEL=1
  10
  11 CFLAGS="-g -O1"
  12
  13 AC_PREREQ([2.60])
  14
  15 AC_CONFIG_AUX_DIR([config])
  16 dnl AC_USE_SYSTEM_EXTENSIONS must be called before any macros that run
  17 dnl the compiler (like AC_PROG_LIBTOOL) to avoid autoconf errors.
  18 AC_USE_SYSTEM_EXTENSIONS
  19
  20 AC_CONFIG_SRCDIR([btrfs.c])
  21 AC_PREFIX_DEFAULT([/usr])
  22
  23 AC_PROG_CC
  24 AC_CANONICAL_HOST
  25 AC_C_CONST
  26 AC_C_VOLATILE
  27 AC_C_BIGENDIAN
  28
  29 AC_SYS_LARGEFILE
  30
  31 AC_PROG_INSTALL
  32 AC_PROG_LN_S
  33 AC_PATH_PROG([AR], [ar])
  34 AC_PATH_PROG([RM], [rm], [rm])
  35 AC_PATH_PROG([RMDIR], [rmdir], [rmdir])
  36
  37 AC_CHECK_FUNCS([openat], [],
  38         [AC_MSG_ERROR([cannot find openat() function])])
  39
  40 m4_ifndef([PKG_PROG_PKG_CONFIG],
  41   [m4_fatal([Could not locate the pkg-config autoconf
  42     macros. These are usually located in /usr/share/aclocal/pkg.m4.
  43     If your macros are in a different location, try setting the
  44     environment variable AL_OPTS="-I/other/macro/dir" before running
  45     ./autogen.sh or autoreconf again.])])
  46 PKG_PROG_PKG_CONFIG
  47
  48
  49 dnl
  50 dnl Calls pkg-config --static
  51 dnl
  52 AC_DEFUN([PKG_STATIC], [
  53   if AC_RUN_LOG([pkg-config --exists --print-errors "$2"]); then
  54     $1=`pkg-config --libs --static "$2"`
  55     AC_SUBST([$1])
  56   else
  57     AC_MSG_ERROR([pkg-config description of $2, needed for static build, is not available])
  58   fi
  59 ])
  60
  61
  62 AC_ARG_ENABLE([backtrace],
  63   AS_HELP_STRING([--disable-backtrace], [disable btrfs backtrace]),
  64   [], [enable_backtrace=yes]
  65 )
  66
  67 AS_IF([test "x$enable_backtrace" = xno], [
  68   AC_DEFINE([BTRFS_DISABLE_BACKTRACE], [1], [disable backtrace stuff in kerncompat.h ])
  69 ])
  70
  71 if test "x$enable_backtrace" = xyes; then
  72         AC_CHECK_HEADERS([execinfo.h])
  73         AC_CHECK_FUNCS([backtrace backtrace_symbols_fd], [],
  74               AC_MSG_ERROR([standard library does not have backtrace support]))
  75 fi
  76
  77
  78 AC_ARG_ENABLE([documentation],
  79               AS_HELP_STRING([--disable-documentation], [do not build domumentation]),
  80   [], [enable_documentation=yes]
  81 )
  82 AS_IF([test "x$enable_documentation" = xyes], [DISABLE_DOCUMENTATION=0], [DISABLE_DOCUMENTATION=1])
  83 AC_SUBST([DISABLE_DOCUMENTATION])
  84
  85 dnl detect tools to build documentation
  86 if test "x$enable_documentation" = xyes; then
  87         AC_PATH_PROG([ASCIIDOC], [asciidoc], [asciidoc])
  88         AC_PATH_PROG([XMLTO], [xmlto], [xmlto])
  89         AC_PATH_PROG([GZIP], [gzip], [gzip])
  90         AC_PATH_PROG([MV], [mv], [mv])
  91         AC_PROG_SED
  92 fi
  93
  94 AC_ARG_ENABLE([convert],
  95               AS_HELP_STRING([--disable-convert], [do not build btrfs-convert]),
  96   [], [enable_btrfsconvert=yes]
  97 )
  98
  99 AS_IF([test "x$enable_btrfsconvert" = xyes], [DISABLE_BTRFSCONVERT=0], [DISABLE_BTRFSCONVERT=1])
 100 AC_SUBST([DISABLE_BTRFSCONVERT])
 101
 102 if test "x$enable_btrfsconvert" = xyes; then
 103         PKG_CHECK_MODULES(EXT2FS, [ext2fs])
 104         PKG_CHECK_MODULES(COM_ERR, [com_err])
 105 fi
 106
 107
 108 dnl Define <NAME>_LIBS= and <NAME>_CFLAGS= by pkg-config
 109 dnl
 110 dnl The default PKG_CHECK_MODULES() action-if-not-found is end the
 111 dnl execution with error. The static libs are optional.
 112
 113 PKG_CHECK_MODULES(BLKID, [blkid])
 114 PKG_STATIC(BLKID_LIBS_STATIC, [blkid])
 115
 116 PKG_CHECK_MODULES(UUID, [uuid])
 117 PKG_STATIC(UUID_LIBS_STATIC, [uuid])
 118
 119 PKG_CHECK_MODULES(ZLIB, [zlib])
 120 PKG_STATIC(ZLIB_LIBS_STATIC, [zlib])
 121
 122 dnl lzo library does not provide pkg-config, let use classic way
 123 AC_CHECK_LIB([lzo2], [lzo_version], [
 124         LZO2_LIBS="-llzo2"
 125         LZO2_CFLAGS=""
 126         LZO2_LIBS_STATIC="-llzo2"],[
 127         AC_MSG_ERROR([cannot find lzo2 library])
 128 ])
 129 AC_SUBST([LZO2_LIBS])
 130 AC_SUBST([LZO2_LIBS_STATIC])
 131 AC_SUBST([LZO2_CFLAGS])
 132
 133
 134 dnl library stuff
 135 AC_SUBST([LIBBTRFS_MAJOR])
 136 AC_SUBST([LIBBTRFS_MINOR])
 137 AC_SUBST([LIBBTRFS_PATCHLEVEL])
 138
 139 AC_CONFIG_HEADERS([config.h])
 140
 141 AC_CONFIG_FILES([
 142 Makefile
 143 Documentation/Makefile
 144 version.h
 145 ])
 146
 147 AC_OUTPUT
 148
 149 AC_MSG_RESULT([
 150         ${PACKAGE_NAME} ${PACKAGE_VERSION}
 151
 152         prefix:            ${prefix}
 153         exec prefix:       ${exec_prefix}
 154
 155         bindir:            ${bindir}
 156         libdir:            ${libdir}
 157         includedir:        ${includedir}
 158
 159         compiler:          ${CC}
 160         cflags:            ${CFLAGS}
 161         ldflags:           ${LDFLAGS}
 162
 163         documentaton:      ${enable_documentation}
 164         backtrace support: ${enable_backtrace}
 165         btrfs-convert:     ${enable_btrfsconvert}
 166
 167         Type 'make' to compile.
 168 ])
 169