configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.18.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl CURRENT, REVISION, AGE
  42 dnl - library source changed -> increment REVISION
  43 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  44 dnl - interfaces added -> increment AGE
  45 dnl - interfaces removed -> AGE = 0
  46 dnl sets GST_LT_LDFLAGS
  47 AS_LIBTOOL(GST, 13, 0, 13)
  48
  49 dnl FIXME: this macro doesn't actually work;
  50 dnl the generated libtool script has no support for the listed tags.
  51 dnl So this needs to be fixed first if we want to use this
  52 dnl AS_LIBTOOL_TAGS
  53
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=0.10.17.1
  58
  59 dnl *** autotools stuff ****
  60
  61 dnl allow for different autotools
  62 AS_AUTOTOOLS_ALTERNATE
  63
  64 dnl Add parameters for aclocal
  65 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  66
  67 dnl set up gettext
  68 dnl the version check needs to stay here because autopoint greps for it
  69 AM_GNU_GETTEXT_VERSION([0.11.5])
  70 AM_GNU_GETTEXT([external])
  71 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  72
  73 dnl *** check for arguments to configure ***
  74
  75 AG_GST_ARG_DEBUG
  76 AG_GST_ARG_PROFILING
  77 AG_GST_ARG_VALGRIND
  78 AG_GST_ARG_GCOV
  79
  80 AG_GST_ARG_EXAMPLES
  81
  82 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  83 AG_GST_ARG_WITH_PACKAGE_NAME
  84 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  85
  86 dnl let distro override plugin install helper path
  87 AC_ARG_WITH(install-plugins-helper,
  88   AC_HELP_STRING([--with-install-plugins-helper],
  89     [specify path of helper script to call to install plugins]),
  90   [
  91     case "${withval}" in
  92       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  93       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  94       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  95     esac
  96   ],
  97   [
  98     dnl Default value
  99     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 100   ]
 101 )
 102 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 103 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 104     [plugin install helper script])
 105 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 106
 107 AG_GST_ARG_WITH_PLUGINS
 108
 109 AG_GST_ARG_ENABLE_EXTERNAL
 110
 111 AG_GST_ARG_ENABLE_EXPERIMENTAL
 112
 113 dnl *** checks for platform ***
 114
 115 dnl * hardware/architecture *
 116
 117 dnl common/m4/gst-arch.m4
 118 dnl check CPU type
 119 AG_GST_ARCH
 120
 121 dnl check for large file support
 122 dnl affected plugins must include config.h
 123 AC_SYS_LARGEFILE
 124
 125 dnl *** checks for programs ***
 126
 127 dnl find a compiler
 128 AC_PROG_CC
 129
 130 dnl check if the compiler supports '-c' and '-o' options
 131 AM_PROG_CC_C_O
 132
 133 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 134 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 135
 136 dnl check for documentation tools
 137 GTK_DOC_CHECK([1.3])
 138 AS_PATH_PYTHON([2.1])
 139 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 140
 141 dnl *** checks for libraries ***
 142
 143 dnl For interactive UNIX (a Sun thing)
 144 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 145 AC_ISC_POSIX
 146
 147 dnl libm, for sin() etc.
 148 AC_CHECK_LIBM
 149 AC_SUBST(LIBM)
 150
 151 dnl *** checks for header files ***
 152
 153 dnl check if we have ANSI C header files
 154 AC_HEADER_STDC
 155
 156 dnl used in gst/ffmpegcolorspace/mem.c
 157 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 158 AC_CHECK_HEADERS([malloc.h])
 159
 160 dnl used in gst/subparse/gstsubparse.c
 161 AC_CHECK_HEADERS([regex.h], HAVE_REGEX_H="yes", HAVE_REGEX_H="no")
 162 AM_CONDITIONAL(HAVE_REGEX_H, test "x$HAVE_REGEX_H" = "xyes")
 163
 164 if test "x$HAVE_REGEX_H" = "xyes"; then
 165   ac_cppflags_save="$CPPFLAGS"
 166   CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 167   AC_COMPILE_IFELSE(
 168     AC_LANG_PROGRAM([
 169 #include <libxml/HTMLparser.h>
 170                      ],[
 171 #ifndef LIBXML_HTML_ENABLED
 172 #error libxml2 has no HTML support
 173 #endif /* LIBXML_HTML_ENABLED */
 174                      ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 175   CPPFLAGS="$ac_cppflags_save"
 176 else
 177   HAVE_LIBXML_HTML="no"
 178 fi
 179 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 180
 181 dnl used in gst/tcp
 182 AC_CHECK_HEADERS([sys/socket.h],
 183   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 184 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 185
 186 dnl used in gst-libs/gst/rtsp
 187 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 188 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 189   WIN32_LIBS="-lws2_32"
 190   AC_SUBST(WIN32_LIBS)
 191 fi
 192
 193 dnl check for hstrerror, for gst-libs/gst/rtsp
 194 save_libs="$LIBS"
 195 AC_CHECK_FUNC(hstrerror, ,
 196     AC_CHECK_LIB(resolv, hstrerror, ,
 197         [AC_DEFINE(NO_HSTRERROR, 1,
 198              [Define if you have no native hstrerror() function.])]))
 199 HSTRERROR_LIBS=$LIBS
 200 AC_SUBST(HSTRERROR_LIBS)
 201 LIBS="$save_libs"
 202
 203 dnl used in gst-libs/gst/pbutils and associated unit test
 204 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 205
 206 dnl ffmpegcolorspace includes _stdint.h
 207 dnl also, Windows does not have long long
 208 AX_CREATE_STDINT_H
 209
 210 dnl *** checks for functions ***
 211 AC_CHECK_FUNCS([localtime_r gmtime_r])
 212
 213 dnl *** checks for types/defines ***
 214
 215 dnl Check for FIONREAD ioctl declaration
 216 dnl used in gst/tcp
 217 GST_CHECK_FIONREAD
 218
 219 dnl *** checks for structures ***
 220
 221 dnl *** checks for compiler characteristics ***
 222
 223 dnl make sure we can use "inline" from C code
 224 AC_C_INLINE
 225
 226 dnl *** checks for library functions ***
 227
 228 dnl check for fseeko()
 229 AC_FUNC_FSEEKO
 230
 231 dnl Check for fast float to int casting as defined in C99
 232 dnl used in gst-libs/gst/floatcast/floatcast.h
 233 save_libs=$LIBS
 234 LIBS="$LIBS $LIBM"
 235 AC_C99_FUNC_LRINT
 236 AC_C99_FUNC_LRINTF
 237 LIBS=$save_libs
 238
 239 dnl Check for a way to display the function name in debug output
 240 AG_GST_CHECK_FUNCTION
 241
 242 dnl *** checks for dependency libraries ***
 243
 244 dnl GLib is required
 245 AG_GST_GLIB_CHECK([2.6])
 246
 247 dnl liboil is required
 248 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 249 if test "x$HAVE_LIBOIL" != "xyes"; then
 250   AC_ERROR([liboil-0.3.8 or later is required])
 251 fi
 252
 253 dnl checks for gstreamer
 254 dnl uninstalled is selected preferentially -- see pkg-config(1)
 255 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 256 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 257 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 258 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 259 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 260 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 261
 262 dnl Check for documentation xrefs
 263 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 264 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 265 AC_SUBST(GLIB_PREFIX)
 266 AC_SUBST(GST_PREFIX)
 267
 268 dnl GTK is optional and used in examples
 269 HAVE_GTK=NO
 270 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 271 if test "x$HAVE_GTK_22" = "xyes"; then
 272   HAVE_GTK=yes
 273   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 274   AC_SUBST(GTK_VERSION)
 275   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 276   AC_SUBST(GTK_BASE_DIR)
 277 else
 278   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 279 fi
 280 if test "x$HAVE_GTK_20" = "xyes"; then
 281   HAVE_GTK=yes
 282 fi
 283 GTK_CFLAGS=$GTK2_CFLAGS
 284 GTK_LIBS=$GTK2_LIBS
 285 AC_SUBST(GTK_LIBS)
 286 AC_SUBST(GTK_CFLAGS)
 287 AC_SUBST(HAVE_GTK)
 288 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 289
 290 dnl *** set variables based on configure arguments ***
 291
 292 dnl set license and copyright notice
 293 GST_LICENSE="LGPL"
 294 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 295 AC_SUBST(GST_LICENSE)
 296
 297 dnl set location of plugin directory
 298 AG_GST_SET_PLUGINDIR
 299
 300 dnl define an ERROR_CFLAGS Makefile variable
 301 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 302
 303 dnl define correct level for debugging messages
 304 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 305
 306 dnl used in examples
 307 AG_GST_DEFAULT_ELEMENTS
 308
 309 dnl *** plug-ins to include ***
 310
 311 dnl these are all the gst plug-ins, compilable without additional libs
 312 AG_GST_CHECK_PLUGIN(adder)
 313 AG_GST_CHECK_PLUGIN(audioconvert)
 314 AG_GST_CHECK_PLUGIN(audiorate)
 315 AG_GST_CHECK_PLUGIN(audioresample)
 316 AG_GST_CHECK_PLUGIN(audiotestsrc)
 317 AG_GST_CHECK_PLUGIN(ffmpegcolorspace)
 318 AG_GST_CHECK_PLUGIN(gdp)
 319 AG_GST_CHECK_PLUGIN(playback)
 320 AG_GST_CHECK_PLUGIN(subparse)
 321 AG_GST_CHECK_PLUGIN(tcp)
 322 AG_GST_CHECK_PLUGIN(typefind)
 323 AG_GST_CHECK_PLUGIN(videotestsrc)
 324 AG_GST_CHECK_PLUGIN(videorate)
 325 AG_GST_CHECK_PLUGIN(videoscale)
 326 AG_GST_CHECK_PLUGIN(volume)
 327
 328 dnl disable plug-ins that require libxml2's HTML support if it is not available
 329 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 330   AG_GST_DISABLE_PLUGIN(subparse)
 331 fi
 332
 333 dnl disable plug-ins that require sys/socket.h if it is not available
 334 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 335   AG_GST_DISABLE_PLUGIN(tcp)
 336 fi
 337
 338 dnl *** sys plug-ins ***
 339
 340 echo
 341 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 342 echo
 343
 344 dnl *** X11 ***
 345 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 346 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 347                   [ximagesink], [
 348   AC_PATH_XTRA
 349   ac_cflags_save="$CFLAGS"
 350   ac_cppflags_save="$CPPFLAGS"
 351   CFLAGS="$CFLAGS $X_CFLAGS"
 352   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 353
 354   dnl now try to find the HEADER
 355   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 356
 357   if test "x$HAVE_X" = "xno"
 358   then
 359     AC_MSG_NOTICE([cannot find X11 development files])
 360   else
 361     dnl this is much more than we want
 362     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 363     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 364     dnl it does not add the libs; therefore we add them here
 365     X_LIBS="$X_LIBS -lX11"
 366     AC_SUBST(X_CFLAGS)
 367     AC_SUBST(X_LIBS)
 368   fi
 369   AC_SUBST(HAVE_X)
 370   CFLAGS="$ac_cflags_save"
 371   CPPFLAGS="$ac_cppflags_save"
 372 ])
 373
 374 dnl Check for Xv extension
 375 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 376 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 377                   [xvimagesink], [
 378   AG_GST_CHECK_XV
 379 ])
 380
 381 dnl check for X Shm
 382 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 383 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 384   if test x$HAVE_X = xyes; then
 385     AC_CHECK_LIB(Xext, XShmAttach,
 386                  HAVE_XSHM="yes", HAVE_XSHM="no",
 387                  $X_LIBS)
 388     if test "x$HAVE_XSHM" = "xyes"; then
 389       XSHM_LIBS="-lXext"
 390     else
 391       dnl On AIX, it is in XextSam instead, but we still need -lXext
 392       AC_CHECK_LIB(XextSam, XShmAttach,
 393                    HAVE_XSHM="yes", HAVE_XSHM="no",
 394                    $X_LIBS)
 395       if test "x$HAVE_XSHM" = "xyes"; then
 396         XSHM_LIBS="-lXext -lXextSam"
 397       fi
 398     fi
 399   fi
 400 ], , [
 401   AC_SUBST(HAVE_XSHM)
 402   AC_SUBST(XSHM_LIBS)
 403 ])
 404
 405 dnl v4l/v4l2 checks have been moved down because they require X
 406
 407 dnl *** Video 4 Linux ***
 408 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 409 dnl renamed to GST_V4L in accordance with V4L2 below
 410 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 411 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 412   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 413 #include <sys/types.h>
 414 #define _LINUX_TIME_H
 415 #define __user
 416 #include <linux/videodev.h>
 417   ])
 418
 419   dnl we can build v4l without Xv, but then we won't have XOverlay support
 420   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 421   then
 422     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 423     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 424   fi
 425 ])
 426
 427 dnl *** ext plug-ins ***
 428 dnl keep this list sorted alphabetically !
 429
 430 if test "x$BUILD_EXTERNAL" = "xyes"; then
 431
 432 echo
 433 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 434 echo
 435
 436 dnl *** alsa ***
 437 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 438 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 439   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 440     HAVE_ALSA="yes"
 441     AC_SUBST(ALSA_CFLAGS)
 442     AC_SUBST(ALSA_LIBS)
 443   ], [
 444     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 445   ])
 446 ])
 447
 448 dnl *** CDParanoia ***
 449 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 450 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 451   AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 452                       cdda_open, -lm,
 453                       cdda_interface.h,
 454                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 455                       HEADER_DIR="no"
 456                       FOUND_CDPARANOIA="yes")
 457   if test "x$FOUND_CDPARANOIA" != "xyes";
 458   then
 459     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 460                         cdda_open, -lm,
 461                         cdda/cdda_interface.h,
 462                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 463                         HEADER_DIR="yes"
 464                         FOUND_CDPARANOIA="yes")
 465   fi
 466   if test "x$HEADER_DIR" = "xyes";
 467   then
 468     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 469                        defined if cdda headers are in a cdda/ directory)
 470   fi
 471   AC_SUBST(CDPARANOIA_LIBS)
 472 ])
 473 dnl FIXME : add second check somehow if that is necessary
 474 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 475 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 476
 477 dnl *** GNOME VFS ***
 478 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 479 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 480   AG_GST_PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0)
 481 ])
 482
 483 dnl *** libgio ***
 484 USE_GIO=$BUILD_EXPERIMENTAL
 485 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 486 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 487   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.15.2, HAVE_GIO="yes", [
 488     HAVE_GIO="no"
 489     AC_MSG_RESULT(no)
 490   ])
 491   AC_SUBST(GIO_CFLAGS)
 492   AC_SUBST(GIO_LIBS)
 493   AC_SUBST(GIO_LDFLAGS)
 494 ])
 495
 496 dnl *** libvisual ***
 497 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 498 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 499   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 500   if test $HAVE_LIBVISUAL = no
 501   then
 502     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 503   fi
 504 ])
 505
 506 dnl *** ogg ***
 507 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 508 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 509   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 510   if test $HAVE_OGG = no
 511   then
 512     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 513     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 514   fi
 515 ])
 516
 517 dnl *** pango ***
 518 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 519 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 520   AG_GST_PKG_CHECK_MODULES(PANGO, pango pangoft2)
 521 ])
 522
 523 dnl *** theora ***
 524 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 525 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 526   dnl this check will work as long as theora uses 1.0.x or similar for the
 527   dnl first post-alpha release and not just 1.0
 528   AG_GST_PKG_CHECK_MODULES(THEORA, theora >= 1.0alpha5)
 529 ])
 530
 531 dnl *** vorbis ***
 532 dnl AM_PATH_VORBIS only takes two options
 533 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 534 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 535   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 536   if test $HAVE_VORBIS = no
 537   then
 538     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 539     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 540   fi
 541 ])
 542
 543 if test "x$HAVE_VORBIS" = "xyes"; then
 544   ac_cflags_save="$CFLAGS"
 545   AC_COMPILE_IFELSE(
 546     AC_LANG_PROGRAM([
 547 #include <vorbis/codec.h>
 548                      ],[
 549 vorbis_dsp_state *v;
 550
 551 vorbis_synthesis_restart (v);
 552                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 553   if test "x$HAVE_VSR" = "xyes"; then
 554     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 555                        [defined if vorbis_synthesis_restart is present])
 556   fi
 557   CFLAGS="$ac_cflags_save"
 558 fi
 559
 560 else
 561
 562 dnl not building plugins with external dependencies,
 563 dnl but we still need to set the conditionals
 564 AM_CONDITIONAL(USE_ALSA, false)
 565 AM_CONDITIONAL(USE_CDPARANOIA, false)
 566 AM_CONDITIONAL(USE_GNOME_VFS, false)
 567 AM_CONDITIONAL(USE_GIO, false)
 568 AM_CONDITIONAL(USE_LIBVISUAL, false)
 569 AM_CONDITIONAL(USE_OGG, false)
 570 AM_CONDITIONAL(USE_PANGO, false)
 571 AM_CONDITIONAL(USE_THEORA, false)
 572 AM_CONDITIONAL(USE_VORBIS, false)
 573
 574 fi dnl of EXT plugins
 575
 576 dnl seeking needs freetype, so check for it here
 577 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 578   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 579 ])
 580 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 581 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 582 AC_SUBST(FT2_CFLAGS)
 583 AC_SUBST(FT2_LIBS)
 584
 585 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 586
 587 dnl Overview:
 588 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 589 dnl GST_*:              flags shared by built objects to link against GStreamer
 590 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 591 dnl                          (compare to other modules) or for i18n
 592 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 593 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 594 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 595 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 596
 597 dnl GST_OPTION_CFLAGS
 598 if test "x$USE_DEBUG" = xyes; then
 599    PROFILE_CFLAGS="-g"
 600 fi
 601 AC_SUBST(PROFILE_CFLAGS)
 602
 603 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 604   dnl Define _only_ during CVS (not pre-releases or releases)
 605   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 606 else
 607   DEPRECATED_CFLAGS=""
 608 fi
 609 AC_SUBST(DEPRECATED_CFLAGS)
 610
 611 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 612 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 613 AC_SUBST(GST_OPTION_CFLAGS)
 614
 615 dnl our libraries need to be versioned correctly
 616 AC_SUBST(GST_LT_LDFLAGS)
 617
 618 dnl GST_PLUGINS_BASE_CFLAGS
 619 dnl prefer internal headers to already installed ones
 620 dnl also add builddir include for enumtypes and marshal
 621 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 622 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 623
 624 dnl FIXME: do we want to rename to GST_ALL_* ?
 625 dnl add GST_OPTION_CFLAGS, but overridable
 626 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 627 AC_SUBST(GST_CFLAGS)
 628 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 629 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 630 AC_SUBST(GST_LIBS)
 631
 632 dnl LDFLAGS really should only contain flags, not libs - they get added before
 633 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 634 GST_ALL_LDFLAGS="-no-undefined"
 635 AC_SUBST(GST_ALL_LDFLAGS)
 636
 637 dnl GST_LIB_LDFLAGS
 638 dnl linker flags shared by all libraries
 639 dnl LDFLAGS modifier defining exported symbols from built libraries
 640 dnl (export _gst_foo but not __gst_foo)
 641 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 642 AC_SUBST(GST_LIB_LDFLAGS)
 643
 644 dnl this really should only contain flags, not libs - they get added before
 645 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 646 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 647 AC_SUBST(GST_PLUGIN_LDFLAGS)
 648
 649 dnl *** output files ***
 650
 651 AC_CONFIG_FILES(
 652 Makefile
 653 gst-plugins-base.spec
 654 gst/Makefile
 655 gst/adder/Makefile
 656 gst/audioconvert/Makefile
 657 gst/audiorate/Makefile
 658 gst/audioresample/Makefile
 659 gst/audiotestsrc/Makefile
 660 gst/ffmpegcolorspace/Makefile
 661 gst/gdp/Makefile
 662 gst/playback/Makefile
 663 gst/subparse/Makefile
 664 gst/tcp/Makefile
 665 gst/typefind/Makefile
 666 gst/videotestsrc/Makefile
 667 gst/videorate/Makefile
 668 gst/videoscale/Makefile
 669 gst/volume/Makefile
 670 sys/Makefile
 671 sys/ximage/Makefile
 672 sys/xvimage/Makefile
 673 sys/v4l/Makefile
 674 ext/Makefile
 675 ext/alsa/Makefile
 676 ext/cdparanoia/Makefile
 677 ext/gnomevfs/Makefile
 678 ext/gio/Makefile
 679 ext/libvisual/Makefile
 680 ext/ogg/Makefile
 681 ext/pango/Makefile
 682 ext/theora/Makefile
 683 ext/vorbis/Makefile
 684 gst-libs/Makefile
 685 gst-libs/gst/Makefile
 686 gst-libs/gst/audio/Makefile
 687 gst-libs/gst/cdda/Makefile
 688 gst-libs/gst/fft/Makefile
 689 gst-libs/gst/floatcast/Makefile
 690 gst-libs/gst/interfaces/Makefile
 691 gst-libs/gst/netbuffer/Makefile
 692 gst-libs/gst/riff/Makefile
 693 gst-libs/gst/rtp/Makefile
 694 gst-libs/gst/rtsp/Makefile
 695 gst-libs/gst/sdp/Makefile
 696 gst-libs/gst/tag/Makefile
 697 gst-libs/gst/pbutils/Makefile
 698 gst-libs/gst/video/Makefile
 699 tools/Makefile
 700 win32/common/config.h
 701 pkgconfig/Makefile
 702 pkgconfig/gstreamer-audio.pc
 703 pkgconfig/gstreamer-audio-uninstalled.pc
 704 pkgconfig/gstreamer-cdda.pc
 705 pkgconfig/gstreamer-cdda-uninstalled.pc
 706 pkgconfig/gstreamer-fft.pc
 707 pkgconfig/gstreamer-fft-uninstalled.pc
 708 pkgconfig/gstreamer-floatcast.pc
 709 pkgconfig/gstreamer-floatcast-uninstalled.pc
 710 pkgconfig/gstreamer-interfaces.pc
 711 pkgconfig/gstreamer-interfaces-uninstalled.pc
 712 pkgconfig/gstreamer-netbuffer.pc
 713 pkgconfig/gstreamer-netbuffer-uninstalled.pc
 714 pkgconfig/gstreamer-pbutils.pc
 715 pkgconfig/gstreamer-pbutils-uninstalled.pc
 716 pkgconfig/gstreamer-riff.pc
 717 pkgconfig/gstreamer-riff-uninstalled.pc
 718 pkgconfig/gstreamer-rtp.pc
 719 pkgconfig/gstreamer-rtp-uninstalled.pc
 720 pkgconfig/gstreamer-rtsp.pc
 721 pkgconfig/gstreamer-rtsp-uninstalled.pc
 722 pkgconfig/gstreamer-sdp.pc
 723 pkgconfig/gstreamer-sdp-uninstalled.pc
 724 pkgconfig/gstreamer-tag.pc
 725 pkgconfig/gstreamer-tag-uninstalled.pc
 726 pkgconfig/gstreamer-video.pc
 727 pkgconfig/gstreamer-video-uninstalled.pc
 728 pkgconfig/gstreamer-plugins-base.pc
 729 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 730 tests/Makefile
 731 tests/check/Makefile
 732 tests/examples/Makefile
 733 tests/examples/dynamic/Makefile
 734 tests/examples/seek/Makefile
 735 tests/examples/volume/Makefile
 736 tests/examples/snapshot/Makefile
 737 tests/icles/Makefile
 738 docs/Makefile
 739 docs/design/Makefile
 740 docs/libs/Makefile
 741 docs/plugins/Makefile
 742 docs/version.entities
 743 po/Makefile.in
 744 common/Makefile
 745 common/m4/Makefile
 746 m4/Makefile
 747 )
 748 AC_OUTPUT
 749
 750 AG_GST_OUTPUT_PLUGINS