configure.ac

   1 #  Copyright 2005 Adam Jackson.
   2 #
   3 #  Permission is hereby granted, free of charge, to any person obtaining a
   4 #  copy of this software and associated documentation files (the "Software"),
   5 #  to deal in the Software without restriction, including without limitation
   6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
   7 #  license, and/or sell copies of the Software, and to permit persons to whom
   8 #  the Software is furnished to do so, subject to the following conditions:
   9 #
  10 #  The above copyright notice and this permission notice (including the next
  11 #  paragraph) shall be included in all copies or substantial portions of the
  12 #  Software.
  13 #
  14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  20
  21 AC_PREREQ(2.57)
  22 AC_INIT([libdrm], 2.4.0, [dri-devel@lists.sourceforge.net], libdrm)
  23 AC_CONFIG_SRCDIR([Makefile.am])
  24 AM_INIT_AUTOMAKE([dist-bzip2])
  25
  26 AM_CONFIG_HEADER([libdrm/config.h])
  27
  28 AC_DISABLE_STATIC
  29 AC_PROG_LIBTOOL
  30 AC_PROG_CC
  31
  32 AC_HEADER_STDC
  33 AC_SYS_LARGEFILE
  34
  35 pkgconfigdir=${libdir}/pkgconfig
  36 AC_SUBST(pkgconfigdir)
  37 AC_ARG_ENABLE(udev,     AS_HELP_STRING([--enable-udev],
  38                                 [Enable support for using udev instead of mknod (default: disabled)]),
  39                                 [UDEV=$enableval], [UDEV=no])
  40
  41
  42 dnl ===========================================================================
  43 dnl check compiler flags
  44 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
  45   AC_MSG_CHECKING([whether $CC supports $1])
  46
  47   libdrm_save_CFLAGS="$CFLAGS"
  48   CFLAGS="$CFLAGS $1"
  49
  50   AC_COMPILE_IFELSE([ ], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
  51   CFLAGS="$libdrm_save_CFLAGS"
  52
  53   if test "x$libdrm_cc_flag" = "xyes"; then
  54     ifelse([$2], , :, [$2])
  55   else
  56     ifelse([$3], , :, [$3])
  57   fi
  58   AC_MSG_RESULT([$libdrm_cc_flag])
  59 ])
  60
  61 dnl Use lots of warning flags with with gcc and compatible compilers
  62
  63 dnl Note: if you change the following variable, the cache is automatically
  64 dnl skipped and all flags rechecked.  So there's no need to do anything
  65 dnl else.  If for any reason you need to force a recheck, just change
  66 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
  67
  68 MAYBE_WARN="-Wall -Wextra \
  69 -Wsign-compare -Werror-implicit-function-declaration \
  70 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
  71 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
  72 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
  73 -Wstrict-aliasing=2 -Winit-self -Wunsafe-loop-optimizations \
  74 -Wdeclaration-after-statement -Wold-style-definition \
  75 -Wno-missing-field-initializers -Wno-unused-parameter \
  76 -Wno-attributes -Wno-long-long -Winline"
  77
  78 # invalidate cached value if MAYBE_WARN has changed
  79 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
  80         unset libdrm_cv_warn_cflags
  81 fi
  82 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
  83         echo
  84         WARN_CFLAGS=""
  85
  86         # Some warning options are not supported by all versions of
  87         # gcc, so test all desired options against the current
  88         # compiler.
  89         #
  90         # Note that there are some order dependencies
  91         # here. Specifically, an option that disables a warning will
  92         # have no net effect if a later option then enables that
  93         # warnings, (perhaps implicitly). So we put some grouped
  94         # options (-Wall and -Wextra) up front and the -Wno options
  95         # last.
  96
  97         for W in $MAYBE_WARN; do
  98                 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
  99         done
 100
 101         libdrm_cv_warn_cflags=$WARN_CFLAGS
 102         libdrm_cv_warn_maybe=$MAYBE_WARN
 103
 104         AC_MSG_CHECKING([which warning flags were supported])])
 105 WARN_CFLAGS="$libdrm_cv_warn_cflags"
 106
 107 if test "x$UDEV" = xyes; then
 108         AC_DEFINE(UDEV, 1, [Have UDEV support])
 109 fi
 110
 111 AC_SUBST(WARN_CFLAGS)
 112 AC_OUTPUT([
 113         Makefile
 114         libdrm/Makefile
 115         libdrm/intel/Makefile
 116         shared-core/Makefile
 117         tests/Makefile
 118         libdrm.pc])