configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.17.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl CURRENT, REVISION, AGE
  42 dnl - library source changed -> increment REVISION
  43 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  44 dnl - interfaces added -> increment AGE
  45 dnl - interfaces removed -> AGE = 0
  46 dnl sets GST_LT_LDFLAGS
  47 AS_LIBTOOL(GST, 12, 0, 12)
  48
  49 dnl FIXME: this macro doesn't actually work;
  50 dnl the generated libtool script has no support for the listed tags.
  51 dnl So this needs to be fixed first if we want to use this
  52 dnl AS_LIBTOOL_TAGS
  53
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=0.10.15.1
  58
  59 dnl *** autotools stuff ****
  60
  61 dnl allow for different autotools
  62 AS_AUTOTOOLS_ALTERNATE
  63
  64 dnl Add parameters for aclocal
  65 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  66
  67 dnl set up gettext
  68 dnl the version check needs to stay here because autopoint greps for it
  69 AM_GNU_GETTEXT_VERSION([0.11.5])
  70 AM_GNU_GETTEXT([external])
  71 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  72
  73 dnl *** check for arguments to configure ***
  74
  75 AG_GST_ARG_DEBUG
  76 AG_GST_ARG_PROFILING
  77 AG_GST_ARG_VALGRIND
  78 AG_GST_ARG_GCOV
  79
  80 AG_GST_ARG_EXAMPLES
  81
  82 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  83 AG_GST_ARG_WITH_PACKAGE_NAME
  84 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  85
  86 dnl let distro override plugin install helper path
  87 AC_ARG_WITH(install-plugins-helper,
  88   AC_HELP_STRING([--with-install-plugins-helper],
  89     [specify path of helper script to call to install plugins]),
  90   [
  91     case "${withval}" in
  92       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  93       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  94       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  95     esac
  96   ],
  97   [
  98     dnl Default value
  99     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 100   ]
 101 )
 102 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 103 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 104     [plugin install helper script])
 105 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 106
 107
 108 dnl these are all the gst plug-ins, compilable without additional libs
 109 GST_PLUGINS_ALL="\
 110         adder \
 111         audioconvert \
 112         audiorate \
 113         audioresample \
 114         audiotestsrc \
 115         ffmpegcolorspace \
 116         gdp \
 117         playback \
 118         typefind \
 119         videotestsrc \
 120         videorate \
 121         videoscale \
 122         volume \
 123         "
 124 AC_SUBST(GST_PLUGINS_ALL)
 125
 126 GST_PLUGINS_SELECTED=""
 127 AG_GST_ARG_WITH_PLUGINS
 128 AC_SUBST(GST_PLUGINS_SELECTED)
 129
 130 AG_GST_ARG_ENABLE_EXTERNAL
 131
 132 AG_GST_ARG_ENABLE_EXPERIMENTAL
 133 dnl *** checks for platform ***
 134
 135 dnl * hardware/architecture *
 136
 137 dnl common/m4/gst-arch.m4
 138 dnl check CPU type
 139 AG_GST_ARCH
 140
 141 dnl check for large file support
 142 dnl affected plugins must include config.h
 143 AC_SYS_LARGEFILE
 144
 145 dnl *** checks for programs ***
 146
 147 dnl find a compiler
 148 AC_PROG_CC
 149
 150 dnl check if the compiler supports '-c' and '-o' options
 151 AM_PROG_CC_C_O
 152
 153 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 154 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 155
 156 dnl check for documentation tools
 157 GTK_DOC_CHECK([1.3])
 158 AS_PATH_PYTHON([2.1])
 159 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 160
 161 dnl We need SED if building the docs
 162 if test "x$ENABLE_PLUGIN_DOCS" = "xyes"; then
 163   AC_PROG_SED
 164   AC_SUBST(SED)
 165 fi
 166
 167 dnl *** checks for libraries ***
 168
 169 dnl For interactive UNIX (a Sun thing)
 170 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 171 AC_ISC_POSIX
 172
 173 dnl libm, for sin() etc.
 174 AC_CHECK_LIBM
 175 AC_SUBST(LIBM)
 176
 177 dnl *** checks for header files ***
 178
 179 dnl check if we have ANSI C header files
 180 AC_HEADER_STDC
 181
 182 dnl used in gst/ffmpegcolorspace/mem.c
 183 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 184 AC_CHECK_HEADERS([malloc.h])
 185
 186 dnl used in gst/subparse/gstsubparse.c
 187 AC_CHECK_HEADERS([regex.h], HAVE_REGEX_H="yes", HAVE_REGEX_H="no")
 188 AM_CONDITIONAL(HAVE_REGEX_H, test "x$HAVE_REGEX_H" = "xyes")
 189
 190 if test "x$HAVE_REGEX_H" = "xyes"; then
 191   ac_cppflags_save="$CPPFLAGS"
 192   CPPFLAGS="-Wall -Werror `$PKG_CONFIG --cflags libxml-2.0`"
 193   AC_COMPILE_IFELSE(
 194     AC_LANG_PROGRAM([
 195 #include <libxml/HTMLparser.h>
 196                      ],[
 197 #ifndef LIBXML_HTML_ENABLED
 198 #error libxml2 has no HTML support
 199 #endif /* LIBXML_HTML_ENABLED */
 200                      ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 201   CPPFLAGS="$ac_cppflags_save"
 202
 203   if test "x$HAVE_LIBXML_HTML" = "xyes"; then
 204     GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED subparse"
 205   else
 206     GST_PLUGINS_NO="\t[subparse]\n$GST_PLUGINS_NO"
 207   fi
 208 else
 209   GST_PLUGINS_NO="\t[subparse]\n$GST_PLUGINS_NO"
 210   HAVE_LIBXML_HTML="no"
 211 fi
 212 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 213
 214 dnl used in gst/tcp
 215 AC_CHECK_HEADERS([sys/socket.h],
 216   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 217 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 218 if test "x$HAVE_SYS_SOCKET_H" = "xyes"; then
 219   GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED tcp"
 220 else
 221   GST_PLUGINS_NO="\t[tcp]\n$GST_PLUGINS_NO"
 222 fi
 223
 224 dnl used in gst-libs/gst/rtsp
 225 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 226 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 227   WIN32_LIBS="-lws2_32"
 228   AC_SUBST(WIN32_LIBS)
 229 fi
 230
 231 dnl check for hstrerror, for gst-libs/gst/rtsp
 232 save_libs="$LIBS"
 233 AC_CHECK_FUNC(hstrerror, ,
 234     AC_CHECK_LIB(resolv, hstrerror, ,
 235         [AC_DEFINE(NO_HSTRERROR, 1,
 236              [Define if you have no native hstrerror() function.])]))
 237 HSTRERROR_LIBS=$LIBS
 238 AC_SUBST(HSTRERROR_LIBS)
 239 LIBS="$save_libs"
 240
 241 dnl used in gst-libs/gst/pbutils and associated unit test
 242 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 243
 244 dnl ffmpegcolorspace includes _stdint.h
 245 dnl also, Windows does not have long long
 246 AX_CREATE_STDINT_H
 247
 248 dnl *** checks for functions ***
 249 AC_CHECK_FUNCS([localtime_r gmtime_r])
 250
 251 dnl *** checks for types/defines ***
 252
 253 dnl Check for FIONREAD ioctl declaration
 254 dnl used in gst/tcp
 255 GST_CHECK_FIONREAD
 256
 257 dnl *** checks for structures ***
 258
 259 dnl *** checks for compiler characteristics ***
 260
 261 dnl make sure we can use "inline" from C code
 262 AC_C_INLINE
 263
 264 dnl *** checks for library functions ***
 265
 266 dnl check for fseeko()
 267 AC_FUNC_FSEEKO
 268
 269 dnl Check for fast float to int casting as defined in C99
 270 dnl used in gst-libs/gst/floatcast/floatcast.h
 271 AC_C99_FUNC_LRINT
 272 AC_C99_FUNC_LRINTF
 273
 274 dnl Check for a way to display the function name in debug output
 275 AG_GST_CHECK_FUNCTION
 276
 277 dnl *** checks for dependency libraries ***
 278
 279 dnl GLib is required
 280 AG_GST_GLIB_CHECK([2.6])
 281
 282 dnl liboil is required
 283 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 284 if test "x$HAVE_LIBOIL" != "xyes"
 285 then
 286   AC_ERROR([liboil-0.3.8 or later is required])
 287 fi
 288
 289 dnl checks for gstreamer
 290 dnl uninstalled is selected preferentially -- see pkg-config(1)
 291 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 292 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 293 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 294 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 295 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 296 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 297
 298 dnl Check for documentation xrefs
 299 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 300 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 301 AC_SUBST(GLIB_PREFIX)
 302 AC_SUBST(GST_PREFIX)
 303
 304 dnl GTK is optional and used in examples
 305 HAVE_GTK=NO
 306 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 307 if test "x$HAVE_GTK_22" = "xyes"; then
 308   HAVE_GTK=yes
 309   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 310   AC_SUBST(GTK_VERSION)
 311   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 312   AC_SUBST(GTK_BASE_DIR)
 313 else
 314   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 315 fi
 316 if test "x$HAVE_GTK_20" = "xyes"; then
 317   HAVE_GTK=yes
 318 fi
 319 GTK_CFLAGS=$GTK2_CFLAGS
 320 GTK_LIBS=$GTK2_LIBS
 321 AC_SUBST(GTK_LIBS)
 322 AC_SUBST(GTK_CFLAGS)
 323 AC_SUBST(HAVE_GTK)
 324 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 325
 326 dnl *** set variables based on configure arguments ***
 327
 328 dnl set license and copyright notice
 329 GST_LICENSE="LGPL"
 330 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 331 AC_SUBST(GST_LICENSE)
 332
 333 dnl set location of plugin directory
 334 AG_GST_SET_PLUGINDIR
 335
 336 dnl define an ERROR_CFLAGS Makefile variable
 337 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 338
 339 dnl define correct level for debugging messages
 340 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 341
 342 dnl used in examples
 343 AG_GST_DEFAULT_ELEMENTS
 344
 345 dnl *** sys plug-ins ***
 346
 347 echo
 348 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 349 echo
 350
 351 dnl *** X11 ***
 352 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 353 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 354                   [ximagesink], [
 355   AC_PATH_XTRA
 356   ac_cflags_save="$CFLAGS"
 357   ac_cppflags_save="$CPPFLAGS"
 358   CFLAGS="$CFLAGS $X_CFLAGS"
 359   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 360
 361   dnl now try to find the HEADER
 362   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 363
 364   if test "x$HAVE_X" = "xno"
 365   then
 366     AC_MSG_NOTICE([cannot find X11 development files])
 367   else
 368     dnl this is much more than we want
 369     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 370     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 371     dnl it does not add the libs; therefore we add them here
 372     X_LIBS="$X_LIBS -lX11"
 373     AC_SUBST(X_CFLAGS)
 374     AC_SUBST(X_LIBS)
 375   fi
 376   AC_SUBST(HAVE_X)
 377   CFLAGS="$ac_cflags_save"
 378   CPPFLAGS="$ac_cppflags_save"
 379 ])
 380
 381 dnl Check for Xv extension
 382 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 383 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 384                   [xvimagesink], [
 385   AG_GST_CHECK_XV
 386 ])
 387
 388 dnl check for X Shm
 389 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 390 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 391   if test x$HAVE_X = xyes; then
 392     AC_CHECK_LIB(Xext, XShmAttach,
 393                  HAVE_XSHM="yes", HAVE_XSHM="no",
 394                  $X_LIBS)
 395     if test "x$HAVE_XSHM" = "xyes"; then
 396       XSHM_LIBS="-lXext"
 397     else
 398       dnl On AIX, it is in XextSam instead, but we still need -lXext
 399       AC_CHECK_LIB(XextSam, XShmAttach,
 400                    HAVE_XSHM="yes", HAVE_XSHM="no",
 401                    $X_LIBS)
 402       if test "x$HAVE_XSHM" = "xyes"; then
 403         XSHM_LIBS="-lXext -lXextSam"
 404       fi
 405     fi
 406   fi
 407 ], , [
 408   AC_SUBST(HAVE_XSHM)
 409   AC_SUBST(XSHM_LIBS)
 410 ])
 411
 412 dnl v4l/v4l2 checks have been moved down because they require X
 413
 414 dnl *** Video 4 Linux ***
 415 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 416 dnl renamed to GST_V4L in accordance with V4L2 below
 417 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 418 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 419   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 420 #include <sys/types.h>
 421 #define _LINUX_TIME_H
 422 #define __user
 423 #include <linux/videodev.h>
 424   ])
 425
 426   dnl we can build v4l without Xv, but then we won't have XOverlay support
 427   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 428   then
 429     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 430     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 431   fi
 432 ])
 433
 434 dnl *** ext plug-ins ***
 435 dnl keep this list sorted alphabetically !
 436
 437 if test "x$BUILD_EXTERNAL" = "xyes"; then
 438
 439 echo
 440 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 441 echo
 442
 443 dnl *** alsa ***
 444 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 445 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 446   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 447     HAVE_ALSA="yes"
 448     AC_SUBST(ALSA_CFLAGS)
 449     AC_SUBST(ALSA_LIBS)
 450   ], [
 451     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 452   ])
 453 ])
 454
 455 dnl *** CDParanoia ***
 456 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 457 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 458   AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 459                       cdda_open, -lm,
 460                       cdda_interface.h,
 461                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 462                       HEADER_DIR="no"
 463                       FOUND_CDPARANOIA="yes")
 464   if test "x$FOUND_CDPARANOIA" != "xyes";
 465   then
 466     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 467                         cdda_open, -lm,
 468                         cdda/cdda_interface.h,
 469                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 470                         HEADER_DIR="yes"
 471                         FOUND_CDPARANOIA="yes")
 472   fi
 473   if test "x$HEADER_DIR" = "xyes";
 474   then
 475     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 476                        defined if cdda headers are in a cdda/ directory)
 477   fi
 478   AC_SUBST(CDPARANOIA_LIBS)
 479 ])
 480 dnl FIXME : add second check somehow if that is necessary
 481 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 482 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 483
 484 dnl *** GNOME VFS ***
 485 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 486 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 487   AG_GST_PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0)
 488 ])
 489
 490 dnl *** libgio ***
 491 USE_GIO=$BUILD_EXPERIMENTAL
 492 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 493 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 494   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.15.2, HAVE_GIO="yes", [
 495     HAVE_GIO="no"
 496     AC_MSG_RESULT(no)
 497   ])
 498   AC_SUBST(GIO_CFLAGS)
 499   AC_SUBST(GIO_LIBS)
 500   AC_SUBST(GIO_LDFLAGS)
 501 ])
 502
 503 dnl *** libvisual ***
 504 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 505 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 506   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 507   if test $HAVE_LIBVISUAL = no
 508   then
 509     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 510   fi
 511 ])
 512
 513 dnl *** ogg ***
 514 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 515 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 516   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 517   if test $HAVE_OGG = no
 518   then
 519     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 520     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 521   fi
 522 ])
 523
 524 dnl *** pango ***
 525 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 526 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 527   AG_GST_PKG_CHECK_MODULES(PANGO, pango pangoft2)
 528 ])
 529
 530 dnl *** theora ***
 531 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 532 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 533   dnl this check will work as long as theora uses 1.0.x or similar for the
 534   dnl first post-alpha release and not just 1.0
 535   AG_GST_PKG_CHECK_MODULES(THEORA, theora >= 1.0alpha5)
 536 ])
 537
 538 dnl *** vorbis ***
 539 dnl AM_PATH_VORBIS only takes two options
 540 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 541 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 542   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 543   if test $HAVE_VORBIS = no
 544   then
 545     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 546     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 547   fi
 548 ])
 549
 550 if test "x$HAVE_VORBIS" = "xyes"; then
 551   ac_cflags_save="$CFLAGS"
 552   dnl FIXME: does this work on non-gcc? -- Company
 553   dnl FIXME: no, it doesn't.  Why is this here in the first place ? -- thomasvs
 554   CFLAGS="-Wall -Werror"
 555   AC_COMPILE_IFELSE(
 556     AC_LANG_PROGRAM([
 557 #include <vorbis/codec.h>
 558                      ],[
 559 vorbis_dsp_state *v;
 560
 561 vorbis_synthesis_restart (v);
 562                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 563   if test "x$HAVE_VSR" = "xyes"; then
 564     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 565                        [defined if vorbis_synthesis_restart is present])
 566   fi
 567   CFLAGS="$ac_cflags_save"
 568 fi
 569
 570 else
 571
 572 dnl not building plugins with external dependencies,
 573 dnl but we still need to set the conditionals
 574 AM_CONDITIONAL(USE_ALSA, false)
 575 AM_CONDITIONAL(USE_CDPARANOIA, false)
 576 AM_CONDITIONAL(USE_GNOME_VFS, false)
 577 AM_CONDITIONAL(USE_GIO, false)
 578 AM_CONDITIONAL(USE_LIBVISUAL, false)
 579 AM_CONDITIONAL(USE_OGG, false)
 580 AM_CONDITIONAL(USE_PANGO, false)
 581 AM_CONDITIONAL(USE_THEORA, false)
 582 AM_CONDITIONAL(USE_VORBIS, false)
 583
 584 fi dnl of EXT plugins
 585
 586 dnl seeking needs freetype, so check for it here
 587 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 588   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 589 ])
 590 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 591 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 592 AC_SUBST(FT2_CFLAGS)
 593 AC_SUBST(FT2_LIBS)
 594
 595 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 596
 597 dnl Overview:
 598 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 599 dnl GST_*:              flags shared by built objects to link against GStreamer
 600 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 601 dnl                          (compare to other modules) or for i18n
 602 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 603 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 604 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 605 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 606
 607 dnl GST_OPTION_CFLAGS
 608 if test "x$USE_DEBUG" = xyes; then
 609    PROFILE_CFLAGS="-g"
 610 fi
 611 AC_SUBST(PROFILE_CFLAGS)
 612
 613 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 614   dnl Define _only_ during CVS (not pre-releases or releases)
 615   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 616 else
 617   DEPRECATED_CFLAGS=""
 618 fi
 619 AC_SUBST(DEPRECATED_CFLAGS)
 620
 621 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 622 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 623 AC_SUBST(GST_OPTION_CFLAGS)
 624
 625 dnl our libraries need to be versioned correctly
 626 AC_SUBST(GST_LT_LDFLAGS)
 627
 628 dnl GST_PLUGINS_BASE_CFLAGS
 629 dnl prefer internal headers to already installed ones
 630 dnl also add builddir include for enumtypes and marshal
 631 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 632 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 633
 634 dnl FIXME: do we want to rename to GST_ALL_* ?
 635 dnl add GST_OPTION_CFLAGS, but overridable
 636 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 637 AC_SUBST(GST_CFLAGS)
 638 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 639 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 640 AC_SUBST(GST_LIBS)
 641
 642 dnl LDFLAGS really should only contain flags, not libs - they get added before
 643 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 644 GST_ALL_LDFLAGS="-no-undefined"
 645 AC_SUBST(GST_ALL_LDFLAGS)
 646
 647 dnl GST_LIB_LDFLAGS
 648 dnl linker flags shared by all libraries
 649 dnl LDFLAGS modifier defining exported symbols from built libraries
 650 dnl (export _gst_foo but not __gst_foo)
 651 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 652 AC_SUBST(GST_LIB_LDFLAGS)
 653
 654 dnl this really should only contain flags, not libs - they get added before
 655 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 656 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 657 AC_SUBST(GST_PLUGIN_LDFLAGS)
 658
 659 dnl *** output files ***
 660
 661 AC_CONFIG_FILES(
 662 Makefile
 663 gst-plugins-base.spec
 664 gst/Makefile
 665 gst/adder/Makefile
 666 gst/audioconvert/Makefile
 667 gst/audiorate/Makefile
 668 gst/audioresample/Makefile
 669 gst/audiotestsrc/Makefile
 670 gst/ffmpegcolorspace/Makefile
 671 gst/gdp/Makefile
 672 gst/playback/Makefile
 673 gst/subparse/Makefile
 674 gst/tcp/Makefile
 675 gst/typefind/Makefile
 676 gst/videotestsrc/Makefile
 677 gst/videorate/Makefile
 678 gst/videoscale/Makefile
 679 gst/volume/Makefile
 680 sys/Makefile
 681 sys/ximage/Makefile
 682 sys/xvimage/Makefile
 683 sys/v4l/Makefile
 684 ext/Makefile
 685 ext/alsa/Makefile
 686 ext/cdparanoia/Makefile
 687 ext/gnomevfs/Makefile
 688 ext/gio/Makefile
 689 ext/libvisual/Makefile
 690 ext/ogg/Makefile
 691 ext/pango/Makefile
 692 ext/theora/Makefile
 693 ext/vorbis/Makefile
 694 gst-libs/Makefile
 695 gst-libs/gst/Makefile
 696 gst-libs/gst/audio/Makefile
 697 gst-libs/gst/cdda/Makefile
 698 gst-libs/gst/fft/Makefile
 699 gst-libs/gst/floatcast/Makefile
 700 gst-libs/gst/interfaces/Makefile
 701 gst-libs/gst/netbuffer/Makefile
 702 gst-libs/gst/riff/Makefile
 703 gst-libs/gst/rtp/Makefile
 704 gst-libs/gst/rtsp/Makefile
 705 gst-libs/gst/sdp/Makefile
 706 gst-libs/gst/tag/Makefile
 707 gst-libs/gst/pbutils/Makefile
 708 gst-libs/gst/video/Makefile
 709 tools/Makefile
 710 win32/common/config.h
 711 pkgconfig/Makefile
 712 pkgconfig/gstreamer-audio.pc
 713 pkgconfig/gstreamer-audio-uninstalled.pc
 714 pkgconfig/gstreamer-cdda.pc
 715 pkgconfig/gstreamer-cdda-uninstalled.pc
 716 pkgconfig/gstreamer-fft.pc
 717 pkgconfig/gstreamer-fft-uninstalled.pc
 718 pkgconfig/gstreamer-floatcast.pc
 719 pkgconfig/gstreamer-floatcast-uninstalled.pc
 720 pkgconfig/gstreamer-interfaces.pc
 721 pkgconfig/gstreamer-interfaces-uninstalled.pc
 722 pkgconfig/gstreamer-netbuffer.pc
 723 pkgconfig/gstreamer-netbuffer-uninstalled.pc
 724 pkgconfig/gstreamer-pbutils.pc
 725 pkgconfig/gstreamer-pbutils-uninstalled.pc
 726 pkgconfig/gstreamer-riff.pc
 727 pkgconfig/gstreamer-riff-uninstalled.pc
 728 pkgconfig/gstreamer-rtp.pc
 729 pkgconfig/gstreamer-rtp-uninstalled.pc
 730 pkgconfig/gstreamer-rtsp.pc
 731 pkgconfig/gstreamer-rtsp-uninstalled.pc
 732 pkgconfig/gstreamer-sdp.pc
 733 pkgconfig/gstreamer-sdp-uninstalled.pc
 734 pkgconfig/gstreamer-tag.pc
 735 pkgconfig/gstreamer-tag-uninstalled.pc
 736 pkgconfig/gstreamer-video.pc
 737 pkgconfig/gstreamer-video-uninstalled.pc
 738 pkgconfig/gstreamer-plugins-base.pc
 739 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 740 tests/Makefile
 741 tests/check/Makefile
 742 tests/examples/Makefile
 743 tests/examples/dynamic/Makefile
 744 tests/examples/seek/Makefile
 745 tests/examples/volume/Makefile
 746 tests/examples/snapshot/Makefile
 747 tests/icles/Makefile
 748 docs/Makefile
 749 docs/design/Makefile
 750 docs/libs/Makefile
 751 docs/plugins/Makefile
 752 docs/version.entities
 753 po/Makefile.in
 754 common/Makefile
 755 common/m4/Makefile
 756 m4/Makefile
 757 )
 758 AC_OUTPUT
 759
 760 AG_GST_OUTPUT_PLUGINS