configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # in easier to understand terms:
  24 #
  25 # <mclasen> on the stable branch, interface age == micro
  26 # <mclasen> on the unstable (ie master), interface age = 0
  27
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [31])
  30 m4_define([glib_micro_version], [0])
  31 m4_define([glib_interface_age], [0])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_HEADER([config.h])
  56 AC_CONFIG_SRCDIR([glib/glib.h])
  57 AC_CONFIG_MACRO_DIR([m4macros])
  58
  59 # Save this value here, since automake will set cflags later
  60 cflags_set=${CFLAGS+set}
  61
  62 AM_INIT_AUTOMAKE([1.11 no-define no-dist-gzip dist-xz tar-ustar])
  63 AM_MAINTAINER_MODE([enable])
  64
  65 # Support silent build rules. Disable
  66 # by either passing --disable-silent-rules to configure or passing V=1
  67 # to make
  68 AM_SILENT_RULES([yes])
  69
  70 GLIB_MAJOR_VERSION=glib_major_version
  71 GLIB_MINOR_VERSION=glib_minor_version
  72 GLIB_MICRO_VERSION=glib_micro_version
  73 GLIB_INTERFACE_AGE=glib_interface_age
  74 GLIB_BINARY_AGE=glib_binary_age
  75 GLIB_VERSION=glib_version
  76
  77 AC_SUBST(GLIB_MAJOR_VERSION)
  78 AC_SUBST(GLIB_MINOR_VERSION)
  79 AC_SUBST(GLIB_MICRO_VERSION)
  80 AC_SUBST(GLIB_VERSION)
  81 AC_SUBST(GLIB_INTERFACE_AGE)
  82 AC_SUBST(GLIB_BINARY_AGE)
  83
  84 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  85           [Define to the GLIB major version])
  86 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  87           [Define to the GLIB minor version])
  88 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  89           [Define to the GLIB micro version])
  90 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  91           [Define to the GLIB interface age])
  92 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  93           [Define to the GLIB binary age])
  94
  95 # libtool versioning
  96 LT_RELEASE=glib_lt_release
  97 LT_CURRENT=glib_lt_current
  98 LT_REVISION=glib_lt_revision
  99 LT_AGE=glib_lt_age
 100 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 101 AC_SUBST(LT_RELEASE)
 102 AC_SUBST(LT_CURRENT)
 103 AC_SUBST(LT_REVISION)
 104 AC_SUBST(LT_AGE)
 105 AC_SUBST(LT_CURRENT_MINUS_AGE)
 106
 107 dnl Checks for programs.
 108 AC_PROG_CC
 109 AC_PROG_CPP
 110
 111 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 112
 113 AC_CANONICAL_HOST
 114
 115 AC_MSG_CHECKING([for the BeOS])
 116 case $host in
 117   *-*-beos*)
 118     glib_native_beos="yes"
 119     ;;
 120   *)
 121     glib_native_beos="no"
 122     ;;
 123 esac
 124 AC_MSG_RESULT([$glib_native_beos])
 125
 126 dnl
 127
 128 AC_MSG_CHECKING([for Win32])
 129 LIB_EXE_MACHINE_FLAG=X86
 130 case "$host" in
 131   *-*-mingw*)
 132     glib_native_win32=yes
 133     glib_pid_type='void *'
 134     glib_cv_stack_grows=no
 135     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 136     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 137     # (Sorry, I don't know exactly what is the problem, but it is related to
 138     # floating point formatting and decimal point vs. comma.)
 139     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 140     # rigorous enough to notice, though.
 141     # So preset the autoconf cache variables.
 142     ac_cv_func_vsnprintf_c99=no
 143     ac_cv_func_snprintf_c99=no
 144     case "$host" in
 145     x86_64-*-*)
 146       LIB_EXE_MACHINE_FLAG=X64
 147       ;;
 148     esac
 149     ;;
 150   *)
 151     glib_native_win32=no
 152     glib_pid_type=int
 153     ;;
 154 esac
 155 case $host in
 156   *-*-linux*)
 157     glib_os_linux=yes
 158     ;;
 159 esac
 160
 161 AC_MSG_RESULT([$glib_native_win32])
 162
 163 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 164
 165 glib_have_carbon=no
 166 AC_MSG_CHECKING([for Mac OS X Carbon support])
 167 AC_TRY_CPP([
 168 #include <Carbon/Carbon.h>
 169 #include <CoreServices/CoreServices.h>
 170 ], glib_have_carbon=yes)
 171
 172 AC_MSG_RESULT([$glib_have_carbon])
 173
 174 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 175 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 176 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 177 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 178 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 179
 180 if test "$glib_native_win32" = "yes"; then
 181   AC_CHECK_TOOL(WINDRES, windres, no)
 182   if test "$WINDRES" = no; then
 183     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 184   fi
 185   AC_CHECK_TOOL(NM, nm, no)
 186   if test "$NM" = no; then
 187     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 188   fi
 189   AC_CHECK_TOOL(RANLIB, ranlib, :)
 190   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 191 fi
 192 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 193
 194 if test "$glib_native_win32" != yes; then
 195     # libtool option to control which symbols are exported
 196     # right now, symbols starting with _ are not exported
 197     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 198 else
 199     # We currently use .def files on Windows
 200     LIBTOOL_EXPORT_OPTIONS=
 201 fi
 202 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 203
 204 if test "x$glib_have_carbon" = "xyes"; then
 205   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 206   LDFLAGS="$LDFLAGS -framework Carbon"
 207 fi
 208
 209 gl_GLIBC21
 210 if test "x$GLIBC21" = "xyes"; then
 211   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 212 fi
 213
 214 dnl declare --enable-* args and collect ac_help strings
 215 AC_ARG_ENABLE(debug,
 216               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 217                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 218               enable_debug=glib_debug_default)
 219
 220 AC_ARG_ENABLE(gc_friendly,
 221               [AC_HELP_STRING([--enable-gc-friendly],
 222                               [turn on garbage collector friendliness [default=no]])],,
 223               [enable_gc_friendly=no])
 224 AC_ARG_ENABLE(mem_pools,
 225               [AC_HELP_STRING([--disable-mem-pools],
 226                               [disable all glib memory pools])],,
 227               [disable_mem_pools=no])
 228 AC_ARG_ENABLE(rebuilds,
 229               [AC_HELP_STRING([--disable-rebuilds],
 230                               [disable all source autogeneration rules])],,
 231               [enable_rebuilds=yes])
 232
 233 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 234 if test "x$enable_gc_friendly" = "xyes"; then
 235   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 236   AC_MSG_RESULT([yes])
 237 else
 238   AC_MSG_RESULT([no])
 239 fi
 240
 241 AC_MSG_CHECKING([whether to disable memory pools])
 242 if test "x$disable_mem_pools" = "xno"; then
 243   AC_MSG_RESULT([no])
 244 else
 245   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 246   AC_SUBST(DISABLE_MEM_POOLS)
 247   AC_MSG_RESULT([yes])
 248 fi
 249
 250 dnl location to install runtime libraries, e.g. ../../lib to install
 251 dnl to /lib if libdir is /usr/lib
 252 AC_ARG_WITH(runtime-libdir,
 253            [AC_HELP_STRING([--with-runtime-libdir=RELPATH],
 254                            [Install runtime libraries relative to libdir])],
 255            [],
 256            [with_runtime_libdir=""])
 257 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 258 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 259 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 260 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 261 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 262
 263 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 264 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 265 AC_LANG_SAVE
 266 AC_LANG_CPLUSPLUS
 267 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 268 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 269 AC_LANG_RESTORE
 270
 271 AM_PROG_CC_STDC
 272 AM_PROG_CC_C_O
 273 AC_PROG_INSTALL
 274
 275 AC_SYS_LARGEFILE
 276
 277 PKG_PROG_PKG_CONFIG(0.16)
 278
 279 if test "x$enable_debug" = "xyes"; then
 280   if test x$cflags_set != xset ; then
 281       case " $CFLAGS " in
 282       *[[\ \    ]]-g[[\ \       ]]*) ;;
 283       *) CFLAGS="$CFLAGS -g" ;;
 284       esac
 285   fi
 286
 287   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 288 else
 289   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 290
 291   if test "x$enable_debug" = "xno"; then
 292     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 293   fi
 294 fi
 295
 296 # Ensure MSVC-compatible struct packing convention is used when
 297 # compiling for Win32 with gcc.
 298 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 299 # gcc2 uses "-fnative-struct".
 300 if test x"$glib_native_win32" = xyes; then
 301   if test x"$GCC" = xyes; then
 302     msnative_struct=''
 303     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 304     if test -z "$ac_cv_prog_CC"; then
 305       our_gcc="$CC"
 306     else
 307       our_gcc="$ac_cv_prog_CC"
 308     fi
 309     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 310       2.)
 311         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 312           msnative_struct='-fnative-struct'
 313         fi
 314         ;;
 315       *)
 316         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 317           msnative_struct='-mms-bitfields'
 318         fi
 319         ;;
 320     esac
 321     if test x"$msnative_struct" = x ; then
 322       AC_MSG_RESULT([no way])
 323       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 324     else
 325       CFLAGS="$CFLAGS $msnative_struct"
 326       AC_MSG_RESULT([${msnative_struct}])
 327     fi
 328   fi
 329 fi
 330 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 331 AC_SUBST(GLIB_EXTRA_CFLAGS)
 332
 333 AC_EXEEXT
 334
 335 # define a MAINT-like variable REBUILD which is set if Perl
 336 # and awk are found, so autogenerated sources can be rebuilt
 337 AC_PROG_AWK
 338 AC_CHECK_PROGS(PERL, [perl5 perl])
 339 # We would like indent, but don't require it.
 340 AC_CHECK_PROG(INDENT, indent, indent)
 341 REBUILD=\#
 342 if test "x$enable_rebuilds" = "xyes" && \
 343      test -n "$PERL" && \
 344      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 345      test -n "$AWK" ; then
 346   REBUILD=
 347 fi
 348 AC_SUBST(REBUILD)
 349
 350 # Need full path to Perl for glib-mkenums
 351 #
 352 if test "x$PERL" != x ; then
 353   AC_PATH_PROG(PERL_PATH, [$PERL])
 354 fi
 355 if test "x$PERL_PATH" = x ; then
 356   PERL_PATH="/usr/bin/env perl"
 357 fi
 358 AC_SUBST(PERL_PATH)
 359
 360 # Need suitable python path for greport
 361 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 362
 363
 364 dnl ***********************
 365 dnl *** Tests for iconv ***
 366 dnl ***********************
 367 dnl
 368 dnl We do this before the gettext checks, to avoid distortion
 369
 370 dnl On Windows we use a native implementation
 371
 372 if test x"$glib_native_win32" = xyes; then
 373   with_libiconv=native
 374 else
 375   AC_ARG_WITH(libiconv,
 376               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 377                               [use the libiconv library])],,
 378               [with_libiconv=maybe])
 379
 380   found_iconv=no
 381   case $with_libiconv in
 382     maybe)
 383       # Check in the C library first
 384       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 385       # Check if we have GNU libiconv
 386       if test $found_iconv = "no"; then
 387         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 388       fi
 389       # Check if we have a iconv in -liconv, possibly from vendor
 390       if test $found_iconv = "no"; then
 391         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 392       fi
 393       ;;
 394     no)
 395       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 396       ;;
 397     gnu|yes)
 398       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 399       ;;
 400     native)
 401       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 402       ;;
 403   esac
 404
 405   if test "x$found_iconv" = "xno" ; then
 406      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 407   fi
 408 fi
 409
 410 AC_ARG_ENABLE(iconv-cache,
 411               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 412                               [cache iconv descriptors [default=auto]])],,
 413               [enable_iconv_cache=auto])
 414
 415 AC_MSG_CHECKING([whether to cache iconv descriptors])
 416 case $enable_iconv_cache in
 417   auto)
 418     if test $ac_cv_gnu_library_2_1 = yes; then
 419       enable_iconv_cache=no
 420     else
 421       enable_iconv_cache=yes
 422     fi
 423   ;;
 424   yes|no)
 425   ;;
 426   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 427   ;;
 428 esac
 429
 430 if test $enable_iconv_cache = yes; then
 431    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 432 fi
 433
 434 AC_MSG_RESULT($enable_iconv_cache)
 435
 436
 437 dnl
 438 dnl zlib support
 439 dnl
 440 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 441 if test "x$found_zlib" = "xno" ; then
 442   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 443   if test "x$found_zlib" = "xno" ; then
 444     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 445   fi
 446   ZLIB_LIBS='-lz'
 447   AC_SUBST(ZLIB_LIBS)
 448 fi
 449
 450 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 451 AC_SUBST(LIBFFI_CFLAGS)
 452 AC_SUBST(LIBFFI_LIBS)
 453
 454 dnl
 455 dnl gettext support
 456 dnl
 457
 458 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 459 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 460 GLIB_GNU_GETTEXT
 461
 462 if test "$gt_cv_have_gettext" != "yes" ; then
 463   AC_MSG_ERROR([
 464 *** You must have either have gettext support in your C library, or use the
 465 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 466 ])
 467 fi
 468
 469 LIBS="$INTLLIBS $LIBS"
 470
 471 GETTEXT_PACKAGE=glib20
 472 AC_SUBST(GETTEXT_PACKAGE)
 473 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 474   [Define the gettext package to be used])
 475
 476 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 477
 478 dnl
 479 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 480 dnl
 481
 482 if test x"$glib_native_win32" != xyes; then
 483   if test x$with_libiconv != xno ; then
 484     case " $INTLLIBS " in
 485     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 486     *) ICONV_LIBS="-liconv" ;;
 487     esac
 488   fi
 489 fi
 490 AC_SUBST(ICONV_LIBS)
 491
 492 case $with_libiconv in
 493   gnu)
 494     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 495     ;;
 496   native)
 497     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 498     ;;
 499 esac
 500
 501 dnl Initialize libtool
 502 LT_PREREQ([2.2])
 503 LT_INIT([disable-static win32-dll])
 504 dnl when using libtool 2.x create libtool early, because it's used in configure
 505 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 506
 507
 508 if test "x$GCC" = "xyes"; then
 509   case " $CFLAGS " in
 510   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 511   *) CFLAGS="$CFLAGS -Wall" ;;
 512   esac
 513 fi
 514
 515 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES"
 516
 517 if test "$glib_native_win32" = "yes"; then
 518   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 519     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 520   fi
 521   if test x$enable_static = xyes; then
 522     glib_win32_static_compilation=yes
 523     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 524 #define GOBJECT_STATIC_COMPILATION 1"
 525     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 526   fi
 527 fi
 528 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 529
 530 dnl
 531 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 532 dnl
 533 if test $cross_compiling != yes ; then
 534     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 535     glib_save_LIBS=$LIBS
 536     LIBS="$LIBS -lm"
 537     AC_TRY_RUN([#include <math.h>
 538                  int main (void) { return (log(1) != log(1.)); }],
 539          AC_MSG_RESULT(none needed),
 540          glib_save_CFLAGS=$CFLAGS
 541          CFLAGS="$CFLAGS -std1"
 542          AC_TRY_RUN([#include <math.h>
 543                      int main (void) { return (log(1) != log(1.)); }],
 544              AC_MSG_RESULT(-std1),
 545              AC_MSG_RESULT()
 546              CFLAGS=$glib_save_CFLAGS
 547              AC_MSG_WARN(
 548                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 549          )
 550     )
 551     LIBS=$glib_save_LIBS
 552 fi
 553
 554 dnl NeXTStep cc seems to need this
 555 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 556 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 557   AC_MSG_RESULT(none needed),
 558   glib_save_CFLAGS=$CFLAGS
 559   CFLAGS="$CFLAGS -posix"
 560   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 561     AC_MSG_RESULT(-posix),
 562     AC_MSG_RESULT()
 563     CFLAGS=$glib_save_CFLAGS
 564     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 565
 566 # Checks for header files.
 567 AC_HEADER_STDC
 568
 569 # Checks for library functions.
 570 AC_FUNC_VPRINTF
 571 AC_FUNC_ALLOCA
 572 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2)
 573 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 574
 575 dnl don't use AC_CHECK_FUNCS here, otherwise HAVE_QSORT_R will
 576 dnl be automatically defined, which we don't want to do
 577 dnl until we have checked this function is actually usable
 578 AC_CHECK_FUNC([qsort_r])
 579
 580 # BSD has a qsort_r with wrong argument order
 581 if test x$ac_cv_func_qsort_r = xyes ; then
 582   AC_CACHE_CHECK([if qsort_r uses glibc compatible argument order], glib_cv_have_qsort_r, [
 583   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 584   #define _GNU_SOURCE
 585   #include <stdlib.h>
 586
 587   static int
 588   cmp (const void *a, const void *b, void *c)
 589   {
 590     const int *ia = a;
 591     const int *ib = b;
 592
 593     if (*ia < *ib)
 594       return -1;
 595     else if (*ia > *ib)
 596       return 1;
 597     else
 598       return 0;
 599   }
 600
 601   int
 602   main (int argc, char **argv)
 603   {
 604     int arr[3] = { 1, 2, 0 };
 605     int d = 3;
 606
 607     qsort_r (arr, 3, sizeof (int), cmp, &d);
 608
 609     if (arr[0] == 0 && arr[1] == 1 && arr[2] == 2)
 610       return 0;
 611     else
 612       return 1;
 613   }]])],[glib_cv_have_qsort_r=yes],[glib_cv_have_qsort_r=no])])
 614 fi
 615
 616 if test x$glib_cv_have_qsort_r = xyes ; then
 617   AC_DEFINE(HAVE_QSORT_R, 1, [Define to 1 if you have the 'qsort_r' function])
 618 fi
 619
 620 AC_CHECK_SIZEOF(char)
 621 AC_CHECK_SIZEOF(short)
 622 AC_CHECK_SIZEOF(long)
 623 AC_CHECK_SIZEOF(int)
 624 AC_CHECK_SIZEOF(void *)
 625 AC_CHECK_SIZEOF(long long)
 626 AC_CHECK_SIZEOF(__int64)
 627
 628 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 629   :
 630 else
 631   AC_MSG_ERROR([
 632 *** GLib requires a 64 bit type. You might want to consider
 633 *** using the GNU C compiler.
 634 ])
 635 fi
 636
 637 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 638         # long long is a 64 bit integer.
 639         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 640         AC_CACHE_VAL(glib_cv_long_long_format,[
 641                 for format in ll q I64; do
 642                   AC_TRY_RUN([#include <stdio.h>
 643                         int main()
 644                         {
 645                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 646                           char buffer[1000];
 647                           sprintf (buffer, "%${format}u", a);
 648                           sscanf (buffer, "%${format}u", &b);
 649                           exit (b!=a);
 650                         }
 651                         ],
 652                         [glib_cv_long_long_format=${format}
 653                         break],
 654                         [],[:])
 655                 done])
 656         if test -n "$glib_cv_long_long_format"; then
 657           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 658           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 659           if test x"$glib_cv_long_long_format" = xI64; then
 660             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 661           fi
 662         else
 663           AC_MSG_RESULT(none)
 664         fi
 665 elif test x$ac_cv_sizeof___int64 = x8; then
 666         # __int64 is a 64 bit integer.
 667         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 668         # We know this is MSVCRT.DLL, and what the formats are
 669         glib_cv_long_long_format=I64
 670         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 671         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 672         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 673 fi
 674
 675 dnl long doubles were not used, and a portability problem
 676 dnl AC_C_LONG_DOUBLE
 677 AC_C_CONST
 678
 679 dnl ok, here we try to check whether the systems prototypes for
 680 dnl malloc and friends actually match the prototypes provided
 681 dnl by gmem.h (keep in sync). i currently only know how to check
 682 dnl this reliably with gcc (-Werror), improvements for other
 683 dnl compilers are apprechiated.
 684 SANE_MALLOC_PROTOS=no
 685 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 686 glib_save_CFLAGS=$CFLAGS
 687 if test "x$GCC" = "xyes"; then
 688   CFLAGS="$CFLAGS -Werror"
 689   AC_TRY_COMPILE([#include <stdlib.h>], [
 690     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 691     void* (*my_malloc_p)  (size_t)         = malloc;
 692     void  (*my_free_p)    (void*)          = free;
 693     void* (*my_realloc_p) (void*, size_t)  = realloc;
 694     my_calloc_p = 0;
 695     my_malloc_p = 0;
 696     my_free_p = 0;
 697     my_realloc_p = 0;
 698   ],
 699     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 700       [Define if you have correct malloc prototypes])
 701     SANE_MALLOC_PROTOS=yes)
 702 fi
 703 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 704 CFLAGS=$glib_save_CFLAGS
 705
 706 dnl
 707 dnl check in which direction the stack grows
 708 dnl
 709 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 710         AC_TRY_RUN([
 711         volatile int *a = 0, *b = 0;
 712         void foo (void);
 713         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 714         void foo (void) { volatile int x = 5; b = &x; }
 715         ],
 716         glib_cv_stack_grows=no
 717         ,
 718         glib_cv_stack_grows=yes
 719         ,)
 720 ])
 721
 722 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 723 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 724 dnl actually supported.
 725 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 726         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 727         __inline int foo () { return 0; }
 728         int main () { return foo (); }
 729         ]])],
 730         glib_cv_has__inline=yes
 731         ,
 732         glib_cv_has__inline=no
 733         ,)
 734 ])
 735 case x$glib_cv_has__inline in
 736 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 737 esac
 738 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 739         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 740         __inline__ int foo () { return 0; }
 741         int main () { return foo (); }
 742         ]])],
 743         glib_cv_has__inline__=yes
 744         ,
 745         glib_cv_has__inline__=no
 746         ,)
 747 ])
 748 case x$glib_cv_has__inline__ in
 749 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 750 esac
 751 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 752         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 753         #undef inline
 754         inline int foo () { return 0; }
 755         int main () { return foo (); }
 756         ]])],
 757         glib_cv_hasinline=yes
 758         ,
 759         glib_cv_hasinline=no
 760         ,)
 761 ])
 762 case x$glib_cv_hasinline in
 763 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 764 esac
 765
 766 # if we can use inline functions in headers
 767 AC_MSG_CHECKING(if inline functions in headers work)
 768 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 769 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 770 #  undef inline
 771 #  define inline __inline__
 772 #elif !defined (G_HAVE_INLINE)
 773 #  undef inline
 774 #  if defined (G_HAVE___INLINE__)
 775 #    define inline __inline__
 776 #  elif defined (G_HAVE___INLINE)
 777 #    define inline __inline
 778 #  endif
 779 #endif
 780
 781 int glib_test_func2 (int);
 782
 783 static inline int
 784 glib_test_func1 (void) {
 785   return glib_test_func2 (1);
 786 }
 787
 788 int
 789 main (void) {
 790   int i = 1;
 791 }]])],[g_can_inline=yes],[g_can_inline=no])
 792 AC_MSG_RESULT($g_can_inline)
 793
 794 dnl *** check for working do while(0) macros ***
 795 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 796         AC_TRY_COMPILE([],[
 797         #define STMT_START do
 798         #define STMT_END while(0)
 799         #define STMT_TEST STMT_START { i = 0; } STMT_END
 800         int main(void) { int i = 1; STMT_TEST; return i; }],
 801         [g_cv_support_dowhile_macros=yes],
 802         [g_cv_support_dowhile_macros=no],
 803         [g_cv_support_dowhile_macros=yes])
 804 ])
 805 if test x$g_cv_support_dowhile_macros = xyes; then
 806   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 807 fi
 808
 809 # check for flavours of varargs macros
 810 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 811 AC_TRY_COMPILE([],[
 812 int a(int p1, int p2, int p3);
 813 #define call_a(...) a(1,__VA_ARGS__)
 814 call_a(2,3);
 815 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 816 AC_MSG_RESULT($g_have_iso_c_varargs)
 817
 818 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 819 if test "$CXX" = ""; then
 820 dnl No C++ compiler
 821   g_have_iso_cxx_varargs=no
 822 else
 823   AC_LANG_CPLUSPLUS
 824   AC_TRY_COMPILE([],[
 825 int a(int p1, int p2, int p3);
 826 #define call_a(...) a(1,__VA_ARGS__)
 827 call_a(2,3);
 828 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 829   AC_LANG_C
 830 fi
 831 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 832
 833 AC_MSG_CHECKING(for GNUC varargs macros)
 834 AC_TRY_COMPILE([],[
 835 int a(int p1, int p2, int p3);
 836 #define call_a(params...) a(1,params)
 837 call_a(2,3);
 838 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 839 AC_MSG_RESULT($g_have_gnuc_varargs)
 840
 841 # check for GNUC visibility support
 842 AC_MSG_CHECKING(for GNUC visibility attribute)
 843 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 844 void
 845 __attribute__ ((visibility ("hidden")))
 846      f_hidden (void)
 847 {
 848 }
 849 void
 850 __attribute__ ((visibility ("internal")))
 851      f_internal (void)
 852 {
 853 }
 854 void
 855 __attribute__ ((visibility ("protected")))
 856      f_protected (void)
 857 {
 858 }
 859 void
 860 __attribute__ ((visibility ("default")))
 861      f_default (void)
 862 {
 863 }
 864 int main (int argc, char **argv)
 865 {
 866         f_hidden();
 867         f_internal();
 868         f_protected();
 869         f_default();
 870         return 0;
 871 }
 872 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 873 AC_MSG_RESULT($g_have_gnuc_visibility)
 874 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 875
 876 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 877 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 878 #else
 879 # include "error: this is not Sun Studio."
 880 #endif
 881 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 882 AC_MSG_RESULT($g_have_sunstudio_visibility)
 883 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 884
 885 # check for bytesex stuff
 886 AC_C_BIGENDIAN
 887 if test x$ac_cv_c_bigendian = xuniversal ; then
 888 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 889 #else
 890 #error Not a big endian.
 891 #endif],
 892     ac_cv_c_bigendian=yes
 893     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 894 #else
 895 #error Not a little endian.
 896 #endif],
 897     ac_cv_c_bigendian=no
 898     ,AC_MSG_WARN([Could not determine endianness.])))
 899 fi
 900
 901
 902 # check for header files
 903 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 904 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 905 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 906 AC_CHECK_HEADERS([sys/vfs.h sys/mount.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 907 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h sys/sysctl.h fstab.h])
 908 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 909 AC_CHECK_HEADERS([linux/magic.h])
 910
 911 # check for structure fields
 912 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 913 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 914 #include <sys/stat.h>
 915 #include <unistd.h>
 916 #ifdef HAVE_SYS_STATFS_H
 917 #include <sys/statfs.h>
 918 #endif
 919 #ifdef HAVE_SYS_PARAM_H
 920 #include <sys/param.h>
 921 #endif
 922 #ifdef HAVE_SYS_MOUNT_H
 923 #include <sys/mount.h>
 924 #endif])
 925 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 926 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 927 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 928 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 929
 930 # Checks for libcharset
 931 AM_LANGINFO_CODESET
 932 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 933 AC_CHECK_FUNCS(setlocale)
 934
 935 # check additional type sizes
 936 AC_CHECK_SIZEOF(size_t)
 937
 938 dnl Try to figure out whether gsize, gssize should be long or int
 939 AC_MSG_CHECKING([for the appropriate definition for size_t])
 940
 941 case $ac_cv_sizeof_size_t in
 942   $ac_cv_sizeof_short)
 943       glib_size_type=short
 944       ;;
 945   $ac_cv_sizeof_int)
 946       glib_size_type=int
 947       ;;
 948   $ac_cv_sizeof_long)
 949       glib_size_type=long
 950       ;;
 951   $ac_cv_sizeof_long_long)
 952       glib_size_type='long long'
 953       ;;
 954   $ac_cv_sizeof__int64)
 955       glib_size_type='__int64'
 956       ;;
 957   *)  AC_MSG_ERROR([No type matching size_t in size])
 958       ;;
 959 esac
 960
 961 dnl If int/long are the same size, we see which one produces
 962 dnl warnings when used in the location as size_t. (This matters
 963 dnl on AIX with xlc)
 964 dnl
 965 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 966    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 967   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 968 #if defined(_AIX) && !defined(__GNUC__)
 969 #pragma options langlvl=stdc89
 970 #endif
 971 #include <stddef.h>
 972 int main ()
 973 {
 974   size_t s = 1;
 975   unsigned int *size_int = &s;
 976   return (int)*size_int;
 977 }
 978     ]])],glib_size_type=int,
 979       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 980 #if defined(_AIX) && !defined(__GNUC__)
 981 #pragma options langlvl=stdc89
 982 #endif
 983 #include <stddef.h>
 984 int main ()
 985 {
 986    size_t s = 1;
 987    unsigned long *size_long = &s;
 988    return (int)*size_long;
 989 }
 990         ]])],glib_size_type=long)])
 991 fi
 992
 993 AC_MSG_RESULT(unsigned $glib_size_type)
 994
 995 # Check for some functions
 996 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 997 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid)
 998 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
 999 # Check for high-resolution sleep functions
1000 AC_CHECK_FUNCS(splice)
1001
1002 # To avoid finding a compatibility unusable statfs, which typically
1003 # successfully compiles, but warns to use the newer statvfs interface:
1004 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1005 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1006
1007 AC_MSG_CHECKING([whether to use statfs or statvfs])
1008 # Some systems have both statfs and statvfs, pick the most "native" for these
1009 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1010    [
1011    # on solaris and irix, statfs doesn't even have the f_bavail field
1012    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1013       [ac_cv_func_statfs=no],
1014    # else, at least on linux, statfs is the actual syscall
1015       [ac_cv_func_statvfs=no])
1016    ])
1017
1018 AS_IF([test x$ac_cv_func_statfs = xyes],
1019       [
1020          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1021          AC_MSG_RESULT([statfs])
1022       ],
1023       [test x$ac_cv_func_statvfs = xyes],
1024       [
1025          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1026          AC_MSG_RESULT([statvfs])
1027       ],
1028       [  AC_MSG_RESULT([neither])])
1029
1030 AC_CHECK_HEADERS(crt_externs.h)
1031 AC_CHECK_FUNCS(_NSGetEnviron)
1032
1033 AC_FUNC_VSNPRINTF_C99
1034 AC_FUNC_PRINTF_UNIX98
1035
1036 # Internet address families
1037 if test $glib_native_win32 = yes; then
1038   glib_inet_includes=["
1039 #include <winsock2.h>
1040   "]
1041 else
1042   glib_inet_includes=["
1043 #include <sys/types.h>
1044 #include <sys/socket.h>
1045   "]
1046 fi
1047
1048 glib_failed=false
1049 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1050 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1051 # winsock defines this even though it doesn't support it
1052 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1053 if $glib_failed ; then
1054   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1055 fi
1056
1057 glib_failed=false
1058 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1059 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1060 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1061 if $glib_failed ; then
1062   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1063 fi
1064
1065 AC_CHECK_FUNCS(getprotobyname_r endservent)
1066 AC_CHECK_HEADERS([netdb.h wspiapi.h arpa/nameser_compat.h])
1067
1068 if test $glib_native_win32 = no; then
1069   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1070   NETWORK_LIBS=""
1071   AC_MSG_CHECKING([for res_query])
1072   AC_TRY_LINK([#include <sys/types.h>
1073                #include <netinet/in.h>
1074                #include <arpa/nameser.h>
1075                #include <resolv.h>
1076               ],[
1077                res_query("test", 0, 0, (void *)0, 0);
1078               ],[AC_MSG_RESULT([yes])],
1079               [save_libs="$LIBS"
1080                LIBS="-lresolv $LIBS"
1081                AC_TRY_LINK([#include <sys/types.h>
1082                             #include <netinet/in.h>
1083                             #include <arpa/nameser.h>
1084                             #include <resolv.h>
1085                            ],[
1086                             res_query("test", 0, 0, (void *)0, 0);
1087                            ],[AC_MSG_RESULT([in -lresolv])
1088                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1089                            [LIBS="-lbind $save_libs"
1090                             AC_TRY_LINK([#include <resolv.h>],
1091                                         [res_query("test", 0, 0, (void *)0, 0);],
1092                                         [AC_MSG_RESULT([in -lbind])
1093                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1094                                         [AC_MSG_ERROR(not found)])])
1095                LIBS="$save_libs"])
1096   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1097                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1098                                         [AC_MSG_ERROR(Could not find socket())]))
1099 fi
1100 AC_SUBST(NETWORK_LIBS)
1101
1102 case $host in
1103   *-*-solaris* )
1104      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1105      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1106      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1107      ;;
1108 esac
1109
1110 dnl
1111 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1112 dnl
1113 if test "$ac_cv_func_statfs" = yes ; then
1114   AC_MSG_CHECKING([number of arguments to statfs()])
1115   AC_TRY_COMPILE([#include <unistd.h>
1116   #ifdef HAVE_SYS_PARAM_H
1117   #include <sys/param.h>
1118   #endif
1119   #ifdef HAVE_SYS_VFS_H
1120   #include <sys/vfs.h>
1121   #endif
1122   #ifdef HAVE_SYS_MOUNT_H
1123   #include <sys/mount.h>
1124   #endif
1125   #ifdef HAVE_SYS_STATFS_H
1126   #include <sys/statfs.h>
1127   #endif], [struct statfs st;
1128   statfs(NULL, &st);],[
1129     AC_MSG_RESULT([2])
1130     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1131     AC_TRY_COMPILE([#include <unistd.h>
1132   #ifdef HAVE_SYS_PARAM_H
1133   #include <sys/param.h>
1134   #endif
1135   #ifdef HAVE_SYS_VFS_H
1136   #include <sys/vfs.h>
1137   #endif
1138   #ifdef HAVE_SYS_MOUNT_H
1139   #include <sys/mount.h>
1140   #endif
1141   #ifdef HAVE_SYS_STATFS_H
1142   #include <sys/statfs.h>
1143   #endif], [struct statfs st;
1144   statfs(NULL, &st, sizeof (st), 0);],[
1145       AC_MSG_RESULT([4])
1146       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1147       AC_MSG_RESULT(unknown)
1148       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1149 fi
1150
1151 #
1152 # Check whether to use an included printf
1153 #
1154
1155 AC_ARG_ENABLE(included-printf,
1156               [AC_HELP_STRING([--enable-included-printf],
1157                               [use included printf [default=auto]])],
1158               enable_included_printf="$enableval")
1159
1160 need_included_printf=no
1161 if test "x$enable_included_printf" = "xyes" ; then
1162   need_included_printf=yes
1163 fi
1164 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1165   need_included_printf=yes
1166 fi
1167 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1168   need_included_printf=yes
1169 fi
1170 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1171    test -z "$glib_cv_long_long_format" ; then
1172   need_included_printf=yes
1173 fi
1174
1175 if test "x$enable_included_printf" = "xno" &&
1176    test "x$need_included_printf" = "xyes" ; then
1177   AC_MSG_ERROR([
1178 *** Your C library's printf doesn't appear to have the features that
1179 *** GLib needs, but you specified --enable-included-printf=no.])
1180 fi
1181
1182 enable_included_printf=$need_included_printf
1183
1184 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1185 if test "$enable_included_printf" != "yes" ; then
1186   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1187 else
1188   if test -z "$glib_cv_long_long_format" ; then
1189     glib_cv_long_long_format="ll"
1190   fi
1191   AC_DEFINE(HAVE_VASPRINTF,1)
1192 fi
1193
1194 # Checks needed for gnulib vasnprintf
1195 bh_C_SIGNED
1196 jm_AC_TYPE_LONG_LONG
1197 gt_TYPE_LONGDOUBLE
1198 gt_TYPE_WCHAR_T
1199 gt_TYPE_WINT_T
1200 AC_TYPE_SIZE_T
1201 AC_CHECK_TYPES(ptrdiff_t)
1202 jm_AC_TYPE_INTMAX_T
1203 AC_CHECK_FUNCS([snprintf wcslen])
1204 AC_FUNC_SNPRINTF_C99
1205
1206 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1207 # The check is borrowed from the PERL Configure script.
1208 if test "$ac_cv_func_memmove" != "yes"; then
1209   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1210     glib_cv_working_bcopy,[AC_TRY_RUN([
1211       int main() {
1212         char buf[128], abc[128], *b;
1213         int len, off, align;
1214         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1215         for (align = 7; align >= 0; align--) {
1216           for (len = 36; len; len--) {
1217             b = buf+align; bcopy(abc, b, len);
1218             for (off = 1; off <= len; off++) {
1219               bcopy(b, b+off, len); bcopy(b+off, b, len);
1220                 if (bcmp(b, abc, len)) return(1);
1221             }
1222           }
1223         }
1224         return(0);
1225       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1226
1227   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1228   if test "$glib_cv_working_bcopy" = "yes"; then
1229     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1230   fi
1231 fi
1232
1233 # Check for sys_errlist
1234 AC_MSG_CHECKING(for sys_errlist)
1235 AC_TRY_LINK(, [
1236 extern char *sys_errlist[];
1237 extern int sys_nerr;
1238 sys_errlist[sys_nerr-1][0] = 0;
1239 ], glib_ok=yes, glib_ok=no)
1240 AC_MSG_RESULT($glib_ok)
1241 if test "$glib_ok" = "no"; then
1242     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
1243 fi
1244
1245 # Check for sys_siglist
1246 AC_MSG_CHECKING(for sys_siglist)
1247 AC_TRY_LINK(, [
1248 extern char *sys_siglist[];
1249 exit (sys_siglist[0]);
1250 ], glib_ok=yes, glib_ok=no)
1251 AC_MSG_RESULT($glib_ok)
1252 if test "$glib_ok" = "no"; then
1253     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
1254 fi
1255
1256 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
1257 AC_MSG_CHECKING(for sys_siglist declaration)
1258 AC_TRY_COMPILE([#include <signal.h>], [
1259 strlen (sys_siglist[0]);
1260 ], glib_ok=yes, glib_ok=no)
1261 AC_MSG_RESULT($glib_ok)
1262 if test "$glib_ok" = "no"; then
1263     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
1264 fi
1265
1266 # Check if <sys/select.h> needs to be included for fd_set
1267 AC_MSG_CHECKING([for fd_set])
1268 AC_TRY_COMPILE([#include <sys/types.h>],
1269         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1270 if test "$gtk_ok" = "yes"; then
1271     AC_MSG_RESULT([yes, found in sys/types.h])
1272 else
1273     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1274     if test "$gtk_ok" = "yes"; then
1275         # *** FIXME: give it a different name
1276         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1277         AC_MSG_RESULT([yes, found in sys/select.h])
1278     else
1279         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1280         AC_MSG_RESULT(no)
1281     fi
1282 fi
1283
1284 dnl *** check for sane realloc() ***
1285 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1286         AC_TRY_RUN([#include <stdlib.h>
1287         int main() {
1288           return realloc (0, sizeof (int)) == 0;
1289         }],
1290         [glib_cv_sane_realloc=yes],
1291         [glib_cv_sane_realloc=no],
1292         [glib_cv_sane_realloc=yes])
1293 ])
1294 if test x$glib_cv_sane_realloc = xyes; then
1295   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1296 fi
1297
1298 dnl Check for nl_langinfo and CODESET
1299 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1300         AC_TRY_COMPILE([#include <langinfo.h>],
1301                 [char *codeset = nl_langinfo (CODESET);],
1302                 [glib_cv_langinfo_codeset=yes],
1303                 [glib_cv_langinfo_codeset=no])])
1304 if test x$glib_cv_langinfo_codeset = xyes; then
1305   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1306 fi
1307
1308 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1309 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1310         AC_TRY_COMPILE([#include <langinfo.h>],
1311                 [char *str;
1312                  str = nl_langinfo (PM_STR);
1313                  str = nl_langinfo (D_T_FMT);
1314                  str = nl_langinfo (D_FMT);
1315                  str = nl_langinfo (T_FMT);
1316                  str = nl_langinfo (T_FMT_AMPM);
1317                  str = nl_langinfo (MON_1);
1318                  str = nl_langinfo (ABMON_12);
1319                  str = nl_langinfo (DAY_1);
1320                  str = nl_langinfo (ABDAY_7);],
1321                 [glib_cv_langinfo_time=yes],
1322                 [glib_cv_langinfo_time=no])])
1323 if test x$glib_cv_langinfo_time = xyes; then
1324   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1325 fi
1326
1327 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_WC
1328 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_WC)], glib_cv_langinfo_outdigit,[
1329         AC_TRY_COMPILE([#include <langinfo.h>],
1330                 [char *str;
1331                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_WC);
1332                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_WC);
1333                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_WC);
1334                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_WC);
1335                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_WC);
1336                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_WC);
1337                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_WC);
1338                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_WC);
1339                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_WC);
1340                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_WC);],
1341                 [glib_cv_langinfo_outdigit=yes],
1342                 [glib_cv_langinfo_outdigit=no])])
1343 if test x$glib_cv_langinfo_outdigit = xyes; then
1344   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_WC)])
1345 fi
1346
1347 dnl ****************************************
1348 dnl *** posix_memalign                   ***
1349 dnl ****************************************
1350 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1351 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1352     glib_cv_compliant_posix_memalign=0
1353     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1354         AC_TRY_RUN([
1355                 #define _XOPEN_SOURCE 600
1356                 #include <stdlib.h> /* posix_memalign() should be defined here */
1357                 /* some systems break if #include <malloc.h> used */
1358                 static void test_memalign (size_t boundary, size_t size) {
1359                     void *mem = 0;
1360                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1361                         exit (1);
1362                     else
1363                       free (mem);
1364                 }
1365                 int main() {
1366                     test_memalign (  128,   128 - 2 * sizeof (void*));
1367                     test_memalign (  256,   256 - 2 * sizeof (void*));
1368                     test_memalign (  512,   512 - 2 * sizeof (void*));
1369                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1370                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1371                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1372                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1373                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1374                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1375                     exit (0); /* success */
1376                 }
1377                 ],
1378             [glib_cv_compliant_posix_memalign=1], [], [:])
1379       :
1380     fi
1381     ])
1382 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1383     AC_MSG_RESULT(yes)
1384     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1385 else
1386     AC_MSG_RESULT(no)
1387 fi
1388
1389
1390 dnl ****************************************
1391 dnl *** strlcpy/strlcat                  ***
1392 dnl ****************************************
1393 # Check for strlcpy
1394 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1395 AC_TRY_RUN([#include <stdlib.h>
1396 #include <string.h>
1397 int main() {
1398   char p[10];
1399   (void) strlcpy (p, "hi", 10);
1400   if (strlcat (p, "bye", 0) != 3)
1401     return 1;
1402   return 0;
1403 }], glib_cv_have_strlcpy=yes,
1404     glib_cv_have_strlcpy=no,
1405     glib_cv_have_strlcpy=no)])
1406 if test "$glib_cv_have_strlcpy" = "yes"; then
1407     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1408 fi
1409
1410
1411 dnl **********************
1412 dnl *** va_copy checks ***
1413 dnl **********************
1414 dnl we currently check for all three va_copy possibilities, so we get
1415 dnl all results in config.log for bug reports.
1416 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1417         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1418 #include <stdlib.h>
1419         void f (int i, ...) {
1420         va_list args1, args2;
1421         va_start (args1, i);
1422         va_copy (args2, args1);
1423         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1424           exit (1);
1425         va_end (args1); va_end (args2);
1426         }
1427         int main() {
1428           f (0, 42);
1429           return 0;
1430         }]])],
1431         [glib_cv_va_copy=yes],
1432         [glib_cv_va_copy=no])
1433 ])
1434 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1435         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1436 #include <stdlib.h>
1437         void f (int i, ...) {
1438         va_list args1, args2;
1439         va_start (args1, i);
1440         __va_copy (args2, args1);
1441         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1442           exit (1);
1443         va_end (args1); va_end (args2);
1444         }
1445         int main() {
1446           f (0, 42);
1447           return 0;
1448         }]])],
1449         [glib_cv___va_copy=yes],
1450         [glib_cv___va_copy=no])
1451 ])
1452
1453 if test "x$glib_cv_va_copy" = "xyes"; then
1454   g_va_copy_func=va_copy
1455 else if test "x$glib_cv___va_copy" = "xyes"; then
1456   g_va_copy_func=__va_copy
1457 fi
1458 fi
1459
1460 if test -n "$g_va_copy_func"; then
1461   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1462 fi
1463
1464 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1465         AC_TRY_RUN([#include <stdarg.h>
1466 #include <stdlib.h>
1467         void f (int i, ...) {
1468         va_list args1, args2;
1469         va_start (args1, i);
1470         args2 = args1;
1471         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1472           exit (1);
1473         va_end (args1); va_end (args2);
1474         }
1475         int main() {
1476           f (0, 42);
1477           return 0;
1478         }],
1479         [glib_cv_va_val_copy=yes],
1480         [glib_cv_va_val_copy=no],
1481         [glib_cv_va_val_copy=yes])
1482 ])
1483
1484 if test "x$glib_cv_va_val_copy" = "xno"; then
1485   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1486 fi
1487
1488 dnl ***********************
1489 dnl *** g_module checks ***
1490 dnl ***********************
1491 G_MODULE_LIBS=
1492 G_MODULE_LIBS_EXTRA=
1493 G_MODULE_PLUGIN_LIBS=
1494 if test x"$glib_native_win32" = xyes; then
1495   dnl No use for this on Win32
1496   G_MODULE_LDFLAGS=
1497 else
1498   export SED
1499   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1500 fi
1501 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1502 G_MODULE_NEED_USCORE=0
1503 G_MODULE_BROKEN_RTLD_GLOBAL=0
1504 G_MODULE_HAVE_DLERROR=0
1505 dnl *** force native WIN32 shared lib loader
1506 if test -z "$G_MODULE_IMPL"; then
1507   case "$host" in
1508   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1509   esac
1510 fi
1511 dnl *** force native AIX library loader
1512 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1513 if test -z "$G_MODULE_IMPL"; then
1514   case "$host" in
1515   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1516   esac
1517 fi
1518 dnl *** dlopen() and dlsym() in system libraries
1519 if test -z "$G_MODULE_IMPL"; then
1520         AC_CHECK_FUNC(dlopen,
1521                       [AC_CHECK_FUNC(dlsym,
1522                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1523                       [])
1524 fi
1525 dnl *** load_image (BeOS)
1526 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1527   AC_CHECK_LIB(root, load_image,
1528       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1529       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1530       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1531       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1532       [])
1533 fi
1534 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1535 if test -z "$G_MODULE_IMPL"; then
1536         AC_CHECK_FUNC(NSLinkModule,
1537                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1538                        G_MODULE_NEED_USCORE=1],
1539                       [])
1540 fi
1541 dnl *** dlopen() and dlsym() in libdl
1542 if test -z "$G_MODULE_IMPL"; then
1543         AC_CHECK_LIB(dl, dlopen,
1544                      [AC_CHECK_LIB(dl, dlsym,
1545                                    [G_MODULE_LIBS=-ldl
1546                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1547                      [])
1548 fi
1549 dnl *** shl_load() in libdld (HP-UX)
1550 if test -z "$G_MODULE_IMPL"; then
1551         AC_CHECK_LIB(dld, shl_load,
1552                 [G_MODULE_LIBS=-ldld
1553                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1554                 [])
1555 fi
1556 dnl *** additional checks for G_MODULE_IMPL_DL
1557 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1558         LIBS_orig="$LIBS"
1559         LDFLAGS_orig="$LDFLAGS"
1560         LIBS="$G_MODULE_LIBS $LIBS"
1561         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1562 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1563         echo "void glib_plugin_test(void) { }" > plugin.c
1564         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1565                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1566         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1567                 glib_cv_rtldglobal_broken,[
1568                 AC_TRY_RUN([
1569 #include <dlfcn.h>
1570 #ifndef RTLD_GLOBAL
1571 #  define RTLD_GLOBAL 0
1572 #endif
1573 #ifndef RTLD_LAZY
1574 #  define RTLD_LAZY 0
1575 #endif
1576 int glib_plugin_test;
1577 int main () {
1578     void *handle, *global, *local;
1579     global = &glib_plugin_test;
1580     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1581     if (!handle) return 0;
1582     local = dlsym (handle, "glib_plugin_test");
1583     return global == local;
1584 }                       ],
1585                         [glib_cv_rtldglobal_broken=no],
1586                         [glib_cv_rtldglobal_broken=yes],
1587                         [glib_cv_rtldglobal_broken=no])
1588                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1589                 rmdir .libs 2>/dev/null
1590         ])
1591         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1592                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1593         else
1594                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1595         fi
1596 dnl *** check whether we need preceeding underscores
1597         AC_CACHE_CHECK([for preceeding underscore in symbols],
1598                 glib_cv_uscore,[
1599                 AC_TRY_RUN([#include <dlfcn.h>
1600                 int glib_underscore_test (void) { return 42; }
1601                 int main() {
1602                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1603                   handle = dlopen ((void*)0, 0);
1604                   if (handle) {
1605                     f1 = dlsym (handle, "glib_underscore_test");
1606                     f2 = dlsym (handle, "_glib_underscore_test");
1607                   } return (!f2 || f1);
1608                 }],
1609                         [glib_cv_uscore=yes],
1610                         [glib_cv_uscore=no],
1611                         [])
1612                 rm -f plugin.c plugin.$ac_objext plugin.lo
1613         ])
1614         GLIB_ASSERT_SET(glib_cv_uscore)
1615         if test "x$glib_cv_uscore" = "xyes"; then
1616                 G_MODULE_NEED_USCORE=1
1617         else
1618                 G_MODULE_NEED_USCORE=0
1619         fi
1620
1621         LDFLAGS="$LDFLAGS_orig"
1622 dnl *** check for having dlerror()
1623         AC_CHECK_FUNC(dlerror,
1624                 [G_MODULE_HAVE_DLERROR=1],
1625                 [G_MODULE_HAVE_DLERROR=0])
1626         LIBS="$LIBS_orig"
1627 fi
1628 dnl *** done, have we got an implementation?
1629 if test -z "$G_MODULE_IMPL"; then
1630         G_MODULE_IMPL=0
1631         G_MODULE_SUPPORTED=false
1632 else
1633         G_MODULE_SUPPORTED=true
1634 fi
1635
1636 AC_MSG_CHECKING(for the suffix of module shared libraries)
1637 export SED
1638 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1639 eval $shrext_cmds
1640 module=yes eval std_shrext=$shrext_cmds
1641 # chop the initial dot
1642 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1643 AC_MSG_RESULT(.$glib_gmodule_suffix)
1644 # any reason it may fail?
1645 if test "x$glib_gmodule_suffix" = x; then
1646         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1647 fi
1648
1649 AC_SUBST(G_MODULE_SUPPORTED)
1650 AC_SUBST(G_MODULE_IMPL)
1651 AC_SUBST(G_MODULE_LIBS)
1652 AC_SUBST(G_MODULE_LIBS_EXTRA)
1653 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1654 AC_SUBST(G_MODULE_LDFLAGS)
1655 AC_SUBST(G_MODULE_HAVE_DLERROR)
1656 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1657 AC_SUBST(G_MODULE_NEED_USCORE)
1658 AC_SUBST(GLIB_DEBUG_FLAGS)
1659
1660 dnl **********************
1661 dnl *** g_spawn checks ***
1662 dnl **********************
1663
1664 AC_MSG_CHECKING(for gspawn implementation)
1665 case "$host" in
1666   *-*-mingw*)
1667     GSPAWN=gspawn-win32.lo
1668     ;;
1669   *)
1670     GSPAWN=gspawn.lo
1671     ;;
1672 esac
1673 AC_MSG_RESULT($GSPAWN)
1674 AC_SUBST(GSPAWN)
1675
1676 dnl *************************
1677 dnl *** GIOChannel checks ***
1678 dnl *************************
1679
1680 AC_MSG_CHECKING(for GIOChannel implementation)
1681 case "$host" in
1682   *-*-mingw*)
1683     GIO=giowin32.lo
1684     ;;
1685   *)
1686     GIO=giounix.lo
1687     ;;
1688 esac
1689 AC_MSG_RESULT($GIO)
1690 AC_SUBST(GIO)
1691
1692 dnl *********************************
1693 dnl *** Directory for GIO modules ***
1694 dnl *********************************
1695
1696 AC_ARG_WITH(gio-module-dir,
1697            [AC_HELP_STRING([--with-gio-module-dir=PATH],
1698                            [Load gio modules from this directory [LIBDIR/gio/modules]])],
1699            [],
1700            [with_gio_module_dir='${libdir}/gio/modules'])
1701 GIO_MODULE_DIR=$with_gio_module_dir
1702 AC_SUBST(GIO_MODULE_DIR)
1703
1704 dnl **********************************
1705 dnl *** Check for libselinux (GIO) ***
1706 dnl **********************************
1707 AC_ARG_ENABLE(selinux, [  --disable-selinux       build without selinux support])
1708 msg_selinux=no
1709 SELINUX_LIBS=
1710 if test "x$enable_selinux" != "xno"; then
1711
1712  AC_CHECK_LIB(selinux, is_selinux_enabled,
1713    [AC_CHECK_HEADERS(selinux/selinux.h,
1714      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1715        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1716         SELINUX_LIBS="-lselinux"
1717         msg_selinux=yes])
1718      ])
1719    ])
1720 fi
1721 AC_SUBST(SELINUX_LIBS)
1722
1723 dnl *****************************
1724 dnl ** Check for inotify (GIO) **
1725 dnl *****************************
1726 inotify_support=no
1727 AC_CHECK_HEADERS([sys/inotify.h],
1728 [
1729         inotify_support=yes
1730         AC_CHECK_FUNCS(inotify_init1)
1731 ])
1732
1733 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1734
1735 dnl *********************************
1736 dnl ** Check for Solaris FEN (GIO) **
1737 dnl *********************************
1738 fen_support=no
1739 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1740 #include <port.h>
1741 #ifndef PORT_SOURCE_FILE
1742 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1743 #endif
1744 int main() { return 0; } ]])],
1745 [
1746         fen_support=yes
1747 ],)
1748
1749 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1750
1751 dnl ****************************
1752 dnl *** Checks for FAM (GIO) ***
1753 dnl ****************************
1754
1755 should_disable_fam=no
1756
1757 AC_ARG_ENABLE(fam, [  --disable-fam          build without enabling fam for file system monitoring],
1758                          [
1759                                 if test "x$enable_fam" = "xno"; then
1760                                         should_disable_fam=yes
1761                                         echo "Not building FAM support"
1762                                 fi
1763                          ]
1764                          )
1765 fam_support=no
1766 FAM_LIBS=
1767 if test "x$should_disable_fam" = "xno"; then
1768 AC_CHECK_LIB(fam, FAMOpen,
1769   [AC_CHECK_HEADERS(fam.h,
1770     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1771      AC_CHECK_LIB(fam, FAMNoExists,
1772                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1773      FAM_LIBS="-lfam"]
1774      fam_support=yes,
1775     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1776   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1777 AC_SUBST(FAM_LIBS)
1778 fi
1779 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1780
1781
1782 dnl *****************************
1783 dnl *** Check for xattr (GIO) ***
1784 dnl *****************************
1785 AC_ARG_ENABLE(xattr, [  --disable-xattr           build without xattr support])
1786 msg_xattr=no
1787 XATTR_LIBS=
1788 if test "x$enable_xattr" != "xno"; then
1789
1790 dnl either glibc or libattr can provide xattr support
1791
1792 dnl for both of them, we check for getxattr being in
1793 dnl the library and a valid xattr header.
1794
1795 dnl try glibc
1796  AC_CHECK_LIB(c, getxattr,
1797    [AC_CHECK_HEADERS(sys/xattr.h,
1798      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1799       msg_xattr=yes])
1800    ])
1801
1802   if test "x$msg_xattr" != "xyes"; then
1803 dnl   failure. try libattr
1804    AC_CHECK_LIB(attr, getxattr,
1805       [AC_CHECK_HEADERS(attr/xattr.h,
1806        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1807         XATTR_LIBS="-lattr"
1808         msg_xattr=yes])
1809       ])
1810   fi
1811
1812   if test "x$msg_xattr" = "xyes"; then
1813     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1814     AC_TRY_COMPILE([
1815       #include <stdio.h>
1816       #ifdef HAVE_SYS_TYPES_H
1817       #include <sys/types.h>
1818       #endif
1819       #ifdef HAVE_SYS_XATTR_H
1820       #include <sys/xattr.h>
1821       #elif HAVE_ATTR_XATTR_H
1822       #include <attr/xattr.h>
1823       #endif
1824     ],
1825     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1826     [
1827       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1828       AC_MSG_RESULT([yes])
1829     ],
1830     [AC_MSG_RESULT([no])]
1831     )
1832   fi
1833
1834 fi
1835 AC_SUBST(XATTR_LIBS)
1836
1837 dnl ****************************************
1838 dnl *** platform dependent source checks ***
1839 dnl ****************************************
1840
1841 AC_MSG_CHECKING(for platform-dependent source)
1842 case "$host" in
1843   *-*-cygwin*|*-*-mingw*)
1844     PLATFORMDEP=gwin32.lo
1845     ;;
1846   *)
1847     PLATFORMDEP=
1848     ;;
1849 esac
1850 AC_MSG_RESULT($PLATFORMDEP)
1851 AC_SUBST(PLATFORMDEP)
1852
1853 AC_MSG_CHECKING([whether to compile timeloop])
1854 case "$host" in
1855   *-*-cygwin*|*-*-mingw*|*-*-minix)
1856     enable_timeloop=no
1857     ;;
1858   *)
1859     enable_timeloop=yes
1860     ;;
1861 esac
1862 AC_MSG_RESULT($enable_timeloop)
1863 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1864
1865 AC_MSG_CHECKING([if building for some Win32 platform])
1866 case "$host" in
1867   *-*-mingw*|*-*-cygwin*)
1868     platform_win32=yes
1869     ;;
1870   *)
1871     platform_win32=no
1872     ;;
1873 esac
1874 AC_MSG_RESULT($platform_win32)
1875 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1876
1877 dnl ***********************
1878 dnl *** g_thread checks ***
1879 dnl ***********************
1880
1881 AC_ARG_WITH(threads,
1882            [AC_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1883                            [specify a thread implementation to use])],
1884            [if test "x$with_threads" = x; then
1885                 want_threads=yes
1886             else
1887                 want_threads=$with_threads
1888             fi],
1889            [want_threads=yes])
1890
1891 dnl error and warning message
1892 dnl *************************
1893
1894 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1895                 computer."
1896
1897 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1898                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1899                 compilation now, but then your programs might not work.
1900                 Please provide information on how it is done on your system."
1901
1902 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1903                 "
1904
1905 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1906                 provide information on your thread implementation."
1907
1908 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1909                 functions will not be MT-safe during their first call because
1910                 there is no working 'getpwuid_r' on your system."
1911
1912 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1913                 because there is no 'localtime_r' on your system."
1914
1915 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1916                 crude surrogate will be used. If you happen to know a
1917                 yield function for your system, please inform the GLib
1918                 developers."
1919
1920 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1921                 threads on your system. Thus threads can only have the default
1922                 priority. If you happen to know these main/max
1923                 priorities, please inform the GLib developers."
1924
1925 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1926                 linking threaded applications. As GLib cannot do that
1927                 automatically, you will get an linkg error everytime you are
1928                 not using the right compiler. In that case you have to relink
1929                 with the right compiler. Ususally just '_r' is appended
1930                 to the compiler name."
1931
1932 dnl determination of thread implementation
1933 dnl ***************************************
1934
1935 have_threads=no
1936 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1937                                 || test "x$want_threads" = xdce; then
1938         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1939         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1940         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1941         glib_save_CPPFLAGS="$CPPFLAGS"
1942         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1943         if test "x$have_threads" = xno; then
1944                 AC_TRY_COMPILE([#include <pthread.h>],
1945                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1946                         have_threads=posix)
1947         fi
1948         # Tru64Unix requires -pthread to find pthread.h. See #103020
1949         CPPFLAGS="$CPPFLAGS -pthread"
1950         if test "x$have_threads" = xno; then
1951         AC_TRY_COMPILE([#include <pthread.h>],
1952                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1953                        have_threads=posix)
1954         fi
1955         CPPFLAGS="$glib_save_CPPFLAGS"
1956 fi
1957 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1958         case $host in
1959                 *-*-mingw*)
1960                 have_threads=win32
1961                 ;;
1962         esac
1963 fi
1964
1965 AC_MSG_CHECKING(for thread implementation)
1966
1967 if test "x$have_threads" = xno; then
1968         AC_MSG_RESULT(none available)
1969         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1970 else
1971         AC_MSG_RESULT($have_threads)
1972 fi
1973
1974
1975 dnl determination of G_THREAD_CFLAGS
1976 dnl ********************************
1977
1978 G_THREAD_LIBS=
1979 G_THREAD_LIBS_EXTRA=
1980 G_THREAD_CFLAGS=
1981
1982 dnl
1983 dnl Test program for basic POSIX threads functionality
1984 dnl
1985 m4_define([glib_thread_test],[
1986 #include <pthread.h>
1987 int check_me = 0;
1988 void* func(void* data) {check_me = 42; return &check_me;}
1989 int main()
1990  { pthread_t t;
1991    void *ret;
1992    pthread_create (&t, $1, func, 0);
1993    pthread_join (t, &ret);
1994    return (check_me != 42 || ret != &check_me);
1995 }])
1996
1997 dnl
1998 dnl Test program for sched_get_priority_min()
1999 dnl
2000 m4_define([glib_sched_priority_test],[
2001 #include <sched.h>
2002 #include <errno.h>
2003 int main() {
2004     errno = 0;
2005     return sched_get_priority_min(SCHED_OTHER)==-1
2006            && errno != 0;
2007 }])
2008
2009 if test x"$have_threads" = xposix; then
2010   # First we test for posix, whether -pthread or -pthreads do the trick as
2011   # both CPPFLAG and LIBS.
2012   # One of them does for most gcc versions and some other platforms/compilers
2013   # too and could be considered as the canonical way to go.
2014   case $host in
2015     *-*-cygwin*|*-*-darwin*)
2016        # skip cygwin and darwin -pthread or -pthreads test
2017        ;;
2018     *-solaris*)
2019       # These compiler/linker flags work with both Sun Studio and gcc
2020       # Sun Studio expands -mt to -D_REENTRANT and -lthread
2021       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2022       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2023       G_THREAD_LIBS="-lpthread -lthread"
2024       ;;
2025     *)
2026       for flag in pthread pthreads mt; do
2027         glib_save_CFLAGS="$CFLAGS"
2028         CFLAGS="$CFLAGS -$flag"
2029         AC_TRY_RUN(glib_thread_test(0),
2030                    glib_flag_works=yes,
2031                    glib_flag_works=no,
2032                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2033                                    glib_flag_works=yes,
2034                                    glib_flag_works=no)])
2035         CFLAGS="$glib_save_CFLAGS"
2036         if test $glib_flag_works = yes ; then
2037            G_THREAD_CFLAGS=-$flag
2038         G_THREAD_LIBS=-$flag
2039         break;
2040         fi
2041       done
2042        ;;
2043   esac
2044 fi
2045
2046 if test x"$G_THREAD_CFLAGS" = x; then
2047
2048   # The canonical -pthread[s] does not work. Try something different.
2049
2050   case $host in
2051         *-aix*)
2052                 if test x"$GCC" = xyes; then
2053                         # GCC 3.0 and above needs -pthread.
2054                         # Should be coverd by the case above.
2055                         # GCC 2.x and below needs -mthreads
2056                         G_THREAD_CFLAGS="-mthreads"
2057                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2058                 else
2059                         # We are probably using the aix compiler. Normaly a
2060                         # program would have to be compiled with the _r variant
2061                         # of the corresponding compiler, but we as GLib cannot
2062                         # do that: but the good news is that for compiling the
2063                         # only difference is the added -D_THREAD_SAFE compile
2064                         # option. This is according to the "C for AIX User's
2065                         # Guide".
2066                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2067                 fi
2068                 ;;
2069         *-dg-dgux*)  # DG/UX
2070                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2071                 ;;
2072         *-sysv5uw7*) # UnixWare 7
2073                 # We are not using gcc with -pthread. Catched above.
2074                 G_THREAD_CFLAGS="-Kthread"
2075                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2076                 ;;
2077         *-mingw*)
2078                 # No flag needed when using MSVCRT.DLL
2079                 G_THREAD_CFLAGS=""
2080                 ;;
2081         *)
2082                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2083                 ;;
2084   esac
2085
2086 fi
2087
2088 # if we are not finding the localtime_r function, then we probably are
2089 # not using the proper multithread flag
2090
2091 glib_save_CPPFLAGS="$CPPFLAGS"
2092 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2093
2094 # First we test, whether localtime_r is declared in time.h
2095 # directly. Then we test whether a macro localtime_r exists, in
2096 # which case localtime_r in the test program is replaced and thus
2097 # if we still find localtime_r in the output, it is not defined as
2098 # a macro.
2099
2100 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2101   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2102                                                            localtime_r(a,b)],
2103                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2104
2105 CPPFLAGS="$glib_save_CPPFLAGS"
2106
2107 AC_MSG_CHECKING(thread related cflags)
2108 AC_MSG_RESULT($G_THREAD_CFLAGS)
2109 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2110
2111 dnl determination of G_THREAD_LIBS
2112 dnl ******************************
2113
2114 mutex_has_default=no
2115 case $have_threads in
2116         posix)
2117           glib_save_CPPFLAGS="$CPPFLAGS"
2118           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2119           if test x"$G_THREAD_LIBS" = x; then
2120             case $host in
2121               *-aix*)
2122                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2123                 # probably using the aix compiler.
2124                 AC_MSG_WARN($AIX_COMPILE_INFO)
2125                 ;;
2126               *)
2127                 G_THREAD_LIBS=error
2128                 glib_save_LIBS="$LIBS"
2129                 for thread_lib in "" pthread pthread32 pthreads thread; do
2130                         if test x"$thread_lib" = x; then
2131                                 add_thread_lib=""
2132                                 IN=""
2133                         else
2134                                 add_thread_lib="-l$thread_lib"
2135                                 IN=" in -l$thread_lib"
2136                         fi
2137                         if test x"$have_threads" = xposix; then
2138                                 defattr=0
2139                         else
2140                                 defattr=pthread_attr_default
2141                         fi
2142
2143                         LIBS="$add_thread_lib $glib_save_LIBS"
2144
2145                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2146                         AC_TRY_RUN(glib_thread_test($defattr),
2147                                    glib_result=yes,
2148                                    glib_result=no,
2149                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2150                                                    glib_result=yes,
2151                                                    glib_result=no)])
2152                         AC_MSG_RESULT($glib_result)
2153
2154                         if test "$glib_result" = "yes" ; then
2155                           G_THREAD_LIBS="$add_thread_lib"
2156                           break
2157                         fi
2158                 done
2159                 if test "x$G_THREAD_LIBS" = xerror; then
2160                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2161                 fi
2162                 LIBS="$glib_save_LIBS"
2163                 ;;
2164             esac
2165           fi
2166
2167           glib_save_LIBS="$LIBS"
2168           for thread_lib in "" rt rte; do
2169             if test x"$thread_lib" = x; then
2170               add_thread_lib=""
2171               IN=""
2172             else
2173               add_thread_lib="-l$thread_lib"
2174               IN=" in -l$thread_lib"
2175             fi
2176             LIBS="$add_thread_lib $glib_save_LIBS"
2177
2178             AC_MSG_CHECKING(for sched_get_priority_min$IN)
2179             AC_TRY_RUN(glib_sched_priority_test,
2180                        glib_result=yes,
2181                        glib_result=no,
2182                        [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_sched_priority_test)],
2183                                        glib_result=yes,
2184                                        glib_result=no)])
2185             AC_MSG_RESULT($glib_result)
2186
2187             if test "$glib_result" = "yes" ; then
2188                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
2189                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
2190                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
2191                break
2192             fi
2193           done
2194           LIBS="$glib_save_LIBS"
2195           mutex_has_default=yes
2196           mutex_default_type='pthread_mutex_t'
2197           mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
2198           mutex_header_file='pthread.h'
2199           g_threads_impl="POSIX"
2200           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2201           CPPFLAGS="$glib_save_CPPFLAGS"
2202           ;;
2203         win32)
2204            g_threads_impl="WIN32"
2205            ;;
2206         *)
2207            g_threads_impl="NONE"
2208            G_THREAD_LIBS=error
2209            ;;
2210 esac
2211
2212 if test "x$G_THREAD_LIBS" = xerror; then
2213         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2214 fi
2215
2216 case $host in
2217   *-*-beos*)
2218     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2219     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2220     ;;
2221   *)
2222     ;;
2223 esac
2224
2225 AC_MSG_CHECKING(thread related libraries)
2226 AC_MSG_RESULT($G_THREAD_LIBS)
2227
2228 dnl check for mt safe function variants and some posix functions
2229 dnl ************************************************************
2230
2231 glib_save_LIBS="$LIBS"
2232 # we are not doing the following for now, as this might require glib
2233 # to always be linked with the thread libs on some platforms.
2234 # LIBS="$LIBS $G_THREAD_LIBS"
2235 AC_CHECK_FUNCS(localtime_r gmtime_r)
2236 if test "$ac_cv_header_pwd_h" = "yes"; then
2237         AC_CACHE_CHECK([for posix getpwuid_r],
2238                 ac_cv_func_posix_getpwuid_r,
2239                 [AC_TRY_RUN([
2240 #include <errno.h>
2241 #include <pwd.h>
2242 int main () {
2243     char buffer[10000];
2244     struct passwd pwd, *pwptr = &pwd;
2245     int error;
2246     errno = 0;
2247     error = getpwuid_r (0, &pwd, buffer,
2248                         sizeof (buffer), &pwptr);
2249    return (error < 0 && errno == ENOSYS)
2250            || error == ENOSYS;
2251 }                               ],
2252                         [ac_cv_func_posix_getpwuid_r=yes],
2253                         [ac_cv_func_posix_getpwuid_r=no])])
2254         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2255         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2256                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2257                         [Have POSIX function getpwuid_r])
2258         else
2259                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2260                         ac_cv_func_nonposix_getpwuid_r,
2261                         [AC_TRY_LINK([#include <pwd.h>],
2262                                 [char buffer[10000];
2263                                 struct passwd pwd;
2264                                 getpwuid_r (0, &pwd, buffer,
2265                                                 sizeof (buffer));],
2266                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2267                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2268                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2269                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2270                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2271                                 [Have non-POSIX function getpwuid_r])
2272                 fi
2273         fi
2274 fi
2275 if test "$ac_cv_header_grp_h" = "yes"; then
2276         AC_CACHE_CHECK([for posix getgrgid_r],
2277                 ac_cv_func_posix_getgrgid_r,
2278                 [AC_TRY_RUN([
2279 #include <errno.h>
2280 #include <grp.h>
2281 int main () {
2282     char buffer[10000];
2283     struct group grp, *grpptr = &grp;
2284     int error;
2285     errno = 0;
2286     error = getgrgid_r (0, &grp, buffer,
2287                         sizeof (buffer), &grpptr);
2288    return (error < 0 && errno == ENOSYS)
2289            || error == ENOSYS;
2290 }                              ],
2291                        [ac_cv_func_posix_getgrgid_r=yes],
2292                        [ac_cv_func_posix_getgrgid_r=no])])
2293         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2294         if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2295                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2296                         [Have POSIX function getgrgid_r])
2297         else
2298                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2299                         ac_cv_func_nonposix_getgrgid_r,
2300                         [AC_TRY_LINK([#include <grp.h>],
2301                                 [char buffer[10000];
2302                                 struct group grp;
2303                                 getgrgid_r (0, &grp, buffer,
2304                                 sizeof (buffer));],
2305                         [ac_cv_func_nonposix_getgrgid_r=yes],
2306                         [ac_cv_func_nonposix_getgrgid_r=no])])
2307                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2308                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2309                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2310                                 [Have non-POSIX function getgrgid_r])
2311                 fi
2312         fi
2313 fi
2314 LIBS="$G_THREAD_LIBS $LIBS"
2315 if test x"$have_threads" = xposix; then
2316         glib_save_CPPFLAGS="$CPPFLAGS"
2317         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2318         dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
2319         GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
2320         # This is not AC_CHECK_FUNC to also work with function
2321         # name mangling in header files.
2322         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2323         AC_TRY_LINK([#include <pthread.h>],
2324                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
2325                 [AC_MSG_RESULT(yes)
2326                 AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2327                           [Have function pthread_attr_setstacksize])],
2328                 [AC_MSG_RESULT(no)])
2329         AC_MSG_CHECKING(for minimal/maximal thread priority)
2330         if test x"$posix_priority_min" = x; then
2331                 AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
2332                         PX_PRIO_MIN],,[
2333                         posix_priority_min=PX_PRIO_MIN
2334                         posix_priority_max=PX_PRIO_MAX])
2335         fi
2336         if test x"$posix_priority_min" = x; then
2337                 # AIX
2338                 AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
2339                         PTHREAD_PRIO_MIN],,[
2340                         posix_priority_min=PTHREAD_PRIO_MIN
2341                         posix_priority_max=PTHREAD_PRIO_MAX])
2342         fi
2343         if test x"$posix_priority_min" = x; then
2344                 AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
2345                         PRI_OTHER_MIN],,[
2346                         posix_priority_min=PRI_OTHER_MIN
2347                         posix_priority_max=PRI_OTHER_MAX])
2348         fi
2349         if test x"$posix_priority_min" = x; then
2350                 AC_MSG_RESULT(none found)
2351                 AC_MSG_WARN($POSIX_NO_PRIORITIES)
2352                 posix_priority_min=-1
2353                 posix_priority_max=-1
2354         else
2355                 AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
2356                 AC_MSG_CHECKING(for pthread_setschedparam)
2357                 AC_TRY_LINK([#include <pthread.h>],
2358                   [pthread_t t; pthread_setschedparam(t, 0, NULL)],
2359                   [AC_MSG_RESULT(yes)
2360                 AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
2361                    AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
2362                   [AC_MSG_RESULT(no)
2363                    AC_MSG_WARN($POSIX_NO_PRIORITIES)])
2364         fi
2365         posix_yield_func=none
2366         AC_MSG_CHECKING(for posix yield function)
2367         for yield_func in sched_yield pthread_yield_np pthread_yield \
2368                                                 thr_yield; do
2369                 AC_TRY_LINK([#include <pthread.h>],
2370                         [$yield_func()],
2371                         [posix_yield_func="$yield_func"
2372                         break])
2373         done
2374         if test x"$posix_yield_func" = xnone; then
2375                 AC_MSG_RESULT(none found)
2376                 AC_MSG_WARN($POSIX_NO_YIELD)
2377                 posix_yield_func="g_usleep(1000)"
2378         else
2379                 AC_MSG_RESULT($posix_yield_func)
2380                 posix_yield_func="$posix_yield_func()"
2381         fi
2382         AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
2383         CPPFLAGS="$glib_save_CPPFLAGS"
2384
2385 elif test x"$have_threads" = xwin32; then
2386         # It's a pointer to a private struct
2387         GLIB_SIZEOF(,struct _GThreadData *, system_thread)
2388 fi
2389
2390 LIBS="$glib_save_LIBS"
2391
2392 # now spit out all the warnings.
2393 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2394    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2395         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2396 fi
2397 if test "$ac_cv_func_localtime_r" != "yes"; then
2398         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2399 fi
2400
2401 if test x"$glib_cv_sizeof_system_thread" = x; then
2402    # use a pointer as a fallback.
2403    GLIB_SIZEOF(,void *, system_thread)
2404 fi
2405
2406 #
2407 # Hack to deal with:
2408 #
2409 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2410 #     building shared libraries with linux.
2411 #  b) FreeBSD doesn't do this either.
2412 #
2413 case $host in
2414   *-*-freebsd*|*-*-linux*)
2415     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2416     ;;
2417   *)
2418     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2419     ;;
2420 esac
2421
2422 AC_SUBST(G_THREAD_CFLAGS)
2423 AC_SUBST(G_THREAD_LIBS)
2424 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2425 AC_SUBST(G_THREAD_LIBS_EXTRA)
2426
2427 dnl **********************************************
2428 dnl *** GDefaultMutex setup and initialization ***
2429 dnl **********************************************
2430 dnl
2431 dnl if mutex_has_default = yes, we also got
2432 dnl mutex_default_type, mutex_default_init and mutex_header_file
2433 if test $mutex_has_default = yes ; then
2434         glib_save_CPPFLAGS="$CPPFLAGS"
2435         glib_save_LIBS="$LIBS"
2436         LIBS="$G_THREAD_LIBS $LIBS"
2437         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2438         GLIB_SIZEOF([#include <$mutex_header_file>],
2439                     $mutex_default_type,
2440                     gmutex)
2441         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
2442                            $mutex_default_type,
2443                            gmutex,
2444                            $glib_cv_sizeof_gmutex,
2445                            $mutex_default_init)
2446         if test x"$glib_cv_byte_contents_gmutex" = xno; then
2447                 mutex_has_default=no
2448         fi
2449         CPPFLAGS="$glib_save_CPPFLAGS"
2450         LIBS="$glib_save_LIBS"
2451 fi
2452
2453 AC_CHECK_FUNCS(clock_gettime, [], [
2454   AC_CHECK_LIB(rt, clock_gettime, [
2455     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2456     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2457     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2458     GLIB_RT_LIBS="-lrt"
2459   ])
2460 ])
2461 AC_SUBST(GLIB_RT_LIBS)
2462
2463 AC_CACHE_CHECK(for monotonic clocks,
2464     glib_cv_monotonic_clock,AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
2465 #include <time.h>
2466 #include <unistd.h>
2467 int main() {
2468 #if !(defined(_POSIX_MONOTONIC_CLOCK) && _POSIX_MONOTONIC_CLOCK >= 0 && defined(CLOCK_MONOTONIC))
2469         #error No monotonic clock
2470 #endif
2471         return 0;
2472 }
2473 ]])],glib_cv_monotonic_clock=yes,glib_cv_monotonic_clock=no))
2474 if test "$glib_cv_monotonic_clock" = "yes"; then
2475   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
2476 fi
2477
2478
2479 dnl ************************
2480 dnl *** g_atomic_* tests ***
2481 dnl ************************
2482
2483 AC_MSG_CHECKING([whether to use assembler code for atomic operations])
2484     case $host_cpu in
2485       i386)
2486         AC_MSG_RESULT([none])
2487         glib_memory_barrier_needed=no
2488         ;;
2489       i?86)
2490         AC_MSG_RESULT([i486])
2491         AC_DEFINE_UNQUOTED(G_ATOMIC_I486, 1,
2492                            [i486 atomic implementation])
2493         glib_memory_barrier_needed=no
2494         ;;
2495       sparc*)
2496         SPARCV9_WARNING="Try to rerun configure with CFLAGS='-mcpu=v9',
2497                          when you are using a sparc with v9 instruction set (most
2498                          sparcs nowadays). This will make the code for atomic
2499                          operations much faster. The resulting code will not run
2500                          on very old sparcs though."
2501
2502         AC_LINK_IFELSE([AC_LANG_SOURCE([[
2503           main ()
2504           {
2505             int tmp1, tmp2, tmp3;
2506             __asm__ __volatile__("casx [%2], %0, %1"
2507                                  : "=&r" (tmp1), "=&r" (tmp2) : "r" (&tmp3));
2508           }]])],
2509           AC_MSG_RESULT([sparcv9])
2510           AC_DEFINE_UNQUOTED(G_ATOMIC_SPARCV9, 1,
2511                              [sparcv9 atomic implementation]),
2512           AC_MSG_RESULT([no])
2513           AC_MSG_WARN([[$SPARCV9_WARNING]]))
2514         glib_memory_barrier_needed=yes
2515         ;;
2516       alpha*)
2517         AC_MSG_RESULT([alpha])
2518         AC_DEFINE_UNQUOTED(G_ATOMIC_ALPHA, 1,
2519                            [alpha atomic implementation])
2520         glib_memory_barrier_needed=yes
2521         ;;
2522       x86_64)
2523         AC_MSG_RESULT([x86_64])
2524         AC_DEFINE_UNQUOTED(G_ATOMIC_X86_64, 1,
2525                            [x86_64 atomic implementation])
2526         glib_memory_barrier_needed=no
2527        ;;
2528       powerpc*)
2529         AC_MSG_RESULT([powerpc])
2530         AC_DEFINE_UNQUOTED(G_ATOMIC_POWERPC, 1,
2531                            [powerpc atomic implementation])
2532         glib_memory_barrier_needed=yes
2533         AC_MSG_CHECKING([whether asm supports numbered local labels])
2534         AC_TRY_COMPILE(
2535                        ,[
2536                        __asm__ __volatile__ ("1:       nop\n"
2537                                "         bne-    1b")
2538                        ],[
2539                        AC_DEFINE_UNQUOTED(ASM_NUMERIC_LABELS, 1, [define if asm blocks can use numeric local labels])
2540                        AC_MSG_RESULT([yes])
2541                        ],[
2542                        AC_MSG_RESULT([no])
2543                        ])
2544         ;;
2545       ia64)
2546         AC_MSG_RESULT([ia64])
2547         AC_DEFINE_UNQUOTED(G_ATOMIC_IA64, 1,
2548                            [ia64 atomic implementation])
2549         glib_memory_barrier_needed=yes
2550         ;;
2551       s390|s390x)
2552         AC_MSG_RESULT([s390])
2553         AC_DEFINE_UNQUOTED(G_ATOMIC_S390, 1,
2554                            [s390 atomic implementation])
2555         glib_memory_barrier_needed=no
2556         ;;
2557       arm*)
2558         AC_MSG_RESULT([arm])
2559         AC_DEFINE_UNQUOTED(G_ATOMIC_ARM, 1,
2560                            [arm atomic implementation])
2561         glib_memory_barrier_needed=no
2562         ;;
2563       crisv32*|etraxfs*)
2564         AC_MSG_RESULT([crisv32])
2565         AC_DEFINE_UNQUOTED(G_ATOMIC_CRISV32, 1,
2566                            [crisv32 atomic implementation])
2567         glib_memory_barrier_needed=no
2568         ;;
2569       cris*|etrax*)
2570         AC_MSG_RESULT([cris])
2571         AC_DEFINE_UNQUOTED(G_ATOMIC_CRIS, 1,
2572                            [cris atomic implementation])
2573         glib_memory_barrier_needed=no
2574         ;;
2575       *)
2576         AC_MSG_RESULT([none])
2577         glib_memory_barrier_needed=yes
2578         ;;
2579     esac
2580
2581 glib_cv_gcc_has_builtin_atomic_operations=no
2582 if test x"$GCC" = xyes; then
2583   AC_MSG_CHECKING([whether GCC supports built-in atomic intrinsics])
2584   AC_TRY_LINK([],
2585               [int i;
2586                __sync_synchronize ();
2587                __sync_bool_compare_and_swap (&i, 0, 1);
2588                __sync_fetch_and_add (&i, 1);
2589               ],
2590               [glib_cv_gcc_has_builtin_atomic_operations=yes],
2591               [glib_cv_gcc_has_builtin_atomic_operations=no])
2592
2593   AC_MSG_RESULT($glib_cv_gcc_has_builtin_atomic_operations)
2594 fi
2595 AM_CONDITIONAL(HAVE_GCC_BUILTINS_FOR_ATOMIC_OPERATIONS,
2596                [test $glib_cv_gcc_has_builtin_atomic_operations = yes])
2597
2598 AC_MSG_CHECKING([for Win32 atomic intrinsics])
2599 glib_cv_has_win32_atomic_operations=no
2600 AC_TRY_LINK([],
2601         [int i; _InterlockedExchangeAdd (&i, 0);],
2602         [glib_cv_has_win32_atomic_operations=yes],
2603         [glib_cv_has_win32_atomic_operations=no])
2604 AC_MSG_RESULT($glib_cv_has_win32_atomic_operations)
2605 if test "x$glib_cv_has_win32_atomic_operations" = xyes; then
2606         AC_DEFINE(HAVE_WIN32_BUILTINS_FOR_ATOMIC_OPERATIONS,1,[Have Win32 atomic intrinsics])
2607 fi
2608
2609 dnl ************************
2610 dnl ** Check for futex(2) **
2611 dnl ************************
2612 AC_CACHE_CHECK(for futex(2) system call,
2613     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2614 #include <linux/futex.h>
2615 #include <sys/syscall.h>
2616 #include <unistd.h>
2617 ],[
2618 int
2619 main (void)
2620 {
2621   /* it is not like this actually runs or anything... */
2622   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2623   return 0;
2624 }
2625 ])],glib_cv_futex=yes,glib_cv_futex=no))
2626 if test x"$glib_cv_futex" = xyes; then
2627   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2628 fi
2629
2630 AC_CACHE_CHECK(for eventfd(2) system call,
2631     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2632 #include <sys/eventfd.h>
2633 #include <unistd.h>
2634 ],[
2635 int
2636 main (void)
2637 {
2638   eventfd (0, EFD_CLOEXEC);
2639   return 0;
2640 }
2641 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2642 if test x"$glib_cv_eventfd" = x"yes"; then
2643   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2644 fi
2645 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2646
2647 dnl ****************************************
2648 dnl *** GLib POLL* compatibility defines ***
2649 dnl ****************************************
2650
2651 glib_poll_includes=["
2652 #include <sys/types.h>
2653 #include <sys/poll.h>
2654 "]
2655
2656 if test $ac_cv_header_sys_types_h = yes &&
2657    test $ac_cv_header_sys_poll_h = yes ; then
2658   glib_failed=false
2659   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2660   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2661   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2662   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2663   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2664   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2665   if $glib_failed ; then
2666     AC_MSG_ERROR([Could not determine values for POLL* constants])
2667   fi
2668 else
2669   glib_cv_value_POLLIN=1
2670   glib_cv_value_POLLOUT=4
2671   glib_cv_value_POLLPRI=2
2672   glib_cv_value_POLLERR=8
2673   glib_cv_value_POLLHUP=16
2674   glib_cv_value_POLLNVAL=32
2675 fi
2676
2677 AC_MSG_CHECKING([for broken poll])
2678 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2679         #include <stdlib.h>
2680         #include <fcntl.h>
2681         #include <poll.h>
2682         #ifdef HAVE_SYS_POLL_H
2683         #include <sys/poll.h>
2684         #endif
2685         int main(void) {
2686           struct pollfd fds[1];
2687           int fd;
2688           fd = open("/dev/null", 1);
2689           fds[0].fd = fd;
2690           fds[0].events = POLLIN;
2691           fds[0].revents = 0;
2692           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2693                 exit(1);  /* Does not work for devices -- fail */
2694           }
2695           exit(0);
2696         }]])],
2697   [broken_poll=no],
2698   [broken_poll=yes
2699    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2700   [broken_poll="no (cross compiling)"])
2701 AC_MSG_RESULT($broken_poll)
2702
2703 dnl *********************
2704 dnl *** GRegex checks ***
2705 dnl *********************
2706 PCRE_REQUIRED_VERSION=8.11
2707
2708 # Check if we should compile GRegex
2709 AC_ARG_ENABLE(regex, AC_HELP_STRING([--disable-regex],
2710               [disable the compilation of GRegex]),
2711 [case "${enableval}" in
2712   yes) enable_regex=true ;;
2713   no)  enable_regex=false ;;
2714   *) AC_MSG_ERROR(bad value ${enableval} for --enable-regex) ;;
2715 esac],
2716 [enable_regex=true])
2717
2718 AM_CONDITIONAL(ENABLE_REGEX, $enable_regex)
2719
2720 if test x$enable_regex = xtrue; then
2721   AC_DEFINE(ENABLE_REGEX, [], [include GRegex])
2722   # Check if we should use the internal or the system-supplied pcre
2723   AC_ARG_WITH(pcre,
2724              [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2725                              [specify whether to use the internal or the
2726                               system-supplied PCRE library])])
2727
2728   AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2729
2730   if test "x$with_pcre" = xsystem; then
2731     PKG_CHECK_MODULES(PCRE,
2732                       libpcre >= $PCRE_REQUIRED_VERSION)
2733     AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2734                    glib_save_CFLAGS="$CFLAGS"
2735                    glib_save_LIBS="$LIBS"
2736                    CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2737                    AC_TRY_RUN([#include <pcre.h>
2738                                int main () {
2739                                  int support;
2740                                  pcre_config (PCRE_CONFIG_UTF8, &support);
2741                                  if (!support)
2742                                    return 1;
2743                                  pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2744                                  if (!support)
2745                                    return 1;
2746                                  return 0;
2747                                }],
2748                    glib_cv_pcre_has_unicode=yes,
2749                    glib_cv_pcre_has_unicode=no,
2750                    glib_cv_pcre_has_unicode=yes)
2751                    CFLAGS="$glib_save_CFLAGS"
2752                    LIBS="$glib_save_LIBS"
2753         ])
2754     if test "$glib_cv_pcre_has_unicode" = "no"; then
2755       AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2756     fi
2757     AC_SUBST(PCRE_CFLAGS)
2758     AC_SUBST(PCRE_LIBS)
2759     AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2760     PCRE_REQUIRES=libpcre
2761     AC_SUBST(PCRE_REQUIRES)
2762   else
2763     # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2764     if test x"$GCC" = xyes; then
2765       AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2766       save_CFLAGS="$CFLAGS"
2767       CFLAGS="$CFLAGS -Wno-pointer-sign"
2768       AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2769                             AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2770       CFLAGS="$save_CFLAGS"
2771     fi
2772   fi
2773   AC_SUBST(PCRE_WARN_CFLAGS)
2774 else
2775   AM_CONDITIONAL(USE_SYSTEM_PCRE, false])
2776 fi
2777
2778 dnl **********************
2779 dnl *** Win32 API libs ***
2780 dnl **********************
2781
2782 case $host in
2783   *-*-cygwin*)
2784         G_LIBS_EXTRA="-luser32 -lkernel32"
2785     ;;
2786   *-*-mingw*)
2787         G_LIBS_EXTRA="-lws2_32 -lole32"
2788     ;;
2789   *)
2790         G_LIBS_EXTRA=""
2791     ;;
2792 esac
2793 AC_SUBST(G_LIBS_EXTRA)
2794
2795 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2796 dnl since we need it for g_iconv()
2797
2798 AC_MSG_CHECKING([for EILSEQ])
2799 AC_TRY_COMPILE([
2800 #include <errno.h>
2801 ],
2802 [
2803 int error = EILSEQ;
2804 ], have_eilseq=yes, have_eilseq=no);
2805 AC_MSG_RESULT($have_eilseq)
2806
2807 dnl ******************************************************************
2808 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2809 dnl *** glib-compile-schemas in PATH                               ***
2810 dnl ******************************************************************
2811
2812 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2813
2814 if test $cross_compiling = yes; then
2815   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2816   if test x$GLIB_GENMARSHAL = xno; then
2817     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2818   fi
2819
2820   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2821   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2822     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2823   fi
2824 fi
2825
2826 dnl **************************
2827 dnl *** Checks for gtk-doc ***
2828 dnl **************************
2829
2830 GTK_DOC_CHECK([1.15])
2831
2832 AC_ARG_ENABLE(man,
2833               [AC_HELP_STRING([--enable-man],
2834                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2835               enable_man=no)
2836
2837 if test "${enable_man}" != no; then
2838 dnl
2839 dnl Check for xsltproc
2840 dnl
2841 AC_PATH_PROG([XSLTPROC], [xsltproc])
2842   if test -z "$XSLTPROC"; then
2843     enable_man=no
2844   fi
2845
2846   dnl check for DocBook DTD and stylesheets in the local catalog.
2847   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2848      [DocBook XML DTD V4.1.2],,enable_man=no)
2849   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2850      [DocBook XSL Stylesheets],,enable_man=no)
2851 fi
2852
2853 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2854
2855 dnl
2856 dnl Tracing
2857 dnl
2858
2859 AC_ARG_ENABLE([dtrace],
2860              [AS_HELP_STRING([--enable-dtrace],
2861                               [Enable inclusion of dtrace trace support])])
2862 have_dtrace=no
2863 AC_MSG_CHECKING([whether to include dtrace tracing support])
2864 if test "x$enable_dtrace" != xno; then
2865   if test x$glib_have_carbon = xyes; then
2866     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2867   else
2868     AC_MSG_RESULT([yes])
2869     AC_CHECK_PROGS(DTRACE, dtrace)
2870     if test -z "$DTRACE"; then
2871       if test "x$enable_dtrace" = xyes; then
2872         AC_MSG_ERROR([dtrace not found])
2873       fi
2874     else
2875       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2876                       [if test "x$enable_dtrace" = xyes; then
2877                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2878                        fi])
2879     fi
2880   fi
2881 else
2882   AC_MSG_RESULT([no])
2883 fi
2884 if test "x$have_dtrace" = xyes; then
2885   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2886 fi
2887 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2888
2889 AC_MSG_CHECKING([whether to include systemtap tracing support])
2890 AC_ARG_ENABLE([systemtap],
2891              [AS_HELP_STRING([--enable-systemtap],
2892                               [Enable inclusion of systemtap trace support])])
2893 have_systemtap=no
2894 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2895   have_systemtap=yes
2896 fi
2897 AC_MSG_RESULT(${have_systemtap})
2898
2899 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2900
2901 AC_ARG_WITH([tapset-install-dir],
2902             [AS_HELP_STRING([--with-tapset-install-dir],
2903             [The absolute path where the systemtap tapsets will be installed])],
2904             [if test "x${withval}" = x; then
2905                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2906              else
2907                ABS_TAPSET_DIR="${withval}"
2908               fi],
2909             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2910 AC_SUBST(ABS_TAPSET_DIR)
2911
2912 dnl ************************************
2913 dnl *** Enable lcov coverage reports ***
2914 dnl ************************************
2915
2916 AC_ARG_ENABLE(gcov,
2917   AS_HELP_STRING([--enable-gcov],
2918                  [Enable gcov]),
2919   [use_gcov=$enableval], [use_gcov=no])
2920
2921 if test "x$use_gcov" = "xyes"; then
2922   dnl we need gcc:
2923   if test "$GCC" != "yes"; then
2924     AC_MSG_ERROR([GCC is required for --enable-gcov])
2925   fi
2926
2927   dnl Check if ccache is being used
2928   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2929   case `$SHTOOL path $CC` in
2930     *ccache*[)] gcc_ccache=yes;;
2931     *[)] gcc_ccache=no;;
2932   esac
2933
2934   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2935     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2936   fi
2937
2938   ltp_version_list="1.6 1.7 1.8 1.9"
2939   AC_CHECK_PROG(LTP, lcov, lcov)
2940   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2941
2942   if test "$LTP"; then
2943     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2944       glib_cv_ltp_version=invalid
2945       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2946       for ltp_check_version in $ltp_version_list; do
2947         if test "$ltp_version" = "$ltp_check_version"; then
2948           glib_cv_ltp_version="$ltp_check_version (ok)"
2949         fi
2950       done
2951     ])
2952   else
2953     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2954     AC_MSG_ERROR([$ltp_msg])
2955   fi
2956
2957   case $glib_cv_ltp_version in
2958     ""|invalid[)]
2959       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2960       AC_MSG_ERROR([$ltp_msg])
2961       LTP="exit 0;"
2962       ;;
2963   esac
2964
2965   if test -z "$LTP_GENHTML"; then
2966     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2967   fi
2968
2969   AC_DEFINE(HAVE_GCOV, 1, [Whether you have gcov])
2970
2971   dnl Remove all optimization flags from CFLAGS
2972   changequote({,})
2973   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2974   changequote([,])
2975
2976   dnl Add the special gcc flags
2977   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2978   LDFLAGS="$LDFLAGS -lgcov"
2979 fi
2980
2981 dnl ******************************
2982 dnl *** output the whole stuff ***
2983 dnl ******************************
2984
2985 dnl this section will only be run if config.status is invoked with no
2986 dnl arguments, or with "glib/glibconfig.h" as an argument.
2987 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2988 [
2989         outfile=glib/glibconfig.h-tmp
2990         cat > $outfile <<\_______EOF
2991 /* glibconfig.h
2992  *
2993  * This is a generated file.  Please modify 'configure.ac'
2994  */
2995
2996 #ifndef __G_LIBCONFIG_H__
2997 #define __G_LIBCONFIG_H__
2998
2999 #include <glib/gmacros.h>
3000
3001 _______EOF
3002
3003         if test x$glib_limits_h = xyes; then
3004           echo '#include <limits.h>' >> $outfile
3005         fi
3006         if test x$glib_float_h = xyes; then
3007           echo '#include <float.h>' >> $outfile
3008         fi
3009         if test x$glib_values_h = xyes; then
3010           echo '#include <values.h>' >> $outfile
3011         fi
3012         if test "$glib_header_alloca_h" = "yes"; then
3013           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
3014         fi
3015         if test x$glib_sys_poll_h = xyes; then
3016           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
3017         fi
3018         if test x$glib_included_printf != xyes; then
3019           echo "
3020 /* Specifies that GLib's g_print*() functions wrap the
3021  * system printf functions.  This is useful to know, for example,
3022  * when using glibc's register_printf_function().
3023  */" >> $outfile
3024           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
3025         fi
3026
3027         cat >> $outfile <<_______EOF
3028
3029 G_BEGIN_DECLS
3030
3031 #define G_MINFLOAT      $glib_mf
3032 #define G_MAXFLOAT      $glib_Mf
3033 #define G_MINDOUBLE     $glib_md
3034 #define G_MAXDOUBLE     $glib_Md
3035 #define G_MINSHORT      $glib_ms
3036 #define G_MAXSHORT      $glib_Ms
3037 #define G_MAXUSHORT     $glib_Mus
3038 #define G_MININT        $glib_mi
3039 #define G_MAXINT        $glib_Mi
3040 #define G_MAXUINT       $glib_Mui
3041 #define G_MINLONG       $glib_ml
3042 #define G_MAXLONG       $glib_Ml
3043 #define G_MAXULONG      $glib_Mul
3044
3045 _______EOF
3046
3047
3048         ### this should always be true in a modern C/C++ compiler
3049         cat >>$outfile <<_______EOF
3050 typedef signed char gint8;
3051 typedef unsigned char guint8;
3052 _______EOF
3053
3054
3055         if test -n "$gint16"; then
3056           cat >>$outfile <<_______EOF
3057 typedef signed $gint16 gint16;
3058 typedef unsigned $gint16 guint16;
3059 #define G_GINT16_MODIFIER $gint16_modifier
3060 #define G_GINT16_FORMAT $gint16_format
3061 #define G_GUINT16_FORMAT $guint16_format
3062 _______EOF
3063         fi
3064
3065
3066         if test -n "$gint32"; then
3067           cat >>$outfile <<_______EOF
3068 typedef signed $gint32 gint32;
3069 typedef unsigned $gint32 guint32;
3070 #define G_GINT32_MODIFIER $gint32_modifier
3071 #define G_GINT32_FORMAT $gint32_format
3072 #define G_GUINT32_FORMAT $guint32_format
3073 _______EOF
3074         fi
3075
3076         cat >>$outfile <<_______EOF
3077 #define G_HAVE_GINT64 1          /* deprecated, always true */
3078
3079 ${glib_extension}typedef signed $gint64 gint64;
3080 ${glib_extension}typedef unsigned $gint64 guint64;
3081
3082 #define G_GINT64_CONSTANT(val)  $gint64_constant
3083 #define G_GUINT64_CONSTANT(val) $guint64_constant
3084 _______EOF
3085
3086         if test x$gint64_format != x ; then
3087           cat >>$outfile <<_______EOF
3088 #define G_GINT64_MODIFIER $gint64_modifier
3089 #define G_GINT64_FORMAT $gint64_format
3090 #define G_GUINT64_FORMAT $guint64_format
3091 _______EOF
3092         else
3093           cat >>$outfile <<_______EOF
3094 #undef G_GINT64_MODIFIER
3095 #undef G_GINT64_FORMAT
3096 #undef G_GUINT64_FORMAT
3097 _______EOF
3098         fi
3099
3100         cat >>$outfile <<_______EOF
3101
3102 #define GLIB_SIZEOF_VOID_P $glib_void_p
3103 #define GLIB_SIZEOF_LONG   $glib_long
3104 #define GLIB_SIZEOF_SIZE_T $glib_size_t
3105
3106 _______EOF
3107
3108         cat >>$outfile <<_______EOF
3109 typedef signed $glib_size_type_define gssize;
3110 typedef unsigned $glib_size_type_define gsize;
3111 #define G_GSIZE_MODIFIER $gsize_modifier
3112 #define G_GSSIZE_FORMAT $gssize_format
3113 #define G_GSIZE_FORMAT $gsize_format
3114
3115 #define G_MAXSIZE       G_MAXU$glib_msize_type
3116 #define G_MINSSIZE      G_MIN$glib_msize_type
3117 #define G_MAXSSIZE      G_MAX$glib_msize_type
3118
3119 typedef gint64 goffset;
3120 #define G_MINOFFSET     G_MININT64
3121 #define G_MAXOFFSET     G_MAXINT64
3122
3123 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
3124 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
3125 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
3126
3127 _______EOF
3128
3129         if test -z "$glib_unknown_void_p"; then
3130           cat >>$outfile <<_______EOF
3131
3132 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
3133 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
3134
3135 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
3136 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
3137
3138 typedef signed $glib_intptr_type_define gintptr;
3139 typedef unsigned $glib_intptr_type_define guintptr;
3140
3141 #define G_GINTPTR_MODIFIER      $gintptr_modifier
3142 #define G_GINTPTR_FORMAT        $gintptr_format
3143 #define G_GUINTPTR_FORMAT       $guintptr_format
3144 _______EOF
3145         else
3146           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
3147         fi
3148
3149
3150
3151         cat >>$outfile <<_______EOF
3152 $glib_atexit
3153 $glib_memmove
3154 $glib_defines
3155 $glib_os
3156 $glib_static_compilation
3157
3158 $glib_vacopy
3159
3160 #ifdef  __cplusplus
3161 #define G_HAVE_INLINE   1
3162 #else   /* !__cplusplus */
3163 $glib_inline
3164 #endif  /* !__cplusplus */
3165
3166 #ifdef  __cplusplus
3167 #define G_CAN_INLINE    1
3168 _______EOF
3169
3170         if test x$g_can_inline = xyes ; then
3171                 cat >>$outfile <<_______EOF
3172 #else   /* !__cplusplus */
3173 #define G_CAN_INLINE    1
3174 _______EOF
3175         fi
3176
3177         cat >>$outfile <<_______EOF
3178 #endif
3179
3180 _______EOF
3181
3182         if test x$g_have_iso_c_varargs = xyes ; then
3183                 cat >>$outfile <<_______EOF
3184 #ifndef __cplusplus
3185 # define G_HAVE_ISO_VARARGS 1
3186 #endif
3187 _______EOF
3188         fi
3189         if test x$g_have_iso_cxx_varargs = xyes ; then
3190                 cat >>$outfile <<_______EOF
3191 #ifdef __cplusplus
3192 # define G_HAVE_ISO_VARARGS 1
3193 #endif
3194 _______EOF
3195         fi
3196         if test x$g_have_gnuc_varargs = xyes ; then
3197                 cat >>$outfile <<_______EOF
3198
3199 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3200  * is passed ISO vararg support is turned off, and there is no work
3201  * around to turn it on, so we unconditionally turn it off.
3202  */
3203 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3204 #  undef G_HAVE_ISO_VARARGS
3205 #endif
3206
3207 #define G_HAVE_GNUC_VARARGS 1
3208 _______EOF
3209         fi
3210
3211         case x$g_stack_grows in
3212         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3213         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3214         esac
3215
3216
3217         echo >>$outfile
3218         if test x$g_have_eilseq = xno; then
3219                 cat >>$outfile <<_______EOF
3220 #ifndef EILSEQ
3221 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3222  * The correspondence between this and the corresponding definition
3223  * in libiconv is essential.
3224  */
3225 #  define EILSEQ ENOENT
3226 #endif
3227 _______EOF
3228
3229         fi
3230
3231         if test x$g_have_gnuc_visibility = xyes; then
3232                 cat >>$outfile <<_______EOF
3233 #define G_HAVE_GNUC_VISIBILITY 1
3234 _______EOF
3235         fi
3236                 cat >>$outfile <<_______EOF
3237 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3238 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3239 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3240 #define G_GNUC_INTERNAL __hidden
3241 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3242 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3243 #else
3244 #define G_GNUC_INTERNAL
3245 #endif
3246 _______EOF
3247
3248
3249         echo >>$outfile
3250         if test x$g_mutex_has_default = xyes; then
3251                 cat >>$outfile <<_______EOF
3252 #define G_THREADS_ENABLED
3253 #define G_THREADS_IMPL_$g_threads_impl_def
3254 typedef struct _GStaticMutex GStaticMutex;
3255 struct _GStaticMutex
3256 {
3257   struct _GMutex *runtime_mutex;
3258   union {
3259     char   pad[[$g_mutex_sizeof]];
3260     double dummy_double;
3261     void  *dummy_pointer;
3262     long   dummy_long;
3263   } static_mutex;
3264 };
3265 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
3266 #define g_static_mutex_get_mutex(mutex) \\
3267   (g_thread_use_default_impl ? ((GMutex*)(gpointer) ((mutex)->static_mutex.pad)) : \\
3268    g_static_mutex_get_mutex_impl_shortcut (&((mutex)->runtime_mutex)))
3269 _______EOF
3270         else
3271                 cat >>$outfile <<_______EOF
3272 #define G_THREADS_ENABLED
3273 #define G_THREADS_IMPL_$g_threads_impl_def
3274 typedef struct _GMutex* GStaticMutex;
3275 #define G_STATIC_MUTEX_INIT NULL
3276 #define g_static_mutex_get_mutex(mutex) \\
3277   (g_static_mutex_get_mutex_impl_shortcut (mutex))
3278 _______EOF
3279         fi
3280
3281         cat >>$outfile <<_______EOF
3282 /* This represents a system thread as used by the implementation. An
3283  * alien implementaion, as loaded by g_thread_init can only count on
3284  * "sizeof (gpointer)" bytes to store their info. We however need more
3285  * for some of our native implementations. */
3286 typedef union _GSystemThread GSystemThread;
3287 union _GSystemThread
3288 {
3289   char   data[[$g_system_thread_sizeof]];
3290   double dummy_double;
3291   void  *dummy_pointer;
3292   long   dummy_long;
3293 };
3294 _______EOF
3295         if test x"$g_memory_barrier_needed" != xno; then
3296           echo >>$outfile
3297           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3298         fi
3299         if test x"$g_gcc_atomic_ops" != xno; then
3300           echo >>$outfile
3301           echo "#define G_ATOMIC_OP_USE_GCC_BUILTINS 1" >>$outfile
3302         fi
3303         echo >>$outfile
3304         g_bit_sizes="16 32 64"
3305         for bits in $g_bit_sizes; do
3306           cat >>$outfile <<_______EOF
3307 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3308 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3309 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3310 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3311 _______EOF
3312         done
3313
3314         cat >>$outfile <<_______EOF
3315 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3316 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3317 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3318 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3319 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3320 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3321 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3322 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3323 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3324 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3325 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3326 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3327 #define G_BYTE_ORDER $g_byte_order
3328
3329 #define GLIB_SYSDEF_POLLIN =$g_pollin
3330 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3331 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3332 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3333 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3334 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3335
3336 #define G_MODULE_SUFFIX "$g_module_suffix"
3337
3338 /* A GPid is an abstraction for a process "handle". It is *not* an
3339  * abstraction for a process identifier in general. GPid is used in
3340  * GLib only for descendant processes spawned with the g_spawn*
3341  * functions. On POSIX there is no "process handle" concept as such,
3342  * but on Windows a GPid is a handle to a process, a kind of pointer,
3343  * not a process identifier.
3344  */
3345 typedef $g_pid_type GPid;
3346
3347 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3348 #define GLIB_SYSDEF_AF_INET $g_af_inet
3349 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3350
3351 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3352 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3353 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3354
3355 G_END_DECLS
3356
3357 #endif /* GLIBCONFIG_H */
3358 _______EOF
3359
3360
3361         if cmp -s $outfile glib/glibconfig.h; then
3362           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3363           rm -f $outfile
3364         else
3365           mv $outfile glib/glibconfig.h
3366         fi
3367 ],[
3368
3369 # Note that if two cases are the same, case goes with the first one.
3370 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3371 # on variable expansion in case labels.  Look at the generated config.status
3372 # for a hint.
3373
3374 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3375   glib_header_alloca_h="$ac_cv_working_alloca_h"
3376 else
3377   glib_header_alloca_h="$ac_cv_header_alloca_h"
3378 fi
3379
3380 case xyes in
3381 x$ac_cv_header_float_h)
3382   glib_float_h=yes
3383   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3384   glib_md=DBL_MIN glib_Md=DBL_MAX
3385   ;;
3386 x$ac_cv_header_values_h)
3387   glib_values_h=yes
3388   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3389   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3390   ;;
3391 esac
3392
3393 case xyes in
3394 x$ac_cv_header_limits_h)
3395   glib_limits_h=yes
3396   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3397   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3398   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3399   ;;
3400 x$ac_cv_header_values_h)
3401   glib_values_h=yes
3402   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3403   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3404   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3405   ;;
3406 esac
3407
3408 if test x$ac_cv_header_sys_poll_h = xyes ; then
3409   glib_sys_poll_h=yes
3410 fi
3411
3412 if test x$enable_included_printf = xyes ; then
3413   glib_included_printf=yes
3414 fi
3415
3416 case 2 in
3417 $ac_cv_sizeof_short)
3418   gint16=short
3419   gint16_modifier='"h"'
3420   gint16_format='"hi"'
3421   guint16_format='"hu"'
3422   ;;
3423 $ac_cv_sizeof_int)
3424   gint16=int
3425   gint16_modifier='""'
3426   gint16_format='"i"'
3427   guint16_format='"u"'
3428   ;;
3429 esac
3430 case 4 in
3431 $ac_cv_sizeof_short)
3432   gint32=short
3433   gint32_modifier='"h"'
3434   gint32_format='"hi"'
3435   guint32_format='"hu"'
3436   ;;
3437 $ac_cv_sizeof_int)
3438   gint32=int
3439   gint32_modifier='""'
3440   gint32_format='"i"'
3441   guint32_format='"u"'
3442   ;;
3443 $ac_cv_sizeof_long)
3444   gint32=long
3445   gint32_modifier='"l"'
3446   gint32_format='"li"'
3447   guint32_format='"lu"'
3448   ;;
3449 esac
3450 case 8 in
3451 $ac_cv_sizeof_int)
3452   gint64=int
3453   gint64_modifier='""'
3454   gint64_format='"i"'
3455   guint64_format='"u"'
3456   glib_extension=
3457   gint64_constant='(val)'
3458   guint64_constant='(val)'
3459   ;;
3460 $ac_cv_sizeof_long)
3461   gint64=long
3462   gint64_modifier='"l"'
3463   gint64_format='"li"'
3464   guint64_format='"lu"'
3465   glib_extension=
3466   gint64_constant='(val##L)'
3467   guint64_constant='(val##UL)'
3468   ;;
3469 $ac_cv_sizeof_long_long)
3470   gint64='long long'
3471   if test -n "$glib_cv_long_long_format"; then
3472     gint64_modifier='"'$glib_cv_long_long_format'"'
3473     gint64_format='"'$glib_cv_long_long_format'i"'
3474     guint64_format='"'$glib_cv_long_long_format'u"'
3475   fi
3476   glib_extension='G_GNUC_EXTENSION '
3477   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3478   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3479   ;;
3480 $ac_cv_sizeof___int64)
3481   gint64='__int64'
3482   if test -n "$glib_cv_long_long_format"; then
3483     gint64_modifier='"'$glib_cv_long_long_format'"'
3484     gint64_format='"'$glib_cv_long_long_format'i"'
3485     guint64_format='"'$glib_cv_long_long_format'u"'
3486   fi
3487   glib_extension=
3488   gint64_constant='(val##i64)'
3489   guint64_constant='(val##ui64)'
3490   ;;
3491 esac
3492 glib_size_t=$ac_cv_sizeof_size_t
3493 glib_size_type_define="$glib_size_type"
3494 glib_void_p=$ac_cv_sizeof_void_p
3495 glib_long=$ac_cv_sizeof_long
3496
3497 case "$glib_size_type" in
3498 short)
3499   gsize_modifier='"h"'
3500   gsize_format='"hu"'
3501   gssize_format='"hi"'
3502   glib_msize_type='SHRT'
3503   ;;
3504 int)
3505   gsize_modifier='""'
3506   gsize_format='"u"'
3507   gssize_format='"i"'
3508   glib_msize_type='INT'
3509   ;;
3510 long)
3511   gsize_modifier='"l"'
3512   gsize_format='"lu"'
3513   gssize_format='"li"'
3514   glib_msize_type='LONG'
3515   ;;
3516 "long long"|__int64)
3517   gsize_modifier='"I64"'
3518   gsize_format='"I64u"'
3519   gssize_format='"I64i"'
3520   glib_msize_type='INT64'
3521   ;;
3522 esac
3523
3524 gintbits=`expr $ac_cv_sizeof_int \* 8`
3525 glongbits=`expr $ac_cv_sizeof_long \* 8`
3526 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3527
3528 case $ac_cv_sizeof_void_p in
3529 $ac_cv_sizeof_int)
3530   glib_intptr_type_define=int
3531   gintptr_modifier='""'
3532   gintptr_format='"i"'
3533   guintptr_format='"u"'
3534   glib_gpi_cast=''
3535   glib_gpui_cast=''
3536   ;;
3537 $ac_cv_sizeof_long)
3538   glib_intptr_type_define=long
3539   gintptr_modifier='"l"'
3540   gintptr_format='"li"'
3541   guintptr_format='"lu"'
3542   glib_gpi_cast='(glong)'
3543   glib_gpui_cast='(gulong)'
3544   ;;
3545 $ac_cv_sizeof_long_long)
3546   glib_intptr_type_define='long long'
3547   gintptr_modifier='"I64"'
3548   gintptr_format='"I64i"'
3549   guintptr_format='"I64u"'
3550   glib_gpi_cast='(gint64)'
3551   glib_gpui_cast='(guint64)'
3552   ;;
3553 $ac_cv_sizeof___int64)
3554   glib_intptr_type_define=__int64
3555   gintptr_modifier='"I64"'
3556   gintptr_format='"I64i"'
3557   guintptr_format='"I64u"'
3558   glib_gpi_cast='(gint64)'
3559   glib_gpui_cast='(guint64)'
3560   ;;
3561 *)
3562   glib_unknown_void_p=yes
3563   ;;
3564 esac
3565
3566
3567 case xyes in
3568 x$ac_cv_func_atexit)
3569   glib_atexit="
3570 #ifdef NeXT /* @#%@! NeXTStep */
3571 # define g_ATEXIT(proc) (!atexit (proc))
3572 #else
3573 # define g_ATEXIT(proc) (atexit (proc))
3574 #endif"
3575   ;;
3576 x$ac_cv_func_on_exit)
3577   glib_atexit="
3578 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3579   ;;
3580 esac
3581
3582 case xyes in
3583 x$ac_cv_func_memmove)
3584   glib_memmove='
3585 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3586   ;;
3587 x$glib_cv_working_bcopy)
3588   glib_memmove="
3589 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3590 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3591   ;;
3592 *)
3593   glib_memmove="
3594 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3595  * so we have to roll our own copy routine. */
3596 void g_memmove (void* dest, const void * src, unsigned long len);"
3597   ;;
3598 esac
3599
3600 glib_defines="
3601 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3602 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3603 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3604 "
3605
3606 case xyes in
3607 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3608 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3609 *)                      glib_vacopy=''
3610 esac
3611
3612 if test x$glib_cv_va_val_copy = xno; then
3613   glib_vacopy="\$glib_vacopy
3614 #define G_VA_COPY_AS_ARRAY 1"
3615 fi
3616
3617 if test x$glib_cv_hasinline = xyes; then
3618     glib_inline='#define G_HAVE_INLINE 1'
3619 fi
3620 if test x$glib_cv_has__inline = xyes; then
3621     glib_inline="\$glib_inline
3622 #define G_HAVE___INLINE 1"
3623 fi
3624 if test x$glib_cv_has__inline__ = xyes; then
3625     glib_inline="\$glib_inline
3626 #define G_HAVE___INLINE__ 1"
3627 fi
3628
3629 g_have_gnuc_varargs=$g_have_gnuc_varargs
3630 g_have_iso_c_varargs=$g_have_iso_c_varargs
3631 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3632
3633 g_can_inline=$g_can_inline
3634 g_have_gnuc_visibility=$g_have_gnuc_visibility
3635 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3636
3637 if test x$ac_cv_c_bigendian = xyes; then
3638   g_byte_order=G_BIG_ENDIAN
3639   g_bs_native=BE
3640   g_bs_alien=LE
3641 else
3642   g_byte_order=G_LITTLE_ENDIAN
3643   g_bs_native=LE
3644   g_bs_alien=BE
3645 fi
3646
3647 g_pollin=$glib_cv_value_POLLIN
3648 g_pollout=$glib_cv_value_POLLOUT
3649 g_pollpri=$glib_cv_value_POLLPRI
3650 g_pollhup=$glib_cv_value_POLLHUP
3651 g_pollerr=$glib_cv_value_POLLERR
3652 g_pollnval=$glib_cv_value_POLLNVAL
3653
3654 g_af_unix=$glib_cv_value_AF_UNIX
3655 g_af_inet=$glib_cv_value_AF_INET
3656 g_af_inet6=$glib_cv_value_AF_INET6
3657
3658 g_msg_peek=$glib_cv_value_MSG_PEEK
3659 g_msg_oob=$glib_cv_value_MSG_OOB
3660 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3661
3662 g_stack_grows=$glib_cv_stack_grows
3663
3664 g_have_eilseq=$have_eilseq
3665
3666 g_threads_impl_def=$g_threads_impl
3667
3668 g_mutex_has_default="$mutex_has_default"
3669 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
3670 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
3671 g_mutex_contents="$glib_cv_byte_contents_gmutex"
3672
3673 g_memory_barrier_needed="$glib_memory_barrier_needed"
3674 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3675
3676 g_module_suffix="$glib_gmodule_suffix"
3677
3678 g_pid_type="$glib_pid_type"
3679 case $host in
3680   *-*-beos*)
3681     glib_os="#define G_OS_BEOS"
3682     ;;
3683   *-*-cygwin*)
3684     glib_os="#define G_OS_UNIX
3685 #define G_PLATFORM_WIN32
3686 #define G_WITH_CYGWIN"
3687     ;;
3688   *-*-mingw*)
3689     glib_os="#define G_OS_WIN32
3690 #define G_PLATFORM_WIN32"
3691     ;;
3692   *)
3693     glib_os="#define G_OS_UNIX"
3694     ;;
3695 esac
3696 glib_static_compilation=""
3697 if test x$glib_win32_static_compilation = xyes; then
3698   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3699 #define GOBJECT_STATIC_COMPILATION 1"
3700 fi
3701 ])
3702
3703 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3704 #
3705 # 1.2.14 required for dbus_message_set_serial
3706 PKG_CHECK_MODULES(DBUS1,
3707                   dbus-1 >= 1.2.14,
3708                   [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3709                   have_dbus1=no)
3710 AC_SUBST(DBUS1_CFLAGS)
3711 AC_SUBST(DBUS1_LIBS)
3712 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3713
3714 dnl
3715 dnl Check for -Bsymbolic-functions linker flag used to avoid
3716 dnl intra-library PLT jumps, if available.
3717 dnl
3718
3719 AC_ARG_ENABLE(Bsymbolic,
3720               [AC_HELP_STRING([--disable-Bsymbolic],
3721                               [avoid linking with -Bsymbolic])],,
3722               [SAVED_LDFLAGS="${LDFLAGS}"
3723                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3724                LDFLAGS=-Wl,-Bsymbolic-functions
3725                AC_TRY_LINK([], [int main (void) { return 0; }],
3726                            AC_MSG_RESULT(yes)
3727                            enable_Bsymbolic=yes,
3728                            AC_MSG_RESULT(no)
3729                            enable_Bsymbolic=no)
3730                LDFLAGS="${SAVED_LDFLAGS}"])
3731
3732 if test "x${enable_Bsymbolic}" == "xyes"; then
3733   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3734 fi
3735
3736 AC_SUBST(GLIB_LINK_FLAGS)
3737
3738 #
3739 # Define variables corresponding to the correct include paths to use for
3740 # in-tree building.
3741 #
3742
3743 # for config.h:
3744 config_h_INCLUDES='-I$(top_builddir)'
3745 AC_SUBST(config_h_INCLUDES)
3746
3747 # glib:
3748 #   config.h
3749 #   $(top_builddir)/glib: for glibconfig.h
3750 #   $(top_srcdir)/glib:   for glib.h
3751 #   $(top_srcdir):        for everything
3752 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3753 AC_SUBST(glib_INCLUDES)
3754
3755 # gthread:
3756 #   same as glib
3757 gthread_INCLUDES='$(glib_INCLUDES)'
3758 AC_SUBST(gthread_INCLUDES)
3759
3760 # gobject:
3761 #   same as gthread
3762 gobject_INCLUDES='$(gthread_INCLUDES)'
3763 AC_SUBST(gobject_INCLUDES)
3764
3765 # gmodule:
3766 #   glib includes
3767 #   $(top_srcdir)/gmodule: for gmodule.h
3768 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3769 AC_SUBST(gmodule_INCLUDES)
3770
3771 # gio:
3772 #   same as gmodule
3773 gio_INCLUDES='$(gmodule_INCLUDES)'
3774 AC_SUBST(gio_INCLUDES)
3775
3776
3777 AC_CONFIG_FILES([
3778 glib-2.0.pc
3779 glib-2.0-uninstalled.pc
3780 gmodule-2.0.pc
3781 gmodule-export-2.0.pc
3782 gmodule-no-export-2.0.pc
3783 gmodule-2.0-uninstalled.pc
3784 gmodule-no-export-2.0-uninstalled.pc
3785 gthread-2.0.pc
3786 gthread-2.0-uninstalled.pc
3787 gobject-2.0.pc
3788 gobject-2.0-uninstalled.pc
3789 gio-2.0.pc
3790 gio-unix-2.0.pc
3791 gio-windows-2.0.pc
3792 gio-2.0-uninstalled.pc
3793 gio-unix-2.0-uninstalled.pc
3794 glib-zip
3795 glib-gettextize
3796 Makefile
3797 build/Makefile
3798 build/win32/Makefile
3799 build/win32/dirent/Makefile
3800 build/win32/vs9/Makefile
3801 build/win32/vs10/Makefile
3802 glib/Makefile
3803 glib/glib.stp
3804 glib/libcharset/Makefile
3805 glib/gnulib/Makefile
3806 glib/pcre/Makefile
3807 glib/update-pcre/Makefile
3808 glib/tests/Makefile
3809 gmodule/Makefile
3810 gmodule/gmoduleconf.h
3811 gobject/Makefile
3812 gobject/gobject.stp
3813 gobject/glib-mkenums
3814 gobject/tests/Makefile
3815 gthread/Makefile
3816 gthread/tests/Makefile
3817 gio/Makefile
3818 gio/gdbus-2.0/codegen/Makefile
3819 gio/gdbus-2.0/codegen/config.py
3820 gio/xdgmime/Makefile
3821 gio/inotify/Makefile
3822 gio/fen/Makefile
3823 gio/fam/Makefile
3824 gio/win32/Makefile
3825 gio/tests/Makefile
3826 gio/tests/gdbus-object-manager-example/Makefile
3827 po/Makefile.in
3828 docs/Makefile
3829 docs/reference/Makefile
3830 docs/reference/glib/Makefile
3831 docs/reference/glib/version.xml
3832 docs/reference/gobject/Makefile
3833 docs/reference/gobject/version.xml
3834 docs/reference/gio/Makefile
3835 docs/reference/gio/gdbus-object-manager-example/Makefile
3836 docs/reference/gio/version.xml
3837 tests/Makefile
3838 tests/gobject/Makefile
3839 tests/refcount/Makefile
3840 m4macros/Makefile
3841 ])
3842
3843 AC_CONFIG_COMMANDS([chmod-scripts],
3844 [chmod 0755 glib-zip
3845 chmod 0755 glib-gettextize
3846 chmod 0755 gobject/glib-mkenums])
3847
3848 # we want to invoke this macro solely so that the config.status script
3849 # and automake generated makefiles know about these generated files.
3850 # They are only needed to distcheck the package
3851 if false; then
3852   AC_CONFIG_FILES([
3853     INSTALL
3854     README
3855     config.h.win32
3856     glib/glibconfig.h.win32
3857     glib/makefile.msc
3858     glib/glib.rc
3859     gmodule/makefile.msc
3860     gmodule/gmodule.rc
3861     gobject/makefile.msc
3862     gobject/gobject.rc
3863     gthread/makefile.msc
3864     gthread/gthread.rc
3865     gio/gio.rc
3866     tests/makefile.msc
3867   ])
3868 fi
3869
3870 AC_OUTPUT