configure.ac

   1 # gstreamer-vaapi package version number
   2 m4_define([gst_vaapi_major_version], [0])
   3 m4_define([gst_vaapi_minor_version], [4])
   4 m4_define([gst_vaapi_micro_version], [0])
   5 m4_define([gst_vaapi_pre_version],   [1])
   6 m4_define([gst_vaapi_version],
   7           [gst_vaapi_major_version.gst_vaapi_minor_version.gst_vaapi_micro_version])
   8 m4_if(gst_vaapi_pre_version, [0], [], [
   9 m4_append([gst_vaapi_version], gst_vaapi_pre_version, [.pre])
  10 ])
  11
  12 # glib version number
  13 m4_define([glib_major_version], [2])
  14 m4_define([glib_minor_version], [28])
  15 m4_define([glib_micro_version], [0])
  16 m4_define([glib_major_minor_version],
  17           [glib_major_version.glib_minor_version])
  18 m4_define([glib_version],
  19           [glib_major_version.glib_minor_version.glib_micro_version])
  20
  21 # gst version number
  22 m4_define([gst_major_version], [0])
  23 m4_define([gst_minor_version], [10])
  24 m4_define([gst_micro_version], [14])
  25 m4_define([gst_major_minor_version],
  26           [gst_major_version.gst_minor_version])
  27 m4_define([gst_version],
  28           [gst_major_version.gst_minor_version.gst_micro_version])
  29
  30 # gst plugins-base version number
  31 m4_define([gst_plugins_base_major_version], [0])
  32 m4_define([gst_plugins_base_minor_version], [10])
  33 m4_define([gst_plugins_base_micro_version], [31])
  34 m4_define([gst_plugins_base_version],
  35           [gst_plugins_base_major_version.gst_plugins_base_minor_version.gst_plugins_base_micro_version])
  36
  37 # gst plugins-bad version number
  38 m4_define([gst_plugins_bad_major_version], [0])
  39 m4_define([gst_plugins_bad_minor_version], [10])
  40 m4_define([gst_plugins_bad_micro_version], [22])
  41 m4_define([gst_plugins_bad_version],
  42           [gst_plugins_bad_major_version.gst_plugins_bad_minor_version.gst_plugins_bad_micro_version])
  43
  44 # VA-API minimum version number
  45 m4_define([va_api_version],     [0.30.4])
  46 m4_define([va_api_x11_version], [0.31.0])
  47 m4_define([va_api_glx_version], [0.32.0])
  48
  49 # libva package version number
  50 m4_define([libva_x11_package_version], [1.0.3])
  51 m4_define([libva_glx_package_version], [1.0.9])
  52
  53 # gtk-doc version number
  54 # XXX: introspection annotations require gtk-doc >= 1.12
  55 m4_define([gtkdoc_major_version], [1])
  56 m4_define([gtkdoc_minor_version], [9])
  57 m4_define([gtkdoc_version], [gtkdoc_major_version.gtkdoc_minor_version])
  58
  59 AC_PREREQ([2.58])
  60 AC_INIT([gst_vaapi], [gst_vaapi_version],
  61     [gwenole.beauchesne@intel.com],
  62     [gstreamer-vaapi])
  63
  64 AC_CONFIG_HEADERS([config.h])
  65 AC_CONFIG_SRCDIR([Makefile.am])
  66 AC_CONFIG_MACRO_DIR([m4])
  67 AC_CONFIG_AUX_DIR([build-aux])
  68
  69 AC_CANONICAL_TARGET
  70
  71 AM_INIT_AUTOMAKE
  72
  73 TODAY="`LC_ALL=C date +'%a, %d %b %Y %X %z'`"
  74 AC_SUBST(TODAY)
  75
  76 GST_VAAPI_MAJOR_VERSION=gst_vaapi_major_version
  77 AC_SUBST(GST_VAAPI_MAJOR_VERSION)
  78
  79 LIBVA_PACKAGE_VERSION=libva_x11_package_version
  80 AC_SUBST(LIBVA_PACKAGE_VERSION)
  81
  82 dnl Versions for GStreamer and plugins-base
  83 GST_MAJORMINOR=gst_major_minor_version
  84 GST_VERSION_REQUIRED=gst_version
  85 GST_PLUGINS_BASE_VERSION_REQUIRED=gst_plugins_base_version
  86 GST_PLUGINS_BAD_VERSION_REQUIRED=gst_plugins_bad_version
  87 AC_SUBST(GST_MAJORMINOR)
  88 AC_SUBST(GST_VERSION_REQUIRED)
  89 AC_SUBST(GST_PLUGINS_BASE_VERSION_REQUIRED)
  90 AC_SUBST(GST_PLUGINS_BAD_VERSION_REQUIRED)
  91
  92 dnl Use pretty build output with automake >= 1.11
  93 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [
  94   AM_DEFAULT_VERBOSITY=1
  95   AC_SUBST(AM_DEFAULT_VERBOSITY)
  96 ])
  97
  98 dnl Check for tools
  99 AC_PROG_CC
 100 AM_PROG_CC_C_O
 101 AC_PROG_LIBTOOL
 102
 103 AC_ARG_ENABLE(x11,
 104     AS_HELP_STRING([--enable-x11],
 105                    [enable X11 output @<:@default=yes@:>@]),
 106     [], [enable_x11="yes"])
 107
 108 AC_ARG_ENABLE(glx,
 109     AS_HELP_STRING([--enable-glx],
 110                    [enable OpenGL/X11 @<:@default=yes@:>@]),
 111     [], [enable_glx="yes"])
 112
 113 AC_ARG_ENABLE(vaapi-glx,
 114     AS_HELP_STRING([--enable-vaapi-glx],
 115                    [enable VA/GLX extensions @<:@default=yes@:>@]),
 116     [], [enable_vaapi_glx="yes"])
 117
 118 AC_ARG_ENABLE(vaapisink-glx,
 119     AS_HELP_STRING([--enable-vaapisink-glx],
 120                    [enable OpenGL/X11 to vaapisink @<:@default=yes@:>@]),
 121     [], [enable_vaapisink_glx="no"])
 122
 123 dnl Check for basic libraries
 124 AC_CHECK_LIB(m, tan)
 125
 126 dnl Check for Gtk doc
 127 GTKDOC_VERSION=gtkdoc_version
 128 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
 129 m4_ifdef([GTK_DOC_CHECK], [
 130 GTK_DOC_CHECK([$GTKDOC_VERSION], [--flavour no-tmpl])], [
 131 AM_CONDITIONAL([ENABLE_GTK_DOC], [false])])
 132 AC_SUBST(GTKDOC_VERSION)
 133
 134 dnl Check for GLib
 135 GLIB_VERSION_REQUIRED=glib_version
 136 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= $GLIB_VERSION_REQUIRED])
 137 AC_SUBST(GLIB_VERSION_REQUIRED)
 138
 139 dnl ---------------------------------------------------------------------------
 140 dnl -- GStreamer                                                             --
 141 dnl ---------------------------------------------------------------------------
 142
 143 dnl GStreamer Core
 144 PKG_CHECK_MODULES([GST],      [gstreamer-$GST_MAJORMINOR >= gst_version])
 145 PKG_CHECK_MODULES([GST_BASE], [gstreamer-base-$GST_MAJORMINOR >= gst_version])
 146
 147 AC_CACHE_CHECK([for GstBaseSink::query hook], ac_cv_have_gst_base_sink_query, [
 148     saved_CFLAGS="$CFLAGS"
 149     CFLAGS="$CFLAGS $GST_BASE_CFLAGS"
 150     saved_LIBS="$LIBS"
 151     LIBS="$LIBS $GST_BASE_LIBS"
 152     AC_COMPILE_IFELSE(
 153         [AC_LANG_PROGRAM(
 154             [[#include <gst/base/gstbasesink.h>]],
 155             [[GstBaseSinkClass klass; klass.query = NULL;]])],
 156         [ac_cv_have_gst_base_sink_query="yes"],
 157         [ac_cv_have_gst_base_sink_query="no"]
 158     )
 159     CFLAGS="$saved_CFLAGS"
 160     LIBS="$saved_LIBS"
 161 ])
 162 if test "$ac_cv_have_gst_base_sink_query" != "yes"; then
 163     AC_MSG_ERROR([GstBaseSink does not contain the 'query' vfunc])
 164 fi
 165
 166 dnl GStreamer -base plugins
 167 PKG_CHECK_MODULES([GST_PLUGINS_BASE],
 168     [gstreamer-plugins-base-$GST_MAJORMINOR >= gst_plugins_base_version])
 169 PKG_CHECK_MODULES([GST_INTERFACES],
 170     [gstreamer-interfaces-$GST_MAJORMINOR >= gst_plugins_base_version])
 171
 172 dnl ... GstVideoOverlayComposition (gstreamer-video)
 173 PKG_CHECK_MODULES([GST_VIDEO],
 174     [gstreamer-video-$GST_MAJORMINOR >= gst_plugins_base_version])
 175
 176 AC_CACHE_CHECK([for GstVideoOverlayComposition],
 177     ac_cv_have_gst_video_overlay_composition, [
 178     saved_CFLAGS="$CFLAGS"
 179     CFLAGS="$CFLAGS $GST_CFLAGS"
 180     saved_LIBS="$LIBS"
 181     LIBS="$LIBS $GST_LIBS"
 182     AC_COMPILE_IFELSE(
 183         [AC_LANG_PROGRAM(
 184             [[#include <gst/video/video-overlay-composition.h>]],
 185             [[GstVideoOverlayComposition *c = gst_video_overlay_composition_new(0);]])],
 186         [ac_cv_have_gst_video_overlay_composition="yes"],
 187         [ac_cv_have_gst_video_overlay_composition="no"]
 188     )
 189     CFLAGS="$saved_CFLAGS"
 190     LIBS="$saved_LIBS"
 191 ])
 192 if test "$ac_cv_have_gst_video_overlay_composition" != "yes"; then
 193     AC_MSG_ERROR([GstVideoOverlayComposition is not available])
 194 fi
 195
 196 dnl GStreamer -bad plugins
 197 PKG_CHECK_MODULES([GST_BASEVIDEO],
 198     [gstreamer-basevideo-$GST_MAJORMINOR >= gst_plugins_bad_version])
 199
 200 dnl ... bitstream parsers
 201 USE_CODEC_PARSERS=1
 202 USE_LOCAL_CODEC_PARSERS=0
 203
 204 PKG_CHECK_MODULES([GST_CODEC_PARSERS],
 205     [gstreamer-codecparsers-$GST_MAJORMINOR >= gst_plugins_bad_version])
 206
 207 dnl ... 0.10.23 addition, could be implemented otherwise
 208 AC_CACHE_CHECK([for GstH264SliceHdr::n_emulation_prevention_bytes],
 209     ac_cv_have_gst_h264_slice_hdr_epb_count, [
 210     saved_CFLAGS="$CFLAGS"
 211     CFLAGS="$CFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 212     saved_LIBS="$LIBS"
 213     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 214     AC_COMPILE_IFELSE(
 215         [AC_LANG_PROGRAM(
 216             [[#include <gst/codecparsers/gsth264parser.h>]],
 217             [[GstH264SliceHdr slice_hdr;
 218               slice_hdr.n_emulation_prevention_bytes = 0;]])],
 219         [ac_cv_have_gst_h264_slice_hdr_epb_count="yes"],
 220         [ac_cv_have_gst_h264_slice_hdr_epb_count="no"]
 221     )
 222     CFLAGS="$saved_CFLAGS"
 223     LIBS="$saved_LIBS"
 224 ])
 225
 226 if test "$ac_cv_have_gst_h264_slice_hdr_epb_count" = "yes"; then
 227     AC_DEFINE_UNQUOTED(HAVE_GST_H264_SLICE_HDR_EPB_COUNT, 1,
 228         [Defined to 1 if GstH264SliceHdr::n_emulation_prevention_bytes exists.])
 229 fi
 230
 231 dnl ... JPEG parser, not upstream yet
 232 AC_CACHE_CHECK([for JPEG parser],
 233     ac_cv_have_gst_jpeg_parser, [
 234     saved_CFLAGS="$CFLAGS"
 235     CFLAGS="$CFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 236     saved_LIBS="$LIBS"
 237     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 238     AC_COMPILE_IFELSE(
 239         [AC_LANG_PROGRAM(
 240             [[#include <gst/codecparsers/gstjpegparser.h>]],
 241             [[GstJpegImage jpeg_image;]])],
 242         [ac_cv_have_gst_jpeg_parser="yes"],
 243         [ac_cv_have_gst_jpeg_parser="no" USE_LOCAL_CODEC_PARSERS=1]
 244     )
 245     CFLAGS="$saved_CFLAGS"
 246     LIBS="$saved_LIBS"
 247 ])
 248
 249 if test "$ac_cv_have_gst_jpeg_parser" = "yes"; then
 250     AC_DEFINE_UNQUOTED(HAVE_GST_JPEG_PARSER, 1,
 251         [Defined to 1 if JPEG parser exists.])
 252 fi
 253 AM_CONDITIONAL(USE_LOCAL_CODEC_PARSERS, test $USE_LOCAL_CODEC_PARSERS -eq 1)
 254
 255 dnl GST_ALL_LDFLAGS:
 256 dnl LDFLAGS really should only contain flags, not libs - they get added before
 257 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 258 GST_ALL_LDFLAGS="-no-undefined"
 259 AC_SUBST(GST_ALL_LDFLAGS)
 260
 261 dnl GST_PLUGIN_LDFLAGS:
 262 dnl this really should only contain flags, not libs - they get added before
 263 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 264 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^([_]*gst_plugin_desc|gst_.*_get_type)\$\$' $GST_ALL_LDFLAGS"
 265 AC_SUBST(GST_PLUGIN_LDFLAGS)
 266
 267 dnl Check for the GStreamer plugins directory
 268 AC_MSG_CHECKING([for GStreamer plugins directory])
 269 GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_MAJORMINOR --variable pluginsdir`
 270 if test -z "$GST_PLUGINS_DIR"; then
 271     echo "FAIL FAIL FAIL"
 272     GST_PLUGINS_DIR="\$(libdir)/gstreamer-$GST_MAJORMINOR"
 273 fi
 274 AC_MSG_RESULT([$GST_PLUGINS_DIR])
 275 plugindir="$GST_PLUGINS_DIR"
 276 AC_SUBST(plugindir)
 277
 278 dnl ---------------------------------------------------------------------------
 279 dnl -- Renderers                                                             --
 280 dnl ---------------------------------------------------------------------------
 281
 282 dnl Check for X11
 283 USE_X11=0
 284 if test "$enable_x11" = "yes"; then
 285     PKG_CHECK_MODULES(X11, [x11], [USE_X11=1], [USE_X11=0])
 286     if test $USE_X11 -eq 1; then
 287         saved_CPPFLAGS="$CPPFLAGS"
 288         CPPFLAGS="$CPPFLAGS $WAYLAND_CFLAGS"
 289         AC_CHECK_HEADERS([X11/Xlib.h X11/Xutil.h X11/Xatom.h], [:], [USE_X11=0])
 290         CPPFLAGS="$saved_CPPFLAGS"
 291     fi
 292 fi
 293
 294 dnl OpenGL
 295 enable_opengl="no"
 296 if test "$enable_glx" = "yes"; then
 297     enable_opengl="yes"
 298 fi
 299
 300 HAVE_GL=0
 301 if test "$enable_opengl" = "yes"; then
 302     HAVE_GL=1
 303     PKG_CHECK_MODULES([GL], [gl], [:], [HAVE_GL=0])
 304     saved_CPPFLAGS="$CPPFLAGS"
 305     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
 306     AC_CHECK_HEADERS([GL/gl.h GL/glext.h], [:], [HAVE_GL=0], [
 307 #ifdef HAVE_GL_GL_H
 308 # include <GL/gl.h>
 309 #endif
 310     ])
 311     CPPFLAGS="$saved_CPPFLAGS"
 312 fi
 313
 314 dnl ... GLX
 315 USE_GLX=0
 316 if test "$enable_glx" = "yes" -a $HAVE_GL -eq 1 -a $USE_X11 -eq 1; then
 317     USE_GLX=1
 318     saved_CPPFLAGS="$CPPFLAGS"
 319     saved_LIBS="$LIBS"
 320     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
 321     LIBS="$LIBS $GL_LIBS"
 322     AC_CHECK_HEADERS([GL/glx.h], [:], [USE_GLX=0], [
 323 #ifdef HAVE_GL_GL_H
 324 # include <GL/gl.h>
 325 #endif
 326     ])
 327     AC_CHECK_LIB([GL], [glXCreateContext], [:], [USE_GLX=0])
 328     CPPFLAGS="$saved_CPPFLAGS"
 329     LIBS="$saved_LIBS"
 330 fi
 331
 332 dnl ---------------------------------------------------------------------------
 333 dnl -- VA-API                                                                --
 334 dnl ---------------------------------------------------------------------------
 335
 336 dnl Core API
 337 LIBVA_PKGNAME="libva"
 338 PKG_CHECK_MODULES(LIBVA, [$LIBVA_PKGNAME >= va_api_version])
 339 AC_SUBST(LIBVA_PKGNAME)
 340
 341 VA_VERSION=`$PKG_CONFIG --modversion libva`
 342 VA_MAJOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f1`
 343 VA_MINOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f2`
 344 VA_MICRO_VERSION=`echo "$VA_VERSION" | cut -d'.' -f3`
 345 VA_VERSION_STR="$VA_VERSION"
 346
 347 dnl VA/X11 API
 348 HAVE_VA_X11=0
 349 LIBVA_X11_PKGNAME="libva-x11"
 350 if test $USE_X11 -eq 1; then
 351     PKG_CHECK_MODULES(LIBVA_X11, [$LIBVA_X11_PKGNAME >= va_api_x11_version],
 352         [HAVE_VA_X11=1], [USE_X11=0])
 353 fi
 354 AC_SUBST(LIBVA_X11_PKGNAME)
 355
 356 dnl VA/GLX API
 357 HAVE_VA_GLX=0
 358 LIBVA_GLX_PKGNAME="libva-glx"
 359 if test $USE_GLX -eq 1; then
 360     PKG_CHECK_MODULES(LIBVA_GLX, [$LIBVA_GLX_PKGNAME >= va_api_glx_version],
 361         [HAVE_VA_GLX=1])
 362     if test "$enable_vaapi_glx" = "yes" -a $HAVE_VA_GLX -eq 0; then
 363         AC_MSG_WARN([VA/GLX not found or disabled. Fallbacking to TFP+FBO])
 364         LIBVA_GLX_PKGNAME="$LIBVA_X11_PKGNAME"
 365     fi
 366 fi
 367 AC_SUBST(LIBVA_GLX_PKGNAME)
 368
 369 dnl Check for JPEG decoding API (0.33+)
 370 USE_JPEG_DECODER=0
 371 AC_CACHE_CHECK([for JPEG decoding API],
 372     ac_cv_have_jpeg_decoding_api, [
 373     saved_CFLAGS="$CFLAGS"
 374     CFLAGS="$CFLAGS $LIBVA_CFLAGS"
 375     saved_LIBS="$LIBS"
 376     LIBS="$CFLAGS $LIBVA_LIBS"
 377     AC_COMPILE_IFELSE(
 378         [AC_LANG_PROGRAM(
 379             [[#include <va/va.h>
 380               #include <va/va_dec_jpeg.h>]],
 381             [[VAPictureParameterBufferJPEG pic_param;
 382               VASliceParameterBufferJPEG slice_param;
 383               VAHuffmanTableBufferJPEG huffman_table;
 384               VAIQMatrixBufferJPEG iq_matrix;]])],
 385         [ac_cv_have_jpeg_decoding_api="yes" USE_JPEG_DECODER=1],
 386         [ac_cv_have_jpeg_decoding_api="no"]
 387     )
 388     CFLAGS="$saved_CFLAGS"
 389     LIBS="$saved_LIBS"
 390 ])
 391
 392 dnl Check for OpenGL support to vaapisink
 393 if test "$enable_vaapisink_glx:$USE_GLX" = "yes:1"; then
 394     USE_VAAPISINK_GLX=1
 395 else
 396     USE_VAAPISINK_GLX=0
 397 fi
 398
 399 dnl ---------------------------------------------------------------------------
 400 dnl -- Generate files and summary                                            --
 401 dnl ---------------------------------------------------------------------------
 402
 403 case ":$USE_X11:$USE_GLX:" in
 404 *:1:*)
 405     ;;
 406 *)
 407     AC_MSG_ERROR([No renderer is enabled])
 408     ;;
 409 esac
 410
 411 AC_DEFINE_UNQUOTED(USE_JPEG_DECODER, $USE_JPEG_DECODER,
 412     [Defined to 1 if JPEG decoder is used])
 413 AM_CONDITIONAL(USE_JPEG_DECODER, test $USE_JPEG_DECODER -eq 1)
 414
 415 AC_DEFINE_UNQUOTED(USE_X11, $USE_X11,
 416     [Defined to 1 if X11 is enabled])
 417 AM_CONDITIONAL(USE_X11, test $USE_X11 -eq 1)
 418
 419 AC_DEFINE_UNQUOTED(USE_GLX, $USE_GLX,
 420     [Defined to 1 if GLX is enabled])
 421 AM_CONDITIONAL(USE_GLX, test $USE_GLX -eq 1)
 422
 423 AC_DEFINE_UNQUOTED([USE_VAAPI_GLX], [$HAVE_VA_GLX],
 424     [Defined to 1 if VA/GLX is enabled])
 425 AM_CONDITIONAL([USE_VAAPI_GLX], [test $HAVE_VA_GLX -eq 1])
 426
 427 AC_DEFINE_UNQUOTED(USE_VAAPISINK_GLX, $USE_VAAPISINK_GLX,
 428     [Defined to 1 to enable GLX support to vaapisink])
 429 AM_CONDITIONAL(USE_VAAPISINK_GLX, test $USE_VAAPISINK_GLX -eq 1)
 430
 431 pkgconfigdir=${libdir}/pkgconfig
 432 AC_SUBST(pkgconfigdir)
 433
 434 AC_CONFIG_FILES([
 435     Makefile
 436     debian.upstream/Makefile
 437     debian.upstream/changelog
 438     debian.upstream/control
 439     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi-doc.install:\
 440 debian.upstream/gstreamer-vaapi-doc.install.in
 441     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi.install:\
 442 debian.upstream/gstreamer-vaapi.install.in
 443     debian.upstream/libgstvaapi$GST_VAAPI_MAJOR_VERSION.install:\
 444 debian.upstream/libgstvaapi.install.in
 445     debian.upstream/libgstvaapi-dev.install
 446     debian.upstream/libgstvaapi-glx-$GST_VAAPI_MAJOR_VERSION.install:\
 447 debian.upstream/libgstvaapi-glx.install.in
 448     debian.upstream/libgstvaapi-x11-$GST_VAAPI_MAJOR_VERSION.install:\
 449 debian.upstream/libgstvaapi-x11.install.in
 450     docs/Makefile
 451     docs/reference/Makefile
 452     docs/reference/libs/Makefile
 453     docs/reference/libs/libs-docs.xml
 454     docs/reference/plugins/Makefile
 455     docs/reference/plugins/plugins-docs.xml
 456     gst-libs/Makefile
 457     gst-libs/gst/Makefile
 458     gst-libs/gst/codecparsers/Makefile
 459     gst-libs/gst/vaapi/Makefile
 460     gst/Makefile
 461     gst/vaapi/Makefile
 462     pkgconfig/Makefile
 463     pkgconfig/gstreamer-vaapi-$GST_MAJORMINOR.pc:\
 464 pkgconfig/gstreamer-vaapi.pc.in
 465     pkgconfig/gstreamer-vaapi-glx-$GST_MAJORMINOR.pc:\
 466 pkgconfig/gstreamer-vaapi-glx.pc.in
 467     pkgconfig/gstreamer-vaapi-x11-$GST_MAJORMINOR.pc:\
 468 pkgconfig/gstreamer-vaapi-x11.pc.in
 469     tests/Makefile
 470 ])
 471 AC_OUTPUT
 472
 473 dnl Print summary
 474 yesno() {
 475     test $1 -eq 1 && echo yes || echo no
 476 }
 477
 478 echo
 479 echo $PACKAGE configuration summary:
 480 echo
 481 echo VA-API version ................... : $VA_VERSION_STR
 482 echo GLX support ...................... : $(yesno $USE_GLX)
 483 echo VA/X11 support ................... : $(yesno $USE_X11)
 484 echo VA/GLX support ................... : $(yesno $HAVE_VA_GLX)
 485 echo VaapiSink/GL ..................... : $(yesno $USE_VAAPISINK_GLX)
 486 echo